configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_INIT([lttng-ust],[2.1.0-rc1],[mathieu dot desnoyers at efficios dot com])
   5
   6 # Following the numbering scheme proposed by libtool for the library version
   7 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
   8 AC_SUBST([LTTNG_UST_LIBRARY_VERSION], [0:0:0])
   9 # note: remember to update tracepoint.h dlopen() to match this version
  10 # number. TODO: eventually automate by exporting the major number.
  11
  12 AC_CONFIG_AUX_DIR([config])
  13 AC_CANONICAL_TARGET
  14 AC_CANONICAL_HOST
  15 AC_CONFIG_MACRO_DIR([config])
  16 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
  17 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  18 AC_CONFIG_SRCDIR([include/lttng/tracepoint.h])
  19
  20 # Configuration options, which will be installed in the config.h
  21 AC_CONFIG_HEADERS([config.h include/lttng/ust-config.h])
  22 AH_TEMPLATE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [Use efficient unaligned access.])
  23 AH_TEMPLATE([LTTNG_UST_HAVE_SDT_INTEGRATION], [SystemTap integration via sdt.h])
  24
  25 # Compute minor/major/patchlevel version numbers
  26 AC_PROG_SED
  27 major_version=$(echo AC_PACKAGE_VERSION | sed 's/^\([[0-9]]\)*\.[[0-9]]*\.[[0-9]]*.*$/\1/')
  28 minor_version=$(echo AC_PACKAGE_VERSION | sed 's/^[[0-9]]*\.\([[0-9]]*\)\.[[0-9]]*.*$/\1/')
  29 patchlevel_version=$(echo AC_PACKAGE_VERSION | sed 's/^[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\).*$/\1/')
  30 AC_SUBST([MAJOR_VERSION], [$major_version])
  31 AC_SUBST([MINOR_VERSION], [$minor_version])
  32 AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version])
  33 AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [UST major version number])
  34 AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [UST minor version number])
  35 AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [UST patchlevel version number])
  36
  37 version_name="Basse Messe"
  38 version_description="Light coloured German ale whose style was named after the city Cologne (Koln) where it was first brewed. It is a rather simple beer with lightly fruity aromas and a delicate hoppy fragrance. The beer has a pronounced malty taste with a subtle bitter aftertaste"
  39 AC_DEFINE_UNQUOTED([VERSION_NAME], ["$version_name"], [UST version name])
  40 AC_DEFINE_UNQUOTED([VERSION_DESCRIPTION], ["$version_description"], [UST version description])
  41
  42 AC_PROG_GREP
  43 # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
  44 AC_ARG_ENABLE(libtool-linkdep-fixup,
  45         AS_HELP_STRING([--disable-libtool-linkdep-fixup],
  46                         [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)]),
  47         libtool_fixup=$enableval,
  48         libtool_fixup=yes)
  49
  50 AS_IF([test "x$libtool_fixup" = "xyes"],
  51             [
  52             libtool_m4="$srcdir/config/libtool.m4"
  53             libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
  54             AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
  55             libtool_flag_pattern_count=$(grep -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
  56             AS_IF([test $libtool_flag_pattern_count -ne 0],
  57             [
  58                   AC_MSG_RESULT([$libtool_flag_pattern_count])
  59                   AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
  60                   sed -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
  61                   ],
  62                   [
  63                   AC_MSG_RESULT([none])
  64                   ])
  65             ])
  66
  67 # Checks for programs.
  68 AC_PROG_CC
  69 AC_PROG_CXX
  70 AC_PROG_MAKE_SET
  71 LT_INIT
  72
  73 ## Checks for libraries.
  74 AC_CHECK_LIB([dl], [dlopen],
  75 [
  76         have_libdl=yes
  77 ],
  78 [
  79         #libdl not found, check for dlopen in libc.
  80         AC_CHECK_LIB([c], [dlopen],
  81         [
  82                 have_libc_dl=yes
  83         ],
  84         [
  85                 AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
  86         ])
  87 ])
  88 AM_CONDITIONAL([LTTNG_UST_BUILD_WITH_LIBDL], [test "x$have_libdl" = "xyes"])
  89 AM_CONDITIONAL([LTTNG_UST_BUILD_WITH_LIBC_DL], [test "x$have_libc_dl" = "xyes"])
  90
  91 AC_CHECK_LIB([pthread], [pthread_create])
  92
  93 # Check for libuuid
  94 AC_CHECK_LIB([uuid], [uuid_generate],
  95 [
  96         AC_DEFINE_UNQUOTED([LTTNG_UST_HAVE_LIBUUID], 1, [Has libuuid support.])
  97         have_libuuid=yes
  98 ],
  99 [
 100         # libuuid not found, check for uuid_create in libc.
 101         AC_CHECK_LIB([c], [uuid_create],
 102         [
 103                 AC_DEFINE_UNQUOTED([LTTNG_UST_HAVE_LIBC_UUID], 1, [Has libc uuid support.])
 104                 have_libc_uuid=yes
 105         ],
 106         [
 107                 AC_MSG_ERROR([Cannot find libuuid uuid_generate nor libc uuid_create. Use [LDFLAGS]=-Ldir to specify their location.])
 108         ])
 109 ]
 110 )
 111 AM_CONDITIONAL([LTTNG_UST_BUILD_WITH_LIBUUID], [test "x$have_libuuid" = "xyes"])
 112 AM_CONDITIONAL([LTTNG_UST_BUILD_WITH_LIBC_UUID], [test "x$have_libc_uuid" = "xyes"])
 113
 114 # Checks for header files.
 115 #AC_CHECK_HEADERS([fcntl.h stdint.h stdlib.h string.h sys/socket.h sys/time.h unistd.h])
 116
 117 # Checks for typedefs, structures, and compiler characteristics.
 118 AC_C_INLINE
 119 #AC_TYPE_INT16_T
 120 #AC_TYPE_INT32_T
 121 #AC_TYPE_INT64_T
 122 #AC_TYPE_INT8_T
 123 #AC_TYPE_PID_T
 124 #AC_TYPE_SIZE_T
 125 #AC_TYPE_SSIZE_T
 126 #AC_TYPE_UINT16_T
 127 #AC_TYPE_UINT32_T
 128 #AC_TYPE_UINT64_T
 129 #AC_TYPE_UINT8_T
 130 #AC_CHECK_TYPES([ptrdiff_t])
 131
 132 # Checks for library functions.
 133 AC_FUNC_MALLOC
 134 AC_CHECK_FUNCS([gettimeofday munmap socket strerror strtol sched_getcpu sysconf])
 135
 136 CFLAGS="-Wall $CFLAGS"
 137
 138 # URCU
 139
 140 # urcu - check if we just find the headers it out of the box.
 141 AC_CHECK_HEADERS([urcu-bp.h], [], [AC_MSG_ERROR([Cannot find [URCU] headers (urcu-bp.h). Use [CPPFLAGS]=-Idir to specify their location.
 142 This error can also occur when the liburcu package's configure script has not been run.])])
 143
 144 # urcu-cds - check that URCU Concurrent Data Structure lib is available to compilation
 145 # Part of Userspace RCU library 0.7.2 or better.
 146 AC_CHECK_LIB([urcu-cds], [_cds_lfht_new], [], [AC_MSG_ERROR([Cannot find
 147 liburcu-cds lib, part of Userspace RCU 0.7 or better. Use [LDFLAGS]=-Ldir to specify its location.])])
 148
 149 AC_MSG_CHECKING([caa_likely()])
 150 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 151 #include <urcu/compiler.h>
 152 void fct(void)
 153 {
 154         if (caa_likely(1)) {
 155         }
 156 }
 157 ]])],[
 158         AC_MSG_RESULT([yes])
 159 ],[
 160         AC_MSG_RESULT([no])
 161         AC_MSG_ERROR([Please upgrade your version of liburcu to 0.6.6 or better])
 162
 163 ])
 164
 165 # urcu - check that URCU lib is available to compilation
 166 AC_CHECK_LIB([urcu-bp], [synchronize_rcu_bp], [], [AC_MSG_ERROR([Cannot find liburcu-bp lib. Use [LDFLAGS]=-Ldir to specify its location.])])
 167
 168 # urcu - check that URCU lib is at least version 0.6
 169 AC_CHECK_LIB([urcu-bp], [call_rcu_bp], [], [AC_MSG_ERROR([liburcu 0.6 or newer is needed, please update your version or use [LDFLAGS]=-Ldir to specify the right location.])])
 170
 171
 172 # Check for various supplementary host information (beyond the
 173 # triplet) which might affect the library format choices.  E.g., we
 174 # can be building with `i686-unknown-linux-gnu-gcc -m64'
 175
 176 case "${host}" in
 177 changequote(,)dnl
 178   i[34567]86-*-linux*)
 179 changequote([,])dnl
 180     AC_CACHE_CHECK([if building for x86-64], [ust_cv_i386_is_x86_64],
 181                     [save_CPPFLAGS="$CPPFLAGS"
 182                     CPPFLAGS="$CPPFLAGS $CFLAGS"
 183                     AC_EGREP_CPP([got it], [
 184 #if __x86_64__
 185 got it
 186 #endif
 187                  ], [ust_cv_i386_is_x86_64=yes],
 188                     [ust_cv_i386_is_x86_64=no])
 189                     CPPFLAGS="$save_CPPFLAGS"])
 190     ;;
 191 esac
 192
 193 AC_MSG_CHECKING([library format for the host system])
 194 case $host_cpu in
 195 changequote(,)dnl
 196         i[3456]86)
 197 changequote([,])dnl
 198           if test "$ust_cv_i386_is_x86_64" = yes ; then
 199              LIBFORMAT="elf64-x86-64"
 200           else
 201              LIBFORMAT="elf32-i386"
 202           fi
 203           ;;
 204         x86_64) LIBFORMAT="elf64-x86-64" ;;
 205         amd64) LIBFORMAT="elf64-x86-64" ;;
 206         powerpc) LIBFORMAT="elf32-powerpc" ;;
 207         ppc64) LIBFORMAT="elf64-powerpc" ;;
 208         powerpc64) LIBFORMAT="elf64-powerpc" ;;
 209         s390) LIBFORMAT="elf32-s390"; NO_UNALIGNED_ACCESS=1 ;;
 210         s390x) LIBFORMAT="elf64-s390"; NO_UNALIGNED_ACCESS=1 ;;
 211         armv5) LIBFORMAT="elf32-littlearm"; NO_UNALIGNED_ACCESS=1 ;;
 212         arm) LIBFORMAT="elf32-littlearm"; NO_UNALIGNED_ACCESS=1 ;;
 213         mips*) LIBFORMAT=""; NO_UNALIGNED_ACCESS=1;;
 214         *) AC_MSG_ERROR([unable to detect library format (unsupported architecture ($host_cpu)?)]) ;;
 215 esac
 216 AC_SUBST(LIBFORMAT)
 217 AC_MSG_RESULT($LIBFORMAT)
 218
 219 if test "x$host_cpu" = "xarm" ; then
 220 AC_MSG_CHECKING([checking for armv5])
 221 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 222 #ifndef __ARM_ARCH_5TEJ__
 223 #error "no arm5 here"
 224 #endif
 225 ]])],[
 226         AC_MSG_RESULT([yes])
 227         NO_UNALIGNED_ACCESS=1
 228
 229 ],[
 230         AC_MSG_RESULT([no])
 231
 232 ])
 233 fi
 234 if test x$NO_UNALIGNED_ACCESS = x ; then
 235 AC_DEFINE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [1])
 236 fi
 237
 238 # Set compile flags to java include files if given
 239 AC_ARG_WITH([java-jdk],
 240         [AS_HELP_STRING([--with-java-jdk=DIR],[use the Java JDK in DIR. Ex : $JAVA_HOME.])],
 241         [JAVA_JDK=$withval],
 242         [JAVA_JDK=""]
 243 )
 244 AS_IF([test $JAVA_JDK],[
 245         AS_IF([test -d $JAVA_JDK],[
 246                 AC_MSG_RESULT([using Java includes in $JAVA_SDK])
 247                 SUBDIRS=`find $JAVA_JDK/include -type d`
 248                 CPPFLAGS+=" "
 249                 CPPFLAGS+=`for x in $SUBDIRS; do echo -n "-I$x "; done`
 250                 CPPFLAGS+=" "
 251         ],[
 252                 AC_MSG_ERROR(Unable to find Java include files in $JAVA_JDK)
 253         ])
 254 ])
 255
 256 # Check for JNI header files if requested
 257 AC_ARG_WITH([jni-interface],
 258         [AS_HELP_STRING([--with-jni-interface],[build JNI interface between C and Java. Needs Java include files [default=no]])],
 259         [jni_interface=$withval],
 260         [jni_interface=no]
 261 )
 262
 263 AS_IF([test "x$jni_interface" = "xyes"],[
 264         AC_CHECK_HEADERS([jni.h],[],[
 265         AC_MSG_ERROR([missing jni.h
 266 Make sure Sun Java, OpenJDK or GCJ is installed and that this header file exists in the system path.
 267 Use the --with-java-jdk=DIR flag to point to your Java include files, or disable the JNI interface.])
 268         ])
 269 ])
 270 AM_CONDITIONAL([BUILD_JNI_INTERFACE], [test "x$jni_interface" = "xyes"])
 271
 272 # sdt.h integration
 273 AC_ARG_WITH([sdt],
 274         [AS_HELP_STRING([--with-sdt],[provide SystemTap integration via sdt.h [default=no]])],
 275         [with_sdt=$withval],
 276         [with_sdt="no"]
 277 )
 278
 279 AS_IF([test "x$with_sdt" = "xyes"],[
 280         AC_MSG_CHECKING([STAP_PROBEV()])
 281         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 282         #define SDT_USE_VARIADIC
 283         #include <sys/sdt.h>
 284         void fct(void)
 285         {
 286                 STAP_PROBEV(provider,name,1,2,3,4,5,6,7,8,9,10);
 287         }
 288         ]])],[
 289                 AC_MSG_RESULT([yes])
 290                 AC_DEFINE([LTTNG_UST_HAVE_SDT_INTEGRATION], [1])
 291         ],[
 292                 AC_MSG_RESULT([no])
 293                 AC_MSG_ERROR([The sdt.h integration was requested but the STAP_PROBEV define cannot be used. Make sure it is installed, and up to date, or use CPPFLAGS=-I/path/ to specify a non-standard path to sys/sdt.h])
 294         ])
 295 ])
 296
 297 #currently disabled.
 298         #tests/hello2/Makefile
 299         #tests/basic/Makefile
 300         #tests/simple_include/Makefile
 301         #tests/snprintf/Makefile
 302         #tests/test-nevents/Makefile
 303         #tests/test-libustinstr-malloc/Makefile
 304         #tests/dlopen/Makefile
 305         #tests/same_line_marker/Makefile
 306         #tests/trace_event/Makefile
 307         #tests/tracepoint/Makefile
 308         #tests/tracepoint/benchmark/Makefile
 309         #tests/register_test/Makefile
 310         #tests/libustctl_function_#tests/Makefile
 311         #tests/exit-fast/Makefile
 312         #tests/basic_long/Makefile
 313
 314 AC_CONFIG_FILES([
 315         Makefile
 316         doc/Makefile
 317         doc/examples/Makefile
 318         include/Makefile
 319         include/lttng/ust-version.h
 320         snprintf/Makefile
 321         libringbuffer/Makefile
 322         liblttng-ust-comm/Makefile
 323         liblttng-ust/Makefile
 324         liblttng-ust-ctl/Makefile
 325         liblttng-ust-fork/Makefile
 326         liblttng-ust-java/Makefile
 327         liblttng-ust-libc-wrapper/Makefile
 328         tools/Makefile
 329         tests/Makefile
 330         tests/hello/Makefile
 331         tests/hello-static-lib/Makefile
 332         tests/hello.cxx/Makefile
 333         tests/daemon/Makefile
 334         tests/demo/Makefile
 335         tests/fork/Makefile
 336         tests/ust-basic-tracing/Makefile
 337         tests/ust-multi-test/Makefile
 338         lttng-ust.pc
 339 ])
 340
 341 AC_OUTPUT
 342
 343 AS_ECHO()
 344 AS_ECHO("Version name: $version_name")
 345 AS_ECHO("$version_description")
 346
 347 # Report on the configuration options
 348 AS_ECHO()
 349 AS_ECHO("LTTng-UST will be built with the following options:")
 350 AS_ECHO("Library format: $LIBFORMAT")
 351
 352 AS_ECHO()
 353 AS_ECHO_N("Java support (JNI): ")
 354 AS_IF([test "x$jni_interface" = "xyes"], [AS_ECHO("Enabled")], [AS_ECHO("Disabled")])
 355
 356 AS_ECHO_N("sdt.h integration:  ")
 357 AS_IF([test "x$with_sdt" = "xyes"], [AS_ECHO("Enabled")], [AS_ECHO("Disabled")])
 358
 359 AS_ECHO()
 360 AS_ECHO("Type 'make' to compile.")
 361