configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_INIT([lttng-ust],[2.0.6],[mathieu dot desnoyers at efficios dot com])
   5
   6 # Following the numbering scheme proposed by libtool for the library version
   7 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
   8 AC_SUBST([LTTNG_UST_LIBRARY_VERSION], [0:0:0])
   9 # note: remember to update tracepoint.h dlopen() to match this version
  10 # number. TODO: eventually automate by exporting the major number.
  11
  12 AC_CONFIG_AUX_DIR([config])
  13 AC_CANONICAL_TARGET
  14 AC_CANONICAL_HOST
  15 AC_CONFIG_MACRO_DIR([config])
  16 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
  17 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  18 AC_CONFIG_SRCDIR([include/lttng/tracepoint.h])
  19
  20 # Configuration options, which will be installed in the config.h
  21 AC_CONFIG_HEADERS([config.h include/lttng/ust-config.h])
  22 AH_TEMPLATE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [Use efficient unaligned access.])
  23 AH_TEMPLATE([LTTNG_UST_HAVE_SDT_INTEGRATION], [SystemTap integration via sdt.h])
  24
  25 # Compute minor/major/patchlevel version numbers
  26 AC_PROG_SED
  27 major_version=$(echo AC_PACKAGE_VERSION | sed 's/^\([[0-9]]\)*\.[[0-9]]*\.[[0-9]]*.*$/\1/')
  28 minor_version=$(echo AC_PACKAGE_VERSION | sed 's/^[[0-9]]*\.\([[0-9]]*\)\.[[0-9]]*.*$/\1/')
  29 patchlevel_version=$(echo AC_PACKAGE_VERSION | sed 's/^[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\).*$/\1/')
  30 AC_SUBST([MAJOR_VERSION], [$major_version])
  31 AC_SUBST([MINOR_VERSION], [$minor_version])
  32 AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version])
  33 AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [UST major version number])
  34 AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [UST minor version number])
  35 AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [UST patchlevel version number])
  36
  37 version_name="Annedd'ale"
  38 version_description="New type of beer, 100% from Quebec, flavored with sapin beaumier needles, with a touch of hops."
  39 AC_DEFINE_UNQUOTED([VERSION_NAME], [$version_name], [UST version name])
  40 AC_DEFINE_UNQUOTED([VERSION_DESCRIPTION], [$version_description], [UST version description])
  41
  42 AC_PROG_GREP
  43 # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
  44 AC_ARG_ENABLE(libtool-linkdep-fixup,
  45         AS_HELP_STRING([--disable-libtool-linkdep-fixup],
  46                         [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)]),
  47         libtool_fixup=$enableval,
  48         libtool_fixup=yes)
  49
  50 AS_IF([test "x$libtool_fixup" = "xyes"],
  51             [
  52             libtool_m4="$srcdir/config/libtool.m4"
  53             libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
  54             AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
  55             libtool_flag_pattern_count=$(grep -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
  56             AS_IF([test $libtool_flag_pattern_count -ne 0],
  57             [
  58                   AC_MSG_RESULT([$libtool_flag_pattern_count])
  59                   AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
  60                   sed -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
  61                   ],
  62                   [
  63                   AC_MSG_RESULT([none])
  64                   ])
  65             ])
  66
  67 AM_CONDITIONAL([NO_SHARED], [test "x$enable_shared" = "xno"])
  68
  69 # Checks for programs.
  70 AC_PROG_CC
  71 AC_PROG_CXX
  72 AC_PROG_MAKE_SET
  73 LT_INIT
  74
  75 ## Checks for libraries.
  76 AC_CHECK_LIB([dl], [dlopen])
  77 AC_CHECK_LIB([pthread], [pthread_create])
  78
  79 # Check for libuuid
  80 AC_CHECK_LIB([uuid], [uuid_generate],
  81 [
  82         AC_DEFINE_UNQUOTED([LTTNG_UST_HAVE_LIBUUID], 1, [Has libuuid support.])
  83         have_libuuid=yes
  84 ],
  85 [
  86         # libuuid not found, check for uuid_create in libc.
  87         AC_CHECK_LIB([c], [uuid_create],
  88         [
  89                 AC_DEFINE_UNQUOTED([LTTNG_UST_HAVE_LIBC_UUID], 1, [Has libc uuid support.])
  90                 have_libc_uuid=yes
  91         ],
  92         [
  93                 AC_MSG_ERROR([Cannot find libuuid uuid_generate nor libc uuid_create. Use [LDFLAGS]=-Ldir to specify its location.])
  94         ])
  95 ]
  96 )
  97 AM_CONDITIONAL([LTTNG_UST_BUILD_WITH_LIBUUID], [test "x$have_libuuid" = "xyes"])
  98 AM_CONDITIONAL([LTTNG_UST_BUILD_WITH_LIBC_UUID], [test "x$have_libc_uuid" = "xyes"])
  99
 100 # Checks for header files.
 101 #AC_CHECK_HEADERS([fcntl.h stdint.h stdlib.h string.h sys/socket.h sys/time.h unistd.h])
 102
 103 # Checks for typedefs, structures, and compiler characteristics.
 104 AC_C_INLINE
 105 #AC_TYPE_INT16_T
 106 #AC_TYPE_INT32_T
 107 #AC_TYPE_INT64_T
 108 #AC_TYPE_INT8_T
 109 #AC_TYPE_PID_T
 110 #AC_TYPE_SIZE_T
 111 #AC_TYPE_SSIZE_T
 112 #AC_TYPE_UINT16_T
 113 #AC_TYPE_UINT32_T
 114 #AC_TYPE_UINT64_T
 115 #AC_TYPE_UINT8_T
 116 #AC_CHECK_TYPES([ptrdiff_t])
 117
 118 # Checks for library functions.
 119 AC_FUNC_MALLOC
 120 AC_CHECK_FUNCS([gettimeofday munmap socket strerror strtol sched_getcpu sysconf])
 121
 122 CFLAGS="-Wall $CFLAGS"
 123
 124 # URCU
 125
 126 # urcu - check if we just find the headers it out of the box.
 127 AC_CHECK_HEADERS([urcu-bp.h], [], [AC_MSG_ERROR([Cannot find [URCU] headers (urcu-bp.h). Use [CPPFLAGS]=-Idir to specify their location.
 128 This error can also occur when the liburcu package's configure script has not been run.])])
 129
 130 AC_MSG_CHECKING([caa_likely()])
 131 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 132 #include <urcu/compiler.h>
 133 void fct(void)
 134 {
 135         if (caa_likely(1)) {
 136         }
 137 }
 138 ]])],[
 139         AC_MSG_RESULT([yes])
 140 ],[
 141         AC_MSG_RESULT([no])
 142         AC_MSG_ERROR([Please upgrade your version of liburcu to 0.6.6 or better])
 143
 144 ])
 145
 146 # urcu - check that URCU lib is available to compilation
 147 AC_CHECK_LIB([urcu-bp], [synchronize_rcu_bp], [], [AC_MSG_ERROR([Cannot find liburcu-bp lib. Use [LDFLAGS]=-Ldir to specify its location.])])
 148
 149 # urcu - check that URCU lib is at least version 0.6
 150 AC_CHECK_LIB([urcu-bp], [call_rcu_bp], [], [AC_MSG_ERROR([liburcu 0.6 or newer is needed, please update your version or use [LDFLAGS]=-Ldir to specify the right location.])])
 151
 152
 153 # Check for various supplementary host information (beyond the
 154 # triplet) which might affect the library format choices.  E.g., we
 155 # can be building with `i686-unknown-linux-gnu-gcc -m64'
 156
 157 case "${host}" in
 158 changequote(,)dnl
 159   i[34567]86-*-linux*)
 160 changequote([,])dnl
 161     AC_CACHE_CHECK([if building for x86-64], [ust_cv_i386_is_x86_64],
 162                     [save_CPPFLAGS="$CPPFLAGS"
 163                     CPPFLAGS="$CPPFLAGS $CFLAGS"
 164                     AC_EGREP_CPP([got it], [
 165 #if __x86_64__
 166 got it
 167 #endif
 168                  ], [ust_cv_i386_is_x86_64=yes],
 169                     [ust_cv_i386_is_x86_64=no])
 170                     CPPFLAGS="$save_CPPFLAGS"])
 171     ;;
 172     # All symbols must be resolved at link time on Cygwin/MinGW/Windows,
 173     # else libtool will not be able to build shared libraries.
 174     *-*-cygwin*)
 175     LDFLAGS="-Wl,-no-undefined $LDFLAGS";;
 176 esac
 177
 178 AC_MSG_CHECKING([library format for the host system])
 179 case $host_cpu in
 180 changequote(,)dnl
 181         i[3456]86)
 182 changequote([,])dnl
 183           if test "$ust_cv_i386_is_x86_64" = yes ; then
 184              LIBFORMAT="elf64-x86-64"
 185           else
 186              LIBFORMAT="elf32-i386"
 187           fi
 188           ;;
 189         x86_64) LIBFORMAT="elf64-x86-64" ;;
 190         powerpc) LIBFORMAT="elf32-powerpc" ;;
 191         ppc64) LIBFORMAT="elf64-powerpc" ;;
 192         powerpc64) LIBFORMAT="elf64-powerpc" ;;
 193         s390) LIBFORMAT="elf32-s390"; NO_UNALIGNED_ACCESS=1 ;;
 194         s390x) LIBFORMAT="elf64-s390"; NO_UNALIGNED_ACCESS=1 ;;
 195         armv5) LIBFORMAT="elf32-littlearm"; NO_UNALIGNED_ACCESS=1 ;;
 196         arm) LIBFORMAT="elf32-littlearm"; NO_UNALIGNED_ACCESS=1 ;;
 197         mips*) LIBFORMAT=""; NO_UNALIGNED_ACCESS=1;;
 198         *) AC_MSG_ERROR([unable to detect library format (unsupported architecture ($host_cpu)?)]) ;;
 199 esac
 200 AC_SUBST(LIBFORMAT)
 201 AC_MSG_RESULT($LIBFORMAT)
 202
 203 if test "x$host_cpu" = "xarm" ; then
 204 AC_MSG_CHECKING([checking for armv5])
 205 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 206 #ifndef __ARM_ARCH_5TEJ__
 207 #error "no arm5 here"
 208 #endif
 209 ]])],[
 210         AC_MSG_RESULT([yes])
 211         NO_UNALIGNED_ACCESS=1
 212
 213 ],[
 214         AC_MSG_RESULT([no])
 215
 216 ])
 217 fi
 218 if test x$NO_UNALIGNED_ACCESS = x ; then
 219 AC_DEFINE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [1])
 220 fi
 221
 222 # Set compile flags to java include files if given
 223 AC_ARG_WITH([java-jdk],
 224         [AS_HELP_STRING([--with-java-jdk=DIR],[use the Java JDK in DIR. Ex : $JAVA_HOME.])],
 225         [JAVA_JDK=$withval],
 226         [JAVA_JDK=""]
 227 )
 228 AS_IF([test $JAVA_JDK],[
 229         AS_IF([test -d $JAVA_JDK],[
 230                 AC_MSG_RESULT([using Java includes in $JAVA_SDK])
 231                 SUBDIRS=`find $JAVA_JDK/include -type d`
 232                 CPPFLAGS+=" "
 233                 CPPFLAGS+=`for x in $SUBDIRS; do echo -n "-I$x "; done`
 234                 CPPFLAGS+=" "
 235         ],[
 236                 AC_MSG_ERROR(Unable to find Java include files in $JAVA_JDK)
 237         ])
 238 ])
 239
 240 # sdt.h integration
 241 AC_ARG_WITH([sdt],
 242         [AS_HELP_STRING([--with-sdt],[provide SystemTap integration via sdt.h [default=no]])],
 243         [with_sdt=$withval],
 244         [with_sdt="no"]
 245 )
 246
 247 AS_IF([test "x$with_sdt" = "xyes"],[
 248         AC_MSG_CHECKING([STAP_PROBEV()])
 249         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 250         #define SDT_USE_VARIADIC
 251         #include <sys/sdt.h>
 252         void fct(void)
 253         {
 254                 STAP_PROBEV(provider,name,1,2,3,4,5,6,7,8,9,10);
 255         }
 256         ]])],[
 257                 AC_MSG_RESULT([yes])
 258                 AC_DEFINE([LTTNG_UST_HAVE_SDT_INTEGRATION], [1])
 259         ],[
 260                 AC_MSG_RESULT([no])
 261                 AC_MSG_ERROR([The sdt.h integration was requested but the STAP_PROBEV define cannot be used. Make sure it is installed, and up to date, or use CPPFLAGS=-I/path/ to specify a non-standard path to sys/sdt.h])
 262         ])
 263 ])
 264
 265 #currently disabled.
 266         #tests/hello2/Makefile
 267         #tests/basic/Makefile
 268         #tests/simple_include/Makefile
 269         #tests/snprintf/Makefile
 270         #tests/test-nevents/Makefile
 271         #tests/test-libustinstr-malloc/Makefile
 272         #tests/dlopen/Makefile
 273         #tests/same_line_marker/Makefile
 274         #tests/trace_event/Makefile
 275         #tests/tracepoint/Makefile
 276         #tests/tracepoint/benchmark/Makefile
 277         #tests/register_test/Makefile
 278         #tests/libustctl_function_#tests/Makefile
 279         #tests/exit-fast/Makefile
 280         #tests/basic_long/Makefile
 281
 282 #       liblttng-ust-java/Makefile
 283
 284 # Disabled for now, because these libraries
 285 # rely on the dlsym(3) RTLD_NEXT GNU extension.
 286 # This is not implemented in Cygwin.
 287 #liblttng-ust-fork/Makefile
 288 #liblttng-ust-libc-wrapper/Makefile
 289 #tests/fork/Makefile
 290
 291 AC_CONFIG_FILES([
 292         Makefile
 293         doc/Makefile
 294         doc/examples/Makefile
 295         include/Makefile
 296         include/lttng/ust-version.h
 297         snprintf/Makefile
 298         libringbuffer/Makefile
 299         liblttng-ust-comm/Makefile
 300         liblttng-ust/Makefile
 301         liblttng-ust-ctl/Makefile
 302         tools/Makefile
 303         tests/Makefile
 304         tests/hello/Makefile
 305         tests/hello-static-lib/Makefile
 306         tests/hello.cxx/Makefile
 307         tests/demo/Makefile
 308         tests/ust-basic-tracing/Makefile
 309         tests/ust-multi-test/Makefile
 310         lttng-ust.pc
 311 ])
 312
 313 AC_OUTPUT
 314
 315 AS_ECHO()
 316 AS_ECHO("Version name: $version_name")
 317 AS_ECHO("$version_description")
 318
 319 # Report on the configuration options
 320 AS_ECHO()
 321 AS_ECHO("LTTng-UST will be built with the following options:")
 322 AS_ECHO("Library format: $LIBFORMAT")
 323
 324 AS_ECHO()
 325 AS_ECHO_N("sdt.h integration:  ")
 326 AS_IF([test "x$with_sdt" = "xyes"], [AS_ECHO("Enabled")], [AS_ECHO("Disabled")])
 327
 328 AS_ECHO()
 329 AS_ECHO("Type 'make' to compile.")
 330