configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_INIT([lttng-ust],[2.0.4],[mathieu dot desnoyers at efficios dot com])
   5
   6 # Following the numbering scheme proposed by libtool for the library version
   7 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
   8 AC_SUBST([LTTNG_UST_LIBRARY_VERSION], [0:0:0])
   9 # note: remember to update tracepoint.h dlopen() to match this version
  10 # number. TODO: eventually automate by exporting the major number.
  11
  12 AC_CONFIG_AUX_DIR([config])
  13 AC_CANONICAL_TARGET
  14 AC_CANONICAL_HOST
  15 AC_CONFIG_MACRO_DIR([config])
  16 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
  17 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  18 AC_CONFIG_SRCDIR([include/lttng/tracepoint.h])
  19
  20 # Configuration options, which will be installed in the config.h
  21 AC_CONFIG_HEADERS([config.h include/lttng/ust-config.h])
  22 AH_TEMPLATE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [Use efficient unaligned access.])
  23 AH_TEMPLATE([LTTNG_UST_HAVE_SDT_INTEGRATION], [SystemTap integration via sdt.h])
  24
  25 # Compute minor/major/patchlevel version numbers
  26 AC_PROG_SED
  27 major_version=$(echo AC_PACKAGE_VERSION | sed 's/^\([[0-9]]\)*\.[[0-9]]*\.[[0-9]]*.*$/\1/')
  28 minor_version=$(echo AC_PACKAGE_VERSION | sed 's/^[[0-9]]*\.\([[0-9]]*\)\.[[0-9]]*.*$/\1/')
  29 patchlevel_version=$(echo AC_PACKAGE_VERSION | sed 's/^[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\).*$/\1/')
  30 AC_SUBST([MAJOR_VERSION], [$major_version])
  31 AC_SUBST([MINOR_VERSION], [$minor_version])
  32 AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version])
  33 AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [UST major version number])
  34 AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [UST minor version number])
  35 AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [UST patchlevel version number])
  36
  37 version_name="Annedd'ale"
  38 version_description="New type of beer, 100% from Quebec, flavored with sapin beaumier needles, with a touch of hops."
  39 AC_DEFINE_UNQUOTED([VERSION_NAME], [$version_name], [UST version name])
  40 AC_DEFINE_UNQUOTED([VERSION_DESCRIPTION], [$version_description], [UST version description])
  41
  42 # Checks for programs.
  43 AC_PROG_CC
  44 AC_PROG_CXX
  45 AC_PROG_MAKE_SET
  46 LT_INIT
  47
  48 ## Checks for libraries.
  49 AC_CHECK_LIB([dl], [dlopen])
  50 AC_CHECK_LIB([pthread], [pthread_create])
  51
  52 # Check for libuuid
  53 AC_CHECK_LIB([uuid], [uuid_generate], [],
  54         [AC_MSG_ERROR([Cannot find libuuid. Use [LDFLAGS]=-Ldir to specify its location.])]
  55 )
  56
  57 # Checks for header files.
  58 #AC_CHECK_HEADERS([fcntl.h stdint.h stdlib.h string.h sys/socket.h sys/time.h unistd.h])
  59
  60 # Checks for typedefs, structures, and compiler characteristics.
  61 AC_C_INLINE
  62 #AC_TYPE_INT16_T
  63 #AC_TYPE_INT32_T
  64 #AC_TYPE_INT64_T
  65 #AC_TYPE_INT8_T
  66 #AC_TYPE_PID_T
  67 #AC_TYPE_SIZE_T
  68 #AC_TYPE_SSIZE_T
  69 #AC_TYPE_UINT16_T
  70 #AC_TYPE_UINT32_T
  71 #AC_TYPE_UINT64_T
  72 #AC_TYPE_UINT8_T
  73 #AC_CHECK_TYPES([ptrdiff_t])
  74
  75 # Checks for library functions.
  76 AC_FUNC_MALLOC
  77 AC_CHECK_FUNCS([gettimeofday munmap socket strerror strtol sched_getcpu sysconf])
  78
  79 CFLAGS="-Wall $CFLAGS"
  80
  81 # URCU
  82
  83 # urcu - check if we just find the headers it out of the box.
  84 AC_CHECK_HEADERS([urcu-bp.h], [], [AC_MSG_ERROR([Cannot find [URCU] headers (urcu-bp.h). Use [CPPFLAGS]=-Idir to specify their location.
  85 This error can also occur when the liburcu package's configure script has not been run.])])
  86
  87 AC_MSG_CHECKING([caa_likely()])
  88 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
  89 #include <urcu/compiler.h>
  90 void fct(void)
  91 {
  92         if (caa_likely(1)) {
  93         }
  94 }
  95 ]])],[
  96         AC_MSG_RESULT([yes])
  97 ],[
  98         AC_MSG_RESULT([no])
  99         AC_MSG_ERROR([Please upgrade your version of liburcu to 0.6.6 or better])
 100
 101 ])
 102
 103 # urcu - check that URCU lib is available to compilation
 104 AC_CHECK_LIB([urcu-bp], [synchronize_rcu_bp], [], [AC_MSG_ERROR([Cannot find liburcu-bp lib. Use [LDFLAGS]=-Ldir to specify its location.])])
 105
 106 # urcu - check that URCU lib is at least version 0.6
 107 AC_CHECK_LIB([urcu-bp], [call_rcu_bp], [], [AC_MSG_ERROR([liburcu 0.6 or newer is needed, please update your version or use [LDFLAGS]=-Ldir to specify the right location.])])
 108
 109
 110 # Check for various supplementary host information (beyond the
 111 # triplet) which might affect the library format choices.  E.g., we
 112 # can be building with `i686-unknown-linux-gnu-gcc -m64'
 113
 114 case "${host}" in
 115 changequote(,)dnl
 116   i[34567]86-*-linux*)
 117 changequote([,])dnl
 118     AC_CACHE_CHECK([if building for x86-64], [ust_cv_i386_is_x86_64],
 119                     [save_CPPFLAGS="$CPPFLAGS"
 120                     CPPFLAGS="$CPPFLAGS $CFLAGS"
 121                     AC_EGREP_CPP([got it], [
 122 #if __x86_64__
 123 got it
 124 #endif
 125                  ], [ust_cv_i386_is_x86_64=yes],
 126                     [ust_cv_i386_is_x86_64=no])
 127                     CPPFLAGS="$save_CPPFLAGS"])
 128     ;;
 129 esac
 130
 131 AC_MSG_CHECKING([library format for the host system])
 132 case $host_cpu in
 133 changequote(,)dnl
 134         i[3456]86)
 135 changequote([,])dnl
 136           if test "$ust_cv_i386_is_x86_64" = yes ; then
 137              LIBFORMAT="elf64-x86-64"
 138           else
 139              LIBFORMAT="elf32-i386"
 140           fi
 141           ;;
 142         x86_64) LIBFORMAT="elf64-x86-64" ;;
 143         powerpc) LIBFORMAT="elf32-powerpc" ;;
 144         ppc64) LIBFORMAT="elf64-powerpc" ;;
 145         powerpc64) LIBFORMAT="elf64-powerpc" ;;
 146         s390) LIBFORMAT="elf32-s390"; NO_UNALIGNED_ACCESS=1 ;;
 147         s390x) LIBFORMAT="elf64-s390"; NO_UNALIGNED_ACCESS=1 ;;
 148         armv5) LIBFORMAT="elf32-littlearm"; NO_UNALIGNED_ACCESS=1 ;;
 149         arm) LIBFORMAT="elf32-littlearm"; NO_UNALIGNED_ACCESS=1 ;;
 150         mips*) LIBFORMAT=""; NO_UNALIGNED_ACCESS=1;;
 151         *) AC_MSG_ERROR([unable to detect library format (unsupported architecture ($host_cpu)?)]) ;;
 152 esac
 153 AC_SUBST(LIBFORMAT)
 154 AC_MSG_RESULT($LIBFORMAT)
 155
 156 if test "x$host_cpu" = "xarm" ; then
 157 AC_MSG_CHECKING([checking for armv5])
 158 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 159 #ifndef __ARM_ARCH_5TEJ__
 160 #error "no arm5 here"
 161 #endif
 162 ]])],[
 163         AC_MSG_RESULT([yes])
 164         NO_UNALIGNED_ACCESS=1
 165
 166 ],[
 167         AC_MSG_RESULT([no])
 168
 169 ])
 170 fi
 171 if test x$NO_UNALIGNED_ACCESS = x ; then
 172 AC_DEFINE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [1])
 173 fi
 174
 175 # Set compile flags to java include files if given
 176 AC_ARG_WITH([java-jdk],
 177         [AS_HELP_STRING([--with-java-jdk=DIR],[use the Java JDK in DIR. Ex : $JAVA_HOME.])],
 178         [JAVA_JDK=$withval],
 179         [JAVA_JDK=""]
 180 )
 181 AS_IF([test $JAVA_JDK],[
 182         AS_IF([test -d $JAVA_JDK],[
 183                 AC_MSG_RESULT([using Java includes in $JAVA_SDK])
 184                 SUBDIRS=`find $JAVA_JDK/include -type d`
 185                 CPPFLAGS+=" "
 186                 CPPFLAGS+=`for x in $SUBDIRS; do echo -n "-I$x "; done`
 187                 CPPFLAGS+=" "
 188         ],[
 189                 AC_MSG_ERROR(Unable to find Java include files in $JAVA_JDK)
 190         ])
 191 ])
 192
 193 # sdt.h integration
 194 AC_ARG_WITH([sdt],
 195         [AS_HELP_STRING([--with-sdt],[provide SystemTap integration via sdt.h [default=no]])],
 196         [with_sdt=$withval],
 197         [with_sdt="no"]
 198 )
 199
 200 AS_IF([test "x$with_sdt" = "xyes"],[
 201         AC_MSG_CHECKING([STAP_PROBEV()])
 202         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 203         #define SDT_USE_VARIADIC
 204         #include <sys/sdt.h>
 205         void fct(void)
 206         {
 207                 STAP_PROBEV(provider,name,1,2,3,4,5,6,7,8,9,10);
 208         }
 209         ]])],[
 210                 AC_MSG_RESULT([yes])
 211                 AC_DEFINE([LTTNG_UST_HAVE_SDT_INTEGRATION], [1])
 212         ],[
 213                 AC_MSG_RESULT([no])
 214                 AC_MSG_ERROR([The sdt.h integration was requested but the STAP_PROBEV define cannot be used. Make sure it is installed, and up to date, or use CPPFLAGS=-I/path/ to specify a non-standard path to sys/sdt.h])
 215         ])
 216 ])
 217
 218 #currently disabled.
 219         #tests/hello2/Makefile
 220         #tests/basic/Makefile
 221         #tests/simple_include/Makefile
 222         #tests/snprintf/Makefile
 223         #tests/test-nevents/Makefile
 224         #tests/test-libustinstr-malloc/Makefile
 225         #tests/dlopen/Makefile
 226         #tests/same_line_marker/Makefile
 227         #tests/trace_event/Makefile
 228         #tests/tracepoint/Makefile
 229         #tests/tracepoint/benchmark/Makefile
 230         #tests/register_test/Makefile
 231         #tests/libustctl_function_#tests/Makefile
 232         #tests/exit-fast/Makefile
 233         #tests/basic_long/Makefile
 234
 235 #       liblttng-ust-java/Makefile
 236
 237 AC_CONFIG_FILES([
 238         Makefile
 239         doc/Makefile
 240         doc/examples/Makefile
 241         include/Makefile
 242         include/lttng/ust-version.h
 243         snprintf/Makefile
 244         libringbuffer/Makefile
 245         liblttng-ust-comm/Makefile
 246         liblttng-ust/Makefile
 247         liblttng-ust-ctl/Makefile
 248         liblttng-ust-fork/Makefile
 249         liblttng-ust-libc-wrapper/Makefile
 250         tools/Makefile
 251         tests/Makefile
 252         tests/hello/Makefile
 253         tests/hello-static-lib/Makefile
 254         tests/hello.cxx/Makefile
 255         tests/demo/Makefile
 256         tests/fork/Makefile
 257         tests/ust-basic-tracing/Makefile
 258         tests/ust-multi-test/Makefile
 259         lttng-ust.pc
 260 ])
 261
 262 AC_OUTPUT
 263
 264 AS_ECHO()
 265 AS_ECHO("Version name: $version_name")
 266 AS_ECHO("$version_description")
 267
 268 # Report on the configuration options
 269 AS_ECHO()
 270 AS_ECHO("LTTng-UST will be built with the following options:")
 271 AS_ECHO("Library format: $LIBFORMAT")
 272
 273 AS_ECHO()
 274 AS_ECHO_N("sdt.h integration:  ")
 275 AS_IF([test "x$with_sdt" = "xyes"], [AS_ECHO("Enabled")], [AS_ECHO("Disabled")])
 276
 277 AS_ECHO()
 278 AS_ECHO("Type 'make' to compile.")
 279