configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_INIT([lttng-ust],[2.0.0-rc4],[mathieu dot desnoyers at efficios dot com])
   5
   6 # Following the numbering scheme proposed by libtool for the library version
   7 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
   8 AC_SUBST([LTTNG_UST_LIBRARY_VERSION], [0:0:0])
   9 # note: remember to update tracepoint.h dlopen() to match this version
  10 # number. TODO: eventually automate by exporting the major number.
  11
  12 AC_CONFIG_AUX_DIR([config])
  13 AC_CANONICAL_TARGET
  14 AC_CANONICAL_HOST
  15 AC_CONFIG_MACRO_DIR([config])
  16 AM_INIT_AUTOMAKE([foreign])
  17 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  18 AC_CONFIG_SRCDIR([include/lttng/tracepoint.h])
  19
  20 # Configuration options, which will be installed in the config.h
  21 AC_CONFIG_HEADERS([config.h include/lttng/ust-config.h])
  22 AH_TEMPLATE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [Use efficient unaligned access.])
  23 AH_TEMPLATE([LTTNG_UST_HAVE_SDT_INTEGRATION], [SystemTap integration via sdt.h])
  24
  25 # Compute minor/major/patchlevel version numbers
  26 AC_PROG_SED
  27 major_version=$(echo AC_PACKAGE_VERSION | sed 's/^\([[0-9]]\)*\.[[0-9]]*\.[[0-9]]*.*$/\1/')
  28 minor_version=$(echo AC_PACKAGE_VERSION | sed 's/^[[0-9]]*\.\([[0-9]]*\)\.[[0-9]]*.*$/\1/')
  29 patchlevel_version=$(echo AC_PACKAGE_VERSION | sed 's/^[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\).*$/\1/')
  30 AC_SUBST([MAJOR_VERSION], [$major_version])
  31 AC_SUBST([MINOR_VERSION], [$minor_version])
  32 AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version])
  33 AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [UST major version number])
  34 AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [UST minor version number])
  35 AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [UST patchlevel version number])
  36
  37 AC_DEFINE_UNQUOTED([VERSION_NAME], "TBD", [UST version name])
  38 AC_DEFINE_UNQUOTED([VERSION_DESCRIPTION], "TBD", [UST version description])
  39
  40 # Checks for programs.
  41 AC_PROG_CC
  42 AC_PROG_CXX
  43 AC_PROG_MAKE_SET
  44 LT_INIT
  45
  46 ## Checks for libraries.
  47 AC_CHECK_LIB([dl], [dlopen])
  48 AC_CHECK_LIB([pthread], [pthread_create])
  49
  50 # Check for libuuid
  51 AC_CHECK_LIB([uuid], [uuid_generate], [],
  52         [AC_MSG_ERROR([Cannot find libuuid. Use [LDFLAGS]=-Ldir to specify its location.])]
  53 )
  54
  55 # Checks for header files.
  56 #AC_CHECK_HEADERS([fcntl.h stdint.h stdlib.h string.h sys/socket.h sys/time.h unistd.h])
  57
  58 # Checks for typedefs, structures, and compiler characteristics.
  59 AC_C_INLINE
  60 #AC_TYPE_INT16_T
  61 #AC_TYPE_INT32_T
  62 #AC_TYPE_INT64_T
  63 #AC_TYPE_INT8_T
  64 #AC_TYPE_PID_T
  65 #AC_TYPE_SIZE_T
  66 #AC_TYPE_SSIZE_T
  67 #AC_TYPE_UINT16_T
  68 #AC_TYPE_UINT32_T
  69 #AC_TYPE_UINT64_T
  70 #AC_TYPE_UINT8_T
  71 #AC_CHECK_TYPES([ptrdiff_t])
  72
  73 # Checks for library functions.
  74 AC_FUNC_MALLOC
  75 AC_CHECK_FUNCS([gettimeofday munmap socket strerror strtol sched_getcpu sysconf])
  76
  77 CFLAGS="-Wall $CFLAGS"
  78
  79 # Check for texinfo, required for building the documentation
  80 # TODO: make this (and building the documentation) optional
  81 AC_CHECK_PROG([TEXINFO], [makeinfo], [yes])
  82 AS_IF([test "x$TEXINFO" != "xyes"],[
  83         AC_MSG_ERROR([Please install the 'texinfo' program and make sure 'makeinfo' is in the PATH.])
  84 ])
  85
  86 # URCU
  87
  88 # urcu - check if we just find the headers it out of the box.
  89 AC_CHECK_HEADERS([urcu-bp.h], [], [AC_MSG_ERROR([Cannot find [URCU] headers (urcu-bp.h). Use [CPPFLAGS]=-Idir to specify their location.
  90 This error can also occur when the liburcu package's configure script has not been run.])])
  91
  92 AC_MSG_CHECKING([caa_likely()])
  93 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
  94 #include <urcu/compiler.h>
  95 void fct(void)
  96 {
  97         if (caa_likely(1)) {
  98         }
  99 }
 100 ]])],[
 101         AC_MSG_RESULT([yes])
 102 ],[
 103         AC_MSG_RESULT([no])
 104         AC_MSG_ERROR([Please upgrade your version of liburcu to 0.6.6 or better])
 105
 106 ])
 107
 108 # urcu - check that URCU lib is available to compilation
 109 AC_CHECK_LIB([urcu-bp], [synchronize_rcu_bp], [], [AC_MSG_ERROR([Cannot find liburcu-bp lib. Use [LDFLAGS]=-Ldir to specify its location.])])
 110
 111 # urcu - check that URCU lib is at least version 0.6
 112 AC_CHECK_LIB([urcu-bp], [call_rcu_bp], [], [AC_MSG_ERROR([liburcu 0.6 or newer is needed, please update your version or use [LDFLAGS]=-Ldir to specify the right location.])])
 113
 114
 115 # Check for various supplementary host information (beyond the
 116 # triplet) which might affect the library format choices.  E.g., we
 117 # can be building with `i686-unknown-linux-gnu-gcc -m64'
 118
 119 case "${host}" in
 120 changequote(,)dnl
 121   i[34567]86-*-linux*)
 122 changequote([,])dnl
 123     AC_CACHE_CHECK([if building for x86-64], [ust_cv_i386_is_x86_64],
 124                     [save_CPPFLAGS="$CPPFLAGS"
 125                     CPPFLAGS="$CPPFLAGS $CFLAGS"
 126                     AC_EGREP_CPP([got it], [
 127 #if __x86_64__
 128 got it
 129 #endif
 130                  ], [ust_cv_i386_is_x86_64=yes],
 131                     [ust_cv_i386_is_x86_64=no])
 132                     CPPFLAGS="$save_CPPFLAGS"])
 133     ;;
 134 esac
 135
 136 AC_MSG_CHECKING([library format for the host system])
 137 case $host_cpu in
 138 changequote(,)dnl
 139         i[3456]86)
 140 changequote([,])dnl
 141           if test "$ust_cv_i386_is_x86_64" = yes ; then
 142              LIBFORMAT="elf64-x86-64"
 143           else
 144              LIBFORMAT="elf32-i386"
 145           fi
 146           ;;
 147         x86_64) LIBFORMAT="elf64-x86-64" ;;
 148         powerpc) LIBFORMAT="elf32-powerpc" ;;
 149         ppc64) LIBFORMAT="elf64-powerpc" ;;
 150         powerpc64) LIBFORMAT="elf64-powerpc" ;;
 151         s390) LIBFORMAT="elf32-s390"; NO_UNALIGNED_ACCESS=1 ;;
 152         s390x) LIBFORMAT="elf64-s390"; NO_UNALIGNED_ACCESS=1 ;;
 153         armv5) LIBFORMAT="elf32-littlearm"; NO_UNALIGNED_ACCESS=1 ;;
 154         arm) LIBFORMAT="elf32-littlearm"; NO_UNALIGNED_ACCESS=1 ;;
 155         mips*) LIBFORMAT=""; NO_UNALIGNED_ACCESS=1;;
 156         *) AC_MSG_ERROR([unable to detect library format (unsupported architecture ($host_cpu)?)]) ;;
 157 esac
 158 AC_SUBST(LIBFORMAT)
 159 AC_MSG_RESULT($LIBFORMAT)
 160
 161 if test "x$host_cpu" = "xarm" ; then
 162 AC_MSG_CHECKING([checking for armv5])
 163 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 164 #ifndef __ARM_ARCH_5TEJ__
 165 #error "no arm5 here"
 166 #endif
 167 ]])],[
 168         AC_MSG_RESULT([yes])
 169         NO_UNALIGNED_ACCESS=1
 170
 171 ],[
 172         AC_MSG_RESULT([no])
 173
 174 ])
 175 fi
 176 if test x$NO_UNALIGNED_ACCESS = x ; then
 177 AC_DEFINE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [1])
 178 fi
 179
 180 # Set compile flags to java include files if given
 181 AC_ARG_WITH([java-jdk],
 182         [AS_HELP_STRING([--with-java-jdk=DIR],[use the Java JDK in DIR. Ex : $JAVA_HOME.])],
 183         [JAVA_JDK=$withval],
 184         [JAVA_JDK=""]
 185 )
 186 AS_IF([test $JAVA_JDK],[
 187         AS_IF([test -d $JAVA_JDK],[
 188                 AC_MSG_RESULT([using Java includes in $JAVA_SDK])
 189                 SUBDIRS=`find $JAVA_JDK/include -type d`
 190                 CPPFLAGS+=" "
 191                 CPPFLAGS+=`for x in $SUBDIRS; do echo -n "-I$x "; done`
 192                 CPPFLAGS+=" "
 193         ],[
 194                 AC_MSG_ERROR(Unable to find Java include files in $JAVA_JDK)
 195         ])
 196 ])
 197
 198 # Check for JNI header files if requested
 199 AC_ARG_WITH([jni-interface],
 200         [AS_HELP_STRING([--with-jni-interface],[build JNI interface between C and Java. Needs Java include files [default=no]])],
 201         [jni_interface=$withval],
 202         [jni_interface=no]
 203 )
 204
 205 AS_IF([test "x$jni_interface" = "xyes"],[
 206         AC_CHECK_HEADERS([jni.h],[],[
 207         AC_MSG_ERROR([missing jni.h
 208 Make sure Sun Java, OpenJDK or GCJ is installed and that this header file exists in the system path.
 209 Use the --with-java-jdk=DIR flag to point to your Java include files, or disable the JNI interface.])
 210         ])
 211 ])
 212 AM_CONDITIONAL([BUILD_JNI_INTERFACE], [test "x$jni_interface" = "xyes"])
 213
 214 # sdt.h integration
 215 AC_ARG_WITH([sdt],
 216         [AS_HELP_STRING([--with-sdt],[provide SystemTap integration via sdt.h [default=no]])],
 217         [with_sdt=$withval],
 218         [with_sdt="no"]
 219 )
 220
 221 AS_IF([test "x$with_sdt" = "xyes"],[
 222         AC_MSG_CHECKING([STAP_PROBEV()])
 223         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 224         #define SDT_USE_VARIADIC
 225         #include <sys/sdt.h>
 226         void fct(void)
 227         {
 228                 STAP_PROBEV(provider,name,1,2,3,4,5,6,7,8,9,10);
 229         }
 230         ]])],[
 231                 AC_MSG_RESULT([yes])
 232                 AC_DEFINE([LTTNG_UST_HAVE_SDT_INTEGRATION], [1])
 233         ],[
 234                 AC_MSG_RESULT([no])
 235                 AC_MSG_ERROR([The sdt.h integration was requested but the STAP_PROBEV define cannot be used. Make sure it is installed, and up to date, or use CPPFLAGS=-I/path/ to specify a non-standard path to sys/sdt.h])
 236         ])
 237 ])
 238
 239 #currently disabled.
 240         #tests/hello2/Makefile
 241         #tests/basic/Makefile
 242         #tests/simple_include/Makefile
 243         #tests/snprintf/Makefile
 244         #tests/test-nevents/Makefile
 245         #tests/test-libustinstr-malloc/Makefile
 246         #tests/dlopen/Makefile
 247         #tests/same_line_marker/Makefile
 248         #tests/trace_event/Makefile
 249         #tests/tracepoint/Makefile
 250         #tests/tracepoint/benchmark/Makefile
 251         #tests/register_test/Makefile
 252         #tests/libustctl_function_#tests/Makefile
 253         #tests/exit-fast/Makefile
 254         #tests/basic_long/Makefile
 255
 256 AC_CONFIG_FILES([
 257         Makefile
 258         doc/Makefile
 259         doc/examples/Makefile
 260         include/Makefile
 261         include/lttng/ust-version.h
 262         snprintf/Makefile
 263         libringbuffer/Makefile
 264         liblttng-ust-comm/Makefile
 265         liblttng-ust/Makefile
 266         liblttng-ust-ctl/Makefile
 267         liblttng-ust-fork/Makefile
 268         liblttng-ust-java/Makefile
 269         liblttng-ust-libc-wrapper/Makefile
 270         tools/Makefile
 271         tests/Makefile
 272         tests/hello/Makefile
 273         tests/hello-static-lib/Makefile
 274         tests/hello.cxx/Makefile
 275         tests/demo/Makefile
 276         tests/fork/Makefile
 277         tests/ust-basic-tracing/Makefile
 278         tests/ust-multi-test/Makefile
 279         lttng-ust.pc
 280 ])
 281
 282 AC_OUTPUT
 283
 284 # Report on the configuration options
 285 AS_ECHO()
 286 AS_ECHO("LTTng-UST will be built with the following options:")
 287 AS_ECHO("Library format: $LIBFORMAT")
 288
 289 AS_ECHO()
 290 AS_ECHO_N("Java support (JNI): ")
 291 AS_IF([test "x$jni_interface" = "xyes"], [AS_ECHO("Enabled")], [AS_ECHO("Disabled")])
 292
 293 AS_ECHO_N("sdt.h integration:  ")
 294 AS_IF([test "x$with_sdt" = "xyes"], [AS_ECHO("Enabled")], [AS_ECHO("Disabled")])
 295
 296 AS_ECHO()
 297 AS_ECHO("Type 'make' to compile.")
 298