configure.ac

   1 dnl -*- Autoconf -*-
   2 dnl Process this file with autoconf to produce a configure script.
   3
   4 dnl Version infos
   5 m4_define([V_MAJOR], [2])
   6 m4_define([V_MINOR], [9])
   7 m4_define([V_PATCH], [7])
   8 dnl m4_define([V_EXTRA], [])
   9 m4_define([V_STRING], [V_MAJOR.V_MINOR.V_PATCH])
  10 m4_ifdef([V_EXTRA], [m4_append([V_STRING], [-V_EXTRA])])
  11 m4_define([V_NAME], [[Joannès]])
  12 m4_define([V_DESC], [[Berliner Weisse style beer from the Trèfle Noir microbrewery in Rouyn-Noranda. It is a tangy beer with a distinct pink dress and intense fruit flavor, thanks to the presence of fresh blackcurrant grown in Témiscamingue.]])
  13
  14 AC_INIT([lttng-ust], V_STRING, [mathieu dot desnoyers at efficios dot com])
  15
  16 # Following the numbering scheme proposed by libtool for the library version
  17 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
  18 # This is the library version of liblttng-ust.
  19 AC_SUBST([LTTNG_UST_LIBRARY_VERSION], [0:0:0])
  20 # note: remember to update tracepoint.h dlopen() to match this version
  21 # number. TODO: eventually automate by exporting the major number.
  22
  23 # This is the library version of liblttng-ust-ctl, used internally by
  24 # liblttng-ust, lttng-sessiond, and lttng-consumerd.
  25 AC_SUBST([LTTNG_UST_CTL_LIBRARY_VERSION], [2:0:0])
  26
  27 AC_CONFIG_AUX_DIR([config])
  28 AC_CANONICAL_TARGET
  29 AC_CANONICAL_HOST
  30 AC_CONFIG_MACRO_DIR([config])
  31 AM_INIT_AUTOMAKE([1.9 foreign dist-bzip2 no-dist-gzip tar-ustar])
  32 AM_MAINTAINER_MODE([enable])
  33 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  34 AC_CONFIG_SRCDIR([include/lttng/tracepoint.h])
  35
  36 AC_REQUIRE_AUX_FILE([tap-driver.sh])
  37
  38 # Configuration options, which will be installed in the config.h
  39 AC_CONFIG_HEADERS([config.h include/lttng/ust-config.h])
  40 AH_TEMPLATE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [Use efficient unaligned access.])
  41 AH_TEMPLATE([LTTNG_UST_HAVE_SDT_INTEGRATION], [SystemTap integration via sdt.h])
  42 AH_TEMPLATE([LTTNG_UST_HAVE_PERF_EVENT], [Perf event integration via perf_event.h])
  43
  44 dnl Substitute minor/major/patchlevel version numbers
  45 AC_SUBST([MAJOR_VERSION], [V_MAJOR])
  46 AC_SUBST([MINOR_VERSION], [V_MINOR])
  47 AC_SUBST([PATCHLEVEL_VERSION], [V_PATCH])
  48
  49 AC_PROG_SED
  50 AC_PROG_GREP
  51 AC_PROG_LN_S
  52 AC_PROG_MKDIR_P
  53
  54 # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
  55 AC_ARG_ENABLE([libtool-linkdep-fixup], [
  56         AS_HELP_STRING([--disable-libtool-linkdep-fixup], [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)])
  57 ], [
  58         libtool_fixup=$enableval
  59 ], [
  60         libtool_fixup=yes
  61 ])
  62
  63 AS_IF([test "x$libtool_fixup" = "xyes"], [
  64         libtool_m4="$srcdir/config/libtool.m4"
  65         libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
  66         AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
  67         libtool_flag_pattern_count=$(grep -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
  68
  69         AS_IF([test $libtool_flag_pattern_count -ne 0], [
  70         AC_MSG_RESULT([$libtool_flag_pattern_count])
  71         AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
  72                 sed -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
  73         ], [
  74                 AC_MSG_RESULT([none])
  75         ])
  76 ])
  77
  78 AM_CONDITIONAL([NO_SHARED], [test "x$enable_shared" = "xno"])
  79
  80 # Checks for programs.
  81 AC_PROG_CC
  82 AC_PROG_CXX
  83 AC_CHECK_PROG([HAVE_CMAKE], [cmake], ["yes"])
  84 AM_CONDITIONAL([HAVE_CMAKE], [test "x$HAVE_CMAKE" = "xyes"])
  85 AC_PROG_MAKE_SET
  86 LT_INIT
  87
  88 # rw_PROG_CXX_WORKS
  89 # Check whether the C++ compiler works.
  90 AC_CACHE_CHECK([whether the C++ compiler works], [rw_cv_prog_cxx_works], [
  91         AC_LANG_PUSH([C++])
  92
  93         AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])], [
  94                 check_cxx_designated_initializers=yes
  95         ], [
  96                 rw_cv_prog_cxx_works=no
  97         ])
  98
  99         AS_IF([test "x$check_cxx_designated_initializers" = "xyes"], [
 100                 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 101                         struct foo { int a; int b; };
 102                         void fct(void)
 103                         {
 104                                 struct foo f = { .a = 0, .b = 1 };
 105                         }
 106                 ]])], [
 107                         rw_cv_prog_cxx_works=yes
 108                 ], [
 109                         rw_cv_prog_cxx_works=no
 110                 ])
 111         ])
 112
 113         AC_LANG_POP([C++])
 114 ])
 115
 116 AM_CONDITIONAL([CXX_WORKS], [test "x$rw_cv_prog_cxx_works" = "xyes"])
 117
 118 # Check if the compiler support weak symbols
 119 AX_SYS_WEAK_ALIAS
 120
 121 AS_IF([test "x${ax_cv_sys_weak_alias}" = "xno"], [
 122         AC_MSG_ERROR([Your platform doesn't support weak symbols.])
 123 ])
 124
 125 # Checks for libraries.
 126 AC_CHECK_LIB([dl], [dlopen], [
 127         have_libdl=yes
 128         libdl_name=dl
 129 ], [
 130         #libdl not found, check for dlopen in libc.
 131         AC_CHECK_LIB([c], [dlopen], [
 132                 have_libc_dl=yes
 133                 libdl_name=c
 134         ], [
 135                 AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
 136         ])
 137 ])
 138
 139 # Check if libdl has dlmopen support.
 140 AH_TEMPLATE([HAVE_DLMOPEN], ["Define to 1 if dlmopen is available."])
 141 AC_CHECK_LIB([$libdl_name], [dlmopen],
 142         [AC_DEFINE([HAVE_DLMOPEN], [1])]
 143 )
 144
 145 AM_CONDITIONAL([LTTNG_UST_BUILD_WITH_LIBDL], [test "x$have_libdl" = "xyes"])
 146 AM_CONDITIONAL([LTTNG_UST_BUILD_WITH_LIBC_DL], [test "x$have_libc_dl" = "xyes"])
 147
 148 AC_CHECK_LIB([pthread], [pthread_create])
 149 AC_CHECK_LIB([pthread], [pthread_setname_np],
 150         AC_DEFINE([HAVE_PTHREAD_SETNAME_NP], [1], [Define to 1 if pthread_setname_np is available.]),
 151         AC_CHECK_LIB([pthread], [pthread_set_name_np],
 152                 AC_DEFINE([HAVE_PTHREAD_SET_NAME_NP], [1], [Define to 1 if pthread_set_name_np is available.]),
 153                 AC_MSG_RESULT([pthread setname/set_name not found.])))
 154
 155 # Check for dlfcn.h
 156 AC_CHECK_HEADER([dlfcn.h])
 157 AS_IF([test "x${ac_cv_header_dlfcn_h}" = "xyes"], [
 158         AC_CHECK_DECLS([RTLD_DI_LINKMAP], [], [], [
 159                 #define _GNU_SOURCE /* Required on Linux to get GNU extensions */
 160                 #include <dlfcn.h>
 161         ])
 162 ], [
 163         ac_cv_have_decl_RTLD_DI_LINKMAP="no"
 164 ])
 165
 166 AM_CONDITIONAL([HAVE_DLINFO], [test "x${ac_cv_have_decl_RTLD_DI_LINKMAP}" = "xyes"])
 167
 168 # Checks for header files.
 169 dnl AC_CHECK_HEADERS([fcntl.h stdint.h stdlib.h string.h sys/socket.h sys/time.h unistd.h])
 170
 171 # Checks for typedefs, structures, and compiler characteristics.
 172 AC_C_INLINE
 173 dnl AC_TYPE_INT16_T
 174 dnl AC_TYPE_INT32_T
 175 dnl AC_TYPE_INT64_T
 176 dnl AC_TYPE_INT8_T
 177 dnl AC_TYPE_PID_T
 178 dnl AC_TYPE_SIZE_T
 179 dnl AC_TYPE_SSIZE_T
 180 dnl AC_TYPE_UINT16_T
 181 dnl AC_TYPE_UINT32_T
 182 dnl AC_TYPE_UINT64_T
 183 dnl AC_TYPE_UINT8_T
 184 dnl AC_CHECK_TYPES([ptrdiff_t])
 185
 186 # Checks for library functions.
 187 AC_FUNC_MALLOC
 188 AC_CHECK_FUNCS([gettimeofday munmap socket strerror strtol sched_getcpu sysconf])
 189
 190 # URCU
 191
 192 # urcu - check if we just find the headers it out of the box.
 193 AC_CHECK_HEADERS([urcu-bp.h], [], [AC_MSG_ERROR([Cannot find [URCU] headers (urcu-bp.h). Use [CPPFLAGS]=-Idir to specify their location.
 194 This error can also occur when the liburcu package's configure script has not been run.])])
 195
 196 # urcu-cds - check that URCU Concurrent Data Structure lib is available to compilation
 197 # Part of Userspace RCU library 0.7.2 or better.
 198 AC_CHECK_LIB([urcu-cds], [_cds_lfht_new], [], [AC_MSG_ERROR([Cannot find
 199 liburcu-cds lib, part of Userspace RCU 0.7 or better. Use [LDFLAGS]=-Ldir to specify its location.])])
 200
 201 AC_MSG_CHECKING([caa_likely()])
 202 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 203         #include <urcu/compiler.h>
 204         void fct(void)
 205         {
 206                 if (caa_likely(1)) {
 207                 }
 208         }
 209 ]])], [
 210         AC_MSG_RESULT([yes])
 211 ], [
 212         AC_MSG_RESULT([no])
 213         AC_MSG_ERROR([Please upgrade your version of liburcu to 0.6.6 or better])
 214 ])
 215
 216 # urcu - check that URCU lib is available to compilation
 217 AC_CHECK_LIB([urcu-bp], [synchronize_rcu_bp], [], [AC_MSG_ERROR([Cannot find liburcu-bp lib. Use [LDFLAGS]=-Ldir to specify its location.])])
 218
 219 # urcu - check that URCU lib is at least version 0.6
 220 AC_CHECK_LIB([urcu-bp], [call_rcu_bp], [], [AC_MSG_ERROR([liburcu 0.6 or newer is needed, please update your version or use [LDFLAGS]=-Ldir to specify the right location.])])
 221
 222 # optional linux/perf_event.h
 223 AC_CHECK_HEADERS([linux/perf_event.h], [have_perf_event=yes], [])
 224
 225 # Perf event counters are supported on all architectures supported by
 226 # perf, using the read system call as fallback.
 227 AM_CONDITIONAL([HAVE_PERF_EVENT], [test "x$have_perf_event" = "xyes"])
 228
 229 AS_IF([test "x$have_perf_event" = "xyes"], [
 230         AC_DEFINE([LTTNG_UST_HAVE_PERF_EVENT], [1])
 231 ])
 232
 233 AC_MSG_CHECKING([host system alignment requirements])
 234 AS_CASE([$host_cpu],
 235         [i[[3456]]86], [],
 236         [x86_64], [],
 237         [amd64], [],
 238         [powerpc], [],
 239         [ppc64], [],
 240         [ppc64le], [],
 241         [powerpc64], [],
 242         [powerpc64le], [],
 243         [s390], [NO_UNALIGNED_ACCESS=1],
 244         [s390x], [NO_UNALIGNED_ACCESS=1],
 245         [arm*], [NO_UNALIGNED_ACCESS=1],
 246         [aarch64*], [NO_UNALIGNED_ACCESS=1],
 247         [mips*], [NO_UNALIGNED_ACCESS=1],
 248         [tile*], [NO_UNALIGNED_ACCESS=1],
 249         [
 250                 UNSUPPORTED_ARCH=1
 251                 NO_UNALIGNED_ACCESS=1
 252         ])
 253 AC_MSG_RESULT([$host_cpu])
 254
 255 AS_IF([test "x$NO_UNALIGNED_ACCESS" = "x"], [
 256         AC_DEFINE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [1])
 257 ])
 258
 259 # Check for JNI header files if requested
 260 AC_ARG_ENABLE([jni-interface], [
 261         AS_HELP_STRING([--enable-jni-interface], [build JNI interface between C and Java. Needs Java include files [default=no]])
 262 ], [
 263         jni_interface=$enableval
 264 ], [
 265         jni_interface=no
 266 ])
 267
 268 AM_CONDITIONAL([BUILD_JNI_INTERFACE], [test "x$jni_interface" = "xyes"])
 269
 270
 271 AC_ARG_ENABLE([java-agent-jul], [
 272         AS_HELP_STRING([--enable-java-agent-jul], [build the LTTng UST Java agent with JUL support [default=no]])
 273 ], [
 274         java_agent_jul=$enableval
 275 ], [
 276         java_agent_jul=no
 277 ])
 278
 279 AC_ARG_ENABLE([java-agent-log4j], [
 280         AS_HELP_STRING([--enable-java-agent-log4j], [build the LTTng UST Java agent with Log4j support [default=no]])
 281 ], [
 282         java_agent_log4j=$enableval
 283 ], [
 284         java_agent_log4j=no
 285 ])
 286
 287 AC_ARG_ENABLE([java-agent-all], [
 288         AS_HELP_STRING([--enable-java-agent-all], [build the LTTng UST Java agent with all supported backends [default=no]])
 289 ], [
 290         java_agent_jul=$enableval
 291         java_agent_log4j=$enableval
 292 ], [:])
 293
 294 AM_CONDITIONAL([BUILD_JAVA_AGENT], [test "x$java_agent_jul" = "xyes" || test "x$java_agent_log4j" = "xyes"])
 295 AM_CONDITIONAL([BUILD_JAVA_AGENT_WITH_JUL], [test "x$java_agent_jul" = "xyes"])
 296 AM_CONDITIONAL([BUILD_JAVA_AGENT_WITH_LOG4J], [test "x$java_agent_log4j" = "xyes"])
 297
 298 AS_IF([test "x$jni_interface" = "xyes" || test "x$java_agent_jul" = "xyes" || test "x$java_agent_log4j" = "xyes"], [
 299         AX_JAVA_OPTIONS
 300         AX_PROG_JAVAC
 301         AX_PROG_JAVA
 302         AX_PROG_JAR
 303
 304         AX_JNI_INCLUDE_DIR
 305         for JNI_INCLUDE_DIR in $JNI_INCLUDE_DIRS
 306         do
 307                 JNI_CPPFLAGS="$JNI_CPPFLAGS -I$JNI_INCLUDE_DIR"
 308         done
 309
 310         saved_CPPFLAGS="$CPPFLAGS"
 311         CPPFLAGS="$CPPFLAGS $JNI_CPPFLAGS"
 312         AX_PROG_JAVAH
 313         CPPFLAGS="$saved_CPPFLAGS"
 314 ])
 315
 316 AM_CONDITIONAL([HAVE_JAVAH], [test "x$JAVAH" != "x"])
 317
 318 AS_IF([test "x$java_agent_log4j" = "xyes"], [
 319         AX_CHECK_CLASSPATH
 320         AX_CHECK_CLASS([org.apache.log4j.Logger])
 321         AS_IF([test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"], [
 322                 AC_MSG_ERROR([The UST Java agent support for log4j was requested but the Log4j classes were not found. Please specify the location of the Log4j jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j.jar"])
 323         ])
 324 ])
 325
 326 # Option to build the python agent
 327 AC_ARG_ENABLE([python-agent], [
 328         AS_HELP_STRING([--enable-python-agent], [build the LTTng UST Python agent [default=no]])
 329 ], [
 330         python_agent=$enableval
 331 ], [:])
 332 AM_CONDITIONAL([BUILD_PYTHON_AGENT], [test "x$python_agent" = "xyes"])
 333 AS_IF([test "x$python_agent" = "xyes"], [
 334         AM_PATH_PYTHON([2.7])
 335 ])
 336
 337 # sdt.h integration
 338 AC_ARG_WITH([sdt], [
 339         AS_HELP_STRING([--with-sdt], [provide SystemTap integration via sdt.h [default=no]])
 340 ], [
 341         with_sdt=$withval
 342 ], [
 343         with_sdt="no"
 344 ])
 345
 346 AS_IF([test "x$with_sdt" = "xyes"], [
 347         AC_MSG_CHECKING([STAP_PROBEV()])
 348         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 349                 #define SDT_USE_VARIADIC
 350                 #include <sys/sdt.h>
 351                 void fct(void)
 352                 {
 353                         STAP_PROBEV(provider,name,1,2,3,4,5,6,7,8,9,10);
 354                 }
 355         ]])], [
 356                 AC_MSG_RESULT([yes])
 357                 AC_DEFINE([LTTNG_UST_HAVE_SDT_INTEGRATION], [1])
 358         ], [
 359                 AC_MSG_RESULT([no])
 360                 AC_MSG_ERROR([The sdt.h integration was requested but the STAP_PROBEV define cannot be used. Make sure it is installed, and up to date, or use CPPFLAGS=-I/path/ to specify a non-standard path to sys/sdt.h])
 361         ])
 362 ])
 363
 364 AC_MSG_CHECKING([whether shared libraries are enabled])
 365 AS_IF([test "x$enable_shared" = "xyes"], [
 366         AC_MSG_RESULT([yes])
 367 ], [
 368         AC_MSG_RESULT([no])
 369         AC_MSG_ERROR([LTTng-UST requires shared libraries to be enabled])
 370 ])
 371
 372 AC_ARG_WITH([lttng-system-rundir], [
 373         AS_HELP_STRING([--with-lttng-system-rundir], [Location of the system directory where LTTng-UST expects the system-wide lttng-sessiond runtime files. The default is "/var/run/lttng".]),
 374 ], [
 375         lttng_system_rundir="$withval"
 376 ], [
 377         lttng_system_rundir="/var/run/lttng"
 378 ])
 379 AC_DEFINE_UNQUOTED([LTTNG_SYSTEM_RUNDIR], ["$lttng_system_rundir"],
 380                 [LTTng system runtime directory])
 381
 382 AC_CHECK_PROG([BUILD_GEN_TP_EXAMPLES], [python], ["yes"])
 383 AM_CONDITIONAL([BUILD_GEN_TP_EXAMPLES], [test "x$BUILD_GEN_TP_EXAMPLES" = "xyes"])
 384
 385 # Set $IN_GIT_REPO if we're in the Git repository; the `bootstrap` file
 386 # is not distributed in tarballs.
 387 AS_IF([test -f "$srcdir/bootstrap"], [in_git_repo=yes], [in_git_repo=no])
 388 AM_CONDITIONAL([IN_GIT_REPO], [test "x$in_git_repo" = "xyes"])
 389
 390 # Enable building man pages (user's intention).
 391 AC_ARG_ENABLE(
 392         man-pages,
 393         AS_HELP_STRING(
 394                 [--disable-man-pages],
 395                 [Do not build and install man pages (already built in a distributed tarball)]
 396         ),
 397         [man_pages_opt=$enableval],
 398         [man_pages_opt=yes]
 399 )
 400
 401 # Check for asciidoc and xmlto if we enabled building the man pages.
 402 have_asciidoc_xmlto=no
 403
 404 AS_IF([test "x$man_pages_opt" = "xyes"], [
 405         AC_PATH_PROG([ASCIIDOC], [asciidoc], [no])
 406         AC_PATH_PROG([XMLTO], [xmlto], [no])
 407
 408         AS_IF([test "x$ASCIIDOC" = "xno" || test "x$XMLTO" = "xno"], [
 409                 AS_IF([test "x$in_git_repo" = "xyes"], [
 410                         # This is an error because we're in the Git repo, which
 411                         # means the man pages are not already generated for us,
 412                         # thus asciidoc/xmlto are required because we were asked
 413                         # to build the man pages.
 414                         AC_MSG_ERROR([
 415 Both asciidoc and xmlto are needed to build the LTTng-UST man pages. Use
 416 --disable-man-pages to disable building the man pages, in which case
 417 they will not be installed.
 418                         ])
 419                 ], [
 420                         # Only warn here: since we're in the tarball, the man
 421                         # pages should already be generated at this point, thus
 422                         # asciidoc/xmlto are not strictly required.
 423                         AC_MSG_WARN([
 424 Both asciidoc and xmlto are needed to build the LTTng-UST man pages.
 425 Note that the man pages are already built in this distribution tarball,
 426 so asciidoc and xmlto are only needed if you intend to modify their
 427 sources. Use --disable-man-pages to completely disable building
 428 and installing the man pages.
 429                         ])
 430                 ])
 431         ], [
 432                 have_asciidoc_xmlto=yes
 433         ])
 434 ])
 435
 436 # Export man page build condition: build the man pages if the user
 437 # asked for it, and if the tools are available.
 438 AM_CONDITIONAL([MAN_PAGES_OPT], [test "x$man_pages_opt" != "xno"])
 439 AM_CONDITIONAL([HAVE_ASCIIDOC_XMLTO], [test "x$have_asciidoc_xmlto" = "xyes"])
 440
 441 # Default values
 442 AC_DEFUN([_AC_DEFINE_AND_SUBST], [
 443         AC_DEFINE_UNQUOTED([CONFIG_$1], [$2], [$1])
 444         $1="$2"
 445         AC_SUBST([$1])
 446 ])
 447
 448 _AC_DEFINE_AND_SUBST([LTTNG_UST_DEFAULT_CONSTRUCTOR_TIMEOUT_MS], [3000])
 449
 450 AM_CFLAGS="-Wall"
 451 AC_SUBST(AM_CFLAGS)
 452 AC_SUBST(JNI_CPPFLAGS)
 453
 454 AC_CONFIG_FILES([
 455         Makefile
 456         doc/Makefile
 457         doc/examples/Makefile
 458         doc/man/Makefile
 459         include/Makefile
 460         include/lttng/ust-version.h
 461         snprintf/Makefile
 462         libringbuffer/Makefile
 463         liblttng-ust-comm/Makefile
 464         liblttng-ust/Makefile
 465         liblttng-ust-ctl/Makefile
 466         liblttng-ust-fork/Makefile
 467         liblttng-ust-dl/Makefile
 468         liblttng-ust-fd/Makefile
 469         liblttng-ust-java/Makefile
 470         liblttng-ust-java-agent/Makefile
 471         liblttng-ust-java-agent/java/Makefile
 472         liblttng-ust-java-agent/java/lttng-ust-agent-all/Makefile
 473         liblttng-ust-java-agent/java/lttng-ust-agent-common/Makefile
 474         liblttng-ust-java-agent/java/lttng-ust-agent-jul/Makefile
 475         liblttng-ust-java-agent/java/lttng-ust-agent-log4j/Makefile
 476         liblttng-ust-java-agent/jni/Makefile
 477         liblttng-ust-java-agent/jni/common/Makefile
 478         liblttng-ust-java-agent/jni/jul/Makefile
 479         liblttng-ust-java-agent/jni/log4j/Makefile
 480         liblttng-ust-libc-wrapper/Makefile
 481         liblttng-ust-cyg-profile/Makefile
 482         liblttng-ust-python-agent/Makefile
 483         python-lttngust/Makefile
 484         python-lttngust/setup.py
 485         python-lttngust/lttngust/__init__.py
 486         tools/Makefile
 487         tests/Makefile
 488         tests/ctf-types/Makefile
 489         tests/hello/Makefile
 490         tests/hello.cxx/Makefile
 491         tests/same_line_tracepoint/Makefile
 492         tests/snprintf/Makefile
 493         tests/ust-elf/Makefile
 494         tests/benchmark/Makefile
 495         tests/utils/Makefile
 496         tests/test-app-ctx/Makefile
 497         tests/gcc-weak-hidden/Makefile
 498         lttng-ust.pc
 499 ])
 500
 501 # Create link for python agent for the VPATH guru.
 502 AC_CONFIG_LINKS([
 503         python-lttngust/lttngust/agent.py:python-lttngust/lttngust/agent.py
 504         python-lttngust/lttngust/cmd.py:python-lttngust/lttngust/cmd.py
 505         python-lttngust/lttngust/debug.py:python-lttngust/lttngust/debug.py
 506         python-lttngust/lttngust/loghandler.py:python-lttngust/lttngust/loghandler.py
 507 ])
 508
 509 AC_OUTPUT
 510
 511 AS_ECHO
 512 AS_ECHO(["m4_bpatsubst(V_NAME, ["], [\\"])"])
 513 AS_ECHO
 514 AS_ECHO(["m4_bpatsubst(V_DESC, ["], [\\"])"])
 515
 516 # Report on the configuration options
 517 AS_ECHO
 518 AS_ECHO(["LTTng-UST will be built with the following options:"])
 519
 520 AS_ECHO
 521
 522 AS_ECHO_N(["Java agent (JUL support): "])
 523 AS_IF([test "x$java_agent_jul" = "xyes"], [AS_ECHO(["Enabled"])], [AS_ECHO(["Disabled (Use --enable-java-agent-jul)"])])
 524
 525 AS_ECHO_N(["Java agent (Log4j support): "])
 526 AS_IF([test "x$java_agent_log4j" = "xyes"], [AS_ECHO(["Enabled"])], [AS_ECHO(["Disabled (Use --enable-java-agent-log4j)"])])
 527
 528 AS_ECHO_N(["JNI interface (JNI): "])
 529 AS_IF([test "x$jni_interface" = "xyes"], [AS_ECHO(["Enabled"])], [AS_ECHO(["Disabled (Use --enable-jni-interface)"])])
 530
 531 AS_ECHO_N(["Python ($PYTHON) agent: "])
 532 AS_IF([test "x$python_agent" = "xyes"], [AS_ECHO(["Enabled"])], [AS_ECHO(["Disabled (Use --enable-python-agent)"])])
 533
 534 AS_ECHO_N(["sdt.h integration: "])
 535 AS_IF([test "x$with_sdt" = "xyes"], [AS_ECHO(["Enabled"])], [AS_ECHO(["Disabled"])])
 536
 537 AS_ECHO(["Architecture: $host_cpu"])
 538 AS_ECHO_N(["Efficient unaligned memory access: "])
 539 AS_IF([test "x$NO_UNALIGNED_ACCESS" != "x1"], [AS_ECHO(["yes"])], [AS_IF([test "x$UNSUPPORTED_ARCH" != "x1"], [AS_ECHO(["no"])], [AS_ECHO(["unknown"])])])
 540 AS_IF([test "x$UNSUPPORTED_ARCH" = "x1"], [AC_MSG_WARN([Your architecture ($host_cpu) is unsupported, using safe default of no unaligned access])])
 541 AS_ECHO
 542
 543 AS_ECHO(["Type 'make' to compile."])
 544