configure.ac

   1 dnl SPDX-License-Identifier: GPL-2.0-only
   2 AC_PREREQ([2.64])
   3 AC_INIT([lttng-tools],[2.14.0-pre],[jeremie.galarneau@efficios.com],[],[https://lttng.org])
   4
   5 AC_CONFIG_HEADERS([include/config.h])
   6 AC_CONFIG_AUX_DIR([config])
   7 AC_CONFIG_MACRO_DIR([m4])
   8
   9 AC_CANONICAL_TARGET
  10 AC_CANONICAL_HOST
  11
  12 AM_INIT_AUTOMAKE([1.12 foreign dist-bzip2 no-dist-gzip tar-pax nostdinc])
  13 AM_MAINTAINER_MODE([enable])
  14
  15 # Enable silent rules if available (Introduced in AM 1.11)
  16 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  17
  18
  19 ##                   ##
  20 ## C compiler checks ##
  21 ##                   ##
  22
  23 # Choose the C compiler
  24 AC_PROG_CC
  25 # AC_PROG_CC_STDC was merged in AC_PROG_CC in autoconf 2.70
  26 m4_version_prereq([2.70], [], [AC_PROG_CC_STDC])
  27
  28 # Make sure the C compiler supports C99
  29 AS_IF([test "$ac_cv_prog_cc_c99" = "no"], [AC_MSG_ERROR([The compiler does not support C99])])
  30
  31 # Enable available system extensions and LFS support
  32 AC_USE_SYSTEM_EXTENSIONS
  33 AC_SYS_LARGEFILE
  34
  35 # Make sure the C compiler supports __attribute__
  36 AX_C___ATTRIBUTE__
  37 AS_IF([test "x$ax_cv___attribute__" != "xyes"],
  38   [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
  39
  40 # Make sure we have pthread support
  41 AX_PTHREAD([], [AC_MSG_ERROR([Could not configure pthread support])])
  42
  43 # Checks for typedefs, structures, and compiler characteristics.
  44 AC_C_INLINE
  45 AC_TYPE_INT32_T
  46 AC_TYPE_INT64_T
  47 AC_TYPE_MODE_T
  48 AC_TYPE_OFF_T
  49 AC_TYPE_PID_T
  50 AC_TYPE_SIZE_T
  51 AC_TYPE_SSIZE_T
  52 AC_TYPE_UID_T
  53 AC_TYPE_UINT16_T
  54 AC_TYPE_UINT32_T
  55 AC_TYPE_UINT64_T
  56 AC_TYPE_UINT8_T
  57
  58 # Detect warning flags supported by the C and C++ compilers and append them to
  59 # WARN_CFLAGS and WARN_CXXFLAGS.
  60 m4_define([WARN_FLAGS_COMMON_LIST], [ dnl
  61   -Wall dnl
  62   dnl We currently get this warning when building with Clang:
  63   dnl
  64   dnl /usr/include/setjmp.h:54:12: error: declaration of built-in function '__sigsetjmp' requires the declaration of the 'jmp_buf' type, commonly provided in the header <setjmp.h>. [-Werror,-Wincomplete-setjmp-declaration]
  65   dnl extern int __sigsetjmp (struct __jmp_buf_tag __env[1], int __savemask) __THROWNL;
  66   dnl            ^
  67   -Wno-incomplete-setjmp-declaration dnl
  68   -Wmissing-declarations dnl
  69   -Wshadow dnl
  70   -Wno-gnu-folding-constant dnl
  71   -Wsuggest-attribute=format dnl
  72   -Wformat=2 dnl
  73 ])
  74
  75 # Detect warning flags specific to the C compiler and append them to
  76 # WARN_CFLAGS.
  77 m4_define([WARN_FLAGS_C_LIST], [ dnl
  78   -Wdiscarded-qualifiers dnl
  79   -Wmissing-prototypes dnl
  80   -Wmissing-parameter-type dnl
  81 ])
  82
  83 # Pass -Werror as an extra flag during the test: this is needed to make the
  84 # -Wunknown-warning-option diagnostic fatal with clang.
  85 AC_LANG_PUSH([C])
  86 AX_APPEND_COMPILE_FLAGS([WARN_FLAGS_COMMON_LIST WARN_FLAGS_C_LIST], [WARN_CFLAGS], [-Werror])
  87 AC_LANG_POP([C])
  88
  89 # The test used in AX_APPEND_COMPILE_FLAGS, generated using AC_LANG_PROGRAM, is
  90 # written in such a way that it triggers warnings with the following warning
  91 # flags.  So they would always end up disabled if we put them there, because
  92 # the test program would not build.
  93 #
  94 # Enable them here unconditionally.  They are supported by GCC >= 4.8 and by
  95 # Clang >= 3.3 (required by the project) and are only valid for C code.
  96 WARN_CFLAGS="${WARN_CFLAGS} -Wold-style-definition -Wstrict-prototypes"
  97
  98 # Disable 'strict aliasing' if the C compiler supports it.
  99 AC_LANG_PUSH([C])
 100 AX_APPEND_COMPILE_FLAGS([-fno-strict-aliasing], [OPT_CFLAGS], [-Werror])
 101 AC_LANG_POP([C])
 102
 103
 104 ##                     ##
 105 ## C++ compiler checks ##
 106 ##                     ##
 107
 108 # Find a C++11 compiler with GNU extensions (-std=gnu++11)
 109 AX_CXX_COMPILE_STDCXX([11], [ext], [mandatory])
 110
 111 # Detect warning flags specific to the C++ compiler and append them to
 112 # WARN_CXXFLAGS.
 113 m4_define([WARN_FLAGS_CXX_LIST], [ dnl
 114   dnl GCC enables this with -Wall in C++, and that generates a
 115   dnl lot of warnings that have on average a low value to fix.
 116   -Wno-sign-compare dnl
 117 ])
 118
 119 # Pass -Werror as an extra flag during the test: this is needed to make the
 120 # -Wunknown-warning-option diagnostic fatal with clang.
 121 AC_LANG_PUSH([C++])
 122 AX_APPEND_COMPILE_FLAGS([WARN_FLAGS_COMMON_LIST WARN_FLAGS_CXX_LIST], [WARN_CXXFLAGS], [-Werror])
 123 AC_LANG_POP([C++])
 124
 125 # Disable 'strict aliasing' if the C++ compiler supports it.
 126 AC_LANG_PUSH([C++])
 127 AX_APPEND_COMPILE_FLAGS([-fno-strict-aliasing], [OPT_CXXFLAGS], [-Werror])
 128 AC_LANG_POP([C++])
 129
 130
 131 # When given, add -Werror to WARN_CFLAGS and WARN_CXXFLAGS.
 132 AC_ARG_ENABLE([Werror],[
 133   AS_HELP_STRING([--enable-Werror], [Treat compiler warnings as errors.])
 134 ])
 135
 136 AS_IF([test "x$enable_Werror" = "xyes"], [
 137   WARN_CFLAGS="${WARN_CFLAGS} -Werror"
 138   WARN_CXXFLAGS="${WARN_CXXFLAGS} -Werror"
 139 ])
 140
 141 # Checks for programs.
 142 AC_PROG_GREP
 143 AC_PROG_MAKE_SET
 144 AC_PROG_SED
 145 AC_PATH_PROG([report_fold], [fold])
 146 LT_INIT
 147
 148 # Check for objcopy, required by the base address statedump and dynamic linker tests
 149 AC_CHECK_TOOL([OBJCOPY], [objcopy], [no])
 150 AS_IF([test "x$OBJCOPY" = "xno"],
 151         [AC_MSG_WARN([Cannot find objcopy. The base address statedump and dynamic linker tests will be disabled. Install the binutils package to remediate this.])]
 152 )
 153 AM_CONDITIONAL([HAVE_OBJCOPY], [test "x$OBJCOPY" != xno])
 154
 155 # check for pgrep
 156 AC_PATH_PROG([PGREP], [pgrep], [no])
 157 AM_CONDITIONAL([HAVE_PGREP], [test "x$PGREP" != "xno"])
 158
 159 # set $IN_GIT_REPO if we're in the Git repository; the `bootstrap` file
 160 # is not distributed in tarballs
 161 AS_IF([test -f "$srcdir/bootstrap"], [in_git_repo=yes], [in_git_repo=no])
 162 AM_CONDITIONAL([IN_GIT_REPO], [test "x$in_git_repo" = "xyes"])
 163
 164 # check for bison
 165 AC_PROG_YACC
 166 BISON=$YACC
 167 AX_PROG_BISON_VERSION([2.4], [have_bison=yes])
 168
 169 AS_IF([test "x$have_bison" != "xyes"], [
 170   AS_IF([test "x$in_git_repo" = "xyes"], [
 171     AC_MSG_FAILURE([
 172 Bison >= 2.4 is required when building from the Git repository. You can
 173 set the YACC variable to override automatic detection.
 174     ])
 175   ], [
 176     AC_MSG_WARN([
 177 Missing Bison >= 2.4. Note that the parser files are already built in
 178 this distribution tarball, so Bison is only needed if you intend to
 179 modify their sources. You can set the YACC variable to override automatic
 180 detection.
 181     ])
 182   ])
 183 ])
 184 AM_CONDITIONAL([HAVE_BISON], [test "x$have_bison" = "xyes"])
 185
 186 # check for flex
 187 # Prior to autoconf 2.70, AC_PROG_FLEX did not take an argument. This is not a
 188 # problem since the argument is silently ignored by older versions.
 189 AC_PROG_LEX([noyywrap])
 190 FLEX=$LEX
 191 AX_PROG_FLEX_VERSION([2.5.35], [have_flex=yes])
 192
 193 AS_IF([test "x$have_flex" != "xyes"], [
 194   AS_IF([test "x$in_git_repo" = "xyes"], [
 195     AC_MSG_FAILURE([
 196 Flex >= 2.5.35 is required when building from the Git repository. You can
 197 set the LEX variable to override automatic detection.
 198     ])
 199   ], [
 200     AC_MSG_WARN([
 201 Missing Flex >= 2.5.35. Note that the lexer files are already built in
 202 this distribution tarball, so Flex is only needed if you intend to
 203 modify their sources. You can set the LEX variable to override automatic
 204 detection.
 205     ])
 206   ])
 207 ])
 208 AM_CONDITIONAL([HAVE_FLEX], [test "x$have_flex" = "xyes"])
 209
 210
 211
 212 # Check if linker has the -no-pie option.
 213 AX_CHECK_LINK_FLAG([-no-pie], [linker_have_no_pie_option=yes])
 214 AM_CONDITIONAL([LINKER_HAVE_NO_PIE_OPTION], [test "x$linker_have_no_pie_option" = "xyes"])
 215
 216 AX_LIB_SOCKET_NSL
 217
 218 LT_NO_UNDEFINED=""
 219 AS_CASE([$host_os],
 220   [cygwin*],
 221     [
 222       LT_NO_UNDEFINED="-no-undefined"
 223     ],
 224   [cygwin*|darwin*|mingw*|solaris*],
 225     [
 226       # On platforms where we only support the relayd, disable the other binaries by default
 227       AS_IF([test "x$enable_bin_lttng" = "x" ], [enable_bin_lttng=no])
 228       AS_IF([test "x$enable_bin_lttng_consumerd" = "x" ], [enable_bin_lttng_consumerd=no])
 229       AS_IF([test "x$enable_bin_lttng_crash" = "x" ], [enable_bin_lttng_crash=no])
 230       AS_IF([test "x$enable_bin_lttng_sessiond" = "x" ], [enable_bin_lttng_sessiond=no])
 231       AS_IF([test "x$enable_extras" = "x" ], [enable_extras=no])
 232       AS_IF([test "x$with_lttng_ust" = "x" ], [with_lttng_ust=no])
 233     ]
 234 )
 235
 236 AC_SUBST(LT_NO_UNDEFINED)
 237
 238 # Compute minor/major/patchlevel version numbers
 239 major_version=$(echo AC_PACKAGE_VERSION | $SED 's/^\([[0-9]]\)*\.[[0-9]]*\.[[0-9]]*.*$/\1/')
 240 minor_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.\([[0-9]]*\)\.[[0-9]]*.*$/\1/')
 241 patchlevel_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\).*$/\1/')
 242
 243 AC_SUBST([MAJOR_VERSION], [$major_version])
 244 AC_SUBST([MINOR_VERSION], [$minor_version])
 245 AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version])
 246 AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [LTTng-Tools major version number])
 247 AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [LTTng-Tools minor version number])
 248 AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [LTTng-Tools patchlevel version number])
 249
 250 version_name="O-Beer"
 251 version_description="An alcoholic drink made from yeast-fermented malt flavored with hops."
 252 version_description_c=$(echo $version_description | $SED 's/"/\\"/g')
 253
 254 AC_DEFINE_UNQUOTED([VERSION_NAME], ["$version_name"], "")
 255 AC_DEFINE_UNQUOTED([VERSION_DESCRIPTION], ["$version_description_c"], "")
 256
 257 # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
 258 AC_ARG_ENABLE(libtool-linkdep-fixup,
 259         AS_HELP_STRING([--disable-libtool-linkdep-fixup],
 260                         [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)]),
 261         libtool_fixup=$enableval,
 262         libtool_fixup=yes)
 263
 264 AS_IF([test "x$libtool_fixup" = "xyes"],
 265             [
 266             libtool_m4="$srcdir/m4/libtool.m4"
 267             libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
 268             AC_MSG_CHECKING([for occurrence(s) of link_all_deplibs = no in $libtool_m4])
 269             libtool_flag_pattern_count=$($GREP -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
 270             AS_IF([test $libtool_flag_pattern_count -ne 0],
 271             [
 272                   AC_MSG_RESULT([$libtool_flag_pattern_count])
 273                   AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
 274                   $SED -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
 275                   ],
 276                   [
 277                   AC_MSG_RESULT([none])
 278                   ])
 279             ])
 280
 281 AM_CONDITIONAL([NO_SHARED], [test x$enable_shared = xno])
 282
 283 AC_CHECK_HEADERS([ \
 284         sys/types.h unistd.h fcntl.h string.h pthread.h limits.h \
 285         signal.h stdlib.h sys/un.h sys/socket.h stdlib.h stdio.h \
 286         getopt.h sys/ipc.h sys/shm.h popt.h grp.h arpa/inet.h \
 287         netdb.h netinet/in.h paths.h stddef.h sys/file.h sys/ioctl.h \
 288         sys/mount.h sys/param.h sys/time.h elf.h
 289 ])
 290
 291 AM_CONDITIONAL([HAVE_ELF_H], [test x$ac_cv_header_elf_h = xyes])
 292
 293 # Basic functions check
 294 AC_CHECK_FUNCS([ \
 295         atexit bzero clock_gettime dup2 fdatasync fls ftruncate \
 296         gethostbyname gethostname getpagesize localtime_r memchr memrchr memset \
 297         mkdir munmap putenv realpath rmdir socket strchr strcspn strdup \
 298         strncasecmp strndup strnlen strpbrk strrchr strstr strtol strtoul \
 299         strtoull dirfd gethostbyname2 getipnodebyname epoll_create1 \
 300         sched_getcpu sysconf sync_file_range
 301 ])
 302
 303 # Check for pthread_setname_np and pthread_getname_np
 304 LTTNG_PTHREAD_SETNAME_NP
 305 LTTNG_PTHREAD_GETNAME_NP
 306
 307 # Check if clock_gettime, timer_create, timer_settime, and timer_delete are available in lib rt, and if so,
 308 # add -lrt to LIBS
 309 AC_CHECK_LIB([rt], [clock_gettime, timer_create, timer_settime, timer_delete])
 310
 311 # Checks for dl.
 312 AC_CHECK_LIB([dl], [dlopen], [
 313         have_libdl=yes
 314         libdl_name=dl
 315         DL_LIBS="-ldl"
 316 ], [
 317         # libdl not found, check for dlopen in libc.
 318         AC_CHECK_LIB([c], [dlopen], [
 319                 have_libc_dl=yes
 320                 libdl_name=c
 321                 DL_LIBS="-lc"
 322         ], [
 323                 AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
 324         ])
 325 ])
 326 AC_SUBST(DL_LIBS)
 327
 328 # Check if libdl has dlmopen support.
 329 AH_TEMPLATE([HAVE_DLMOPEN], ["Define to 1 if dlmopen is available."])
 330 AC_CHECK_LIB([$libdl_name], [dlmopen], [
 331         AC_DEFINE([HAVE_DLMOPEN], [1])
 332         HAVE_DLMOPEN=1
 333 ], [
 334         HAVE_DLMOPEN=0
 335 ])
 336 AC_SUBST(HAVE_DLMOPEN)
 337
 338 # Babeltrace viewer check
 339 AC_ARG_WITH([babeltrace-bin],
 340         AS_HELP_STRING([--with-babeltrace-bin],
 341         [Location of the babeltrace viewer executable (including the filename)]),
 342         [BABELTRACE_BIN="$withval"],
 343         [BABELTRACE_BIN=''])
 344 AC_SUBST([BABELTRACE_BIN])
 345
 346 AC_ARG_WITH([babeltrace2-bin],
 347         AS_HELP_STRING([--with-babeltrace2-bin],
 348         [Location of the babeltrace2 viewer executable (including the filename)]),
 349         [BABELTRACE2_BIN="$withval"],
 350         [BABELTRACE2_BIN=''])
 351 AC_SUBST([BABELTRACE2_BIN])
 352
 353 AC_ARG_WITH([consumerd32-bin],
 354         AS_HELP_STRING([--with-consumerd32-bin],
 355         [Location of the 32-bit consumerd executable (including the filename)]),
 356         [CONSUMERD32_BIN="$withval"],
 357         [CONSUMERD32_BIN=''])
 358 AC_SUBST([CONSUMERD32_BIN])
 359
 360 AC_ARG_WITH([consumerd64-bin],
 361         AS_HELP_STRING([--with-consumerd64-bin],
 362         [Location of the 64-bit consumerd executable (including the filename)]),
 363         [CONSUMERD64_BIN="$withval"],
 364         [CONSUMERD64_BIN=''])
 365 AC_SUBST([CONSUMERD64_BIN])
 366
 367 AC_ARG_WITH([consumerd32-libdir],
 368         AS_HELP_STRING([--with-consumerd32-libdir],
 369         [Directory containing the 32-bit consumerd libraries]),
 370         [CONSUMERD32_LIBDIR="$withval"],
 371         [CONSUMERD32_LIBDIR=''])
 372 AC_SUBST([CONSUMERD32_LIBDIR])
 373
 374 AC_ARG_WITH([consumerd64-libdir],
 375         AS_HELP_STRING([--with-consumerd64-libdir],
 376         [Directory containing the 64-bit consumerd libraries]),
 377         [CONSUMERD64_LIBDIR="$withval"],
 378         [CONSUMERD64_LIBDIR=''])
 379 AC_SUBST([CONSUMERD64_LIBDIR])
 380
 381 AC_ARG_WITH([sessiond-bin],
 382         AS_HELP_STRING([--with-sessiond-bin],
 383         [Location of the sessiond executable (including the filename)]),
 384         [SESSIOND_BIN="$withval"],
 385         [SESSIOND_BIN=''])
 386 AC_SUBST([SESSIOND_BIN])
 387
 388 AC_ARG_WITH([lttng-system-rundir],
 389         AS_HELP_STRING([--with-lttng-system-rundir],
 390         [Location of the system directory where the system-wide lttng-sessiond runtime files are kept. The default is "/var/run/lttng".]),
 391         [LTTNG_SYSTEM_RUNDIR="$withval"],
 392         [LTTNG_SYSTEM_RUNDIR="/var/run/lttng"])
 393 AC_SUBST([LTTNG_SYSTEM_RUNDIR])
 394
 395 AC_ARG_ENABLE([test-java-agent-jul],
 396         [AS_HELP_STRING([--enable-test-java-agent-jul],[enable the LTTng UST Java agent JUL tests [default=no]])],
 397         [test_java_agent_jul=$enableval],
 398         [test_java_agent_jul=no]
 399 )
 400
 401 AC_ARG_ENABLE([test-java-agent-log4j],
 402         [AS_HELP_STRING([--enable-test-java-agent-log4j],[enable the LTTng UST Java agent Log4j 1.x tests [default=no]])],
 403         [test_java_agent_log4j=$enableval],
 404         [test_java_agent_log4j=no]
 405 )
 406
 407 AC_ARG_ENABLE([test-java-agent-log4j2],
 408         [AS_HELP_STRING([--enable-test-java-agent-log4j2],[enable the LTTng UST Java agent Log4j 2.x tests [default=no]])],
 409         [test_java_agent_log4j2=$enableval],
 410         [test_java_agent_log4j2=no]
 411 )
 412
 413 AC_ARG_ENABLE([test-java-agent-all],
 414         [AS_HELP_STRING([--enable-test-java-agent-all],[enable all the LTTng UST Java agent tests [default=no]])],
 415         [test_java_agent_jul=$enableval
 416          test_java_agent_log4j=$enableval
 417          test_java_agent_log4j2=$enableval],
 418         [:]
 419 )
 420
 421 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_BIN], "$CONSUMERD32_BIN", [Location of the 32-bit consumerd executable.])
 422 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_BIN], "$CONSUMERD64_BIN", [Location of the 64-bit consumerd executable])
 423 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_LIBDIR], "$CONSUMERD32_LIBDIR", [Search for consumerd 32-bit libraries in this location.])
 424 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_LIBDIR], "$CONSUMERD64_LIBDIR", [Search for consumerd 64-bit libraries in this location.])
 425 AC_DEFINE_UNQUOTED([CONFIG_BABELTRACE_BIN], "$BABELTRACE_BIN", [Location of the babeltrace viewer executable.])
 426 AC_DEFINE_UNQUOTED([CONFIG_BABELTRACE2_BIN], "$BABELTRACE2_BIN", [Location of the babeltrace2 viewer executable.])
 427 AC_DEFINE_UNQUOTED([CONFIG_SESSIOND_BIN], "$SESSIOND_BIN", [Location of the sessiond executable.])
 428 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_RUNDIR], ["$LTTNG_SYSTEM_RUNDIR"], [LTTng system runtime directory])
 429
 430 AC_DEFUN([_AC_DEFINE_AND_SUBST], [
 431         AC_DEFINE_UNQUOTED([CONFIG_$1], [$2], [$1])
 432         $1="$2"
 433         AC_SUBST([$1])
 434 ])
 435
 436 AC_DEFUN([_AC_DEFINE_QUOTED_AND_SUBST], [
 437         AC_DEFINE_UNQUOTED([CONFIG_$1], ["$2"], [$1])
 438         $1="$2"
 439         AC_SUBST([$1])
 440 ])
 441
 442 # Default values
 443 m4_define([_DEFAULT_CHANNEL_SUBBUF_SIZE], [16384])
 444 m4_define([_DEFAULT_CHANNEL_SUBBUF_NUM], [4])
 445 m4_define([_DEFAULT_CHANNEL_SWITCH_TIMER], [0])
 446 m4_define([_DEFAULT_CHANNEL_LIVE_TIMER], [0])
 447 m4_define([_DEFAULT_CHANNEL_READ_TIMER], [200000])
 448 m4_define([_DEFAULT_CHANNEL_MONITOR_TIMER], [1000000])
 449 m4_define([_DEFAULT_CHANNEL_BLOCKING_TIMEOUT], [0])
 450 _AC_DEFINE_AND_SUBST([DEFAULT_AGENT_TCP_PORT_RANGE_BEGIN], [5345])
 451 _AC_DEFINE_AND_SUBST([DEFAULT_AGENT_TCP_PORT_RANGE_END], [5354])
 452 _AC_DEFINE_AND_SUBST([DEFAULT_APP_SOCKET_RW_TIMEOUT], [5])
 453 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE])
 454 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_COUNT], [0])
 455 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_SIZE], [0])
 456 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 457 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_READ_TIMER], [_DEFAULT_CHANNEL_READ_TIMER])
 458 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 459 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_SIZE], [1048576])
 460 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 461 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
 462 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_BLOCKING_TIMEOUT], [_DEFAULT_CHANNEL_BLOCKING_TIMEOUT])
 463 _AC_DEFINE_AND_SUBST([DEFAULT_LTTNG_LIVE_TIMER], [1000000])
 464 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_CACHE_SIZE], [4096])
 465 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_READ_TIMER], [0])
 466 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_NUM], [2])
 467 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_SIZE], [4096])
 468 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 469 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_CONTROL_PORT], [5342])
 470 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_DATA_PORT], [5343])
 471 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_VIEWER_PORT], [5344])
 472 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 473 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_READ_TIMER], [0])
 474 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_BLOCKING_TIMEOUT], [0])
 475 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 476 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE])
 477 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 478 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
 479 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 480 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_READ_TIMER], [0])
 481 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_BLOCKING_TIMEOUT], [0])
 482 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 483 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_SIZE], [524288])
 484 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 485 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
 486 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_AGENT_BIND_ADDRESS], [localhost])
 487 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_CONTROL_BIND_ADDRESS], [0.0.0.0])
 488 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_DATA_BIND_ADDRESS], [0.0.0.0])
 489 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_VIEWER_BIND_ADDRESS], [localhost])
 490 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_RELAYD_CTRL_MAX_PAYLOAD_SIZE], [134217728])
 491 _AC_DEFINE_AND_SUBST([DEFAULT_ROTATE_PENDING_TIMER], [500000])
 492 _AC_DEFINE_AND_SUBST([DEFAULT_EVENT_NOTIFIER_ERROR_COUNT_MAP_SIZE], [4096])
 493
 494 # Command short descriptions
 495 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ADD_CONTEXT], [Add context fields to be recorded])
 496 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ADD_TRIGGER], [Add a trigger])
 497 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_CLEAR], [Clear a recording session])
 498 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_CREATE], [Create a recording session])
 499 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DESTROY], [Destroy recording sessions])
 500 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_CHANNEL], [Disable channels])
 501 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_EVENT], [Disable recording event rules])
 502 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_ROTATION], [Unset a recording session rotation schedule])
 503 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_CHANNEL], [Create or enable a channel])
 504 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_EVENT], [Create or enable recording event rules])
 505 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_ROTATION], [Set a recording session rotation schedule])
 506 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_HELP], [Show the help of a command])
 507 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LIST], [List recording sessions and instrumentation points])
 508 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LIST_TRIGGERS], [List triggers])
 509 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LOAD], [Load recording session configurations])
 510 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_REGENERATE], [Regenerate specific recording session data])
 511 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_REMOVE_TRIGGER], [Remove a trigger])
 512 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ROTATE], [Archive the current trace chunk of a recording session])
 513 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SAVE], [Save recording session configurations])
 514 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SET_SESSION], [Set the current recording session])
 515 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SNAPSHOT], [Take a recording session snapshot])
 516 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_START], [Start a recording session])
 517 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STATUS], [Show the status of the current recording session])
 518 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STOP], [Stop a recording session])
 519 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_TRACK], [Allow specific processes to record events])
 520 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_UNTRACK], [Disallow specific processes to record events])
 521 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VERSION], [Show LTTng-tools version information])
 522 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VIEW], [Launch a trace reader])
 523
 524 if test "x$prefix" = "xNONE"; then
 525         prefix=$ac_default_prefix
 526 fi
 527 CONFDIR=`eval echo $sysconfdir`
 528 AC_SUBST(CONFDIR)
 529 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_CONFIGDIR],"$CONFDIR", [LTTng system configuration directory.])
 530
 531 AX_DEFINE_DIR([CONFIG_LTTNG_SYSTEM_DATADIR], [datadir], [LTTng system data directory.])
 532
 533 # Check libpopt
 534 PKG_CHECK_MODULES([POPT], [popt],
 535   [
 536     dnl PKG_CHECK_MODULES defines POPT_LIBS
 537   ],
 538   [
 539     AC_MSG_WARN([pkg-config was unable to find a valid .pc for libpopt. Set PKG_CONFIG_PATH to specify the pkgconfig configuration file location])
 540     AC_MSG_WARN([Finding libpopt without pkg-config.])
 541     AC_CHECK_LIB([popt],
 542       [poptGetContext],
 543       [POPT_LIBS="-lpopt"],
 544       [
 545         AC_MSG_FAILURE([Cannot find libpopt. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location])
 546       ]
 547     )
 548   ]
 549 )
 550 AC_SUBST(POPT_LIBS)
 551
 552 PKG_CHECK_MODULES([libxml2], [libxml-2.0 >= 2.7.6])
 553
 554 AC_CHECK_FUNC([clock_gettime], [AC_DEFINE_UNQUOTED([LTTNG_HAVE_CLOCK_GETTIME], 1, [Has clock_gettime() support.])])
 555
 556 # URCU library version needed or newer
 557 PKG_CHECK_MODULES([URCU], [liburcu >= 0.11])
 558 PKG_CHECK_MODULES([URCU_CDS], [liburcu-cds >= 0.11])
 559 AM_CPPFLAGS="$AM_CPPFLAGS $URCU_CFLAGS"
 560
 561 # Check for libkmod, it will be auto-neabled if found but won't fail if it's not,
 562 # it can be explicitly disabled with --without-kmod
 563 AH_TEMPLATE([HAVE_KMOD], [Define if you have kmod support])
 564 AC_ARG_WITH([kmod],
 565   [AS_HELP_STRING([--with-kmod], [build with lkmod support @<:@default=check@:>@])],
 566   [],
 567   [with_kmod=check]
 568 )
 569
 570 AS_IF([test "x$with_kmod" != "xno"],
 571   [
 572     AC_CHECK_LIB([kmod], [kmod_module_probe_insert_module],
 573       [
 574         AC_DEFINE([HAVE_KMOD], [1])
 575         KMOD_LIBS="-lkmod"
 576       ],
 577       [
 578         if test "x$with_kmod" != xcheck; then
 579           AC_MSG_FAILURE([Cannot find libkmod. Use [LDFLAGS]=-Ldir and [CPPFLAGS]=-Idir to specify its location.])
 580         else
 581           with_kmod=no
 582         fi
 583       ]
 584     )
 585   ]
 586 )
 587 AC_SUBST(KMOD_LIBS)
 588
 589 # Check for liblttng-ust-ctl, fail if it's not found,
 590 # it can be explicitly disabled with --without-lttng-ust
 591 AH_TEMPLATE([HAVE_LIBLTTNG_UST_CTL], [Define if you have LTTng-UST control support])
 592 AC_ARG_WITH([lttng-ust],
 593   [AS_HELP_STRING([--without-lttng-ust], [build without LTTng-UST (Userspace Tracing) support])],
 594   [],
 595   [with_lttng_ust=yes]
 596 )
 597
 598 AS_IF([test "x$with_lttng_ust" = "xyes"], [
 599   AC_DEFINE([HAVE_LIBLTTNG_UST_CTL], [1])
 600
 601   # Check for liblttng-ust
 602   PKG_CHECK_MODULES([UST], [lttng-ust >= $major_version.$minor_version])
 603
 604   # Check for liblttng-ust-ctl
 605   PKG_CHECK_MODULES([UST_CTL], [lttng-ust-ctl >= $major_version.$minor_version])
 606
 607   AM_CPPFLAGS="$AM_CPPFLAGS $UST_CFLAGS"
 608 ])
 609
 610 AM_CONDITIONAL([HAVE_LIBLTTNG_UST_CTL], [test "x$with_lttng_ust" = "xyes"])
 611
 612
 613 # Check for fmemopen
 614 AC_CHECK_LIB([c], [fmemopen],
 615 [
 616         AC_DEFINE_UNQUOTED([LTTNG_HAVE_FMEMOPEN], 1, [Has fmemopen support.])
 617 ]
 618 )
 619
 620 # check for libpfm
 621 AC_CHECK_LIB([pfm], [pfm_initialize],
 622              [
 623               have_libpfm=yes
 624               ])
 625 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBPFM], [test "x$have_libpfm" = "xyes"])
 626
 627 # For Python
 628 # SWIG version needed or newer:
 629 swig_version=2.0.0
 630
 631 AC_ARG_ENABLE([python-bindings],
 632               [AS_HELP_STRING([--enable-python-bindings],
 633                               [compile Python bindings])],
 634               [enable_python_binding=$enableval], [enable_python_binding=no])
 635
 636 AM_CONDITIONAL([PYTHON_BINDING], [test "x$enable_python_binding" = xyes])
 637
 638 if test "x$enable_python_binding" = xyes; then
 639   AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ])
 640   AS_IF([test x$enable_shared = xno], [ AC_MSG_ERROR([Python bindings require shared libraries.]) ])
 641   AM_PATH_PYTHON([3.0])
 642
 643   AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config])
 644   AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
 645   AS_IF([test -z "$PYTHON_INCLUDE"], [
 646     AS_IF([test -z "$PYTHON_CONFIG"], [
 647       AC_PATH_PROGS([PYTHON_CONFIG],
 648                     [python$PYTHON_VERSION-config python-config],
 649                     [no],
 650                     [`dirname $PYTHON`])
 651       AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
 652     ])
 653     AC_MSG_CHECKING([python include flags])
 654     PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
 655     AC_MSG_RESULT([$PYTHON_INCLUDE])
 656   ])
 657
 658 else
 659     AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl
 660 [if you want Python bindings.])
 661
 662 fi
 663
 664 # Epoll check. If not present, the build will fallback on poll() API
 665 AX_HAVE_EPOLL(
 666         [AX_CONFIG_FEATURE_ENABLE(epoll)],
 667         [AX_CONFIG_FEATURE_DISABLE(epoll)]
 668 )
 669 AX_CONFIG_FEATURE(
 670         [epoll], [This platform supports epoll(7)],
 671         [HAVE_EPOLL], [This platform supports epoll(7).]
 672 )
 673
 674 AS_IF([test "x$ac_cv_func_dirfd" = "xyes"],
 675         [AX_CONFIG_FEATURE_ENABLE(dirfd)],
 676         [AX_CONFIG_FEATURE_DISABLE(dirfd)]
 677 )
 678 AX_CONFIG_FEATURE(
 679         [dirfd], [Use directory file descriptors],
 680         [HAVE_DIRFD], [This platform supports directory file descriptors.]
 681 )
 682
 683 AM_CONDITIONAL([TEST_JAVA_JUL_AGENT], [test "x$test_java_agent_jul" = "xyes"])
 684 AM_CONDITIONAL([TEST_JAVA_LOG4J_AGENT], [test "x$test_java_agent_log4j" = "xyes"])
 685 AM_CONDITIONAL([TEST_JAVA_LOG4J2_AGENT], [test "x$test_java_agent_log4j2" = "xyes"])
 686
 687 if test "x$test_java_agent_jul" = "xyes" || test "x$test_java_agent_log4j" = "xyes" || test "x$test_java_agent_log4j2" = "xyes"; then
 688         AX_JAVA_OPTIONS
 689         AX_PROG_JAVAC
 690         AX_PROG_JAVA
 691         AX_PROG_JAR
 692
 693         AX_CHECK_CLASSPATH
 694
 695         # Check for Java UST agent common class first
 696         AX_CHECK_CLASS(org.lttng.ust.agent.AbstractLttngAgent)
 697         if test "x$ac_cv_class_org_lttng_ust_agent_AbstractLttngAgent" = "xno"; then
 698                 AC_MSG_ERROR([The UST Java agent common class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-common.jar"])
 699         fi
 700
 701         if test "x$test_java_agent_jul" = "xyes"; then
 702                 # Check for JUL agent class
 703                 AX_CHECK_CLASS(org.lttng.ust.agent.jul.LttngLogHandler)
 704                 if test "x$ac_cv_class_org_lttng_ust_agent_jul_LttngLogHandler" = "xno"; then
 705                         AC_MSG_ERROR([The UST Java agent JUL class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-jul.jar"])
 706                 fi
 707         fi
 708
 709         if test "x$test_java_agent_log4j" = "xyes"; then
 710                 # Check for Log4j agent class
 711                 AX_CHECK_CLASS(org.lttng.ust.agent.log4j.LttngLogAppender)
 712                 if test "x$ac_cv_class_org_lttng_ust_agent_log4j_LttngLogAppender" = "xno"; then
 713                         AC_MSG_ERROR([The UST Java agent Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-log4j.jar"])
 714                 fi
 715
 716                 # Check for Log4j class
 717                 AX_CHECK_CLASS(org.apache.log4j.Logger)
 718                 if test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"; then
 719                         AC_MSG_ERROR([The Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j.jar"])
 720                 fi
 721         fi
 722
 723         if test "x$test_java_agent_log4j2" = "xyes"; then
 724                 # Check for Log4j2 agent class
 725                 AX_CHECK_CLASS(org.lttng.ust.agent.log4j2.LttngLogAppender)
 726                 if test "x$ac_cv_class_org_lttng_ust_agent_log4j2_LttngLogAppender" = "xno"; then
 727                         AC_MSG_ERROR([The UST Java agent Log4j 2.x class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-log4j2.jar"])
 728                 fi
 729
 730                 # Check for Log4j 2.x classes
 731                 AX_CHECK_CLASS([org.apache.logging.log4j.Logger])
 732                 AX_CHECK_CLASS([org.apache.logging.log4j.core.Core])
 733                 if test "x$ac_cv_class_org_apache_logging_log4j_Logger" = "xno" || test "x$ac_cv_class_org_apache_logging_log4j_core_Core" = "xno"; then
 734                         AC_MSG_ERROR([The Log4j 2.x API or core class was not found. Please specify the location of the jars via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j-core.jar:/path/to/log4j-api.jar"])
 735                 fi
 736         fi
 737 fi
 738
 739 # enable building man pages (user's intention)
 740 AC_ARG_ENABLE(
 741         man-pages,
 742         AS_HELP_STRING(
 743                 [--disable-man-pages],
 744                 [Do not build and install man pages (already built in a distributed tarball)]
 745         ),
 746         [man_pages_opt=$enableval],
 747         [man_pages_opt=yes]
 748 )
 749
 750 # check for asciidoc and xmlto if we enabled building the man pages
 751 have_asciidoc_xmlto=no
 752 warn_prebuilt_man_pages=no
 753
 754 AS_IF([test "x$man_pages_opt" = "xyes"], [
 755         AC_PATH_PROG([ASCIIDOC], [asciidoc], [no])
 756         AC_PATH_PROG([XMLTO], [xmlto], [no])
 757
 758         AS_IF([test "x$ASCIIDOC" = "xno" || test "x$XMLTO" = "xno"], [
 759                 AS_IF([test "x$in_git_repo" = "xyes"], [
 760                         # this is an error because we're in the Git repo, which
 761                         # means the man pages are not already generated for us,
 762                         # thus asciidoc/xmlto are required because we were asked
 763                         # to build the man pages
 764                         AC_MSG_ERROR([
 765 You need asciidoc and xmlto to build the LTTng-tools man pages. Use
 766 --disable-man-pages to disable building the man pages, in which case
 767 they will not be installed.
 768                         ])
 769                 ], [
 770                         # only warn here: since we're in the tarball, the man
 771                         # pages should already be generated at this point, thus
 772                         # asciidoc/xmlto are not strictly required
 773                         warn_prebuilt_man_pages=yes
 774                 ])
 775         ], [
 776                 have_asciidoc_xmlto=yes
 777         ])
 778 ])
 779
 780 # export man page build condition: build the man pages if the user
 781 # asked for it, and if the tools are available
 782 AM_CONDITIONAL([MAN_PAGES_OPT], [test "x$man_pages_opt" != "xno"])
 783 AM_CONDITIONAL([HAVE_ASCIIDOC_XMLTO], [test "x$have_asciidoc_xmlto" = "xyes"])
 784
 785 AC_DEFINE_UNQUOTED([MANPATH], ["`eval eval echo $mandir`"], [Path to man pages.])
 786
 787 # embedded --help message
 788 AC_ARG_ENABLE(
 789         [embedded-help],
 790         AS_HELP_STRING(
 791                 [--enable-embedded-help],
 792                 [Embed the --help messages in the executable files]
 793         ),
 794         [embedded_help=$enableval],
 795         [embedded_help=no]
 796 )
 797 AS_IF([test "x$embedded_help" = "xyes"], [
 798         AS_IF([test "x$man_pages_opt" = "xno"], [
 799                 AC_MSG_ERROR([You need the --enable-man-pages option with the --enable-embedded-help option.])
 800         ])
 801         AC_PATH_PROG([man_prog_path], [man], [no])
 802         AS_IF([test "x$man_prog_path" = "xno"], [
 803                 AC_MSG_ERROR([You need man with the --enable-embedded-help option.])
 804         ])
 805         AC_DEFINE_UNQUOTED([LTTNG_EMBED_HELP], 1, [Embed --help messages.])
 806         AC_SUBST([MANPROG], [$man_prog_path])
 807 ])
 808 AM_CONDITIONAL([EMBED_HELP], [test "x$embedded_help" != "xno"])
 809
 810 # Python agent test
 811 UST_PYTHON_AGENT="lttngust"
 812
 813 AC_ARG_ENABLE(test-python2-agent,
 814         AS_HELP_STRING([--enable-test-python2-agent],
 815                 [enable tests for python2 agent. Python2 interpreter path can be overridden by setting the PYTHON2 environment variable. Default: Autodetect]
 816         ),[:],[test_python2_agent_autodetect=yes]
 817 )
 818
 819 AC_ARG_ENABLE(test-python3-agent,
 820         AS_HELP_STRING([--enable-test-python3-agent],
 821                 [enable tests for python3 agent. Python3 interpreter path can be overridden by setting the PYTHON3 environment variable. Default: Autodetect]
 822         ),[:],[test_python3_agent_autodetect=yes]
 823 )
 824
 825 AC_ARG_ENABLE(test-python-agent-all,
 826         AS_HELP_STRING([--enable-test-python-agent-all],
 827                 [enable test for all python{2/3} agent.]
 828         ),
 829 )
 830
 831 AS_IF([test ! -z "$enable_test_python_agent_all"], [
 832        unset test_python2_agent_autodetect
 833        unset test_python3_agent_autodetect
 834 ])
 835
 836 AS_IF([test "x$enable_test_python_agent_all" = "xyes"], [
 837        enable_test_python2_agent=yes
 838        enable_test_python3_agent=yes
 839 ])
 840
 841 AS_IF([test "x$enable_test_python_agent_all" = "xno"], [
 842        enable_test_python2_agent=no
 843        enable_test_python3_agent=no
 844 ])
 845
 846
 847 AS_IF([test "x$enable_test_python2_agent" = "xyes" -o "x$test_python2_agent_autodetect" = "xyes" ], [
 848         AS_IF([test -z "$PYTHON2"], [
 849                         PYTHON2=python2
 850                 ], [
 851                         AC_MSG_WARN([Using user-defined PYTHON2 ($PYTHON2) for lttng-ust python2 agent check])
 852         ])
 853
 854         AC_PATH_PROG([PYTHON2_BIN],[$PYTHON2])
 855         AS_IF([test -z "$PYTHON2_BIN"], [
 856                 AS_IF([test -z "$test_python2_agent_autodetect"],[
 857                         AC_MSG_ERROR([No python2 interpreter found. PYTHON2 can be set to override default interpreter path])
 858                 ])
 859         ], [
 860                 AC_MSG_CHECKING([for python2 lttng-ust agent])
 861                 AS_IF([$PYTHON2_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
 862                         PYTHON2_AGENT=$PYTHON2_BIN
 863                         AC_MSG_RESULT([yes])
 864                         RUN_PYTHON_AGENT_TEST=yes
 865                 ], [
 866                         AC_MSG_RESULT([no])
 867                         AS_IF([test -z "$test_python2_agent_autodetect"],[
 868                                 AC_MSG_ERROR([No python2 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
 869                         ])
 870                 ])
 871
 872         ])
 873
 874 ])
 875
 876 AS_IF([test "x$enable_test_python3_agent" = "xyes" -o "x$test_python3_agent_autodetect" = "xyes" ], [
 877         AS_IF([test -z "$PYTHON3"], [
 878                 PYTHON3=python3
 879         ], [
 880                 AC_MSG_WARN([Using user-defined PYTHON3 ($PYTHON3) for lttng-ust python3 agent check])
 881         ])
 882
 883         AC_PATH_PROG([PYTHON3_BIN],[$PYTHON3])
 884         AS_IF([test -z "$PYTHON3_BIN"], [
 885                 AS_IF([test -z "$test_python3_agent_autodetect"],[
 886                         AC_MSG_ERROR([No python3 interpreter found. PYTHON3 can be set to override default interpreter path])
 887                 ])
 888         ], [
 889                 AC_MSG_CHECKING([for python3 lttng-ust agent])
 890                 AS_IF([$PYTHON3_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
 891                         PYTHON3_AGENT=$PYTHON3_BIN
 892                         AC_MSG_RESULT([yes])
 893                         RUN_PYTHON_AGENT_TEST=yes
 894                 ], [
 895                         AC_MSG_RESULT([no])
 896                         AS_IF([test -z "$test_python3_agent_autodetect"],[
 897                                 AC_MSG_ERROR([No python3 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
 898                         ])
 899                 ])
 900
 901         ])
 902 ])
 903 AC_SUBST([RUN_PYTHON_AGENT_TEST])
 904 AC_SUBST([PYTHON2_AGENT])
 905 AC_SUBST([PYTHON3_AGENT])
 906
 907 AC_ARG_ENABLE([test-sdt-uprobe],
 908   [AS_HELP_STRING([--enable-test-sdt-uprobe], [enable the LTTng UST SDT uprobe tests [default=autodetect]])],
 909   [test_sdt_uprobe="$enableval"],
 910   [test_sdt_uprobe=autodetect]
 911 )
 912
 913 AS_IF([test "$test_sdt_uprobe" != "no"], [
 914   LTTNG_CHECK_SDT_WORKS
 915   AC_PATH_PROG([DTRACE], [dtrace])
 916 ])
 917
 918 AS_IF([test "$test_sdt_uprobe" = "yes"], [
 919   AS_IF([test "$lttng_cv_sdt_works" = "no"], [
 920     AC_MSG_ERROR([Cannot find 'sys/sdt.h'.])
 921   ])
 922   AS_IF([test "x$DTRACE" = "x"], [
 923     AC_MSG_ERROR([Cannot find SystemTap dtrace. You can set the DTRACE variable to override automatic detection.])
 924   ])
 925 ])
 926
 927 AS_IF([test "$test_sdt_uprobe" = "autodetect"], [
 928   AS_IF([test "$lttng_cv_sdt_works" = "yes"], [
 929     AS_IF([test "x$DTRACE" != "x"], [
 930       test_sdt_uprobe=yes
 931     ])
 932   ])
 933 ])
 934
 935 AM_CONDITIONAL([TEST_SDT_UPROBE], [test "$test_sdt_uprobe" = "yes"])
 936
 937 # Arguments for binaries build exclusion
 938 AC_ARG_ENABLE([bin-lttng], AS_HELP_STRING([--disable-bin-lttng],[Disable the build of lttng binaries]))
 939 AC_ARG_ENABLE([bin-lttng-consumerd], AS_HELP_STRING([--disable-bin-lttng-consumerd],
 940               [Disable the build of lttng-consumerd binaries]))
 941 AC_ARG_ENABLE([bin-lttng-crash], AS_HELP_STRING([--disable-bin-lttng-crash],[Disable the build of lttng-crash binaries]))
 942 AC_ARG_ENABLE([bin-lttng-relayd], AS_HELP_STRING([--disable-bin-lttng-relayd],
 943               [Disable the build of lttng-relayd binaries]))
 944 AC_ARG_ENABLE([bin-lttng-sessiond], AS_HELP_STRING([--disable-bin-lttng-sessiond],
 945               [Disable the build of lttng-sessiond binaries]))
 946 AC_ARG_ENABLE([extras], AS_HELP_STRING([--disable-extras],
 947               [Disable the build of the extra components]))
 948
 949
 950 build_lib_consumer=no
 951 build_lib_health=no
 952 build_lib_index=no
 953 build_lib_kernel_consumer=no
 954 build_lib_kernel_ctl=no
 955 build_lib_lttng_ctl=no
 956 build_lib_relayd=no
 957 build_lib_sessiond_comm=no
 958 build_lib_testpoint=no
 959 build_lib_ust_consumer=no
 960
 961 # There is an overlap for enabled dependencies, but this makes everything
 962 # simpler. libcommon and libconfig are always compiled so they are not repeated
 963 # here.
 964
 965 # Enable binary dependencies.
 966 AS_IF([test x$enable_bin_lttng != xno],
 967       [
 968        build_lib_lttng_ctl=yes
 969       ]
 970 )
 971
 972 AS_IF([test x$enable_bin_lttng_consumerd != xno],
 973       [
 974        build_lib_consumer=yes
 975        build_lib_sessiond_comm=yes
 976        build_lib_index=yes
 977        build_lib_health=yes
 978        build_lib_testpoint=yes
 979       ]
 980 )
 981
 982 AS_IF([test x$enable_bin_lttng_crash != xno],
 983       # Do nothing since libconfig and libcommon are built by default.
 984       []
 985 )
 986
 987 AS_IF([test x$enable_bin_lttng_relayd != xno],
 988       [
 989        build_lib_sessiond_comm=yes
 990        build_lib_index=yes
 991        build_lib_health=yes
 992        build_lib_testpoint=yes
 993       ]
 994 )
 995 AS_IF([test x$enable_bin_lttng_sessiond != xno],
 996       [
 997        build_lib_lttng_ctl=yes
 998        build_lib_sessiond_comm=yes
 999        build_lib_kernel_ctl=yes
1000        build_lib_relayd=yes
1001        build_lib_testpoint=yes
1002        build_lib_health=yes
1003       ]
1004 )
1005
1006 # Libraries dependencies enabling
1007 AS_IF([test x$build_lib_lttng_ctl = xyes],
1008       [
1009        build_lib_sessiond_comm=yes
1010       ]
1011 )
1012
1013 AS_IF([test x$build_lib_consumer = xyes],
1014       [
1015        build_lib_sessiond_comm=yes
1016        build_lib_kernel_consumer=yes
1017        build_lib_relayd=yes
1018        AS_IF([test "x$with_lttng_ust" = "xyes"], [build_lib_ust_consumer=yes])
1019       ]
1020 )
1021
1022 AS_IF([test x$build_lib_kernel_consumer = xyes],
1023       [
1024        build_lib_kernel_ctl=yes
1025        build_lib_relayd=yes
1026       ]
1027 )
1028
1029 AS_IF([test x$build_lib_relayd = xyes],
1030       [
1031        build_lib_sessiond_comm=yes
1032       ]
1033 )
1034
1035 # Find arch type
1036 AS_CASE([$host_cpu],
1037         [k1om], [ARCHTYPE="x86"],
1038         [i386], [ARCHTYPE="x86"],
1039         [i486], [ARCHTYPE="x86"],
1040         [i586], [ARCHTYPE="x86"],
1041         [i686], [ARCHTYPE="x86"],
1042         [amd64], [ARCHTYPE="x86"],
1043         [x86_64], [ARCHTYPE="x86"],
1044         [powerpc], [ARCHTYPE="ppc"],
1045         [ppc64], [ARCHTYPE="ppc"],
1046         [powerpc64], [ARCHTYPE="ppc"],
1047         [powerpc64le], [ARCHTYPE="ppc"],
1048         [ppc], [ARCHTYPE="ppc"],
1049         [s390], [ARCHTYPE="s390"],
1050         [s390x], [ARCHTYPE="s390"],
1051         [sparc], [ARCHTYPE="sparc64"],
1052         [sparc64], [ARCHTYPE="sparc64"],
1053         [alpha*], [ARCHTYPE="alpha"],
1054         [ia64], [ARCHTYPE="ia64"],
1055         [arm*], [ARCHTYPE="arm"],
1056         [aarch64*], [ARCHTYPE="aarch64"],
1057         [mips*], [ARCHTYPE="mips"],
1058         [nios2*], [ARCHTYPE="nios2"],
1059         [tile*], [ARCHTYPE="tile"],
1060         [hppa*], [ARCHTYPE="hppa"],
1061         [m68k], [ARCHTYPE="m68k"],
1062         [riscv*], [ARCHTYPE="riscv"],
1063         [ARCHTYPE="unknown"]
1064 )
1065
1066 AC_SUBST(ARCHTYPE)
1067
1068 AS_CASE([$host_os],
1069         [linux*], [OSTYPE="linux"],
1070         [freebsd*], [OSTYPE="freebsd"],
1071         [solaris*], [OSTYPE="solaris"],
1072         [cygwin*], [OSTYPE="cygwin"],
1073         [mingw*], [OSTYPE="mingw"],
1074         [OSTYPE="unknown"]
1075 )
1076 AC_SUBST(OSTYPE)
1077 AM_CONDITIONAL([IS_LINUX], [test $OSTYPE = "linux"])
1078
1079
1080
1081 # Userspace callstack capture is only supported by the Linux kernel on x86.
1082 AH_TEMPLATE([HAVE_MODULES_USERSPACE_CALLSTACK_CONTEXT], [Define if you have LTTng-modules userspace callstack tracing support])
1083 AS_IF([test "x$ARCHTYPE" = "xx86" && test "x$OSTYPE" = "xlinux"],[
1084         have_modules_userspace_callstack_context=yes
1085         AC_DEFINE([HAVE_MODULES_USERSPACE_CALLSTACK_CONTEXT], [1])
1086 ])
1087 AM_CONDITIONAL([HAVE_MODULES_USERSPACE_CALLSTACK_CONTEXT], [test x$have_modules_userspace_callstack_context = xyes])
1088
1089 # Export binaries build conditions.
1090 AM_CONDITIONAL([BUILD_BIN_LTTNG], [test x$enable_bin_lttng != xno])
1091 AM_CONDITIONAL([BUILD_BIN_LTTNG_CONSUMERD], [test x$enable_bin_lttng_consumerd != xno])
1092 AM_CONDITIONAL([BUILD_BIN_LTTNG_CRASH], [test x$enable_bin_lttng_crash != xno])
1093 AM_CONDITIONAL([BUILD_BIN_LTTNG_RELAYD], [test x$enable_bin_lttng_relayd != xno])
1094 AM_CONDITIONAL([BUILD_BIN_LTTNG_SESSIOND], [test x$enable_bin_lttng_sessiond != xno])
1095
1096 # Export the tests and extras build conditions.
1097 AS_IF([\
1098 test "x$enable_bin_lttng" != "xno" && \
1099 test "x$enable_bin_lttng_consumerd" != "xno" && \
1100 test "x$enable_bin_lttng_crash" != "xno" && \
1101 test "x$enable_bin_lttng_relayd" != "xno" && \
1102 test "x$enable_bin_lttng_sessiond" != "xno"],
1103 [build_tests=yes],
1104 [build_tests=no]
1105 )
1106
1107 AM_CONDITIONAL([BUILD_TESTS], [test x$build_tests = xyes])
1108 AM_CONDITIONAL([BUILD_EXTRAS], [test x$enable_extras != xno])
1109
1110 # Export libraries build conditions.
1111 AM_CONDITIONAL([BUILD_LIB_CONSUMER], [test x$build_lib_consumer = xyes])
1112 AM_CONDITIONAL([BUILD_LIB_HEALTH], [test x$build_lib_health = xyes])
1113 AM_CONDITIONAL([BUILD_LIB_INDEX], [test x$build_lib_index = xyes])
1114 AM_CONDITIONAL([BUILD_LIB_KERNEL_CONSUMER], [test x$build_lib_kernel_consumer = xyes])
1115 AM_CONDITIONAL([BUILD_LIB_KERNEL_CTL], [test x$build_lib_kernel_ctl = xyes])
1116 AM_CONDITIONAL([BUILD_LIB_LTTNG_CTL], [test x$build_lib_lttng_ctl = xyes])
1117 AM_CONDITIONAL([BUILD_LIB_RELAYD], [test x$build_lib_relayd = xyes])
1118 AM_CONDITIONAL([BUILD_LIB_SESSIOND_COMM], [test x$build_lib_sessiond_comm = xyes])
1119 AM_CONDITIONAL([BUILD_LIB_TESTPOINT], [test x$build_lib_testpoint = xyes])
1120 AM_CONDITIONAL([BUILD_LIB_UST_CONSUMER], [test x$build_lib_ust_consumer = xyes])
1121
1122 AM_CFLAGS="-fvisibility=hidden $OPT_CFLAGS $WARN_CFLAGS $PTHREAD_CFLAGS"
1123 AC_SUBST(AM_CFLAGS)
1124
1125 AM_CXXFLAGS="-fvisibility=hidden -fvisibility-inlines-hidden $OPT_CXXFLAGS $WARN_CXXFLAGS $PTHREAD_CFLAGS"
1126 AC_SUBST(AM_CXXFLAGS)
1127
1128 # This is set even though it is empty, so Makefiles can do "AM_LDFLAGS += ...".
1129 AM_LDFLAGS=""
1130 AC_SUBST(AM_LDFLAGS)
1131
1132 # The order in which the include folders are searched is important.
1133 # The top_builddir should always be searched first in the event that a build
1134 # time generated file is included. An example of this is the "version.i" file.
1135 # In a scenario where lttng-tools is built from a distribution tarball and in a
1136 # out-of-tree manner, the generated "version.i" has priority on the one from
1137 # the source (distribution tarball) and must be found first.
1138 AM_CPPFLAGS="-I\$(top_builddir)/include -I\$(top_srcdir)/include -I\$(top_builddir)/src -I\$(top_srcdir)/src -include config.h $AM_CPPFLAGS"
1139 AC_SUBST(AM_CPPFLAGS)
1140
1141 lttngincludedir="${includedir}/lttng"
1142 AC_SUBST(lttngincludedir)
1143
1144 lttngactionincludedir="${includedir}/lttng/action"
1145 AC_SUBST(lttngactionincludedir)
1146
1147 lttngconditionincludedir="${includedir}/lttng/condition"
1148 AC_SUBST(lttngconditionincludedir)
1149
1150 lttngnotificationincludedir="${includedir}/lttng/notification"
1151 AC_SUBST(lttngnotificationincludedir)
1152
1153 lttngtriggerincludedir="${includedir}/lttng/trigger"
1154 AC_SUBST(lttngtriggerincludedir)
1155
1156 lttngeventruleincludedir="${includedir}/lttng/event-rule"
1157 AC_SUBST(lttngeventruleincludedir)
1158
1159 lttnglibexecdir="${libdir}/lttng/libexec"
1160 AC_SUBST(lttnglibexecdir)
1161
1162 AC_CONFIG_FILES([
1163         Makefile
1164         doc/Makefile
1165         doc/examples/Makefile
1166         doc/examples/rotation/Makefile
1167         doc/examples/trigger-condition-event-matches/Makefile
1168         doc/man/Makefile
1169         doc/man/asciidoc-attrs.conf
1170         include/Makefile
1171         extras/Makefile
1172         extras/bindings/Makefile
1173         extras/bindings/swig/Makefile
1174         extras/bindings/swig/python/Makefile
1175         extras/core-handler/Makefile
1176         src/Makefile
1177         src/common/Makefile
1178         src/lib/Makefile
1179         src/lib/lttng-ctl/Makefile
1180         src/lib/lttng-ctl/lttng-ctl.pc
1181         src/bin/Makefile
1182         src/bin/lttng-consumerd/Makefile
1183         src/bin/lttng-sessiond/Makefile
1184         src/bin/lttng-relayd/Makefile
1185         src/bin/lttng/Makefile
1186         src/bin/lttng-crash/Makefile
1187         src/vendor/Makefile
1188         src/vendor/msgpack/Makefile
1189         tests/Makefile
1190         tests/destructive/Makefile
1191         tests/regression/Makefile
1192         tests/regression/kernel/Makefile
1193         tests/regression/tools/Makefile
1194         tests/regression/tools/streaming/Makefile
1195         tests/regression/tools/filtering/Makefile
1196         tests/regression/tools/health/Makefile
1197         tests/regression/tools/tracefile-limits/Makefile
1198         tests/regression/tools/snapshots/Makefile
1199         tests/regression/tools/live/Makefile
1200         tests/regression/tools/exclusion/Makefile
1201         tests/regression/tools/save-load/Makefile
1202         tests/regression/tools/save-load/configuration/Makefile
1203         tests/regression/tools/mi/Makefile
1204         tests/regression/tools/wildcard/Makefile
1205         tests/regression/tools/channel/Makefile
1206         tests/regression/tools/crash/Makefile
1207         tests/regression/tools/regen-metadata/Makefile
1208         tests/regression/tools/regen-statedump/Makefile
1209         tests/regression/tools/notification/Makefile
1210         tests/regression/tools/rotation/Makefile
1211         tests/regression/tools/base-path/Makefile
1212         tests/regression/tools/metadata/Makefile
1213         tests/regression/tools/tracker/Makefile
1214         tests/regression/tools/working-directory/Makefile
1215         tests/regression/tools/relayd-grouping/Makefile
1216         tests/regression/tools/clear/Makefile
1217         tests/regression/tools/trigger/Makefile
1218         tests/regression/tools/trigger/rate-policy/Makefile
1219         tests/regression/tools/trigger/start-stop/Makefile
1220         tests/regression/tools/trigger/utils/Makefile
1221         tests/regression/tools/trigger/name/Makefile
1222         tests/regression/tools/trigger/hidden/Makefile
1223         tests/regression/ust/Makefile
1224         tests/regression/ust/nprocesses/Makefile
1225         tests/regression/ust/high-throughput/Makefile
1226         tests/regression/ust/low-throughput/Makefile
1227         tests/regression/ust/before-after/Makefile
1228         tests/regression/ust/buffers-pid/Makefile
1229         tests/regression/ust/periodical-metadata-flush/Makefile
1230         tests/regression/ust/multi-session/Makefile
1231         tests/regression/ust/multi-lib/Makefile
1232         tests/regression/ust/overlap/Makefile
1233         tests/regression/ust/overlap/demo/Makefile
1234         tests/regression/ust/linking/Makefile
1235         tests/regression/ust/daemon/Makefile
1236         tests/regression/ust/exit-fast/Makefile
1237         tests/regression/ust/fork/Makefile
1238         tests/regression/ust/libc-wrapper/Makefile
1239         tests/regression/ust/baddr-statedump/Makefile
1240         tests/regression/ust/ust-dl/Makefile
1241         tests/regression/ust/java-jul/Makefile
1242         tests/regression/ust/java-log4j/Makefile
1243         tests/regression/ust/java-log4j2/Makefile
1244         tests/regression/ust/getcpu-override/Makefile
1245         tests/regression/ust/clock-override/Makefile
1246         tests/regression/ust/type-declarations/Makefile
1247         tests/regression/ust/rotation-destroy-flush/Makefile
1248         tests/regression/ust/blocking/Makefile
1249         tests/regression/ust/namespaces/Makefile
1250         tests/stress/Makefile
1251         tests/unit/Makefile
1252         tests/unit/ini_config/Makefile
1253         tests/perf/Makefile
1254         tests/utils/Makefile
1255         tests/utils/tap/Makefile
1256         tests/utils/testapp/Makefile
1257         tests/utils/testapp/gen-ns-events/Makefile
1258         tests/utils/testapp/gen-kernel-test-events/Makefile
1259         tests/utils/testapp/gen-py-events/Makefile
1260         tests/utils/testapp/gen-ust-events/Makefile
1261         tests/utils/testapp/gen-ust-events-ns/Makefile
1262         tests/utils/testapp/gen-syscall-events-callstack/Makefile
1263         tests/utils/testapp/gen-ust-nevents/Makefile
1264         tests/utils/testapp/gen-ust-nevents-str/Makefile
1265         tests/utils/testapp/gen-syscall-events/Makefile
1266         tests/utils/testapp/gen-ust-tracef/Makefile
1267         tests/utils/testapp/userspace-probe-elf-binary/Makefile
1268         tests/utils/testapp/userspace-probe-elf-cxx-binary/Makefile
1269         tests/utils/testapp/userspace-probe-sdt-binary/Makefile
1270         tests/utils/xml-utils/Makefile
1271 ])
1272
1273 # Inject variable into python test script.
1274 AC_CONFIG_FILES([tests/regression/ust/python-logging/test_python_logging],[chmod +x tests/regression/ust/python-logging/test_python_logging])
1275 # Inject LTTNG_TOOLS_BUILD_WITH_LIBPFM variable in test script.
1276 AC_CONFIG_FILES([tests/perf/test_perf_raw],[chmod +x tests/perf/test_perf_raw])
1277 AC_CONFIG_FILES([tests/regression/ust/ust-dl/test_ust-dl],[chmod +x tests/regression/ust/ust-dl/test_ust-dl])
1278
1279 AC_OUTPUT
1280
1281 #
1282 # Mini-report on what will be built.
1283 #
1284
1285 PPRINT_INIT
1286 PPRINT_SET_INDENT(1)
1287 PPRINT_SET_TS(38)
1288
1289 AS_ECHO
1290 AS_ECHO("${PPRINT_COLOR_BLDBLU}LTTng-tools $PACKAGE_VERSION \"$version_name\"$PPRINT_COLOR_RST")
1291 AS_ECHO
1292
1293 AS_IF([test -n "$report_fold"], [
1294         AS_ECHO("`AS_ECHO("$version_description") | $report_fold -s`")
1295 ], [
1296         AS_ECHO("$version_description")
1297 ])
1298
1299 AS_ECHO
1300 PPRINT_SUBTITLE([Features])
1301
1302 # Target architecture we're building for.
1303 target_arch=$host_cpu
1304 [
1305 for f in $CFLAGS; do
1306         if test $f = "-m32"; then
1307                         target_arch="32-bit"
1308         elif test $f = "-m64"; then
1309                         target_arch="64-bit"
1310         fi
1311 done
1312 ]
1313 PPRINT_PROP_STRING([Target architecture], $target_arch)
1314
1315 # kmod enabled/disabled
1316 test "x$with_kmod" != "xno" && value=1 || value=0
1317 PPRINT_PROP_BOOL([libkmod support], $value)
1318
1319 # LTTng-UST enabled/disabled
1320 test "x$with_lttng_ust" = "xyes" && value=1 || value=0
1321 PPRINT_PROP_BOOL([LTTng-UST support], $value)
1322
1323 AS_ECHO
1324 PPRINT_SUBTITLE([Binaries])
1325
1326 # List binaries to be built
1327 test x$enable_bin_lttng != xno && value=1 || value=0
1328 PPRINT_PROP_BOOL([lttng], $value)
1329
1330 test x$enable_bin_lttng_consumerd != xno && value=1 || value=0
1331 PPRINT_PROP_BOOL([lttng-consumerd], $value)
1332
1333 test x$enable_bin_lttng_crash != xno && value=1 || value=0
1334 PPRINT_PROP_BOOL([lttng-crash], $value)
1335
1336 test x$enable_bin_lttng_relayd != xno && value=1 || value=0
1337 PPRINT_PROP_BOOL([lttng-relayd], $value)
1338
1339 test x$enable_bin_lttng_sessiond != xno && value=1 || value=0
1340 PPRINT_PROP_BOOL([lttng-sessiond], $value)
1341
1342 # Extras
1343 test x$enable_extras != xno && value=1 || value=0
1344 AS_ECHO
1345 PPRINT_SET_INDENT(0)
1346 PPRINT_PROP_BOOL([Extras], $value, $PPRINT_COLOR_SUBTITLE)
1347 PPRINT_SET_INDENT(1)
1348
1349 AS_ECHO
1350 PPRINT_SUBTITLE([Tests])
1351
1352 # Print clear message that tests won't be built
1353 AS_IF([test "x$build_tests" = "xno"],[
1354         PPRINT_WARN([Tests won't be built since some binaries were disabled])
1355 ])
1356
1357 # LTTng UST Java agent JUL tests enabled/disabled
1358 test "x$test_java_agent_jul" = "xyes" && value=1 || value=0
1359 PPRINT_PROP_BOOL([LTTng-UST Java agent JUL tests], $value)
1360
1361 # LTTng UST Java agent Log4j 1.x tests enabled/disabled
1362 test "x$test_java_agent_log4j" = "xyes" && value=1 || value=0
1363 PPRINT_PROP_BOOL([LTTng-UST Java agent Log4j 1.x tests], $value)
1364
1365 # LTTng UST Java agent Log4j 2.x tests enabled/disabled
1366 test "x$test_java_agent_log4j2" = "xyes" && value=1 || value=0
1367 PPRINT_PROP_BOOL([LTTng-UST Java agent Log4j 2.x tests], $value)
1368
1369 test ! -z "$PYTHON2_AGENT" && value=1 || value=0
1370 PPRINT_PROP_BOOL([LTTng-UST Python2 agent tests], $value)
1371
1372 test ! -z "$PYTHON3_AGENT" && value=1 || value=0
1373 PPRINT_PROP_BOOL([LTTng-UST Python3 agent tests], $value)
1374
1375 # userspace-probe SDT instrumentation tests enabled/disabled
1376 test "x$test_sdt_uprobe" = "xyes" && value=1 || value=0
1377 PPRINT_PROP_BOOL([LTTng-modules SDT uprobe tests], $value)
1378
1379 #Python binding enabled/disabled
1380 test "x$enable_python_binding" = xyes && value=1 || value=0
1381 AS_ECHO
1382 PPRINT_SET_INDENT(0)
1383 PPRINT_PROP_BOOL([Python binding], $value, $PPRINT_COLOR_SUBTITLE)
1384
1385 # man pages build enabled/disabled
1386 m4_pushdef([build_man_pages_msg], [Build and install man pages])
1387
1388 AS_IF([test "x$man_pages_opt" != "xno"], [
1389         AS_IF([test "x$in_git_repo" = "xyes"], [
1390                 PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
1391         ], [
1392                 AS_IF([test "x$have_asciidoc_xmlto" = "xyes"], [
1393                         PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
1394                 ], [
1395                         PPRINT_PROP_STRING([build_man_pages_msg],
1396                                 [${PPRINT_COLOR_BLDGRN}yes (already built)],
1397                                 $PPRINT_COLOR_SUBTITLE)
1398                 ])
1399         ])
1400 ], [
1401         PPRINT_PROP_BOOL([build_man_pages_msg], 0, $PPRINT_COLOR_SUBTITLE)
1402 ])
1403
1404 m4_popdef([build_man_pages_msg])
1405
1406 test "x$embedded_help" = xyes && value=1 || value=0
1407 PPRINT_PROP_BOOL([Embed --help messages], $value, $PPRINT_COLOR_SUBTITLE)
1408
1409 PPRINT_SET_INDENT(1)
1410
1411 report_bindir="`eval eval echo $bindir`"
1412 report_libdir="`eval eval echo $libdir`"
1413
1414 # Print the bindir and libdir this `make install' will install into.
1415 AS_ECHO
1416 PPRINT_SUBTITLE([Install directories])
1417 PPRINT_PROP_STRING([Binaries], [$report_bindir])
1418 PPRINT_PROP_STRING([Libraries], [$report_libdir])
1419
1420 AS_ECHO
1421 PPRINT_SUBTITLE([Search directories])
1422
1423 # If we build the sessiond, print the paths it will use
1424 AS_IF([test "$SESSIOND_BIN" = ""],[
1425         path="$report_bindir/lttng-sessiond"
1426 ],[
1427         path="$SESSIOND_BIN"
1428 ])
1429 PPRINT_PROP_STRING([lttng-sessiond executable], [$path])
1430
1431 AS_IF([test "$CONSUMERD32_BIN" = ""],[
1432         path="`eval eval echo $lttnglibexecdir`/lttng-consumerd"
1433 ],[
1434         path="$CONSUMERD32_BIN"
1435 ])
1436 PPRINT_PROP_STRING([32-bit lttng-consumerd executable], [$path])
1437
1438 AS_IF([test "$CONSUMERD32_LIBDIR" = ""],[
1439         path="`eval eval echo $libdir`"
1440 ],[
1441         path="$CONSUMERD32_LIBDIR"
1442 ])
1443 PPRINT_PROP_STRING([32-bit consumer libraries], [$path])
1444
1445 AS_IF([test "$CONSUMERD64_BIN" = ""],[
1446         path="`eval eval echo $lttnglibexecdir`/lttng-consumerd"
1447 ],[
1448         path="$CONSUMERD64_BIN"
1449 ])
1450 PPRINT_PROP_STRING([64-bit lttng-consumerd executable], [$path])
1451
1452 AS_IF([test "$CONSUMERD64_LIBDIR" = ""],[
1453         path="`eval eval echo $libdir`"
1454 ],[
1455         path="$CONSUMERD64_LIBDIR"
1456 ])
1457 PPRINT_PROP_STRING([64-bit consumer libraries], [$path])
1458 PPRINT_SET_INDENT(0)
1459
1460 AS_IF([test "x$warn_prebuilt_man_pages" = "xyes" ], [
1461         AS_ECHO
1462         PPRINT_WARN([You need asciidoc and xmlto to build the LTTng-tools man pages.
1463
1464 Note that the man pages are already built in this distribution tarball,
1465 therefore asciidoc and xmlto are only needed if you intend to modify
1466 their sources.
1467
1468 Also note that the installed man pages will contain the project's
1469 default command-line option and environment variable values.
1470
1471 Use --disable-man-pages to completely disable building and installing
1472 the man pages.])
1473 ])