configure.ac

   1 dnl SPDX-License-Identifier: GPL-2.0-only
   2 AC_PREREQ([2.64])
   3 AC_INIT([lttng-tools],[2.14.0-pre],[jeremie.galarneau@efficios.com],[],[https://lttng.org])
   4
   5 AC_CONFIG_HEADERS([include/config.h])
   6 AC_CONFIG_AUX_DIR([config])
   7 AC_CONFIG_MACRO_DIR([m4])
   8
   9 AC_CANONICAL_TARGET
  10 AC_CANONICAL_HOST
  11
  12 AM_INIT_AUTOMAKE([1.12 foreign dist-bzip2 no-dist-gzip tar-pax nostdinc])
  13 AM_MAINTAINER_MODE([enable])
  14
  15 # Enable silent rules if available (Introduced in AM 1.11)
  16 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  17
  18
  19 ##                   ##
  20 ## C compiler checks ##
  21 ##                   ##
  22
  23 # Choose the C compiler
  24 AC_PROG_CC
  25 # AC_PROG_CC_STDC was merged in AC_PROG_CC in autoconf 2.70
  26 m4_version_prereq([2.70], [], [AC_PROG_CC_STDC])
  27
  28 # Make sure the C compiler supports C99
  29 AS_IF([test "$ac_cv_prog_cc_c99" = "no"], [AC_MSG_ERROR([The compiler does not support C99])])
  30
  31 # Enable available system extensions and LFS support
  32 AC_USE_SYSTEM_EXTENSIONS
  33 AC_SYS_LARGEFILE
  34
  35 # Make sure the C compiler supports __attribute__
  36 AX_C___ATTRIBUTE__
  37 AS_IF([test "x$ax_cv___attribute__" != "xyes"],
  38   [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
  39
  40 # Make sure we have pthread support
  41 AX_PTHREAD([], [AC_MSG_ERROR([Could not configure pthread support])])
  42
  43 # Checks for typedefs, structures, and compiler characteristics.
  44 AC_C_INLINE
  45 AC_TYPE_INT32_T
  46 AC_TYPE_INT64_T
  47 AC_TYPE_MODE_T
  48 AC_TYPE_OFF_T
  49 AC_TYPE_PID_T
  50 AC_TYPE_SIZE_T
  51 AC_TYPE_SSIZE_T
  52 AC_TYPE_UID_T
  53 AC_TYPE_UINT16_T
  54 AC_TYPE_UINT32_T
  55 AC_TYPE_UINT64_T
  56 AC_TYPE_UINT8_T
  57
  58 # Detect warning flags supported by the C and C++ compilers and append them to
  59 # WARN_CFLAGS and WARN_CXXFLAGS.
  60 m4_define([WARN_FLAGS_COMMON_LIST], [ dnl
  61   -Wall dnl
  62   -Wextra dnl
  63   -Wmissing-declarations dnl
  64   -Wnull-dereference dnl
  65   -Wundef dnl
  66   -Wredundant-decls dnl
  67   -Wshadow dnl
  68   -Wsuggest-attribute=format dnl
  69   -Wtautological-constant-out-of-range-compare dnl Clang specific
  70   -Wwrite-strings dnl
  71   -Wformat=2 dnl
  72   -Wstrict-aliasing dnl
  73   -Wmissing-noreturn dnl
  74   -Wduplicated-cond dnl
  75   -Wduplicated-branches dnl
  76   -Wlogical-op dnl
  77   -Winit-self dnl
  78   dnl We currently get this warning when building with Clang:
  79   dnl
  80   dnl /usr/include/setjmp.h:54:12: error: declaration of built-in function '__sigsetjmp' requires the declaration of the 'jmp_buf' type, commonly provided in the header <setjmp.h>. [-Werror,-Wincomplete-setjmp-declaration]
  81   dnl extern int __sigsetjmp (struct __jmp_buf_tag __env[1], int __savemask) __THROWNL;
  82   dnl            ^
  83   -Wno-incomplete-setjmp-declaration dnl
  84   -Wno-gnu-folding-constant dnl Clang specific
  85 ])
  86
  87 # Detect warning flags specific to the C compiler and append them to
  88 # WARN_CFLAGS.
  89 m4_define([WARN_FLAGS_C_LIST], [ dnl
  90   -Wdiscarded-qualifiers dnl
  91   -Wmissing-prototypes dnl
  92   -Wmissing-parameter-type dnl
  93   -Wsuggest-final-types dnl
  94   -Wsuggest-final-methods dnl
  95   -Wsuggest-override dnl
  96 ])
  97
  98 # Pass -Werror as an extra flag during the test: this is needed to make the
  99 # -Wunknown-warning-option diagnostic fatal with clang.
 100 AC_LANG_PUSH([C])
 101 AX_APPEND_COMPILE_FLAGS([WARN_FLAGS_COMMON_LIST WARN_FLAGS_C_LIST], [WARN_CFLAGS], [-Werror])
 102 AC_LANG_POP([C])
 103
 104 # The test used in AX_APPEND_COMPILE_FLAGS, generated using AC_LANG_PROGRAM, is
 105 # written in such a way that it triggers warnings with the following warning
 106 # flags.  So they would always end up disabled if we put them there, because
 107 # the test program would not build.
 108 #
 109 # Enable them here unconditionally.  They are supported by GCC >= 4.8 and by
 110 # Clang >= 3.3 (required by the project) and are only valid for C code.
 111 WARN_CFLAGS="${WARN_CFLAGS} -Wold-style-definition -Wstrict-prototypes"
 112
 113 # Disable 'strict aliasing' if the C compiler supports it.
 114 AC_LANG_PUSH([C])
 115 AX_APPEND_COMPILE_FLAGS([-fno-strict-aliasing], [OPT_CFLAGS], [-Werror])
 116 AC_LANG_POP([C])
 117
 118
 119 ##                     ##
 120 ## C++ compiler checks ##
 121 ##                     ##
 122
 123 # Find a C++11 compiler with GNU extensions (-std=gnu++11)
 124 AX_CXX_COMPILE_STDCXX([11], [ext], [mandatory])
 125
 126 # Detect warning flags specific to the C++ compiler and append them to
 127 # WARN_CXXFLAGS.
 128 m4_define([WARN_FLAGS_CXX_LIST], [ dnl
 129   dnl GCC enables this with -Wall in C++, and that generates a
 130   dnl lot of warnings that have on average a low value to fix.
 131   -Wno-sign-compare dnl
 132 ])
 133
 134 # Pass -Werror as an extra flag during the test: this is needed to make the
 135 # -Wunknown-warning-option diagnostic fatal with clang.
 136 AC_LANG_PUSH([C++])
 137 AX_APPEND_COMPILE_FLAGS([WARN_FLAGS_COMMON_LIST WARN_FLAGS_CXX_LIST], [WARN_CXXFLAGS], [-Werror])
 138 AC_LANG_POP([C++])
 139
 140 # Disable 'strict aliasing' if the C++ compiler supports it.
 141 AC_LANG_PUSH([C++])
 142 AX_APPEND_COMPILE_FLAGS([-fno-strict-aliasing], [OPT_CXXFLAGS], [-Werror])
 143 AC_LANG_POP([C++])
 144
 145
 146 # When given, add -Werror to WARN_CFLAGS and WARN_CXXFLAGS.
 147 AC_ARG_ENABLE([Werror],[
 148   AS_HELP_STRING([--enable-Werror], [Treat compiler warnings as errors.])
 149 ])
 150
 151 AS_IF([test "x$enable_Werror" = "xyes"], [
 152   WARN_CFLAGS="${WARN_CFLAGS} -Werror"
 153   WARN_CXXFLAGS="${WARN_CXXFLAGS} -Werror"
 154 ])
 155
 156 # Checks for programs.
 157 AC_PROG_GREP
 158 AC_PROG_MAKE_SET
 159 AC_PROG_SED
 160 AC_PATH_PROG([report_fold], [fold])
 161 LT_INIT
 162
 163 # Check for objcopy, required by the base address statedump and dynamic linker tests
 164 AC_CHECK_TOOL([OBJCOPY], [objcopy])
 165 AS_IF([test "x$OBJCOPY" = "x"],
 166         [AC_MSG_WARN([Cannot find objcopy. The base address statedump and dynamic linker tests will be disabled. Install the binutils package to remediate this.])]
 167 )
 168 AM_CONDITIONAL([HAVE_OBJCOPY], [test "x$OBJCOPY" != "x"])
 169
 170 # check for pgrep
 171 AC_PATH_PROG([PGREP], [pgrep])
 172 AM_CONDITIONAL([HAVE_PGREP], [test "x$PGREP" != "x"])
 173
 174 AC_PATH_PROG([SHELLCHECK], [shellcheck])
 175 AM_CONDITIONAL([HAVE_SHELLCHECK], [test "x$SHELLCHECK" != "x"])
 176
 177 # set $IN_GIT_REPO if we're in the Git repository; the `bootstrap` file
 178 # is not distributed in tarballs
 179 AS_IF([test -f "$srcdir/bootstrap"], [in_git_repo=yes], [in_git_repo=no])
 180 AM_CONDITIONAL([IN_GIT_REPO], [test "x$in_git_repo" = "xyes"])
 181
 182 # check for bison
 183 AC_PROG_YACC
 184 BISON=$YACC
 185 AX_PROG_BISON_VERSION([2.4], [have_bison=yes])
 186
 187 AS_IF([test "x$have_bison" != "xyes"], [
 188   AS_IF([test "x$in_git_repo" = "xyes"], [
 189     AC_MSG_FAILURE([
 190 Bison >= 2.4 is required when building from the Git repository. You can
 191 set the YACC variable to override automatic detection.
 192     ])
 193   ], [
 194     AC_MSG_WARN([
 195 Missing Bison >= 2.4. Note that the parser files are already built in
 196 this distribution tarball, so Bison is only needed if you intend to
 197 modify their sources. You can set the YACC variable to override automatic
 198 detection.
 199     ])
 200   ])
 201 ])
 202 AM_CONDITIONAL([HAVE_BISON], [test "x$have_bison" = "xyes"])
 203
 204 # check for flex
 205 # Prior to autoconf 2.70, AC_PROG_FLEX did not take an argument. This is not a
 206 # problem since the argument is silently ignored by older versions.
 207 AC_PROG_LEX([noyywrap])
 208 FLEX=$LEX
 209 AX_PROG_FLEX_VERSION([2.5.35], [have_flex=yes])
 210
 211 AS_IF([test "x$have_flex" != "xyes"], [
 212   AS_IF([test "x$in_git_repo" = "xyes"], [
 213     AC_MSG_FAILURE([
 214 Flex >= 2.5.35 is required when building from the Git repository. You can
 215 set the LEX variable to override automatic detection.
 216     ])
 217   ], [
 218     AC_MSG_WARN([
 219 Missing Flex >= 2.5.35. Note that the lexer files are already built in
 220 this distribution tarball, so Flex is only needed if you intend to
 221 modify their sources. You can set the LEX variable to override automatic
 222 detection.
 223     ])
 224   ])
 225 ])
 226 AM_CONDITIONAL([HAVE_FLEX], [test "x$have_flex" = "xyes"])
 227
 228
 229
 230 # Check if linker has the -no-pie option.
 231 AX_CHECK_LINK_FLAG([-no-pie], [linker_have_no_pie_option=yes])
 232 AM_CONDITIONAL([LINKER_HAVE_NO_PIE_OPTION], [test "x$linker_have_no_pie_option" = "xyes"])
 233
 234 AX_LIB_SOCKET_NSL
 235
 236 LT_NO_UNDEFINED=""
 237 AS_CASE([$host_os],
 238   [cygwin*],
 239     [
 240       LT_NO_UNDEFINED="-no-undefined"
 241     ],
 242   [cygwin*|darwin*|mingw*|solaris*],
 243     [
 244       # On platforms where we only support the relayd, disable the other binaries by default
 245       AS_IF([test "x$enable_bin_lttng" = "x" ], [enable_bin_lttng=no])
 246       AS_IF([test "x$enable_bin_lttng_consumerd" = "x" ], [enable_bin_lttng_consumerd=no])
 247       AS_IF([test "x$enable_bin_lttng_crash" = "x" ], [enable_bin_lttng_crash=no])
 248       AS_IF([test "x$enable_bin_lttng_sessiond" = "x" ], [enable_bin_lttng_sessiond=no])
 249       AS_IF([test "x$enable_extras" = "x" ], [enable_extras=no])
 250       AS_IF([test "x$with_lttng_ust" = "x" ], [with_lttng_ust=no])
 251     ]
 252 )
 253
 254 AC_SUBST(LT_NO_UNDEFINED)
 255
 256 # Compute minor/major/patchlevel version numbers
 257 major_version=$(echo AC_PACKAGE_VERSION | $SED 's/^\([[0-9]]\)*\.[[0-9]]*\.[[0-9]]*.*$/\1/')
 258 minor_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.\([[0-9]]*\)\.[[0-9]]*.*$/\1/')
 259 patchlevel_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\).*$/\1/')
 260
 261 AC_SUBST([MAJOR_VERSION], [$major_version])
 262 AC_SUBST([MINOR_VERSION], [$minor_version])
 263 AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version])
 264 AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [LTTng-Tools major version number])
 265 AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [LTTng-Tools minor version number])
 266 AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [LTTng-Tools patchlevel version number])
 267
 268 version_name="O-Beer"
 269 version_description="An alcoholic drink made from yeast-fermented malt flavored with hops."
 270 version_description_c=$(echo $version_description | $SED 's/"/\\"/g')
 271
 272 AC_DEFINE_UNQUOTED([VERSION_NAME], ["$version_name"], "")
 273 AC_DEFINE_UNQUOTED([VERSION_DESCRIPTION], ["$version_description_c"], "")
 274
 275 # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
 276 AC_ARG_ENABLE(libtool-linkdep-fixup,
 277         AS_HELP_STRING([--disable-libtool-linkdep-fixup],
 278                         [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)]),
 279         libtool_fixup=$enableval,
 280         libtool_fixup=yes)
 281
 282 AS_IF([test "x$libtool_fixup" = "xyes"],
 283             [
 284             libtool_m4="$srcdir/m4/libtool.m4"
 285             libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
 286             AC_MSG_CHECKING([for occurrence(s) of link_all_deplibs = no in $libtool_m4])
 287             libtool_flag_pattern_count=$($GREP -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
 288             AS_IF([test $libtool_flag_pattern_count -ne 0],
 289             [
 290                   AC_MSG_RESULT([$libtool_flag_pattern_count])
 291                   AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
 292                   $SED -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
 293                   ],
 294                   [
 295                   AC_MSG_RESULT([none])
 296                   ])
 297             ])
 298
 299 AM_CONDITIONAL([NO_SHARED], [test x$enable_shared = xno])
 300
 301 AC_CHECK_HEADERS([ \
 302         sys/types.h unistd.h fcntl.h string.h pthread.h limits.h \
 303         signal.h stdlib.h sys/un.h sys/socket.h stdlib.h stdio.h \
 304         getopt.h sys/ipc.h sys/shm.h popt.h grp.h arpa/inet.h \
 305         netdb.h netinet/in.h paths.h stddef.h sys/file.h sys/ioctl.h \
 306         sys/mount.h sys/param.h sys/time.h elf.h sys/random.h sys/syscall.h
 307 ])
 308
 309 AM_CONDITIONAL([HAVE_ELF_H], [test x$ac_cv_header_elf_h = xyes])
 310
 311 # Basic functions check
 312 AC_CHECK_FUNCS([ \
 313         atexit bzero clock_gettime dup2 fdatasync fls ftruncate \
 314         gethostbyname gethostname getpagesize localtime_r memchr memrchr memset \
 315         mkdir munmap putenv realpath rmdir socket strchr strcspn strdup \
 316         strncasecmp strndup strnlen strpbrk strrchr strstr strtol strtoul \
 317         strtoull dirfd gethostbyname2 getipnodebyname epoll_create1 \
 318         sched_getcpu sysconf sync_file_range getrandom
 319 ])
 320
 321 # Check for pthread_setname_np and pthread_getname_np
 322 LTTNG_PTHREAD_SETNAME_NP
 323 LTTNG_PTHREAD_GETNAME_NP
 324
 325 # Check if clock_gettime, timer_create, timer_settime, and timer_delete are available in lib rt, and if so,
 326 # add -lrt to LIBS
 327 AC_CHECK_LIB([rt], [clock_gettime, timer_create, timer_settime, timer_delete])
 328
 329 # Checks for dl.
 330 AC_CHECK_LIB([dl], [dlopen], [
 331         have_libdl=yes
 332         libdl_name=dl
 333         DL_LIBS="-ldl"
 334 ], [
 335         # libdl not found, check for dlopen in libc.
 336         AC_CHECK_LIB([c], [dlopen], [
 337                 have_libc_dl=yes
 338                 libdl_name=c
 339                 DL_LIBS="-lc"
 340         ], [
 341                 AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
 342         ])
 343 ])
 344 AC_SUBST(DL_LIBS)
 345
 346 # Check if libdl has dlmopen support.
 347 AH_TEMPLATE([HAVE_DLMOPEN], ["Define to 1 if dlmopen is available."])
 348 AC_CHECK_LIB([$libdl_name], [dlmopen], [
 349         AC_DEFINE([HAVE_DLMOPEN], [1])
 350         HAVE_DLMOPEN=1
 351 ], [
 352         HAVE_DLMOPEN=0
 353 ])
 354 AC_SUBST(HAVE_DLMOPEN)
 355
 356 # Babeltrace viewer check
 357 AC_ARG_WITH([babeltrace-bin],
 358         AS_HELP_STRING([--with-babeltrace-bin],
 359         [Location of the babeltrace viewer executable (including the filename)]),
 360         [BABELTRACE_BIN="$withval"],
 361         [BABELTRACE_BIN=''])
 362 AC_SUBST([BABELTRACE_BIN])
 363
 364 AC_ARG_WITH([babeltrace2-bin],
 365         AS_HELP_STRING([--with-babeltrace2-bin],
 366         [Location of the babeltrace2 viewer executable (including the filename)]),
 367         [BABELTRACE2_BIN="$withval"],
 368         [BABELTRACE2_BIN=''])
 369 AC_SUBST([BABELTRACE2_BIN])
 370
 371 AC_ARG_WITH([consumerd32-bin],
 372         AS_HELP_STRING([--with-consumerd32-bin],
 373         [Location of the 32-bit consumerd executable (including the filename)]),
 374         [CONSUMERD32_BIN="$withval"],
 375         [CONSUMERD32_BIN=''])
 376 AC_SUBST([CONSUMERD32_BIN])
 377
 378 AC_ARG_WITH([consumerd64-bin],
 379         AS_HELP_STRING([--with-consumerd64-bin],
 380         [Location of the 64-bit consumerd executable (including the filename)]),
 381         [CONSUMERD64_BIN="$withval"],
 382         [CONSUMERD64_BIN=''])
 383 AC_SUBST([CONSUMERD64_BIN])
 384
 385 AC_ARG_WITH([consumerd32-libdir],
 386         AS_HELP_STRING([--with-consumerd32-libdir],
 387         [Directory containing the 32-bit consumerd libraries]),
 388         [CONSUMERD32_LIBDIR="$withval"],
 389         [CONSUMERD32_LIBDIR=''])
 390 AC_SUBST([CONSUMERD32_LIBDIR])
 391
 392 AC_ARG_WITH([consumerd64-libdir],
 393         AS_HELP_STRING([--with-consumerd64-libdir],
 394         [Directory containing the 64-bit consumerd libraries]),
 395         [CONSUMERD64_LIBDIR="$withval"],
 396         [CONSUMERD64_LIBDIR=''])
 397 AC_SUBST([CONSUMERD64_LIBDIR])
 398
 399 AC_ARG_WITH([sessiond-bin],
 400         AS_HELP_STRING([--with-sessiond-bin],
 401         [Location of the sessiond executable (including the filename)]),
 402         [SESSIOND_BIN="$withval"],
 403         [SESSIOND_BIN=''])
 404 AC_SUBST([SESSIOND_BIN])
 405
 406 AC_ARG_WITH([lttng-system-rundir],
 407         AS_HELP_STRING([--with-lttng-system-rundir],
 408         [Location of the system directory where the system-wide lttng-sessiond runtime files are kept. The default is "/var/run/lttng".]),
 409         [LTTNG_SYSTEM_RUNDIR="$withval"],
 410         [LTTNG_SYSTEM_RUNDIR="/var/run/lttng"])
 411 AC_SUBST([LTTNG_SYSTEM_RUNDIR])
 412
 413 AC_ARG_ENABLE([test-java-agent-jul],
 414         [AS_HELP_STRING([--enable-test-java-agent-jul],[enable the LTTng UST Java agent JUL tests [default=no]])],
 415         [test_java_agent_jul=$enableval],
 416         [test_java_agent_jul=no]
 417 )
 418
 419 AC_ARG_ENABLE([test-java-agent-log4j],
 420         [AS_HELP_STRING([--enable-test-java-agent-log4j],[enable the LTTng UST Java agent Log4j 1.x tests [default=no]])],
 421         [test_java_agent_log4j=$enableval],
 422         [test_java_agent_log4j=no]
 423 )
 424
 425 AC_ARG_ENABLE([test-java-agent-log4j2],
 426         [AS_HELP_STRING([--enable-test-java-agent-log4j2],[enable the LTTng UST Java agent Log4j 2.x tests [default=no]])],
 427         [test_java_agent_log4j2=$enableval],
 428         [test_java_agent_log4j2=no]
 429 )
 430
 431 AC_ARG_ENABLE([test-java-agent-all],
 432         [AS_HELP_STRING([--enable-test-java-agent-all],[enable all the LTTng UST Java agent tests [default=no]])],
 433         [test_java_agent_jul=$enableval
 434          test_java_agent_log4j=$enableval
 435          test_java_agent_log4j2=$enableval],
 436         [:]
 437 )
 438
 439 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_BIN], "$CONSUMERD32_BIN", [Location of the 32-bit consumerd executable.])
 440 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_BIN], "$CONSUMERD64_BIN", [Location of the 64-bit consumerd executable])
 441 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_LIBDIR], "$CONSUMERD32_LIBDIR", [Search for consumerd 32-bit libraries in this location.])
 442 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_LIBDIR], "$CONSUMERD64_LIBDIR", [Search for consumerd 64-bit libraries in this location.])
 443 AC_DEFINE_UNQUOTED([CONFIG_BABELTRACE_BIN], "$BABELTRACE_BIN", [Location of the babeltrace viewer executable.])
 444 AC_DEFINE_UNQUOTED([CONFIG_BABELTRACE2_BIN], "$BABELTRACE2_BIN", [Location of the babeltrace2 viewer executable.])
 445 AC_DEFINE_UNQUOTED([CONFIG_SESSIOND_BIN], "$SESSIOND_BIN", [Location of the sessiond executable.])
 446 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_RUNDIR], ["$LTTNG_SYSTEM_RUNDIR"], [LTTng system runtime directory])
 447
 448 AC_DEFUN([_AC_DEFINE_AND_SUBST], [
 449         AC_DEFINE_UNQUOTED([CONFIG_$1], [$2], [$1])
 450         $1="$2"
 451         AC_SUBST([$1])
 452 ])
 453
 454 AC_DEFUN([_AC_DEFINE_QUOTED_AND_SUBST], [
 455         AC_DEFINE_UNQUOTED([CONFIG_$1], ["$2"], [$1])
 456         $1="$2"
 457         AC_SUBST([$1])
 458 ])
 459
 460 # Default values
 461 m4_define([_DEFAULT_CHANNEL_SUBBUF_SIZE], [16384])
 462 m4_define([_DEFAULT_CHANNEL_SUBBUF_NUM], [4])
 463 m4_define([_DEFAULT_CHANNEL_SWITCH_TIMER], [0])
 464 m4_define([_DEFAULT_CHANNEL_LIVE_TIMER], [0])
 465 m4_define([_DEFAULT_CHANNEL_READ_TIMER], [200000])
 466 m4_define([_DEFAULT_CHANNEL_MONITOR_TIMER], [1000000])
 467 m4_define([_DEFAULT_CHANNEL_BLOCKING_TIMEOUT], [0])
 468 _AC_DEFINE_AND_SUBST([DEFAULT_AGENT_TCP_PORT_RANGE_BEGIN], [5345])
 469 _AC_DEFINE_AND_SUBST([DEFAULT_AGENT_TCP_PORT_RANGE_END], [5354])
 470 _AC_DEFINE_AND_SUBST([DEFAULT_APP_SOCKET_RW_TIMEOUT], [5])
 471 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE])
 472 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_COUNT], [0])
 473 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_SIZE], [0])
 474 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 475 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_READ_TIMER], [_DEFAULT_CHANNEL_READ_TIMER])
 476 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 477 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_SIZE], [1048576])
 478 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 479 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
 480 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_BLOCKING_TIMEOUT], [_DEFAULT_CHANNEL_BLOCKING_TIMEOUT])
 481 _AC_DEFINE_AND_SUBST([DEFAULT_LTTNG_LIVE_TIMER], [1000000])
 482 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_CACHE_SIZE], [4096])
 483 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_READ_TIMER], [0])
 484 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_NUM], [2])
 485 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_SIZE], [4096])
 486 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 487 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_CONTROL_PORT], [5342])
 488 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_DATA_PORT], [5343])
 489 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_VIEWER_PORT], [5344])
 490 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 491 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_READ_TIMER], [0])
 492 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_BLOCKING_TIMEOUT], [0])
 493 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 494 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE])
 495 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 496 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
 497 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 498 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_READ_TIMER], [0])
 499 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_BLOCKING_TIMEOUT], [0])
 500 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 501 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_SIZE], [524288])
 502 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 503 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
 504 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_AGENT_BIND_ADDRESS], [localhost])
 505 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_CONTROL_BIND_ADDRESS], [0.0.0.0])
 506 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_DATA_BIND_ADDRESS], [0.0.0.0])
 507 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_VIEWER_BIND_ADDRESS], [localhost])
 508 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_RELAYD_CTRL_MAX_PAYLOAD_SIZE], [134217728])
 509 _AC_DEFINE_AND_SUBST([DEFAULT_ROTATE_PENDING_TIMER], [500000])
 510 _AC_DEFINE_AND_SUBST([DEFAULT_EVENT_NOTIFIER_ERROR_COUNT_MAP_SIZE], [4096])
 511
 512 # Command short descriptions
 513 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ADD_CONTEXT], [Add context fields to be recorded])
 514 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ADD_TRIGGER], [Add a trigger])
 515 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_CLEAR], [Clear a recording session])
 516 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_CREATE], [Create a recording session])
 517 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DESTROY], [Destroy recording sessions])
 518 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_CHANNEL], [Disable channels])
 519 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_EVENT], [Disable recording event rules])
 520 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_ROTATION], [Unset a recording session rotation schedule])
 521 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_CHANNEL], [Create or enable a channel])
 522 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_EVENT], [Create or enable recording event rules])
 523 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_ROTATION], [Set a recording session rotation schedule])
 524 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_HELP], [Show the help of a command])
 525 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LIST], [List recording sessions and instrumentation points])
 526 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LIST_TRIGGERS], [List triggers])
 527 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LOAD], [Load recording session configurations])
 528 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_REGENERATE], [Regenerate specific recording session data])
 529 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_REMOVE_TRIGGER], [Remove a trigger])
 530 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ROTATE], [Archive the current trace chunk of a recording session])
 531 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SAVE], [Save recording session configurations])
 532 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SET_SESSION], [Set the current recording session])
 533 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SNAPSHOT], [Take a recording session snapshot])
 534 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_START], [Start a recording session])
 535 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STATUS], [Show the status of the current recording session])
 536 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STOP], [Stop a recording session])
 537 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_TRACK], [Allow specific processes to record events])
 538 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_UNTRACK], [Disallow specific processes to record events])
 539 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VERSION], [Show LTTng-tools version information])
 540 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VIEW], [Launch a trace reader])
 541
 542 if test "x$prefix" = "xNONE"; then
 543         prefix=$ac_default_prefix
 544 fi
 545 CONFDIR=`eval echo $sysconfdir`
 546 AC_SUBST(CONFDIR)
 547 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_CONFIGDIR],"$CONFDIR", [LTTng system configuration directory.])
 548
 549 AX_DEFINE_DIR([CONFIG_LTTNG_SYSTEM_DATADIR], [datadir], [LTTng system data directory.])
 550
 551 # Check libpopt
 552 PKG_CHECK_MODULES([POPT], [popt],
 553   [
 554     dnl PKG_CHECK_MODULES defines POPT_LIBS
 555   ],
 556   [
 557     AC_MSG_WARN([pkg-config was unable to find a valid .pc for libpopt. Set PKG_CONFIG_PATH to specify the pkgconfig configuration file location])
 558     AC_MSG_WARN([Finding libpopt without pkg-config.])
 559     AC_CHECK_LIB([popt],
 560       [poptGetContext],
 561       [POPT_LIBS="-lpopt"],
 562       [
 563         AC_MSG_FAILURE([Cannot find libpopt. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location])
 564       ]
 565     )
 566   ]
 567 )
 568 AC_SUBST(POPT_LIBS)
 569
 570 PKG_CHECK_MODULES([libxml2], [libxml-2.0 >= 2.7.6])
 571
 572 AC_CHECK_FUNC([clock_gettime], [AC_DEFINE_UNQUOTED([LTTNG_HAVE_CLOCK_GETTIME], 1, [Has clock_gettime() support.])])
 573
 574 # URCU library version needed or newer
 575 PKG_CHECK_MODULES([URCU], [liburcu >= 0.14])
 576 PKG_CHECK_MODULES([URCU_CDS], [liburcu-cds >= 0.14])
 577 AM_CPPFLAGS="$AM_CPPFLAGS $URCU_CFLAGS"
 578
 579 # Check for libkmod, it will be auto-neabled if found but won't fail if it's not,
 580 # it can be explicitly disabled with --without-kmod
 581 AH_TEMPLATE([HAVE_KMOD], [Define if you have kmod support])
 582 AC_ARG_WITH([kmod],
 583   [AS_HELP_STRING([--with-kmod], [build with lkmod support @<:@default=check@:>@])],
 584   [],
 585   [with_kmod=check]
 586 )
 587
 588 AS_IF([test "x$with_kmod" != "xno"],
 589   [
 590     AC_CHECK_LIB([kmod], [kmod_module_probe_insert_module],
 591       [
 592         AC_DEFINE([HAVE_KMOD], [1])
 593         KMOD_LIBS="-lkmod"
 594       ],
 595       [
 596         if test "x$with_kmod" != xcheck; then
 597           AC_MSG_FAILURE([Cannot find libkmod. Use [LDFLAGS]=-Ldir and [CPPFLAGS]=-Idir to specify its location.])
 598         else
 599           with_kmod=no
 600         fi
 601       ]
 602     )
 603   ]
 604 )
 605 AC_SUBST(KMOD_LIBS)
 606
 607 # Check for liblttng-ust-ctl, fail if it's not found,
 608 # it can be explicitly disabled with --without-lttng-ust
 609 AH_TEMPLATE([HAVE_LIBLTTNG_UST_CTL], [Define if you have LTTng-UST control support])
 610 AC_ARG_WITH([lttng-ust],
 611   [AS_HELP_STRING([--without-lttng-ust], [build without LTTng-UST (Userspace Tracing) support])],
 612   [],
 613   [with_lttng_ust=yes]
 614 )
 615
 616 AS_IF([test "x$with_lttng_ust" = "xyes"], [
 617   AC_DEFINE([HAVE_LIBLTTNG_UST_CTL], [1])
 618
 619   # Check for liblttng-ust
 620   PKG_CHECK_MODULES([UST], [lttng-ust >= $major_version.$minor_version])
 621
 622   # Check for liblttng-ust-ctl
 623   PKG_CHECK_MODULES([UST_CTL], [lttng-ust-ctl >= $major_version.$minor_version])
 624
 625   AM_CPPFLAGS="$AM_CPPFLAGS $UST_CFLAGS"
 626 ])
 627
 628 AM_CONDITIONAL([HAVE_LIBLTTNG_UST_CTL], [test "x$with_lttng_ust" = "xyes"])
 629
 630
 631 # Check for fmemopen
 632 AC_CHECK_LIB([c], [fmemopen],
 633 [
 634         AC_DEFINE_UNQUOTED([LTTNG_HAVE_FMEMOPEN], 1, [Has fmemopen support.])
 635 ]
 636 )
 637
 638 # check for libpfm
 639 AC_CHECK_LIB([pfm], [pfm_initialize],
 640              [
 641               have_libpfm=yes
 642               ])
 643 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBPFM], [test "x$have_libpfm" = "xyes"])
 644
 645 # For Python
 646 # SWIG version needed or newer:
 647 swig_version=2.0.0
 648
 649 AC_ARG_ENABLE([python-bindings],
 650               [AS_HELP_STRING([--enable-python-bindings],
 651                               [compile Python bindings])],
 652               [enable_python_binding=$enableval], [enable_python_binding=no])
 653
 654 AM_CONDITIONAL([PYTHON_BINDING], [test "x$enable_python_binding" = xyes])
 655
 656 if test "x$enable_python_binding" = xyes; then
 657   AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ])
 658   AS_IF([test x$enable_shared = xno], [ AC_MSG_ERROR([Python bindings require shared libraries.]) ])
 659   AM_PATH_PYTHON([3.0])
 660
 661   AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config])
 662   AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
 663   AS_IF([test -z "$PYTHON_INCLUDE"], [
 664     AS_IF([test -z "$PYTHON_CONFIG"], [
 665       AC_PATH_PROGS([PYTHON_CONFIG],
 666                     [python$PYTHON_VERSION-config python-config],
 667                     [],
 668                     [`dirname $PYTHON`])
 669       AS_IF([test "x$PYTHON_CONFIG" = "x"], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
 670     ])
 671     AC_MSG_CHECKING([python include flags])
 672     PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
 673     AC_MSG_RESULT([$PYTHON_INCLUDE])
 674   ])
 675
 676 else
 677     AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl
 678 [if you want Python bindings.])
 679
 680 fi
 681
 682 # Epoll check. If not present, the build will fallback on poll() API
 683 AX_HAVE_EPOLL(
 684         [AX_CONFIG_FEATURE_ENABLE(epoll)],
 685         [AX_CONFIG_FEATURE_DISABLE(epoll)]
 686 )
 687 AX_CONFIG_FEATURE(
 688         [epoll], [This platform supports epoll(7)],
 689         [HAVE_EPOLL], [This platform supports epoll(7).]
 690 )
 691
 692 AS_IF([test "x$ac_cv_func_dirfd" = "xyes"],
 693         [AX_CONFIG_FEATURE_ENABLE(dirfd)],
 694         [AX_CONFIG_FEATURE_DISABLE(dirfd)]
 695 )
 696 AX_CONFIG_FEATURE(
 697         [dirfd], [Use directory file descriptors],
 698         [HAVE_DIRFD], [This platform supports directory file descriptors.]
 699 )
 700
 701 AM_CONDITIONAL([TEST_JAVA_JUL_AGENT], [test "x$test_java_agent_jul" = "xyes"])
 702 AM_CONDITIONAL([TEST_JAVA_LOG4J_AGENT], [test "x$test_java_agent_log4j" = "xyes"])
 703 AM_CONDITIONAL([TEST_JAVA_LOG4J2_AGENT], [test "x$test_java_agent_log4j2" = "xyes"])
 704
 705 if test "x$test_java_agent_jul" = "xyes" || test "x$test_java_agent_log4j" = "xyes" || test "x$test_java_agent_log4j2" = "xyes"; then
 706         AX_JAVA_OPTIONS
 707         AX_PROG_JAVAC
 708         AX_PROG_JAVA
 709         AX_PROG_JAR
 710
 711         AX_CHECK_CLASSPATH
 712
 713         # Check for Java UST agent common class first
 714         AX_CHECK_CLASS(org.lttng.ust.agent.AbstractLttngAgent)
 715         if test "x$ac_cv_class_org_lttng_ust_agent_AbstractLttngAgent" = "xno"; then
 716                 AC_MSG_ERROR([The UST Java agent common class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-common.jar"])
 717         fi
 718
 719         if test "x$test_java_agent_jul" = "xyes"; then
 720                 # Check for JUL agent class
 721                 AX_CHECK_CLASS(org.lttng.ust.agent.jul.LttngLogHandler)
 722                 if test "x$ac_cv_class_org_lttng_ust_agent_jul_LttngLogHandler" = "xno"; then
 723                         AC_MSG_ERROR([The UST Java agent JUL class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-jul.jar"])
 724                 fi
 725         fi
 726
 727         if test "x$test_java_agent_log4j" = "xyes"; then
 728                 # Check for Log4j agent class
 729                 AX_CHECK_CLASS(org.lttng.ust.agent.log4j.LttngLogAppender)
 730                 if test "x$ac_cv_class_org_lttng_ust_agent_log4j_LttngLogAppender" = "xno"; then
 731                         AC_MSG_ERROR([The UST Java agent Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-log4j.jar"])
 732                 fi
 733
 734                 # Check for Log4j class
 735                 AX_CHECK_CLASS(org.apache.log4j.Logger)
 736                 if test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"; then
 737                         AC_MSG_ERROR([The Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j.jar"])
 738                 fi
 739         fi
 740
 741         if test "x$test_java_agent_log4j2" = "xyes"; then
 742                 # Check for Log4j2 agent class
 743                 AX_CHECK_CLASS(org.lttng.ust.agent.log4j2.LttngLogAppender)
 744                 if test "x$ac_cv_class_org_lttng_ust_agent_log4j2_LttngLogAppender" = "xno"; then
 745                         AC_MSG_ERROR([The UST Java agent Log4j 2.x class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-log4j2.jar"])
 746                 fi
 747
 748                 # Check for Log4j 2.x classes
 749                 AX_CHECK_CLASS([org.apache.logging.log4j.Logger])
 750                 AX_CHECK_CLASS([org.apache.logging.log4j.core.Core])
 751                 if test "x$ac_cv_class_org_apache_logging_log4j_Logger" = "xno" || test "x$ac_cv_class_org_apache_logging_log4j_core_Core" = "xno"; then
 752                         AC_MSG_ERROR([The Log4j 2.x API or core class was not found. Please specify the location of the jars via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j-core.jar:/path/to/log4j-api.jar"])
 753                 fi
 754         fi
 755 fi
 756
 757 # enable building man pages (user's intention)
 758 AC_ARG_ENABLE(
 759         man-pages,
 760         AS_HELP_STRING(
 761                 [--disable-man-pages],
 762                 [Do not build and install man pages (already built in a distributed tarball)]
 763         ),
 764         [man_pages_opt=$enableval],
 765         [man_pages_opt=yes]
 766 )
 767
 768 # check for asciidoc and xmlto if we enabled building the man pages
 769 have_asciidoc_xmlto=no
 770 warn_prebuilt_man_pages=no
 771
 772 AS_IF([test "x$man_pages_opt" = "xyes"], [
 773         AC_PATH_PROG([ASCIIDOC], [asciidoc])
 774         AC_PATH_PROG([XMLTO], [xmlto])
 775
 776         AS_IF([test "x$ASCIIDOC" = "x" || test "x$XMLTO" = "x"], [
 777                 AS_IF([test "x$in_git_repo" = "xyes"], [
 778                         # this is an error because we're in the Git repo, which
 779                         # means the man pages are not already generated for us,
 780                         # thus asciidoc/xmlto are required because we were asked
 781                         # to build the man pages
 782                         AC_MSG_ERROR([
 783 You need asciidoc and xmlto to build the LTTng-tools man pages. Use
 784 --disable-man-pages to disable building the man pages, in which case
 785 they will not be installed.
 786                         ])
 787                 ], [
 788                         # only warn here: since we're in the tarball, the man
 789                         # pages should already be generated at this point, thus
 790                         # asciidoc/xmlto are not strictly required
 791                         warn_prebuilt_man_pages=yes
 792                 ])
 793         ], [
 794                 have_asciidoc_xmlto=yes
 795         ])
 796 ])
 797
 798 # export man page build condition: build the man pages if the user
 799 # asked for it, and if the tools are available
 800 AM_CONDITIONAL([MAN_PAGES_OPT], [test "x$man_pages_opt" != "xno"])
 801 AM_CONDITIONAL([HAVE_ASCIIDOC_XMLTO], [test "x$have_asciidoc_xmlto" = "xyes"])
 802
 803 AC_DEFINE_UNQUOTED([MANPATH], ["`eval eval echo $mandir`"], [Path to man pages.])
 804
 805 # embedded --help message
 806 AC_ARG_ENABLE(
 807         [embedded-help],
 808         AS_HELP_STRING(
 809                 [--enable-embedded-help],
 810                 [Embed the --help messages in the executable files]
 811         ),
 812         [embedded_help=$enableval],
 813         [embedded_help=no]
 814 )
 815 AS_IF([test "x$embedded_help" = "xyes"], [
 816         AS_IF([test "x$man_pages_opt" = "xno"], [
 817                 AC_MSG_ERROR([You need the --enable-man-pages option with the --enable-embedded-help option.])
 818         ])
 819         AC_PATH_PROG([man_prog_path], [man])
 820         AS_IF([test "x$man_prog_path" = "x"], [
 821                 AC_MSG_ERROR([You need man with the --enable-embedded-help option.])
 822         ])
 823         AC_DEFINE_UNQUOTED([LTTNG_EMBED_HELP], 1, [Embed --help messages.])
 824         AC_SUBST([MANPROG], [$man_prog_path])
 825 ])
 826 AM_CONDITIONAL([EMBED_HELP], [test "x$embedded_help" != "xno"])
 827
 828 # Python agent test
 829 UST_PYTHON_AGENT="lttngust"
 830
 831 AC_ARG_ENABLE(test-python2-agent,
 832         AS_HELP_STRING([--enable-test-python2-agent],
 833                 [enable tests for python2 agent. Python2 interpreter path can be overridden by setting the PYTHON2 environment variable. Default: Autodetect]
 834         ),[:],[test_python2_agent_autodetect=yes]
 835 )
 836
 837 AC_ARG_ENABLE(test-python3-agent,
 838         AS_HELP_STRING([--enable-test-python3-agent],
 839                 [enable tests for python3 agent. Python3 interpreter path can be overridden by setting the PYTHON3 environment variable. Default: Autodetect]
 840         ),[:],[test_python3_agent_autodetect=yes]
 841 )
 842
 843 AC_ARG_ENABLE(test-python-agent-all,
 844         AS_HELP_STRING([--enable-test-python-agent-all],
 845                 [enable test for all python{2/3} agent.]
 846         ),
 847 )
 848
 849 AS_IF([test ! -z "$enable_test_python_agent_all"], [
 850        unset test_python2_agent_autodetect
 851        unset test_python3_agent_autodetect
 852 ])
 853
 854 AS_IF([test "x$enable_test_python_agent_all" = "xyes"], [
 855        enable_test_python2_agent=yes
 856        enable_test_python3_agent=yes
 857 ])
 858
 859 AS_IF([test "x$enable_test_python_agent_all" = "xno"], [
 860        enable_test_python2_agent=no
 861        enable_test_python3_agent=no
 862 ])
 863
 864
 865 AS_IF([test "x$enable_test_python2_agent" = "xyes" -o "x$test_python2_agent_autodetect" = "xyes" ], [
 866         AS_IF([test -z "$PYTHON2"], [
 867                         PYTHON2=python2
 868                 ], [
 869                         AC_MSG_WARN([Using user-defined PYTHON2 ($PYTHON2) for lttng-ust python2 agent check])
 870         ])
 871
 872         AC_PATH_PROG([PYTHON2_BIN],[$PYTHON2])
 873         AS_IF([test -z "$PYTHON2_BIN"], [
 874                 AS_IF([test -z "$test_python2_agent_autodetect"],[
 875                         AC_MSG_ERROR([No python2 interpreter found. PYTHON2 can be set to override default interpreter path])
 876                 ])
 877         ], [
 878                 AC_MSG_CHECKING([for python2 lttng-ust agent])
 879                 AS_IF([$PYTHON2_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
 880                         PYTHON2_AGENT=$PYTHON2_BIN
 881                         AC_MSG_RESULT([yes])
 882                         RUN_PYTHON_AGENT_TEST=yes
 883                 ], [
 884                         AC_MSG_RESULT([no])
 885                         AS_IF([test -z "$test_python2_agent_autodetect"],[
 886                                 AC_MSG_ERROR([No python2 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
 887                         ])
 888                 ])
 889
 890         ])
 891
 892 ])
 893
 894 AS_IF([test "x$enable_test_python3_agent" = "xyes" -o "x$test_python3_agent_autodetect" = "xyes" ], [
 895         AS_IF([test -z "$PYTHON3"], [
 896                 PYTHON3=python3
 897         ], [
 898                 AC_MSG_WARN([Using user-defined PYTHON3 ($PYTHON3) for lttng-ust python3 agent check])
 899         ])
 900
 901         AC_PATH_PROG([PYTHON3_BIN],[$PYTHON3])
 902         AS_IF([test -z "$PYTHON3_BIN"], [
 903                 AS_IF([test -z "$test_python3_agent_autodetect"],[
 904                         AC_MSG_ERROR([No python3 interpreter found. PYTHON3 can be set to override default interpreter path])
 905                 ])
 906         ], [
 907                 AC_MSG_CHECKING([for python3 lttng-ust agent])
 908                 AS_IF([$PYTHON3_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
 909                         PYTHON3_AGENT=$PYTHON3_BIN
 910                         AC_MSG_RESULT([yes])
 911                         RUN_PYTHON_AGENT_TEST=yes
 912                 ], [
 913                         AC_MSG_RESULT([no])
 914                         AS_IF([test -z "$test_python3_agent_autodetect"],[
 915                                 AC_MSG_ERROR([No python3 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
 916                         ])
 917                 ])
 918
 919         ])
 920 ])
 921 AC_SUBST([RUN_PYTHON_AGENT_TEST])
 922 AC_SUBST([PYTHON2_AGENT])
 923 AC_SUBST([PYTHON3_AGENT])
 924
 925 AC_ARG_ENABLE([test-sdt-uprobe],
 926   [AS_HELP_STRING([--enable-test-sdt-uprobe], [enable the LTTng UST SDT uprobe tests [default=autodetect]])],
 927   [test_sdt_uprobe="$enableval"],
 928   [test_sdt_uprobe=autodetect]
 929 )
 930
 931 AS_IF([test "$test_sdt_uprobe" != "no"], [
 932   LTTNG_CHECK_SDT_WORKS
 933   AC_PATH_PROG([DTRACE], [dtrace])
 934 ])
 935
 936 AS_IF([test "$test_sdt_uprobe" = "yes"], [
 937   AS_IF([test "$lttng_cv_sdt_works" = "no"], [
 938     AC_MSG_ERROR([Cannot find 'sys/sdt.h'.])
 939   ])
 940   AS_IF([test "x$DTRACE" = "x"], [
 941     AC_MSG_ERROR([Cannot find SystemTap dtrace. You can set the DTRACE variable to override automatic detection.])
 942   ])
 943 ])
 944
 945 AS_IF([test "$test_sdt_uprobe" = "autodetect"], [
 946   AS_IF([test "$lttng_cv_sdt_works" = "yes"], [
 947     AS_IF([test "x$DTRACE" != "x"], [
 948       test_sdt_uprobe=yes
 949     ])
 950   ])
 951 ])
 952
 953 AM_CONDITIONAL([TEST_SDT_UPROBE], [test "$test_sdt_uprobe" = "yes"])
 954
 955 # Arguments for binaries build exclusion
 956 AC_ARG_ENABLE([bin-lttng], AS_HELP_STRING([--disable-bin-lttng],[Disable the build of lttng binaries]))
 957 AC_ARG_ENABLE([bin-lttng-consumerd], AS_HELP_STRING([--disable-bin-lttng-consumerd],
 958               [Disable the build of lttng-consumerd binaries]))
 959 AC_ARG_ENABLE([bin-lttng-crash], AS_HELP_STRING([--disable-bin-lttng-crash],[Disable the build of lttng-crash binaries]))
 960 AC_ARG_ENABLE([bin-lttng-relayd], AS_HELP_STRING([--disable-bin-lttng-relayd],
 961               [Disable the build of lttng-relayd binaries]))
 962 AC_ARG_ENABLE([bin-lttng-sessiond], AS_HELP_STRING([--disable-bin-lttng-sessiond],
 963               [Disable the build of lttng-sessiond binaries]))
 964 AC_ARG_ENABLE([extras], AS_HELP_STRING([--disable-extras],
 965               [Disable the build of the extra components]))
 966
 967
 968 build_lib_consumer=no
 969 build_lib_health=no
 970 build_lib_index=no
 971 build_lib_kernel_consumer=no
 972 build_lib_kernel_ctl=no
 973 build_lib_lttng_ctl=no
 974 build_lib_relayd=no
 975 build_lib_sessiond_comm=no
 976 build_lib_testpoint=no
 977 build_lib_ust_consumer=no
 978
 979 # There is an overlap for enabled dependencies, but this makes everything
 980 # simpler. libcommon and libconfig are always compiled so they are not repeated
 981 # here.
 982
 983 # Enable binary dependencies.
 984 AS_IF([test x$enable_bin_lttng != xno],
 985       [
 986        build_lib_lttng_ctl=yes
 987       ]
 988 )
 989
 990 AS_IF([test x$enable_bin_lttng_consumerd != xno],
 991       [
 992        build_lib_consumer=yes
 993        build_lib_sessiond_comm=yes
 994        build_lib_index=yes
 995        build_lib_health=yes
 996        build_lib_testpoint=yes
 997       ]
 998 )
 999
1000 AS_IF([test x$enable_bin_lttng_crash != xno],
1001       # Do nothing since libconfig and libcommon are built by default.
1002       []
1003 )
1004
1005 AS_IF([test x$enable_bin_lttng_relayd != xno],
1006       [
1007        build_lib_sessiond_comm=yes
1008        build_lib_index=yes
1009        build_lib_health=yes
1010        build_lib_testpoint=yes
1011       ]
1012 )
1013 AS_IF([test x$enable_bin_lttng_sessiond != xno],
1014       [
1015        build_lib_lttng_ctl=yes
1016        build_lib_sessiond_comm=yes
1017        build_lib_kernel_ctl=yes
1018        build_lib_relayd=yes
1019        build_lib_testpoint=yes
1020        build_lib_health=yes
1021       ]
1022 )
1023
1024 # Libraries dependencies enabling
1025 AS_IF([test x$build_lib_lttng_ctl = xyes],
1026       [
1027        build_lib_sessiond_comm=yes
1028       ]
1029 )
1030
1031 AS_IF([test x$build_lib_consumer = xyes],
1032       [
1033        build_lib_sessiond_comm=yes
1034        build_lib_kernel_consumer=yes
1035        build_lib_relayd=yes
1036        AS_IF([test "x$with_lttng_ust" = "xyes"], [build_lib_ust_consumer=yes])
1037       ]
1038 )
1039
1040 AS_IF([test x$build_lib_kernel_consumer = xyes],
1041       [
1042        build_lib_kernel_ctl=yes
1043        build_lib_relayd=yes
1044       ]
1045 )
1046
1047 AS_IF([test x$build_lib_relayd = xyes],
1048       [
1049        build_lib_sessiond_comm=yes
1050       ]
1051 )
1052
1053 # Find arch type
1054 AS_CASE([$host_cpu],
1055         [k1om], [ARCHTYPE="x86"],
1056         [i386], [ARCHTYPE="x86"],
1057         [i486], [ARCHTYPE="x86"],
1058         [i586], [ARCHTYPE="x86"],
1059         [i686], [ARCHTYPE="x86"],
1060         [amd64], [ARCHTYPE="x86"],
1061         [x86_64], [ARCHTYPE="x86"],
1062         [powerpc], [ARCHTYPE="ppc"],
1063         [ppc64], [ARCHTYPE="ppc"],
1064         [powerpc64], [ARCHTYPE="ppc"],
1065         [powerpc64le], [ARCHTYPE="ppc"],
1066         [ppc], [ARCHTYPE="ppc"],
1067         [s390], [ARCHTYPE="s390"],
1068         [s390x], [ARCHTYPE="s390"],
1069         [sparc], [ARCHTYPE="sparc64"],
1070         [sparc64], [ARCHTYPE="sparc64"],
1071         [alpha*], [ARCHTYPE="alpha"],
1072         [ia64], [ARCHTYPE="ia64"],
1073         [arm*], [ARCHTYPE="arm"],
1074         [aarch64*], [ARCHTYPE="aarch64"],
1075         [mips*], [ARCHTYPE="mips"],
1076         [nios2*], [ARCHTYPE="nios2"],
1077         [tile*], [ARCHTYPE="tile"],
1078         [hppa*], [ARCHTYPE="hppa"],
1079         [m68k], [ARCHTYPE="m68k"],
1080         [riscv*], [ARCHTYPE="riscv"],
1081         [ARCHTYPE="unknown"]
1082 )
1083
1084 AC_SUBST(ARCHTYPE)
1085
1086 AS_CASE([$host_os],
1087         [linux*], [OSTYPE="linux"],
1088         [freebsd*], [OSTYPE="freebsd"],
1089         [solaris*], [OSTYPE="solaris"],
1090         [cygwin*], [OSTYPE="cygwin"],
1091         [mingw*], [OSTYPE="mingw"],
1092         [OSTYPE="unknown"]
1093 )
1094 AC_SUBST(OSTYPE)
1095 AM_CONDITIONAL([IS_LINUX], [test $OSTYPE = "linux"])
1096
1097
1098
1099 # Userspace callstack capture is only supported by the Linux kernel on x86.
1100 AH_TEMPLATE([HAVE_MODULES_USERSPACE_CALLSTACK_CONTEXT], [Define if you have LTTng-modules userspace callstack tracing support])
1101 AS_IF([test "x$ARCHTYPE" = "xx86" && test "x$OSTYPE" = "xlinux"],[
1102         have_modules_userspace_callstack_context=yes
1103         AC_DEFINE([HAVE_MODULES_USERSPACE_CALLSTACK_CONTEXT], [1])
1104 ])
1105 AM_CONDITIONAL([HAVE_MODULES_USERSPACE_CALLSTACK_CONTEXT], [test x$have_modules_userspace_callstack_context = xyes])
1106
1107 # Export binaries build conditions.
1108 AM_CONDITIONAL([BUILD_BIN_LTTNG], [test x$enable_bin_lttng != xno])
1109 AM_CONDITIONAL([BUILD_BIN_LTTNG_CONSUMERD], [test x$enable_bin_lttng_consumerd != xno])
1110 AM_CONDITIONAL([BUILD_BIN_LTTNG_CRASH], [test x$enable_bin_lttng_crash != xno])
1111 AM_CONDITIONAL([BUILD_BIN_LTTNG_RELAYD], [test x$enable_bin_lttng_relayd != xno])
1112 AM_CONDITIONAL([BUILD_BIN_LTTNG_SESSIOND], [test x$enable_bin_lttng_sessiond != xno])
1113
1114 # Export the tests and extras build conditions.
1115 AS_IF([\
1116 test "x$enable_bin_lttng" != "xno" && \
1117 test "x$enable_bin_lttng_consumerd" != "xno" && \
1118 test "x$enable_bin_lttng_crash" != "xno" && \
1119 test "x$enable_bin_lttng_relayd" != "xno" && \
1120 test "x$enable_bin_lttng_sessiond" != "xno"],
1121 [build_tests=yes],
1122 [build_tests=no]
1123 )
1124
1125 AM_CONDITIONAL([BUILD_TESTS], [test x$build_tests = xyes])
1126 AM_CONDITIONAL([BUILD_EXTRAS], [test x$enable_extras != xno])
1127
1128 # Export libraries build conditions.
1129 AM_CONDITIONAL([BUILD_LIB_CONSUMER], [test x$build_lib_consumer = xyes])
1130 AM_CONDITIONAL([BUILD_LIB_HEALTH], [test x$build_lib_health = xyes])
1131 AM_CONDITIONAL([BUILD_LIB_INDEX], [test x$build_lib_index = xyes])
1132 AM_CONDITIONAL([BUILD_LIB_KERNEL_CONSUMER], [test x$build_lib_kernel_consumer = xyes])
1133 AM_CONDITIONAL([BUILD_LIB_KERNEL_CTL], [test x$build_lib_kernel_ctl = xyes])
1134 AM_CONDITIONAL([BUILD_LIB_LTTNG_CTL], [test x$build_lib_lttng_ctl = xyes])
1135 AM_CONDITIONAL([BUILD_LIB_RELAYD], [test x$build_lib_relayd = xyes])
1136 AM_CONDITIONAL([BUILD_LIB_SESSIOND_COMM], [test x$build_lib_sessiond_comm = xyes])
1137 AM_CONDITIONAL([BUILD_LIB_TESTPOINT], [test x$build_lib_testpoint = xyes])
1138 AM_CONDITIONAL([BUILD_LIB_UST_CONSUMER], [test x$build_lib_ust_consumer = xyes])
1139
1140 AM_CFLAGS="-fvisibility=hidden $OPT_CFLAGS $WARN_CFLAGS $PTHREAD_CFLAGS"
1141 AC_SUBST(AM_CFLAGS)
1142
1143 AM_CXXFLAGS="-fvisibility=hidden -fvisibility-inlines-hidden $OPT_CXXFLAGS $WARN_CXXFLAGS $PTHREAD_CFLAGS"
1144 AC_SUBST(AM_CXXFLAGS)
1145
1146 # This is set even though it is empty, so Makefiles can do "AM_LDFLAGS += ...".
1147 AM_LDFLAGS=""
1148 AC_SUBST(AM_LDFLAGS)
1149
1150 # The order in which the include folders are searched is important.
1151 # The top_builddir should always be searched first in the event that a build
1152 # time generated file is included. An example of this is the "version.i" file.
1153 # In a scenario where lttng-tools is built from a distribution tarball and in a
1154 # out-of-tree manner, the generated "version.i" has priority on the one from
1155 # the source (distribution tarball) and must be found first.
1156 AM_CPPFLAGS="-I\$(top_builddir)/include -I\$(top_srcdir)/include -I\$(top_builddir)/src -I\$(top_srcdir)/src -include config.h $AM_CPPFLAGS"
1157 AC_SUBST(AM_CPPFLAGS)
1158
1159 lttngincludedir="${includedir}/lttng"
1160 AC_SUBST(lttngincludedir)
1161
1162 lttngactionincludedir="${includedir}/lttng/action"
1163 AC_SUBST(lttngactionincludedir)
1164
1165 lttngconditionincludedir="${includedir}/lttng/condition"
1166 AC_SUBST(lttngconditionincludedir)
1167
1168 lttngnotificationincludedir="${includedir}/lttng/notification"
1169 AC_SUBST(lttngnotificationincludedir)
1170
1171 lttngtriggerincludedir="${includedir}/lttng/trigger"
1172 AC_SUBST(lttngtriggerincludedir)
1173
1174 lttngeventruleincludedir="${includedir}/lttng/event-rule"
1175 AC_SUBST(lttngeventruleincludedir)
1176
1177 lttnglibexecdir="${libdir}/lttng/libexec"
1178 AC_SUBST(lttnglibexecdir)
1179
1180 AC_CONFIG_FILES([
1181         Makefile
1182         doc/Makefile
1183         doc/examples/Makefile
1184         doc/examples/rotation/Makefile
1185         doc/examples/trigger-condition-event-matches/Makefile
1186         doc/man/Makefile
1187         doc/man/asciidoc-attrs.conf
1188         include/Makefile
1189         extras/Makefile
1190         extras/bindings/Makefile
1191         extras/bindings/swig/Makefile
1192         extras/bindings/swig/python/Makefile
1193         extras/core-handler/Makefile
1194         src/Makefile
1195         src/common/Makefile
1196         src/lib/Makefile
1197         src/lib/lttng-ctl/Makefile
1198         src/lib/lttng-ctl/lttng-ctl.pc
1199         src/bin/Makefile
1200         src/bin/lttng-consumerd/Makefile
1201         src/bin/lttng-sessiond/Makefile
1202         src/bin/lttng-relayd/Makefile
1203         src/bin/lttng/Makefile
1204         src/bin/lttng-crash/Makefile
1205         src/vendor/Makefile
1206         src/vendor/msgpack/Makefile
1207         tests/Makefile
1208         tests/destructive/Makefile
1209         tests/meta/Makefile
1210         tests/regression/Makefile
1211         tests/regression/kernel/Makefile
1212         tests/regression/tools/Makefile
1213         tests/regression/tools/streaming/Makefile
1214         tests/regression/tools/filtering/Makefile
1215         tests/regression/tools/health/Makefile
1216         tests/regression/tools/tracefile-limits/Makefile
1217         tests/regression/tools/snapshots/Makefile
1218         tests/regression/tools/live/Makefile
1219         tests/regression/tools/exclusion/Makefile
1220         tests/regression/tools/save-load/Makefile
1221         tests/regression/tools/save-load/configuration/Makefile
1222         tests/regression/tools/mi/Makefile
1223         tests/regression/tools/wildcard/Makefile
1224         tests/regression/tools/channel/Makefile
1225         tests/regression/tools/crash/Makefile
1226         tests/regression/tools/regen-metadata/Makefile
1227         tests/regression/tools/regen-statedump/Makefile
1228         tests/regression/tools/notification/Makefile
1229         tests/regression/tools/rotation/Makefile
1230         tests/regression/tools/base-path/Makefile
1231         tests/regression/tools/metadata/Makefile
1232         tests/regression/tools/tracker/Makefile
1233         tests/regression/tools/working-directory/Makefile
1234         tests/regression/tools/relayd-grouping/Makefile
1235         tests/regression/tools/clear/Makefile
1236         tests/regression/tools/trigger/Makefile
1237         tests/regression/tools/trigger/rate-policy/Makefile
1238         tests/regression/tools/trigger/start-stop/Makefile
1239         tests/regression/tools/trigger/utils/Makefile
1240         tests/regression/tools/trigger/name/Makefile
1241         tests/regression/tools/trigger/hidden/Makefile
1242         tests/regression/tools/context/Makefile
1243         tests/regression/ust/Makefile
1244         tests/regression/ust/nprocesses/Makefile
1245         tests/regression/ust/high-throughput/Makefile
1246         tests/regression/ust/low-throughput/Makefile
1247         tests/regression/ust/before-after/Makefile
1248         tests/regression/ust/buffers-pid/Makefile
1249         tests/regression/ust/periodical-metadata-flush/Makefile
1250         tests/regression/ust/multi-session/Makefile
1251         tests/regression/ust/multi-lib/Makefile
1252         tests/regression/ust/overlap/Makefile
1253         tests/regression/ust/overlap/demo/Makefile
1254         tests/regression/ust/linking/Makefile
1255         tests/regression/ust/daemon/Makefile
1256         tests/regression/ust/exit-fast/Makefile
1257         tests/regression/ust/fork/Makefile
1258         tests/regression/ust/libc-wrapper/Makefile
1259         tests/regression/ust/baddr-statedump/Makefile
1260         tests/regression/ust/ust-dl/Makefile
1261         tests/regression/ust/java-jul/Makefile
1262         tests/regression/ust/java-log4j/Makefile
1263         tests/regression/ust/java-log4j2/Makefile
1264         tests/regression/ust/getcpu-override/Makefile
1265         tests/regression/ust/clock-override/Makefile
1266         tests/regression/ust/type-declarations/Makefile
1267         tests/regression/ust/rotation-destroy-flush/Makefile
1268         tests/regression/ust/blocking/Makefile
1269         tests/regression/ust/namespaces/Makefile
1270         tests/stress/Makefile
1271         tests/unit/Makefile
1272         tests/unit/ini_config/Makefile
1273         tests/perf/Makefile
1274         tests/utils/Makefile
1275         tests/utils/lttngtest/Makefile
1276         tests/utils/tap/Makefile
1277         tests/utils/testapp/Makefile
1278         tests/utils/testapp/gen-ns-events/Makefile
1279         tests/utils/testapp/gen-kernel-test-events/Makefile
1280         tests/utils/testapp/gen-py-events/Makefile
1281         tests/utils/testapp/gen-ust-events/Makefile
1282         tests/utils/testapp/gen-ust-events-ns/Makefile
1283         tests/utils/testapp/gen-syscall-events-callstack/Makefile
1284         tests/utils/testapp/gen-ust-nevents/Makefile
1285         tests/utils/testapp/gen-ust-nevents-str/Makefile
1286         tests/utils/testapp/gen-syscall-events/Makefile
1287         tests/utils/testapp/gen-ust-tracef/Makefile
1288         tests/utils/testapp/userspace-probe-elf-binary/Makefile
1289         tests/utils/testapp/userspace-probe-elf-cxx-binary/Makefile
1290         tests/utils/testapp/userspace-probe-sdt-binary/Makefile
1291         tests/utils/xml-utils/Makefile
1292 ])
1293
1294 # Inject variable into python test script.
1295 AC_CONFIG_FILES([tests/regression/ust/python-logging/test_python_logging],[chmod +x tests/regression/ust/python-logging/test_python_logging])
1296 # Inject LTTNG_TOOLS_BUILD_WITH_LIBPFM variable in test script.
1297 AC_CONFIG_FILES([tests/perf/test_perf_raw],[chmod +x tests/perf/test_perf_raw])
1298 AC_CONFIG_FILES([tests/regression/ust/ust-dl/test_ust-dl],[chmod +x tests/regression/ust/ust-dl/test_ust-dl])
1299 AC_CONFIG_FILES([pre-inst-env],[chmod +x pre-inst-env])
1300
1301 AC_OUTPUT
1302
1303 #
1304 # Mini-report on what will be built.
1305 #
1306
1307 PPRINT_INIT
1308 PPRINT_SET_INDENT(1)
1309 PPRINT_SET_TS(38)
1310
1311 AS_ECHO
1312 AS_ECHO("${PPRINT_COLOR_BLDBLU}LTTng-tools $PACKAGE_VERSION \"$version_name\"$PPRINT_COLOR_RST")
1313 AS_ECHO
1314
1315 AS_IF([test -n "$report_fold"], [
1316         AS_ECHO("`AS_ECHO("$version_description") | $report_fold -s`")
1317 ], [
1318         AS_ECHO("$version_description")
1319 ])
1320
1321 AS_ECHO
1322 PPRINT_SUBTITLE([Features])
1323
1324 # Target architecture we're building for.
1325 target_arch=$host_cpu
1326 [
1327 for f in $CFLAGS; do
1328         if test $f = "-m32"; then
1329                         target_arch="32-bit"
1330         elif test $f = "-m64"; then
1331                         target_arch="64-bit"
1332         fi
1333 done
1334 ]
1335 PPRINT_PROP_STRING([Target architecture], $target_arch)
1336
1337 # kmod enabled/disabled
1338 test "x$with_kmod" != "xno" && value=1 || value=0
1339 PPRINT_PROP_BOOL([libkmod support], $value)
1340
1341 # LTTng-UST enabled/disabled
1342 test "x$with_lttng_ust" = "xyes" && value=1 || value=0
1343 PPRINT_PROP_BOOL([LTTng-UST support], $value)
1344
1345 AS_ECHO
1346 PPRINT_SUBTITLE([Binaries])
1347
1348 # List binaries to be built
1349 test x$enable_bin_lttng != xno && value=1 || value=0
1350 PPRINT_PROP_BOOL([lttng], $value)
1351
1352 test x$enable_bin_lttng_consumerd != xno && value=1 || value=0
1353 PPRINT_PROP_BOOL([lttng-consumerd], $value)
1354
1355 test x$enable_bin_lttng_crash != xno && value=1 || value=0
1356 PPRINT_PROP_BOOL([lttng-crash], $value)
1357
1358 test x$enable_bin_lttng_relayd != xno && value=1 || value=0
1359 PPRINT_PROP_BOOL([lttng-relayd], $value)
1360
1361 test x$enable_bin_lttng_sessiond != xno && value=1 || value=0
1362 PPRINT_PROP_BOOL([lttng-sessiond], $value)
1363
1364 # Extras
1365 test x$enable_extras != xno && value=1 || value=0
1366 AS_ECHO
1367 PPRINT_SET_INDENT(0)
1368 PPRINT_PROP_BOOL([Extras], $value, $PPRINT_COLOR_SUBTITLE)
1369 PPRINT_SET_INDENT(1)
1370
1371 AS_ECHO
1372 PPRINT_SUBTITLE([Tests])
1373
1374 # Print clear message that tests won't be built
1375 AS_IF([test "x$build_tests" = "xno"],[
1376         PPRINT_WARN([Tests won't be built since some binaries were disabled])
1377 ])
1378
1379 # LTTng UST Java agent JUL tests enabled/disabled
1380 test "x$test_java_agent_jul" = "xyes" && value=1 || value=0
1381 PPRINT_PROP_BOOL([LTTng-UST Java agent JUL tests], $value)
1382
1383 # LTTng UST Java agent Log4j 1.x tests enabled/disabled
1384 test "x$test_java_agent_log4j" = "xyes" && value=1 || value=0
1385 PPRINT_PROP_BOOL([LTTng-UST Java agent Log4j 1.x tests], $value)
1386
1387 # LTTng UST Java agent Log4j 2.x tests enabled/disabled
1388 test "x$test_java_agent_log4j2" = "xyes" && value=1 || value=0
1389 PPRINT_PROP_BOOL([LTTng-UST Java agent Log4j 2.x tests], $value)
1390
1391 test ! -z "$PYTHON2_AGENT" && value=1 || value=0
1392 PPRINT_PROP_BOOL([LTTng-UST Python2 agent tests], $value)
1393
1394 test ! -z "$PYTHON3_AGENT" && value=1 || value=0
1395 PPRINT_PROP_BOOL([LTTng-UST Python3 agent tests], $value)
1396
1397 # userspace-probe SDT instrumentation tests enabled/disabled
1398 test "x$test_sdt_uprobe" = "xyes" && value=1 || value=0
1399 PPRINT_PROP_BOOL([LTTng-modules SDT uprobe tests], $value)
1400
1401 #Python binding enabled/disabled
1402 test "x$enable_python_binding" = xyes && value=1 || value=0
1403 AS_ECHO
1404 PPRINT_SET_INDENT(0)
1405 PPRINT_PROP_BOOL([Python binding], $value, $PPRINT_COLOR_SUBTITLE)
1406
1407 # man pages build enabled/disabled
1408 m4_pushdef([build_man_pages_msg], [Build and install man pages])
1409
1410 AS_IF([test "x$man_pages_opt" != "xno"], [
1411         AS_IF([test "x$in_git_repo" = "xyes"], [
1412                 PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
1413         ], [
1414                 AS_IF([test "x$have_asciidoc_xmlto" = "xyes"], [
1415                         PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
1416                 ], [
1417                         PPRINT_PROP_STRING([build_man_pages_msg],
1418                                 [${PPRINT_COLOR_BLDGRN}yes (already built)],
1419                                 $PPRINT_COLOR_SUBTITLE)
1420                 ])
1421         ])
1422 ], [
1423         PPRINT_PROP_BOOL([build_man_pages_msg], 0, $PPRINT_COLOR_SUBTITLE)
1424 ])
1425
1426 m4_popdef([build_man_pages_msg])
1427
1428 test "x$embedded_help" = xyes && value=1 || value=0
1429 PPRINT_PROP_BOOL([Embed --help messages], $value, $PPRINT_COLOR_SUBTITLE)
1430
1431 PPRINT_SET_INDENT(1)
1432
1433 report_bindir="`eval eval echo $bindir`"
1434 report_libdir="`eval eval echo $libdir`"
1435
1436 # Print the bindir and libdir this `make install' will install into.
1437 AS_ECHO
1438 PPRINT_SUBTITLE([Install directories])
1439 PPRINT_PROP_STRING([Binaries], [$report_bindir])
1440 PPRINT_PROP_STRING([Libraries], [$report_libdir])
1441
1442 AS_ECHO
1443 PPRINT_SUBTITLE([Search directories])
1444
1445 # If we build the sessiond, print the paths it will use
1446 AS_IF([test "$SESSIOND_BIN" = ""],[
1447         path="$report_bindir/lttng-sessiond"
1448 ],[
1449         path="$SESSIOND_BIN"
1450 ])
1451 PPRINT_PROP_STRING([lttng-sessiond executable], [$path])
1452
1453 AS_IF([test "$CONSUMERD32_BIN" = ""],[
1454         path="`eval eval echo $lttnglibexecdir`/lttng-consumerd"
1455 ],[
1456         path="$CONSUMERD32_BIN"
1457 ])
1458 PPRINT_PROP_STRING([32-bit lttng-consumerd executable], [$path])
1459
1460 AS_IF([test "$CONSUMERD32_LIBDIR" = ""],[
1461         path="`eval eval echo $libdir`"
1462 ],[
1463         path="$CONSUMERD32_LIBDIR"
1464 ])
1465 PPRINT_PROP_STRING([32-bit consumer libraries], [$path])
1466
1467 AS_IF([test "$CONSUMERD64_BIN" = ""],[
1468         path="`eval eval echo $lttnglibexecdir`/lttng-consumerd"
1469 ],[
1470         path="$CONSUMERD64_BIN"
1471 ])
1472 PPRINT_PROP_STRING([64-bit lttng-consumerd executable], [$path])
1473
1474 AS_IF([test "$CONSUMERD64_LIBDIR" = ""],[
1475         path="`eval eval echo $libdir`"
1476 ],[
1477         path="$CONSUMERD64_LIBDIR"
1478 ])
1479 PPRINT_PROP_STRING([64-bit consumer libraries], [$path])
1480 PPRINT_SET_INDENT(0)
1481
1482 AS_IF([test "x$warn_prebuilt_man_pages" = "xyes" ], [
1483         AS_ECHO
1484         PPRINT_WARN([You need asciidoc and xmlto to build the LTTng-tools man pages.
1485
1486 Note that the man pages are already built in this distribution tarball,
1487 therefore asciidoc and xmlto are only needed if you intend to modify
1488 their sources.
1489
1490 Also note that the installed man pages will contain the project's
1491 default command-line option and environment variable values.
1492
1493 Use --disable-man-pages to completely disable building and installing
1494 the man pages.])
1495 ])