configure.ac

   1 AC_INIT([lttng-tools],[2.0.4],[dgoulet@efficios.com],[],[http://lttng.org])
   2 AC_CONFIG_AUX_DIR([config])
   3 AC_CANONICAL_TARGET
   4 AC_CANONICAL_HOST
   5 AC_CONFIG_MACRO_DIR([config])
   6 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
   7 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
   8
   9 version_name="Annedd'ale"
  10 version_description="New type of beer, 100% from Quebec, flavored with sapin beaumier needles, with a touch of hops."
  11
  12 AC_DEFINE_UNQUOTED([VERSION_NAME], ["$version_name"], "")
  13 AC_DEFINE_UNQUOTED([VERSION_DESCRIPTION], ["$version_description"], "")
  14
  15 AC_CONFIG_HEADERS([include/config.h])
  16
  17 AC_PROG_GREP
  18 # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
  19 AC_ARG_ENABLE(libtool-linkdep-fixup,
  20         AS_HELP_STRING([--disable-libtool-linkdep-fixup],
  21                         [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)]),
  22         libtool_fixup=$enableval,
  23         libtool_fixup=yes)
  24
  25 AS_IF([test "x$libtool_fixup" = "xyes"],
  26             [
  27             libtool_m4="$srcdir/config/libtool.m4"
  28             libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
  29             AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
  30             libtool_flag_pattern_count=$(grep -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
  31             AS_IF([test $libtool_flag_pattern_count -ne 0],
  32             [
  33                   AC_MSG_RESULT([$libtool_flag_pattern_count])
  34                   AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
  35                   sed -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
  36                   ],
  37                   [
  38                   AC_MSG_RESULT([none])
  39                   ])
  40             ])
  41
  42 AC_CHECK_HEADERS([ \
  43         sys/types.h unistd.h fcntl.h string.h pthread.h limits.h \
  44         signal.h stdlib.h sys/un.h sys/socket.h stdlib.h stdio.h \
  45         getopt.h sys/ipc.h sys/shm.h popt.h grp.h \
  46 ])
  47
  48 # Babeltrace viewer check
  49 AC_ARG_WITH([babeltrace-bin],
  50         AS_HELP_STRING([--with-babeltrace-bin],
  51         [Location of the babeltrace viewer executable (including the filename)]),
  52         [BABELTRACE_BIN="$withval"],
  53         [BABELTRACE_BIN=''])
  54 AC_SUBST([BABELTRACE_BIN])
  55
  56 # lttv-gui
  57 AC_ARG_WITH([lttv-gui-bin],
  58         AS_HELP_STRING([--with-lttv-gui-bin],
  59    [Location of the lttv GUI viewer executable (including the filename)]),
  60    [LTTV_GUI_BIN="$withval"],
  61    [LTTV_GUI_BIN=''])
  62 AC_SUBST([LTTV_GUI_BIN])
  63
  64 AC_ARG_WITH([consumerd32-bin],
  65         AS_HELP_STRING([--with-consumerd32-bin],
  66         [Location of the 32-bit consumerd executable (including the filename)]),
  67         [CONSUMERD32_BIN="$withval"],
  68         [CONSUMERD32_BIN=''])
  69 AC_SUBST([CONSUMERD32_BIN])
  70
  71 AC_ARG_WITH([consumerd64-bin],
  72         AS_HELP_STRING([--with-consumerd64-bin],
  73         [Location of the 64-bit consumerd executable (including the filename)]),
  74         [CONSUMERD64_BIN="$withval"],
  75         [CONSUMERD64_BIN=''])
  76 AC_SUBST([CONSUMERD64_BIN])
  77
  78 AC_ARG_WITH([consumerd32-libdir],
  79         AS_HELP_STRING([--with-consumerd32-libdir],
  80         [Directory containing the 32-bit consumerd libraries]),
  81         [CONSUMERD32_LIBDIR="$withval"],
  82         [CONSUMERD32_LIBDIR=''])
  83 AC_SUBST([CONSUMERD32_LIBDIR])
  84
  85 AC_ARG_WITH([consumerd64-libdir],
  86         AS_HELP_STRING([--with-consumerd64-libdir],
  87         [Directory containing the 64-bit consumerd libraries]),
  88         [CONSUMERD64_LIBDIR="$withval"],
  89         [CONSUMERD64_LIBDIR=''])
  90 AC_SUBST([CONSUMERD64_LIBDIR])
  91
  92 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_BIN], "$CONSUMERD32_BIN", [Location of the 32-bit consumerd executable.])
  93 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_BIN], "$CONSUMERD64_BIN", [Location of the 64-bit consumerd executable])
  94 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_LIBDIR], "$CONSUMERD32_LIBDIR", [Search for consumerd 32-bit libraries in this location.])
  95 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_LIBDIR], "$CONSUMERD64_LIBDIR", [Search for consumerd 64-bit libraries in this location.])
  96 AC_DEFINE_UNQUOTED([CONFIG_BABELTRACE_BIN], "$BABELTRACE_BIN", [Location of the babeltrace viewer executable.])
  97 AC_DEFINE_UNQUOTED([CONFIG_LTTV_GUI_BIN], "$LTTV_GUI_BIN", [Location of the lttv GUI viewer executable.])
  98
  99 # Check for pthread
 100 AC_CHECK_LIB([pthread], [pthread_create], [],
 101         [AC_MSG_ERROR([Cannot find libpthread. Use [LDFLAGS]=-Ldir to specify its location.])]
 102 )
 103
 104 # Check libpopt
 105 AC_CHECK_LIB([popt], [poptGetContext], [],
 106         [AC_MSG_ERROR([Cannot find libpopt. Use [LDFLAGS]=-Ldir to specify its location.])]
 107 )
 108
 109 # URCU library version needed or newer
 110 liburcu_version=">= 0.6.7"
 111
 112 # Check liburcu needed function calls
 113 AC_CHECK_DECL([cds_list_add], [],
 114         [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu/list.h>]]
 115 )
 116 AC_CHECK_DECL([cds_wfq_init], [],
 117         [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu/wfqueue.h>]]
 118 )
 119 AC_CHECK_DECL([cds_wfq_dequeue_blocking], [],
 120     [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu/wfqueue.h>]]
 121 )
 122 AC_CHECK_DECL([futex_async], [],
 123         [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu/futex.h>]]
 124 )
 125 AC_CHECK_DECL([rcu_thread_offline], [],
 126         [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu.h>]]
 127 )
 128 AC_CHECK_DECL([rcu_thread_online], [],
 129         [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu.h>]]
 130 )
 131 AC_CHECK_DECL([caa_likely], [],
 132         [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu.h>]]
 133 )
 134
 135 # Check liblttng-ust-ctl library
 136 AC_ARG_ENABLE(lttng-ust,
 137         AS_HELP_STRING([--disable-lttng-ust],[build without LTTng-UST (Userspace Tracing) support]),
 138         lttng_ust_support=$enableval, lttng_ust_support=yes)
 139
 140 AS_IF([test "x$lttng_ust_support" = "xyes"], [
 141         AC_CHECK_LIB([lttng-ust-ctl], [ustctl_create_session], [],
 142                 [AC_MSG_ERROR([Cannot find LTTng-UST. Use [LDFLAGS]=-Ldir to specify its location, or specify --disable-lttng-ust to build lttng-tools without LTTng-UST support.])]
 143         )
 144 ])
 145
 146 AM_CONDITIONAL([HAVE_LIBLTTNG_UST_CTL], [ test "x$ac_cv_lib_lttng_ust_ctl_ustctl_create_session" = "xyes" ])
 147
 148 AC_CHECK_FUNCS([sched_getcpu sysconf])
 149
 150 # check for dlopen
 151 AC_CHECK_LIB([dl], [dlopen],
 152 [
 153         have_libdl=yes
 154 ],
 155 [
 156         #libdl not found, check for dlopen in libc.
 157         AC_CHECK_LIB([c], [dlopen],
 158         [
 159                 have_libc_dl=yes
 160         ],
 161         [
 162                 AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
 163         ])
 164 ])
 165 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBDL], [test "x$have_libdl" = "xyes"])
 166 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBC_DL], [test "x$have_libc_dl" = "xyes"])
 167
 168 # Option to only build the consumer daemon and its libraries
 169 AC_ARG_WITH([consumerd-only],
 170         AS_HELP_STRING([--with-consumerd-only],[Only build the consumer daemon [default=no]]),
 171         [consumerd_only=$withval],
 172         [consumerd_only=no])
 173 AM_CONDITIONAL([BUILD_CONSUMERD_ONLY], [test "x$consumerd_only" = "xyes"])
 174
 175 # Epoll check. If not present, the build will fallback on poll() API
 176 AX_HAVE_EPOLL(
 177         [AX_CONFIG_FEATURE_ENABLE(epoll)],
 178         [AX_CONFIG_FEATURE_DISABLE(epoll)]
 179 )
 180 AX_CONFIG_FEATURE(
 181         [epoll], [This platform supports epoll(7)],
 182         [HAVE_EPOLL], [This platform supports epoll(7).],
 183         [enable_epoll="yes"], [enable_epoll="no"]
 184 )
 185 AM_CONDITIONAL([COMPAT_EPOLL], [ test "$enable_epoll" = "yes" ])
 186
 187 AC_SYS_LARGEFILE
 188 AC_PROG_CC
 189 LT_INIT
 190
 191 CFLAGS="-Wall $CFLAGS -g -fno-strict-aliasing"
 192
 193 DEFAULT_INCLUDES="-I\$(top_srcdir) -I\$(top_builddir) -I\$(top_builddir)/src -I\$(top_builddir)/include -include config.h"
 194
 195 lttngincludedir="${includedir}/lttng"
 196
 197 AC_SUBST(lttngincludedir)
 198 AC_SUBST(DEFAULT_INCLUDES)
 199
 200 lttnglibexecdir="${libdir}/lttng/libexec"
 201 AC_SUBST(lttnglibexecdir)
 202
 203 AC_CONFIG_FILES([
 204         Makefile
 205         doc/Makefile
 206         doc/man/Makefile
 207         include/Makefile
 208         src/Makefile
 209         src/common/Makefile
 210         src/common/kernel-ctl/Makefile
 211         src/common/kernel-consumer/Makefile
 212         src/common/ust-consumer/Makefile
 213         src/common/hashtable/Makefile
 214         src/common/sessiond-comm/Makefile
 215         src/common/compat/Makefile
 216         src/lib/Makefile
 217         src/lib/lttng-ctl/Makefile
 218         src/bin/Makefile
 219         src/bin/lttng-consumerd/Makefile
 220         src/bin/lttng-sessiond/Makefile
 221         src/bin/lttng/Makefile
 222         tests/Makefile
 223         tests/ust-nevents/Makefile
 224         tests/ust-nprocesses/Makefile
 225 ])
 226
 227 AC_OUTPUT
 228
 229 #
 230 # Mini-report on what will be built
 231 #
 232 AS_ECHO()
 233
 234 AS_ECHO("Version name: $version_name")
 235 AS_ECHO("$version_description")
 236
 237 AS_ECHO()
 238
 239 # Target architecture we're building for
 240 target_arch=$host_cpu
 241 [
 242 for f in $CFLAGS; do
 243         if test $f = "-m32"; then
 244                         target_arch="32-bit"
 245         elif test $f = "-m64"; then
 246                         target_arch="64-bit"
 247         fi
 248 done
 249 ]
 250 AS_ECHO_N("Target architecture: ")
 251 AS_ECHO($target_arch)
 252
 253 # LTTng-UST enabled/disabled
 254 AS_ECHO_N("Lttng-UST support: ")
 255 AS_IF([test "x$lttng_ust_support" = "xyes"],[
 256         AS_ECHO("Enabled")
 257 ],[
 258         AS_ECHO("Disabled")
 259 ])
 260
 261 # Do we build only the consumerd, or everything
 262 AS_IF([test "x$consumerd_only" = "xyes"],[
 263         AS_ECHO("Only the consumerd daemon will be built.")
 264 ],[
 265         AS_ECHO("All binaries will be built.")
 266 ])
 267
 268 # Print the bindir and libdir this `make install' will install into.
 269 AS_ECHO()
 270 AS_ECHO_N("Binaries will be installed in:  ")
 271 AS_ECHO("`eval eval echo $bindir`")
 272 AS_ECHO_N("Libraries will be installed in: ")
 273 AS_ECHO("`eval eval echo $libdir`")
 274
 275 # If we build the sessiond, print the paths it will use
 276 AS_IF([test "x$consumerd_only" = "xno"],[
 277         AS_ECHO()
 278         AS_ECHO("The sessiond daemon will look in the following directories: ")
 279         AS_ECHO_N("32-bit consumerd executable at: ")
 280         AS_IF([test "$CONSUMERD32_BIN" = ""],[
 281                 AS_ECHO_N("`eval eval echo $lttnglibexecdir`")
 282                 AS_ECHO("/lttng-consumerd")
 283         ],[
 284                 AS_ECHO("$CONSUMERD32_BIN")
 285         ])
 286
 287         AS_ECHO_N("32-bit consumer libraries in:   ")
 288         AS_IF([test "$CONSUMERD32_LIBDIR" = ""],[
 289                 AS_ECHO("`eval eval echo $libdir`")
 290         ],[
 291                 AS_ECHO("$CONSUMERD32_LIBDIR")
 292         ])
 293
 294         AS_ECHO_N("64-bit consumerd executable at: ")
 295         AS_IF([test "$CONSUMERD64_BIN" = ""],[
 296                 AS_ECHO_N("`eval eval echo $lttnglibexecdir`")
 297                 AS_ECHO("/lttng-consumerd")
 298         ],[
 299                 AS_ECHO("$CONSUMERD64_BIN")
 300         ])
 301
 302         AS_ECHO_N("64-bit consumer libraries in:   ")
 303         AS_IF([test "$CONSUMERD64_LIBDIR" = ""],[
 304                 AS_ECHO("`eval eval echo $libdir`")
 305         ],[
 306                 AS_ECHO("$CONSUMERD64_LIBDIR")
 307         ])
 308 ])
 309
 310 AS_ECHO()
 311