X-Git-Url: https://git.lttng.org/?p=lttng-tools.git;a=blobdiff_plain;f=config%2Fax_prog_flex_version.m4;fp=config%2Fax_prog_flex_version.m4;h=0000000000000000000000000000000000000000;hp=da60e00f52497e08aa2065d152af0e3ead0e0194;hb=b7d2e95f49f3b34c9f00a0fb4d9de10bba056180;hpb=5b5bb8c82d70cf65707d5561e0640bf2ae8c2e6e

diff --git a/config/ax_prog_flex_version.m4 b/config/ax_prog_flex_version.m4
deleted file mode 100644
index da60e00f5..000000000
--- a/config/ax_prog_flex_version.m4
+++ /dev/null
@@ -1,69 +0,0 @@
-# ===========================================================================
-#   http://www.gnu.org/software/autoconf-archive/ax_prog_flex_version.html
-# ===========================================================================
-#
-# SYNOPSIS
-#
-#   AX_PROG_FLEX_VERSION([VERSION],[ACTION-IF-TRUE],[ACTION-IF-FALSE])
-#
-# DESCRIPTION
-#
-#   Makes sure that flex version is greater or equal to the version
-#   indicated. If true the shell commands in ACTION-IF-TRUE are executed. If
-#   not the shell commands in commands in ACTION-IF-TRUE are executed. If
-#   not the shell commands in ACTION-IF-FALSE are run. Note if $FLEX is not
-#   set (for example by running AC_CHECK_PROG or AC_PATH_PROG) the macro
-#   will fail.
-#
-#   Example:
-#
-#     AC_PATH_PROG([FLEX],[flex])
-#     AX_PROG_FLEX_VERSION([2.5.39],[ ... ],[ ... ])
-#
-#   This will check to make sure that the flex you have is at least version
-#   2.5.39 or greater.
-#
-#   NOTE: This macro uses the $FLEX variable to perform the check.
-#
-# LICENSE
-#
-#   Copyright (c) 2015 Jonathan Rajotte-Julien <jonathan.rajotte-julien@efficios.com>
-#
-#   Copying and distribution of this file, with or without modification, are
-#   permitted in any medium without royalty provided the copyright notice
-#   and this notice are preserved. This file is offered as-is, without any
-#   warranty.
-
-#serial 1
-
-AC_DEFUN([AX_PROG_FLEX_VERSION],[
-    AC_REQUIRE([AC_PROG_SED])
-    AC_REQUIRE([AC_PROG_GREP])
-
-    AS_IF([test -n "$FLEX"],[
-        ax_flex_version="$1"
-
-        AC_MSG_CHECKING([for flex version])
-        changequote(<<,>>)
-        flex_version=`$FLEX --version 2>&1 \
-          | $SED -n -e '/flex /b inspect
-b
-: inspect
-s/.* (\{0,1\}\([0-9]*\.[0-9]*\.[0-9]*\))\{0,1\}.*/\1/;p'`
-        changequote([,])
-        AC_MSG_RESULT($flex_version)
-
-	AC_SUBST([FLEX_VERSION],[$flex_version])
-
-        AX_COMPARE_VERSION([$flex_version],[ge],[$ax_flex_version],[
-	    :
-            $2
-        ],[
-	    :
-            $3
-        ])
-    ],[
-        AC_MSG_WARN([could not find flex])
-        $3
-    ])
-])