| | 1 | dnl SPDX-License-Identifier: GPL-2.0-only |
| | 2 | AC_PREREQ([2.64]) |
| | 3 | AC_INIT([lttng-tools],[2.13.11],[jeremie.galarneau@efficios.com],[],[https://lttng.org]) |
| | 4 | |
| | 5 | AC_CONFIG_HEADERS([include/config.h]) |
| | 6 | AC_CONFIG_AUX_DIR([config]) |
| | 7 | AC_CONFIG_MACRO_DIR([m4]) |
| | 8 | |
| | 9 | AC_CANONICAL_TARGET |
| | 10 | AC_CANONICAL_HOST |
| | 11 | |
| | 12 | AM_INIT_AUTOMAKE([1.12 foreign dist-bzip2 no-dist-gzip tar-pax nostdinc]) |
| | 13 | AM_MAINTAINER_MODE([enable]) |
| | 14 | |
| | 15 | # Enable silent rules if available (Introduced in AM 1.11) |
| | 16 | m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])]) |
| | 17 | |
| | 18 | # Checks for C compiler |
| | 19 | AC_USE_SYSTEM_EXTENSIONS |
| | 20 | AC_SYS_LARGEFILE |
| | 21 | AC_PROG_CC |
| | 22 | # AC_PROG_CC_STDC was merged in AC_PROG_CC in autoconf 2.70 |
| | 23 | m4_version_prereq([2.70], [], [AC_PROG_CC_STDC]) |
| | 24 | AC_PROG_CXX |
| | 25 | RW_PROG_CXX_WORKS |
| | 26 | AM_CONDITIONAL([CXX_WORKS], [test "x$rw_cv_prog_cxx_works" = "xyes"]) |
| | 27 | |
| | 28 | # Detect warning flags supported by the compiler, append them to WARN_CFLAGS. |
| | 29 | # |
| | 30 | # Pass -Werror as an extra flag during the test: this is needed to make the |
| | 31 | # -Wunknown-warning-option diagnostic fatal with clang. |
| | 32 | AX_APPEND_COMPILE_FLAGS([ dnl |
| | 33 | -Wall dnl |
| | 34 | dnl We currently get this warning when building with Clang: |
| | 35 | dnl |
| | 36 | dnl /usr/include/setjmp.h:54:12: error: declaration of built-in function '__sigsetjmp' requires the declaration of the 'jmp_buf' type, commonly provided in the header <setjmp.h>. [-Werror,-Wincomplete-setjmp-declaration] |
| | 37 | dnl extern int __sigsetjmp (struct __jmp_buf_tag __env[1], int __savemask) __THROWNL; |
| | 38 | dnl ^ |
| | 39 | -Wno-incomplete-setjmp-declaration dnl |
| | 40 | -Wdiscarded-qualifiers dnl |
| | 41 | -Wmissing-declarations dnl |
| | 42 | -Wmissing-prototypes dnl |
| | 43 | -Wmissing-parameter-type dnl |
| | 44 | -Wold-style-definition dnl |
| | 45 | -Wstrict-prototypes dnl |
| | 46 | -Wshadow dnl |
| | 47 | ], |
| | 48 | [WARN_CFLAGS], |
| | 49 | [-Werror]) |
| | 50 | |
| | 51 | # When given, add -Werror to WARN_CFLAGS. |
| | 52 | AC_ARG_ENABLE([Werror], |
| | 53 | [AS_HELP_STRING([--enable-Werror], [Treat compiler warnings as errors.])] |
| | 54 | ) |
| | 55 | AS_IF([test "x$enable_Werror" = "xyes"], |
| | 56 | [WARN_CFLAGS="${WARN_CFLAGS} -Werror"] |
| | 57 | ) |
| | 58 | |
| | 59 | # Checks for programs. |
| | 60 | AC_PROG_GREP |
| | 61 | AC_PROG_MAKE_SET |
| | 62 | AC_PROG_SED |
| | 63 | AC_PATH_PROG([report_fold], [fold]) |
| | 64 | LT_INIT |
| | 65 | |
| | 66 | # Check for objcopy, required by the base address statedump and dynamic linker tests |
| | 67 | AC_CHECK_TOOL([OBJCOPY], [objcopy]) |
| | 68 | AS_IF([test "x$OBJCOPY" = "x"], |
| | 69 | [AC_MSG_WARN([Cannot find objcopy. The base address statedump and dynamic linker tests will be disabled. Install the binutils package to remediate this.])] |
| | 70 | ) |
| | 71 | AM_CONDITIONAL([HAVE_OBJCOPY], [test "x$OBJCOPY" != "x"]) |
| | 72 | |
| | 73 | # check for pgrep |
| | 74 | AC_PATH_PROG([PGREP], [pgrep]) |
| | 75 | AM_CONDITIONAL([HAVE_PGREP], [test "x$PGREP" != "x"]) |
| | 76 | |
| | 77 | # set $IN_GIT_REPO if we're in the Git repository; the `bootstrap` file |
| | 78 | # is not distributed in tarballs |
| | 79 | AS_IF([test -f "$srcdir/bootstrap"], [in_git_repo=yes], [in_git_repo=no]) |
| | 80 | AM_CONDITIONAL([IN_GIT_REPO], [test "x$in_git_repo" = "xyes"]) |
| | 81 | |
| | 82 | # check for bison |
| | 83 | AC_PROG_YACC |
| | 84 | BISON=$YACC |
| | 85 | AX_PROG_BISON_VERSION([2.4], [have_bison=yes]) |
| | 86 | |
| | 87 | AS_IF([test "x$have_bison" != "xyes"], [ |
| | 88 | AS_IF([test "x$in_git_repo" = "xyes"], [ |
| | 89 | AC_MSG_FAILURE([ |
| | 90 | Bison >= 2.4 is required when building from the Git repository. You can |
| | 91 | set the YACC variable to override automatic detection. |
| | 92 | ]) |
| | 93 | ], [ |
| | 94 | AC_MSG_WARN([ |
| | 95 | Missing Bison >= 2.4. Note that the parser files are already built in |
| | 96 | this distribution tarball, so Bison is only needed if you intend to |
| | 97 | modify their sources. You can set the YACC variable to override automatic |
| | 98 | detection. |
| | 99 | ]) |
| | 100 | ]) |
| | 101 | ]) |
| | 102 | AM_CONDITIONAL([HAVE_BISON], [test "x$have_bison" = "xyes"]) |
| | 103 | |
| | 104 | # check for flex |
| | 105 | # Prior to autoconf 2.70, AC_PROG_FLEX did not take an argument. This is not a |
| | 106 | # problem since the argument is silently ignored by older versions. |
| | 107 | AC_PROG_LEX([noyywrap]) |
| | 108 | FLEX=$LEX |
| | 109 | AX_PROG_FLEX_VERSION([2.5.35], [have_flex=yes]) |
| | 110 | |
| | 111 | AS_IF([test "x$have_flex" != "xyes"], [ |
| | 112 | AS_IF([test "x$in_git_repo" = "xyes"], [ |
| | 113 | AC_MSG_FAILURE([ |
| | 114 | Flex >= 2.5.35 is required when building from the Git repository. You can |
| | 115 | set the LEX variable to override automatic detection. |
| | 116 | ]) |
| | 117 | ], [ |
| | 118 | AC_MSG_WARN([ |
| | 119 | Missing Flex >= 2.5.35. Note that the lexer files are already built in |
| | 120 | this distribution tarball, so Flex is only needed if you intend to |
| | 121 | modify their sources. You can set the LEX variable to override automatic |
| | 122 | detection. |
| | 123 | ]) |
| | 124 | ]) |
| | 125 | ]) |
| | 126 | AM_CONDITIONAL([HAVE_FLEX], [test "x$have_flex" = "xyes"]) |
| | 127 | |
| | 128 | |
| | 129 | # Checks for typedefs, structures, and compiler characteristics. |
| | 130 | AC_C_INLINE |
| | 131 | AC_TYPE_INT32_T |
| | 132 | AC_TYPE_INT64_T |
| | 133 | AC_TYPE_MODE_T |
| | 134 | AC_TYPE_OFF_T |
| | 135 | AC_TYPE_PID_T |
| | 136 | AC_TYPE_SIZE_T |
| | 137 | AC_TYPE_SSIZE_T |
| | 138 | AC_TYPE_UID_T |
| | 139 | AC_TYPE_UINT16_T |
| | 140 | AC_TYPE_UINT32_T |
| | 141 | AC_TYPE_UINT64_T |
| | 142 | AC_TYPE_UINT8_T |
| | 143 | |
| | 144 | AX_C___ATTRIBUTE__ |
| | 145 | AS_IF([test "x$ax_cv___attribute__" = "xyes"], |
| | 146 | [:], |
| | 147 | [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])]) |
| | 148 | |
| | 149 | AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])]) |
| | 150 | |
| | 151 | # Check if linker has the -no-pie option. |
| | 152 | AX_CHECK_LINK_FLAG([-no-pie], [linker_have_no_pie_option=yes]) |
| | 153 | AM_CONDITIONAL([LINKER_HAVE_NO_PIE_OPTION], [test "x$linker_have_no_pie_option" = "xyes"]) |
| | 154 | |
| | 155 | AX_LIB_SOCKET_NSL |
| | 156 | |
| | 157 | LT_NO_UNDEFINED="" |
| | 158 | AS_CASE([$host_os], |
| | 159 | [cygwin*], |
| | 160 | [ |
| | 161 | LT_NO_UNDEFINED="-no-undefined" |
| | 162 | ], |
| | 163 | [cygwin*|darwin*|mingw*|solaris*], |
| | 164 | [ |
| | 165 | # On platforms where we only support the relayd, disable the other binaries by default |
| | 166 | AS_IF([test "x$enable_bin_lttng" = "x" ], [enable_bin_lttng=no]) |
| | 167 | AS_IF([test "x$enable_bin_lttng_consumerd" = "x" ], [enable_bin_lttng_consumerd=no]) |
| | 168 | AS_IF([test "x$enable_bin_lttng_crash" = "x" ], [enable_bin_lttng_crash=no]) |
| | 169 | AS_IF([test "x$enable_bin_lttng_sessiond" = "x" ], [enable_bin_lttng_sessiond=no]) |
| | 170 | AS_IF([test "x$enable_extras" = "x" ], [enable_extras=no]) |
| | 171 | AS_IF([test "x$with_lttng_ust" = "x" ], [with_lttng_ust=no]) |
| | 172 | ] |
| | 173 | ) |
| | 174 | |
| | 175 | AC_SUBST(LT_NO_UNDEFINED) |
| | 176 | |
| | 177 | # Compute minor/major/patchlevel version numbers |
| | 178 | major_version=$(echo AC_PACKAGE_VERSION | $SED 's/^\([[0-9]]\)*\.[[0-9]]*\.[[0-9]]*.*$/\1/') |
| | 179 | minor_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.\([[0-9]]*\)\.[[0-9]]*.*$/\1/') |
| | 180 | patchlevel_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\).*$/\1/') |
| | 181 | |
| | 182 | AC_SUBST([MAJOR_VERSION], [$major_version]) |
| | 183 | AC_SUBST([MINOR_VERSION], [$minor_version]) |
| | 184 | AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version]) |
| | 185 | AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [LTTng-Tools major version number]) |
| | 186 | AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [LTTng-Tools minor version number]) |
| | 187 | AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [LTTng-Tools patchlevel version number]) |
| | 188 | |
| | 189 | version_name="Nordicité" |
| | 190 | version_description="The product of a collaboration between Champ Libre and Boréale, this farmhouse IPA is brewed with Kveik yeast and Québec-grown barley, oats and juniper branches. The result is a remarkable fruity hazy golden IPA that offers a balanced touch of resinous and woodsy bitterness." |
| | 191 | version_description_c=$(echo $version_description | $SED 's/"/\\"/g') |
| | 192 | |
| | 193 | AC_DEFINE_UNQUOTED([VERSION_NAME], ["$version_name"], "") |
| | 194 | AC_DEFINE_UNQUOTED([VERSION_DESCRIPTION], ["$version_description_c"], "") |
| | 195 | |
| | 196 | # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321. |
| | 197 | AC_ARG_ENABLE(libtool-linkdep-fixup, |
| | 198 | AS_HELP_STRING([--disable-libtool-linkdep-fixup], |
| | 199 | [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)]), |
| | 200 | libtool_fixup=$enableval, |
| | 201 | libtool_fixup=yes) |
| | 202 | |
| | 203 | AS_IF([test "x$libtool_fixup" = "xyes"], |
| | 204 | [ |
| | 205 | libtool_m4="$srcdir/m4/libtool.m4" |
| | 206 | libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)" |
| | 207 | AC_MSG_CHECKING([for occurrence(s) of link_all_deplibs = no in $libtool_m4]) |
| | 208 | libtool_flag_pattern_count=$($GREP -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4) |
| | 209 | AS_IF([test $libtool_flag_pattern_count -ne 0], |
| | 210 | [ |
| | 211 | AC_MSG_RESULT([$libtool_flag_pattern_count]) |
| | 212 | AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown]) |
| | 213 | $SED -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4 |
| | 214 | ], |
| | 215 | [ |
| | 216 | AC_MSG_RESULT([none]) |
| | 217 | ]) |
| | 218 | ]) |
| | 219 | |
| | 220 | AM_CONDITIONAL([NO_SHARED], [test x$enable_shared = xno]) |
| | 221 | |
| | 222 | AC_CHECK_HEADERS([ \ |
| | 223 | sys/types.h unistd.h fcntl.h string.h pthread.h limits.h \ |
| | 224 | signal.h stdlib.h sys/un.h sys/socket.h stdlib.h stdio.h \ |
| | 225 | getopt.h sys/ipc.h sys/shm.h popt.h grp.h arpa/inet.h \ |
| | 226 | netdb.h netinet/in.h paths.h stddef.h sys/file.h sys/ioctl.h \ |
| | 227 | sys/mount.h sys/param.h sys/time.h elf.h sys/random.h sys/syscall.h |
| | 228 | ]) |
| | 229 | |
| | 230 | AM_CONDITIONAL([HAVE_ELF_H], [test x$ac_cv_header_elf_h = xyes]) |
| | 231 | |
| | 232 | # Basic functions check |
| | 233 | AC_CHECK_FUNCS([ \ |
| | 234 | atexit bzero clock_gettime dup2 fdatasync fls ftruncate \ |
| | 235 | gethostbyname gethostname getpagesize localtime_r memchr memrchr memset \ |
| | 236 | mkdir munmap putenv realpath rmdir socket strchr strcspn strdup \ |
| | 237 | strncasecmp strndup strnlen strpbrk strrchr strstr strtol strtoul \ |
| | 238 | strtoull dirfd gethostbyname2 getipnodebyname epoll_create1 \ |
| | 239 | sched_getcpu sysconf sync_file_range getrandom flock |
| | 240 | ]) |
| | 241 | |
| | 242 | # Check for pthread_setname_np and pthread_getname_np |
| | 243 | LTTNG_PTHREAD_SETNAME_NP |
| | 244 | LTTNG_PTHREAD_GETNAME_NP |
| | 245 | |
| | 246 | # Check if clock_gettime, timer_create, timer_settime, and timer_delete are available in lib rt, and if so, |
| | 247 | # add -lrt to LIBS |
| | 248 | AC_CHECK_LIB([rt], [clock_gettime, timer_create, timer_settime, timer_delete]) |
| | 249 | |
| | 250 | # Checks for dl. |
| | 251 | AC_CHECK_LIB([dl], [dlopen], [ |
| | 252 | have_libdl=yes |
| | 253 | libdl_name=dl |
| | 254 | DL_LIBS="-ldl" |
| | 255 | ], [ |
| | 256 | # libdl not found, check for dlopen in libc. |
| | 257 | AC_CHECK_LIB([c], [dlopen], [ |
| | 258 | have_libc_dl=yes |
| | 259 | libdl_name=c |
| | 260 | DL_LIBS="-lc" |
| | 261 | ], [ |
| | 262 | AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.]) |
| | 263 | ]) |
| | 264 | ]) |
| | 265 | AC_SUBST(DL_LIBS) |
| | 266 | |
| | 267 | # Check if libdl has dlmopen support. |
| | 268 | AH_TEMPLATE([HAVE_DLMOPEN], ["Define to 1 if dlmopen is available."]) |
| | 269 | AC_CHECK_LIB([$libdl_name], [dlmopen], [ |
| | 270 | AC_DEFINE([HAVE_DLMOPEN], [1]) |
| | 271 | HAVE_DLMOPEN=1 |
| | 272 | ], [ |
| | 273 | HAVE_DLMOPEN=0 |
| | 274 | ]) |
| | 275 | AC_SUBST(HAVE_DLMOPEN) |
| | 276 | |
| | 277 | # Babeltrace viewer check |
| | 278 | AC_ARG_WITH([babeltrace-bin], |
| | 279 | AS_HELP_STRING([--with-babeltrace-bin], |
| | 280 | [Location of the babeltrace viewer executable (including the filename)]), |
| | 281 | [BABELTRACE_BIN="$withval"], |
| | 282 | [BABELTRACE_BIN='']) |
| | 283 | AC_SUBST([BABELTRACE_BIN]) |
| | 284 | |
| | 285 | AC_ARG_WITH([babeltrace2-bin], |
| | 286 | AS_HELP_STRING([--with-babeltrace2-bin], |
| | 287 | [Location of the babeltrace2 viewer executable (including the filename)]), |
| | 288 | [BABELTRACE2_BIN="$withval"], |
| | 289 | [BABELTRACE2_BIN='']) |
| | 290 | AC_SUBST([BABELTRACE2_BIN]) |
| | 291 | |
| | 292 | AC_ARG_WITH([consumerd32-bin], |
| | 293 | AS_HELP_STRING([--with-consumerd32-bin], |
| | 294 | [Location of the 32-bit consumerd executable (including the filename)]), |
| | 295 | [CONSUMERD32_BIN="$withval"], |
| | 296 | [CONSUMERD32_BIN='']) |
| | 297 | AC_SUBST([CONSUMERD32_BIN]) |
| | 298 | |
| | 299 | AC_ARG_WITH([consumerd64-bin], |
| | 300 | AS_HELP_STRING([--with-consumerd64-bin], |
| | 301 | [Location of the 64-bit consumerd executable (including the filename)]), |
| | 302 | [CONSUMERD64_BIN="$withval"], |
| | 303 | [CONSUMERD64_BIN='']) |
| | 304 | AC_SUBST([CONSUMERD64_BIN]) |
| | 305 | |
| | 306 | AC_ARG_WITH([consumerd32-libdir], |
| | 307 | AS_HELP_STRING([--with-consumerd32-libdir], |
| | 308 | [Directory containing the 32-bit consumerd libraries]), |
| | 309 | [CONSUMERD32_LIBDIR="$withval"], |
| | 310 | [CONSUMERD32_LIBDIR='']) |
| | 311 | AC_SUBST([CONSUMERD32_LIBDIR]) |
| | 312 | |
| | 313 | AC_ARG_WITH([consumerd64-libdir], |
| | 314 | AS_HELP_STRING([--with-consumerd64-libdir], |
| | 315 | [Directory containing the 64-bit consumerd libraries]), |
| | 316 | [CONSUMERD64_LIBDIR="$withval"], |
| | 317 | [CONSUMERD64_LIBDIR='']) |
| | 318 | AC_SUBST([CONSUMERD64_LIBDIR]) |
| | 319 | |
| | 320 | AC_ARG_WITH([sessiond-bin], |
| | 321 | AS_HELP_STRING([--with-sessiond-bin], |
| | 322 | [Location of the sessiond executable (including the filename)]), |
| | 323 | [SESSIOND_BIN="$withval"], |
| | 324 | [SESSIOND_BIN='']) |
| | 325 | AC_SUBST([SESSIOND_BIN]) |
| | 326 | |
| | 327 | AC_ARG_WITH([lttng-system-rundir], |
| | 328 | AS_HELP_STRING([--with-lttng-system-rundir], |
| | 329 | [Location of the system directory where the system-wide lttng-sessiond runtime files are kept. The default is "/var/run/lttng".]), |
| | 330 | [LTTNG_SYSTEM_RUNDIR="$withval"], |
| | 331 | [LTTNG_SYSTEM_RUNDIR="/var/run/lttng"]) |
| | 332 | AC_SUBST([LTTNG_SYSTEM_RUNDIR]) |
| | 333 | |
| | 334 | AC_ARG_ENABLE([test-java-agent-jul], |
| | 335 | [AS_HELP_STRING([--enable-test-java-agent-jul],[enable the LTTng UST Java agent JUL tests [default=no]])], |
| | 336 | [test_java_agent_jul=$enableval], |
| | 337 | [test_java_agent_jul=no] |
| | 338 | ) |
| | 339 | |
| | 340 | AC_ARG_ENABLE([test-java-agent-log4j], |
| | 341 | [AS_HELP_STRING([--enable-test-java-agent-log4j],[enable the LTTng UST Java agent Log4j 1.x tests [default=no]])], |
| | 342 | [test_java_agent_log4j=$enableval], |
| | 343 | [test_java_agent_log4j=no] |
| | 344 | ) |
| | 345 | |
| | 346 | AC_ARG_ENABLE([test-java-agent-log4j2], |
| | 347 | [AS_HELP_STRING([--enable-test-java-agent-log4j2],[enable the LTTng UST Java agent Log4j 2.x tests [default=no]])], |
| | 348 | [test_java_agent_log4j2=$enableval], |
| | 349 | [test_java_agent_log4j2=no] |
| | 350 | ) |
| | 351 | |
| | 352 | AC_ARG_ENABLE([test-java-agent-all], |
| | 353 | [AS_HELP_STRING([--enable-test-java-agent-all],[enable all the LTTng UST Java agent tests [default=no]])], |
| | 354 | [test_java_agent_jul=$enableval |
| | 355 | test_java_agent_log4j=$enableval], |
| | 356 | [:] |
| | 357 | ) |
| | 358 | |
| | 359 | AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_BIN], "$CONSUMERD32_BIN", [Location of the 32-bit consumerd executable.]) |
| | 360 | AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_BIN], "$CONSUMERD64_BIN", [Location of the 64-bit consumerd executable]) |
| | 361 | AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_LIBDIR], "$CONSUMERD32_LIBDIR", [Search for consumerd 32-bit libraries in this location.]) |
| | 362 | AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_LIBDIR], "$CONSUMERD64_LIBDIR", [Search for consumerd 64-bit libraries in this location.]) |
| | 363 | AC_DEFINE_UNQUOTED([CONFIG_BABELTRACE_BIN], "$BABELTRACE_BIN", [Location of the babeltrace viewer executable.]) |
| | 364 | AC_DEFINE_UNQUOTED([CONFIG_BABELTRACE2_BIN], "$BABELTRACE2_BIN", [Location of the babeltrace2 viewer executable.]) |
| | 365 | AC_DEFINE_UNQUOTED([CONFIG_SESSIOND_BIN], "$SESSIOND_BIN", [Location of the sessiond executable.]) |
| | 366 | AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_RUNDIR], ["$LTTNG_SYSTEM_RUNDIR"], [LTTng system runtime directory]) |
| | 367 | |
| | 368 | AC_DEFUN([_AC_DEFINE_AND_SUBST], [ |
| | 369 | AC_DEFINE_UNQUOTED([CONFIG_$1], [$2], [$1]) |
| | 370 | $1="$2" |
| | 371 | AC_SUBST([$1]) |
| | 372 | ]) |
| | 373 | |
| | 374 | AC_DEFUN([_AC_DEFINE_QUOTED_AND_SUBST], [ |
| | 375 | AC_DEFINE_UNQUOTED([CONFIG_$1], ["$2"], [$1]) |
| | 376 | $1="$2" |
| | 377 | AC_SUBST([$1]) |
| | 378 | ]) |
| | 379 | |
| | 380 | # Default values |
| | 381 | m4_define([_DEFAULT_CHANNEL_SUBBUF_SIZE], [16384]) |
| | 382 | m4_define([_DEFAULT_CHANNEL_SUBBUF_NUM], [4]) |
| | 383 | m4_define([_DEFAULT_CHANNEL_SWITCH_TIMER], [0]) |
| | 384 | m4_define([_DEFAULT_CHANNEL_LIVE_TIMER], [0]) |
| | 385 | m4_define([_DEFAULT_CHANNEL_READ_TIMER], [200000]) |
| | 386 | m4_define([_DEFAULT_CHANNEL_MONITOR_TIMER], [1000000]) |
| | 387 | m4_define([_DEFAULT_CHANNEL_BLOCKING_TIMEOUT], [0]) |
| | 388 | _AC_DEFINE_AND_SUBST([DEFAULT_AGENT_TCP_PORT_RANGE_BEGIN], [5345]) |
| | 389 | _AC_DEFINE_AND_SUBST([DEFAULT_AGENT_TCP_PORT_RANGE_END], [5354]) |
| | 390 | _AC_DEFINE_AND_SUBST([DEFAULT_APP_SOCKET_RW_TIMEOUT], [5]) |
| | 391 | _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE]) |
| | 392 | _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_COUNT], [0]) |
| | 393 | _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_SIZE], [0]) |
| | 394 | _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER]) |
| | 395 | _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_READ_TIMER], [_DEFAULT_CHANNEL_READ_TIMER]) |
| | 396 | _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM]) |
| | 397 | _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_SIZE], [1048576]) |
| | 398 | _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER]) |
| | 399 | _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER]) |
| | 400 | _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_BLOCKING_TIMEOUT], [_DEFAULT_CHANNEL_BLOCKING_TIMEOUT]) |
| | 401 | _AC_DEFINE_AND_SUBST([DEFAULT_LTTNG_LIVE_TIMER], [1000000]) |
| | 402 | _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_CACHE_SIZE], [4096]) |
| | 403 | _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_READ_TIMER], [0]) |
| | 404 | _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_NUM], [2]) |
| | 405 | _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_SIZE], [4096]) |
| | 406 | _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER]) |
| | 407 | _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_CONTROL_PORT], [5342]) |
| | 408 | _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_DATA_PORT], [5343]) |
| | 409 | _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_VIEWER_PORT], [5344]) |
| | 410 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER]) |
| | 411 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_READ_TIMER], [0]) |
| | 412 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_BLOCKING_TIMEOUT], [0]) |
| | 413 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM]) |
| | 414 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE]) |
| | 415 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER]) |
| | 416 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER]) |
| | 417 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER]) |
| | 418 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_READ_TIMER], [0]) |
| | 419 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_BLOCKING_TIMEOUT], [0]) |
| | 420 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM]) |
| | 421 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_SIZE], [524288]) |
| | 422 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER]) |
| | 423 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER]) |
| | 424 | _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_AGENT_BIND_ADDRESS], [localhost]) |
| | 425 | _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_CONTROL_BIND_ADDRESS], [0.0.0.0]) |
| | 426 | _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_DATA_BIND_ADDRESS], [0.0.0.0]) |
| | 427 | _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_VIEWER_BIND_ADDRESS], [localhost]) |
| | 428 | _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_RELAYD_CTRL_MAX_PAYLOAD_SIZE], [134217728]) |
| | 429 | _AC_DEFINE_AND_SUBST([DEFAULT_ROTATE_PENDING_TIMER], [500000]) |
| | 430 | _AC_DEFINE_AND_SUBST([DEFAULT_EVENT_NOTIFIER_ERROR_COUNT_MAP_SIZE], [4096]) |
| | 431 | |
| | 432 | # Command short descriptions |
| | 433 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ADD_CONTEXT], [Add context fields to be recorded]) |
| | 434 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ADD_TRIGGER], [Add a trigger]) |
| | 435 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_CLEAR], [Clear a recording session]) |
| | 436 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_CREATE], [Create a recording session]) |
| | 437 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DESTROY], [Destroy recording sessions]) |
| | 438 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_CHANNEL], [Disable channels]) |
| | 439 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_EVENT], [Disable recording event rules]) |
| | 440 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_ROTATION], [Unset a recording session rotation schedule]) |
| | 441 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_CHANNEL], [Create or enable a channel]) |
| | 442 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_EVENT], [Create or enable recording event rules]) |
| | 443 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_ROTATION], [Set a recording session rotation schedule]) |
| | 444 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_HELP], [Show the help of a command]) |
| | 445 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LIST], [List recording sessions and instrumentation points]) |
| | 446 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LIST_TRIGGERS], [List triggers]) |
| | 447 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LOAD], [Load recording session configurations]) |
| | 448 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_REGENERATE], [Regenerate specific recording session data]) |
| | 449 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_REMOVE_TRIGGER], [Remove a trigger]) |
| | 450 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ROTATE], [Archive the current trace chunk of a recording session]) |
| | 451 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SAVE], [Save recording session configurations]) |
| | 452 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SET_SESSION], [Set the current recording session]) |
| | 453 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SNAPSHOT], [Take a recording session snapshot]) |
| | 454 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_START], [Start a recording session]) |
| | 455 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STATUS], [Show the status of the current recording session]) |
| | 456 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STOP], [Stop a recording session]) |
| | 457 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_TRACK], [Allow specific processes to record events]) |
| | 458 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_UNTRACK], [Disallow specific processes to record events]) |
| | 459 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VERSION], [Show LTTng-tools version information]) |
| | 460 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VIEW], [Launch a trace reader]) |
| | 461 | |
| | 462 | if test "x$prefix" = "xNONE"; then |
| | 463 | prefix=$ac_default_prefix |
| | 464 | fi |
| | 465 | CONFDIR=`eval echo $sysconfdir` |
| | 466 | AC_SUBST(CONFDIR) |
| | 467 | AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_CONFIGDIR],"$CONFDIR", [LTTng system configuration directory.]) |
| | 468 | |
| | 469 | AX_DEFINE_DIR([CONFIG_LTTNG_SYSTEM_DATADIR], [datadir], [LTTng system data directory.]) |
| | 470 | |
| | 471 | # Check libpopt |
| | 472 | PKG_CHECK_MODULES([POPT], [popt], |
| | 473 | [ |
| | 474 | dnl PKG_CHECK_MODULES defines POPT_LIBS |
| | 475 | ], |
| | 476 | [ |
| | 477 | AC_MSG_WARN([pkg-config was unable to find a valid .pc for libpopt. Set PKG_CONFIG_PATH to specify the pkgconfig configuration file location]) |
| | 478 | AC_MSG_WARN([Finding libpopt without pkg-config.]) |
| | 479 | AC_CHECK_LIB([popt], |
| | 480 | [poptGetContext], |
| | 481 | [POPT_LIBS="-lpopt"], |
| | 482 | [ |
| | 483 | AC_MSG_FAILURE([Cannot find libpopt. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location]) |
| | 484 | ] |
| | 485 | ) |
| | 486 | ] |
| | 487 | ) |
| | 488 | AC_SUBST(POPT_LIBS) |
| | 489 | |
| | 490 | PKG_CHECK_MODULES([libxml2], [libxml-2.0 >= 2.7.6]) |
| | 491 | |
| | 492 | AC_CHECK_FUNC([clock_gettime], [AC_DEFINE_UNQUOTED([LTTNG_HAVE_CLOCK_GETTIME], 1, [Has clock_gettime() support.])]) |
| | 493 | |
| | 494 | # URCU library version needed or newer |
| | 495 | PKG_CHECK_MODULES([URCU], [liburcu >= 0.11]) |
| | 496 | PKG_CHECK_MODULES([URCU_BP], [liburcu-bp >= 0.11]) |
| | 497 | PKG_CHECK_MODULES([URCU_CDS], [liburcu-cds >= 0.11]) |
| | 498 | AM_CPPFLAGS="$AM_CPPFLAGS $URCU_CFLAGS" |
| | 499 | |
| | 500 | # Check for libkmod, it will be auto-neabled if found but won't fail if it's not, |
| | 501 | # it can be explicitly disabled with --without-kmod |
| | 502 | AH_TEMPLATE([HAVE_KMOD], [Define if you have kmod support]) |
| | 503 | AC_ARG_WITH([kmod], |
| | 504 | [AS_HELP_STRING([--with-kmod], [build with lkmod support @<:@default=check@:>@])], |
| | 505 | [], |
| | 506 | [with_kmod=check] |
| | 507 | ) |
| | 508 | |
| | 509 | AS_IF([test "x$with_kmod" != "xno"], |
| | 510 | [ |
| | 511 | AC_CHECK_LIB([kmod], [kmod_module_probe_insert_module], |
| | 512 | [ |
| | 513 | AC_DEFINE([HAVE_KMOD], [1]) |
| | 514 | KMOD_LIBS="-lkmod" |
| | 515 | ], |
| | 516 | [ |
| | 517 | if test "x$with_kmod" != xcheck; then |
| | 518 | AC_MSG_FAILURE([Cannot find libkmod. Use [LDFLAGS]=-Ldir and [CPPFLAGS]=-Idir to specify its location.]) |
| | 519 | else |
| | 520 | with_kmod=no |
| | 521 | fi |
| | 522 | ] |
| | 523 | ) |
| | 524 | ] |
| | 525 | ) |
| | 526 | AC_SUBST(KMOD_LIBS) |
| | 527 | |
| | 528 | # Check for liblttng-ust-ctl, fail if it's not found, |
| | 529 | # it can be explicitly disabled with --without-lttng-ust |
| | 530 | AH_TEMPLATE([HAVE_LIBLTTNG_UST_CTL], [Define if you have LTTng-UST control support]) |
| | 531 | AC_ARG_WITH([lttng-ust], |
| | 532 | [AS_HELP_STRING([--without-lttng-ust], [build without LTTng-UST (Userspace Tracing) support])], |
| | 533 | [], |
| | 534 | [with_lttng_ust=yes] |
| | 535 | ) |
| | 536 | |
| | 537 | AS_IF([test "x$with_lttng_ust" = "xyes"], [ |
| | 538 | AC_DEFINE([HAVE_LIBLTTNG_UST_CTL], [1]) |
| | 539 | |
| | 540 | # Check for liblttng-ust |
| | 541 | PKG_CHECK_MODULES([UST], [lttng-ust >= $major_version.$minor_version]) |
| | 542 | |
| | 543 | # Check for liblttng-ust-ctl |
| | 544 | PKG_CHECK_MODULES([UST_CTL], [lttng-ust-ctl >= $major_version.$minor_version]) |
| | 545 | |
| | 546 | AM_CPPFLAGS="$AM_CPPFLAGS $UST_CFLAGS" |
| | 547 | ]) |
| | 548 | |
| | 549 | AM_CONDITIONAL([HAVE_LIBLTTNG_UST_CTL], [test "x$with_lttng_ust" = "xyes"]) |
| | 550 | |
| | 551 | |
| | 552 | # Check for fmemopen |
| | 553 | AC_CHECK_LIB([c], [fmemopen], |
| | 554 | [ |
| | 555 | AC_DEFINE_UNQUOTED([LTTNG_HAVE_FMEMOPEN], 1, [Has fmemopen support.]) |
| | 556 | ] |
| | 557 | ) |
| | 558 | |
| | 559 | # check for libpfm |
| | 560 | AC_CHECK_LIB([pfm], [pfm_initialize], |
| | 561 | [ |
| | 562 | have_libpfm=yes |
| | 563 | ]) |
| | 564 | AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBPFM], [test "x$have_libpfm" = "xyes"]) |
| | 565 | |
| | 566 | # For Python |
| | 567 | # SWIG version needed or newer: |
| | 568 | swig_version=2.0.0 |
| | 569 | |
| | 570 | AC_ARG_ENABLE([python-bindings], |
| | 571 | [AS_HELP_STRING([--enable-python-bindings], |
| | 572 | [compile Python bindings])], |
| | 573 | [enable_python_binding=$enableval], [enable_python_binding=no]) |
| | 574 | |
| | 575 | AM_CONDITIONAL([PYTHON_BINDING], [test "x$enable_python_binding" = xyes]) |
| | 576 | |
| | 577 | if test "x$enable_python_binding" = xyes; then |
| | 578 | AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ]) |
| | 579 | AS_IF([test x$enable_shared = xno], [ AC_MSG_ERROR([Python bindings require shared libraries.]) ]) |
| | 580 | AM_PATH_PYTHON([3.0]) |
| | 581 | |
| | 582 | AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config]) |
| | 583 | AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config]) |
| | 584 | AS_IF([test -z "$PYTHON_INCLUDE"], [ |
| | 585 | AS_IF([test -z "$PYTHON_CONFIG"], [ |
| | 586 | AC_PATH_PROGS([PYTHON_CONFIG], |
| | 587 | [python$PYTHON_VERSION-config python-config], |
| | 588 | [], |
| | 589 | [`dirname $PYTHON`]) |
| | 590 | AS_IF([test "x$PYTHON_CONFIG" = "x"], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])]) |
| | 591 | ]) |
| | 592 | AC_MSG_CHECKING([python include flags]) |
| | 593 | PYTHON_INCLUDE=`$PYTHON_CONFIG --includes` |
| | 594 | AC_MSG_RESULT([$PYTHON_INCLUDE]) |
| | 595 | ]) |
| | 596 | |
| | 597 | else |
| | 598 | AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl |
| | 599 | [if you want Python bindings.]) |
| | 600 | |
| | 601 | fi |
| | 602 | |
| | 603 | # Epoll check. If not present, the build will fallback on poll() API |
| | 604 | AX_HAVE_EPOLL( |
| | 605 | [AX_CONFIG_FEATURE_ENABLE(epoll)], |
| | 606 | [AX_CONFIG_FEATURE_DISABLE(epoll)] |
| | 607 | ) |
| | 608 | AX_CONFIG_FEATURE( |
| | 609 | [epoll], [This platform supports epoll(7)], |
| | 610 | [HAVE_EPOLL], [This platform supports epoll(7).] |
| | 611 | ) |
| | 612 | |
| | 613 | AS_IF([test "x$ac_cv_func_dirfd" = "xyes"], |
| | 614 | [AX_CONFIG_FEATURE_ENABLE(dirfd)], |
| | 615 | [AX_CONFIG_FEATURE_DISABLE(dirfd)] |
| | 616 | ) |
| | 617 | AX_CONFIG_FEATURE( |
| | 618 | [dirfd], [Use directory file descriptors], |
| | 619 | [HAVE_DIRFD], [This platform supports directory file descriptors.] |
| | 620 | ) |
| | 621 | |
| | 622 | AM_CONDITIONAL([TEST_JAVA_JUL_AGENT], [test "x$test_java_agent_jul" = "xyes"]) |
| | 623 | AM_CONDITIONAL([TEST_JAVA_LOG4J_AGENT], [test "x$test_java_agent_log4j" = "xyes"]) |
| | 624 | AM_CONDITIONAL([TEST_JAVA_LOG4J2_AGENT], [test "x$test_java_agent_log4j2" = "xyes"]) |
| | 625 | |
| | 626 | if test "x$test_java_agent_jul" = "xyes" || test "x$test_java_agent_log4j" = "xyes" || test "x$test_java_agent_log4j2" = "xyes"; then |
| | 627 | AX_JAVA_OPTIONS |
| | 628 | AX_PROG_JAVAC |
| | 629 | AX_PROG_JAVA |
| | 630 | AX_PROG_JAR |
| | 631 | |
| | 632 | AX_CHECK_CLASSPATH |
| | 633 | |
| | 634 | # Check for Java UST agent common class first |
| | 635 | AX_CHECK_CLASS(org.lttng.ust.agent.AbstractLttngAgent) |
| | 636 | if test "x$ac_cv_class_org_lttng_ust_agent_AbstractLttngAgent" = "xno"; then |
| | 637 | AC_MSG_ERROR([The UST Java agent common class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-common.jar"]) |
| | 638 | fi |
| | 639 | |
| | 640 | if test "x$test_java_agent_jul" = "xyes"; then |
| | 641 | # Check for JUL agent class |
| | 642 | AX_CHECK_CLASS(org.lttng.ust.agent.jul.LttngLogHandler) |
| | 643 | if test "x$ac_cv_class_org_lttng_ust_agent_jul_LttngLogHandler" = "xno"; then |
| | 644 | AC_MSG_ERROR([The UST Java agent JUL class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-jul.jar"]) |
| | 645 | fi |
| | 646 | fi |
| | 647 | |
| | 648 | if test "x$test_java_agent_log4j" = "xyes"; then |
| | 649 | # Check for Log4j agent class |
| | 650 | AX_CHECK_CLASS(org.lttng.ust.agent.log4j.LttngLogAppender) |
| | 651 | if test "x$ac_cv_class_org_lttng_ust_agent_log4j_LttngLogAppender" = "xno"; then |
| | 652 | AC_MSG_ERROR([The UST Java agent Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-log4j.jar"]) |
| | 653 | fi |
| | 654 | |
| | 655 | # Check for Log4j class |
| | 656 | AX_CHECK_CLASS(org.apache.log4j.Logger) |
| | 657 | if test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"; then |
| | 658 | AC_MSG_ERROR([The Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j.jar"]) |
| | 659 | fi |
| | 660 | fi |
| | 661 | |
| | 662 | if test "x$test_java_agent_log4j2" = "xyes"; then |
| | 663 | # Check for Log4j2 agent class |
| | 664 | AX_CHECK_CLASS(org.lttng.ust.agent.log4j2.LttngLogAppender) |
| | 665 | if test "x$ac_cv_class_org_lttng_ust_agent_log4j2_LttngLogAppender" = "xno"; then |
| | 666 | AC_MSG_ERROR([The UST Java agent Log4j 2.x class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-log4j2.jar"]) |
| | 667 | fi |
| | 668 | |
| | 669 | # Check for Log4j 2.x classes |
| | 670 | AX_CHECK_CLASS([org.apache.logging.log4j.Logger]) |
| | 671 | AX_CHECK_CLASS([org.apache.logging.log4j.core.Core]) |
| | 672 | if test "x$ac_cv_class_org_apache_logging_log4j_Logger" = "xno" || test "x$ac_cv_class_org_apache_logging_log4j_core_Core" = "xno"; then |
| | 673 | AC_MSG_ERROR([The Log4j 2.x API or core class was not found. Please specify the location of the jars via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j-core.jar:/path/to/log4j-api.jar"]) |
| | 674 | fi |
| | 675 | fi |
| | 676 | fi |
| | 677 | |
| | 678 | # enable building man pages (user's intention) |
| | 679 | AC_ARG_ENABLE( |
| | 680 | man-pages, |
| | 681 | AS_HELP_STRING( |
| | 682 | [--disable-man-pages], |
| | 683 | [Do not build and install man pages (already built in a distributed tarball)] |
| | 684 | ), |
| | 685 | [man_pages_opt=$enableval], |
| | 686 | [man_pages_opt=yes] |
| | 687 | ) |
| | 688 | |
| | 689 | # check for asciidoc and xmlto if we enabled building the man pages |
| | 690 | have_asciidoc_xmlto=no |
| | 691 | warn_prebuilt_man_pages=no |
| | 692 | |
| | 693 | AS_IF([test "x$man_pages_opt" = "xyes"], [ |
| | 694 | AC_PATH_PROG([ASCIIDOC], [asciidoc]) |
| | 695 | AC_PATH_PROG([XMLTO], [xmlto]) |
| | 696 | |
| | 697 | AS_IF([test "x$ASCIIDOC" = "x" || test "x$XMLTO" = "x"], [ |
| | 698 | AS_IF([test "x$in_git_repo" = "xyes"], [ |
| | 699 | # this is an error because we're in the Git repo, which |
| | 700 | # means the man pages are not already generated for us, |
| | 701 | # thus asciidoc/xmlto are required because we were asked |
| | 702 | # to build the man pages |
| | 703 | AC_MSG_ERROR([ |
| | 704 | You need asciidoc and xmlto to build the LTTng-tools man pages. Use |
| | 705 | --disable-man-pages to disable building the man pages, in which case |
| | 706 | they will not be installed. |
| | 707 | ]) |
| | 708 | ], [ |
| | 709 | # only warn here: since we're in the tarball, the man |
| | 710 | # pages should already be generated at this point, thus |
| | 711 | # asciidoc/xmlto are not strictly required |
| | 712 | warn_prebuilt_man_pages=yes |
| | 713 | ]) |
| | 714 | ], [ |
| | 715 | have_asciidoc_xmlto=yes |
| | 716 | ]) |
| | 717 | ]) |
| | 718 | |
| | 719 | # export man page build condition: build the man pages if the user |
| | 720 | # asked for it, and if the tools are available |
| | 721 | AM_CONDITIONAL([MAN_PAGES_OPT], [test "x$man_pages_opt" != "xno"]) |
| | 722 | AM_CONDITIONAL([HAVE_ASCIIDOC_XMLTO], [test "x$have_asciidoc_xmlto" = "xyes"]) |
| | 723 | |
| | 724 | AC_DEFINE_UNQUOTED([MANPATH], ["`eval eval echo $mandir`"], [Path to man pages.]) |
| | 725 | |
| | 726 | # embedded --help message |
| | 727 | AC_ARG_ENABLE( |
| | 728 | [embedded-help], |
| | 729 | AS_HELP_STRING( |
| | 730 | [--enable-embedded-help], |
| | 731 | [Embed the --help messages in the executable files] |
| | 732 | ), |
| | 733 | [embedded_help=$enableval], |
| | 734 | [embedded_help=no] |
| | 735 | ) |
| | 736 | AS_IF([test "x$embedded_help" = "xyes"], [ |
| | 737 | AS_IF([test "x$man_pages_opt" = "xno"], [ |
| | 738 | AC_MSG_ERROR([You need the --enable-man-pages option with the --enable-embedded-help option.]) |
| | 739 | ]) |
| | 740 | AC_PATH_PROG([man_prog_path], [man]) |
| | 741 | AS_IF([test "x$man_prog_path" = "x"], [ |
| | 742 | AC_MSG_ERROR([You need man with the --enable-embedded-help option.]) |
| | 743 | ]) |
| | 744 | AC_DEFINE_UNQUOTED([LTTNG_EMBED_HELP], 1, [Embed --help messages.]) |
| | 745 | AC_SUBST([MANPROG], [$man_prog_path]) |
| | 746 | ]) |
| | 747 | AM_CONDITIONAL([EMBED_HELP], [test "x$embedded_help" != "xno"]) |
| | 748 | |
| | 749 | # Python agent test |
| | 750 | UST_PYTHON_AGENT="lttngust" |
| | 751 | |
| | 752 | AC_ARG_ENABLE(test-python2-agent, |
| | 753 | AS_HELP_STRING([--enable-test-python2-agent], |
| | 754 | [enable tests for python2 agent. Python2 interpreter path can be overridden by setting the PYTHON2 environment variable. Default: Autodetect] |
| | 755 | ),[:],[test_python2_agent_autodetect=yes] |
| | 756 | ) |
| | 757 | |
| | 758 | AC_ARG_ENABLE(test-python3-agent, |
| | 759 | AS_HELP_STRING([--enable-test-python3-agent], |
| | 760 | [enable tests for python3 agent. Python3 interpreter path can be overridden by setting the PYTHON3 environment variable. Default: Autodetect] |
| | 761 | ),[:],[test_python3_agent_autodetect=yes] |
| | 762 | ) |
| | 763 | |
| | 764 | AC_ARG_ENABLE(test-python-agent-all, |
| | 765 | AS_HELP_STRING([--enable-test-python-agent-all], |
| | 766 | [enable test for all python{2/3} agent.] |
| | 767 | ), |
| | 768 | ) |
| | 769 | |
| | 770 | AS_IF([test ! -z "$enable_test_python_agent_all"], [ |
| | 771 | unset test_python2_agent_autodetect |
| | 772 | unset test_python3_agent_autodetect |
| | 773 | ]) |
| | 774 | |
| | 775 | AS_IF([test "x$enable_test_python_agent_all" = "xyes"], [ |
| | 776 | enable_test_python2_agent=yes |
| | 777 | enable_test_python3_agent=yes |
| | 778 | ]) |
| | 779 | |
| | 780 | AS_IF([test "x$enable_test_python_agent_all" = "xno"], [ |
| | 781 | enable_test_python2_agent=no |
| | 782 | enable_test_python3_agent=no |
| | 783 | ]) |
| | 784 | |
| | 785 | |
| | 786 | AS_IF([test "x$enable_test_python2_agent" = "xyes" -o "x$test_python2_agent_autodetect" = "xyes" ], [ |
| | 787 | AS_IF([test -z "$PYTHON2"], [ |
| | 788 | PYTHON2=python2 |
| | 789 | ], [ |
| | 790 | AC_MSG_WARN([Using user-defined PYTHON2 ($PYTHON2) for lttng-ust python2 agent check]) |
| | 791 | ]) |
| | 792 | |
| | 793 | AC_PATH_PROG([PYTHON2_BIN],[$PYTHON2]) |
| | 794 | AS_IF([test -z "$PYTHON2_BIN"], [ |
| | 795 | AS_IF([test -z "$test_python2_agent_autodetect"],[ |
| | 796 | AC_MSG_ERROR([No python2 interpreter found. PYTHON2 can be set to override default interpreter path]) |
| | 797 | ]) |
| | 798 | ], [ |
| | 799 | AC_MSG_CHECKING([for python2 lttng-ust agent]) |
| | 800 | AS_IF([$PYTHON2_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [ |
| | 801 | PYTHON2_AGENT=$PYTHON2_BIN |
| | 802 | AC_MSG_RESULT([yes]) |
| | 803 | RUN_PYTHON_AGENT_TEST=yes |
| | 804 | ], [ |
| | 805 | AC_MSG_RESULT([no]) |
| | 806 | AS_IF([test -z "$test_python2_agent_autodetect"],[ |
| | 807 | AC_MSG_ERROR([No python2 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.]) |
| | 808 | ]) |
| | 809 | ]) |
| | 810 | |
| | 811 | ]) |
| | 812 | |
| | 813 | ]) |
| | 814 | |
| | 815 | AS_IF([test "x$enable_test_python3_agent" = "xyes" -o "x$test_python3_agent_autodetect" = "xyes" ], [ |
| | 816 | AS_IF([test -z "$PYTHON3"], [ |
| | 817 | PYTHON3=python3 |
| | 818 | ], [ |
| | 819 | AC_MSG_WARN([Using user-defined PYTHON3 ($PYTHON3) for lttng-ust python3 agent check]) |
| | 820 | ]) |
| | 821 | |
| | 822 | AC_PATH_PROG([PYTHON3_BIN],[$PYTHON3]) |
| | 823 | AS_IF([test -z "$PYTHON3_BIN"], [ |
| | 824 | AS_IF([test -z "$test_python3_agent_autodetect"],[ |
| | 825 | AC_MSG_ERROR([No python3 interpreter found. PYTHON3 can be set to override default interpreter path]) |
| | 826 | ]) |
| | 827 | ], [ |
| | 828 | AC_MSG_CHECKING([for python3 lttng-ust agent]) |
| | 829 | AS_IF([$PYTHON3_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [ |
| | 830 | PYTHON3_AGENT=$PYTHON3_BIN |
| | 831 | AC_MSG_RESULT([yes]) |
| | 832 | RUN_PYTHON_AGENT_TEST=yes |
| | 833 | ], [ |
| | 834 | AC_MSG_RESULT([no]) |
| | 835 | AS_IF([test -z "$test_python3_agent_autodetect"],[ |
| | 836 | AC_MSG_ERROR([No python3 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.]) |
| | 837 | ]) |
| | 838 | ]) |
| | 839 | |
| | 840 | ]) |
| | 841 | ]) |
| | 842 | AC_SUBST([RUN_PYTHON_AGENT_TEST]) |
| | 843 | AC_SUBST([PYTHON2_AGENT]) |
| | 844 | AC_SUBST([PYTHON3_AGENT]) |
| | 845 | |
| | 846 | AC_ARG_ENABLE([test-sdt-uprobe], |
| | 847 | [AS_HELP_STRING([--enable-test-sdt-uprobe], [enable the LTTng UST SDT uprobe tests [default=autodetect]])], |
| | 848 | [test_sdt_uprobe="$enableval"], |
| | 849 | [test_sdt_uprobe=autodetect] |
| | 850 | ) |
| | 851 | |
| | 852 | AS_IF([test "$test_sdt_uprobe" != "no"], [ |
| | 853 | LTTNG_CHECK_SDT_WORKS |
| | 854 | AC_PATH_PROG([DTRACE], [dtrace]) |
| | 855 | ]) |
| | 856 | |
| | 857 | AS_IF([test "$test_sdt_uprobe" = "yes"], [ |
| | 858 | AS_IF([test "$lttng_cv_sdt_works" = "no"], [ |
| | 859 | AC_MSG_ERROR([Cannot find 'sys/sdt.h'.]) |
| | 860 | ]) |
| | 861 | AS_IF([test "x$DTRACE" = "x"], [ |
| | 862 | AC_MSG_ERROR([Cannot find SystemTap dtrace. You can set the DTRACE variable to override automatic detection.]) |
| | 863 | ]) |
| | 864 | ]) |
| | 865 | |
| | 866 | AS_IF([test "$test_sdt_uprobe" = "autodetect"], [ |
| | 867 | AS_IF([test "$lttng_cv_sdt_works" = "yes"], [ |
| | 868 | AS_IF([test "x$DTRACE" != "x"], [ |
| | 869 | test_sdt_uprobe=yes |
| | 870 | ]) |
| | 871 | ]) |
| | 872 | ]) |
| | 873 | |
| | 874 | AM_CONDITIONAL([TEST_SDT_UPROBE], [test "$test_sdt_uprobe" = "yes"]) |
| | 875 | |
| | 876 | # Arguments for binaries build exclusion |
| | 877 | AC_ARG_ENABLE([bin-lttng], AS_HELP_STRING([--disable-bin-lttng],[Disable the build of lttng binaries])) |
| | 878 | AC_ARG_ENABLE([bin-lttng-consumerd], AS_HELP_STRING([--disable-bin-lttng-consumerd], |
| | 879 | [Disable the build of lttng-consumerd binaries])) |
| | 880 | AC_ARG_ENABLE([bin-lttng-crash], AS_HELP_STRING([--disable-bin-lttng-crash],[Disable the build of lttng-crash binaries])) |
| | 881 | AC_ARG_ENABLE([bin-lttng-relayd], AS_HELP_STRING([--disable-bin-lttng-relayd], |
| | 882 | [Disable the build of lttng-relayd binaries])) |
| | 883 | AC_ARG_ENABLE([bin-lttng-sessiond], AS_HELP_STRING([--disable-bin-lttng-sessiond], |
| | 884 | [Disable the build of lttng-sessiond binaries])) |
| | 885 | AC_ARG_ENABLE([extras], AS_HELP_STRING([--disable-extras], |
| | 886 | [Disable the build of the extra components])) |
| | 887 | |
| | 888 | |
| | 889 | build_lib_consumer=no |
| | 890 | build_lib_health=no |
| | 891 | build_lib_index=no |
| | 892 | build_lib_kernel_consumer=no |
| | 893 | build_lib_kernel_ctl=no |
| | 894 | build_lib_lttng_ctl=no |
| | 895 | build_lib_relayd=no |
| | 896 | build_lib_sessiond_comm=no |
| | 897 | build_lib_testpoint=no |
| | 898 | build_lib_ust_consumer=no |
| | 899 | |
| | 900 | # There is an overlap for enabled dependencies, but this makes everything |
| | 901 | # simpler. libcommon and libconfig are always compiled so they are not repeated |
| | 902 | # here. |
| | 903 | |
| | 904 | # Enable binary dependencies. |
| | 905 | AS_IF([test x$enable_bin_lttng != xno], |
| | 906 | [ |
| | 907 | build_lib_lttng_ctl=yes |
| | 908 | ] |
| | 909 | ) |
| | 910 | |
| | 911 | AS_IF([test x$enable_bin_lttng_consumerd != xno], |
| | 912 | [ |
| | 913 | build_lib_consumer=yes |
| | 914 | build_lib_sessiond_comm=yes |
| | 915 | build_lib_index=yes |
| | 916 | build_lib_health=yes |
| | 917 | build_lib_testpoint=yes |
| | 918 | ] |
| | 919 | ) |
| | 920 | |
| | 921 | AS_IF([test x$enable_bin_lttng_crash != xno], |
| | 922 | # Do nothing since libconfig and libcommon are built by default. |
| | 923 | [] |
| | 924 | ) |
| | 925 | |
| | 926 | AS_IF([test x$enable_bin_lttng_relayd != xno], |
| | 927 | [ |
| | 928 | build_lib_lttng_ctl=yes |
| | 929 | build_lib_sessiond_comm=yes |
| | 930 | build_lib_index=yes |
| | 931 | build_lib_health=yes |
| | 932 | build_lib_testpoint=yes |
| | 933 | ] |
| | 934 | ) |
| | 935 | AS_IF([test x$enable_bin_lttng_sessiond != xno], |
| | 936 | [ |
| | 937 | build_lib_lttng_ctl=yes |
| | 938 | build_lib_sessiond_comm=yes |
| | 939 | build_lib_kernel_ctl=yes |
| | 940 | build_lib_relayd=yes |
| | 941 | build_lib_testpoint=yes |
| | 942 | build_lib_health=yes |
| | 943 | ] |
| | 944 | ) |
| | 945 | |
| | 946 | # Libraries dependencies enabling |
| | 947 | AS_IF([test x$build_lib_lttng_ctl = xyes], |
| | 948 | [ |
| | 949 | build_lib_sessiond_comm=yes |
| | 950 | ] |
| | 951 | ) |
| | 952 | |
| | 953 | AS_IF([test x$build_lib_consumer = xyes], |
| | 954 | [ |
| | 955 | build_lib_sessiond_comm=yes |
| | 956 | build_lib_kernel_consumer=yes |
| | 957 | build_lib_relayd=yes |
| | 958 | AS_IF([test "x$with_lttng_ust" = "xyes"], [build_lib_ust_consumer=yes]) |
| | 959 | ] |
| | 960 | ) |
| | 961 | |
| | 962 | AS_IF([test x$build_lib_kernel_consumer = xyes], |
| | 963 | [ |
| | 964 | build_lib_kernel_ctl=yes |
| | 965 | build_lib_relayd=yes |
| | 966 | ] |
| | 967 | ) |
| | 968 | |
| | 969 | AS_IF([test x$build_lib_relayd = xyes], |
| | 970 | [ |
| | 971 | build_lib_sessiond_comm=yes |
| | 972 | ] |
| | 973 | ) |
| | 974 | |
| | 975 | # Find arch type |
| | 976 | AS_CASE([$host_cpu], |
| | 977 | [k1om], [ARCHTYPE="x86"], |
| | 978 | [i386], [ARCHTYPE="x86"], |
| | 979 | [i486], [ARCHTYPE="x86"], |
| | 980 | [i586], [ARCHTYPE="x86"], |
| | 981 | [i686], [ARCHTYPE="x86"], |
| | 982 | [amd64], [ARCHTYPE="x86"], |
| | 983 | [x86_64], [ARCHTYPE="x86"], |
| | 984 | [powerpc], [ARCHTYPE="ppc"], |
| | 985 | [ppc64], [ARCHTYPE="ppc"], |
| | 986 | [powerpc64], [ARCHTYPE="ppc"], |
| | 987 | [powerpc64le], [ARCHTYPE="ppc"], |
| | 988 | [ppc], [ARCHTYPE="ppc"], |
| | 989 | [s390], [ARCHTYPE="s390"], |
| | 990 | [s390x], [ARCHTYPE="s390"], |
| | 991 | [sparc], [ARCHTYPE="sparc64"], |
| | 992 | [sparc64], [ARCHTYPE="sparc64"], |
| | 993 | [alpha*], [ARCHTYPE="alpha"], |
| | 994 | [ia64], [ARCHTYPE="ia64"], |
| | 995 | [arm*], [ARCHTYPE="arm"], |
| | 996 | [aarch64*], [ARCHTYPE="aarch64"], |
| | 997 | [mips*], [ARCHTYPE="mips"], |
| | 998 | [nios2*], [ARCHTYPE="nios2"], |
| | 999 | [tile*], [ARCHTYPE="tile"], |
| | 1000 | [hppa*], [ARCHTYPE="hppa"], |
| | 1001 | [m68k], [ARCHTYPE="m68k"], |
| | 1002 | [riscv*], [ARCHTYPE="riscv"], |
| | 1003 | [ARCHTYPE="unknown"] |
| | 1004 | ) |
| | 1005 | |
| | 1006 | AC_SUBST(ARCHTYPE) |
| | 1007 | |
| | 1008 | AS_CASE([$host_os], |
| | 1009 | [linux*], [OSTYPE="linux"], |
| | 1010 | [freebsd*], [OSTYPE="freebsd"], |
| | 1011 | [solaris*], [OSTYPE="solaris"], |
| | 1012 | [cygwin*], [OSTYPE="cygwin"], |
| | 1013 | [mingw*], [OSTYPE="mingw"], |
| | 1014 | [OSTYPE="unknown"] |
| | 1015 | ) |
| | 1016 | AC_SUBST(OSTYPE) |
| | 1017 | AM_CONDITIONAL([IS_LINUX], [test $OSTYPE = "linux"]) |
| | 1018 | |
| | 1019 | |
| | 1020 | |
| | 1021 | # Userspace callstack capture is only supported by the Linux kernel on x86. |
| | 1022 | AH_TEMPLATE([HAVE_MODULES_USERSPACE_CALLSTACK_CONTEXT], [Define if you have LTTng-modules userspace callstack tracing support]) |
| | 1023 | AS_IF([test "x$ARCHTYPE" = "xx86" && test "x$OSTYPE" = "xlinux"],[ |
| | 1024 | have_modules_userspace_callstack_context=yes |
| | 1025 | AC_DEFINE([HAVE_MODULES_USERSPACE_CALLSTACK_CONTEXT], [1]) |
| | 1026 | ]) |
| | 1027 | AM_CONDITIONAL([HAVE_MODULES_USERSPACE_CALLSTACK_CONTEXT], [test x$have_modules_userspace_callstack_context = xyes]) |
| | 1028 | |
| | 1029 | # Export binaries build conditions. |
| | 1030 | AM_CONDITIONAL([BUILD_BIN_LTTNG], [test x$enable_bin_lttng != xno]) |
| | 1031 | AM_CONDITIONAL([BUILD_BIN_LTTNG_CONSUMERD], [test x$enable_bin_lttng_consumerd != xno]) |
| | 1032 | AM_CONDITIONAL([BUILD_BIN_LTTNG_CRASH], [test x$enable_bin_lttng_crash != xno]) |
| | 1033 | AM_CONDITIONAL([BUILD_BIN_LTTNG_RELAYD], [test x$enable_bin_lttng_relayd != xno]) |
| | 1034 | AM_CONDITIONAL([BUILD_BIN_LTTNG_SESSIOND], [test x$enable_bin_lttng_sessiond != xno]) |
| | 1035 | |
| | 1036 | # Export the tests and extras build conditions. |
| | 1037 | AS_IF([\ |
| | 1038 | test "x$enable_bin_lttng" != "xno" && \ |
| | 1039 | test "x$enable_bin_lttng_consumerd" != "xno" && \ |
| | 1040 | test "x$enable_bin_lttng_crash" != "xno" && \ |
| | 1041 | test "x$enable_bin_lttng_relayd" != "xno" && \ |
| | 1042 | test "x$enable_bin_lttng_sessiond" != "xno"], |
| | 1043 | [build_tests=yes], |
| | 1044 | [build_tests=no] |
| | 1045 | ) |
| | 1046 | |
| | 1047 | AM_CONDITIONAL([BUILD_TESTS], [test x$build_tests = xyes]) |
| | 1048 | AM_CONDITIONAL([BUILD_EXTRAS], [test x$enable_extras != xno]) |
| | 1049 | |
| | 1050 | # Export libraries build conditions. |
| | 1051 | AM_CONDITIONAL([BUILD_LIB_CONSUMER], [test x$build_lib_consumer = xyes]) |
| | 1052 | AM_CONDITIONAL([BUILD_LIB_HEALTH], [test x$build_lib_health = xyes]) |
| | 1053 | AM_CONDITIONAL([BUILD_LIB_INDEX], [test x$build_lib_index = xyes]) |
| | 1054 | AM_CONDITIONAL([BUILD_LIB_KERNEL_CONSUMER], [test x$build_lib_kernel_consumer = xyes]) |
| | 1055 | AM_CONDITIONAL([BUILD_LIB_KERNEL_CTL], [test x$build_lib_kernel_ctl = xyes]) |
| | 1056 | AM_CONDITIONAL([BUILD_LIB_LTTNG_CTL], [test x$build_lib_lttng_ctl = xyes]) |
| | 1057 | AM_CONDITIONAL([BUILD_LIB_RELAYD], [test x$build_lib_relayd = xyes]) |
| | 1058 | AM_CONDITIONAL([BUILD_LIB_SESSIOND_COMM], [test x$build_lib_sessiond_comm = xyes]) |
| | 1059 | AM_CONDITIONAL([BUILD_LIB_TESTPOINT], [test x$build_lib_testpoint = xyes]) |
| | 1060 | AM_CONDITIONAL([BUILD_LIB_UST_CONSUMER], [test x$build_lib_ust_consumer = xyes]) |
| | 1061 | |
| | 1062 | AM_CFLAGS="${WARN_CFLAGS} -fno-strict-aliasing $PTHREAD_CFLAGS" |
| | 1063 | AC_SUBST(AM_CFLAGS) |
| | 1064 | |
| | 1065 | # This is set even though it is empty, so Makefiles can do "AM_LDFLAGS += ...". |
| | 1066 | AM_LDFLAGS="" |
| | 1067 | AC_SUBST(AM_LDFLAGS) |
| | 1068 | |
| | 1069 | # The order in which the include folders are searched is important. |
| | 1070 | # The top_builddir should always be searched first in the event that a build |
| | 1071 | # time generated file is included. An example of this is the "version.i" file. |
| | 1072 | # In a scenario where lttng-tools is built from a distribution tarball and in a |
| | 1073 | # out-of-tree manner, the generated "version.i" has priority on the one from |
| | 1074 | # the source (distribution tarball) and must be found first. |
| | 1075 | AM_CPPFLAGS="-I\$(top_builddir)/include -I\$(top_srcdir)/include -I\$(top_builddir)/src -I\$(top_srcdir)/src -include config.h $AM_CPPFLAGS" |
| | 1076 | AC_SUBST(AM_CPPFLAGS) |
| | 1077 | |
| | 1078 | lttngincludedir="${includedir}/lttng" |
| | 1079 | AC_SUBST(lttngincludedir) |
| | 1080 | |
| | 1081 | lttngactionincludedir="${includedir}/lttng/action" |
| | 1082 | AC_SUBST(lttngactionincludedir) |
| | 1083 | |
| | 1084 | lttngconditionincludedir="${includedir}/lttng/condition" |
| | 1085 | AC_SUBST(lttngconditionincludedir) |
| | 1086 | |
| | 1087 | lttngnotificationincludedir="${includedir}/lttng/notification" |
| | 1088 | AC_SUBST(lttngnotificationincludedir) |
| | 1089 | |
| | 1090 | lttngtriggerincludedir="${includedir}/lttng/trigger" |
| | 1091 | AC_SUBST(lttngtriggerincludedir) |
| | 1092 | |
| | 1093 | lttngeventruleincludedir="${includedir}/lttng/event-rule" |
| | 1094 | AC_SUBST(lttngeventruleincludedir) |
| | 1095 | |
| | 1096 | lttnglibexecdir="${libdir}/lttng/libexec" |
| | 1097 | AC_SUBST(lttnglibexecdir) |
| | 1098 | |
| | 1099 | AC_CONFIG_FILES([ |
| | 1100 | Makefile |
| | 1101 | doc/Makefile |
| | 1102 | doc/examples/Makefile |
| | 1103 | doc/examples/rotation/Makefile |
| | 1104 | doc/examples/trigger-condition-event-matches/Makefile |
| | 1105 | doc/man/Makefile |
| | 1106 | doc/man/asciidoc-attrs.conf |
| | 1107 | include/Makefile |
| | 1108 | extras/Makefile |
| | 1109 | extras/bindings/Makefile |
| | 1110 | extras/bindings/swig/Makefile |
| | 1111 | extras/bindings/swig/python/Makefile |
| | 1112 | extras/core-handler/Makefile |
| | 1113 | src/Makefile |
| | 1114 | src/common/Makefile |
| | 1115 | src/common/argpar/Makefile |
| | 1116 | src/common/argpar-utils/Makefile |
| | 1117 | src/common/bytecode/Makefile |
| | 1118 | src/common/kernel-ctl/Makefile |
| | 1119 | src/common/kernel-consumer/Makefile |
| | 1120 | src/common/consumer/Makefile |
| | 1121 | src/common/ust-consumer/Makefile |
| | 1122 | src/common/hashtable/Makefile |
| | 1123 | src/common/sessiond-comm/Makefile |
| | 1124 | src/common/compat/Makefile |
| | 1125 | src/common/relayd/Makefile |
| | 1126 | src/common/testpoint/Makefile |
| | 1127 | src/common/index/Makefile |
| | 1128 | src/common/health/Makefile |
| | 1129 | src/common/config/Makefile |
| | 1130 | src/common/string-utils/Makefile |
| | 1131 | src/common/fd-tracker/Makefile |
| | 1132 | src/common/filter/Makefile |
| | 1133 | src/lib/Makefile |
| | 1134 | src/lib/lttng-ctl/Makefile |
| | 1135 | src/lib/lttng-ctl/lttng-ctl.pc |
| | 1136 | src/bin/Makefile |
| | 1137 | src/bin/lttng-consumerd/Makefile |
| | 1138 | src/bin/lttng-sessiond/Makefile |
| | 1139 | src/bin/lttng-relayd/Makefile |
| | 1140 | src/bin/lttng/Makefile |
| | 1141 | src/bin/lttng-crash/Makefile |
| | 1142 | src/vendor/Makefile |
| | 1143 | src/vendor/msgpack/Makefile |
| | 1144 | tests/Makefile |
| | 1145 | tests/destructive/Makefile |
| | 1146 | tests/regression/Makefile |
| | 1147 | tests/regression/kernel/Makefile |
| | 1148 | tests/regression/tools/Makefile |
| | 1149 | tests/regression/tools/streaming/Makefile |
| | 1150 | tests/regression/tools/filtering/Makefile |
| | 1151 | tests/regression/tools/health/Makefile |
| | 1152 | tests/regression/tools/tracefile-limits/Makefile |
| | 1153 | tests/regression/tools/snapshots/Makefile |
| | 1154 | tests/regression/tools/live/Makefile |
| | 1155 | tests/regression/tools/exclusion/Makefile |
| | 1156 | tests/regression/tools/save-load/Makefile |
| | 1157 | tests/regression/tools/save-load/configuration/Makefile |
| | 1158 | tests/regression/tools/mi/Makefile |
| | 1159 | tests/regression/tools/wildcard/Makefile |
| | 1160 | tests/regression/tools/channel/Makefile |
| | 1161 | tests/regression/tools/client/Makefile |
| | 1162 | tests/regression/tools/crash/Makefile |
| | 1163 | tests/regression/tools/regen-metadata/Makefile |
| | 1164 | tests/regression/tools/regen-statedump/Makefile |
| | 1165 | tests/regression/tools/notification/Makefile |
| | 1166 | tests/regression/tools/rotation/Makefile |
| | 1167 | tests/regression/tools/base-path/Makefile |
| | 1168 | tests/regression/tools/metadata/Makefile |
| | 1169 | tests/regression/tools/tracker/Makefile |
| | 1170 | tests/regression/tools/working-directory/Makefile |
| | 1171 | tests/regression/tools/relayd-grouping/Makefile |
| | 1172 | tests/regression/tools/clear/Makefile |
| | 1173 | tests/regression/tools/trigger/Makefile |
| | 1174 | tests/regression/tools/trigger/rate-policy/Makefile |
| | 1175 | tests/regression/tools/trigger/start-stop/Makefile |
| | 1176 | tests/regression/tools/trigger/utils/Makefile |
| | 1177 | tests/regression/tools/trigger/name/Makefile |
| | 1178 | tests/regression/tools/trigger/hidden/Makefile |
| | 1179 | tests/regression/ust/Makefile |
| | 1180 | tests/regression/ust/nprocesses/Makefile |
| | 1181 | tests/regression/ust/high-throughput/Makefile |
| | 1182 | tests/regression/ust/low-throughput/Makefile |
| | 1183 | tests/regression/ust/before-after/Makefile |
| | 1184 | tests/regression/ust/buffers-pid/Makefile |
| | 1185 | tests/regression/ust/periodical-metadata-flush/Makefile |
| | 1186 | tests/regression/ust/multi-session/Makefile |
| | 1187 | tests/regression/ust/multi-lib/Makefile |
| | 1188 | tests/regression/ust/overlap/Makefile |
| | 1189 | tests/regression/ust/overlap/demo/Makefile |
| | 1190 | tests/regression/ust/linking/Makefile |
| | 1191 | tests/regression/ust/daemon/Makefile |
| | 1192 | tests/regression/ust/exit-fast/Makefile |
| | 1193 | tests/regression/ust/fork/Makefile |
| | 1194 | tests/regression/ust/libc-wrapper/Makefile |
| | 1195 | tests/regression/ust/baddr-statedump/Makefile |
| | 1196 | tests/regression/ust/ust-dl/Makefile |
| | 1197 | tests/regression/ust/java-jul/Makefile |
| | 1198 | tests/regression/ust/java-log4j/Makefile |
| | 1199 | tests/regression/ust/java-log4j2/Makefile |
| | 1200 | tests/regression/ust/getcpu-override/Makefile |
| | 1201 | tests/regression/ust/clock-override/Makefile |
| | 1202 | tests/regression/ust/type-declarations/Makefile |
| | 1203 | tests/regression/ust/rotation-destroy-flush/Makefile |
| | 1204 | tests/regression/ust/blocking/Makefile |
| | 1205 | tests/regression/ust/namespaces/Makefile |
| | 1206 | tests/stress/Makefile |
| | 1207 | tests/unit/Makefile |
| | 1208 | tests/unit/ini_config/Makefile |
| | 1209 | tests/perf/Makefile |
| | 1210 | tests/utils/Makefile |
| | 1211 | tests/utils/tap/Makefile |
| | 1212 | tests/utils/testapp/Makefile |
| | 1213 | tests/utils/testapp/gen-data-pending/Makefile |
| | 1214 | tests/utils/testapp/gen-ns-events/Makefile |
| | 1215 | tests/utils/testapp/gen-kernel-test-events/Makefile |
| | 1216 | tests/utils/testapp/gen-py-events/Makefile |
| | 1217 | tests/utils/testapp/gen-ust-events/Makefile |
| | 1218 | tests/utils/testapp/gen-ust-events-ns/Makefile |
| | 1219 | tests/utils/testapp/gen-syscall-events-callstack/Makefile |
| | 1220 | tests/utils/testapp/gen-ust-nevents/Makefile |
| | 1221 | tests/utils/testapp/gen-ust-nevents-str/Makefile |
| | 1222 | tests/utils/testapp/gen-syscall-events/Makefile |
| | 1223 | tests/utils/testapp/gen-ust-tracef/Makefile |
| | 1224 | tests/utils/testapp/userspace-probe-elf-binary/Makefile |
| | 1225 | tests/utils/testapp/userspace-probe-elf-cxx-binary/Makefile |
| | 1226 | tests/utils/testapp/userspace-probe-sdt-binary/Makefile |
| | 1227 | tests/utils/xml-utils/Makefile |
| | 1228 | ]) |
| | 1229 | |
| | 1230 | # Inject variable into python test script. |
| | 1231 | AC_CONFIG_FILES([tests/regression/ust/python-logging/test_python_logging],[chmod +x tests/regression/ust/python-logging/test_python_logging]) |
| | 1232 | # Inject LTTNG_TOOLS_BUILD_WITH_LIBPFM variable in test script. |
| | 1233 | AC_CONFIG_FILES([tests/perf/test_perf_raw],[chmod +x tests/perf/test_perf_raw]) |
| | 1234 | AC_CONFIG_FILES([tests/regression/ust/ust-dl/test_ust-dl],[chmod +x tests/regression/ust/ust-dl/test_ust-dl]) |
| | 1235 | |
| | 1236 | AC_OUTPUT |
| | 1237 | |
| | 1238 | # |
| | 1239 | # Mini-report on what will be built. |
| | 1240 | # |
| | 1241 | |
| | 1242 | PPRINT_INIT |
| | 1243 | PPRINT_SET_INDENT(1) |
| | 1244 | PPRINT_SET_TS(38) |
| | 1245 | |
| | 1246 | AS_ECHO |
| | 1247 | AS_ECHO("${PPRINT_COLOR_BLDBLU}LTTng-tools $PACKAGE_VERSION \"$version_name\"$PPRINT_COLOR_RST") |
| | 1248 | AS_ECHO |
| | 1249 | |
| | 1250 | AS_IF([test -n "$report_fold"], [ |
| | 1251 | AS_ECHO("`AS_ECHO("$version_description") | $report_fold -s`") |
| | 1252 | ], [ |
| | 1253 | AS_ECHO("$version_description") |
| | 1254 | ]) |
| | 1255 | |
| | 1256 | AS_ECHO |
| | 1257 | PPRINT_SUBTITLE([Features]) |
| | 1258 | |
| | 1259 | # Target architecture we're building for. |
| | 1260 | target_arch=$host_cpu |
| | 1261 | [ |
| | 1262 | for f in $CFLAGS; do |
| | 1263 | if test $f = "-m32"; then |
| | 1264 | target_arch="32-bit" |
| | 1265 | elif test $f = "-m64"; then |
| | 1266 | target_arch="64-bit" |
| | 1267 | fi |
| | 1268 | done |
| | 1269 | ] |
| | 1270 | PPRINT_PROP_STRING([Target architecture], $target_arch) |
| | 1271 | |
| | 1272 | # kmod enabled/disabled |
| | 1273 | test "x$with_kmod" != "xno" && value=1 || value=0 |
| | 1274 | PPRINT_PROP_BOOL([libkmod support], $value) |
| | 1275 | |
| | 1276 | # LTTng-UST enabled/disabled |
| | 1277 | test "x$with_lttng_ust" = "xyes" && value=1 || value=0 |
| | 1278 | PPRINT_PROP_BOOL([LTTng-UST support], $value) |
| | 1279 | |
| | 1280 | AS_ECHO |
| | 1281 | PPRINT_SUBTITLE([Binaries]) |
| | 1282 | |
| | 1283 | # List binaries to be built |
| | 1284 | test x$enable_bin_lttng != xno && value=1 || value=0 |
| | 1285 | PPRINT_PROP_BOOL([lttng], $value) |
| | 1286 | |
| | 1287 | test x$enable_bin_lttng_consumerd != xno && value=1 || value=0 |
| | 1288 | PPRINT_PROP_BOOL([lttng-consumerd], $value) |
| | 1289 | |
| | 1290 | test x$enable_bin_lttng_crash != xno && value=1 || value=0 |
| | 1291 | PPRINT_PROP_BOOL([lttng-crash], $value) |
| | 1292 | |
| | 1293 | test x$enable_bin_lttng_relayd != xno && value=1 || value=0 |
| | 1294 | PPRINT_PROP_BOOL([lttng-relayd], $value) |
| | 1295 | |
| | 1296 | test x$enable_bin_lttng_sessiond != xno && value=1 || value=0 |
| | 1297 | PPRINT_PROP_BOOL([lttng-sessiond], $value) |
| | 1298 | |
| | 1299 | # Extras |
| | 1300 | test x$enable_extras != xno && value=1 || value=0 |
| | 1301 | AS_ECHO |
| | 1302 | PPRINT_SET_INDENT(0) |
| | 1303 | PPRINT_PROP_BOOL([Extras], $value, $PPRINT_COLOR_SUBTITLE) |
| | 1304 | PPRINT_SET_INDENT(1) |
| | 1305 | |
| | 1306 | AS_ECHO |
| | 1307 | PPRINT_SUBTITLE([Tests]) |
| | 1308 | |
| | 1309 | # Print clear message that tests won't be built |
| | 1310 | AS_IF([test "x$build_tests" = "xno"],[ |
| | 1311 | PPRINT_WARN([Tests won't be built since some binaries were disabled]) |
| | 1312 | ]) |
| | 1313 | |
| | 1314 | # LTTng UST Java agent JUL tests enabled/disabled |
| | 1315 | test "x$test_java_agent_jul" = "xyes" && value=1 || value=0 |
| | 1316 | PPRINT_PROP_BOOL([LTTng-UST Java agent JUL tests], $value) |
| | 1317 | |
| | 1318 | # LTTng UST Java agent Log4j 1.x tests enabled/disabled |
| | 1319 | test "x$test_java_agent_log4j" = "xyes" && value=1 || value=0 |
| | 1320 | PPRINT_PROP_BOOL([LTTng-UST Java agent Log4j 1.x tests], $value) |
| | 1321 | |
| | 1322 | # LTTng UST Java agent Log4j 2.x tests enabled/disabled |
| | 1323 | test "x$test_java_agent_log4j2" = "xyes" && value=1 || value=0 |
| | 1324 | PPRINT_PROP_BOOL([LTTng-UST Java agent Log4j 2.x tests], $value) |
| | 1325 | |
| | 1326 | test ! -z "$PYTHON2_AGENT" && value=1 || value=0 |
| | 1327 | PPRINT_PROP_BOOL([LTTng-UST Python2 agent tests], $value) |
| | 1328 | |
| | 1329 | test ! -z "$PYTHON3_AGENT" && value=1 || value=0 |
| | 1330 | PPRINT_PROP_BOOL([LTTng-UST Python3 agent tests], $value) |
| | 1331 | |
| | 1332 | # userspace-probe SDT instrumentation tests enabled/disabled |
| | 1333 | test "x$test_sdt_uprobe" = "xyes" && value=1 || value=0 |
| | 1334 | PPRINT_PROP_BOOL([LTTng-modules SDT uprobe tests], $value) |
| | 1335 | |
| | 1336 | #Python binding enabled/disabled |
| | 1337 | test "x$enable_python_binding" = xyes && value=1 || value=0 |
| | 1338 | AS_ECHO |
| | 1339 | PPRINT_SET_INDENT(0) |
| | 1340 | PPRINT_PROP_BOOL([Python binding], $value, $PPRINT_COLOR_SUBTITLE) |
| | 1341 | |
| | 1342 | # man pages build enabled/disabled |
| | 1343 | m4_pushdef([build_man_pages_msg], [Build and install man pages]) |
| | 1344 | |
| | 1345 | AS_IF([test "x$man_pages_opt" != "xno"], [ |
| | 1346 | AS_IF([test "x$in_git_repo" = "xyes"], [ |
| | 1347 | PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE) |
| | 1348 | ], [ |
| | 1349 | AS_IF([test "x$have_asciidoc_xmlto" = "xyes"], [ |
| | 1350 | PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE) |
| | 1351 | ], [ |
| | 1352 | PPRINT_PROP_STRING([build_man_pages_msg], |
| | 1353 | [${PPRINT_COLOR_BLDGRN}yes (already built)], |
| | 1354 | $PPRINT_COLOR_SUBTITLE) |
| | 1355 | ]) |
| | 1356 | ]) |
| | 1357 | ], [ |
| | 1358 | PPRINT_PROP_BOOL([build_man_pages_msg], 0, $PPRINT_COLOR_SUBTITLE) |
| | 1359 | ]) |
| | 1360 | |
| | 1361 | m4_popdef([build_man_pages_msg]) |
| | 1362 | |
| | 1363 | test "x$embedded_help" = xyes && value=1 || value=0 |
| | 1364 | PPRINT_PROP_BOOL([Embed --help messages], $value, $PPRINT_COLOR_SUBTITLE) |
| | 1365 | |
| | 1366 | PPRINT_SET_INDENT(1) |
| | 1367 | |
| | 1368 | report_bindir="`eval eval echo $bindir`" |
| | 1369 | report_libdir="`eval eval echo $libdir`" |
| | 1370 | |
| | 1371 | # Print the bindir and libdir this `make install' will install into. |
| | 1372 | AS_ECHO |
| | 1373 | PPRINT_SUBTITLE([Install directories]) |
| | 1374 | PPRINT_PROP_STRING([Binaries], [$report_bindir]) |
| | 1375 | PPRINT_PROP_STRING([Libraries], [$report_libdir]) |
| | 1376 | |
| | 1377 | AS_ECHO |
| | 1378 | PPRINT_SUBTITLE([Search directories]) |
| | 1379 | |
| | 1380 | # If we build the sessiond, print the paths it will use |
| | 1381 | AS_IF([test "$SESSIOND_BIN" = ""],[ |
| | 1382 | path="$report_bindir/lttng-sessiond" |
| | 1383 | ],[ |
| | 1384 | path="$SESSIOND_BIN" |
| | 1385 | ]) |
| | 1386 | PPRINT_PROP_STRING([lttng-sessiond executable], [$path]) |
| | 1387 | |
| | 1388 | AS_IF([test "$CONSUMERD32_BIN" = ""],[ |
| | 1389 | path="`eval eval echo $lttnglibexecdir`/lttng-consumerd" |
| | 1390 | ],[ |
| | 1391 | path="$CONSUMERD32_BIN" |
| | 1392 | ]) |
| | 1393 | PPRINT_PROP_STRING([32-bit lttng-consumerd executable], [$path]) |
| | 1394 | |
| | 1395 | AS_IF([test "$CONSUMERD32_LIBDIR" = ""],[ |
| | 1396 | path="`eval eval echo $libdir`" |
| | 1397 | ],[ |
| | 1398 | path="$CONSUMERD32_LIBDIR" |
| | 1399 | ]) |
| | 1400 | PPRINT_PROP_STRING([32-bit consumer libraries], [$path]) |
| | 1401 | |
| | 1402 | AS_IF([test "$CONSUMERD64_BIN" = ""],[ |
| | 1403 | path="`eval eval echo $lttnglibexecdir`/lttng-consumerd" |
| | 1404 | ],[ |
| | 1405 | path="$CONSUMERD64_BIN" |
| | 1406 | ]) |
| | 1407 | PPRINT_PROP_STRING([64-bit lttng-consumerd executable], [$path]) |
| | 1408 | |
| | 1409 | AS_IF([test "$CONSUMERD64_LIBDIR" = ""],[ |
| | 1410 | path="`eval eval echo $libdir`" |
| | 1411 | ],[ |
| | 1412 | path="$CONSUMERD64_LIBDIR" |
| | 1413 | ]) |
| | 1414 | PPRINT_PROP_STRING([64-bit consumer libraries], [$path]) |
| | 1415 | PPRINT_SET_INDENT(0) |
| | 1416 | |
| | 1417 | AS_IF([test "x$warn_prebuilt_man_pages" = "xyes" ], [ |
| | 1418 | AS_ECHO |
| | 1419 | PPRINT_WARN([You need asciidoc and xmlto to build the LTTng-tools man pages. |
| | 1420 | |
| | 1421 | Note that the man pages are already built in this distribution tarball, |
| | 1422 | therefore asciidoc and xmlto are only needed if you intend to modify |
| | 1423 | their sources. |
| | 1424 | |
| | 1425 | Also note that the installed man pages will contain the project's |
| | 1426 | default command-line option and environment variable values. |
| | 1427 | |
| | 1428 | Use --disable-man-pages to completely disable building and installing |
| | 1429 | the man pages.]) |
| | 1430 | ]) |
projects / lttng-tools.git / blame_incremental