| | 1 | dnl SPDX-License-Identifier: GPL-2.0-only |
| | 2 | AC_PREREQ([2.64]) |
| | 3 | AC_INIT([lttng-tools],[2.14.0-pre],[jeremie.galarneau@efficios.com],[],[https://lttng.org]) |
| | 4 | |
| | 5 | AC_CONFIG_HEADERS([include/config.h]) |
| | 6 | AC_CONFIG_AUX_DIR([config]) |
| | 7 | AC_CONFIG_MACRO_DIR([m4]) |
| | 8 | |
| | 9 | AC_CANONICAL_TARGET |
| | 10 | AC_CANONICAL_HOST |
| | 11 | |
| | 12 | AM_INIT_AUTOMAKE([1.12 foreign dist-bzip2 no-dist-gzip tar-pax nostdinc]) |
| | 13 | AM_MAINTAINER_MODE([enable]) |
| | 14 | |
| | 15 | # Enable silent rules if available (Introduced in AM 1.11) |
| | 16 | m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])]) |
| | 17 | |
| | 18 | |
| | 19 | ## ## |
| | 20 | ## C compiler checks ## |
| | 21 | ## ## |
| | 22 | |
| | 23 | # Choose the C compiler |
| | 24 | AC_PROG_CC |
| | 25 | # AC_PROG_CC_STDC was merged in AC_PROG_CC in autoconf 2.70 |
| | 26 | m4_version_prereq([2.70], [], [AC_PROG_CC_STDC]) |
| | 27 | |
| | 28 | # Make sure the C compiler supports C99 |
| | 29 | AS_IF([test "$ac_cv_prog_cc_c99" = "no"], [AC_MSG_ERROR([The compiler does not support C99])]) |
| | 30 | |
| | 31 | # Enable available system extensions and LFS support |
| | 32 | AC_USE_SYSTEM_EXTENSIONS |
| | 33 | AC_SYS_LARGEFILE |
| | 34 | |
| | 35 | # Make sure the C compiler supports __attribute__ |
| | 36 | AX_C___ATTRIBUTE__ |
| | 37 | AS_IF([test "x$ax_cv___attribute__" != "xyes"], |
| | 38 | [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])]) |
| | 39 | |
| | 40 | # Make sure we have pthread support |
| | 41 | AX_PTHREAD([], [AC_MSG_ERROR([Could not configure pthread support])]) |
| | 42 | |
| | 43 | # Checks for typedefs, structures, and compiler characteristics. |
| | 44 | AC_C_INLINE |
| | 45 | AC_TYPE_INT32_T |
| | 46 | AC_TYPE_INT64_T |
| | 47 | AC_TYPE_MODE_T |
| | 48 | AC_TYPE_OFF_T |
| | 49 | AC_TYPE_PID_T |
| | 50 | AC_TYPE_SIZE_T |
| | 51 | AC_TYPE_SSIZE_T |
| | 52 | AC_TYPE_UID_T |
| | 53 | AC_TYPE_UINT16_T |
| | 54 | AC_TYPE_UINT32_T |
| | 55 | AC_TYPE_UINT64_T |
| | 56 | AC_TYPE_UINT8_T |
| | 57 | |
| | 58 | # Detect warning flags supported by the C and C++ compilers and append them to |
| | 59 | # WARN_CFLAGS and WARN_CXXFLAGS. |
| | 60 | m4_define([WARN_FLAGS_COMMON_LIST], [ dnl |
| | 61 | -Wall dnl |
| | 62 | -Wnull-dereference dnl |
| | 63 | -Wundef dnl |
| | 64 | dnl We currently get this warning when building with Clang: |
| | 65 | dnl |
| | 66 | dnl /usr/include/setjmp.h:54:12: error: declaration of built-in function '__sigsetjmp' requires the declaration of the 'jmp_buf' type, commonly provided in the header <setjmp.h>. [-Werror,-Wincomplete-setjmp-declaration] |
| | 67 | dnl extern int __sigsetjmp (struct __jmp_buf_tag __env[1], int __savemask) __THROWNL; |
| | 68 | dnl ^ |
| | 69 | -Wno-incomplete-setjmp-declaration dnl |
| | 70 | -Wmissing-declarations dnl |
| | 71 | -Wshadow dnl |
| | 72 | -Wno-gnu-folding-constant dnl |
| | 73 | -Wsuggest-attribute=format dnl |
| | 74 | -Wformat=2 dnl |
| | 75 | ]) |
| | 76 | |
| | 77 | # Detect warning flags specific to the C compiler and append them to |
| | 78 | # WARN_CFLAGS. |
| | 79 | m4_define([WARN_FLAGS_C_LIST], [ dnl |
| | 80 | -Wdiscarded-qualifiers dnl |
| | 81 | -Wmissing-prototypes dnl |
| | 82 | -Wmissing-parameter-type dnl |
| | 83 | ]) |
| | 84 | |
| | 85 | # Pass -Werror as an extra flag during the test: this is needed to make the |
| | 86 | # -Wunknown-warning-option diagnostic fatal with clang. |
| | 87 | AC_LANG_PUSH([C]) |
| | 88 | AX_APPEND_COMPILE_FLAGS([WARN_FLAGS_COMMON_LIST WARN_FLAGS_C_LIST], [WARN_CFLAGS], [-Werror]) |
| | 89 | AC_LANG_POP([C]) |
| | 90 | |
| | 91 | # The test used in AX_APPEND_COMPILE_FLAGS, generated using AC_LANG_PROGRAM, is |
| | 92 | # written in such a way that it triggers warnings with the following warning |
| | 93 | # flags. So they would always end up disabled if we put them there, because |
| | 94 | # the test program would not build. |
| | 95 | # |
| | 96 | # Enable them here unconditionally. They are supported by GCC >= 4.8 and by |
| | 97 | # Clang >= 3.3 (required by the project) and are only valid for C code. |
| | 98 | WARN_CFLAGS="${WARN_CFLAGS} -Wold-style-definition -Wstrict-prototypes" |
| | 99 | |
| | 100 | # Disable 'strict aliasing' if the C compiler supports it. |
| | 101 | AC_LANG_PUSH([C]) |
| | 102 | AX_APPEND_COMPILE_FLAGS([-fno-strict-aliasing], [OPT_CFLAGS], [-Werror]) |
| | 103 | AC_LANG_POP([C]) |
| | 104 | |
| | 105 | |
| | 106 | ## ## |
| | 107 | ## C++ compiler checks ## |
| | 108 | ## ## |
| | 109 | |
| | 110 | # Find a C++11 compiler with GNU extensions (-std=gnu++11) |
| | 111 | AX_CXX_COMPILE_STDCXX([11], [ext], [mandatory]) |
| | 112 | |
| | 113 | # Detect warning flags specific to the C++ compiler and append them to |
| | 114 | # WARN_CXXFLAGS. |
| | 115 | m4_define([WARN_FLAGS_CXX_LIST], [ dnl |
| | 116 | dnl GCC enables this with -Wall in C++, and that generates a |
| | 117 | dnl lot of warnings that have on average a low value to fix. |
| | 118 | -Wno-sign-compare dnl |
| | 119 | ]) |
| | 120 | |
| | 121 | # Pass -Werror as an extra flag during the test: this is needed to make the |
| | 122 | # -Wunknown-warning-option diagnostic fatal with clang. |
| | 123 | AC_LANG_PUSH([C++]) |
| | 124 | AX_APPEND_COMPILE_FLAGS([WARN_FLAGS_COMMON_LIST WARN_FLAGS_CXX_LIST], [WARN_CXXFLAGS], [-Werror]) |
| | 125 | AC_LANG_POP([C++]) |
| | 126 | |
| | 127 | # Disable 'strict aliasing' if the C++ compiler supports it. |
| | 128 | AC_LANG_PUSH([C++]) |
| | 129 | AX_APPEND_COMPILE_FLAGS([-fno-strict-aliasing], [OPT_CXXFLAGS], [-Werror]) |
| | 130 | AC_LANG_POP([C++]) |
| | 131 | |
| | 132 | |
| | 133 | # When given, add -Werror to WARN_CFLAGS and WARN_CXXFLAGS. |
| | 134 | AC_ARG_ENABLE([Werror],[ |
| | 135 | AS_HELP_STRING([--enable-Werror], [Treat compiler warnings as errors.]) |
| | 136 | ]) |
| | 137 | |
| | 138 | AS_IF([test "x$enable_Werror" = "xyes"], [ |
| | 139 | WARN_CFLAGS="${WARN_CFLAGS} -Werror" |
| | 140 | WARN_CXXFLAGS="${WARN_CXXFLAGS} -Werror" |
| | 141 | ]) |
| | 142 | |
| | 143 | # Checks for programs. |
| | 144 | AC_PROG_GREP |
| | 145 | AC_PROG_MAKE_SET |
| | 146 | AC_PROG_SED |
| | 147 | AC_PATH_PROG([report_fold], [fold]) |
| | 148 | LT_INIT |
| | 149 | |
| | 150 | # Check for objcopy, required by the base address statedump and dynamic linker tests |
| | 151 | AC_CHECK_TOOL([OBJCOPY], [objcopy], [no]) |
| | 152 | AS_IF([test "x$OBJCOPY" = "xno"], |
| | 153 | [AC_MSG_WARN([Cannot find objcopy. The base address statedump and dynamic linker tests will be disabled. Install the binutils package to remediate this.])] |
| | 154 | ) |
| | 155 | AM_CONDITIONAL([HAVE_OBJCOPY], [test "x$OBJCOPY" != xno]) |
| | 156 | |
| | 157 | # check for pgrep |
| | 158 | AC_PATH_PROG([PGREP], [pgrep], [no]) |
| | 159 | AM_CONDITIONAL([HAVE_PGREP], [test "x$PGREP" != "xno"]) |
| | 160 | |
| | 161 | # set $IN_GIT_REPO if we're in the Git repository; the `bootstrap` file |
| | 162 | # is not distributed in tarballs |
| | 163 | AS_IF([test -f "$srcdir/bootstrap"], [in_git_repo=yes], [in_git_repo=no]) |
| | 164 | AM_CONDITIONAL([IN_GIT_REPO], [test "x$in_git_repo" = "xyes"]) |
| | 165 | |
| | 166 | # check for bison |
| | 167 | AC_PROG_YACC |
| | 168 | BISON=$YACC |
| | 169 | AX_PROG_BISON_VERSION([2.4], [have_bison=yes]) |
| | 170 | |
| | 171 | AS_IF([test "x$have_bison" != "xyes"], [ |
| | 172 | AS_IF([test "x$in_git_repo" = "xyes"], [ |
| | 173 | AC_MSG_FAILURE([ |
| | 174 | Bison >= 2.4 is required when building from the Git repository. You can |
| | 175 | set the YACC variable to override automatic detection. |
| | 176 | ]) |
| | 177 | ], [ |
| | 178 | AC_MSG_WARN([ |
| | 179 | Missing Bison >= 2.4. Note that the parser files are already built in |
| | 180 | this distribution tarball, so Bison is only needed if you intend to |
| | 181 | modify their sources. You can set the YACC variable to override automatic |
| | 182 | detection. |
| | 183 | ]) |
| | 184 | ]) |
| | 185 | ]) |
| | 186 | AM_CONDITIONAL([HAVE_BISON], [test "x$have_bison" = "xyes"]) |
| | 187 | |
| | 188 | # check for flex |
| | 189 | # Prior to autoconf 2.70, AC_PROG_FLEX did not take an argument. This is not a |
| | 190 | # problem since the argument is silently ignored by older versions. |
| | 191 | AC_PROG_LEX([noyywrap]) |
| | 192 | FLEX=$LEX |
| | 193 | AX_PROG_FLEX_VERSION([2.5.35], [have_flex=yes]) |
| | 194 | |
| | 195 | AS_IF([test "x$have_flex" != "xyes"], [ |
| | 196 | AS_IF([test "x$in_git_repo" = "xyes"], [ |
| | 197 | AC_MSG_FAILURE([ |
| | 198 | Flex >= 2.5.35 is required when building from the Git repository. You can |
| | 199 | set the LEX variable to override automatic detection. |
| | 200 | ]) |
| | 201 | ], [ |
| | 202 | AC_MSG_WARN([ |
| | 203 | Missing Flex >= 2.5.35. Note that the lexer files are already built in |
| | 204 | this distribution tarball, so Flex is only needed if you intend to |
| | 205 | modify their sources. You can set the LEX variable to override automatic |
| | 206 | detection. |
| | 207 | ]) |
| | 208 | ]) |
| | 209 | ]) |
| | 210 | AM_CONDITIONAL([HAVE_FLEX], [test "x$have_flex" = "xyes"]) |
| | 211 | |
| | 212 | |
| | 213 | |
| | 214 | # Check if linker has the -no-pie option. |
| | 215 | AX_CHECK_LINK_FLAG([-no-pie], [linker_have_no_pie_option=yes]) |
| | 216 | AM_CONDITIONAL([LINKER_HAVE_NO_PIE_OPTION], [test "x$linker_have_no_pie_option" = "xyes"]) |
| | 217 | |
| | 218 | AX_LIB_SOCKET_NSL |
| | 219 | |
| | 220 | LT_NO_UNDEFINED="" |
| | 221 | AS_CASE([$host_os], |
| | 222 | [cygwin*], |
| | 223 | [ |
| | 224 | LT_NO_UNDEFINED="-no-undefined" |
| | 225 | ], |
| | 226 | [cygwin*|darwin*|mingw*|solaris*], |
| | 227 | [ |
| | 228 | # On platforms where we only support the relayd, disable the other binaries by default |
| | 229 | AS_IF([test "x$enable_bin_lttng" = "x" ], [enable_bin_lttng=no]) |
| | 230 | AS_IF([test "x$enable_bin_lttng_consumerd" = "x" ], [enable_bin_lttng_consumerd=no]) |
| | 231 | AS_IF([test "x$enable_bin_lttng_crash" = "x" ], [enable_bin_lttng_crash=no]) |
| | 232 | AS_IF([test "x$enable_bin_lttng_sessiond" = "x" ], [enable_bin_lttng_sessiond=no]) |
| | 233 | AS_IF([test "x$enable_extras" = "x" ], [enable_extras=no]) |
| | 234 | AS_IF([test "x$with_lttng_ust" = "x" ], [with_lttng_ust=no]) |
| | 235 | ] |
| | 236 | ) |
| | 237 | |
| | 238 | AC_SUBST(LT_NO_UNDEFINED) |
| | 239 | |
| | 240 | # Compute minor/major/patchlevel version numbers |
| | 241 | major_version=$(echo AC_PACKAGE_VERSION | $SED 's/^\([[0-9]]\)*\.[[0-9]]*\.[[0-9]]*.*$/\1/') |
| | 242 | minor_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.\([[0-9]]*\)\.[[0-9]]*.*$/\1/') |
| | 243 | patchlevel_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\).*$/\1/') |
| | 244 | |
| | 245 | AC_SUBST([MAJOR_VERSION], [$major_version]) |
| | 246 | AC_SUBST([MINOR_VERSION], [$minor_version]) |
| | 247 | AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version]) |
| | 248 | AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [LTTng-Tools major version number]) |
| | 249 | AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [LTTng-Tools minor version number]) |
| | 250 | AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [LTTng-Tools patchlevel version number]) |
| | 251 | |
| | 252 | version_name="O-Beer" |
| | 253 | version_description="An alcoholic drink made from yeast-fermented malt flavored with hops." |
| | 254 | version_description_c=$(echo $version_description | $SED 's/"/\\"/g') |
| | 255 | |
| | 256 | AC_DEFINE_UNQUOTED([VERSION_NAME], ["$version_name"], "") |
| | 257 | AC_DEFINE_UNQUOTED([VERSION_DESCRIPTION], ["$version_description_c"], "") |
| | 258 | |
| | 259 | # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321. |
| | 260 | AC_ARG_ENABLE(libtool-linkdep-fixup, |
| | 261 | AS_HELP_STRING([--disable-libtool-linkdep-fixup], |
| | 262 | [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)]), |
| | 263 | libtool_fixup=$enableval, |
| | 264 | libtool_fixup=yes) |
| | 265 | |
| | 266 | AS_IF([test "x$libtool_fixup" = "xyes"], |
| | 267 | [ |
| | 268 | libtool_m4="$srcdir/m4/libtool.m4" |
| | 269 | libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)" |
| | 270 | AC_MSG_CHECKING([for occurrence(s) of link_all_deplibs = no in $libtool_m4]) |
| | 271 | libtool_flag_pattern_count=$($GREP -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4) |
| | 272 | AS_IF([test $libtool_flag_pattern_count -ne 0], |
| | 273 | [ |
| | 274 | AC_MSG_RESULT([$libtool_flag_pattern_count]) |
| | 275 | AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown]) |
| | 276 | $SED -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4 |
| | 277 | ], |
| | 278 | [ |
| | 279 | AC_MSG_RESULT([none]) |
| | 280 | ]) |
| | 281 | ]) |
| | 282 | |
| | 283 | AM_CONDITIONAL([NO_SHARED], [test x$enable_shared = xno]) |
| | 284 | |
| | 285 | AC_CHECK_HEADERS([ \ |
| | 286 | sys/types.h unistd.h fcntl.h string.h pthread.h limits.h \ |
| | 287 | signal.h stdlib.h sys/un.h sys/socket.h stdlib.h stdio.h \ |
| | 288 | getopt.h sys/ipc.h sys/shm.h popt.h grp.h arpa/inet.h \ |
| | 289 | netdb.h netinet/in.h paths.h stddef.h sys/file.h sys/ioctl.h \ |
| | 290 | sys/mount.h sys/param.h sys/time.h elf.h |
| | 291 | ]) |
| | 292 | |
| | 293 | AM_CONDITIONAL([HAVE_ELF_H], [test x$ac_cv_header_elf_h = xyes]) |
| | 294 | |
| | 295 | # Basic functions check |
| | 296 | AC_CHECK_FUNCS([ \ |
| | 297 | atexit bzero clock_gettime dup2 fdatasync fls ftruncate \ |
| | 298 | gethostbyname gethostname getpagesize localtime_r memchr memrchr memset \ |
| | 299 | mkdir munmap putenv realpath rmdir socket strchr strcspn strdup \ |
| | 300 | strncasecmp strndup strnlen strpbrk strrchr strstr strtol strtoul \ |
| | 301 | strtoull dirfd gethostbyname2 getipnodebyname epoll_create1 \ |
| | 302 | sched_getcpu sysconf sync_file_range |
| | 303 | ]) |
| | 304 | |
| | 305 | # Check for pthread_setname_np and pthread_getname_np |
| | 306 | LTTNG_PTHREAD_SETNAME_NP |
| | 307 | LTTNG_PTHREAD_GETNAME_NP |
| | 308 | |
| | 309 | # Check if clock_gettime, timer_create, timer_settime, and timer_delete are available in lib rt, and if so, |
| | 310 | # add -lrt to LIBS |
| | 311 | AC_CHECK_LIB([rt], [clock_gettime, timer_create, timer_settime, timer_delete]) |
| | 312 | |
| | 313 | # Checks for dl. |
| | 314 | AC_CHECK_LIB([dl], [dlopen], [ |
| | 315 | have_libdl=yes |
| | 316 | libdl_name=dl |
| | 317 | DL_LIBS="-ldl" |
| | 318 | ], [ |
| | 319 | # libdl not found, check for dlopen in libc. |
| | 320 | AC_CHECK_LIB([c], [dlopen], [ |
| | 321 | have_libc_dl=yes |
| | 322 | libdl_name=c |
| | 323 | DL_LIBS="-lc" |
| | 324 | ], [ |
| | 325 | AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.]) |
| | 326 | ]) |
| | 327 | ]) |
| | 328 | AC_SUBST(DL_LIBS) |
| | 329 | |
| | 330 | # Check if libdl has dlmopen support. |
| | 331 | AH_TEMPLATE([HAVE_DLMOPEN], ["Define to 1 if dlmopen is available."]) |
| | 332 | AC_CHECK_LIB([$libdl_name], [dlmopen], [ |
| | 333 | AC_DEFINE([HAVE_DLMOPEN], [1]) |
| | 334 | HAVE_DLMOPEN=1 |
| | 335 | ], [ |
| | 336 | HAVE_DLMOPEN=0 |
| | 337 | ]) |
| | 338 | AC_SUBST(HAVE_DLMOPEN) |
| | 339 | |
| | 340 | # Babeltrace viewer check |
| | 341 | AC_ARG_WITH([babeltrace-bin], |
| | 342 | AS_HELP_STRING([--with-babeltrace-bin], |
| | 343 | [Location of the babeltrace viewer executable (including the filename)]), |
| | 344 | [BABELTRACE_BIN="$withval"], |
| | 345 | [BABELTRACE_BIN='']) |
| | 346 | AC_SUBST([BABELTRACE_BIN]) |
| | 347 | |
| | 348 | AC_ARG_WITH([babeltrace2-bin], |
| | 349 | AS_HELP_STRING([--with-babeltrace2-bin], |
| | 350 | [Location of the babeltrace2 viewer executable (including the filename)]), |
| | 351 | [BABELTRACE2_BIN="$withval"], |
| | 352 | [BABELTRACE2_BIN='']) |
| | 353 | AC_SUBST([BABELTRACE2_BIN]) |
| | 354 | |
| | 355 | AC_ARG_WITH([consumerd32-bin], |
| | 356 | AS_HELP_STRING([--with-consumerd32-bin], |
| | 357 | [Location of the 32-bit consumerd executable (including the filename)]), |
| | 358 | [CONSUMERD32_BIN="$withval"], |
| | 359 | [CONSUMERD32_BIN='']) |
| | 360 | AC_SUBST([CONSUMERD32_BIN]) |
| | 361 | |
| | 362 | AC_ARG_WITH([consumerd64-bin], |
| | 363 | AS_HELP_STRING([--with-consumerd64-bin], |
| | 364 | [Location of the 64-bit consumerd executable (including the filename)]), |
| | 365 | [CONSUMERD64_BIN="$withval"], |
| | 366 | [CONSUMERD64_BIN='']) |
| | 367 | AC_SUBST([CONSUMERD64_BIN]) |
| | 368 | |
| | 369 | AC_ARG_WITH([consumerd32-libdir], |
| | 370 | AS_HELP_STRING([--with-consumerd32-libdir], |
| | 371 | [Directory containing the 32-bit consumerd libraries]), |
| | 372 | [CONSUMERD32_LIBDIR="$withval"], |
| | 373 | [CONSUMERD32_LIBDIR='']) |
| | 374 | AC_SUBST([CONSUMERD32_LIBDIR]) |
| | 375 | |
| | 376 | AC_ARG_WITH([consumerd64-libdir], |
| | 377 | AS_HELP_STRING([--with-consumerd64-libdir], |
| | 378 | [Directory containing the 64-bit consumerd libraries]), |
| | 379 | [CONSUMERD64_LIBDIR="$withval"], |
| | 380 | [CONSUMERD64_LIBDIR='']) |
| | 381 | AC_SUBST([CONSUMERD64_LIBDIR]) |
| | 382 | |
| | 383 | AC_ARG_WITH([sessiond-bin], |
| | 384 | AS_HELP_STRING([--with-sessiond-bin], |
| | 385 | [Location of the sessiond executable (including the filename)]), |
| | 386 | [SESSIOND_BIN="$withval"], |
| | 387 | [SESSIOND_BIN='']) |
| | 388 | AC_SUBST([SESSIOND_BIN]) |
| | 389 | |
| | 390 | AC_ARG_WITH([lttng-system-rundir], |
| | 391 | AS_HELP_STRING([--with-lttng-system-rundir], |
| | 392 | [Location of the system directory where the system-wide lttng-sessiond runtime files are kept. The default is "/var/run/lttng".]), |
| | 393 | [LTTNG_SYSTEM_RUNDIR="$withval"], |
| | 394 | [LTTNG_SYSTEM_RUNDIR="/var/run/lttng"]) |
| | 395 | AC_SUBST([LTTNG_SYSTEM_RUNDIR]) |
| | 396 | |
| | 397 | AC_ARG_ENABLE([test-java-agent-jul], |
| | 398 | [AS_HELP_STRING([--enable-test-java-agent-jul],[enable the LTTng UST Java agent JUL tests [default=no]])], |
| | 399 | [test_java_agent_jul=$enableval], |
| | 400 | [test_java_agent_jul=no] |
| | 401 | ) |
| | 402 | |
| | 403 | AC_ARG_ENABLE([test-java-agent-log4j], |
| | 404 | [AS_HELP_STRING([--enable-test-java-agent-log4j],[enable the LTTng UST Java agent Log4j 1.x tests [default=no]])], |
| | 405 | [test_java_agent_log4j=$enableval], |
| | 406 | [test_java_agent_log4j=no] |
| | 407 | ) |
| | 408 | |
| | 409 | AC_ARG_ENABLE([test-java-agent-log4j2], |
| | 410 | [AS_HELP_STRING([--enable-test-java-agent-log4j2],[enable the LTTng UST Java agent Log4j 2.x tests [default=no]])], |
| | 411 | [test_java_agent_log4j2=$enableval], |
| | 412 | [test_java_agent_log4j2=no] |
| | 413 | ) |
| | 414 | |
| | 415 | AC_ARG_ENABLE([test-java-agent-all], |
| | 416 | [AS_HELP_STRING([--enable-test-java-agent-all],[enable all the LTTng UST Java agent tests [default=no]])], |
| | 417 | [test_java_agent_jul=$enableval |
| | 418 | test_java_agent_log4j=$enableval |
| | 419 | test_java_agent_log4j2=$enableval], |
| | 420 | [:] |
| | 421 | ) |
| | 422 | |
| | 423 | AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_BIN], "$CONSUMERD32_BIN", [Location of the 32-bit consumerd executable.]) |
| | 424 | AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_BIN], "$CONSUMERD64_BIN", [Location of the 64-bit consumerd executable]) |
| | 425 | AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_LIBDIR], "$CONSUMERD32_LIBDIR", [Search for consumerd 32-bit libraries in this location.]) |
| | 426 | AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_LIBDIR], "$CONSUMERD64_LIBDIR", [Search for consumerd 64-bit libraries in this location.]) |
| | 427 | AC_DEFINE_UNQUOTED([CONFIG_BABELTRACE_BIN], "$BABELTRACE_BIN", [Location of the babeltrace viewer executable.]) |
| | 428 | AC_DEFINE_UNQUOTED([CONFIG_BABELTRACE2_BIN], "$BABELTRACE2_BIN", [Location of the babeltrace2 viewer executable.]) |
| | 429 | AC_DEFINE_UNQUOTED([CONFIG_SESSIOND_BIN], "$SESSIOND_BIN", [Location of the sessiond executable.]) |
| | 430 | AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_RUNDIR], ["$LTTNG_SYSTEM_RUNDIR"], [LTTng system runtime directory]) |
| | 431 | |
| | 432 | AC_DEFUN([_AC_DEFINE_AND_SUBST], [ |
| | 433 | AC_DEFINE_UNQUOTED([CONFIG_$1], [$2], [$1]) |
| | 434 | $1="$2" |
| | 435 | AC_SUBST([$1]) |
| | 436 | ]) |
| | 437 | |
| | 438 | AC_DEFUN([_AC_DEFINE_QUOTED_AND_SUBST], [ |
| | 439 | AC_DEFINE_UNQUOTED([CONFIG_$1], ["$2"], [$1]) |
| | 440 | $1="$2" |
| | 441 | AC_SUBST([$1]) |
| | 442 | ]) |
| | 443 | |
| | 444 | # Default values |
| | 445 | m4_define([_DEFAULT_CHANNEL_SUBBUF_SIZE], [16384]) |
| | 446 | m4_define([_DEFAULT_CHANNEL_SUBBUF_NUM], [4]) |
| | 447 | m4_define([_DEFAULT_CHANNEL_SWITCH_TIMER], [0]) |
| | 448 | m4_define([_DEFAULT_CHANNEL_LIVE_TIMER], [0]) |
| | 449 | m4_define([_DEFAULT_CHANNEL_READ_TIMER], [200000]) |
| | 450 | m4_define([_DEFAULT_CHANNEL_MONITOR_TIMER], [1000000]) |
| | 451 | m4_define([_DEFAULT_CHANNEL_BLOCKING_TIMEOUT], [0]) |
| | 452 | _AC_DEFINE_AND_SUBST([DEFAULT_AGENT_TCP_PORT_RANGE_BEGIN], [5345]) |
| | 453 | _AC_DEFINE_AND_SUBST([DEFAULT_AGENT_TCP_PORT_RANGE_END], [5354]) |
| | 454 | _AC_DEFINE_AND_SUBST([DEFAULT_APP_SOCKET_RW_TIMEOUT], [5]) |
| | 455 | _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE]) |
| | 456 | _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_COUNT], [0]) |
| | 457 | _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_SIZE], [0]) |
| | 458 | _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER]) |
| | 459 | _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_READ_TIMER], [_DEFAULT_CHANNEL_READ_TIMER]) |
| | 460 | _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM]) |
| | 461 | _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_SIZE], [1048576]) |
| | 462 | _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER]) |
| | 463 | _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER]) |
| | 464 | _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_BLOCKING_TIMEOUT], [_DEFAULT_CHANNEL_BLOCKING_TIMEOUT]) |
| | 465 | _AC_DEFINE_AND_SUBST([DEFAULT_LTTNG_LIVE_TIMER], [1000000]) |
| | 466 | _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_CACHE_SIZE], [4096]) |
| | 467 | _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_READ_TIMER], [0]) |
| | 468 | _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_NUM], [2]) |
| | 469 | _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_SIZE], [4096]) |
| | 470 | _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER]) |
| | 471 | _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_CONTROL_PORT], [5342]) |
| | 472 | _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_DATA_PORT], [5343]) |
| | 473 | _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_VIEWER_PORT], [5344]) |
| | 474 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER]) |
| | 475 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_READ_TIMER], [0]) |
| | 476 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_BLOCKING_TIMEOUT], [0]) |
| | 477 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM]) |
| | 478 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE]) |
| | 479 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER]) |
| | 480 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER]) |
| | 481 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER]) |
| | 482 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_READ_TIMER], [0]) |
| | 483 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_BLOCKING_TIMEOUT], [0]) |
| | 484 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM]) |
| | 485 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_SIZE], [524288]) |
| | 486 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER]) |
| | 487 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER]) |
| | 488 | _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_AGENT_BIND_ADDRESS], [localhost]) |
| | 489 | _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_CONTROL_BIND_ADDRESS], [0.0.0.0]) |
| | 490 | _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_DATA_BIND_ADDRESS], [0.0.0.0]) |
| | 491 | _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_VIEWER_BIND_ADDRESS], [localhost]) |
| | 492 | _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_RELAYD_CTRL_MAX_PAYLOAD_SIZE], [134217728]) |
| | 493 | _AC_DEFINE_AND_SUBST([DEFAULT_ROTATE_PENDING_TIMER], [500000]) |
| | 494 | _AC_DEFINE_AND_SUBST([DEFAULT_EVENT_NOTIFIER_ERROR_COUNT_MAP_SIZE], [4096]) |
| | 495 | |
| | 496 | # Command short descriptions |
| | 497 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ADD_CONTEXT], [Add context fields to be recorded]) |
| | 498 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ADD_TRIGGER], [Add a trigger]) |
| | 499 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_CLEAR], [Clear a recording session]) |
| | 500 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_CREATE], [Create a recording session]) |
| | 501 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DESTROY], [Destroy recording sessions]) |
| | 502 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_CHANNEL], [Disable channels]) |
| | 503 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_EVENT], [Disable recording event rules]) |
| | 504 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_ROTATION], [Unset a recording session rotation schedule]) |
| | 505 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_CHANNEL], [Create or enable a channel]) |
| | 506 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_EVENT], [Create or enable recording event rules]) |
| | 507 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_ROTATION], [Set a recording session rotation schedule]) |
| | 508 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_HELP], [Show the help of a command]) |
| | 509 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LIST], [List recording sessions and instrumentation points]) |
| | 510 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LIST_TRIGGERS], [List triggers]) |
| | 511 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LOAD], [Load recording session configurations]) |
| | 512 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_REGENERATE], [Regenerate specific recording session data]) |
| | 513 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_REMOVE_TRIGGER], [Remove a trigger]) |
| | 514 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ROTATE], [Archive the current trace chunk of a recording session]) |
| | 515 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SAVE], [Save recording session configurations]) |
| | 516 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SET_SESSION], [Set the current recording session]) |
| | 517 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SNAPSHOT], [Take a recording session snapshot]) |
| | 518 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_START], [Start a recording session]) |
| | 519 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STATUS], [Show the status of the current recording session]) |
| | 520 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STOP], [Stop a recording session]) |
| | 521 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_TRACK], [Allow specific processes to record events]) |
| | 522 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_UNTRACK], [Disallow specific processes to record events]) |
| | 523 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VERSION], [Show LTTng-tools version information]) |
| | 524 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VIEW], [Launch a trace reader]) |
| | 525 | |
| | 526 | if test "x$prefix" = "xNONE"; then |
| | 527 | prefix=$ac_default_prefix |
| | 528 | fi |
| | 529 | CONFDIR=`eval echo $sysconfdir` |
| | 530 | AC_SUBST(CONFDIR) |
| | 531 | AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_CONFIGDIR],"$CONFDIR", [LTTng system configuration directory.]) |
| | 532 | |
| | 533 | AX_DEFINE_DIR([CONFIG_LTTNG_SYSTEM_DATADIR], [datadir], [LTTng system data directory.]) |
| | 534 | |
| | 535 | # Check libpopt |
| | 536 | PKG_CHECK_MODULES([POPT], [popt], |
| | 537 | [ |
| | 538 | dnl PKG_CHECK_MODULES defines POPT_LIBS |
| | 539 | ], |
| | 540 | [ |
| | 541 | AC_MSG_WARN([pkg-config was unable to find a valid .pc for libpopt. Set PKG_CONFIG_PATH to specify the pkgconfig configuration file location]) |
| | 542 | AC_MSG_WARN([Finding libpopt without pkg-config.]) |
| | 543 | AC_CHECK_LIB([popt], |
| | 544 | [poptGetContext], |
| | 545 | [POPT_LIBS="-lpopt"], |
| | 546 | [ |
| | 547 | AC_MSG_FAILURE([Cannot find libpopt. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location]) |
| | 548 | ] |
| | 549 | ) |
| | 550 | ] |
| | 551 | ) |
| | 552 | AC_SUBST(POPT_LIBS) |
| | 553 | |
| | 554 | PKG_CHECK_MODULES([libxml2], [libxml-2.0 >= 2.7.6]) |
| | 555 | |
| | 556 | AC_CHECK_FUNC([clock_gettime], [AC_DEFINE_UNQUOTED([LTTNG_HAVE_CLOCK_GETTIME], 1, [Has clock_gettime() support.])]) |
| | 557 | |
| | 558 | # URCU library version needed or newer |
| | 559 | PKG_CHECK_MODULES([URCU], [liburcu >= 0.11]) |
| | 560 | PKG_CHECK_MODULES([URCU_CDS], [liburcu-cds >= 0.11]) |
| | 561 | AM_CPPFLAGS="$AM_CPPFLAGS $URCU_CFLAGS" |
| | 562 | |
| | 563 | # Check for libkmod, it will be auto-neabled if found but won't fail if it's not, |
| | 564 | # it can be explicitly disabled with --without-kmod |
| | 565 | AH_TEMPLATE([HAVE_KMOD], [Define if you have kmod support]) |
| | 566 | AC_ARG_WITH([kmod], |
| | 567 | [AS_HELP_STRING([--with-kmod], [build with lkmod support @<:@default=check@:>@])], |
| | 568 | [], |
| | 569 | [with_kmod=check] |
| | 570 | ) |
| | 571 | |
| | 572 | AS_IF([test "x$with_kmod" != "xno"], |
| | 573 | [ |
| | 574 | AC_CHECK_LIB([kmod], [kmod_module_probe_insert_module], |
| | 575 | [ |
| | 576 | AC_DEFINE([HAVE_KMOD], [1]) |
| | 577 | KMOD_LIBS="-lkmod" |
| | 578 | ], |
| | 579 | [ |
| | 580 | if test "x$with_kmod" != xcheck; then |
| | 581 | AC_MSG_FAILURE([Cannot find libkmod. Use [LDFLAGS]=-Ldir and [CPPFLAGS]=-Idir to specify its location.]) |
| | 582 | else |
| | 583 | with_kmod=no |
| | 584 | fi |
| | 585 | ] |
| | 586 | ) |
| | 587 | ] |
| | 588 | ) |
| | 589 | AC_SUBST(KMOD_LIBS) |
| | 590 | |
| | 591 | # Check for liblttng-ust-ctl, fail if it's not found, |
| | 592 | # it can be explicitly disabled with --without-lttng-ust |
| | 593 | AH_TEMPLATE([HAVE_LIBLTTNG_UST_CTL], [Define if you have LTTng-UST control support]) |
| | 594 | AC_ARG_WITH([lttng-ust], |
| | 595 | [AS_HELP_STRING([--without-lttng-ust], [build without LTTng-UST (Userspace Tracing) support])], |
| | 596 | [], |
| | 597 | [with_lttng_ust=yes] |
| | 598 | ) |
| | 599 | |
| | 600 | AS_IF([test "x$with_lttng_ust" = "xyes"], [ |
| | 601 | AC_DEFINE([HAVE_LIBLTTNG_UST_CTL], [1]) |
| | 602 | |
| | 603 | # Check for liblttng-ust |
| | 604 | PKG_CHECK_MODULES([UST], [lttng-ust >= $major_version.$minor_version]) |
| | 605 | |
| | 606 | # Check for liblttng-ust-ctl |
| | 607 | PKG_CHECK_MODULES([UST_CTL], [lttng-ust-ctl >= $major_version.$minor_version]) |
| | 608 | |
| | 609 | AM_CPPFLAGS="$AM_CPPFLAGS $UST_CFLAGS" |
| | 610 | ]) |
| | 611 | |
| | 612 | AM_CONDITIONAL([HAVE_LIBLTTNG_UST_CTL], [test "x$with_lttng_ust" = "xyes"]) |
| | 613 | |
| | 614 | |
| | 615 | # Check for fmemopen |
| | 616 | AC_CHECK_LIB([c], [fmemopen], |
| | 617 | [ |
| | 618 | AC_DEFINE_UNQUOTED([LTTNG_HAVE_FMEMOPEN], 1, [Has fmemopen support.]) |
| | 619 | ] |
| | 620 | ) |
| | 621 | |
| | 622 | # check for libpfm |
| | 623 | AC_CHECK_LIB([pfm], [pfm_initialize], |
| | 624 | [ |
| | 625 | have_libpfm=yes |
| | 626 | ]) |
| | 627 | AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBPFM], [test "x$have_libpfm" = "xyes"]) |
| | 628 | |
| | 629 | # For Python |
| | 630 | # SWIG version needed or newer: |
| | 631 | swig_version=2.0.0 |
| | 632 | |
| | 633 | AC_ARG_ENABLE([python-bindings], |
| | 634 | [AS_HELP_STRING([--enable-python-bindings], |
| | 635 | [compile Python bindings])], |
| | 636 | [enable_python_binding=$enableval], [enable_python_binding=no]) |
| | 637 | |
| | 638 | AM_CONDITIONAL([PYTHON_BINDING], [test "x$enable_python_binding" = xyes]) |
| | 639 | |
| | 640 | if test "x$enable_python_binding" = xyes; then |
| | 641 | AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ]) |
| | 642 | AS_IF([test x$enable_shared = xno], [ AC_MSG_ERROR([Python bindings require shared libraries.]) ]) |
| | 643 | AM_PATH_PYTHON([3.0]) |
| | 644 | |
| | 645 | AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config]) |
| | 646 | AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config]) |
| | 647 | AS_IF([test -z "$PYTHON_INCLUDE"], [ |
| | 648 | AS_IF([test -z "$PYTHON_CONFIG"], [ |
| | 649 | AC_PATH_PROGS([PYTHON_CONFIG], |
| | 650 | [python$PYTHON_VERSION-config python-config], |
| | 651 | [no], |
| | 652 | [`dirname $PYTHON`]) |
| | 653 | AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])]) |
| | 654 | ]) |
| | 655 | AC_MSG_CHECKING([python include flags]) |
| | 656 | PYTHON_INCLUDE=`$PYTHON_CONFIG --includes` |
| | 657 | AC_MSG_RESULT([$PYTHON_INCLUDE]) |
| | 658 | ]) |
| | 659 | |
| | 660 | else |
| | 661 | AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl |
| | 662 | [if you want Python bindings.]) |
| | 663 | |
| | 664 | fi |
| | 665 | |
| | 666 | # Epoll check. If not present, the build will fallback on poll() API |
| | 667 | AX_HAVE_EPOLL( |
| | 668 | [AX_CONFIG_FEATURE_ENABLE(epoll)], |
| | 669 | [AX_CONFIG_FEATURE_DISABLE(epoll)] |
| | 670 | ) |
| | 671 | AX_CONFIG_FEATURE( |
| | 672 | [epoll], [This platform supports epoll(7)], |
| | 673 | [HAVE_EPOLL], [This platform supports epoll(7).] |
| | 674 | ) |
| | 675 | |
| | 676 | AS_IF([test "x$ac_cv_func_dirfd" = "xyes"], |
| | 677 | [AX_CONFIG_FEATURE_ENABLE(dirfd)], |
| | 678 | [AX_CONFIG_FEATURE_DISABLE(dirfd)] |
| | 679 | ) |
| | 680 | AX_CONFIG_FEATURE( |
| | 681 | [dirfd], [Use directory file descriptors], |
| | 682 | [HAVE_DIRFD], [This platform supports directory file descriptors.] |
| | 683 | ) |
| | 684 | |
| | 685 | AM_CONDITIONAL([TEST_JAVA_JUL_AGENT], [test "x$test_java_agent_jul" = "xyes"]) |
| | 686 | AM_CONDITIONAL([TEST_JAVA_LOG4J_AGENT], [test "x$test_java_agent_log4j" = "xyes"]) |
| | 687 | AM_CONDITIONAL([TEST_JAVA_LOG4J2_AGENT], [test "x$test_java_agent_log4j2" = "xyes"]) |
| | 688 | |
| | 689 | if test "x$test_java_agent_jul" = "xyes" || test "x$test_java_agent_log4j" = "xyes" || test "x$test_java_agent_log4j2" = "xyes"; then |
| | 690 | AX_JAVA_OPTIONS |
| | 691 | AX_PROG_JAVAC |
| | 692 | AX_PROG_JAVA |
| | 693 | AX_PROG_JAR |
| | 694 | |
| | 695 | AX_CHECK_CLASSPATH |
| | 696 | |
| | 697 | # Check for Java UST agent common class first |
| | 698 | AX_CHECK_CLASS(org.lttng.ust.agent.AbstractLttngAgent) |
| | 699 | if test "x$ac_cv_class_org_lttng_ust_agent_AbstractLttngAgent" = "xno"; then |
| | 700 | AC_MSG_ERROR([The UST Java agent common class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-common.jar"]) |
| | 701 | fi |
| | 702 | |
| | 703 | if test "x$test_java_agent_jul" = "xyes"; then |
| | 704 | # Check for JUL agent class |
| | 705 | AX_CHECK_CLASS(org.lttng.ust.agent.jul.LttngLogHandler) |
| | 706 | if test "x$ac_cv_class_org_lttng_ust_agent_jul_LttngLogHandler" = "xno"; then |
| | 707 | AC_MSG_ERROR([The UST Java agent JUL class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-jul.jar"]) |
| | 708 | fi |
| | 709 | fi |
| | 710 | |
| | 711 | if test "x$test_java_agent_log4j" = "xyes"; then |
| | 712 | # Check for Log4j agent class |
| | 713 | AX_CHECK_CLASS(org.lttng.ust.agent.log4j.LttngLogAppender) |
| | 714 | if test "x$ac_cv_class_org_lttng_ust_agent_log4j_LttngLogAppender" = "xno"; then |
| | 715 | AC_MSG_ERROR([The UST Java agent Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-log4j.jar"]) |
| | 716 | fi |
| | 717 | |
| | 718 | # Check for Log4j class |
| | 719 | AX_CHECK_CLASS(org.apache.log4j.Logger) |
| | 720 | if test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"; then |
| | 721 | AC_MSG_ERROR([The Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j.jar"]) |
| | 722 | fi |
| | 723 | fi |
| | 724 | |
| | 725 | if test "x$test_java_agent_log4j2" = "xyes"; then |
| | 726 | # Check for Log4j2 agent class |
| | 727 | AX_CHECK_CLASS(org.lttng.ust.agent.log4j2.LttngLogAppender) |
| | 728 | if test "x$ac_cv_class_org_lttng_ust_agent_log4j2_LttngLogAppender" = "xno"; then |
| | 729 | AC_MSG_ERROR([The UST Java agent Log4j 2.x class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-log4j2.jar"]) |
| | 730 | fi |
| | 731 | |
| | 732 | # Check for Log4j 2.x classes |
| | 733 | AX_CHECK_CLASS([org.apache.logging.log4j.Logger]) |
| | 734 | AX_CHECK_CLASS([org.apache.logging.log4j.core.Core]) |
| | 735 | if test "x$ac_cv_class_org_apache_logging_log4j_Logger" = "xno" || test "x$ac_cv_class_org_apache_logging_log4j_core_Core" = "xno"; then |
| | 736 | AC_MSG_ERROR([The Log4j 2.x API or core class was not found. Please specify the location of the jars via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j-core.jar:/path/to/log4j-api.jar"]) |
| | 737 | fi |
| | 738 | fi |
| | 739 | fi |
| | 740 | |
| | 741 | # enable building man pages (user's intention) |
| | 742 | AC_ARG_ENABLE( |
| | 743 | man-pages, |
| | 744 | AS_HELP_STRING( |
| | 745 | [--disable-man-pages], |
| | 746 | [Do not build and install man pages (already built in a distributed tarball)] |
| | 747 | ), |
| | 748 | [man_pages_opt=$enableval], |
| | 749 | [man_pages_opt=yes] |
| | 750 | ) |
| | 751 | |
| | 752 | # check for asciidoc and xmlto if we enabled building the man pages |
| | 753 | have_asciidoc_xmlto=no |
| | 754 | warn_prebuilt_man_pages=no |
| | 755 | |
| | 756 | AS_IF([test "x$man_pages_opt" = "xyes"], [ |
| | 757 | AC_PATH_PROG([ASCIIDOC], [asciidoc], [no]) |
| | 758 | AC_PATH_PROG([XMLTO], [xmlto], [no]) |
| | 759 | |
| | 760 | AS_IF([test "x$ASCIIDOC" = "xno" || test "x$XMLTO" = "xno"], [ |
| | 761 | AS_IF([test "x$in_git_repo" = "xyes"], [ |
| | 762 | # this is an error because we're in the Git repo, which |
| | 763 | # means the man pages are not already generated for us, |
| | 764 | # thus asciidoc/xmlto are required because we were asked |
| | 765 | # to build the man pages |
| | 766 | AC_MSG_ERROR([ |
| | 767 | You need asciidoc and xmlto to build the LTTng-tools man pages. Use |
| | 768 | --disable-man-pages to disable building the man pages, in which case |
| | 769 | they will not be installed. |
| | 770 | ]) |
| | 771 | ], [ |
| | 772 | # only warn here: since we're in the tarball, the man |
| | 773 | # pages should already be generated at this point, thus |
| | 774 | # asciidoc/xmlto are not strictly required |
| | 775 | warn_prebuilt_man_pages=yes |
| | 776 | ]) |
| | 777 | ], [ |
| | 778 | have_asciidoc_xmlto=yes |
| | 779 | ]) |
| | 780 | ]) |
| | 781 | |
| | 782 | # export man page build condition: build the man pages if the user |
| | 783 | # asked for it, and if the tools are available |
| | 784 | AM_CONDITIONAL([MAN_PAGES_OPT], [test "x$man_pages_opt" != "xno"]) |
| | 785 | AM_CONDITIONAL([HAVE_ASCIIDOC_XMLTO], [test "x$have_asciidoc_xmlto" = "xyes"]) |
| | 786 | |
| | 787 | AC_DEFINE_UNQUOTED([MANPATH], ["`eval eval echo $mandir`"], [Path to man pages.]) |
| | 788 | |
| | 789 | # embedded --help message |
| | 790 | AC_ARG_ENABLE( |
| | 791 | [embedded-help], |
| | 792 | AS_HELP_STRING( |
| | 793 | [--enable-embedded-help], |
| | 794 | [Embed the --help messages in the executable files] |
| | 795 | ), |
| | 796 | [embedded_help=$enableval], |
| | 797 | [embedded_help=no] |
| | 798 | ) |
| | 799 | AS_IF([test "x$embedded_help" = "xyes"], [ |
| | 800 | AS_IF([test "x$man_pages_opt" = "xno"], [ |
| | 801 | AC_MSG_ERROR([You need the --enable-man-pages option with the --enable-embedded-help option.]) |
| | 802 | ]) |
| | 803 | AC_PATH_PROG([man_prog_path], [man], [no]) |
| | 804 | AS_IF([test "x$man_prog_path" = "xno"], [ |
| | 805 | AC_MSG_ERROR([You need man with the --enable-embedded-help option.]) |
| | 806 | ]) |
| | 807 | AC_DEFINE_UNQUOTED([LTTNG_EMBED_HELP], 1, [Embed --help messages.]) |
| | 808 | AC_SUBST([MANPROG], [$man_prog_path]) |
| | 809 | ]) |
| | 810 | AM_CONDITIONAL([EMBED_HELP], [test "x$embedded_help" != "xno"]) |
| | 811 | |
| | 812 | # Python agent test |
| | 813 | UST_PYTHON_AGENT="lttngust" |
| | 814 | |
| | 815 | AC_ARG_ENABLE(test-python2-agent, |
| | 816 | AS_HELP_STRING([--enable-test-python2-agent], |
| | 817 | [enable tests for python2 agent. Python2 interpreter path can be overridden by setting the PYTHON2 environment variable. Default: Autodetect] |
| | 818 | ),[:],[test_python2_agent_autodetect=yes] |
| | 819 | ) |
| | 820 | |
| | 821 | AC_ARG_ENABLE(test-python3-agent, |
| | 822 | AS_HELP_STRING([--enable-test-python3-agent], |
| | 823 | [enable tests for python3 agent. Python3 interpreter path can be overridden by setting the PYTHON3 environment variable. Default: Autodetect] |
| | 824 | ),[:],[test_python3_agent_autodetect=yes] |
| | 825 | ) |
| | 826 | |
| | 827 | AC_ARG_ENABLE(test-python-agent-all, |
| | 828 | AS_HELP_STRING([--enable-test-python-agent-all], |
| | 829 | [enable test for all python{2/3} agent.] |
| | 830 | ), |
| | 831 | ) |
| | 832 | |
| | 833 | AS_IF([test ! -z "$enable_test_python_agent_all"], [ |
| | 834 | unset test_python2_agent_autodetect |
| | 835 | unset test_python3_agent_autodetect |
| | 836 | ]) |
| | 837 | |
| | 838 | AS_IF([test "x$enable_test_python_agent_all" = "xyes"], [ |
| | 839 | enable_test_python2_agent=yes |
| | 840 | enable_test_python3_agent=yes |
| | 841 | ]) |
| | 842 | |
| | 843 | AS_IF([test "x$enable_test_python_agent_all" = "xno"], [ |
| | 844 | enable_test_python2_agent=no |
| | 845 | enable_test_python3_agent=no |
| | 846 | ]) |
| | 847 | |
| | 848 | |
| | 849 | AS_IF([test "x$enable_test_python2_agent" = "xyes" -o "x$test_python2_agent_autodetect" = "xyes" ], [ |
| | 850 | AS_IF([test -z "$PYTHON2"], [ |
| | 851 | PYTHON2=python2 |
| | 852 | ], [ |
| | 853 | AC_MSG_WARN([Using user-defined PYTHON2 ($PYTHON2) for lttng-ust python2 agent check]) |
| | 854 | ]) |
| | 855 | |
| | 856 | AC_PATH_PROG([PYTHON2_BIN],[$PYTHON2]) |
| | 857 | AS_IF([test -z "$PYTHON2_BIN"], [ |
| | 858 | AS_IF([test -z "$test_python2_agent_autodetect"],[ |
| | 859 | AC_MSG_ERROR([No python2 interpreter found. PYTHON2 can be set to override default interpreter path]) |
| | 860 | ]) |
| | 861 | ], [ |
| | 862 | AC_MSG_CHECKING([for python2 lttng-ust agent]) |
| | 863 | AS_IF([$PYTHON2_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [ |
| | 864 | PYTHON2_AGENT=$PYTHON2_BIN |
| | 865 | AC_MSG_RESULT([yes]) |
| | 866 | RUN_PYTHON_AGENT_TEST=yes |
| | 867 | ], [ |
| | 868 | AC_MSG_RESULT([no]) |
| | 869 | AS_IF([test -z "$test_python2_agent_autodetect"],[ |
| | 870 | AC_MSG_ERROR([No python2 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.]) |
| | 871 | ]) |
| | 872 | ]) |
| | 873 | |
| | 874 | ]) |
| | 875 | |
| | 876 | ]) |
| | 877 | |
| | 878 | AS_IF([test "x$enable_test_python3_agent" = "xyes" -o "x$test_python3_agent_autodetect" = "xyes" ], [ |
| | 879 | AS_IF([test -z "$PYTHON3"], [ |
| | 880 | PYTHON3=python3 |
| | 881 | ], [ |
| | 882 | AC_MSG_WARN([Using user-defined PYTHON3 ($PYTHON3) for lttng-ust python3 agent check]) |
| | 883 | ]) |
| | 884 | |
| | 885 | AC_PATH_PROG([PYTHON3_BIN],[$PYTHON3]) |
| | 886 | AS_IF([test -z "$PYTHON3_BIN"], [ |
| | 887 | AS_IF([test -z "$test_python3_agent_autodetect"],[ |
| | 888 | AC_MSG_ERROR([No python3 interpreter found. PYTHON3 can be set to override default interpreter path]) |
| | 889 | ]) |
| | 890 | ], [ |
| | 891 | AC_MSG_CHECKING([for python3 lttng-ust agent]) |
| | 892 | AS_IF([$PYTHON3_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [ |
| | 893 | PYTHON3_AGENT=$PYTHON3_BIN |
| | 894 | AC_MSG_RESULT([yes]) |
| | 895 | RUN_PYTHON_AGENT_TEST=yes |
| | 896 | ], [ |
| | 897 | AC_MSG_RESULT([no]) |
| | 898 | AS_IF([test -z "$test_python3_agent_autodetect"],[ |
| | 899 | AC_MSG_ERROR([No python3 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.]) |
| | 900 | ]) |
| | 901 | ]) |
| | 902 | |
| | 903 | ]) |
| | 904 | ]) |
| | 905 | AC_SUBST([RUN_PYTHON_AGENT_TEST]) |
| | 906 | AC_SUBST([PYTHON2_AGENT]) |
| | 907 | AC_SUBST([PYTHON3_AGENT]) |
| | 908 | |
| | 909 | AC_ARG_ENABLE([test-sdt-uprobe], |
| | 910 | [AS_HELP_STRING([--enable-test-sdt-uprobe], [enable the LTTng UST SDT uprobe tests [default=autodetect]])], |
| | 911 | [test_sdt_uprobe="$enableval"], |
| | 912 | [test_sdt_uprobe=autodetect] |
| | 913 | ) |
| | 914 | |
| | 915 | AS_IF([test "$test_sdt_uprobe" != "no"], [ |
| | 916 | LTTNG_CHECK_SDT_WORKS |
| | 917 | AC_PATH_PROG([DTRACE], [dtrace]) |
| | 918 | ]) |
| | 919 | |
| | 920 | AS_IF([test "$test_sdt_uprobe" = "yes"], [ |
| | 921 | AS_IF([test "$lttng_cv_sdt_works" = "no"], [ |
| | 922 | AC_MSG_ERROR([Cannot find 'sys/sdt.h'.]) |
| | 923 | ]) |
| | 924 | AS_IF([test "x$DTRACE" = "x"], [ |
| | 925 | AC_MSG_ERROR([Cannot find SystemTap dtrace. You can set the DTRACE variable to override automatic detection.]) |
| | 926 | ]) |
| | 927 | ]) |
| | 928 | |
| | 929 | AS_IF([test "$test_sdt_uprobe" = "autodetect"], [ |
| | 930 | AS_IF([test "$lttng_cv_sdt_works" = "yes"], [ |
| | 931 | AS_IF([test "x$DTRACE" != "x"], [ |
| | 932 | test_sdt_uprobe=yes |
| | 933 | ]) |
| | 934 | ]) |
| | 935 | ]) |
| | 936 | |
| | 937 | AM_CONDITIONAL([TEST_SDT_UPROBE], [test "$test_sdt_uprobe" = "yes"]) |
| | 938 | |
| | 939 | # Arguments for binaries build exclusion |
| | 940 | AC_ARG_ENABLE([bin-lttng], AS_HELP_STRING([--disable-bin-lttng],[Disable the build of lttng binaries])) |
| | 941 | AC_ARG_ENABLE([bin-lttng-consumerd], AS_HELP_STRING([--disable-bin-lttng-consumerd], |
| | 942 | [Disable the build of lttng-consumerd binaries])) |
| | 943 | AC_ARG_ENABLE([bin-lttng-crash], AS_HELP_STRING([--disable-bin-lttng-crash],[Disable the build of lttng-crash binaries])) |
| | 944 | AC_ARG_ENABLE([bin-lttng-relayd], AS_HELP_STRING([--disable-bin-lttng-relayd], |
| | 945 | [Disable the build of lttng-relayd binaries])) |
| | 946 | AC_ARG_ENABLE([bin-lttng-sessiond], AS_HELP_STRING([--disable-bin-lttng-sessiond], |
| | 947 | [Disable the build of lttng-sessiond binaries])) |
| | 948 | AC_ARG_ENABLE([extras], AS_HELP_STRING([--disable-extras], |
| | 949 | [Disable the build of the extra components])) |
| | 950 | |
| | 951 | |
| | 952 | build_lib_consumer=no |
| | 953 | build_lib_health=no |
| | 954 | build_lib_index=no |
| | 955 | build_lib_kernel_consumer=no |
| | 956 | build_lib_kernel_ctl=no |
| | 957 | build_lib_lttng_ctl=no |
| | 958 | build_lib_relayd=no |
| | 959 | build_lib_sessiond_comm=no |
| | 960 | build_lib_testpoint=no |
| | 961 | build_lib_ust_consumer=no |
| | 962 | |
| | 963 | # There is an overlap for enabled dependencies, but this makes everything |
| | 964 | # simpler. libcommon and libconfig are always compiled so they are not repeated |
| | 965 | # here. |
| | 966 | |
| | 967 | # Enable binary dependencies. |
| | 968 | AS_IF([test x$enable_bin_lttng != xno], |
| | 969 | [ |
| | 970 | build_lib_lttng_ctl=yes |
| | 971 | ] |
| | 972 | ) |
| | 973 | |
| | 974 | AS_IF([test x$enable_bin_lttng_consumerd != xno], |
| | 975 | [ |
| | 976 | build_lib_consumer=yes |
| | 977 | build_lib_sessiond_comm=yes |
| | 978 | build_lib_index=yes |
| | 979 | build_lib_health=yes |
| | 980 | build_lib_testpoint=yes |
| | 981 | ] |
| | 982 | ) |
| | 983 | |
| | 984 | AS_IF([test x$enable_bin_lttng_crash != xno], |
| | 985 | # Do nothing since libconfig and libcommon are built by default. |
| | 986 | [] |
| | 987 | ) |
| | 988 | |
| | 989 | AS_IF([test x$enable_bin_lttng_relayd != xno], |
| | 990 | [ |
| | 991 | build_lib_sessiond_comm=yes |
| | 992 | build_lib_index=yes |
| | 993 | build_lib_health=yes |
| | 994 | build_lib_testpoint=yes |
| | 995 | ] |
| | 996 | ) |
| | 997 | AS_IF([test x$enable_bin_lttng_sessiond != xno], |
| | 998 | [ |
| | 999 | build_lib_lttng_ctl=yes |
| | 1000 | build_lib_sessiond_comm=yes |
| | 1001 | build_lib_kernel_ctl=yes |
| | 1002 | build_lib_relayd=yes |
| | 1003 | build_lib_testpoint=yes |
| | 1004 | build_lib_health=yes |
| | 1005 | ] |
| | 1006 | ) |
| | 1007 | |
| | 1008 | # Libraries dependencies enabling |
| | 1009 | AS_IF([test x$build_lib_lttng_ctl = xyes], |
| | 1010 | [ |
| | 1011 | build_lib_sessiond_comm=yes |
| | 1012 | ] |
| | 1013 | ) |
| | 1014 | |
| | 1015 | AS_IF([test x$build_lib_consumer = xyes], |
| | 1016 | [ |
| | 1017 | build_lib_sessiond_comm=yes |
| | 1018 | build_lib_kernel_consumer=yes |
| | 1019 | build_lib_relayd=yes |
| | 1020 | AS_IF([test "x$with_lttng_ust" = "xyes"], [build_lib_ust_consumer=yes]) |
| | 1021 | ] |
| | 1022 | ) |
| | 1023 | |
| | 1024 | AS_IF([test x$build_lib_kernel_consumer = xyes], |
| | 1025 | [ |
| | 1026 | build_lib_kernel_ctl=yes |
| | 1027 | build_lib_relayd=yes |
| | 1028 | ] |
| | 1029 | ) |
| | 1030 | |
| | 1031 | AS_IF([test x$build_lib_relayd = xyes], |
| | 1032 | [ |
| | 1033 | build_lib_sessiond_comm=yes |
| | 1034 | ] |
| | 1035 | ) |
| | 1036 | |
| | 1037 | # Find arch type |
| | 1038 | AS_CASE([$host_cpu], |
| | 1039 | [k1om], [ARCHTYPE="x86"], |
| | 1040 | [i386], [ARCHTYPE="x86"], |
| | 1041 | [i486], [ARCHTYPE="x86"], |
| | 1042 | [i586], [ARCHTYPE="x86"], |
| | 1043 | [i686], [ARCHTYPE="x86"], |
| | 1044 | [amd64], [ARCHTYPE="x86"], |
| | 1045 | [x86_64], [ARCHTYPE="x86"], |
| | 1046 | [powerpc], [ARCHTYPE="ppc"], |
| | 1047 | [ppc64], [ARCHTYPE="ppc"], |
| | 1048 | [powerpc64], [ARCHTYPE="ppc"], |
| | 1049 | [powerpc64le], [ARCHTYPE="ppc"], |
| | 1050 | [ppc], [ARCHTYPE="ppc"], |
| | 1051 | [s390], [ARCHTYPE="s390"], |
| | 1052 | [s390x], [ARCHTYPE="s390"], |
| | 1053 | [sparc], [ARCHTYPE="sparc64"], |
| | 1054 | [sparc64], [ARCHTYPE="sparc64"], |
| | 1055 | [alpha*], [ARCHTYPE="alpha"], |
| | 1056 | [ia64], [ARCHTYPE="ia64"], |
| | 1057 | [arm*], [ARCHTYPE="arm"], |
| | 1058 | [aarch64*], [ARCHTYPE="aarch64"], |
| | 1059 | [mips*], [ARCHTYPE="mips"], |
| | 1060 | [nios2*], [ARCHTYPE="nios2"], |
| | 1061 | [tile*], [ARCHTYPE="tile"], |
| | 1062 | [hppa*], [ARCHTYPE="hppa"], |
| | 1063 | [m68k], [ARCHTYPE="m68k"], |
| | 1064 | [riscv*], [ARCHTYPE="riscv"], |
| | 1065 | [ARCHTYPE="unknown"] |
| | 1066 | ) |
| | 1067 | |
| | 1068 | AC_SUBST(ARCHTYPE) |
| | 1069 | |
| | 1070 | AS_CASE([$host_os], |
| | 1071 | [linux*], [OSTYPE="linux"], |
| | 1072 | [freebsd*], [OSTYPE="freebsd"], |
| | 1073 | [solaris*], [OSTYPE="solaris"], |
| | 1074 | [cygwin*], [OSTYPE="cygwin"], |
| | 1075 | [mingw*], [OSTYPE="mingw"], |
| | 1076 | [OSTYPE="unknown"] |
| | 1077 | ) |
| | 1078 | AC_SUBST(OSTYPE) |
| | 1079 | AM_CONDITIONAL([IS_LINUX], [test $OSTYPE = "linux"]) |
| | 1080 | |
| | 1081 | |
| | 1082 | |
| | 1083 | # Userspace callstack capture is only supported by the Linux kernel on x86. |
| | 1084 | AH_TEMPLATE([HAVE_MODULES_USERSPACE_CALLSTACK_CONTEXT], [Define if you have LTTng-modules userspace callstack tracing support]) |
| | 1085 | AS_IF([test "x$ARCHTYPE" = "xx86" && test "x$OSTYPE" = "xlinux"],[ |
| | 1086 | have_modules_userspace_callstack_context=yes |
| | 1087 | AC_DEFINE([HAVE_MODULES_USERSPACE_CALLSTACK_CONTEXT], [1]) |
| | 1088 | ]) |
| | 1089 | AM_CONDITIONAL([HAVE_MODULES_USERSPACE_CALLSTACK_CONTEXT], [test x$have_modules_userspace_callstack_context = xyes]) |
| | 1090 | |
| | 1091 | # Export binaries build conditions. |
| | 1092 | AM_CONDITIONAL([BUILD_BIN_LTTNG], [test x$enable_bin_lttng != xno]) |
| | 1093 | AM_CONDITIONAL([BUILD_BIN_LTTNG_CONSUMERD], [test x$enable_bin_lttng_consumerd != xno]) |
| | 1094 | AM_CONDITIONAL([BUILD_BIN_LTTNG_CRASH], [test x$enable_bin_lttng_crash != xno]) |
| | 1095 | AM_CONDITIONAL([BUILD_BIN_LTTNG_RELAYD], [test x$enable_bin_lttng_relayd != xno]) |
| | 1096 | AM_CONDITIONAL([BUILD_BIN_LTTNG_SESSIOND], [test x$enable_bin_lttng_sessiond != xno]) |
| | 1097 | |
| | 1098 | # Export the tests and extras build conditions. |
| | 1099 | AS_IF([\ |
| | 1100 | test "x$enable_bin_lttng" != "xno" && \ |
| | 1101 | test "x$enable_bin_lttng_consumerd" != "xno" && \ |
| | 1102 | test "x$enable_bin_lttng_crash" != "xno" && \ |
| | 1103 | test "x$enable_bin_lttng_relayd" != "xno" && \ |
| | 1104 | test "x$enable_bin_lttng_sessiond" != "xno"], |
| | 1105 | [build_tests=yes], |
| | 1106 | [build_tests=no] |
| | 1107 | ) |
| | 1108 | |
| | 1109 | AM_CONDITIONAL([BUILD_TESTS], [test x$build_tests = xyes]) |
| | 1110 | AM_CONDITIONAL([BUILD_EXTRAS], [test x$enable_extras != xno]) |
| | 1111 | |
| | 1112 | # Export libraries build conditions. |
| | 1113 | AM_CONDITIONAL([BUILD_LIB_CONSUMER], [test x$build_lib_consumer = xyes]) |
| | 1114 | AM_CONDITIONAL([BUILD_LIB_HEALTH], [test x$build_lib_health = xyes]) |
| | 1115 | AM_CONDITIONAL([BUILD_LIB_INDEX], [test x$build_lib_index = xyes]) |
| | 1116 | AM_CONDITIONAL([BUILD_LIB_KERNEL_CONSUMER], [test x$build_lib_kernel_consumer = xyes]) |
| | 1117 | AM_CONDITIONAL([BUILD_LIB_KERNEL_CTL], [test x$build_lib_kernel_ctl = xyes]) |
| | 1118 | AM_CONDITIONAL([BUILD_LIB_LTTNG_CTL], [test x$build_lib_lttng_ctl = xyes]) |
| | 1119 | AM_CONDITIONAL([BUILD_LIB_RELAYD], [test x$build_lib_relayd = xyes]) |
| | 1120 | AM_CONDITIONAL([BUILD_LIB_SESSIOND_COMM], [test x$build_lib_sessiond_comm = xyes]) |
| | 1121 | AM_CONDITIONAL([BUILD_LIB_TESTPOINT], [test x$build_lib_testpoint = xyes]) |
| | 1122 | AM_CONDITIONAL([BUILD_LIB_UST_CONSUMER], [test x$build_lib_ust_consumer = xyes]) |
| | 1123 | |
| | 1124 | AM_CFLAGS="-fvisibility=hidden $OPT_CFLAGS $WARN_CFLAGS $PTHREAD_CFLAGS" |
| | 1125 | AC_SUBST(AM_CFLAGS) |
| | 1126 | |
| | 1127 | AM_CXXFLAGS="-fvisibility=hidden -fvisibility-inlines-hidden $OPT_CXXFLAGS $WARN_CXXFLAGS $PTHREAD_CFLAGS" |
| | 1128 | AC_SUBST(AM_CXXFLAGS) |
| | 1129 | |
| | 1130 | # This is set even though it is empty, so Makefiles can do "AM_LDFLAGS += ...". |
| | 1131 | AM_LDFLAGS="" |
| | 1132 | AC_SUBST(AM_LDFLAGS) |
| | 1133 | |
| | 1134 | # The order in which the include folders are searched is important. |
| | 1135 | # The top_builddir should always be searched first in the event that a build |
| | 1136 | # time generated file is included. An example of this is the "version.i" file. |
| | 1137 | # In a scenario where lttng-tools is built from a distribution tarball and in a |
| | 1138 | # out-of-tree manner, the generated "version.i" has priority on the one from |
| | 1139 | # the source (distribution tarball) and must be found first. |
| | 1140 | AM_CPPFLAGS="-I\$(top_builddir)/include -I\$(top_srcdir)/include -I\$(top_builddir)/src -I\$(top_srcdir)/src -include config.h $AM_CPPFLAGS" |
| | 1141 | AC_SUBST(AM_CPPFLAGS) |
| | 1142 | |
| | 1143 | lttngincludedir="${includedir}/lttng" |
| | 1144 | AC_SUBST(lttngincludedir) |
| | 1145 | |
| | 1146 | lttngactionincludedir="${includedir}/lttng/action" |
| | 1147 | AC_SUBST(lttngactionincludedir) |
| | 1148 | |
| | 1149 | lttngconditionincludedir="${includedir}/lttng/condition" |
| | 1150 | AC_SUBST(lttngconditionincludedir) |
| | 1151 | |
| | 1152 | lttngnotificationincludedir="${includedir}/lttng/notification" |
| | 1153 | AC_SUBST(lttngnotificationincludedir) |
| | 1154 | |
| | 1155 | lttngtriggerincludedir="${includedir}/lttng/trigger" |
| | 1156 | AC_SUBST(lttngtriggerincludedir) |
| | 1157 | |
| | 1158 | lttngeventruleincludedir="${includedir}/lttng/event-rule" |
| | 1159 | AC_SUBST(lttngeventruleincludedir) |
| | 1160 | |
| | 1161 | lttnglibexecdir="${libdir}/lttng/libexec" |
| | 1162 | AC_SUBST(lttnglibexecdir) |
| | 1163 | |
| | 1164 | AC_CONFIG_FILES([ |
| | 1165 | Makefile |
| | 1166 | doc/Makefile |
| | 1167 | doc/examples/Makefile |
| | 1168 | doc/examples/rotation/Makefile |
| | 1169 | doc/examples/trigger-condition-event-matches/Makefile |
| | 1170 | doc/man/Makefile |
| | 1171 | doc/man/asciidoc-attrs.conf |
| | 1172 | include/Makefile |
| | 1173 | extras/Makefile |
| | 1174 | extras/bindings/Makefile |
| | 1175 | extras/bindings/swig/Makefile |
| | 1176 | extras/bindings/swig/python/Makefile |
| | 1177 | extras/core-handler/Makefile |
| | 1178 | src/Makefile |
| | 1179 | src/common/Makefile |
| | 1180 | src/lib/Makefile |
| | 1181 | src/lib/lttng-ctl/Makefile |
| | 1182 | src/lib/lttng-ctl/lttng-ctl.pc |
| | 1183 | src/bin/Makefile |
| | 1184 | src/bin/lttng-consumerd/Makefile |
| | 1185 | src/bin/lttng-sessiond/Makefile |
| | 1186 | src/bin/lttng-relayd/Makefile |
| | 1187 | src/bin/lttng/Makefile |
| | 1188 | src/bin/lttng-crash/Makefile |
| | 1189 | src/vendor/Makefile |
| | 1190 | src/vendor/msgpack/Makefile |
| | 1191 | tests/Makefile |
| | 1192 | tests/destructive/Makefile |
| | 1193 | tests/regression/Makefile |
| | 1194 | tests/regression/kernel/Makefile |
| | 1195 | tests/regression/tools/Makefile |
| | 1196 | tests/regression/tools/streaming/Makefile |
| | 1197 | tests/regression/tools/filtering/Makefile |
| | 1198 | tests/regression/tools/health/Makefile |
| | 1199 | tests/regression/tools/tracefile-limits/Makefile |
| | 1200 | tests/regression/tools/snapshots/Makefile |
| | 1201 | tests/regression/tools/live/Makefile |
| | 1202 | tests/regression/tools/exclusion/Makefile |
| | 1203 | tests/regression/tools/save-load/Makefile |
| | 1204 | tests/regression/tools/save-load/configuration/Makefile |
| | 1205 | tests/regression/tools/mi/Makefile |
| | 1206 | tests/regression/tools/wildcard/Makefile |
| | 1207 | tests/regression/tools/channel/Makefile |
| | 1208 | tests/regression/tools/crash/Makefile |
| | 1209 | tests/regression/tools/regen-metadata/Makefile |
| | 1210 | tests/regression/tools/regen-statedump/Makefile |
| | 1211 | tests/regression/tools/notification/Makefile |
| | 1212 | tests/regression/tools/rotation/Makefile |
| | 1213 | tests/regression/tools/base-path/Makefile |
| | 1214 | tests/regression/tools/metadata/Makefile |
| | 1215 | tests/regression/tools/tracker/Makefile |
| | 1216 | tests/regression/tools/working-directory/Makefile |
| | 1217 | tests/regression/tools/relayd-grouping/Makefile |
| | 1218 | tests/regression/tools/clear/Makefile |
| | 1219 | tests/regression/tools/trigger/Makefile |
| | 1220 | tests/regression/tools/trigger/rate-policy/Makefile |
| | 1221 | tests/regression/tools/trigger/start-stop/Makefile |
| | 1222 | tests/regression/tools/trigger/utils/Makefile |
| | 1223 | tests/regression/tools/trigger/name/Makefile |
| | 1224 | tests/regression/tools/trigger/hidden/Makefile |
| | 1225 | tests/regression/ust/Makefile |
| | 1226 | tests/regression/ust/nprocesses/Makefile |
| | 1227 | tests/regression/ust/high-throughput/Makefile |
| | 1228 | tests/regression/ust/low-throughput/Makefile |
| | 1229 | tests/regression/ust/before-after/Makefile |
| | 1230 | tests/regression/ust/buffers-pid/Makefile |
| | 1231 | tests/regression/ust/periodical-metadata-flush/Makefile |
| | 1232 | tests/regression/ust/multi-session/Makefile |
| | 1233 | tests/regression/ust/multi-lib/Makefile |
| | 1234 | tests/regression/ust/overlap/Makefile |
| | 1235 | tests/regression/ust/overlap/demo/Makefile |
| | 1236 | tests/regression/ust/linking/Makefile |
| | 1237 | tests/regression/ust/daemon/Makefile |
| | 1238 | tests/regression/ust/exit-fast/Makefile |
| | 1239 | tests/regression/ust/fork/Makefile |
| | 1240 | tests/regression/ust/libc-wrapper/Makefile |
| | 1241 | tests/regression/ust/baddr-statedump/Makefile |
| | 1242 | tests/regression/ust/ust-dl/Makefile |
| | 1243 | tests/regression/ust/java-jul/Makefile |
| | 1244 | tests/regression/ust/java-log4j/Makefile |
| | 1245 | tests/regression/ust/java-log4j2/Makefile |
| | 1246 | tests/regression/ust/getcpu-override/Makefile |
| | 1247 | tests/regression/ust/clock-override/Makefile |
| | 1248 | tests/regression/ust/type-declarations/Makefile |
| | 1249 | tests/regression/ust/rotation-destroy-flush/Makefile |
| | 1250 | tests/regression/ust/blocking/Makefile |
| | 1251 | tests/regression/ust/namespaces/Makefile |
| | 1252 | tests/stress/Makefile |
| | 1253 | tests/unit/Makefile |
| | 1254 | tests/unit/ini_config/Makefile |
| | 1255 | tests/perf/Makefile |
| | 1256 | tests/utils/Makefile |
| | 1257 | tests/utils/tap/Makefile |
| | 1258 | tests/utils/testapp/Makefile |
| | 1259 | tests/utils/testapp/gen-ns-events/Makefile |
| | 1260 | tests/utils/testapp/gen-kernel-test-events/Makefile |
| | 1261 | tests/utils/testapp/gen-py-events/Makefile |
| | 1262 | tests/utils/testapp/gen-ust-events/Makefile |
| | 1263 | tests/utils/testapp/gen-ust-events-ns/Makefile |
| | 1264 | tests/utils/testapp/gen-syscall-events-callstack/Makefile |
| | 1265 | tests/utils/testapp/gen-ust-nevents/Makefile |
| | 1266 | tests/utils/testapp/gen-ust-nevents-str/Makefile |
| | 1267 | tests/utils/testapp/gen-syscall-events/Makefile |
| | 1268 | tests/utils/testapp/gen-ust-tracef/Makefile |
| | 1269 | tests/utils/testapp/userspace-probe-elf-binary/Makefile |
| | 1270 | tests/utils/testapp/userspace-probe-elf-cxx-binary/Makefile |
| | 1271 | tests/utils/testapp/userspace-probe-sdt-binary/Makefile |
| | 1272 | tests/utils/xml-utils/Makefile |
| | 1273 | ]) |
| | 1274 | |
| | 1275 | # Inject variable into python test script. |
| | 1276 | AC_CONFIG_FILES([tests/regression/ust/python-logging/test_python_logging],[chmod +x tests/regression/ust/python-logging/test_python_logging]) |
| | 1277 | # Inject LTTNG_TOOLS_BUILD_WITH_LIBPFM variable in test script. |
| | 1278 | AC_CONFIG_FILES([tests/perf/test_perf_raw],[chmod +x tests/perf/test_perf_raw]) |
| | 1279 | AC_CONFIG_FILES([tests/regression/ust/ust-dl/test_ust-dl],[chmod +x tests/regression/ust/ust-dl/test_ust-dl]) |
| | 1280 | |
| | 1281 | AC_OUTPUT |
| | 1282 | |
| | 1283 | # |
| | 1284 | # Mini-report on what will be built. |
| | 1285 | # |
| | 1286 | |
| | 1287 | PPRINT_INIT |
| | 1288 | PPRINT_SET_INDENT(1) |
| | 1289 | PPRINT_SET_TS(38) |
| | 1290 | |
| | 1291 | AS_ECHO |
| | 1292 | AS_ECHO("${PPRINT_COLOR_BLDBLU}LTTng-tools $PACKAGE_VERSION \"$version_name\"$PPRINT_COLOR_RST") |
| | 1293 | AS_ECHO |
| | 1294 | |
| | 1295 | AS_IF([test -n "$report_fold"], [ |
| | 1296 | AS_ECHO("`AS_ECHO("$version_description") | $report_fold -s`") |
| | 1297 | ], [ |
| | 1298 | AS_ECHO("$version_description") |
| | 1299 | ]) |
| | 1300 | |
| | 1301 | AS_ECHO |
| | 1302 | PPRINT_SUBTITLE([Features]) |
| | 1303 | |
| | 1304 | # Target architecture we're building for. |
| | 1305 | target_arch=$host_cpu |
| | 1306 | [ |
| | 1307 | for f in $CFLAGS; do |
| | 1308 | if test $f = "-m32"; then |
| | 1309 | target_arch="32-bit" |
| | 1310 | elif test $f = "-m64"; then |
| | 1311 | target_arch="64-bit" |
| | 1312 | fi |
| | 1313 | done |
| | 1314 | ] |
| | 1315 | PPRINT_PROP_STRING([Target architecture], $target_arch) |
| | 1316 | |
| | 1317 | # kmod enabled/disabled |
| | 1318 | test "x$with_kmod" != "xno" && value=1 || value=0 |
| | 1319 | PPRINT_PROP_BOOL([libkmod support], $value) |
| | 1320 | |
| | 1321 | # LTTng-UST enabled/disabled |
| | 1322 | test "x$with_lttng_ust" = "xyes" && value=1 || value=0 |
| | 1323 | PPRINT_PROP_BOOL([LTTng-UST support], $value) |
| | 1324 | |
| | 1325 | AS_ECHO |
| | 1326 | PPRINT_SUBTITLE([Binaries]) |
| | 1327 | |
| | 1328 | # List binaries to be built |
| | 1329 | test x$enable_bin_lttng != xno && value=1 || value=0 |
| | 1330 | PPRINT_PROP_BOOL([lttng], $value) |
| | 1331 | |
| | 1332 | test x$enable_bin_lttng_consumerd != xno && value=1 || value=0 |
| | 1333 | PPRINT_PROP_BOOL([lttng-consumerd], $value) |
| | 1334 | |
| | 1335 | test x$enable_bin_lttng_crash != xno && value=1 || value=0 |
| | 1336 | PPRINT_PROP_BOOL([lttng-crash], $value) |
| | 1337 | |
| | 1338 | test x$enable_bin_lttng_relayd != xno && value=1 || value=0 |
| | 1339 | PPRINT_PROP_BOOL([lttng-relayd], $value) |
| | 1340 | |
| | 1341 | test x$enable_bin_lttng_sessiond != xno && value=1 || value=0 |
| | 1342 | PPRINT_PROP_BOOL([lttng-sessiond], $value) |
| | 1343 | |
| | 1344 | # Extras |
| | 1345 | test x$enable_extras != xno && value=1 || value=0 |
| | 1346 | AS_ECHO |
| | 1347 | PPRINT_SET_INDENT(0) |
| | 1348 | PPRINT_PROP_BOOL([Extras], $value, $PPRINT_COLOR_SUBTITLE) |
| | 1349 | PPRINT_SET_INDENT(1) |
| | 1350 | |
| | 1351 | AS_ECHO |
| | 1352 | PPRINT_SUBTITLE([Tests]) |
| | 1353 | |
| | 1354 | # Print clear message that tests won't be built |
| | 1355 | AS_IF([test "x$build_tests" = "xno"],[ |
| | 1356 | PPRINT_WARN([Tests won't be built since some binaries were disabled]) |
| | 1357 | ]) |
| | 1358 | |
| | 1359 | # LTTng UST Java agent JUL tests enabled/disabled |
| | 1360 | test "x$test_java_agent_jul" = "xyes" && value=1 || value=0 |
| | 1361 | PPRINT_PROP_BOOL([LTTng-UST Java agent JUL tests], $value) |
| | 1362 | |
| | 1363 | # LTTng UST Java agent Log4j 1.x tests enabled/disabled |
| | 1364 | test "x$test_java_agent_log4j" = "xyes" && value=1 || value=0 |
| | 1365 | PPRINT_PROP_BOOL([LTTng-UST Java agent Log4j 1.x tests], $value) |
| | 1366 | |
| | 1367 | # LTTng UST Java agent Log4j 2.x tests enabled/disabled |
| | 1368 | test "x$test_java_agent_log4j2" = "xyes" && value=1 || value=0 |
| | 1369 | PPRINT_PROP_BOOL([LTTng-UST Java agent Log4j 2.x tests], $value) |
| | 1370 | |
| | 1371 | test ! -z "$PYTHON2_AGENT" && value=1 || value=0 |
| | 1372 | PPRINT_PROP_BOOL([LTTng-UST Python2 agent tests], $value) |
| | 1373 | |
| | 1374 | test ! -z "$PYTHON3_AGENT" && value=1 || value=0 |
| | 1375 | PPRINT_PROP_BOOL([LTTng-UST Python3 agent tests], $value) |
| | 1376 | |
| | 1377 | # userspace-probe SDT instrumentation tests enabled/disabled |
| | 1378 | test "x$test_sdt_uprobe" = "xyes" && value=1 || value=0 |
| | 1379 | PPRINT_PROP_BOOL([LTTng-modules SDT uprobe tests], $value) |
| | 1380 | |
| | 1381 | #Python binding enabled/disabled |
| | 1382 | test "x$enable_python_binding" = xyes && value=1 || value=0 |
| | 1383 | AS_ECHO |
| | 1384 | PPRINT_SET_INDENT(0) |
| | 1385 | PPRINT_PROP_BOOL([Python binding], $value, $PPRINT_COLOR_SUBTITLE) |
| | 1386 | |
| | 1387 | # man pages build enabled/disabled |
| | 1388 | m4_pushdef([build_man_pages_msg], [Build and install man pages]) |
| | 1389 | |
| | 1390 | AS_IF([test "x$man_pages_opt" != "xno"], [ |
| | 1391 | AS_IF([test "x$in_git_repo" = "xyes"], [ |
| | 1392 | PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE) |
| | 1393 | ], [ |
| | 1394 | AS_IF([test "x$have_asciidoc_xmlto" = "xyes"], [ |
| | 1395 | PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE) |
| | 1396 | ], [ |
| | 1397 | PPRINT_PROP_STRING([build_man_pages_msg], |
| | 1398 | [${PPRINT_COLOR_BLDGRN}yes (already built)], |
| | 1399 | $PPRINT_COLOR_SUBTITLE) |
| | 1400 | ]) |
| | 1401 | ]) |
| | 1402 | ], [ |
| | 1403 | PPRINT_PROP_BOOL([build_man_pages_msg], 0, $PPRINT_COLOR_SUBTITLE) |
| | 1404 | ]) |
| | 1405 | |
| | 1406 | m4_popdef([build_man_pages_msg]) |
| | 1407 | |
| | 1408 | test "x$embedded_help" = xyes && value=1 || value=0 |
| | 1409 | PPRINT_PROP_BOOL([Embed --help messages], $value, $PPRINT_COLOR_SUBTITLE) |
| | 1410 | |
| | 1411 | PPRINT_SET_INDENT(1) |
| | 1412 | |
| | 1413 | report_bindir="`eval eval echo $bindir`" |
| | 1414 | report_libdir="`eval eval echo $libdir`" |
| | 1415 | |
| | 1416 | # Print the bindir and libdir this `make install' will install into. |
| | 1417 | AS_ECHO |
| | 1418 | PPRINT_SUBTITLE([Install directories]) |
| | 1419 | PPRINT_PROP_STRING([Binaries], [$report_bindir]) |
| | 1420 | PPRINT_PROP_STRING([Libraries], [$report_libdir]) |
| | 1421 | |
| | 1422 | AS_ECHO |
| | 1423 | PPRINT_SUBTITLE([Search directories]) |
| | 1424 | |
| | 1425 | # If we build the sessiond, print the paths it will use |
| | 1426 | AS_IF([test "$SESSIOND_BIN" = ""],[ |
| | 1427 | path="$report_bindir/lttng-sessiond" |
| | 1428 | ],[ |
| | 1429 | path="$SESSIOND_BIN" |
| | 1430 | ]) |
| | 1431 | PPRINT_PROP_STRING([lttng-sessiond executable], [$path]) |
| | 1432 | |
| | 1433 | AS_IF([test "$CONSUMERD32_BIN" = ""],[ |
| | 1434 | path="`eval eval echo $lttnglibexecdir`/lttng-consumerd" |
| | 1435 | ],[ |
| | 1436 | path="$CONSUMERD32_BIN" |
| | 1437 | ]) |
| | 1438 | PPRINT_PROP_STRING([32-bit lttng-consumerd executable], [$path]) |
| | 1439 | |
| | 1440 | AS_IF([test "$CONSUMERD32_LIBDIR" = ""],[ |
| | 1441 | path="`eval eval echo $libdir`" |
| | 1442 | ],[ |
| | 1443 | path="$CONSUMERD32_LIBDIR" |
| | 1444 | ]) |
| | 1445 | PPRINT_PROP_STRING([32-bit consumer libraries], [$path]) |
| | 1446 | |
| | 1447 | AS_IF([test "$CONSUMERD64_BIN" = ""],[ |
| | 1448 | path="`eval eval echo $lttnglibexecdir`/lttng-consumerd" |
| | 1449 | ],[ |
| | 1450 | path="$CONSUMERD64_BIN" |
| | 1451 | ]) |
| | 1452 | PPRINT_PROP_STRING([64-bit lttng-consumerd executable], [$path]) |
| | 1453 | |
| | 1454 | AS_IF([test "$CONSUMERD64_LIBDIR" = ""],[ |
| | 1455 | path="`eval eval echo $libdir`" |
| | 1456 | ],[ |
| | 1457 | path="$CONSUMERD64_LIBDIR" |
| | 1458 | ]) |
| | 1459 | PPRINT_PROP_STRING([64-bit consumer libraries], [$path]) |
| | 1460 | PPRINT_SET_INDENT(0) |
| | 1461 | |
| | 1462 | AS_IF([test "x$warn_prebuilt_man_pages" = "xyes" ], [ |
| | 1463 | AS_ECHO |
| | 1464 | PPRINT_WARN([You need asciidoc and xmlto to build the LTTng-tools man pages. |
| | 1465 | |
| | 1466 | Note that the man pages are already built in this distribution tarball, |
| | 1467 | therefore asciidoc and xmlto are only needed if you intend to modify |
| | 1468 | their sources. |
| | 1469 | |
| | 1470 | Also note that the installed man pages will contain the project's |
| | 1471 | default command-line option and environment variable values. |
| | 1472 | |
| | 1473 | Use --disable-man-pages to completely disable building and installing |
| | 1474 | the man pages.]) |
| | 1475 | ]) |
projects / lttng-tools.git / blame_incremental