+AC_INIT([lttng-ust],[2.4.0-rc1],[mathieu dot desnoyers at efficios dot com])
+
+# Following the numbering scheme proposed by libtool for the library version
+# http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
+# This is the library version of liblttng-ust.
+AC_SUBST([LTTNG_UST_LIBRARY_VERSION], [0:0:0])
+# note: remember to update tracepoint.h dlopen() to match this version
+# number. TODO: eventually automate by exporting the major number.
+
+# This is the library version of liblttng-ust-ctl, used internally by
+# liblttng-ust, lttng-sessiond, and lttng-consumerd.
+AC_SUBST([LTTNG_UST_CTL_LIBRARY_VERSION], [2:0:0])
+
+AC_CONFIG_AUX_DIR([config])
+AC_CANONICAL_TARGET
+AC_CANONICAL_HOST
+AC_CONFIG_MACRO_DIR([config])
+AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
+m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
+AC_CONFIG_SRCDIR([include/lttng/tracepoint.h])
+
+# Configuration options, which will be installed in the config.h
+AC_CONFIG_HEADERS([config.h include/lttng/ust-config.h])
+AH_TEMPLATE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [Use efficient unaligned access.])
+AH_TEMPLATE([LTTNG_UST_HAVE_SDT_INTEGRATION], [SystemTap integration via sdt.h])
+
+# Compute minor/major/patchlevel version numbers
+AC_PROG_SED
+major_version=$(echo AC_PACKAGE_VERSION | sed 's/^\([[0-9]]\)*\.[[0-9]]*\.[[0-9]]*.*$/\1/')
+minor_version=$(echo AC_PACKAGE_VERSION | sed 's/^[[0-9]]*\.\([[0-9]]*\)\.[[0-9]]*.*$/\1/')
+patchlevel_version=$(echo AC_PACKAGE_VERSION | sed 's/^[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\).*$/\1/')
+AC_SUBST([MAJOR_VERSION], [$major_version])
+AC_SUBST([MINOR_VERSION], [$minor_version])
+AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version])
+AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [UST major version number])
+AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [UST minor version number])
+AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [UST patchlevel version number])
+
+version_name="Époque Opaque"
+version_description="The Époque Opaque is a black IPA from Trou du Diable brewery. The nose is eerily reminiscent of the coffee crisp candy from of our childhood. These strong mocha accents are present on the palate, which are quickly subdued by Japanese and Australian hops leading to a final state of satisfaction enjoyable for any fan of bitter beer."
+
+AC_DEFINE_UNQUOTED([VERSION_NAME], ["$version_name"], [UST version name])
+AC_DEFINE_UNQUOTED([VERSION_DESCRIPTION], ["$version_description"], [UST version description])
+
+AC_PROG_GREP
+# libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
+AC_ARG_ENABLE(libtool-linkdep-fixup,
+ AS_HELP_STRING([--disable-libtool-linkdep-fixup],
+ [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)]),
+ libtool_fixup=$enableval,
+ libtool_fixup=yes)
+
+AS_IF([test "x$libtool_fixup" = "xyes"],
+ [
+ libtool_m4="$srcdir/config/libtool.m4"
+ libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
+ AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
+ libtool_flag_pattern_count=$(grep -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
+ AS_IF([test $libtool_flag_pattern_count -ne 0],
+ [
+ AC_MSG_RESULT([$libtool_flag_pattern_count])
+ AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
+ sed -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
+ ],
+ [
+ AC_MSG_RESULT([none])
+ ])
+ ])
+
+AM_CONDITIONAL([NO_SHARED], [test "x$enable_shared" = "xno"])