scripts/system-tests/system-trigger.groovy

   1 /**
   2  * Copyright (C) 2017 - Francis Deslauriers <francis.deslauriers@efficios.com>
   3  *
   4  * This program is free software: you can redistribute it and/or modify
   5  * it under the terms of the GNU General Public License as published by
   6  * the Free Software Foundation, either version 3 of the License, or
   7  * (at your option) any later version.
   8  *
   9  * This program is distributed in the hope that it will be useful,
  10  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  11  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12  * GNU General Public License for more details.
  13  *
  14  * You should have received a copy of the GNU General Public License
  15  * along with this program.  If not, see <http://www.gnu.org/licenses/>.
  16  */
  17
  18 import hudson.console.HyperlinkNote
  19 import hudson.model.*
  20 import java.io.File
  21 import org.eclipse.jgit.api.Git
  22 import org.eclipse.jgit.lib.Ref
  23
  24 class InvalidKVersionException extends Exception {
  25   public InvalidKVersionException(String message) {
  26     super(message)
  27   }
  28 }
  29
  30 class EmptyKVersionException extends Exception {
  31   public EmptyKVersionException(String message) {
  32     super(message)
  33   }
  34 }
  35
  36 class VanillaKVersion implements Comparable<VanillaKVersion> {
  37
  38   Integer major = 0
  39   Integer majorB = 0
  40   Integer minor = 0
  41   Integer patch = 0
  42   Integer rc = Integer.MAX_VALUE
  43   Boolean inStable = false;
  44
  45   VanillaKVersion() {}
  46
  47   VanillaKVersion(version) {
  48     this.parse(version)
  49   }
  50
  51   static VanillaKVersion minKVersion() {
  52     return new VanillaKVersion("v0.0.0")
  53   }
  54
  55   static VanillaKVersion maxKVersion() {
  56     return new VanillaKVersion("v" + Integer.MAX_VALUE + ".0.0")
  57   }
  58
  59   static VanillaKVersion factory(version) {
  60     return new VanillaKVersion(version)
  61   }
  62
  63   def parse(version) {
  64     this.major = 0
  65     this.majorB = 0
  66     this.minor = 0
  67     this.patch = 0
  68     this.rc = Integer.MAX_VALUE
  69
  70     if (!version) {
  71       throw new EmptyKVersionException("Empty kernel version")
  72     }
  73
  74     def match = version =~ /^v(\d+)\.(\d+)(\.(\d+))?(\.(\d+))?(-rc(\d+))?$/
  75     if (!match) {
  76       throw new InvalidKVersionException("Invalid kernel version: ${version}")
  77     }
  78
  79     Integer offset = 0;
  80
  81     // Major
  82     this.major = Integer.parseInt(match.group(1))
  83     if (this.major <= 2) {
  84       offset = 2
  85       this.majorB = Integer.parseInt(match.group(2))
  86     }
  87
  88     // Minor
  89     if (match.group(2 + offset) != null) {
  90       this.minor = Integer.parseInt(match.group(2 + offset))
  91     }
  92
  93     // Patch level
  94     if (match.group(4 + offset) != null) {
  95       this.patch = Integer.parseInt(match.group(4 + offset))
  96       this.inStable = true
  97     }
  98
  99     // RC
 100     if (match.group(8) != null) {
 101       this.rc = Integer.parseInt(match.group(8))
 102     }
 103   }
 104
 105   Boolean isInStableBranch() {
 106     return this.inStable
 107   }
 108
 109   // Return true if both version are of the same stable branch
 110   Boolean isSameStable(VanillaKVersion o) {
 111     if (this.major != o.major) {
 112       return false
 113     }
 114     if (this.majorB != o.majorB) {
 115       return false
 116     }
 117     if (this.minor != o.minor) {
 118       return false
 119     }
 120
 121     return true
 122   }
 123
 124   @Override int compareTo(VanillaKVersion o) {
 125     if (this.major != o.major) {
 126       return Integer.compare(this.major, o.major)
 127     }
 128     if (this.majorB != o.majorB) {
 129       return Integer.compare(this.majorB, o.majorB)
 130     }
 131     if (this.minor != o.minor) {
 132       return Integer.compare(this.minor, o.minor)
 133     }
 134     if (this.patch != o.patch) {
 135       return Integer.compare(this.patch, o.patch)
 136     }
 137     if (this.rc != o.rc) {
 138       return Integer.compare(this.rc, o.rc)
 139     }
 140
 141     // Same version
 142     return 0;
 143   }
 144
 145   String toString() {
 146     String vString = "v${this.major}"
 147
 148     if (this.majorB > 0) {
 149       vString = vString.concat(".${this.majorB}")
 150     }
 151
 152     vString = vString.concat(".${this.minor}")
 153
 154     if (this.patch > 0) {
 155       vString = vString.concat(".${this.patch}")
 156     }
 157
 158     if (this.rc > 0 && this.rc < Integer.MAX_VALUE) {
 159       vString = vString.concat("-rc${this.rc}")
 160     }
 161     return vString
 162   }
 163 }
 164
 165 // Save the hashmap containing all the jobs and their status to disk. We can do
 166 // that because this job is configured to always run on the master node on
 167 // Jenkins.
 168 def SaveCurrentJobsToWorkspace = { currentJobs, ondiskpath->
 169   try {
 170     File myFile = new File(ondiskpath);
 171     myFile.createNewFile();
 172     def out = new ObjectOutputStream(new FileOutputStream(ondiskpath))
 173     out.writeObject(currentJobs)
 174     out.close()
 175   } catch (e) {
 176     println("Failed to save previous Git object IDs to disk." + e);
 177   }
 178 }
 179
 180 // Load the hashmap containing all the jobs and their last status from disk.
 181 // It's possible because this job is configured to always run on the master
 182 // node on Jenkins
 183 def LoadPreviousJobsFromWorkspace = { ondiskpath ->
 184   def previousJobs = [:]
 185   try {
 186     File myFile = new File(ondiskpath);
 187     def input = new ObjectInputStream(new FileInputStream(ondiskpath))
 188     previousJobs = input.readObject()
 189     input.close()
 190   } catch (e) {
 191     println("Failed to load previous runs from disk." + e);
 192   }
 193   return previousJobs
 194 }
 195
 196
 197 def GetHeadCommits = { remoteRepo, branchesOfInterest ->
 198   def remoteHeads = [:]
 199   def remoteHeadRefs = Git.lsRemoteRepository()
 200                           .setTags(false)
 201                           .setHeads(true)
 202                           .setRemote(remoteRepo).call()
 203
 204   remoteHeadRefs.each {
 205     def branch = it.getName().replaceAll('refs/heads/', '')
 206     if (branchesOfInterest.contains(branch))
 207       remoteHeads[branch] = it.getObjectId().name()
 208   }
 209
 210   return remoteHeads
 211 }
 212
 213 def GetTagIds = { remoteRepo ->
 214   def remoteTags = [:]
 215   def remoteTagRefs = Git.lsRemoteRepository()
 216                          .setTags(true)
 217                          .setHeads(false)
 218                          .setRemote(remoteRepo).call()
 219
 220   remoteTagRefs.each {
 221     // Exclude release candidate tags
 222     if (!it.getName().contains('-rc')) {
 223       remoteTags[it.getName().replaceAll('refs/tags/', '')] = it.getObjectId().name()
 224     }
 225   }
 226
 227   return remoteTags
 228 }
 229
 230 def GetLastTagOfBranch = { tagRefs, branch ->
 231   def tagVersions = tagRefs.collect {new VanillaKVersion(it.key)}
 232   def currMax = new VanillaKVersion('v0.0.0');
 233   if (!branch.contains('master')){
 234     def targetVersion = new VanillaKVersion(branch.replaceAll('linux-', 'v').replaceAll('.y', ''))
 235     tagVersions.each {
 236       if (it.isSameStable(targetVersion)) {
 237         if (currMax < it) {
 238           currMax = it;
 239         }
 240       }
 241     }
 242   } else {
 243     tagVersions.each {
 244       if (!it.isInStableBranch() && currMax < it) {
 245         currMax = it;
 246       }
 247     }
 248   }
 249   return currMax.toString()
 250 }
 251
 252 // Returns the latest tags of each of the branches passed in the argument
 253 def GetLastTagIds = { remoteRepo, branchesOfInterest ->
 254   def remoteHeads = GetHeadCommits(remoteRepo, branchesOfInterest)
 255   def remoteTagRefs = GetTagIds(remoteRepo)
 256   def remoteLastTagCommit = [:]
 257
 258   remoteTagRefs = remoteTagRefs.findAll { !it.key.contains("v2.") }
 259   branchesOfInterest.each {
 260     remoteLastTagCommit[it] = remoteTagRefs[GetLastTagOfBranch(remoteTagRefs, it)]
 261   }
 262
 263   return remoteLastTagCommit
 264 }
 265
 266 def CraftJobName = { jobType, linuxBranch, lttngBranch ->
 267   return "${jobType}_k${linuxBranch}_l${lttngBranch}"
 268 }
 269
 270 def LaunchJob = { jobName, jobInfo ->
 271   def job = Hudson.instance.getJob(jobName)
 272   def params = []
 273   for (paramdef in job.getProperty(ParametersDefinitionProperty.class).getParameterDefinitions()) {
 274     // If there is a default value for this parameter, use it. Don't use empty
 275     // default value parameters.
 276     if (paramdef.getDefaultValue()) {
 277       params += paramdef.getDefaultParameterValue();
 278     }
 279   }
 280
 281   params.add(new StringParameterValue('LTTNG_TOOLS_COMMIT_ID', jobInfo['config']['toolsCommit']))
 282   params.add(new StringParameterValue('LTTNG_MODULES_COMMIT_ID', jobInfo['config']['modulesCommit']))
 283   params.add(new StringParameterValue('LTTNG_UST_COMMIT_ID', jobInfo['config']['ustCommit']))
 284   params.add(new StringParameterValue('KERNEL_TAG_ID', jobInfo['config']['linuxTagID']))
 285   def currBuild = job.scheduleBuild2(0, new Cause.UpstreamCause(build), new ParametersAction(params))
 286
 287   if (currBuild != null ) {
 288     println("Launching job: ${HyperlinkNote.encodeTo('/' + job.url, job.fullDisplayName)}");
 289   } else {
 290     println("Job ${jobName} not found or deactivated.");
 291   }
 292
 293   return currBuild
 294 }
 295
 296 final String toolsRepo = "https://github.com/lttng/lttng-tools.git"
 297 final String modulesRepo = "https://github.com/lttng/lttng-modules.git"
 298 final String ustRepo = "https://github.com/lttng/lttng-ust.git"
 299 final String linuxRepo = "git://git.kernel.org/pub/scm/linux/kernel/git/stable/linux-stable.git"
 300
 301 final String pastJobsPath = build.getEnvironment(listener).get('WORKSPACE') + "/pastjobs";
 302
 303 def recentLttngBranchesOfInterest = ['master',
 304   'stable-2.12',
 305   'stable-2.11']
 306 def recentLinuxBranchesOfInterest = ['master',
 307   'linux-5.4.y',
 308   'linux-5.1.y',
 309   'linux-5.0.y',
 310   'linux-4.19.y',
 311   'linux-4.14.y',
 312   'linux-4.9.y',
 313   'linux-4.4.y']
 314
 315 def legacyLttngBranchesOfInterest = []
 316 def legacyLinuxBranchesOfInterest = []
 317
 318 def vmLinuxBranchesOfInterest = ['linux-3.18.y']
 319
 320 // Generate configurations of interest.
 321 def configurationOfInterest = [] as Set
 322
 323 recentLttngBranchesOfInterest.each { lttngBranch ->
 324   recentLinuxBranchesOfInterest.each { linuxBranch ->
 325     configurationOfInterest.add([lttngBranch, linuxBranch])
 326   }
 327 }
 328
 329 legacyLttngBranchesOfInterest.each { lttngBranch ->
 330   legacyLinuxBranchesOfInterest.each { linuxBranch ->
 331     configurationOfInterest.add([lttngBranch, linuxBranch])
 332   }
 333 }
 334
 335 def lttngBranchesOfInterest = recentLttngBranchesOfInterest + legacyLttngBranchesOfInterest
 336 def linuxBranchesOfInterest = recentLinuxBranchesOfInterest + legacyLinuxBranchesOfInterest + vmLinuxBranchesOfInterest
 337
 338 // For LTTng branches, we look for new commits.
 339 def toolsHeadCommits = GetHeadCommits(toolsRepo, lttngBranchesOfInterest)
 340 def modulesHeadCommits = GetHeadCommits(modulesRepo, lttngBranchesOfInterest)
 341 def ustHeadCommits = GetHeadCommits(ustRepo, lttngBranchesOfInterest)
 342
 343 // For Linux branches, we look for new non-RC tags.
 344 def linuxLastTagIds = GetLastTagIds(linuxRepo, linuxBranchesOfInterest)
 345
 346 def CraftConfig = { linuxBr, lttngBr ->
 347   def job = [:];
 348   job['config'] = [:];
 349   job['config']['linuxBranch'] = linuxBr;
 350   job['config']['lttngBranch'] = lttngBr;
 351   job['config']['linuxTagID'] = linuxLastTagIds[linuxBr];
 352   job['config']['toolsCommit'] = toolsHeadCommits[lttngBr];
 353   job['config']['modulesCommit'] = modulesHeadCommits[lttngBr];
 354   job['config']['ustCommit'] = ustHeadCommits[lttngBr];
 355   job['status'] = 'NOT_SET';
 356   job['build'] = null;
 357   return job;
 358 }
 359
 360 // Check what type of jobs should be triggered.
 361 triggerJobName = build.project.getFullDisplayName();
 362 if (triggerJobName.contains("vm_tests")) {
 363   jobType = 'vm_tests';
 364   recentLttngBranchesOfInterest.each { lttngBranch ->
 365     vmLinuxBranchesOfInterest.each { linuxBranch ->
 366       configurationOfInterest.add([lttngBranch, linuxBranch])
 367     }
 368   }
 369 } else if (triggerJobName.contains("baremetal_tests")) {
 370   jobType = 'baremetal_tests';
 371 }
 372
 373 // Hashmap containing all the jobs, their configuration (commit id, etc. )and
 374 // their status (SUCCEEDED, FAILED, etc.). This Hashmap is made of basic strings
 375 // rather than objects and enums because strings are easily serializable.
 376 def currentJobs = [:];
 377
 378 // Get an up to date view of all the branches of interest.
 379 configurationOfInterest.each { lttngBr, linuxBr  ->
 380   def jobName = CraftJobName(jobType, linuxBr, lttngBr);
 381   currentJobs[jobName] = CraftConfig(linuxBr, lttngBr);
 382 }
 383
 384 //Add canary job
 385 def jobNameCanary = jobType + "_kcanary_lcanary";
 386 currentJobs[jobNameCanary] = [:];
 387 currentJobs[jobNameCanary]['config'] = [:];
 388 currentJobs[jobNameCanary]['config']['linuxBranch'] = 'v4.4.194';
 389 currentJobs[jobNameCanary]['config']['lttngBranch'] = 'v2.10.7';
 390 currentJobs[jobNameCanary]['config']['linuxTagID'] ='a227f8436f2b21146fc024d84e6875907475ace2';
 391 currentJobs[jobNameCanary]['config']['toolsCommit'] = '93fa2c9ff6b52c30173bee80445501ce8677fecc'
 392 currentJobs[jobNameCanary]['config']['modulesCommit'] = 'fe3ca7a9045221ffbedeac40ba7e09b1fc500e21'
 393 currentJobs[jobNameCanary]['config']['ustCommit'] = '0172ce8ece2102d46c7785e6bd96163225c59e49'
 394 currentJobs[jobNameCanary]['status'] = 'NOT_SET';
 395 currentJobs[jobNameCanary]['build'] = null;
 396
 397 def pastJobs = LoadPreviousJobsFromWorkspace(pastJobsPath);
 398
 399 def failedRuns = []
 400 def abortedRuns = []
 401 def isFailed = false
 402 def isAborted = false
 403 def ongoingJobs = 0;
 404
 405 currentJobs.each { jobName, jobInfo ->
 406   // If the job ran in the past, we check if the IDs changed since.
 407   // Fetch past results only if the job is not of type canary.
 408   if (!jobName.contains('_kcanary_lcanary') && pastJobs.containsKey(jobName) &&
 409          build.getBuildVariables().get('FORCE_JOB_RUN') == 'false') {
 410     pastJob = pastJobs[jobName];
 411
 412     // If the code has not changed report previous status.
 413     if (pastJob['config'] == jobInfo['config']) {
 414       // if the config has not changed, we keep it.
 415       // if it's failed, we don't launch a new job and keep it failed.
 416       jobInfo['status'] = pastJob['status'];
 417       if (pastJob['status'] == 'FAILED' &&
 418             build.getBuildVariables().get('FORCE_FAILED_JOB_RUN') == 'false') {
 419         println("${jobName} as not changed since the last failed run. Don't run it again.");
 420         // Marked the umbrella job for failure but still run the jobs that since the
 421         // last run.
 422         isFailed = true;
 423         return;
 424       } else if (pastJob['status'] == 'ABORTED') {
 425         println("${jobName} as not changed since last aborted run. Run it again.");
 426       } else if (pastJob['status'] == 'SUCCEEDED') {
 427         println("${jobName} as not changed since the last successful run. Don't run it again.");
 428         return;
 429       }
 430     }
 431   }
 432
 433   jobInfo['status'] = 'PENDING';
 434   jobInfo['build'] = LaunchJob(jobName, jobInfo);
 435   ongoingJobs += 1;
 436 }
 437
 438 while (ongoingJobs > 0) {
 439   currentJobs.each { jobName, jobInfo ->
 440
 441     if (jobInfo['status'] != 'PENDING') {
 442       return;
 443     }
 444
 445     jobBuild = jobInfo['build']
 446
 447     // The isCancelled() method checks if the run was cancelled before
 448     // execution. We consider such run as being aborted.
 449     if (jobBuild.isCancelled()) {
 450       println("${jobName} was cancelled before launch.")
 451       isAborted = true;
 452       abortedRuns.add(jobName);
 453       ongoingJobs -= 1;
 454       jobInfo['status'] = 'ABORTED'
 455       // Invalidate the build field, as it's not serializable and we don't need
 456       // it anymore.
 457       jobInfo['build'] = null;
 458     } else if (jobBuild.isDone()) {
 459
 460       jobExitStatus = jobBuild.get();
 461
 462       // Invalidate the build field, as it's not serializable and we don't need
 463       // it anymore.
 464       jobInfo['build'] = null;
 465       println("${jobExitStatus.fullDisplayName} completed with status ${jobExitStatus.result}.");
 466
 467       // If the job didn't succeed, add its name to the right list so it can
 468       // be printed at the end of the execution.
 469       ongoingJobs -= 1;
 470       switch (jobExitStatus.result) {
 471       case Result.ABORTED:
 472         isAborted = true;
 473         abortedRuns.add(jobName);
 474         jobInfo['status'] = 'ABORTED'
 475         break;
 476       case Result.FAILURE:
 477         isFailed = true;
 478         failedRuns.add(jobName);
 479         jobInfo['status'] = 'FAILED'
 480         break;
 481       case Result.SUCCESS:
 482         jobInfo['status'] = 'SUCCEEDED'
 483         break;
 484       default:
 485         break;
 486       }
 487     }
 488   }
 489
 490   // Sleep before the next iteration.
 491   try {
 492     Thread.sleep(30000)
 493   } catch(e) {
 494     if (e in InterruptedException) {
 495       build.setResult(hudson.model.Result.ABORTED)
 496       throw new InterruptedException()
 497     } else {
 498       throw(e)
 499     }
 500   }
 501 }
 502
 503 //All jobs are done running. Save their exit status to disk.
 504 SaveCurrentJobsToWorkspace(currentJobs, pastJobsPath);
 505
 506 // Get log of failed runs.
 507 if (failedRuns.size() > 0) {
 508   println("Failed job(s):");
 509   for (failedRun in failedRuns) {
 510     println("\t" + failedRun)
 511   }
 512 }
 513
 514 // Get log of aborted runs.
 515 if (abortedRuns.size() > 0) {
 516   println("Cancelled job(s):");
 517   for (cancelledRun in abortedRuns) {
 518     println("\t" + cancelledRun)
 519   }
 520 }
 521
 522 // Mark this build as Failed if atleast one child build has failed and mark as
 523 // aborted if there was no failure but atleast one job aborted.
 524 if (isFailed) {
 525   build.setResult(hudson.model.Result.FAILURE)
 526 } else if (isAborted) {
 527   build.setResult(hudson.model.Result.ABORTED)
 528 }