m4/ax_prog_javah.m4

   1 # ===========================================================================
   2 #      https://www.gnu.org/software/autoconf-archive/ax_prog_javah.html
   3 # ===========================================================================
   4 #
   5 # SYNOPSIS
   6 #
   7 #   AX_PROG_JAVAH
   8 #
   9 # DESCRIPTION
  10 #
  11 #   AX_PROG_JAVAH tests the availability of the javah header generator and
  12 #   looks for the jni.h header file. If available, JAVAH is set to the full
  13 #   path of javah and CPPFLAGS is updated accordingly.
  14 #
  15 # LICENSE
  16 #
  17 #   Copyright (c) 2008 Luc Maisonobe <luc@spaceroots.org>
  18 #
  19 #   Copying and distribution of this file, with or without modification, are
  20 #   permitted in any medium without royalty provided the copyright notice
  21 #   and this notice are preserved. This file is offered as-is, without any
  22 #   warranty.
  23
  24 #serial 11
  25
  26 AU_ALIAS([AC_PROG_JAVAH], [AX_PROG_JAVAH])
  27 AC_DEFUN([AX_PROG_JAVAH],[
  28 AC_REQUIRE([AC_CANONICAL_BUILD])dnl
  29 AC_REQUIRE([AC_PROG_CPP])dnl
  30 AC_PATH_PROG(JAVAH,javah)
  31 AS_IF([test -n "$ac_cv_path_JAVAH"],
  32       [
  33         AC_PREPROC_IFELSE([AC_LANG_SOURCE([[#include <jni.h>]])],[],[
  34         ac_save_CPPFLAGS="$CPPFLAGS"
  35         _ACJAVAH_FOLLOW_SYMLINKS("$ac_cv_path_JAVAH")
  36         ax_prog_javah_bin_dir=`AS_DIRNAME([$_ACJAVAH_FOLLOWED])`
  37         ac_dir="`AS_DIRNAME([$ax_prog_javah_bin_dir])`/include"
  38         AS_CASE([$build_os],
  39                 [cygwin*|mingw*],
  40                 [ac_machdep=win32],
  41                 [ac_machdep=`AS_ECHO($build_os) | sed 's,[[-0-9]].*,,'`])
  42         CPPFLAGS="$ac_save_CPPFLAGS -I$ac_dir -I$ac_dir/$ac_machdep"
  43         AC_PREPROC_IFELSE([AC_LANG_SOURCE([[#include <jni.h>]])],
  44                           [ac_save_CPPFLAGS="$CPPFLAGS"],
  45                           [AC_MSG_WARN([unable to include <jni.h>])])
  46         CPPFLAGS="$ac_save_CPPFLAGS"])
  47       ])
  48 ])
  49
  50 AC_DEFUN([_ACJAVAH_FOLLOW_SYMLINKS],[
  51 # find the include directory relative to the javac executable
  52 _cur="$1"
  53 while ls -ld "$_cur" 2>/dev/null | grep " -> " >/dev/null; do
  54         AC_MSG_CHECKING([symlink for $_cur])
  55         _slink=`ls -ld "$_cur" | sed 's/.* -> //'`
  56         case "$_slink" in
  57         /*) _cur="$_slink";;
  58         # 'X' avoids triggering unwanted echo options.
  59         *) _cur=`echo "X$_cur" | sed -e 's/^X//' -e 's:[[^/]]*$::'`"$_slink";;
  60         esac
  61         AC_MSG_RESULT([$_cur])
  62 done
  63 _ACJAVAH_FOLLOWED="$_cur"
  64 ])