m4/ax_define_dir.m4

   1 # ===========================================================================
   2 #       http://www.gnu.org/software/autoconf-archive/ax_define_dir.html
   3 # ===========================================================================
   4 #
   5 # OBSOLETE MACRO
   6 #
   7 #   Deprecated because it does not comply with the GNU Coding Standards. See
   8 #   the autoconf manual section "Defining Directories" for alternatives.
   9 #
  10 # SYNOPSIS
  11 #
  12 #   AX_DEFINE_DIR(VARNAME, DIR [, DESCRIPTION])
  13 #
  14 # DESCRIPTION
  15 #
  16 #   This macro sets VARNAME to the expansion of the DIR variable, taking
  17 #   care of fixing up ${prefix} and such.
  18 #
  19 #   VARNAME is then offered as both an output variable and a C preprocessor
  20 #   symbol.
  21 #
  22 #   Example:
  23 #
  24 #     AX_DEFINE_DIR([DATADIR], [datadir], [Where data are placed to.])
  25 #
  26 # LICENSE
  27 #
  28 #   Copyright (c) 2008 Stepan Kasal <kasal@ucw.cz>
  29 #   Copyright (c) 2008 Andreas Schwab <schwab@suse.de>
  30 #   Copyright (c) 2008 Guido U. Draheim <guidod@gmx.de>
  31 #   Copyright (c) 2008 Alexandre Oliva
  32 #
  33 #   Copying and distribution of this file, with or without modification, are
  34 #   permitted in any medium without royalty provided the copyright notice
  35 #   and this notice are preserved. This file is offered as-is, without any
  36 #   warranty.
  37
  38 #serial 8
  39
  40 AU_ALIAS([AC_DEFINE_DIR], [AX_DEFINE_DIR])
  41 AC_DEFUN([AX_DEFINE_DIR], [
  42   prefix_NONE=
  43   exec_prefix_NONE=
  44   test "x$prefix" = xNONE && prefix_NONE=yes && prefix=$ac_default_prefix
  45   test "x$exec_prefix" = xNONE && exec_prefix_NONE=yes && exec_prefix=$prefix
  46 dnl In Autoconf 2.60, ${datadir} refers to ${datarootdir}, which in turn
  47 dnl refers to ${prefix}.  Thus we have to use `eval' twice.
  48   eval ax_define_dir="\"[$]$2\""
  49   eval ax_define_dir="\"$ax_define_dir\""
  50   AC_SUBST($1, "$ax_define_dir")
  51   AC_DEFINE_UNQUOTED($1, "$ax_define_dir", [$3])
  52   test "$prefix_NONE" && prefix=NONE
  53   test "$exec_prefix_NONE" && exec_prefix=NONE
  54 ])