configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4
   5 AC_INIT([userspace-rcu],[0.7.4],[mathieu dot desnoyers at efficios dot com])
   6
   7 # Following the numbering scheme proposed by libtool for the library version
   8 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
   9 AC_SUBST([URCU_LIBRARY_VERSION], [2:0:0])
  10
  11 AC_CONFIG_AUX_DIR([config])
  12 AC_CONFIG_MACRO_DIR([config])
  13 AC_CANONICAL_TARGET
  14 AC_CANONICAL_HOST
  15 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
  16 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  17
  18 m4_include([config/ax_tls.m4])
  19
  20 AC_CONFIG_SRCDIR([urcu.h])
  21
  22 AC_CONFIG_HEADERS([config.h urcu/config.h])
  23
  24 AH_TEMPLATE([CONFIG_RCU_SMP], [Enable SMP support. With SMP support enabled, uniprocessors are also supported. With SMP support disabled, UP systems work fine, but the behavior of SMP systems is undefined.])
  25 AH_TEMPLATE([CONFIG_RCU_HAVE_FENCE], [Defined when on a system that has memory fence instructions.])
  26 AH_TEMPLATE([CONFIG_RCU_HAVE_FUTEX], [Defined when on a system with futex support.])
  27 AH_TEMPLATE([CONFIG_RCU_COMPAT_ARCH], [Compatibility mode for i386 which lacks cmpxchg instruction.])
  28 AH_TEMPLATE([CONFIG_RCU_ARM_HAVE_DMB], [Use the dmb instruction if available for use on ARM.])
  29 AH_TEMPLATE([CONFIG_RCU_TLS], [TLS provided by the compiler.])
  30
  31 # Allow overriding storage used for TLS variables.
  32 AC_ARG_ENABLE([compiler-tls],
  33         AS_HELP_STRING([--disable-compiler-tls], [Use pthread_getspecific() to emulate Thread Local Storage (TLS) variables.]),
  34         [def_compiler_tls=$enableval],
  35         [def_compiler_tls="yes"])
  36
  37 # If not overridden, use ax_tls.m4 to check if TLS is available.
  38 AS_IF([test "x$def_compiler_tls" = "xyes"],
  39         [AX_TLS([def_tls_detect=$ac_cv_tls], [:])],
  40         [:])
  41
  42 AS_IF([test "x$def_tls_detect" = "x"],
  43         [:],
  44         [AC_DEFINE_UNQUOTED([CONFIG_RCU_TLS], $def_tls_detect)])
  45
  46 # Checks for programs.
  47 AC_PROG_CC
  48 AC_PROG_MAKE_SET
  49 LT_INIT
  50
  51 # Checks for typedefs, structures, and compiler characteristics.
  52 AC_C_INLINE
  53 AC_TYPE_PID_T
  54 AC_TYPE_SIZE_T
  55
  56 # Checks for library functions.
  57 AC_FUNC_MALLOC
  58 AC_FUNC_MMAP
  59 AC_CHECK_FUNCS([bzero gettimeofday munmap sched_getcpu strtoul sysconf])
  60
  61 # Find arch type
  62 AS_CASE([$host_cpu],
  63         [i386], [ARCHTYPE="x86" && SUBARCHTYPE="x86compat"],
  64         [i486], [ARCHTYPE="x86"],
  65         [i586], [ARCHTYPE="x86"],
  66         [i686], [ARCHTYPE="x86"],
  67         [amd64], [ARCHTYPE="x86"],
  68         [x86_64], [ARCHTYPE="x86"],
  69         [powerpc], [ARCHTYPE="ppc"],
  70         [ppc64], [ARCHTYPE="ppc"],
  71         [powerpc64], [ARCHTYPE="ppc"],
  72         [ppc], [ARCHTYPE="ppc"],
  73         [s390], [ARCHTYPE="s390"],
  74         [s390x], [ARCHTYPE="s390"],
  75         [sparc], [ARCHTYPE="sparc64"],
  76         [sparc64], [ARCHTYPE="sparc64"],
  77         [alpha*], [ARCHTYPE="alpha"],
  78         [ia64], [ARCHTYPE="gcc"],
  79         [arm*], [ARCHTYPE="arm"],
  80         [mips*], [ARCHTYPE="mips"],
  81         [tile*], [ARCHTYPE="gcc"],
  82         [ARCHTYPE="unknown"]
  83 )
  84
  85 AC_SUBST(ARCHTYPE)
  86 AC_SUBST(SUBARCHTYPE)
  87
  88 UATOMICSRC=urcu/uatomic/$ARCHTYPE.h
  89 ARCHSRC=urcu/arch/$ARCHTYPE.h
  90
  91 AS_IF([test "x$SUBARCHTYPE" = xx86compat],[
  92         AC_DEFINE([CONFIG_RCU_COMPAT_ARCH], [1])
  93 ])
  94
  95 AS_IF([test "$host_cpu" = "armv7l"],[
  96         CFLAGS="$CFLAGS -mcpu=cortex-a9 -mtune=cortex-a9 -O1"
  97 ])
  98
  99 # ARM-specific checks
 100 AS_IF([test "x$ARCHTYPE" = "xarm"],[
 101         AC_MSG_CHECKING([for dmb instruction])
 102         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 103                                 int main()
 104                                 {
 105                                         asm volatile("dmb":::"memory");
 106                                         return 0;
 107                                 }
 108                 ]])
 109         ],[
 110                 AC_MSG_RESULT([yes])
 111                 AC_DEFINE([CONFIG_RCU_ARM_HAVE_DMB], [1])
 112         ],[
 113                 AC_MSG_RESULT([no])
 114         ])
 115 ])
 116
 117 # Tile-specific checks
 118 AS_IF([echo "$host_cpu" | grep "^tile"],[
 119         AC_MSG_CHECKING([for Tile architecture type])
 120         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 121                                 #ifndef __tilegx__
 122                                 #error
 123                                 #endif
 124                 ]])
 125         ],[
 126                 AC_MSG_RESULT([ok])
 127         ],[
 128                 AC_MSG_FAILURE([URCU has only been tested on the TileGx architecture. For other Tile* architectures, please run the tests first and report the results to the maintainer so that proper support can be added.])
 129         ])
 130 ])
 131
 132 # x86-specific checks
 133 AS_IF([test "x$ARCHTYPE" = "xx86"],[
 134         AC_MSG_CHECKING([if architecture really supports the mfence instruction])
 135         #For now, using lock; addl compatibility mode even for i686, because the
 136         #Pentium III is seen as a i686, but lacks mfence instruction.
 137         #Only using fence for x86_64.
 138         AS_IF([test "x$host_cpu" != "xi386" -a "x$host_cpu" != "xi486" -a "x$host_cpu" != "xi586" -a "x$host_cpu" != "xi686"],[
 139                 AC_MSG_RESULT([yes])
 140                 AC_DEFINE([CONFIG_RCU_HAVE_FENCE], [1])
 141         ],[
 142                 AC_MSG_RESULT([no])
 143         ])
 144 ])
 145
 146 # Check if sys_futex() is available
 147 AC_MSG_CHECKING([for sys_futex()])
 148 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 149                 #include <sys/syscall.h>
 150                 #ifndef __NR_futex
 151                 #error "futexes not available"
 152                 #endif
 153         ]])
 154 ],[
 155         AC_MSG_RESULT([yes])
 156         AC_DEFINE([CONFIG_RCU_HAVE_FUTEX], [1])
 157         compat_futex_test=0
 158 ],[
 159         AC_MSG_RESULT([no])
 160         compat_futex_test=1
 161 ])
 162
 163 AM_CONDITIONAL([COMPAT_FUTEX], [test "x$compat_futex_test" = "x1"])
 164 AM_CONDITIONAL([COMPAT_ARCH], [test "x$SUBARCHTYPE" = "xx86compat"])
 165
 166 # smp-support configure option
 167 AC_ARG_ENABLE([smp-support],
 168         AS_HELP_STRING([--disable-smp-support], [Disable SMP support. Warning: only use this on uniprocessor systems. [default=enabled]]),
 169         [def_smp_support=$enableval],
 170         [def_smp_support="yes"])
 171 AS_IF([test "x$def_smp_support" = "xyes"], [AC_DEFINE([CONFIG_RCU_SMP], [1])])
 172
 173
 174 # From the sched_setaffinity(2)'s man page:
 175 # ~~~~
 176 # The CPU affinity system calls were introduced in Linux kernel 2.5.8.
 177 # The library interfaces were introduced in glibc 2.3.  Initially, the
 178 # glibc interfaces included a cpusetsize argument.  In glibc 2.3.3,
 179 # the cpuset size argument was removed, but this argument was
 180 # restored in glibc 2.3.4.
 181 # ~~~~
 182
 183 # In addition to that, some vendors ported the system call to 2.4
 184 # kernels.
 185
 186 # Furthermore, when the function first appeared, the MASK argument was
 187 # an unsigned long pointer, while later it was made into a cpu_set_t
 188 # pointer.  Systems that have the cpu_set_t version also should have
 189 # the CPU_ZERO, CPU_SET, etc. macros.
 190
 191 # All this mess means we have to cater for at least 3 different
 192 # sched_setaffinity prototypes:
 193
 194 # ~~~~
 195 #  int sched_setaffinity (pid_t pid, unsigned int len, unsigned long *mask);
 196 #  int sched_setaffinity (pid_t __pid, size_t __cpusetsize, const cpu_set_t *__cpuset);
 197 #  int sched_setaffinity (pid_t __pid, const cpu_set_t *__mask);
 198 # ~~~~
 199
 200 # Since we define _GNU_SOURCE in the sources, must do so too in the
 201 # autoconf tests, as defining _GNU_SOURCE or not exposes
 202 # sched_setaffinity bits differently.
 203 saved_CFLAGS=$CFLAGS
 204 CFLAGS="$CFLAGS -D_GNU_SOURCE"
 205
 206 AC_CHECK_TYPES([cpu_set_t],
 207         [have_cpu_set_t="yes"],
 208         [have_cpu_set_t="no"],
 209         [#include <sched.h>])
 210
 211 # Confirm that we have CPU_ZERO, and it actually works.
 212 AC_MSG_CHECKING([whether CPU_ZERO works])
 213 AH_TEMPLATE([HAVE_CPU_ZERO], [Defined to 1 if we have CPU_ZERO and it works])
 214 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 215                 #define _GNU_SOURCE
 216                 #include <sched.h>
 217                 int main()
 218                 {
 219                         cpu_set_t foo; CPU_ZERO(&foo);
 220                         return 0;
 221                 }
 222         ]])
 223 ],[
 224         AC_DEFINE(HAVE_CPU_ZERO, 1)
 225         AC_MSG_RESULT([yes])
 226 ],[
 227         AC_MSG_RESULT([no])
 228 ])
 229
 230 # Confirm that we have CPU_SET, and it actually works.
 231 AC_MSG_CHECKING([whether CPU_SET works])
 232 AH_TEMPLATE([HAVE_CPU_SET], [Defined to 1 if we have CPU_SET and it works])
 233 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 234                 #define _GNU_SOURCE
 235                 #include <sched.h>
 236                 int main()
 237                 {
 238                         cpu_set_t foo, mask; CPU_SET(0, &foo);
 239                         return 0;
 240                 }
 241         ]])
 242 ],[
 243         AC_DEFINE(HAVE_CPU_SET, 1)
 244         AC_MSG_RESULT([yes])
 245 ],[
 246         AC_MSG_RESULT([no])
 247 ])
 248
 249 # First check if the function is available at all.
 250 AC_CHECK_FUNCS([sched_setaffinity],[
 251         # Okay, we have it.  Check if also have cpu_set_t.  If we don't,
 252         # then we have the first version using unsigned long, and no
 253         # CPU_ZERO, etc. macros.  If we do have cpu_set_t, we may have the
 254         # version with 2 or 3 arguments.  In that case, CPU_ZERO, etc.,
 255         # should also be present, but we confirm nonetheless.
 256
 257         AS_IF([test "x$have_cpu_set_t" = "xyes"], [
 258                 # We do have it.
 259                 # Check how many arguments does sched_setaffinity take.
 260                 # Should be 3 or 2.
 261                 AC_MSG_CHECKING([how many arguments sched_setaffinity takes])
 262                 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 263                                 #include <sched.h>
 264                                 int main()
 265                                 {
 266                                         cpu_set_t foo;
 267                                         sched_setaffinity(0, sizeof (foo), &foo);
 268                                         return 0;
 269                                 }
 270                         ]])
 271                 ],
 272                 [sched_set_affinity_args=3],
 273                 [sched_set_affinity_args=2])
 274                 AC_DEFINE_UNQUOTED(SCHED_SETAFFINITY_ARGS,
 275                         $sched_set_affinity_args,
 276                         [Defined to sched_setaffinity's number of arguments.])
 277                 AC_MSG_RESULT([$sched_set_affinity_args])
 278         ],[
 279                 # No cpu_set_t, always 3 args.
 280                 AC_DEFINE(SCHED_SETAFFINITY_ARGS, 3)
 281         ])
 282 ])
 283
 284 CFLAGS=$saved_CFLAGS
 285
 286 AC_CONFIG_LINKS([
 287         urcu/arch.h:$ARCHSRC
 288         urcu/uatomic.h:$UATOMICSRC
 289 ])
 290 AC_CONFIG_FILES([
 291         Makefile
 292         doc/Makefile
 293         tests/Makefile
 294         liburcu.pc
 295         liburcu-bp.pc
 296         liburcu-cds.pc
 297         liburcu-qsbr.pc
 298         liburcu-mb.pc
 299         liburcu-signal.pc
 300 ])
 301 AC_OUTPUT
 302
 303 # Report on selected configure options
 304 AS_IF([test "x$def_smp_support" = "xyes"],[
 305         AS_ECHO("SMP support enabled.")
 306 ],[
 307         AS_ECHO("SMP support disabled.")
 308 ])
 309
 310 AS_IF([test "x$def_tls_detect" = "x"],[
 311         AS_ECHO("Thread Local Storage (TLS): pthread_getspecific().")
 312 ],[
 313         AS_ECHO("Thread Local Storage (TLS): $def_tls_detect.")
 314 ])