configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_INIT([lttng-ust],[2.2.0-rc2],[mathieu dot desnoyers at efficios dot com])
   5
   6 # Following the numbering scheme proposed by libtool for the library version
   7 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
   8 # This is the library version of liblttng-ust.
   9 AC_SUBST([LTTNG_UST_LIBRARY_VERSION], [0:0:0])
  10 # note: remember to update tracepoint.h dlopen() to match this version
  11 # number. TODO: eventually automate by exporting the major number.
  12
  13 # This is the library version of liblttng-ust-ctl, used internally by
  14 # liblttng-ust, lttng-sessiond, and lttng-consumerd.
  15 AC_SUBST([LTTNG_UST_CTL_LIBRARY_VERSION], [2:0:0])
  16
  17 AC_CONFIG_AUX_DIR([config])
  18 AC_CANONICAL_TARGET
  19 AC_CANONICAL_HOST
  20 AC_CONFIG_MACRO_DIR([config])
  21 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
  22 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  23 AC_CONFIG_SRCDIR([include/lttng/tracepoint.h])
  24
  25 # Configuration options, which will be installed in the config.h
  26 AC_CONFIG_HEADERS([config.h include/lttng/ust-config.h])
  27 AH_TEMPLATE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [Use efficient unaligned access.])
  28 AH_TEMPLATE([LTTNG_UST_HAVE_SDT_INTEGRATION], [SystemTap integration via sdt.h])
  29
  30 # Compute minor/major/patchlevel version numbers
  31 AC_PROG_SED
  32 major_version=$(echo AC_PACKAGE_VERSION | sed 's/^\([[0-9]]\)*\.[[0-9]]*\.[[0-9]]*.*$/\1/')
  33 minor_version=$(echo AC_PACKAGE_VERSION | sed 's/^[[0-9]]*\.\([[0-9]]*\)\.[[0-9]]*.*$/\1/')
  34 patchlevel_version=$(echo AC_PACKAGE_VERSION | sed 's/^[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\).*$/\1/')
  35 AC_SUBST([MAJOR_VERSION], [$major_version])
  36 AC_SUBST([MINOR_VERSION], [$minor_version])
  37 AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version])
  38 AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [UST major version number])
  39 AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [UST minor version number])
  40 AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [UST patchlevel version number])
  41
  42 version_name="Cuda"
  43 version_description="Brewed at the Benelux microbrewery, this IPA has huge floral, citric and resinous hop aroma, simply an amazing nose. The flavor is very fresh with a light caramel malting touch completing a strong body. Huge amounts of hops, lots of grapefruit, lemon and oranges. This is an outstanding IPA!"
  44 AC_DEFINE_UNQUOTED([VERSION_NAME], ["$version_name"], [UST version name])
  45 AC_DEFINE_UNQUOTED([VERSION_DESCRIPTION], ["$version_description"], [UST version description])
  46
  47 AC_PROG_GREP
  48 # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
  49 AC_ARG_ENABLE(libtool-linkdep-fixup,
  50         AS_HELP_STRING([--disable-libtool-linkdep-fixup],
  51                         [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)]),
  52         libtool_fixup=$enableval,
  53         libtool_fixup=yes)
  54
  55 AS_IF([test "x$libtool_fixup" = "xyes"],
  56             [
  57             libtool_m4="$srcdir/config/libtool.m4"
  58             libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
  59             AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
  60             libtool_flag_pattern_count=$(grep -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
  61             AS_IF([test $libtool_flag_pattern_count -ne 0],
  62             [
  63                   AC_MSG_RESULT([$libtool_flag_pattern_count])
  64                   AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
  65                   sed -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
  66                   ],
  67                   [
  68                   AC_MSG_RESULT([none])
  69                   ])
  70             ])
  71
  72 AM_CONDITIONAL([NO_SHARED], [test "x$enable_shared" = "xno"])
  73
  74 # Checks for programs.
  75 AC_PROG_CC
  76 AC_PROG_CXX
  77 AC_PROG_MAKE_SET
  78 LT_INIT
  79
  80 # rw_PROG_CXX_WORKS
  81 # Check whether the C++ compiler works.
  82 AC_CACHE_CHECK([whether the C++ compiler works],
  83                 [rw_cv_prog_cxx_works],
  84                 [AC_LANG_PUSH([C++])
  85                 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
  86                                 [check_cxx_designated_initializers=yes],
  87                                 [rw_cv_prog_cxx_works=no])
  88                 if test "$check_cxx_designated_initializers" = "yes"; then
  89                         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
  90                                 struct foo { int a; int b; };
  91                                 void fct(void)
  92                                 {
  93                                         struct foo f = { .a = 0, .b = 1 };
  94                                 }
  95                         ]])],[
  96                                 rw_cv_prog_cxx_works=yes
  97                         ],[
  98                                 rw_cv_prog_cxx_works=no
  99                         ])
 100                 fi
 101                 AC_LANG_POP([C++])])
 102
 103 AM_CONDITIONAL([CXX_WORKS], [test "x$rw_cv_prog_cxx_works" = "xyes"])
 104
 105 ## Checks for libraries.
 106 AC_CHECK_LIB([dl], [dlopen],
 107 [
 108         have_libdl=yes
 109 ],
 110 [
 111         #libdl not found, check for dlopen in libc.
 112         AC_CHECK_LIB([c], [dlopen],
 113         [
 114                 have_libc_dl=yes
 115         ],
 116         [
 117                 AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
 118         ])
 119 ])
 120 AM_CONDITIONAL([LTTNG_UST_BUILD_WITH_LIBDL], [test "x$have_libdl" = "xyes"])
 121 AM_CONDITIONAL([LTTNG_UST_BUILD_WITH_LIBC_DL], [test "x$have_libc_dl" = "xyes"])
 122
 123 AC_CHECK_LIB([pthread], [pthread_create])
 124
 125 # Checks for header files.
 126 #AC_CHECK_HEADERS([fcntl.h stdint.h stdlib.h string.h sys/socket.h sys/time.h unistd.h])
 127
 128 # Checks for typedefs, structures, and compiler characteristics.
 129 AC_C_INLINE
 130 #AC_TYPE_INT16_T
 131 #AC_TYPE_INT32_T
 132 #AC_TYPE_INT64_T
 133 #AC_TYPE_INT8_T
 134 #AC_TYPE_PID_T
 135 #AC_TYPE_SIZE_T
 136 #AC_TYPE_SSIZE_T
 137 #AC_TYPE_UINT16_T
 138 #AC_TYPE_UINT32_T
 139 #AC_TYPE_UINT64_T
 140 #AC_TYPE_UINT8_T
 141 #AC_CHECK_TYPES([ptrdiff_t])
 142
 143 # Checks for library functions.
 144 AC_FUNC_MALLOC
 145 AC_CHECK_FUNCS([gettimeofday munmap socket strerror strtol sched_getcpu sysconf])
 146
 147 CFLAGS="-Wall $CFLAGS"
 148
 149 # URCU
 150
 151 # urcu - check if we just find the headers it out of the box.
 152 AC_CHECK_HEADERS([urcu-bp.h], [], [AC_MSG_ERROR([Cannot find [URCU] headers (urcu-bp.h). Use [CPPFLAGS]=-Idir to specify their location.
 153 This error can also occur when the liburcu package's configure script has not been run.])])
 154
 155 # urcu-cds - check that URCU Concurrent Data Structure lib is available to compilation
 156 # Part of Userspace RCU library 0.7.2 or better.
 157 AC_CHECK_LIB([urcu-cds], [_cds_lfht_new], [], [AC_MSG_ERROR([Cannot find
 158 liburcu-cds lib, part of Userspace RCU 0.7 or better. Use [LDFLAGS]=-Ldir to specify its location.])])
 159
 160 AC_MSG_CHECKING([caa_likely()])
 161 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 162 #include <urcu/compiler.h>
 163 void fct(void)
 164 {
 165         if (caa_likely(1)) {
 166         }
 167 }
 168 ]])],[
 169         AC_MSG_RESULT([yes])
 170 ],[
 171         AC_MSG_RESULT([no])
 172         AC_MSG_ERROR([Please upgrade your version of liburcu to 0.6.6 or better])
 173
 174 ])
 175
 176 # urcu - check that URCU lib is available to compilation
 177 AC_CHECK_LIB([urcu-bp], [synchronize_rcu_bp], [], [AC_MSG_ERROR([Cannot find liburcu-bp lib. Use [LDFLAGS]=-Ldir to specify its location.])])
 178
 179 # urcu - check that URCU lib is at least version 0.6
 180 AC_CHECK_LIB([urcu-bp], [call_rcu_bp], [], [AC_MSG_ERROR([liburcu 0.6 or newer is needed, please update your version or use [LDFLAGS]=-Ldir to specify the right location.])])
 181
 182 AC_MSG_CHECKING([host system alignment requirements])
 183 case $host_cpu in
 184 changequote(,)dnl
 185         i[3456]86)
 186 changequote([,])dnl
 187           ;;
 188         x86_64) ;;
 189         amd64) ;;
 190         powerpc) ;;
 191         ppc64) ;;
 192         powerpc64) ;;
 193         s390) NO_UNALIGNED_ACCESS=1 ;;
 194         s390x) NO_UNALIGNED_ACCESS=1 ;;
 195         arm*) NO_UNALIGNED_ACCESS=1 ;;
 196         mips*) NO_UNALIGNED_ACCESS=1 ;;
 197         tile*) NO_UNALIGNED_ACCESS=1 ;;
 198         *) AC_MSG_ERROR([unable to detect alignment requirements (unsupported architecture ($host_cpu)?)]) ;;
 199 esac
 200
 201 if test x$NO_UNALIGNED_ACCESS = x ; then
 202 AC_DEFINE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [1])
 203 fi
 204
 205 # Set compile flags to java include files if given
 206 AC_ARG_WITH([java-jdk],
 207         [AS_HELP_STRING([--with-java-jdk=DIR],[use the Java JDK in DIR. Ex : $JAVA_HOME.])],
 208         [JAVA_JDK=$withval],
 209         [JAVA_JDK=""]
 210 )
 211 AS_IF([test $JAVA_JDK],[
 212         AS_IF([test -d $JAVA_JDK],[
 213                 AC_MSG_RESULT([using Java includes in $JAVA_SDK])
 214                 SUBDIRS=`find $JAVA_JDK/include -type d`
 215                 CPPFLAGS+=" "
 216                 CPPFLAGS+=`for x in $SUBDIRS; do echo -n "-I$x "; done`
 217                 CPPFLAGS+=" "
 218         ],[
 219                 AC_MSG_ERROR(Unable to find Java include files in $JAVA_JDK)
 220         ])
 221 ])
 222
 223 # Check for JNI header files if requested
 224 AC_ARG_WITH([jni-interface],
 225         [AS_HELP_STRING([--with-jni-interface],[build JNI interface between C and Java. Needs Java include files [default=no]])],
 226         [jni_interface=$withval],
 227         [jni_interface=no]
 228 )
 229
 230 AS_IF([test "x$jni_interface" = "xyes"],[
 231         AC_CHECK_HEADERS([jni.h],[],[
 232         AC_MSG_ERROR([missing jni.h
 233 Make sure Sun Java, OpenJDK or GCJ is installed and that this header file exists in the system path.
 234 Use the --with-java-jdk=DIR flag to point to your Java include files, or disable the JNI interface.])
 235         ])
 236 ])
 237 AM_CONDITIONAL([BUILD_JNI_INTERFACE], [test "x$jni_interface" = "xyes"])
 238
 239 # sdt.h integration
 240 AC_ARG_WITH([sdt],
 241         [AS_HELP_STRING([--with-sdt],[provide SystemTap integration via sdt.h [default=no]])],
 242         [with_sdt=$withval],
 243         [with_sdt="no"]
 244 )
 245
 246 AS_IF([test "x$with_sdt" = "xyes"],[
 247         AC_MSG_CHECKING([STAP_PROBEV()])
 248         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 249         #define SDT_USE_VARIADIC
 250         #include <sys/sdt.h>
 251         void fct(void)
 252         {
 253                 STAP_PROBEV(provider,name,1,2,3,4,5,6,7,8,9,10);
 254         }
 255         ]])],[
 256                 AC_MSG_RESULT([yes])
 257                 AC_DEFINE([LTTNG_UST_HAVE_SDT_INTEGRATION], [1])
 258         ],[
 259                 AC_MSG_RESULT([no])
 260                 AC_MSG_ERROR([The sdt.h integration was requested but the STAP_PROBEV define cannot be used. Make sure it is installed, and up to date, or use CPPFLAGS=-I/path/ to specify a non-standard path to sys/sdt.h])
 261         ])
 262 ])
 263
 264 AC_CONFIG_FILES([
 265         Makefile
 266         doc/Makefile
 267         doc/examples/Makefile
 268         include/Makefile
 269         include/lttng/ust-version.h
 270         snprintf/Makefile
 271         libringbuffer/Makefile
 272         liblttng-ust-comm/Makefile
 273         liblttng-ust/Makefile
 274         liblttng-ust-ctl/Makefile
 275         liblttng-ust-fork/Makefile
 276         liblttng-ust-java/Makefile
 277         liblttng-ust-libc-wrapper/Makefile
 278         liblttng-ust-cyg-profile/Makefile
 279         tools/Makefile
 280         tests/Makefile
 281         tests/hello/Makefile
 282         tests/hello.cxx/Makefile
 283         tests/same_line_tracepoint/Makefile
 284         tests/snprintf/Makefile
 285         lttng-ust.pc
 286 ])
 287
 288 AC_OUTPUT
 289
 290 AS_ECHO()
 291 AS_ECHO("Version name: $version_name")
 292 AS_ECHO("$version_description")
 293
 294 # Report on the configuration options
 295 AS_ECHO()
 296 AS_ECHO("LTTng-UST will be built with the following options:")
 297
 298 AS_ECHO()
 299 AS_ECHO_N("Java support (JNI): ")
 300 AS_IF([test "x$jni_interface" = "xyes"], [AS_ECHO("Enabled")], [AS_ECHO("Disabled")])
 301
 302 AS_ECHO_N("sdt.h integration:  ")
 303 AS_IF([test "x$with_sdt" = "xyes"], [AS_ECHO("Enabled")], [AS_ECHO("Disabled")])
 304
 305 AS_ECHO()
 306 AS_ECHO("Type 'make' to compile.")
 307