configure.ac

   1 AC_PREREQ([2.64])
   2 AC_INIT([lttng-tools],[2.10.0-pre],[jeremie.galarneau@efficios.com],[],[https://lttng.org])
   3
   4 AC_CONFIG_HEADERS([include/config.h])
   5 AC_CONFIG_AUX_DIR([config])
   6 AC_CONFIG_MACRO_DIR([m4])
   7
   8 AC_CANONICAL_TARGET
   9 AC_CANONICAL_HOST
  10
  11 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip tar-pax nostdinc])
  12 AM_MAINTAINER_MODE([enable])
  13
  14 # Enable silent rules if available (Introduced in AM 1.11)
  15 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  16
  17 AC_REQUIRE_AUX_FILE([tap-driver.sh])
  18
  19 # Checks for C compiler
  20 AC_USE_SYSTEM_EXTENSIONS
  21 AC_SYS_LARGEFILE
  22 AC_PROG_CC
  23 AC_PROG_CC_STDC
  24
  25 # Checks for programs.
  26 AC_PROG_GREP
  27 AC_PROG_LEX
  28 AC_PROG_MAKE_SET
  29 AC_PROG_SED
  30 AC_PROG_YACC
  31 AC_PATH_PROG(report_fold, fold)
  32 LT_INIT
  33
  34 # Check for objcopy, required by the base address statedump and dynamic linker tests
  35 AC_CHECK_TOOL([OBJCOPY], objcopy, no)
  36 AS_IF([test "x$OBJCOPY" = xno],
  37         [AC_MSG_WARN([Cannont find objcopy. The base address statedump and dynamic linker tests will be disabled. Install the binutils package to remediate this.])]
  38 )
  39 AM_CONDITIONAL([HAVE_OBJCOPY], [test "x$OBJCOPY" != xno])
  40
  41 # Checks for typedefs, structures, and compiler characteristics.
  42 AC_C_INLINE
  43 AC_TYPE_INT32_T
  44 AC_TYPE_INT64_T
  45 AC_TYPE_MODE_T
  46 AC_TYPE_OFF_T
  47 AC_TYPE_PID_T
  48 AC_TYPE_SIZE_T
  49 AC_TYPE_SSIZE_T
  50 AC_TYPE_UID_T
  51 AC_TYPE_UINT16_T
  52 AC_TYPE_UINT32_T
  53 AC_TYPE_UINT64_T
  54 AC_TYPE_UINT8_T
  55
  56 AX_C___ATTRIBUTE__
  57 AS_IF([test "x$ax_cv___attribute__" = "xyes"],
  58         [:],
  59         [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
  60
  61 AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])
  62
  63 AX_LIB_SOCKET_NSL
  64
  65 LT_NO_UNDEFINED=""
  66 AS_CASE([$host_os],
  67   [cygwin*],
  68     [
  69       LT_NO_UNDEFINED="-no-undefined"
  70     ]
  71 )
  72
  73 AC_SUBST(LT_NO_UNDEFINED)
  74
  75 # Compute minor/major/patchlevel version numbers
  76 major_version=$(echo AC_PACKAGE_VERSION | $SED 's/^\([[0-9]]\)*\.[[0-9]]*\.[[0-9]]*.*$/\1/')
  77 minor_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.\([[0-9]]*\)\.[[0-9]]*.*$/\1/')
  78 patchlevel_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\).*$/\1/')
  79
  80 AC_SUBST([MAJOR_VERSION], [$major_version])
  81 AC_SUBST([MINOR_VERSION], [$minor_version])
  82 AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version])
  83 AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [LTTng-Tools major version number])
  84 AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [LTTng-Tools minor version number])
  85 AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [LTTng-Tools patchlevel version number])
  86
  87 version_name="KeKriek"
  88 version_description='From Brasserie Dunham, a sour mashed golden wheat ale fermented with local sour cherries from Tougas orchards. Fresh sweet cherry notes with some tartness, lively carbonation with a dry finish.'
  89 version_description_c=$(echo $version_description | $SED 's/"/\\"/g')
  90
  91 AC_DEFINE_UNQUOTED([VERSION_NAME], ["$version_name"], "")
  92 AC_DEFINE_UNQUOTED([VERSION_DESCRIPTION], ["$version_description_c"], "")
  93
  94 # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
  95 AC_ARG_ENABLE(libtool-linkdep-fixup,
  96         AS_HELP_STRING([--disable-libtool-linkdep-fixup],
  97                         [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)]),
  98         libtool_fixup=$enableval,
  99         libtool_fixup=yes)
 100
 101 AS_IF([test "x$libtool_fixup" = "xyes"],
 102             [
 103             libtool_m4="$srcdir/m4/libtool.m4"
 104             libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
 105             AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
 106             libtool_flag_pattern_count=$($GREP -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
 107             AS_IF([test $libtool_flag_pattern_count -ne 0],
 108             [
 109                   AC_MSG_RESULT([$libtool_flag_pattern_count])
 110                   AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
 111                   $SED -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
 112                   ],
 113                   [
 114                   AC_MSG_RESULT([none])
 115                   ])
 116             ])
 117
 118 AM_CONDITIONAL([NO_SHARED], [test x$enable_shared = xno])
 119
 120 AC_CHECK_HEADERS([ \
 121         sys/types.h unistd.h fcntl.h string.h pthread.h limits.h \
 122         signal.h stdlib.h sys/un.h sys/socket.h stdlib.h stdio.h \
 123         getopt.h sys/ipc.h sys/shm.h popt.h grp.h arpa/inet.h \
 124         netdb.h netinet/in.h paths.h stddef.h sys/file.h sys/ioctl.h \
 125         sys/mount.h sys/param.h sys/time.h
 126 ])
 127
 128 # Basic functions check
 129 AC_CHECK_FUNCS([ \
 130         atexit bzero clock_gettime dup2 fdatasync fls ftruncate \
 131         gethostbyname gethostname getpagesize localtime_r memchr memset \
 132         mkdir munmap putenv realpath rmdir socket strchr strcspn strdup \
 133         strncasecmp strndup strnlen strpbrk strrchr strstr strtol strtoul \
 134         strtoull dirfd gethostbyname2 getipnodebyname epoll_create1 \
 135         sched_getcpu sysconf sync_file_range
 136 ])
 137
 138 # Check if clock_gettime, timer_create, timer_settime, and timer_delete are available in lib rt, and if so,
 139 # add -lrt to LIBS
 140 AC_CHECK_LIB([rt], [clock_gettime, timer_create, timer_settime, timer_delete])
 141
 142 # Babeltrace viewer check
 143 AC_ARG_WITH([babeltrace-bin],
 144         AS_HELP_STRING([--with-babeltrace-bin],
 145         [Location of the babeltrace viewer executable (including the filename)]),
 146         [BABELTRACE_BIN="$withval"],
 147         [BABELTRACE_BIN=''])
 148 AC_SUBST([BABELTRACE_BIN])
 149
 150 # lttv-gui
 151 AC_ARG_WITH([lttv-gui-bin],
 152         AS_HELP_STRING([--with-lttv-gui-bin],
 153    [Location of the lttv GUI viewer executable (including the filename)]),
 154    [LTTV_GUI_BIN="$withval"],
 155    [LTTV_GUI_BIN=''])
 156 AC_SUBST([LTTV_GUI_BIN])
 157
 158 AC_ARG_WITH([consumerd32-bin],
 159         AS_HELP_STRING([--with-consumerd32-bin],
 160         [Location of the 32-bit consumerd executable (including the filename)]),
 161         [CONSUMERD32_BIN="$withval"],
 162         [CONSUMERD32_BIN=''])
 163 AC_SUBST([CONSUMERD32_BIN])
 164
 165 AC_ARG_WITH([consumerd64-bin],
 166         AS_HELP_STRING([--with-consumerd64-bin],
 167         [Location of the 64-bit consumerd executable (including the filename)]),
 168         [CONSUMERD64_BIN="$withval"],
 169         [CONSUMERD64_BIN=''])
 170 AC_SUBST([CONSUMERD64_BIN])
 171
 172 AC_ARG_WITH([consumerd32-libdir],
 173         AS_HELP_STRING([--with-consumerd32-libdir],
 174         [Directory containing the 32-bit consumerd libraries]),
 175         [CONSUMERD32_LIBDIR="$withval"],
 176         [CONSUMERD32_LIBDIR=''])
 177 AC_SUBST([CONSUMERD32_LIBDIR])
 178
 179 AC_ARG_WITH([consumerd64-libdir],
 180         AS_HELP_STRING([--with-consumerd64-libdir],
 181         [Directory containing the 64-bit consumerd libraries]),
 182         [CONSUMERD64_LIBDIR="$withval"],
 183         [CONSUMERD64_LIBDIR=''])
 184 AC_SUBST([CONSUMERD64_LIBDIR])
 185
 186 AC_ARG_WITH([sessiond-bin],
 187         AS_HELP_STRING([--with-sessiond-bin],
 188         [Location of the sessiond executable (including the filename)]),
 189         [SESSIOND_BIN="$withval"],
 190         [SESSIOND_BIN=''])
 191 AC_SUBST([SESSIOND_BIN])
 192
 193 AC_ARG_WITH([lttng-system-rundir],
 194         AS_HELP_STRING([--with-lttng-system-rundir],
 195         [Location of the system directory where the system-wide lttng-sessiond runtime files are kept. The default is "/var/run/lttng".]),
 196         [LTTNG_SYSTEM_RUNDIR="$withval"],
 197         [LTTNG_SYSTEM_RUNDIR="/var/run/lttng"])
 198 AC_SUBST([LTTNG_SYSTEM_RUNDIR])
 199
 200 AC_ARG_ENABLE([test-java-agent-jul],
 201         [AS_HELP_STRING([--enable-test-java-agent-jul],[enable the LTTng UST Java agent JUL tests [default=no]])],
 202         [test_java_agent_jul=$enableval],
 203         [test_java_agent_jul=no]
 204 )
 205
 206 AC_ARG_ENABLE([test-java-agent-log4j],
 207         [AS_HELP_STRING([--enable-test-java-agent-log4j],[enable the LTTng UST Java agent Log4j tests [default=no]])],
 208         [test_java_agent_log4j=$enableval],
 209         [test_java_agent_log4j=no]
 210 )
 211
 212 AC_ARG_ENABLE([test-java-agent-all],
 213         [AS_HELP_STRING([--enable-test-java-agent-all],[enable all the LTTng UST Java agent tests [default=no]])],
 214         [test_java_agent_jul=$enableval
 215          test_java_agent_log4j=$enableval],
 216         [:]
 217 )
 218
 219 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_BIN], "$CONSUMERD32_BIN", [Location of the 32-bit consumerd executable.])
 220 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_BIN], "$CONSUMERD64_BIN", [Location of the 64-bit consumerd executable])
 221 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_LIBDIR], "$CONSUMERD32_LIBDIR", [Search for consumerd 32-bit libraries in this location.])
 222 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_LIBDIR], "$CONSUMERD64_LIBDIR", [Search for consumerd 64-bit libraries in this location.])
 223 AC_DEFINE_UNQUOTED([CONFIG_BABELTRACE_BIN], "$BABELTRACE_BIN", [Location of the babeltrace viewer executable.])
 224 AC_DEFINE_UNQUOTED([CONFIG_LTTV_GUI_BIN], "$LTTV_GUI_BIN", [Location of the lttv GUI viewer executable.])
 225 AC_DEFINE_UNQUOTED([CONFIG_SESSIOND_BIN], "$SESSIOND_BIN", [Location of the sessiond executable.])
 226 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_RUNDIR], ["$LTTNG_SYSTEM_RUNDIR"], [LTTng system runtime directory])
 227
 228 AC_DEFUN([_AC_DEFINE_AND_SUBST], [
 229         AC_DEFINE_UNQUOTED([CONFIG_$1], [$2], [$1])
 230         $1="$2"
 231         AC_SUBST([$1])
 232 ])
 233
 234 AC_DEFUN([_AC_DEFINE_QUOTED_AND_SUBST], [
 235         AC_DEFINE_UNQUOTED([CONFIG_$1], ["$2"], [$1])
 236         $1="$2"
 237         AC_SUBST([$1])
 238 ])
 239
 240 # Default values
 241 m4_define([_DEFAULT_CHANNEL_SUBBUF_SIZE], [16384])
 242 m4_define([_DEFAULT_CHANNEL_SUBBUF_NUM], [4])
 243 m4_define([_DEFAULT_CHANNEL_SWITCH_TIMER], [0])
 244 m4_define([_DEFAULT_CHANNEL_LIVE_TIMER], [0])
 245 m4_define([_DEFAULT_CHANNEL_READ_TIMER], [200000])
 246 m4_define([_DEFAULT_CHANNEL_MONITOR_TIMER], [1000000])
 247 _AC_DEFINE_AND_SUBST([DEFAULT_AGENT_TCP_PORT], [5345])
 248 _AC_DEFINE_AND_SUBST([DEFAULT_APP_SOCKET_RW_TIMEOUT], [5])
 249 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE])
 250 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_COUNT], [0])
 251 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_SIZE], [0])
 252 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 253 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_READ_TIMER], [_DEFAULT_CHANNEL_READ_TIMER])
 254 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 255 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_SIZE], [1048576])
 256 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 257 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
 258 _AC_DEFINE_AND_SUBST([DEFAULT_LTTNG_LIVE_TIMER], [1000000])
 259 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_CACHE_SIZE], [4096])
 260 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_READ_TIMER], [0])
 261 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_NUM], [2])
 262 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_SIZE], [4096])
 263 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 264 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_CONTROL_PORT], [5342])
 265 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_DATA_PORT], [5343])
 266 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_VIEWER_PORT], [5344])
 267 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 268 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_READ_TIMER], [0])
 269 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 270 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE])
 271 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 272 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
 273 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 274 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_READ_TIMER], [0])
 275 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 276 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_SIZE], [524288])
 277 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 278 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
 279 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_AGENT_BIND_ADDRESS], [localhost])
 280 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_CONTROL_BIND_ADDRESS], [0.0.0.0])
 281 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_DATA_BIND_ADDRESS], [0.0.0.0])
 282 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_VIEWER_BIND_ADDRESS], [localhost])
 283
 284 # Command short descriptions
 285 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ADD_CONTEXT], [Add context fields to a channel])
 286 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_CREATE], [Create a tracing session])
 287 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DESTROY], [Tear down tracing sessions])
 288 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_CHANNEL], [Disable tracing channels])
 289 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_EVENT], [Disable event rules])
 290 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_CHANNEL], [Create or enable tracing channels])
 291 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_EVENT], [Create or enable event rules])
 292 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_HELP], [Display help information about a command])
 293 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LIST], [List tracing sessions, domains, channels, and events])
 294 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LOAD], [Load tracing session configurations])
 295 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_REGENERATE], [Manage an LTTng tracing session's data regeneration])
 296 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SAVE], [Save tracing session configurations])
 297 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SET_SESSION], [Set current tracing session])
 298 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SNAPSHOT], [Snapshot buffers of current tracing session])
 299 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_START], [Start tracing])
 300 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STATUS], [Get the status of the current tracing session])
 301 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STOP], [Stop tracing])
 302 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_TRACK], [Track specific system resources])
 303 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_UNTRACK], [Untrack specific system resources])
 304 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VERSION], [Show version information])
 305 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VIEW], [Start trace viewer])
 306
 307 if test "x$prefix" = "xNONE"; then
 308         prefix=$ac_default_prefix
 309 fi
 310 CONFDIR=`eval echo $sysconfdir`
 311 AC_SUBST(CONFDIR)
 312 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_CONFIGDIR],"$CONFDIR", [LTTng system configuration directory.])
 313
 314 AC_DEFINE_DIR([CONFIG_LTTNG_SYSTEM_DATADIR],[datadir], [LTTng system data directory.])
 315
 316 #
 317 # Check for pthread
 318 AC_CHECK_LIB([pthread], [pthread_create], [],
 319         [AC_MSG_ERROR([Cannot find libpthread. Use LDFLAGS=-Ldir to specify its location.])]
 320 )
 321
 322 # Check libpopt
 323 PKG_CHECK_MODULES([POPT], [popt],
 324         [LIBS="$LIBS $POPT_LIBS"],
 325         [
 326                 AC_MSG_WARN([pkg-config was unable to find a valid .pc for libpopt. Set PKG_CONFIG_PATH to specify the pkgconfig configuration file location])
 327                 AC_MSG_WARN([Finding libpopt without pkg-config.])
 328                 AC_CHECK_LIB([popt],
 329                         [poptGetContext],
 330                         [],
 331                         [
 332                                  AC_MSG_ERROR([Cannot find libpopt. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location])
 333                         ]
 334                 )
 335         ]
 336 )
 337
 338 PKG_CHECK_MODULES([libxml2], [libxml-2.0 >= 2.7.6])
 339
 340 # First, check for uuid in system libs
 341 AH_TEMPLATE([LTTNG_HAVE_LIBUUID], [Define if you have libuuid support])
 342 AC_CHECK_FUNCS([uuid_generate],
 343   [
 344     AC_DEFINE([LTTNG_HAVE_LIBUUID], [1])
 345     UUID_LIBS=""
 346   ],
 347   [
 348     # Then, check if the pkg-config module is available, otherwise explicitly check
 349     # for libuuid, or uuid support in the C-library.
 350     PKG_CHECK_MODULES([UUID], [uuid],
 351       [
 352         AC_DEFINE([LTTNG_HAVE_LIBUUID], [1])
 353         dnl PKG_CHECK_MODULES defines UUID_LIBS
 354       ],
 355       [
 356         AC_MSG_WARN([pkg-config was unable to find a valid .pc for libuuid. Set PKG_CONFIG_PATH to specify the pkgconfig configuration file location])
 357         AC_MSG_WARN([Finding libuuid without pkg-config.])
 358         AC_CHECK_LIB([uuid], [uuid_generate],
 359           [
 360             AC_DEFINE([LTTNG_HAVE_LIBUUID], [1])
 361             UUID_LIBS="-luuid"
 362           ],
 363           [
 364             # libuuid not found, check for uuid_create in libc.
 365             AC_CHECK_LIB([c], [uuid_create],
 366               [
 367                 AC_DEFINE([LTTNG_HAVE_LIBUUID], [1])
 368                 UUID_LIBS="-lc"
 369               ],
 370               [
 371                 AC_MSG_FAILURE([Cannot find libuuid uuid_generate nor libc uuid_create. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location])
 372               ]
 373             )
 374           ]
 375         )
 376       ]
 377     )
 378   ]
 379 )
 380 AC_SUBST(UUID_LIBS)
 381
 382 AC_CHECK_FUNC([clock_gettime], [AC_DEFINE_UNQUOTED([LTTNG_HAVE_CLOCK_GETTIME], 1, [Has clock_gettime() support.])])
 383
 384 # URCU library version needed or newer
 385 m4_define([WRONG_LIBURCU_MSG], [Userspace RCU (liburcu) >= 0.9.0 is needed])
 386
 387 # Check liburcu needed function calls
 388 AC_CHECK_DECL([cds_list_add], [],
 389         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/list.h>]])
 390 AC_CHECK_DECL([cds_wfcq_init], [],
 391         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/wfcqueue.h>]])
 392 AC_CHECK_DECL([cds_wfcq_dequeue_blocking], [],
 393         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/wfcqueue.h>]])
 394 AC_CHECK_DECL([futex_async], [],
 395         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/futex.h>]])
 396 AC_CHECK_DECL([rcu_thread_offline], [],
 397         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
 398 AC_CHECK_DECL([rcu_thread_online], [],
 399         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
 400 AC_CHECK_DECL([caa_likely], [],
 401         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
 402 AC_CHECK_LIB([urcu-cds], [_cds_lfht_new], [],
 403         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])])
 404
 405 #Function added in urcu 0.7.0
 406 AC_CHECK_DECL([cmm_smp_mb__before_uatomic_or], [],
 407         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]]
 408 )
 409
 410 #Function added in urcu 0.9.0
 411 AC_CHECK_DECL([urcu_ref_get_unless_zero], [],
 412         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/ref.h>]]
 413 )
 414
 415 # Check for libkmod, it will be auto-neabled if found but won't fail if it's not,
 416 # it can be explicitly disabled with --without-kmod
 417 AH_TEMPLATE([HAVE_KMOD], [Define if you have kmod support])
 418 AC_ARG_WITH([kmod],
 419   [AS_HELP_STRING([--with-kmod], [build with lkmod support @<:@default=check@:>@])],
 420   [],
 421   [with_kmod=check]
 422 )
 423
 424 AS_IF([test "x$with_kmod" != "xno"],
 425   [
 426     AC_CHECK_LIB([kmod], [kmod_module_probe_insert_module],
 427       [
 428         AC_DEFINE([HAVE_KMOD], [1])
 429         KMOD_LIBS="-lkmod"
 430       ],
 431       [
 432         if test "x$with_kmod" != xcheck; then
 433           AC_MSG_FAILURE([Cannot find libkmod. Use [LDFLAGS]=-Ldir and [CPPFLAGS]=-Idir to specify its location.])
 434         else
 435           with_kmod=no
 436         fi
 437       ]
 438     )
 439   ]
 440 )
 441 AC_SUBST(KMOD_LIBS)
 442
 443 # Check for liblttng-ust-ctl, fail if it's not found,
 444 # it can be explicitly disabled with --without-lttng-ust
 445 AH_TEMPLATE([HAVE_LIBLTTNG_UST_CTL], [Define if you have LTTng-UST control support])
 446 AC_ARG_WITH([lttng-ust],
 447   [AS_HELP_STRING([--without-lttng-ust], [build without LTTng-UST (Userspace Tracing) support])],
 448   [],
 449   [with_lttng_ust=yes]
 450 )
 451
 452 AS_IF([test "x$with_lttng_ust" = "xyes"],
 453   [
 454     AC_CHECK_LIB([lttng-ust-ctl], [ustctl_recv_channel_from_consumer],
 455       [
 456         AC_DEFINE([HAVE_LIBLTTNG_UST_CTL], [1])
 457       ],
 458       [
 459         AC_MSG_FAILURE([Cannot find LTTng-UST >= 2.2.x. Use [LDFLAGS]=-Ldir and [CPPFLAGS]=-Idir to specify its location, or specify --without-lttng-ust to build lttng-tools without LTTng-UST support.])
 460       ],
 461       [-lurcu-common -lurcu-bp -lurcu-cds -lrt -ldl]
 462     )
 463   ]
 464 )
 465 AM_CONDITIONAL([HAVE_LIBLTTNG_UST_CTL], [test "x$with_lttng_ust" = "xyes"])
 466
 467
 468
 469 # check for dlopen
 470 AC_CHECK_LIB([dl], [dlopen],
 471   [DL_LIBS="-ldl"],
 472   [
 473     #libdl not found, check for dlopen in libc.
 474     AC_CHECK_LIB([c], [dlopen],
 475       [DL_LIBS="-lc"],
 476       [AC_MSG_FAILURE([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])]
 477     )
 478   ]
 479 )
 480 AC_SUBST(DL_LIBS)
 481
 482 # Check for fmemopen
 483 AC_CHECK_LIB([c], [fmemopen],
 484 [
 485         AC_DEFINE_UNQUOTED([LTTNG_HAVE_FMEMOPEN], 1, [Has fmemopen support.])
 486 ]
 487 )
 488
 489 # Check for open_memstream
 490 AC_CHECK_LIB([c], [open_memstream],
 491 [
 492         AC_DEFINE_UNQUOTED([LTTNG_HAVE_OPEN_MEMSTREAM], 1, [Has open_memstream support.])
 493 ]
 494 )
 495
 496 # check for libpfm
 497 AC_CHECK_LIB([pfm], [pfm_initialize],
 498              [
 499               have_libpfm=yes
 500               ])
 501 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBPFM], [test "x$have_libpfm" = "xyes"])
 502
 503 AC_ARG_ENABLE([git-version],
 504               [AC_HELP_STRING([--disable-git-version],
 505                               [Do not use the git version for the build])],
 506               [have_git_version=$enableval], [have_git_version=yes]
 507 )
 508
 509 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_GIT_SOURCE],
 510         [test "x${have_git_version}" = "xyes"])
 511
 512 # For Python
 513 # SWIG version needed or newer:
 514 swig_version=2.0.0
 515
 516 AC_ARG_ENABLE([python-bindings],
 517               [AC_HELP_STRING([--enable-python-bindings],
 518                               [compile Python bindings])],
 519               [enable_python_binding=$enableval], [enable_python_binding=no])
 520
 521 AM_CONDITIONAL([PYTHON_BINDING], [test "x$enable_python_binding" = xyes])
 522
 523 if test "x$enable_python_binding" = xyes; then
 524   AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ])
 525   AS_IF([test x$enable_shared = xno], [ AC_MSG_ERROR([Python bindings require shared libraries.]) ])
 526   AM_PATH_PYTHON([3.0])
 527
 528   AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config])
 529   AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
 530   AS_IF([test -z "$PYTHON_INCLUDE"], [
 531     AS_IF([test -z "$PYTHON_CONFIG"], [
 532       AC_PATH_PROGS([PYTHON_CONFIG],
 533                     [python$PYTHON_VERSION-config python-config],
 534                     [no],
 535                     [`dirname $PYTHON`])
 536       AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
 537     ])
 538     AC_MSG_CHECKING([python include flags])
 539     PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
 540     AC_MSG_RESULT([$PYTHON_INCLUDE])
 541   ])
 542
 543 else
 544     AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl
 545 [if you want Python bindings.])
 546
 547 fi
 548
 549 # Epoll check. If not present, the build will fallback on poll() API
 550 AX_HAVE_EPOLL(
 551         [AX_CONFIG_FEATURE_ENABLE(epoll)],
 552         [AX_CONFIG_FEATURE_DISABLE(epoll)]
 553 )
 554 AX_CONFIG_FEATURE(
 555         [epoll], [This platform supports epoll(7)],
 556         [HAVE_EPOLL], [This platform supports epoll(7).],
 557         [enable_epoll="yes"], [enable_epoll="no"]
 558 )
 559 AM_CONDITIONAL([COMPAT_EPOLL], [ test "$enable_epoll" = "yes" ])
 560
 561 AM_CONDITIONAL([TEST_JAVA_JUL_AGENT], [test "x$test_java_agent_jul" = "xyes"])
 562 AM_CONDITIONAL([TEST_JAVA_LOG4J_AGENT], [test "x$test_java_agent_log4j" = "xyes"])
 563
 564 if test "x$test_java_agent_jul" = "xyes" || test "x$test_java_agent_log4j" = "xyes"; then
 565         AX_JAVA_OPTIONS
 566         AX_PROG_JAVAC
 567         AX_PROG_JAVA
 568         AX_PROG_JAR
 569
 570         AX_CHECK_CLASSPATH
 571
 572         # Check for Java UST agent common class first
 573         AX_CHECK_CLASS(org.lttng.ust.agent.AbstractLttngAgent)
 574         if test "x$ac_cv_class_org_lttng_ust_agent_AbstractLttngAgent" = "xno"; then
 575                 AC_MSG_ERROR([The UST Java agent common class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-common.jar"])
 576         fi
 577
 578         if test "x$test_java_agent_jul" = "xyes"; then
 579                 # Check for JUL agent class
 580                 AX_CHECK_CLASS(org.lttng.ust.agent.jul.LttngLogHandler)
 581                 if test "x$ac_cv_class_org_lttng_ust_agent_jul_LttngLogHandler" = "xno"; then
 582                         AC_MSG_ERROR([The UST Java agent JUL class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-jul.jar"])
 583                 fi
 584         fi
 585
 586         if test "x$test_java_agent_log4j" = "xyes"; then
 587                 # Check for Log4j agent class
 588                 AX_CHECK_CLASS(org.lttng.ust.agent.log4j.LttngLogAppender)
 589                 if test "x$ac_cv_class_org_lttng_ust_agent_log4j_LttngLogAppender" = "xno"; then
 590                         AC_MSG_ERROR([The UST Java agent Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-log4j.jar"])
 591                 fi
 592
 593                 # Check for Log4j class
 594                 AX_CHECK_CLASS(org.apache.log4j.Logger)
 595                 if test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"; then
 596                         AC_MSG_ERROR([The Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j.jar"])
 597                 fi
 598         fi
 599 fi
 600
 601 # set $IN_GIT_REPO if we're in the Git repository; the `bootstrap` file
 602 # is not distributed in tarballs
 603 AS_IF([test -f "$srcdir/bootstrap"], [in_git_repo=yes], [in_git_repo=no])
 604 AM_CONDITIONAL([IN_GIT_REPO], [test "x$in_git_repo" = "xyes"])
 605
 606 # enable building man pages (user's intention)
 607 AC_ARG_ENABLE(
 608         man-pages,
 609         AS_HELP_STRING(
 610                 [--disable-man-pages],
 611                 [Do not build and install man pages (already built in a distributed tarball)]
 612         ),
 613         [man_pages_opt=$enableval],
 614         [man_pages_opt=yes]
 615 )
 616
 617 # check for asciidoc and xmlto if we enabled building the man pages
 618 have_asciidoc_xmlto=no
 619 warn_prebuilt_man_pages=no
 620
 621 AS_IF([test "x$man_pages_opt" = "xyes"], [
 622         AC_PATH_PROG([ASCIIDOC], [asciidoc], [no])
 623         AC_PATH_PROG([XMLTO], [xmlto], [no])
 624
 625         AS_IF([test "x$ASCIIDOC" = "xno" || test "x$XMLTO" = "xno"], [
 626                 AS_IF([test "x$in_git_repo" = "xyes"], [
 627                         # this is an error because we're in the Git repo, which
 628                         # means the man pages are not already generated for us,
 629                         # thus asciidoc/xmlto are required because we were asked
 630                         # to build the man pages
 631                         AC_MSG_ERROR([
 632 You need asciidoc and xmlto to build the LTTng-tools man pages. Use
 633 --disable-man-pages to disable building the man pages, in which case
 634 they will not be installed.
 635                         ])
 636                 ], [
 637                         # only warn here: since we're in the tarball, the man
 638                         # pages should already be generated at this point, thus
 639                         # asciidoc/xmlto are not strictly required
 640                         warn_prebuilt_man_pages=yes
 641                 ])
 642         ], [
 643                 have_asciidoc_xmlto=yes
 644         ])
 645 ])
 646
 647 # export man page build condition: build the man pages if the user
 648 # asked for it, and if the tools are available
 649 AM_CONDITIONAL([MAN_PAGES_OPT], [test "x$man_pages_opt" != "xno"])
 650 AM_CONDITIONAL([HAVE_ASCIIDOC_XMLTO], [test "x$have_asciidoc_xmlto" = "xyes"])
 651
 652 AC_DEFINE_UNQUOTED([MANPATH], ["`eval eval echo $mandir`"], [Path to man pages.])
 653
 654 # embedded --help message
 655 AC_ARG_ENABLE(
 656         [embedded-help],
 657         AS_HELP_STRING(
 658                 [--enable-embedded-help],
 659                 [Embed the --help messages in the executable files]
 660         ),
 661         [embedded_help=$enableval],
 662         [embedded_help=no]
 663 )
 664 AS_IF([test "x$embedded_help" = "xyes"], [
 665         AS_IF([test "x$man_pages_opt" = "xno"], [
 666                 AC_MSG_ERROR([You need the --enable-man-pages option with the --enable-embedded-help option.])
 667         ])
 668         AC_PATH_PROG([man_prog_path], [man], [no])
 669         AS_IF([test "x$man_prog_path" = "xno"], [
 670                 AC_MSG_ERROR([You need man with the --enable-embedded-help option.])
 671         ])
 672         AC_DEFINE_UNQUOTED([LTTNG_EMBED_HELP], 1, [Embed --help messages.])
 673         AC_SUBST([MANPROG], [$man_prog_path])
 674 ])
 675 AM_CONDITIONAL([EMBED_HELP], [test "x$embedded_help" != "xno"])
 676
 677 # Python agent test
 678 UST_PYTHON_AGENT="lttngust"
 679
 680 AC_ARG_ENABLE(test-python2-agent,
 681         AS_HELP_STRING([--enable-test-python2-agent],
 682                 [enable tests for python2 agent. Python2 interpreter path can be overridden by setting the PYTHON2 environment variable. Default: Autodetect]
 683         ),[:],[test_python2_agent_autodetect=yes]
 684 )
 685
 686 AC_ARG_ENABLE(test-python3-agent,
 687         AS_HELP_STRING([--enable-test-python3-agent],
 688                 [enable tests for python3 agent. Python3 interpreter path can be overridden by setting the PYTHON3 environment variable. Default: Autodetect]
 689         ),[:],[test_python3_agent_autodetect=yes]
 690 )
 691
 692 AC_ARG_ENABLE(test-python-agent-all,
 693         AS_HELP_STRING([--enable-test-python-agent-all],
 694                 [enable test for all python{2/3} agent.]
 695         ),
 696 )
 697
 698 AS_IF([test ! -z "$enable_test_python_agent_all"], [
 699        unset test_python2_agent_autodetect
 700        unset test_python3_agent_autodetect
 701 ])
 702
 703 AS_IF([test "x$enable_test_python_agent_all" = "xyes"], [
 704        enable_test_python2_agent=yes
 705        enable_test_python3_agent=yes
 706 ])
 707
 708 AS_IF([test "x$enable_test_python_agent_all" = "xno"], [
 709        enable_test_python2_agent=no
 710        enable_test_python3_agent=no
 711 ])
 712
 713
 714 AS_IF([test "x$enable_test_python2_agent" = "xyes" -o "x$test_python2_agent_autodetect" = "xyes" ], [
 715         AS_IF([test -z "$PYTHON2"], [
 716                         PYTHON2=python2
 717                 ], [
 718                         AC_MSG_WARN([Using user-defined PYTHON2 ($PYTHON2) for lttng-ust python2 agent check])
 719         ])
 720
 721         AC_PATH_PROG([PYTHON2_BIN],[$PYTHON2])
 722         AS_IF([test -z "$PYTHON2_BIN"], [
 723                 AS_IF([test -z "$test_python2_agent_autodetect"],[
 724                         AC_MSG_ERROR([No python2 interpreter found. PYTHON2 can be set to override default interpreter path])
 725                 ])
 726         ], [
 727                 AC_MSG_CHECKING([for python2 lttng-ust agent])
 728                 AS_IF([$PYTHON2_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
 729                         PYTHON2_AGENT=$PYTHON2_BIN
 730                         AC_MSG_RESULT([yes])
 731                         RUN_PYTHON_AGENT_TEST=yes
 732                 ], [
 733                         AC_MSG_RESULT([no])
 734                         AS_IF([test -z "$test_python2_agent_autodetect"],[
 735                                 AC_MSG_ERROR([No python2 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
 736                         ])
 737                 ])
 738
 739         ])
 740
 741 ])
 742
 743 AS_IF([test "x$enable_test_python3_agent" = "xyes" -o "x$test_python3_agent_autodetect" = "xyes" ], [
 744         AS_IF([test -z "$PYTHON3"], [
 745                 PYTHON3=python3
 746         ], [
 747                 AC_MSG_WARN([Using user-defined PYTHON3 ($PYTHON3) for lttng-ust python3 agent check])
 748         ])
 749
 750         AC_PATH_PROG([PYTHON3_BIN],[$PYTHON3])
 751         AS_IF([test -z "$PYTHON3_BIN"], [
 752                 AS_IF([test -z "$test_python3_agent_autodetect"],[
 753                         AC_MSG_ERROR([No python3 interpreter found. PYTHON3 can be set to override default interpreter path])
 754                 ])
 755         ], [
 756                 AC_MSG_CHECKING([for python3 lttng-ust agent])
 757                 AS_IF([$PYTHON3_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
 758                         PYTHON3_AGENT=$PYTHON3_BIN
 759                         AC_MSG_RESULT([yes])
 760                         RUN_PYTHON_AGENT_TEST=yes
 761                 ], [
 762                         AC_MSG_RESULT([no])
 763                         AS_IF([test -z "$test_python3_agent_autodetect"],[
 764                                 AC_MSG_ERROR([No python3 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
 765                         ])
 766                 ])
 767
 768         ])
 769 ])
 770 AC_SUBST([RUN_PYTHON_AGENT_TEST])
 771 AC_SUBST([PYTHON2_AGENT])
 772 AC_SUBST([PYTHON3_AGENT])
 773
 774 # Arguments for binaries build exclusion
 775 AC_ARG_ENABLE([bin-lttng], AS_HELP_STRING([--disable-bin-lttng],[Disable the build of lttng binaries]))
 776 AC_ARG_ENABLE([bin-lttng-consumerd], AS_HELP_STRING([--disable-bin-lttng-consumerd],
 777               [Disable the build of lttng-consumerd binaries]))
 778 AC_ARG_ENABLE([bin-lttng-crash], AS_HELP_STRING([--disable-bin-lttng-crash],[Disable the build of lttng-crash binaries]))
 779 AC_ARG_ENABLE([bin-lttng-relayd], AS_HELP_STRING([--disable-bin-lttng-relayd],
 780               [Disable the build of lttng-relayd binaries]))
 781 AC_ARG_ENABLE([bin-lttng-sessiond], AS_HELP_STRING([--disable-bin-lttng-sessiond],
 782               [Disable the build of lttng-sessiond binaries]))
 783 AC_ARG_ENABLE([extras], AS_HELP_STRING([--disable-extras],
 784               [Disable the build of the extra components]))
 785
 786
 787 # Always build libconfig since it a dependency of libcommon
 788 build_lib_config=yes
 789
 790 build_lib_compat=no
 791 build_lib_consumer=no
 792 build_lib_hashtable=no
 793 build_lib_health=no
 794 build_lib_index=no
 795 build_lib_kernel_consumer=no
 796 build_lib_kernel_ctl=no
 797 build_lib_lttng_ctl=no
 798 build_lib_relayd=no
 799 build_lib_sessiond_comm=no
 800 build_lib_testpoint=no
 801 build_lib_ust_consumer=no
 802
 803 # There is an overlap for enabled dependencies, but this makes everything
 804 # simpler. libcommon and libconfig are always compiled so they are not repeated
 805 # here.
 806
 807 # Enable binary dependencies.
 808 AS_IF([test x$enable_bin_lttng != xno],
 809       [
 810        build_lib_lttng_ctl=yes
 811       ]
 812 )
 813
 814 AS_IF([test x$enable_bin_lttng_consumerd != xno],
 815       [
 816        build_lib_consumer=yes
 817        build_lib_sessiond_comm=yes
 818        build_lib_index=yes
 819        build_lib_health=yes
 820        build_lib_testpoint=yes
 821       ]
 822 )
 823
 824 AS_IF([test x$enable_bin_lttng_crash != xno],
 825       # Do nothing since libconfig and libcommon are built by default.
 826       []
 827 )
 828
 829 AS_IF([test x$enable_bin_lttng_relayd != xno],
 830       [
 831        build_lib_lttng_ctl=yes
 832        build_lib_sessiond_comm=yes
 833        build_lib_hashtable=yes
 834        build_lib_compat=yes
 835        build_lib_index=yes
 836        build_lib_health=yes
 837        build_lib_testpoint=yes
 838       ]
 839 )
 840 AS_IF([test x$enable_bin_lttng_sessiond != xno],
 841       [
 842        build_lib_lttng_ctl=yes
 843        build_lib_sessiond_comm=yes
 844        build_lib_kernel_ctl=yes
 845        build_lib_hashtable=yes
 846        build_lib_compat=yes
 847        build_lib_relayd=yes
 848        build_lib_testpoint=yes
 849        build_lib_health=yes
 850        build_lib_health=yes
 851       ]
 852 )
 853
 854 # Libraries dependencies enabling
 855 AS_IF([test x$build_lib_lttng_ctl = xyes],
 856       [
 857        build_lib_sessiond_comm=yes
 858        build_lib_hashtable=yes
 859       ]
 860 )
 861
 862 AS_IF([test x$build_lib_consumer = xyes],
 863       [
 864        build_lib_sessiond_comm=yes
 865        build_lib_kernel_consumer=yes
 866        build_lib_hashtable=yes
 867        build_lib_compat=yes
 868        build_lib_relayd=yes
 869        AS_IF([test "x$with_lttng_ust" = "xyes"], [build_lib_ust_consumer=yes])
 870       ]
 871 )
 872
 873 AS_IF([test x$build_lib_kernel_consumer = xyes],
 874       [
 875        build_lib_kernel_ctl=yes
 876        build_lib_relayd=yes
 877       ]
 878 )
 879
 880 AS_IF([test x$build_lib_relayd = xyes],
 881       [
 882        build_lib_sessiond_comm=yes
 883       ]
 884 )
 885
 886
 887 # Export binaries build conditions.
 888 AM_CONDITIONAL([BUILD_BIN_LTTNG], [test x$enable_bin_lttng != xno])
 889 AM_CONDITIONAL([BUILD_BIN_LTTNG_CONSUMERD], [test x$enable_bin_lttng_consumerd != xno])
 890 AM_CONDITIONAL([BUILD_BIN_LTTNG_CRASH], [test x$enable_bin_lttng_crash != xno])
 891 AM_CONDITIONAL([BUILD_BIN_LTTNG_RELAYD], [test x$enable_bin_lttng_relayd != xno])
 892 AM_CONDITIONAL([BUILD_BIN_LTTNG_SESSIOND], [test x$enable_bin_lttng_sessiond != xno])
 893
 894 # Export the tests and extras build conditions.
 895 AS_IF([\
 896 test "x$enable_bin_lttng" != "xno" && \
 897 test "x$enable_bin_lttng_consumerd" != "xno" && \
 898 test "x$enable_bin_lttng_crash" != "xno" && \
 899 test "x$enable_bin_lttng_relayd" != "xno" && \
 900 test "x$enable_bin_lttng_sessiond" != "xno"],
 901 [build_tests=yes],
 902 [build_tests=no]
 903 )
 904
 905 AM_CONDITIONAL([BUILD_TESTS], [test x$build_tests = xyes])
 906 AM_CONDITIONAL([BUILD_EXTRAS], [test x$enable_extras != xno])
 907
 908 # Export libraries build conditions.
 909 AM_CONDITIONAL([BUILD_LIB_COMPAT], [test x$build_lib_compat = xyes])
 910 AM_CONDITIONAL([BUILD_LIB_CONFIG], [test x$build_lib_config = xyes])
 911 AM_CONDITIONAL([BUILD_LIB_CONSUMER], [test x$build_lib_consumer = xyes])
 912 AM_CONDITIONAL([BUILD_LIB_HASHTABLE], [test x$build_lib_hashtable = xyes])
 913 AM_CONDITIONAL([BUILD_LIB_HEALTH], [test x$build_lib_health = xyes])
 914 AM_CONDITIONAL([BUILD_LIB_INDEX], [test x$build_lib_index = xyes])
 915 AM_CONDITIONAL([BUILD_LIB_KERNEL_CONSUMER], [test x$build_lib_kernel_consumer = xyes])
 916 AM_CONDITIONAL([BUILD_LIB_KERNEL_CTL], [test x$build_lib_kernel_ctl = xyes])
 917 AM_CONDITIONAL([BUILD_LIB_LTTNG_CTL], [test x$build_lib_lttng_ctl = xyes])
 918 AM_CONDITIONAL([BUILD_LIB_RELAYD], [test x$build_lib_relayd = xyes])
 919 AM_CONDITIONAL([BUILD_LIB_SESSIOND_COMM], [test x$build_lib_sessiond_comm = xyes])
 920 AM_CONDITIONAL([BUILD_LIB_TESTPOINT], [test x$build_lib_testpoint = xyes])
 921 AM_CONDITIONAL([BUILD_LIB_UST_CONSUMER], [test x$build_lib_ust_consumer = xyes])
 922
 923 # check for pgrep
 924 AC_PATH_PROG([PGREP], [pgrep], [no])
 925 AM_CONDITIONAL([HAS_PGREP], [test "x$PGREP" != "xno"])
 926
 927 # check for bison
 928 have_bison=yes
 929
 930 AS_IF([test "x$(basename "$YACC")" != "xbison -y"], [have_bison=no])
 931 AC_PATH_PROG([BISON], [bison])
 932 AX_PROG_BISON_VERSION([2.4], [], [have_bison=no])
 933
 934 AS_IF([test "x$have_bison" = "xno"], [
 935         AS_IF([test "x$in_git_repo" = "xyes"], [
 936                 AC_MSG_ERROR([Bison >= 2.4 is required when building from the Git repository.])
 937         ], [
 938                 AC_MSG_WARN([
 939 Missing Bison >= 2.4. Note that the parser files are already built in
 940 this distribution tarball, so Bison is only needed if you intend to
 941 modify their sources.
 942                 ])
 943         ])
 944 ])
 945
 946 # export bison condition
 947 AM_CONDITIONAL([HAVE_BISON], [test "x$have_bison" = "xyes"])
 948
 949 # check for flex
 950 have_flex=yes
 951
 952 AS_IF([test "x$LEX" != "xflex"], [have_flex=no])
 953 AC_PATH_PROG([FLEX], [flex])
 954 AX_PROG_FLEX_VERSION([2.5.35], [], [have_flex=no])
 955
 956 AS_IF([test "x$have_flex" = "xno"], [
 957         AS_IF([test "x$in_git_repo" = "xyes"], [
 958                 AC_MSG_ERROR([Flex >= 2.5.35 is required when building from the Git repository.])
 959         ], [
 960                 AC_MSG_WARN([
 961 Missing Flex >= 2.5.35. Note that the lexer files are already built in
 962 this distribution tarball, so Flex is only needed if you intend to
 963 modify their sources.
 964                 ])
 965         ])
 966 ])
 967
 968 # export flex condition
 969 AM_CONDITIONAL([HAVE_FLEX], [test "x$have_flex" = "xyes"])
 970
 971 AM_CFLAGS="-Wall -fno-strict-aliasing $PTHREAD_CFLAGS"
 972 AC_SUBST(AM_CFLAGS)
 973
 974 AM_CPPFLAGS="-I\$(top_srcdir)/include -I\$(top_builddir)/include -I\$(top_srcdir)/src -include config.h $AM_CPPFLAGS"
 975 AC_SUBST(AM_CPPFLAGS)
 976
 977 lttngincludedir="${includedir}/lttng"
 978 AC_SUBST(lttngincludedir)
 979
 980 lttngactionincludedir="${includedir}/lttng/action"
 981 AC_SUBST(lttngactionincludedir)
 982
 983 lttngconditionincludedir="${includedir}/lttng/condition"
 984 AC_SUBST(lttngconditionincludedir)
 985
 986 lttngnotificationincludedir="${includedir}/lttng/notification"
 987 AC_SUBST(lttngnotificationincludedir)
 988
 989 lttngtriggerincludedir="${includedir}/lttng/trigger"
 990 AC_SUBST(lttngtriggerincludedir)
 991
 992 lttnglibexecdir="${libdir}/lttng/libexec"
 993 AC_SUBST(lttnglibexecdir)
 994
 995 AC_CONFIG_FILES([
 996         Makefile
 997         doc/Makefile
 998         doc/man/Makefile
 999         doc/man/asciidoc-attrs.conf
1000         include/Makefile
1001         extras/Makefile
1002         extras/bindings/Makefile
1003         extras/bindings/swig/Makefile
1004         extras/bindings/swig/python/Makefile
1005         extras/core-handler/Makefile
1006         src/Makefile
1007         src/common/Makefile
1008         src/common/kernel-ctl/Makefile
1009         src/common/kernel-consumer/Makefile
1010         src/common/consumer/Makefile
1011         src/common/ust-consumer/Makefile
1012         src/common/hashtable/Makefile
1013         src/common/sessiond-comm/Makefile
1014         src/common/compat/Makefile
1015         src/common/relayd/Makefile
1016         src/common/testpoint/Makefile
1017         src/common/index/Makefile
1018         src/common/health/Makefile
1019         src/common/config/Makefile
1020         src/common/string-utils/Makefile
1021         src/lib/Makefile
1022         src/lib/lttng-ctl/Makefile
1023         src/lib/lttng-ctl/filter/Makefile
1024         src/lib/lttng-ctl/lttng-ctl.pc
1025         src/bin/Makefile
1026         src/bin/lttng-consumerd/Makefile
1027         src/bin/lttng-sessiond/Makefile
1028         src/bin/lttng-relayd/Makefile
1029         src/bin/lttng/Makefile
1030         src/bin/lttng-crash/Makefile
1031         tests/Makefile
1032         tests/destructive/Makefile
1033         tests/regression/Makefile
1034         tests/regression/kernel/Makefile
1035         tests/regression/tools/Makefile
1036         tests/regression/tools/streaming/Makefile
1037         tests/regression/tools/filtering/Makefile
1038         tests/regression/tools/health/Makefile
1039         tests/regression/tools/tracefile-limits/Makefile
1040         tests/regression/tools/snapshots/Makefile
1041         tests/regression/tools/live/Makefile
1042         tests/regression/tools/exclusion/Makefile
1043         tests/regression/tools/save-load/Makefile
1044         tests/regression/tools/save-load/configuration/Makefile
1045         tests/regression/tools/mi/Makefile
1046         tests/regression/tools/wildcard/Makefile
1047         tests/regression/tools/crash/Makefile
1048         tests/regression/tools/regen-metadata/Makefile
1049         tests/regression/tools/regen-statedump/Makefile
1050         tests/regression/tools/notification/Makefile
1051         tests/regression/ust/Makefile
1052         tests/regression/ust/nprocesses/Makefile
1053         tests/regression/ust/high-throughput/Makefile
1054         tests/regression/ust/low-throughput/Makefile
1055         tests/regression/ust/before-after/Makefile
1056         tests/regression/ust/buffers-pid/Makefile
1057         tests/regression/ust/periodical-metadata-flush/Makefile
1058         tests/regression/ust/multi-session/Makefile
1059         tests/regression/ust/overlap/Makefile
1060         tests/regression/ust/overlap/demo/Makefile
1061         tests/regression/ust/linking/Makefile
1062         tests/regression/ust/daemon/Makefile
1063         tests/regression/ust/exit-fast/Makefile
1064         tests/regression/ust/fork/Makefile
1065         tests/regression/ust/libc-wrapper/Makefile
1066         tests/regression/ust/baddr-statedump/Makefile
1067         tests/regression/ust/ust-dl/Makefile
1068         tests/regression/ust/java-jul/Makefile
1069         tests/regression/ust/java-log4j/Makefile
1070         tests/regression/ust/python-logging/Makefile
1071         tests/regression/ust/getcpu-override/Makefile
1072         tests/regression/ust/clock-override/Makefile
1073         tests/regression/ust/type-declarations/Makefile
1074         tests/regression/ust/rotation-destroy-flush/Makefile
1075         tests/regression/ust/blocking/Makefile
1076         tests/stress/Makefile
1077         tests/unit/Makefile
1078         tests/unit/ini_config/Makefile
1079         tests/perf/Makefile
1080         tests/utils/Makefile
1081         tests/utils/tap/Makefile
1082         tests/utils/testapp/Makefile
1083         tests/utils/testapp/gen-ust-events/Makefile
1084         tests/utils/testapp/gen-ust-nevents/Makefile
1085         tests/utils/testapp/gen-ust-nevents-str/Makefile
1086         tests/utils/testapp/gen-ust-tracef/Makefile
1087 ])
1088
1089 # Inject variable into python test script.
1090 AC_CONFIG_FILES([tests/regression/ust/python-logging/test_python_logging],[chmod +x tests/regression/ust/python-logging/test_python_logging])
1091 # Inject LTTNG_TOOLS_BUILD_WITH_LIBPFM variable in test script.
1092 AC_CONFIG_FILES([tests/perf/test_perf_raw],[chmod +x tests/perf/test_perf_raw])
1093
1094 AC_OUTPUT
1095
1096 #
1097 # Mini-report on what will be built.
1098 #
1099
1100 PPRINT_INIT
1101 PPRINT_SET_INDENT(1)
1102 PPRINT_SET_TS(38)
1103
1104 AS_ECHO
1105 AS_ECHO("${PPRINT_COLOR_BLDBLU}LTTng-tools $PACKAGE_VERSION \"$version_name\"$PPRINT_COLOR_RST")
1106 AS_ECHO
1107
1108 AS_IF([test -n "$report_fold"], [
1109         AS_ECHO("`AS_ECHO("$version_description") | $report_fold -s`")
1110 ], [
1111         AS_ECHO("$version_description")
1112 ])
1113
1114 AS_ECHO
1115 PPRINT_SUBTITLE([Features])
1116
1117 # Target architecture we're building for.
1118 target_arch=$host_cpu
1119 [
1120 for f in $CFLAGS; do
1121         if test $f = "-m32"; then
1122                         target_arch="32-bit"
1123         elif test $f = "-m64"; then
1124                         target_arch="64-bit"
1125         fi
1126 done
1127 ]
1128 PPRINT_PROP_STRING([Target architecture], $target_arch)
1129
1130 # kmod enabled/disabled
1131 test "x$with_kmod" != "xno" && value=1 || value=0
1132 PPRINT_PROP_BOOL([libkmod support], $value)
1133
1134 # LTTng-UST enabled/disabled
1135 test "x$with_lttng_ust" = "xyes" && value=1 || value=0
1136 PPRINT_PROP_BOOL([LTTng-UST support], $value)
1137
1138 AS_ECHO
1139 PPRINT_SUBTITLE([Binaries])
1140
1141 # List binaries to be built
1142 test x$enable_bin_lttng != xno && value=1 || value=0
1143 PPRINT_PROP_BOOL([lttng], $value)
1144
1145 test x$enable_bin_lttng_consumerd != xno && value=1 || value=0
1146 PPRINT_PROP_BOOL([lttng-consumerd], $value)
1147
1148 test x$enable_bin_lttng_crash != xno && value=1 || value=0
1149 PPRINT_PROP_BOOL([lttng-crash], $value)
1150
1151 test x$enable_bin_lttng_relayd != xno && value=1 || value=0
1152 PPRINT_PROP_BOOL([lttng-relayd], $value)
1153
1154 test x$enable_bin_lttng_sessiond != xno && value=1 || value=0
1155 PPRINT_PROP_BOOL([lttng-sessiond], $value)
1156
1157 # Extras
1158 test x$enable_extras != xno && value=1 || value=0
1159 AS_ECHO
1160 PPRINT_SET_INDENT(0)
1161 PPRINT_PROP_BOOL([Extras], $value, $PPRINT_COLOR_SUBTITLE)
1162 PPRINT_SET_INDENT(1)
1163
1164 AS_ECHO
1165 PPRINT_SUBTITLE([Tests])
1166
1167 # Print clear message that tests won't be built
1168 AS_IF([test "x$build_tests" = "xno"],[
1169         PPRINT_WARN([Tests won't be built since some binaries were disabled])
1170 ])
1171
1172 # LTTng UST Java agent JUL tests enabled/disabled
1173 test "x$test_java_agent_jul" = "xyes" && value=1 || value=0
1174 PPRINT_PROP_BOOL([LTTng-UST Java agent JUL tests], $value)
1175
1176 # LTTng UST Java agent Log4j tests enabled/disabled
1177 test "x$test_java_agent_log4j" = "xyes" && value=1 || value=0
1178 PPRINT_PROP_BOOL([LTTng-UST Java agent Log4j tests], $value)
1179
1180 test ! -z "$PYTHON2_AGENT" && value=1 || value=0
1181 PPRINT_PROP_BOOL([LTTng-UST Python2 agent tests], $value)
1182
1183 test ! -z "$PYTHON3_AGENT" && value=1 || value=0
1184 PPRINT_PROP_BOOL([LTTng-UST Python3 agent tests], $value)
1185
1186 #Python binding enabled/disabled
1187 test "x$enable_python_binding" = xyes && value=1 || value=0
1188 AS_ECHO
1189 PPRINT_SET_INDENT(0)
1190 PPRINT_PROP_BOOL([Python binding], $value, $PPRINT_COLOR_SUBTITLE)
1191
1192 # man pages build enabled/disabled
1193 m4_pushdef([build_man_pages_msg], [Build and install man pages])
1194
1195 AS_IF([test "x$man_pages_opt" != "xno"], [
1196         AS_IF([test "x$in_git_repo" = "xyes"], [
1197                 PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
1198         ], [
1199                 AS_IF([test "x$have_asciidoc_xmlto" = "xyes"], [
1200                         PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
1201                 ], [
1202                         PPRINT_PROP_STRING([build_man_pages_msg],
1203                                 [${PPRINT_COLOR_BLDGRN}yes (already built)],
1204                                 $PPRINT_COLOR_SUBTITLE)
1205                 ])
1206         ])
1207 ], [
1208         PPRINT_PROP_BOOL([build_man_pages_msg], 0, $PPRINT_COLOR_SUBTITLE)
1209 ])
1210
1211 m4_popdef([build_man_pages_msg])
1212
1213 test "x$embedded_help" = xyes && value=1 || value=0
1214 PPRINT_PROP_BOOL([Embed --help messages], $value, $PPRINT_COLOR_SUBTITLE)
1215
1216 PPRINT_SET_INDENT(1)
1217
1218 report_bindir="`eval eval echo $bindir`"
1219 report_libdir="`eval eval echo $libdir`"
1220
1221 # Print the bindir and libdir this `make install' will install into.
1222 AS_ECHO
1223 PPRINT_SUBTITLE([Install directories])
1224 PPRINT_PROP_STRING([Binaries], [$report_bindir])
1225 PPRINT_PROP_STRING([Libraries], [$report_libdir])
1226
1227 AS_ECHO
1228 PPRINT_SUBTITLE([Search directories])
1229
1230 # If we build the sessiond, print the paths it will use
1231 AS_IF([test "$SESSIOND_BIN" = ""],[
1232         path="$report_bindir/lttng-sessiond"
1233 ],[
1234         path="$SESSIOND_BIN"
1235 ])
1236 PPRINT_PROP_STRING([lttng-sessiond executable], [$path])
1237
1238 AS_IF([test "$CONSUMERD32_BIN" = ""],[
1239         path="`eval eval echo $lttnglibexecdir`/lttng-consumerd"
1240 ],[
1241         path="$CONSUMERD32_BIN"
1242 ])
1243 PPRINT_PROP_STRING([32-bit lttng-consumerd executable], [$path])
1244
1245 AS_IF([test "$CONSUMERD32_LIBDIR" = ""],[
1246         path="`eval eval echo $libdir`"
1247 ],[
1248         path="$CONSUMERD32_LIBDIR"
1249 ])
1250 PPRINT_PROP_STRING([32-bit consumer libraries], [$path])
1251
1252 AS_IF([test "$CONSUMERD64_BIN" = ""],[
1253         path="`eval eval echo $lttnglibexecdir`/lttng-consumerd"
1254 ],[
1255         path="$CONSUMERD64_BIN"
1256 ])
1257 PPRINT_PROP_STRING([64-bit lttng-consumerd executable], [$path])
1258
1259 AS_IF([test "$CONSUMERD64_LIBDIR" = ""],[
1260         path="`eval eval echo $libdir`"
1261 ],[
1262         path="$CONSUMERD64_LIBDIR"
1263 ])
1264 PPRINT_PROP_STRING([64-bit consumer libraries], [$path])
1265 PPRINT_SET_INDENT(0)
1266
1267 AS_IF([test "x$warn_prebuilt_man_pages" = "xyes" ], [
1268         AS_ECHO
1269         PPRINT_WARN([You need asciidoc and xmlto to build the LTTng-tools man pages.
1270
1271 Note that the man pages are already built in this distribution tarball,
1272 therefore asciidoc and xmlto are only needed if you intend to modify
1273 their sources.
1274
1275 Also note that the installed man pages will contain the project's
1276 default command-line option and environment variable values.
1277
1278 Use --disable-man-pages to completely disable building and installing
1279 the man pages.])
1280 ])