config/ax_tls.m4

   1 # ===========================================================================
   2 #          http://www.gnu.org/software/autoconf-archive/ax_tls.html
   3 # ===========================================================================
   4 #
   5 # SYNOPSIS
   6 #
   7 #   AX_TLS([action-if-found], [action-if-not-found])
   8 #
   9 # DESCRIPTION
  10 #
  11 #   Provides a test for the compiler support of thread local storage (TLS)
  12 #   extensions. Defines TLS if it is found. Currently knows about GCC/ICC
  13 #   and MSVC. I think SunPro uses the same as GCC, and Borland apparently
  14 #   supports either.
  15 #
  16 # LICENSE
  17 #
  18 #   Copyright (c) 2008 Alan Woodland <ajw05@aber.ac.uk>
  19 #   Copyright (c) 2010 Diego Elio Petteno` <flameeyes@gmail.com>
  20 #
  21 #   This program is free software: you can redistribute it and/or modify it
  22 #   under the terms of the GNU General Public License as published by the
  23 #   Free Software Foundation, either version 3 of the License, or (at your
  24 #   option) any later version.
  25 #
  26 #   This program is distributed in the hope that it will be useful, but
  27 #   WITHOUT ANY WARRANTY; without even the implied warranty of
  28 #   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU General
  29 #   Public License for more details.
  30 #
  31 #   You should have received a copy of the GNU General Public License along
  32 #   with this program. If not, see <http://www.gnu.org/licenses/>.
  33 #
  34 #   As a special exception, the respective Autoconf Macro's copyright owner
  35 #   gives unlimited permission to copy, distribute and modify the configure
  36 #   scripts that are the output of Autoconf when processing the Macro. You
  37 #   need not follow the terms of the GNU General Public License when using
  38 #   or distributing such scripts, even though portions of the text of the
  39 #   Macro appear in them. The GNU General Public License (GPL) does govern
  40 #   all other use of the material that constitutes the Autoconf Macro.
  41 #
  42 #   This special exception to the GPL applies to versions of the Autoconf
  43 #   Macro released by the Autoconf Archive. When you make and distribute a
  44 #   modified version of the Autoconf Macro, you may extend this special
  45 #   exception to the GPL to apply to your modified version as well.
  46
  47 #serial 11
  48
  49 #   Define m4_ifblank and m4_ifnblank macros from introduced in
  50 #   autotools 2.64 m4sugar.m4 if using an earlier autotools.
  51
  52 ifdef([m4_ifblank], [], [
  53 m4_define([m4_ifblank],
  54 [m4_if(m4_translit([[$1]],  [ ][        ][
  55 ]), [], [$2], [$3])])
  56 ])
  57
  58
  59 ifdef([m4_ifnblank], [], [
  60 m4_define([m4_ifnblank],
  61 [m4_if(m4_translit([[$1]],  [ ][        ][
  62 ]), [], [$3], [$2])])
  63 ])
  64
  65 AC_DEFUN([AX_TLS], [
  66   AC_MSG_CHECKING(for thread local storage (TLS) class)
  67   AC_CACHE_VAL(ac_cv_tls, [
  68     ax_tls_keywords="__thread __declspec(thread) none"
  69     for ax_tls_keyword in $ax_tls_keywords; do
  70        AS_CASE([$ax_tls_keyword],
  71           [none], [ac_cv_tls=none ; break],
  72           [AC_TRY_LINK(
  73                [$ax_tls_keyword int foo;],
  74                [++foo;],
  75                [ac_cv_tls=$ax_tls_keyword ; break],
  76                [ac_cv_tls=none]
  77            )])
  78     done
  79   ])
  80   AC_MSG_RESULT($ac_cv_tls)
  81
  82   AS_IF([test "$ac_cv_tls" != "none"],
  83     AC_DEFINE_UNQUOTED([TLS], $ac_cv_tls, [If the compiler supports a TLS storage class define it to that here])
  84       m4_ifnblank([$1], [$1]),
  85     m4_ifnblank([$2], [$2])
  86   )
  87 ])