[lttng-ust.git] / configure.ac

dnl SPDX-License-Identifier: LGPL-2.1-only
dnl
dnl Copyright (C) 2021 EfficiOS, Inc.
dnl
dnl Process this file with autoconf to produce a configure script.


# Project version information
m4_define([ust_version_major], [2])
m4_define([ust_version_minor], [13])
m4_define([ust_version_patch], [0])
m4_define([ust_version_dev_stage], [-pre])
m4_define([ust_version], ust_version_major[.]ust_version_minor[.]ust_version_patch[]ust_version_dev_stage)
m4_define([ust_version_name], [[Codename TBD]])
m4_define([ust_version_description], [[Description TBD]])

# Library version information of "liblttng-ust"
# Following the numbering scheme proposed by libtool for the library version
# http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
m4_define([ust_lib_version_current], [1])
m4_define([ust_lib_version_revision], [0])
m4_define([ust_lib_version_age], [0])
m4_define([ust_lib_version], ust_lib_version_current[:]ust_lib_version_revision[:]ust_lib_version_age)

# Library version information of "liblttng-ust-ctl"
# Following the numbering scheme proposed by libtool for the library version
# http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
m4_define([ust_ctl_lib_version_current], [5])
m4_define([ust_ctl_lib_version_revision], [0])
m4_define([ust_ctl_lib_version_age], [0])
m4_define([ust_ctl_lib_version], ust_ctl_lib_version_current[:]ust_ctl_lib_version_revision[:]ust_ctl_lib_version_age)


##                     ##
## Autoconf base setup ##
##                     ##

AC_PREREQ([2.69])
AC_INIT([lttng-ust],[ust_version],[mathieu dot desnoyers at efficios dot com],[],[https://lttng.org])

AC_CONFIG_HEADERS([include/config.h include/lttng/ust-config.h include/lttng/ust-version.h])
AC_CONFIG_AUX_DIR([config])
AC_CONFIG_MACRO_DIR([m4])
AC_CONFIG_SRCDIR([include/lttng/tracepoint.h])

AC_CANONICAL_TARGET
AC_CANONICAL_HOST


##                     ##
## Automake base setup ##
##                     ##

AM_INIT_AUTOMAKE([1.12 foreign dist-bzip2 no-dist-gzip tar-ustar nostdinc -Wall -Wno-portability -Werror])
AM_MAINTAINER_MODE([enable])

# Enable silent rules by default
AM_SILENT_RULES([yes])


##                   ##
## C compiler checks ##
##                   ##

# Choose the C compiler
AC_PROG_CC
# AC_PROG_CC_STDC was merged in AC_PROG_CC in autoconf 2.70
m4_version_prereq([2.70], [], [AC_PROG_CC_STDC])

# Make sure the C compiler supports C99
AS_IF([test "$ac_cv_prog_cc_c99" = "no"], [AC_MSG_ERROR([The compiler does not support C99])])

# Enable available system extensions and LFS support
AC_USE_SYSTEM_EXTENSIONS
AC_SYS_LARGEFILE

# Make sure the C compiler supports __attribute__
AX_C___ATTRIBUTE__
AS_IF([test "x$ax_cv___attribute__" != "xyes"],
  [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])

# Make sure we have pthread support
AX_PTHREAD([], [AC_MSG_ERROR([Could not configure pthread support])])

# Make sure the C compiler supports weak symbols
AX_SYS_WEAK_ALIAS
AS_IF([test "x$ax_cv_sys_weak_alias" = "xno"],
  [AC_MSG_ERROR([Your platform doesn't support weak symbols.])])

# Checks for typedefs, structures, and compiler characteristics.
AC_C_INLINE
AC_C_TYPEOF
AC_TYPE_INT16_T
AC_TYPE_INT32_T
AC_TYPE_INT64_T
AC_TYPE_INT8_T
AC_TYPE_MODE_T
AC_TYPE_OFF_T
AC_TYPE_PID_T
AC_TYPE_SIZE_T
AC_TYPE_SSIZE_T
AC_TYPE_UID_T
AC_TYPE_UINT16_T
AC_TYPE_UINT32_T
AC_TYPE_UINT64_T
AC_TYPE_UINT8_T
AC_CHECK_TYPES([ptrdiff_t])


##                     ##
## C++ compiler checks ##
##                     ##

# Find an optional C++11 compiler without GNU extensions (-std=c++11)
AX_CXX_COMPILE_STDCXX([11], [noext], [optional])
AM_CONDITIONAL([HAVE_CXX], [test "$HAVE_CXX11" = "1"])


##               ##
## Header checks ##
##               ##

AC_HEADER_STDBOOL
AC_CHECK_HEADERS([ \
  arpa/inet.h \
  dlfcn.h \
  fcntl.h \
  float.h \
  limits.h \
  linux/perf_event.h \
  locale.h \
  stddef.h \
  sys/socket.h \
  sys/time.h \
  wchar.h \
])

# Check for dlinfo() by testing for RTLD_DI_LINKMAP in dlfcn.h
AS_IF([test "x$ac_cv_header_dlfcn_h" = "xyes"], [
  AC_CHECK_DECL([RTLD_DI_LINKMAP], [], [], [[#include <dlfcn.h>]])
])


##                 ##
## Programs checks ##
##                 ##

AM_PROG_AR
AC_PROG_SED
AC_PROG_GREP
AC_PROG_LN_S
AC_PROG_MKDIR_P
AC_PROG_MAKE_SET
AC_CHECK_PROGS([ASCIIDOC], [asciidoc])
AC_CHECK_PROGS([CMAKE], [cmake])
AC_CHECK_PROGS([FOLD], [fold])
AC_CHECK_PROGS([XMLTO], [xmlto])

AM_PATH_PYTHON([2.7], [], [PYTHON=""])

AX_PROG_JAVAC
AX_PROG_JAVA
AX_PROG_JAR

# Initialize and configure libtool
LT_INIT([disable-static])


AM_CONDITIONAL([HAVE_CMAKE], [test "x$CMAKE" != "x"])

AC_MSG_CHECKING([whether shared libraries are enabled])
AS_IF([test "x$enable_shared" = "xyes"], [
	AC_MSG_RESULT([yes])
], [
	AC_MSG_RESULT([no])
	AC_MSG_ERROR([LTTng-UST requires shared libraries to be enabled])
])

# Checks for library functions.
AC_FUNC_CHOWN
AC_FUNC_FORK
AC_FUNC_MMAP
AC_FUNC_REALLOC
AC_FUNC_STRERROR_R
AC_FUNC_STRNLEN
AC_CHECK_FUNCS([ \
	atexit \
	clock_gettime \
	ftruncate \
	getpagesize \
	gettimeofday \
	localeconv \
	memchr \
	memmove \
	memset \
	mkdir \
	munmap \
	realpath \
	sched_getcpu \
	socket \
	strchr \
	strdup \
	strerror \
	strtol \
	strtoul \
	sysconf \
])

# Check for pthread_setname_np and its signature
LTTNG_PTHREAD_SETNAME_NP
LTTNG_PTHREAD_GETNAME_NP

# AC_FUNC_MALLOC causes problems when cross-compiling.
#AC_FUNC_MALLOC

# Set architecture specific options
AS_CASE([$host_cpu],
	[i[[3456]]86], [],
	[x86_64], [],
	[amd64], [],
	[powerpc], [],
	[ppc64], [],
	[ppc64le], [],
	[powerpc64], [],
	[powerpc64le], [],
	[s390], [],
	[s390x], [],
	[arm*], [
		NO_NUMA=1
		],
	[aarch64*], [],
	[mips*], [],
	[tile*], [],
	[
		UNSUPPORTED_ARCH=1
	])

# Set os specific options
AS_CASE([$host_os],
	[freebsd*], [NO_NUMA=1]
)

# Configuration options, which will be installed in the config.h
AH_TEMPLATE([LTTNG_UST_HAVE_SDT_INTEGRATION], [SystemTap integration via sdt.h])

# Checks for libraries.
AC_CHECK_LIB([dl], [dlopen], [
	libdl_name=dl
	DL_LIBS="-ldl"
], [
	#libdl not found, check for dlopen in libc.
	AC_CHECK_LIB([c], [dlopen], [
		libdl_name=c
		DL_LIBS="-lc"
	], [
		AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
	])
])
AC_SUBST(DL_LIBS)

# Check if libdl has dlmopen support.
AH_TEMPLATE([HAVE_DLMOPEN], ["Define to 1 if dlmopen is available."])
AC_CHECK_LIB([$libdl_name], [dlmopen],
	[AC_DEFINE([HAVE_DLMOPEN], [1])]
)

AM_CONDITIONAL([ENABLE_UST_DL], [test "x${ac_cv_have_decl_RTLD_DI_LINKMAP}" = "xyes"])

# Require URCU >= 0.12 for DEFINE_URCU_TLS_INIT
PKG_CHECK_MODULES([URCU], [liburcu >= 0.12])

# numa.h integration
AS_IF([test "x$NO_NUMA" = "x1"],[
      AS_IF([test "x$enable_numa" = "x" ], [enable_numa=no])
])

AC_ARG_ENABLE([numa], [
AS_HELP_STRING([--disable-numa], [disable NUMA support])
], [
	enable_numa=$enableval
], [
	enable_numa=yes
])

AS_IF([test "x$enable_numa" = "xyes"], [
	# numa - check that numa lib is available
	AC_CHECK_LIB([numa], [numa_available], [],
[AC_MSG_ERROR([libnuma is not available. Please either install it (e.g. libnuma-dev) or use [LDFLAGS]=-Ldir to specify the right location, or use --disable-numa configure argument to disable NUMA support.])])
	have_libnuma=yes
])
AM_CONDITIONAL([ENABLE_NUMA], [test "x$have_libnuma" = "xyes"])

AM_CONDITIONAL([HAVE_PERF_EVENT], [test "x$ac_cv_header_linux_perf_event_h" = "xyes"])

# Check for JNI header files if requested
AC_ARG_ENABLE([jni-interface], [
AS_HELP_STRING([--enable-jni-interface], [build JNI interface between C and Java. Needs Java include files [default=no]])
], [
	jni_interface=$enableval
], [
	jni_interface=no
])

AM_CONDITIONAL([ENABLE_JNI_INTERFACE], [test "x$jni_interface" = "xyes"])


AC_ARG_ENABLE([java-agent-jul], [
AS_HELP_STRING([--enable-java-agent-jul], [build the LTTng UST Java agent with JUL support [default=no]])
], [
	java_agent_jul=$enableval
], [
	java_agent_jul=no
])

AC_ARG_ENABLE([java-agent-log4j], [
AS_HELP_STRING([--enable-java-agent-log4j], [build the LTTng UST Java agent with Log4j support [default=no]])
], [
	java_agent_log4j=$enableval
], [
	java_agent_log4j=no
])

AC_ARG_ENABLE([java-agent-all], [
AS_HELP_STRING([--enable-java-agent-all], [build the LTTng UST Java agent with all supported backends [default=no]])
], [
	java_agent_jul=$enableval
	java_agent_log4j=$enableval
], [:])

AM_CONDITIONAL([ENABLE_JAVA_AGENT], [test "x$java_agent_jul" = "xyes" || test "x$java_agent_log4j" = "xyes"])
AM_CONDITIONAL([ENABLE_JAVA_AGENT_WITH_JUL], [test "x$java_agent_jul" = "xyes"])
AM_CONDITIONAL([ENABLE_JAVA_AGENT_WITH_LOG4J], [test "x$java_agent_log4j" = "xyes"])

AS_IF([test "x$jni_interface" = "xyes" || test "x$java_agent_jul" = "xyes" || test "x$java_agent_log4j" = "xyes"], [
	AX_JAVA_OPTIONS
	AC_ARG_VAR([CLASSPATH], [Java class path])

	AX_JNI_INCLUDE_DIR
	for JNI_INCLUDE_DIR in $JNI_INCLUDE_DIRS
	do
		JNI_CPPFLAGS="$JNI_CPPFLAGS -I$JNI_INCLUDE_DIR"
	done

	saved_CPPFLAGS="$CPPFLAGS"
	CPPFLAGS="$CPPFLAGS $JNI_CPPFLAGS"
	AX_PROG_JAVAH
	CPPFLAGS="$saved_CPPFLAGS"
])

AM_CONDITIONAL([HAVE_JAVAH], [test "x$JAVAH" != "x"])

AS_IF([test "x$java_agent_log4j" = "xyes"], [
	AX_CHECK_CLASSPATH
	AX_CHECK_CLASS([org.apache.log4j.Logger])
	AS_IF([test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"], [
		AC_MSG_ERROR([The UST Java agent support for log4j was requested but the Log4j classes were not found. Please specify the location of the Log4j jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j.jar"])
	])
])

# Option to build the python agent
AC_ARG_ENABLE([python-agent], [
AS_HELP_STRING([--enable-python-agent], [build the LTTng UST Python agent [default=no]])
], [
	python_agent=$enableval
], [:])
AM_CONDITIONAL([ENABLE_PYTHON_AGENT], [test "x$python_agent" = "xyes"])

# sdt.h integration
AC_ARG_WITH([sdt], [
AS_HELP_STRING([--with-sdt], [provide SystemTap integration via sdt.h [default=no]])
], [
	with_sdt=$withval
], [
	with_sdt="no"
])

AS_IF([test "x$with_sdt" = "xyes"], [
	AC_MSG_CHECKING([STAP_PROBEV()])
	AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
		#define SDT_USE_VARIADIC
		#include <sys/sdt.h>
		void fct(void)
		{
			STAP_PROBEV(provider,name,1,2,3,4,5,6,7,8,9,10);
		}
	]])], [
		AC_MSG_RESULT([yes])
		AC_DEFINE([LTTNG_UST_HAVE_SDT_INTEGRATION], [1])
	], [
		AC_MSG_RESULT([no])
		AC_MSG_ERROR([The sdt.h integration was requested but the STAP_PROBEV define cannot be used. Make sure it is installed, and up to date, or use CPPFLAGS=-I/path/ to specify a non-standard path to sys/sdt.h])
	])
])

AC_ARG_WITH([lttng-system-rundir], [
AS_HELP_STRING([--with-lttng-system-rundir], [Location of the system directory where LTTng-UST expects the system-wide lttng-sessiond runtime files. The default is "/var/run/lttng".]),
], [
	lttng_system_rundir="$withval"
], [
	lttng_system_rundir="/var/run/lttng"
])
AC_DEFINE_UNQUOTED([LTTNG_SYSTEM_RUNDIR], ["$lttng_system_rundir"],
		[LTTng system runtime directory])

AM_CONDITIONAL([ENABLE_GEN_TP_EXAMPLES], [test "x$PYTHON" != "x"])

# Enable building examples
AC_ARG_ENABLE(
	examples,
	AS_HELP_STRING(
		[--disable-examples],
		[Do not build and install examples]
	),
	[enable_examples=$enableval],
	[enable_examples=yes]
)

AM_CONDITIONAL([ENABLE_EXAMPLES], [test "x$enable_examples" != "xno"])

# Enable building man pages (user's intention).
AC_ARG_ENABLE(
	man-pages,
	AS_HELP_STRING(
		[--disable-man-pages],
		[Do not build and install man pages (already built in a distributed tarball)]
	),
	[man_pages_opt=$enableval],
	[man_pages_opt=yes]
)

# Check for asciidoc and xmlto if we enabled building the man pages.
have_asciidoc_xmlto=no
warn_prebuilt_man_pages=no

AS_IF([test "x$man_pages_opt" = "xyes"], [
	AS_IF([test "x$ASCIIDOC" = "x" || test "x$XMLTO" = "x"], [
		AE_IF_IN_GIT_REPO([
			# This is an error because we're in the Git repo, which
			# means the man pages are not already generated for us,
			# thus asciidoc/xmlto are required because we were asked
			# to build the man pages.
			AC_MSG_ERROR([
Both asciidoc and xmlto are needed to build the LTTng-UST man pages. Use
--disable-man-pages to disable building the man pages, in which case
they will not be installed.
			])
		], [
			# Only warn here: since we're in the tarball, the man
			# pages should already be generated at this point, thus
			# asciidoc/xmlto are not strictly required.
			warn_prebuilt_man_pages=yes
		])
	], [
		have_asciidoc_xmlto=yes
	])
])

# Export man page build condition: build the man pages if the user
# asked for it, and if the tools are available.
AM_CONDITIONAL([ENABLE_MAN_PAGES], [test "x$man_pages_opt" != "xno"])
AM_CONDITIONAL([HAVE_ASCIIDOC_XMLTO], [test "x$have_asciidoc_xmlto" = "xyes"])


# Defined in include/lttng/ust-version.h
AC_DEFINE([LTTNG_UST_MAJOR_VERSION], ust_version_major, [LTTng UST major version])
AC_DEFINE([LTTNG_UST_MINOR_VERSION], ust_version_minor, [LTTng UST minor version])
AC_DEFINE([LTTNG_UST_PATCHLEVEL_VERSION], ust_version_patch, [LTTng UST patch version])
AC_DEFINE([LTTNG_UST_VERSION], ["]ust_version["], [LTTng UST version string])
AC_DEFINE([LTTNG_UST_LIB_SONAME_MAJOR], [ust_lib_version_current], [Major SONAME number of liblttng-ust])
AC_DEFINE([LTTNG_UST_CTL_LIB_SONAME_MAJOR], [ust_ctl_lib_version_current], [Major SONAME number of liblttng-ust-ctl])


AM_CFLAGS="-Wall $URCU_CFLAGS $PTHREAD_CFLAGS"
AC_SUBST(AM_CFLAGS)

AM_CXXFLAGS="$AM_CFLAGS"
AC_SUBST(AM_CXXFLAGS)

# The order in which the include folders are searched is important.
# The top_builddir should always be searched first in the event that a build
# time generated file is included.
AM_CPPFLAGS="-I\$(top_builddir)/include -I\$(top_srcdir)/include -include config.h"
AC_SUBST(AM_CPPFLAGS)

AC_SUBST(JNI_CPPFLAGS)


##                                     ##
## Output files generated by configure ##
##                                     ##

# List of files to be generated from '.in' templates by AC_OUTPUT
AC_CONFIG_FILES([
	Makefile
	doc/Makefile
	doc/examples/Makefile
	doc/man/Makefile
	include/Makefile
	snprintf/Makefile
	libcounter/Makefile
	libmsgpack/Makefile
	libringbuffer/Makefile
	liblttng-ust-comm/Makefile
	liblttng-ust/Makefile
	liblttng-ust-ctl/Makefile
	liblttng-ust-fork/Makefile
	liblttng-ust-dl/Makefile
	liblttng-ust-fd/Makefile
	liblttng-ust-java/Makefile
	liblttng-ust-java-agent/Makefile
	liblttng-ust-java-agent/java/Makefile
	liblttng-ust-java-agent/java/lttng-ust-agent-all/Makefile
	liblttng-ust-java-agent/java/lttng-ust-agent-common/Makefile
	liblttng-ust-java-agent/java/lttng-ust-agent-jul/Makefile
	liblttng-ust-java-agent/java/lttng-ust-agent-log4j/Makefile
	liblttng-ust-java-agent/jni/Makefile
	liblttng-ust-java-agent/jni/common/Makefile
	liblttng-ust-java-agent/jni/jul/Makefile
	liblttng-ust-java-agent/jni/log4j/Makefile
	liblttng-ust-libc-wrapper/Makefile
	liblttng-ust-cyg-profile/Makefile
	liblttng-ust-python-agent/Makefile
	python-lttngust/Makefile
	python-lttngust/setup.py
	python-lttngust/lttngust/__init__.py
	tools/Makefile
	tests/Makefile
	tests/compile/Makefile
	tests/compile/ctf-types/Makefile
	tests/compile/hello.cxx/Makefile
	tests/compile/hello/Makefile
	tests/compile/hello-many/Makefile
	tests/compile/same_line_tracepoint/Makefile
	tests/compile/test-app-ctx/Makefile
	tests/benchmark/Makefile
	tests/unit/gcc-weak-hidden/Makefile
	tests/unit/libmsgpack/Makefile
	tests/unit/Makefile
	tests/unit/libringbuffer/Makefile
	tests/unit/pthread_name/Makefile
	tests/unit/snprintf/Makefile
	tests/unit/ust-elf/Makefile
	tests/utils/Makefile
	lttng-ust.pc
	lttng-ust-ctl.pc
])

AC_OUTPUT


##                                    ##
## Mini-report on what will be built. ##
##                                    ##

PPRINT_INIT
PPRINT_SET_INDENT(1)
PPRINT_SET_TS(38)

AS_ECHO
AS_IF([test -n "ust_version_name"], [
  AS_ECHO("${PPRINT_COLOR_BLDBLU}LTTng-ust $PACKAGE_VERSION \"ust_version_name\"$PPRINT_COLOR_RST")
], [
  AS_ECHO("${PPRINT_COLOR_BLDBLU}LTTng-ust $PACKAGE_VERSION")
])

AS_ECHO

AS_IF([test -n "ust_version_description"], [
  AS_IF([test -n "$FOLD"], [
    AS_ECHO("`AS_ECHO("ust_version_description") | $FOLD -s`")
  ], [
    AS_ECHO("ust_version_description")
  ])
  AS_ECHO
])

PPRINT_SUBTITLE([System])

PPRINT_PROP_STRING([Target architecture], $host_cpu)

AS_IF([test "x$UNSUPPORTED_ARCH" = "x1"],[
       PPRINT_WARN([Your architecture ($host_cpu) is unsupported, using safe default of no unaligned access.])
])

AS_ECHO
PPRINT_SUBTITLE([Features])
PPRINT_SET_INDENT(1)

test "x$with_sdt" = "xyes" && value=1 || value=0
PPRINT_PROP_BOOL_CUSTOM([sdt.h integration], $value, [use --with-sdt])

test "x$java_agent_jul" = xyes && value=1 || value=0
PPRINT_PROP_BOOL_CUSTOM([Java agent (JUL support)], $value, [use --enable-java-agent-jul])

test "x$java_agent_log4j" = xyes && value=1 || value=0
PPRINT_PROP_BOOL_CUSTOM([Java agent (Log4j support)], $value, [use --enable-java-agent-log4j])

test "x$jni_interface" = xyes && value=1 || value=0
PPRINT_PROP_BOOL_CUSTOM([JNI interface (JNI)], $value, [use --enable-jni-interface])

test "x$python_agent" = xyes && value=1 || value=0
PPRINT_PROP_BOOL_CUSTOM([Python agent], $value, [use --enable-python-agent])

test "x$ac_cv_header_linux_perf_event_h" = "xyes" && value=1 || value=0
PPRINT_PROP_BOOL_CUSTOM([Perf event integration], $value)

test "x$enable_numa" = xyes && value=1 || value=0
PPRINT_PROP_BOOL([NUMA], $value)

AS_ECHO
PPRINT_SET_INDENT(0)

test "x$enable_examples" = xyes && value=1 || value=0
PPRINT_PROP_BOOL([Build and install examples], $value, $PPRINT_COLOR_SUBTITLE)

# man pages build enabled/disabled
m4_pushdef([build_man_pages_msg], [Build and install man pages])

AS_IF([test "x$man_pages_opt" != "xno"], [
	AE_IF_IN_GIT_REPO([
		PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
	], [
		AS_IF([test "x$have_asciidoc_xmlto" = "xyes"], [
			PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
		], [
			PPRINT_PROP_STRING([build_man_pages_msg],
				[${PPRINT_COLOR_BLDGRN}yes (already built)],
				$PPRINT_COLOR_SUBTITLE)
		])
	])
], [
	PPRINT_PROP_BOOL([build_man_pages_msg], 0, $PPRINT_COLOR_SUBTITLE)
])

m4_popdef([build_man_pages_msg])

PPRINT_SET_INDENT(1)

report_bindir="`eval eval echo $bindir`"
report_libdir="`eval eval echo $libdir`"

# Print the bindir and libdir this `make install' will install into.
AS_ECHO
PPRINT_SUBTITLE([Install directories])
PPRINT_PROP_STRING([Binaries], [$report_bindir])
PPRINT_PROP_STRING([Libraries], [$report_libdir])

AS_ECHO
PPRINT_SUBTITLE([System directories])

PPRINT_PROP_STRING([lttng-sessiond rundir], [$lttng_system_rundir])

PPRINT_SET_INDENT(0)

AS_IF([test "x$warn_prebuilt_man_pages" = "xyes" ], [
	AS_ECHO
	PPRINT_WARN([Both asciidoc and xmlto are needed to build the LTTng-UST man pages.

Note that the man pages are already built in this distribution tarball,
therefore asciidoc and xmlto are only needed if you intend to modify
their sources.

Use --disable-man-pages to completely disable building and installing
the man pages.])
])
Commit	Line	Data
	1	dnl SPDX-License-Identifier: LGPL-2.1-only
	2	dnl
	3	dnl Copyright (C) 2021 EfficiOS, Inc.
	4	dnl
	5	dnl Process this file with autoconf to produce a configure script.
	6
	7
	8	# Project version information
	9	m4_define([ust_version_major], [2])
	10	m4_define([ust_version_minor], [13])
	11	m4_define([ust_version_patch], [0])
	12	m4_define([ust_version_dev_stage], [-pre])
	13	m4_define([ust_version], ust_version_major[.]ust_version_minor[.]ust_version_patch[]ust_version_dev_stage)
	14	m4_define([ust_version_name], [[Codename TBD]])
	15	m4_define([ust_version_description], [[Description TBD]])
	16
	17	# Library version information of "liblttng-ust"
	18	# Following the numbering scheme proposed by libtool for the library version
	19	# http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
	20	m4_define([ust_lib_version_current], [1])
	21	m4_define([ust_lib_version_revision], [0])
	22	m4_define([ust_lib_version_age], [0])
	23	m4_define([ust_lib_version], ust_lib_version_current[:]ust_lib_version_revision[:]ust_lib_version_age)
	24
	25	# Library version information of "liblttng-ust-ctl"
	26	# Following the numbering scheme proposed by libtool for the library version
	27	# http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
	28	m4_define([ust_ctl_lib_version_current], [5])
	29	m4_define([ust_ctl_lib_version_revision], [0])
	30	m4_define([ust_ctl_lib_version_age], [0])
	31	m4_define([ust_ctl_lib_version], ust_ctl_lib_version_current[:]ust_ctl_lib_version_revision[:]ust_ctl_lib_version_age)
	32
	33
	34	## ##
	35	## Autoconf base setup ##
	36	## ##
	37
	38	AC_PREREQ([2.69])
	39	AC_INIT([lttng-ust],[ust_version],[mathieu dot desnoyers at efficios dot com],[],[https://lttng.org])
	40
	41	AC_CONFIG_HEADERS([include/config.h include/lttng/ust-config.h include/lttng/ust-version.h])
	42	AC_CONFIG_AUX_DIR([config])
	43	AC_CONFIG_MACRO_DIR([m4])
	44	AC_CONFIG_SRCDIR([include/lttng/tracepoint.h])
	45
	46	AC_CANONICAL_TARGET
	47	AC_CANONICAL_HOST
	48
	49
	50	## ##
	51	## Automake base setup ##
	52	## ##
	53
	54	AM_INIT_AUTOMAKE([1.12 foreign dist-bzip2 no-dist-gzip tar-ustar nostdinc -Wall -Wno-portability -Werror])
	55	AM_MAINTAINER_MODE([enable])
	56
	57	# Enable silent rules by default
	58	AM_SILENT_RULES([yes])
	59
	60
	61	## ##
	62	## C compiler checks ##
	63	## ##
	64
	65	# Choose the C compiler
	66	AC_PROG_CC
	67	# AC_PROG_CC_STDC was merged in AC_PROG_CC in autoconf 2.70
	68	m4_version_prereq([2.70], [], [AC_PROG_CC_STDC])
	69
	70	# Make sure the C compiler supports C99
	71	AS_IF([test "$ac_cv_prog_cc_c99" = "no"], [AC_MSG_ERROR([The compiler does not support C99])])
	72
	73	# Enable available system extensions and LFS support
	74	AC_USE_SYSTEM_EXTENSIONS
	75	AC_SYS_LARGEFILE
	76
	77	# Make sure the C compiler supports __attribute__
	78	AX_C___ATTRIBUTE__
	79	AS_IF([test "x$ax_cv___attribute__" != "xyes"],
	80	[AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
	81
	82	# Make sure we have pthread support
	83	AX_PTHREAD([], [AC_MSG_ERROR([Could not configure pthread support])])
	84
	85	# Make sure the C compiler supports weak symbols
	86	AX_SYS_WEAK_ALIAS
	87	AS_IF([test "x$ax_cv_sys_weak_alias" = "xno"],
	88	[AC_MSG_ERROR([Your platform doesn't support weak symbols.])])
	89
	90	# Checks for typedefs, structures, and compiler characteristics.
	91	AC_C_INLINE
	92	AC_C_TYPEOF
	93	AC_TYPE_INT16_T
	94	AC_TYPE_INT32_T
	95	AC_TYPE_INT64_T
	96	AC_TYPE_INT8_T
	97	AC_TYPE_MODE_T
	98	AC_TYPE_OFF_T
	99	AC_TYPE_PID_T
	100	AC_TYPE_SIZE_T
	101	AC_TYPE_SSIZE_T
	102	AC_TYPE_UID_T
	103	AC_TYPE_UINT16_T
	104	AC_TYPE_UINT32_T
	105	AC_TYPE_UINT64_T
	106	AC_TYPE_UINT8_T
	107	AC_CHECK_TYPES([ptrdiff_t])
	108
	109
	110	## ##
	111	## C++ compiler checks ##
	112	## ##
	113
	114	# Find an optional C++11 compiler without GNU extensions (-std=c++11)
	115	AX_CXX_COMPILE_STDCXX([11], [noext], [optional])
	116	AM_CONDITIONAL([HAVE_CXX], [test "$HAVE_CXX11" = "1"])
	117
	118
	119	## ##
	120	## Header checks ##
	121	## ##
	122
	123	AC_HEADER_STDBOOL
	124	AC_CHECK_HEADERS([ \
	125	arpa/inet.h \
	126	dlfcn.h \
	127	fcntl.h \
	128	float.h \
	129	limits.h \
	130	linux/perf_event.h \
	131	locale.h \
	132	stddef.h \
	133	sys/socket.h \
	134	sys/time.h \
	135	wchar.h \
	136	])
	137
	138	# Check for dlinfo() by testing for RTLD_DI_LINKMAP in dlfcn.h
	139	AS_IF([test "x$ac_cv_header_dlfcn_h" = "xyes"], [
	140	AC_CHECK_DECL([RTLD_DI_LINKMAP], [], [], [[#include <dlfcn.h>]])
	141	])
	142
	143
	144	## ##
	145	## Programs checks ##
	146	## ##
	147
	148	AM_PROG_AR
	149	AC_PROG_SED
	150	AC_PROG_GREP
	151	AC_PROG_LN_S
	152	AC_PROG_MKDIR_P
	153	AC_PROG_MAKE_SET
	154	AC_CHECK_PROGS([ASCIIDOC], [asciidoc])
	155	AC_CHECK_PROGS([CMAKE], [cmake])
	156	AC_CHECK_PROGS([FOLD], [fold])
	157	AC_CHECK_PROGS([XMLTO], [xmlto])
	158
	159	AM_PATH_PYTHON([2.7], [], [PYTHON=""])
	160
	161	AX_PROG_JAVAC
	162	AX_PROG_JAVA
	163	AX_PROG_JAR
	164
	165	# Initialize and configure libtool
	166	LT_INIT([disable-static])
	167
	168
	169	AM_CONDITIONAL([HAVE_CMAKE], [test "x$CMAKE" != "x"])
	170
	171	AC_MSG_CHECKING([whether shared libraries are enabled])
	172	AS_IF([test "x$enable_shared" = "xyes"], [
	173	AC_MSG_RESULT([yes])
	174	], [
	175	AC_MSG_RESULT([no])
	176	AC_MSG_ERROR([LTTng-UST requires shared libraries to be enabled])
	177	])
	178
	179	# Checks for library functions.
	180	AC_FUNC_CHOWN
	181	AC_FUNC_FORK
	182	AC_FUNC_MMAP
	183	AC_FUNC_REALLOC
	184	AC_FUNC_STRERROR_R
	185	AC_FUNC_STRNLEN
	186	AC_CHECK_FUNCS([ \
	187	atexit \
	188	clock_gettime \
	189	ftruncate \
	190	getpagesize \
	191	gettimeofday \
	192	localeconv \
	193	memchr \
	194	memmove \
	195	memset \
	196	mkdir \
	197	munmap \
	198	realpath \
	199	sched_getcpu \
	200	socket \
	201	strchr \
	202	strdup \
	203	strerror \
	204	strtol \
	205	strtoul \
	206	sysconf \
	207	])
	208
	209	# Check for pthread_setname_np and its signature
	210	LTTNG_PTHREAD_SETNAME_NP
	211	LTTNG_PTHREAD_GETNAME_NP
	212
	213	# AC_FUNC_MALLOC causes problems when cross-compiling.
	214	#AC_FUNC_MALLOC
	215
	216	# Set architecture specific options
	217	AS_CASE([$host_cpu],
	218	[i[[3456]]86], [],
	219	[x86_64], [],
	220	[amd64], [],
	221	[powerpc], [],
	222	[ppc64], [],
	223	[ppc64le], [],
	224	[powerpc64], [],
	225	[powerpc64le], [],
	226	[s390], [],
	227	[s390x], [],
	228	[arm*], [
	229	NO_NUMA=1
	230	],
	231	[aarch64*], [],
	232	[mips*], [],
	233	[tile*], [],
	234	[
	235	UNSUPPORTED_ARCH=1
	236	])
	237
	238	# Set os specific options
	239	AS_CASE([$host_os],
	240	[freebsd*], [NO_NUMA=1]
	241	)
	242
	243	# Configuration options, which will be installed in the config.h
	244	AH_TEMPLATE([LTTNG_UST_HAVE_SDT_INTEGRATION], [SystemTap integration via sdt.h])
	245
	246	# Checks for libraries.
	247	AC_CHECK_LIB([dl], [dlopen], [
	248	libdl_name=dl
	249	DL_LIBS="-ldl"
	250	], [
	251	#libdl not found, check for dlopen in libc.
	252	AC_CHECK_LIB([c], [dlopen], [
	253	libdl_name=c
	254	DL_LIBS="-lc"
	255	], [
	256	AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
	257	])
	258	])
	259	AC_SUBST(DL_LIBS)
	260
	261	# Check if libdl has dlmopen support.
	262	AH_TEMPLATE([HAVE_DLMOPEN], ["Define to 1 if dlmopen is available."])
	263	AC_CHECK_LIB([$libdl_name], [dlmopen],
	264	[AC_DEFINE([HAVE_DLMOPEN], [1])]
	265	)
	266
	267	AM_CONDITIONAL([ENABLE_UST_DL], [test "x${ac_cv_have_decl_RTLD_DI_LINKMAP}" = "xyes"])
	268
	269	# Require URCU >= 0.12 for DEFINE_URCU_TLS_INIT
	270	PKG_CHECK_MODULES([URCU], [liburcu >= 0.12])
	271
	272	# numa.h integration
	273	AS_IF([test "x$NO_NUMA" = "x1"],[
	274	AS_IF([test "x$enable_numa" = "x" ], [enable_numa=no])
	275	])
	276
	277	AC_ARG_ENABLE([numa], [
	278	AS_HELP_STRING([--disable-numa], [disable NUMA support])
	279	], [
	280	enable_numa=$enableval
	281	], [
	282	enable_numa=yes
	283	])
	284
	285	AS_IF([test "x$enable_numa" = "xyes"], [
	286	# numa - check that numa lib is available
	287	AC_CHECK_LIB([numa], [numa_available], [],
	288	[AC_MSG_ERROR([libnuma is not available. Please either install it (e.g. libnuma-dev) or use [LDFLAGS]=-Ldir to specify the right location, or use --disable-numa configure argument to disable NUMA support.])])
	289	have_libnuma=yes
	290	])
	291	AM_CONDITIONAL([ENABLE_NUMA], [test "x$have_libnuma" = "xyes"])
	292
	293	AM_CONDITIONAL([HAVE_PERF_EVENT], [test "x$ac_cv_header_linux_perf_event_h" = "xyes"])
	294
	295	# Check for JNI header files if requested
	296	AC_ARG_ENABLE([jni-interface], [
	297	AS_HELP_STRING([--enable-jni-interface], [build JNI interface between C and Java. Needs Java include files [default=no]])
	298	], [
	299	jni_interface=$enableval
	300	], [
	301	jni_interface=no
	302	])
	303
	304	AM_CONDITIONAL([ENABLE_JNI_INTERFACE], [test "x$jni_interface" = "xyes"])
	305
	306
	307	AC_ARG_ENABLE([java-agent-jul], [
	308	AS_HELP_STRING([--enable-java-agent-jul], [build the LTTng UST Java agent with JUL support [default=no]])
	309	], [
	310	java_agent_jul=$enableval
	311	], [
	312	java_agent_jul=no
	313	])
	314
	315	AC_ARG_ENABLE([java-agent-log4j], [
	316	AS_HELP_STRING([--enable-java-agent-log4j], [build the LTTng UST Java agent with Log4j support [default=no]])
	317	], [
	318	java_agent_log4j=$enableval
	319	], [
	320	java_agent_log4j=no
	321	])
	322
	323	AC_ARG_ENABLE([java-agent-all], [
	324	AS_HELP_STRING([--enable-java-agent-all], [build the LTTng UST Java agent with all supported backends [default=no]])
	325	], [
	326	java_agent_jul=$enableval
	327	java_agent_log4j=$enableval
	328	], [:])
	329
	330	AM_CONDITIONAL([ENABLE_JAVA_AGENT], [test "x$java_agent_jul" = "xyes" \|\| test "x$java_agent_log4j" = "xyes"])
	331	AM_CONDITIONAL([ENABLE_JAVA_AGENT_WITH_JUL], [test "x$java_agent_jul" = "xyes"])
	332	AM_CONDITIONAL([ENABLE_JAVA_AGENT_WITH_LOG4J], [test "x$java_agent_log4j" = "xyes"])
	333
	334	AS_IF([test "x$jni_interface" = "xyes" \|\| test "x$java_agent_jul" = "xyes" \|\| test "x$java_agent_log4j" = "xyes"], [
	335	AX_JAVA_OPTIONS
	336	AC_ARG_VAR([CLASSPATH], [Java class path])
	337
	338	AX_JNI_INCLUDE_DIR
	339	for JNI_INCLUDE_DIR in $JNI_INCLUDE_DIRS
	340	do
	341	JNI_CPPFLAGS="$JNI_CPPFLAGS -I$JNI_INCLUDE_DIR"
	342	done
	343
	344	saved_CPPFLAGS="$CPPFLAGS"
	345	CPPFLAGS="$CPPFLAGS $JNI_CPPFLAGS"
	346	AX_PROG_JAVAH
	347	CPPFLAGS="$saved_CPPFLAGS"
	348	])
	349
	350	AM_CONDITIONAL([HAVE_JAVAH], [test "x$JAVAH" != "x"])
	351
	352	AS_IF([test "x$java_agent_log4j" = "xyes"], [
	353	AX_CHECK_CLASSPATH
	354	AX_CHECK_CLASS([org.apache.log4j.Logger])
	355	AS_IF([test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"], [
	356	AC_MSG_ERROR([The UST Java agent support for log4j was requested but the Log4j classes were not found. Please specify the location of the Log4j jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j.jar"])
	357	])
	358	])
	359
	360	# Option to build the python agent
	361	AC_ARG_ENABLE([python-agent], [
	362	AS_HELP_STRING([--enable-python-agent], [build the LTTng UST Python agent [default=no]])
	363	], [
	364	python_agent=$enableval
	365	], [:])
	366	AM_CONDITIONAL([ENABLE_PYTHON_AGENT], [test "x$python_agent" = "xyes"])
	367
	368	# sdt.h integration
	369	AC_ARG_WITH([sdt], [
	370	AS_HELP_STRING([--with-sdt], [provide SystemTap integration via sdt.h [default=no]])
	371	], [
	372	with_sdt=$withval
	373	], [
	374	with_sdt="no"
	375	])
	376
	377	AS_IF([test "x$with_sdt" = "xyes"], [
	378	AC_MSG_CHECKING([STAP_PROBEV()])
	379	AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
	380	#define SDT_USE_VARIADIC
	381	#include <sys/sdt.h>
	382	void fct(void)
	383	{
	384	STAP_PROBEV(provider,name,1,2,3,4,5,6,7,8,9,10);
	385	}
	386	]])], [
	387	AC_MSG_RESULT([yes])
	388	AC_DEFINE([LTTNG_UST_HAVE_SDT_INTEGRATION], [1])
	389	], [
	390	AC_MSG_RESULT([no])
	391	AC_MSG_ERROR([The sdt.h integration was requested but the STAP_PROBEV define cannot be used. Make sure it is installed, and up to date, or use CPPFLAGS=-I/path/ to specify a non-standard path to sys/sdt.h])
	392	])
	393	])
	394
	395	AC_ARG_WITH([lttng-system-rundir], [
	396	AS_HELP_STRING([--with-lttng-system-rundir], [Location of the system directory where LTTng-UST expects the system-wide lttng-sessiond runtime files. The default is "/var/run/lttng".]),
	397	], [
	398	lttng_system_rundir="$withval"
	399	], [
	400	lttng_system_rundir="/var/run/lttng"
	401	])
	402	AC_DEFINE_UNQUOTED([LTTNG_SYSTEM_RUNDIR], ["$lttng_system_rundir"],
	403	[LTTng system runtime directory])
	404
	405	AM_CONDITIONAL([ENABLE_GEN_TP_EXAMPLES], [test "x$PYTHON" != "x"])
	406
	407	# Enable building examples
	408	AC_ARG_ENABLE(
	409	examples,
	410	AS_HELP_STRING(
	411	[--disable-examples],
	412	[Do not build and install examples]
	413	),
	414	[enable_examples=$enableval],
	415	[enable_examples=yes]
	416	)
	417
	418	AM_CONDITIONAL([ENABLE_EXAMPLES], [test "x$enable_examples" != "xno"])
	419
	420	# Enable building man pages (user's intention).
	421	AC_ARG_ENABLE(
	422	man-pages,
	423	AS_HELP_STRING(
	424	[--disable-man-pages],
	425	[Do not build and install man pages (already built in a distributed tarball)]
	426	),
	427	[man_pages_opt=$enableval],
	428	[man_pages_opt=yes]
	429	)
	430
	431	# Check for asciidoc and xmlto if we enabled building the man pages.
	432	have_asciidoc_xmlto=no
	433	warn_prebuilt_man_pages=no
	434
	435	AS_IF([test "x$man_pages_opt" = "xyes"], [
	436	AS_IF([test "x$ASCIIDOC" = "x" \|\| test "x$XMLTO" = "x"], [
	437	AE_IF_IN_GIT_REPO([
	438	# This is an error because we're in the Git repo, which
	439	# means the man pages are not already generated for us,
	440	# thus asciidoc/xmlto are required because we were asked
	441	# to build the man pages.
	442	AC_MSG_ERROR([
	443	Both asciidoc and xmlto are needed to build the LTTng-UST man pages. Use
	444	--disable-man-pages to disable building the man pages, in which case
	445	they will not be installed.
	446	])
	447	], [
	448	# Only warn here: since we're in the tarball, the man
	449	# pages should already be generated at this point, thus
	450	# asciidoc/xmlto are not strictly required.
	451	warn_prebuilt_man_pages=yes
	452	])
	453	], [
	454	have_asciidoc_xmlto=yes
	455	])
	456	])
	457
	458	# Export man page build condition: build the man pages if the user
	459	# asked for it, and if the tools are available.
	460	AM_CONDITIONAL([ENABLE_MAN_PAGES], [test "x$man_pages_opt" != "xno"])
	461	AM_CONDITIONAL([HAVE_ASCIIDOC_XMLTO], [test "x$have_asciidoc_xmlto" = "xyes"])
	462
	463
	464	# Defined in include/lttng/ust-version.h
	465	AC_DEFINE([LTTNG_UST_MAJOR_VERSION], ust_version_major, [LTTng UST major version])
	466	AC_DEFINE([LTTNG_UST_MINOR_VERSION], ust_version_minor, [LTTng UST minor version])
	467	AC_DEFINE([LTTNG_UST_PATCHLEVEL_VERSION], ust_version_patch, [LTTng UST patch version])
	468	AC_DEFINE([LTTNG_UST_VERSION], ["]ust_version["], [LTTng UST version string])
	469	AC_DEFINE([LTTNG_UST_LIB_SONAME_MAJOR], [ust_lib_version_current], [Major SONAME number of liblttng-ust])
	470	AC_DEFINE([LTTNG_UST_CTL_LIB_SONAME_MAJOR], [ust_ctl_lib_version_current], [Major SONAME number of liblttng-ust-ctl])
	471
	472
	473	AM_CFLAGS="-Wall $URCU_CFLAGS $PTHREAD_CFLAGS"
	474	AC_SUBST(AM_CFLAGS)
	475
	476	AM_CXXFLAGS="$AM_CFLAGS"
	477	AC_SUBST(AM_CXXFLAGS)
	478
	479	# The order in which the include folders are searched is important.
	480	# The top_builddir should always be searched first in the event that a build
	481	# time generated file is included.
	482	AM_CPPFLAGS="-I\$(top_builddir)/include -I\$(top_srcdir)/include -include config.h"
	483	AC_SUBST(AM_CPPFLAGS)
	484
	485	AC_SUBST(JNI_CPPFLAGS)
	486
	487
	488	## ##
	489	## Output files generated by configure ##
	490	## ##
	491
	492	# List of files to be generated from '.in' templates by AC_OUTPUT
	493	AC_CONFIG_FILES([
	494	Makefile
	495	doc/Makefile
	496	doc/examples/Makefile
	497	doc/man/Makefile
	498	include/Makefile
	499	snprintf/Makefile
	500	libcounter/Makefile
	501	libmsgpack/Makefile
	502	libringbuffer/Makefile
	503	liblttng-ust-comm/Makefile
	504	liblttng-ust/Makefile
	505	liblttng-ust-ctl/Makefile
	506	liblttng-ust-fork/Makefile
	507	liblttng-ust-dl/Makefile
	508	liblttng-ust-fd/Makefile
	509	liblttng-ust-java/Makefile
	510	liblttng-ust-java-agent/Makefile
	511	liblttng-ust-java-agent/java/Makefile
	512	liblttng-ust-java-agent/java/lttng-ust-agent-all/Makefile
	513	liblttng-ust-java-agent/java/lttng-ust-agent-common/Makefile
	514	liblttng-ust-java-agent/java/lttng-ust-agent-jul/Makefile
	515	liblttng-ust-java-agent/java/lttng-ust-agent-log4j/Makefile
	516	liblttng-ust-java-agent/jni/Makefile
	517	liblttng-ust-java-agent/jni/common/Makefile
	518	liblttng-ust-java-agent/jni/jul/Makefile
	519	liblttng-ust-java-agent/jni/log4j/Makefile
	520	liblttng-ust-libc-wrapper/Makefile
	521	liblttng-ust-cyg-profile/Makefile
	522	liblttng-ust-python-agent/Makefile
	523	python-lttngust/Makefile
	524	python-lttngust/setup.py
	525	python-lttngust/lttngust/__init__.py
	526	tools/Makefile
	527	tests/Makefile
	528	tests/compile/Makefile
	529	tests/compile/ctf-types/Makefile
	530	tests/compile/hello.cxx/Makefile
	531	tests/compile/hello/Makefile
	532	tests/compile/hello-many/Makefile
	533	tests/compile/same_line_tracepoint/Makefile
	534	tests/compile/test-app-ctx/Makefile
	535	tests/benchmark/Makefile
	536	tests/unit/gcc-weak-hidden/Makefile
	537	tests/unit/libmsgpack/Makefile
	538	tests/unit/Makefile
	539	tests/unit/libringbuffer/Makefile
	540	tests/unit/pthread_name/Makefile
	541	tests/unit/snprintf/Makefile
	542	tests/unit/ust-elf/Makefile
	543	tests/utils/Makefile
	544	lttng-ust.pc
	545	lttng-ust-ctl.pc
	546	])
	547
	548	AC_OUTPUT
	549
	550
	551	## ##
	552	## Mini-report on what will be built. ##
	553	## ##
	554
	555	PPRINT_INIT
	556	PPRINT_SET_INDENT(1)
	557	PPRINT_SET_TS(38)
	558
	559	AS_ECHO
	560	AS_IF([test -n "ust_version_name"], [
	561	AS_ECHO("${PPRINT_COLOR_BLDBLU}LTTng-ust $PACKAGE_VERSION \"ust_version_name\"$PPRINT_COLOR_RST")
	562	], [
	563	AS_ECHO("${PPRINT_COLOR_BLDBLU}LTTng-ust $PACKAGE_VERSION")
	564	])
	565
	566	AS_ECHO
	567
	568	AS_IF([test -n "ust_version_description"], [
	569	AS_IF([test -n "$FOLD"], [
	570	AS_ECHO("`AS_ECHO("ust_version_description") \| $FOLD -s`")
	571	], [
	572	AS_ECHO("ust_version_description")
	573	])
	574	AS_ECHO
	575	])
	576
	577	PPRINT_SUBTITLE([System])
	578
	579	PPRINT_PROP_STRING([Target architecture], $host_cpu)
	580
	581	AS_IF([test "x$UNSUPPORTED_ARCH" = "x1"],[
	582	PPRINT_WARN([Your architecture ($host_cpu) is unsupported, using safe default of no unaligned access.])
	583	])
	584
	585	AS_ECHO
	586	PPRINT_SUBTITLE([Features])
	587	PPRINT_SET_INDENT(1)
	588
	589	test "x$with_sdt" = "xyes" && value=1 \|\| value=0
	590	PPRINT_PROP_BOOL_CUSTOM([sdt.h integration], $value, [use --with-sdt])
	591
	592	test "x$java_agent_jul" = xyes && value=1 \|\| value=0
	593	PPRINT_PROP_BOOL_CUSTOM([Java agent (JUL support)], $value, [use --enable-java-agent-jul])
	594
	595	test "x$java_agent_log4j" = xyes && value=1 \|\| value=0
	596	PPRINT_PROP_BOOL_CUSTOM([Java agent (Log4j support)], $value, [use --enable-java-agent-log4j])
	597
	598	test "x$jni_interface" = xyes && value=1 \|\| value=0
	599	PPRINT_PROP_BOOL_CUSTOM([JNI interface (JNI)], $value, [use --enable-jni-interface])
	600
	601	test "x$python_agent" = xyes && value=1 \|\| value=0
	602	PPRINT_PROP_BOOL_CUSTOM([Python agent], $value, [use --enable-python-agent])
	603
	604	test "x$ac_cv_header_linux_perf_event_h" = "xyes" && value=1 \|\| value=0
	605	PPRINT_PROP_BOOL_CUSTOM([Perf event integration], $value)
	606
	607	test "x$enable_numa" = xyes && value=1 \|\| value=0
	608	PPRINT_PROP_BOOL([NUMA], $value)
	609
	610	AS_ECHO
	611	PPRINT_SET_INDENT(0)
	612
	613	test "x$enable_examples" = xyes && value=1 \|\| value=0
	614	PPRINT_PROP_BOOL([Build and install examples], $value, $PPRINT_COLOR_SUBTITLE)
	615
	616	# man pages build enabled/disabled
	617	m4_pushdef([build_man_pages_msg], [Build and install man pages])
	618
	619	AS_IF([test "x$man_pages_opt" != "xno"], [
	620	AE_IF_IN_GIT_REPO([
	621	PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
	622	], [
	623	AS_IF([test "x$have_asciidoc_xmlto" = "xyes"], [
	624	PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
	625	], [
	626	PPRINT_PROP_STRING([build_man_pages_msg],
	627	[${PPRINT_COLOR_BLDGRN}yes (already built)],
	628	$PPRINT_COLOR_SUBTITLE)
	629	])
	630	])
	631	], [
	632	PPRINT_PROP_BOOL([build_man_pages_msg], 0, $PPRINT_COLOR_SUBTITLE)
	633	])
	634
	635	m4_popdef([build_man_pages_msg])
	636
	637	PPRINT_SET_INDENT(1)
	638
	639	report_bindir="`eval eval echo $bindir`"
	640	report_libdir="`eval eval echo $libdir`"
	641
	642	# Print the bindir and libdir this `make install' will install into.
	643	AS_ECHO
	644	PPRINT_SUBTITLE([Install directories])
	645	PPRINT_PROP_STRING([Binaries], [$report_bindir])
	646	PPRINT_PROP_STRING([Libraries], [$report_libdir])
	647
	648	AS_ECHO
	649	PPRINT_SUBTITLE([System directories])
	650
	651	PPRINT_PROP_STRING([lttng-sessiond rundir], [$lttng_system_rundir])
	652
	653	PPRINT_SET_INDENT(0)
	654
	655	AS_IF([test "x$warn_prebuilt_man_pages" = "xyes" ], [
	656	AS_ECHO
	657	PPRINT_WARN([Both asciidoc and xmlto are needed to build the LTTng-UST man pages.
	658
	659	Note that the man pages are already built in this distribution tarball,
	660	therefore asciidoc and xmlto are only needed if you intend to modify
	661	their sources.
	662
	663	Use --disable-man-pages to completely disable building and installing
	664	the man pages.])
	665	])