userspace-rcu tests: zero array before using

[userspace-rcu.git] / configure.ac

#                                               -*- Autoconf -*-
# Process this file with autoconf to produce a configure script.


AC_INIT([userspace-rcu], [0.5.4], [mathieu dot desnoyers at efficios dot com])
AC_CONFIG_AUX_DIR([config])
AC_CANONICAL_TARGET
AC_CANONICAL_HOST
AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])

AC_CONFIG_SRCDIR([urcu.h])
AM_PROG_MKDIR_P

AC_CONFIG_HEADERS([config.h urcu/config.h])

# Keep at the end to do not pollute installed header.
AH_TEMPLATE([CONFIG_RCU_SMP], [Enable SMP support. With SMP support enabled, uniprocessors are also supported. With SMP support disabled, UP systems work fine, but the behavior of SMP systems is undefined.])
AH_TEMPLATE([CONFIG_RCU_HAVE_FENCE], [Defined when on a system that has memory fence instructions.])
AH_TEMPLATE([CONFIG_RCU_HAVE_FUTEX], [Defined when on a system with futex support.])
AH_TEMPLATE([CONFIG_RCU_COMPAT_ARCH], [Compatibility mode for i386 which lacks
cmpxchg instruction.])
AH_TEMPLATE([CONFIG_RCU_ARM_HAVE_DMB], [Use the dmb instruction is available for use on ARM.])

# Checks for programs.
AC_PROG_CC
AC_PROG_MAKE_SET
AC_PROG_LIBTOOL

# Checks for typedefs, structures, and compiler characteristics.
AC_C_INLINE
AC_TYPE_PID_T
AC_TYPE_SIZE_T

# Checks for library functions.
AC_FUNC_MALLOC
AC_FUNC_MMAP
AC_CHECK_FUNCS([bzero gettimeofday munmap sched_getcpu strtoul sysconf])

# Find arch type
case $host_cpu in
	i386) ARCHTYPE="x86"; SUBARCHTYPE="x86compat" ;;
	i486) ARCHTYPE="x86";;
	i586) ARCHTYPE="x86";;
	i686) ARCHTYPE="x86";;
	x86_64) ARCHTYPE="x86";;
	powerpc) ARCHTYPE="ppc" ;;
	ppc64) ARCHTYPE="ppc" ;;
	powerpc64) ARCHTYPE="ppc" ;;
	ppc) ARCHTYPE="ppc" ;;
	s390) ARCHTYPE="s390" ;;
	s390x) ARCHTYPE="s390" ;;
	sparc64) ARCHTYPE="sparc64" ;;
	alpha*) ARCHTYPE="alpha" ;;
	ia64) ARCHTYPE="gcc" ;;
	arm*) ARCHTYPE="arm" ;;
	*) ARCHTYPE="unknown";;
esac

if test "x$ARCHTYPE" = "xarm" ; then
AC_MSG_CHECKING([checking for dmb instruction])
AC_TRY_COMPILE(
[
],
[
asm volatile("dmb":::"memory");
],
[
	AC_MSG_RESULT([yes])
	AC_DEFINE([CONFIG_RCU_ARM_HAVE_DMB], [1])
]
,
[
	AC_MSG_RESULT([no])
]
)
fi

UATOMICSRC=urcu/uatomic_arch_$ARCHTYPE.h
ARCHSRC=urcu/arch_$ARCHTYPE.h
if test "x$ARCHTYPE" != xx86 -a "x$ARCHTYPE" != xppc; then
	APISRC=tests/api_gcc.h
else
	APISRC=tests/api_$ARCHTYPE.h
fi
if test "$ARCHTYPE" == "armv7l"; then
	CFLAGS="-mcpu=cortex-a9 -mtune=cortex-a9 -O"
fi

AC_SUBST(ARCHTYPE)
AC_SUBST(SUBARCHTYPE)

[
#if test "x$ARCHTYPE" = "xx86" -a "x$host_cpu" != "xi386" -a "x$host_cpu" != "xi486" -a "x$host_cpu" != "xi586"; then
#For now, using lock; addl compatibility mode even for i686, because the
#Pentium III is seen as a i686, but lacks mfence instruction.
#Only using fence for x86_64.
if test "x$ARCHTYPE" = "xx86" -a "x$host_cpu" != "xi386" -a "x$host_cpu" != "xi486" -a "x$host_cpu" != "xi586" -a "x$host_cpu" != "xi686"; then
]
	AC_DEFINE([CONFIG_RCU_HAVE_FENCE], [1])
[
fi
]

AC_MSG_CHECKING([sys_futex()])
AC_TRY_COMPILE(
[
#include <sys/syscall.h>
],
[
#ifndef __NR_futex
#error "futexes not available"
#endif
],
[
	AC_MSG_RESULT([yes])
	AC_DEFINE([CONFIG_RCU_HAVE_FUTEX], [1])
	compat_futex_test=0
]
,
[
	AC_MSG_RESULT([no])
	compat_futex_test=1
]
)

AM_CONDITIONAL([COMPAT_FUTEX], [ test "x$compat_futex_test" = "x1" ])

AM_CONDITIONAL([COMPAT_ARCH], [test "x$SUBARCHTYPE" = xx86compat ])

[
if test "x$SUBARCHTYPE" = xx86compat; then
]
	AC_DEFINE([CONFIG_RCU_COMPAT_ARCH], [1])
[
fi
]

AC_ARG_ENABLE([smp-support], [  --disable-smp-support   Disable SMP support. Warning: only use this
                          on uniprocessor systems. [[default=enabled]]], [def_smp_support=$enableval], [def_smp_support="yes"])

[
if test "$def_smp_support" = "no"; then
	echo "SMP support disabled."
else
]
	AC_DEFINE([CONFIG_RCU_SMP], [1])
[
	echo "SMP support enabled."
fi
]

# From the sched_setaffinity(2)'s man page:
# ~~~~
# The CPU affinity system calls were introduced in Linux kernel 2.5.8.
# The library interfaces were introduced in glibc 2.3.  Initially, the
# glibc interfaces included a cpusetsize argument.  In glibc 2.3.3,
# the cpuset size argument was removed, but this argument was
# restored in glibc 2.3.4.
# ~~~~

# In addition to that, some vendors ported the system call to 2.4
# kernels.

# Furthermore, when the function first appeared, the MASK argument was
# an unsigned long pointer, while later it was made into a cpu_set_t
# pointer.  Systems that have the cpu_set_t version also should have
# the CPU_ZERO, CPU_SET, etc. macros.

# All this mess means we have to cater for at least 3 different
# sched_setaffinity prototypes:

# ~~~~
#  int sched_setaffinity (pid_t pid, unsigned int len, unsigned long *mask);
#  int sched_setaffinity (pid_t __pid, size_t __cpusetsize, const cpu_set_t *__cpuset);
#  int sched_setaffinity (pid_t __pid, const cpu_set_t *__mask);
# ~~~~

dnl Since we define _GNU_SOURCE in the sources, must do so too in the
dnl autoconf tests, as defining _GNU_SOURCE or not exposes
dnl sched_setaffinity bits differently.
saved_CFLAGS=$CFLAGS
CFLAGS="$CFLAGS -D_GNU_SOURCE"

# First check if the function is available at all.
AC_CHECK_FUNCS(
  [sched_setaffinity],
  [ # Okay, we have it.  Check if also have cpu_set_t.  If we don't,
    # then we have the first version using unsigned long, and no
    # CPU_ZERO, etc. macros.  If we do have cpu_set_t, we may have the
    # version with 2 or 3 arguments.  In that case, CPU_ZERO, etc.,
    # should also be present, but we confirm nonetheless.

    AC_CHECK_TYPES(
      [cpu_set_t],
      [ # We do have it.  Confirm that we have CPU_ZERO, and it actually works.
	AC_MSG_CHECKING([whether CPU_ZERO works])
	AH_TEMPLATE([HAVE_CPU_ZERO],
		    [Define to 1 if we have CPU_ZERO and if it works])
	AC_COMPILE_IFELSE(
	  [AC_LANG_PROGRAM(
	    [#define _GNU_SOURCE
	    #include <sched.h>],
	    [cpu_set_t foo; CPU_ZERO (&foo);])
	  ],
	  [ # Works!
	    AC_DEFINE(HAVE_CPU_ZERO, 1)
	    AC_MSG_RESULT([yes])
	  ],
	  [AC_MSG_RESULT([no])]
	)

	# Check how many arguments does sched_setaffinity take.
	# Should be 3 or 2.
	AC_MSG_CHECKING([how many arguments sched_setaffinity takes])
	AC_COMPILE_IFELSE(
	  [AC_LANG_PROGRAM(
	    [#include <sched.h>],
	    [cpu_set_t foo; sched_setaffinity (0, sizeof (foo), &foo);])
	  ],
	  [sched_set_affinity_args=3],
	  [sched_set_affinity_args=2])
	AC_DEFINE_UNQUOTED(SCHED_SETAFFINITY_ARGS, $sched_set_affinity_args,
	 [Define to sched_setaffinity's number of arguments.])
	AC_MSG_RESULT([$sched_set_affinity_args])
      ],
      [ # No cpu_set_t, always 3 args.
	AC_DEFINE(SCHED_SETAFFINITY_ARGS, 3) ],
      [#include <sched.h>]
    )
  ]
)

CFLAGS=$saved_CFLAGS

AC_CONFIG_LINKS([
	urcu/arch.h:$ARCHSRC
	urcu/uatomic_arch.h:$UATOMICSRC
	tests/api.h:$APISRC
])
AC_CONFIG_FILES([
	Makefile
	tests/Makefile
])
AC_OUTPUT