configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4
   5 AC_INIT([userspace-rcu], [0.4.1], [mathieu dot desnoyers at efficios dot com])
   6 AC_CONFIG_AUX_DIR([config])
   7 AC_CANONICAL_TARGET
   8 AC_CANONICAL_HOST
   9 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
  10 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  11
  12 AC_CONFIG_SRCDIR([urcu.h])
  13 AM_PROG_MKDIR_P
  14
  15 AC_CONFIG_HEADERS([config.h urcu/config.h])
  16
  17 # Keep at the end to do not pollute installed header.
  18 AH_TEMPLATE([CONFIG_RCU_SMP], [Enable SMP support. With SMP support enabled, uniprocessors are also supported. With SMP support disabled, UP systems work fine, but the behavior of SMP systems is undefined.])
  19 AH_TEMPLATE([CONFIG_RCU_HAVE_FENCE], [Defined when on a system that has memory fence instructions.])
  20 AH_TEMPLATE([CONFIG_RCU_HAVE_FUTEX], [Defined when on a system with futex support.])
  21 AH_TEMPLATE([CONFIG_RCU_COMPAT_ARCH], [Compatibility mode for i386 which lacks
  22 cmpxchg instruction.])
  23
  24 # Checks for programs.
  25 AC_PROG_CC
  26 AC_PROG_MAKE_SET
  27 AC_PROG_LIBTOOL
  28
  29 # Checks for typedefs, structures, and compiler characteristics.
  30 AC_C_INLINE
  31 AC_TYPE_PID_T
  32 AC_TYPE_SIZE_T
  33
  34 # Checks for library functions.
  35 AC_FUNC_MALLOC
  36 AC_FUNC_MMAP
  37 AC_CHECK_FUNCS([bzero gettimeofday munmap strtoul])
  38
  39 # Find arch type
  40 case $host_cpu in
  41         i386) ARCHTYPE="x86"; SUBARCHTYPE="x86compat" ;;
  42         i486) ARCHTYPE="x86";;
  43         i586) ARCHTYPE="x86";;
  44         i686) ARCHTYPE="x86";;
  45         x86_64) ARCHTYPE="x86";;
  46         powerpc) ARCHTYPE="ppc" ;;
  47         ppc64) ARCHTYPE="ppc" ;;
  48         powerpc64) ARCHTYPE="ppc" ;;
  49         ppc) ARCHTYPE="ppc" ;;
  50         s390) ARCHTYPE="s390" ;;
  51         s390x) ARCHTYPE="s390" ;;
  52         sparc64) ARCHTYPE="sparc64" ;;
  53         *) ARCHTYPE="unknown";;
  54 esac
  55
  56 if test "$ARCHTYPE" = "unknown"; then
  57         AC_MSG_ERROR([Unable to detect the architecture.])
  58 fi
  59 AC_SUBST(ARCHTYPE)
  60 AC_SUBST(SUBARCHTYPE)
  61
  62 [
  63 #if test "x$ARCHTYPE" = "xx86" -a "x$host_cpu" != "xi386" -a "x$host_cpu" != "xi486" -a "x$host_cpu" != "xi586"; then
  64 #For now, using lock; addl compatibility mode even for i686, because the
  65 #Pentium III is seen as a i686, but lacks mfence instruction.
  66 #Only using fence for x86_64.
  67 if test "x$ARCHTYPE" = "xx86" -a "x$host_cpu" != "xi386" -a "x$host_cpu" != "xi486" -a "x$host_cpu" != "xi586" -a "x$host_cpu" != "xi686"; then
  68 ]
  69         AC_DEFINE([CONFIG_RCU_HAVE_FENCE], [1])
  70 [
  71 fi
  72 ]
  73
  74 AC_MSG_CHECKING([sys_futex()])
  75 AC_TRY_COMPILE(
  76 [
  77 #include <sys/syscall.h>
  78 ],
  79 [
  80 #ifndef __NR_futex
  81 #error "futexes not available"
  82 #endif
  83 ],
  84 [
  85         AC_MSG_RESULT([yes])
  86         AC_DEFINE([CONFIG_RCU_HAVE_FUTEX], [1])
  87         compat_futex_test=0
  88 ]
  89 ,
  90 [
  91         AC_MSG_RESULT([no])
  92         compat_futex_test=1
  93 ]
  94 )
  95
  96 AM_CONDITIONAL([COMPAT_FUTEX], [ test "x$compat_futex_test" = "x1" ])
  97
  98 AM_CONDITIONAL([GCC_API], [test "x$ARCHTYPE" != xx86 -a "x$ARCHTYPE" != xppc])
  99
 100 AM_CONDITIONAL([COMPAT_ARCH], [test "x$SUBARCHTYPE" = xx86compat ])
 101
 102 [
 103 if test "x$SUBARCHTYPE" = xx86compat; then
 104 ]
 105         AC_DEFINE([CONFIG_RCU_COMPAT_ARCH], [1])
 106 [
 107 fi
 108 ]
 109
 110 AC_ARG_ENABLE([smp-support], [  --disable-smp-support   Disable SMP support. Warning: only use this
 111                           on uniprocessor systems. [[default=enabled]]], [def_smp_support=$enableval], [def_smp_support="yes"])
 112
 113 [
 114 if test "$def_smp_support" = "no"; then
 115         echo "SMP support disabled."
 116 else
 117 ]
 118         AC_DEFINE([CONFIG_RCU_SMP], [1])
 119 [
 120         echo "SMP support enabled."
 121 fi
 122 ]
 123
 124 # From the sched_setaffinity(2)'s man page:
 125 # ~~~~
 126 # The CPU affinity system calls were introduced in Linux kernel 2.5.8.
 127 # The library interfaces were introduced in glibc 2.3.  Initially, the
 128 # glibc interfaces included a cpusetsize argument.  In glibc 2.3.3,
 129 # the cpuset size argument was removed, but this argument was
 130 # restored in glibc 2.3.4.
 131 # ~~~~
 132
 133 # In addition to that, some vendors ported the system call to 2.4
 134 # kernels.
 135
 136 # Furthermore, when the function first appeared, the MASK argument was
 137 # an unsigned long pointer, while later it was made into a cpu_set_t
 138 # pointer.  Systems that have the cpu_set_t version also should have
 139 # the CPU_ZERO, CPU_SET, etc. macros.
 140
 141 # All this mess means we have to cater for at least 3 different
 142 # sched_setaffinity prototypes:
 143
 144 # ~~~~
 145 #  int sched_setaffinity (pid_t pid, unsigned int len, unsigned long *mask);
 146 #  int sched_setaffinity (pid_t __pid, size_t __cpusetsize, const cpu_set_t *__cpuset);
 147 #  int sched_setaffinity (pid_t __pid, const cpu_set_t *__mask);
 148 # ~~~~
 149
 150 dnl Since we define _GNU_SOURCE in the sources, must do so too in the
 151 dnl autoconf tests, as defining _GNU_SOURCE or not exposes
 152 dnl sched_setaffinity bits differently.
 153 saved_CFLAGS=$CFLAGS
 154 CFLAGS="$CFLAGS -D_GNU_SOURCE"
 155
 156 # First check if the function is available at all.
 157 AC_CHECK_FUNCS(
 158   [sched_setaffinity],
 159   [ # Okay, we have it.  Check if also have cpu_set_t.  If we don't,
 160     # then we have the first version using unsigned long, and no
 161     # CPU_ZERO, etc. macros.  If we do have cpu_set_t, we may have the
 162     # version with 2 or 3 arguments.  In that case, CPU_ZERO, etc.,
 163     # should also be present, but we confirm nonetheless.
 164
 165     AC_CHECK_TYPES(
 166       [cpu_set_t],
 167       [ # We do have it.  Confirm that we have CPU_ZERO, and it actually works.
 168         AC_MSG_CHECKING([whether CPU_ZERO works])
 169         AH_TEMPLATE([HAVE_CPU_ZERO],
 170                     [Define to 1 if we have CPU_ZERO and if it works])
 171         AC_COMPILE_IFELSE(
 172           [AC_LANG_PROGRAM(
 173             [#define _GNU_SOURCE
 174             #include <sched.h>],
 175             [cpu_set_t foo; CPU_ZERO (&foo);])
 176           ],
 177           [ # Works!
 178             AC_DEFINE(HAVE_CPU_ZERO, 1)
 179             AC_MSG_RESULT([yes])
 180           ],
 181           [AC_MSG_RESULT([no])]
 182         )
 183
 184         # Check how many arguments does sched_setaffinity take.
 185         # Should be 3 or 2.
 186         AC_MSG_CHECKING([how many arguments sched_setaffinity takes])
 187         AC_COMPILE_IFELSE(
 188           [AC_LANG_PROGRAM(
 189             [#include <sched.h>],
 190             [cpu_set_t foo; sched_setaffinity (0, sizeof (foo), &foo);])
 191           ],
 192           [sched_set_affinity_args=3],
 193           [sched_set_affinity_args=2])
 194         AC_DEFINE_UNQUOTED(SCHED_SETAFFINITY_ARGS, $sched_set_affinity_args,
 195          [Define to sched_setaffinity's number of arguments.])
 196         AC_MSG_RESULT([$sched_set_affinity_args])
 197       ],
 198       [ # No cpu_set_t, always 3 args.
 199         AC_DEFINE(SCHED_SETAFFINITY_ARGS, 3) ],
 200       [#include <sched.h>]
 201     )
 202   ]
 203 )
 204
 205 CFLAGS=$saved_CFLAGS
 206
 207 AC_CONFIG_FILES([
 208         Makefile
 209         tests/Makefile
 210 ])
 211 AC_OUTPUT