configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4
   5 AC_INIT([userspace-rcu], [0.4.1], [mathieu dot desnoyers at efficios dot com])
   6 AC_CONFIG_AUX_DIR([config])
   7 AC_CANONICAL_TARGET
   8 AC_CANONICAL_HOST
   9 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
  10 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  11
  12 AC_CONFIG_SRCDIR([urcu.h])
  13 AM_PROG_MKDIR_P
  14
  15 AC_CONFIG_HEADERS([config.h urcu/config.h])
  16
  17 # Keep at the end to do not pollute installed header.
  18 AH_TEMPLATE([CONFIG_RCU_SMP], [Enable SMP support. With SMP support enabled, uniprocessors are also supported. With SMP support disabled, UP systems work fine, but the behavior of SMP systems is undefined.])
  19 AH_TEMPLATE([CONFIG_RCU_HAVE_FENCE], [Defined when on a system that has memory fence instructions.])
  20 AH_TEMPLATE([CONFIG_RCU_HAVE_FUTEX], [Defined when on a system with futex support.])
  21 AH_TEMPLATE([CONFIG_RCU_COMPAT_ARCH], [Compatibility mode for i386 which lacks
  22 cmpxchg instruction.])
  23
  24 # Checks for programs.
  25 AC_PROG_CC
  26 AC_PROG_MAKE_SET
  27 AC_PROG_LIBTOOL
  28
  29 # Checks for typedefs, structures, and compiler characteristics.
  30 AC_C_INLINE
  31 AC_TYPE_PID_T
  32 AC_TYPE_SIZE_T
  33
  34 # Checks for library functions.
  35 AC_FUNC_MALLOC
  36 AC_FUNC_MMAP
  37 AC_CHECK_FUNCS([bzero gettimeofday munmap strtoul])
  38
  39 # Find arch type
  40 case $host_cpu in
  41         i386) ARCHTYPE="x86"; SUBARCHTYPE="x86compat" ;;
  42         i486) ARCHTYPE="x86";;
  43         i586) ARCHTYPE="x86";;
  44         i686) ARCHTYPE="x86";;
  45         x86_64) ARCHTYPE="x86";;
  46         powerpc) ARCHTYPE="ppc" ;;
  47         ppc64) ARCHTYPE="ppc" ;;
  48         powerpc64) ARCHTYPE="ppc" ;;
  49         ppc) ARCHTYPE="ppc" ;;
  50         s390) ARCHTYPE="s390" ;;
  51         s390x) ARCHTYPE="s390" ;;
  52         sparc64) ARCHTYPE="sparc64" ;;
  53         alpha*) ARCHTYPE="alpha" ;;
  54         *) ARCHTYPE="unknown";;
  55 esac
  56
  57 if test "$ARCHTYPE" = "unknown"; then
  58         AC_MSG_ERROR([Unable to detect the architecture.])
  59 fi
  60 UATOMICSRC=urcu/uatomic_arch_$ARCHTYPE.h
  61 ARCHSRC=urcu/arch_$ARCHTYPE.h
  62 if test "x$ARCHTYPE" != xx86 -a "x$ARCHTYPE" != xppc; then
  63         APISRC=tests/api_gcc.h
  64 else
  65         APISRC=tests/api_$ARCHTYPE.h
  66 fi
  67
  68 AC_SUBST(ARCHTYPE)
  69 AC_SUBST(SUBARCHTYPE)
  70
  71 [
  72 #if test "x$ARCHTYPE" = "xx86" -a "x$host_cpu" != "xi386" -a "x$host_cpu" != "xi486" -a "x$host_cpu" != "xi586"; then
  73 #For now, using lock; addl compatibility mode even for i686, because the
  74 #Pentium III is seen as a i686, but lacks mfence instruction.
  75 #Only using fence for x86_64.
  76 if test "x$ARCHTYPE" = "xx86" -a "x$host_cpu" != "xi386" -a "x$host_cpu" != "xi486" -a "x$host_cpu" != "xi586" -a "x$host_cpu" != "xi686"; then
  77 ]
  78         AC_DEFINE([CONFIG_RCU_HAVE_FENCE], [1])
  79 [
  80 fi
  81 ]
  82
  83 AC_MSG_CHECKING([sys_futex()])
  84 AC_TRY_COMPILE(
  85 [
  86 #include <sys/syscall.h>
  87 ],
  88 [
  89 #ifndef __NR_futex
  90 #error "futexes not available"
  91 #endif
  92 ],
  93 [
  94         AC_MSG_RESULT([yes])
  95         AC_DEFINE([CONFIG_RCU_HAVE_FUTEX], [1])
  96         compat_futex_test=0
  97 ]
  98 ,
  99 [
 100         AC_MSG_RESULT([no])
 101         compat_futex_test=1
 102 ]
 103 )
 104
 105 AM_CONDITIONAL([COMPAT_FUTEX], [ test "x$compat_futex_test" = "x1" ])
 106
 107 AM_CONDITIONAL([COMPAT_ARCH], [test "x$SUBARCHTYPE" = xx86compat ])
 108
 109 [
 110 if test "x$SUBARCHTYPE" = xx86compat; then
 111 ]
 112         AC_DEFINE([CONFIG_RCU_COMPAT_ARCH], [1])
 113 [
 114 fi
 115 ]
 116
 117 AC_ARG_ENABLE([smp-support], [  --disable-smp-support   Disable SMP support. Warning: only use this
 118                           on uniprocessor systems. [[default=enabled]]], [def_smp_support=$enableval], [def_smp_support="yes"])
 119
 120 [
 121 if test "$def_smp_support" = "no"; then
 122         echo "SMP support disabled."
 123 else
 124 ]
 125         AC_DEFINE([CONFIG_RCU_SMP], [1])
 126 [
 127         echo "SMP support enabled."
 128 fi
 129 ]
 130
 131 # From the sched_setaffinity(2)'s man page:
 132 # ~~~~
 133 # The CPU affinity system calls were introduced in Linux kernel 2.5.8.
 134 # The library interfaces were introduced in glibc 2.3.  Initially, the
 135 # glibc interfaces included a cpusetsize argument.  In glibc 2.3.3,
 136 # the cpuset size argument was removed, but this argument was
 137 # restored in glibc 2.3.4.
 138 # ~~~~
 139
 140 # In addition to that, some vendors ported the system call to 2.4
 141 # kernels.
 142
 143 # Furthermore, when the function first appeared, the MASK argument was
 144 # an unsigned long pointer, while later it was made into a cpu_set_t
 145 # pointer.  Systems that have the cpu_set_t version also should have
 146 # the CPU_ZERO, CPU_SET, etc. macros.
 147
 148 # All this mess means we have to cater for at least 3 different
 149 # sched_setaffinity prototypes:
 150
 151 # ~~~~
 152 #  int sched_setaffinity (pid_t pid, unsigned int len, unsigned long *mask);
 153 #  int sched_setaffinity (pid_t __pid, size_t __cpusetsize, const cpu_set_t *__cpuset);
 154 #  int sched_setaffinity (pid_t __pid, const cpu_set_t *__mask);
 155 # ~~~~
 156
 157 dnl Since we define _GNU_SOURCE in the sources, must do so too in the
 158 dnl autoconf tests, as defining _GNU_SOURCE or not exposes
 159 dnl sched_setaffinity bits differently.
 160 saved_CFLAGS=$CFLAGS
 161 CFLAGS="$CFLAGS -D_GNU_SOURCE"
 162
 163 # First check if the function is available at all.
 164 AC_CHECK_FUNCS(
 165   [sched_setaffinity],
 166   [ # Okay, we have it.  Check if also have cpu_set_t.  If we don't,
 167     # then we have the first version using unsigned long, and no
 168     # CPU_ZERO, etc. macros.  If we do have cpu_set_t, we may have the
 169     # version with 2 or 3 arguments.  In that case, CPU_ZERO, etc.,
 170     # should also be present, but we confirm nonetheless.
 171
 172     AC_CHECK_TYPES(
 173       [cpu_set_t],
 174       [ # We do have it.  Confirm that we have CPU_ZERO, and it actually works.
 175         AC_MSG_CHECKING([whether CPU_ZERO works])
 176         AH_TEMPLATE([HAVE_CPU_ZERO],
 177                     [Define to 1 if we have CPU_ZERO and if it works])
 178         AC_COMPILE_IFELSE(
 179           [AC_LANG_PROGRAM(
 180             [#define _GNU_SOURCE
 181             #include <sched.h>],
 182             [cpu_set_t foo; CPU_ZERO (&foo);])
 183           ],
 184           [ # Works!
 185             AC_DEFINE(HAVE_CPU_ZERO, 1)
 186             AC_MSG_RESULT([yes])
 187           ],
 188           [AC_MSG_RESULT([no])]
 189         )
 190
 191         # Check how many arguments does sched_setaffinity take.
 192         # Should be 3 or 2.
 193         AC_MSG_CHECKING([how many arguments sched_setaffinity takes])
 194         AC_COMPILE_IFELSE(
 195           [AC_LANG_PROGRAM(
 196             [#include <sched.h>],
 197             [cpu_set_t foo; sched_setaffinity (0, sizeof (foo), &foo);])
 198           ],
 199           [sched_set_affinity_args=3],
 200           [sched_set_affinity_args=2])
 201         AC_DEFINE_UNQUOTED(SCHED_SETAFFINITY_ARGS, $sched_set_affinity_args,
 202          [Define to sched_setaffinity's number of arguments.])
 203         AC_MSG_RESULT([$sched_set_affinity_args])
 204       ],
 205       [ # No cpu_set_t, always 3 args.
 206         AC_DEFINE(SCHED_SETAFFINITY_ARGS, 3) ],
 207       [#include <sched.h>]
 208     )
 209   ]
 210 )
 211
 212 CFLAGS=$saved_CFLAGS
 213
 214 AC_CONFIG_LINKS([
 215         urcu/arch.h:$ARCHSRC
 216         urcu/uatomic_arch.h:$UATOMICSRC
 217         tests/api.h:$APISRC
 218 ])
 219 AC_CONFIG_FILES([
 220         Makefile
 221         tests/Makefile
 222 ])
 223 AC_OUTPUT