configure.ac

   1 dnl SPDX-License-Identifier: LGPL-2.1-only
   2 dnl
   3 dnl Copyright (C) 2021 EfficiOS, Inc.
   4 dnl
   5 dnl Process this file with autoconf to produce a configure script.
   6
   7 # Project version information
   8 m4_define([urcu_version_major], [0])
   9 m4_define([urcu_version_minor], [12])
  10 m4_define([urcu_version_patch], [0])
  11 m4_define([urcu_version_dev_stage], [])
  12 m4_define([urcu_version], urcu_version_major[.]urcu_version_minor[.]urcu_version_patch[]urcu_version_dev_stage)
  13
  14 # Library version information of "liburcu"
  15 # Following the numbering scheme proposed by libtool for the library version
  16 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
  17 m4_define([urcu_lib_version_current], [7])
  18 m4_define([urcu_lib_version_revision], [0])
  19 m4_define([urcu_lib_version_age], [1])
  20 m4_define([urcu_lib_version], urcu_lib_version_current[:]urcu_lib_version_revision[:]urcu_lib_version_age)
  21
  22
  23 ##                     ##
  24 ## Autoconf base setup ##
  25 ##                     ##
  26
  27 AC_PREREQ([2.69])
  28 AC_INIT([userspace-rcu],[urcu_version],[mathieu dot desnoyers at efficios dot com],[],[http://liburcu.org/])
  29
  30 AC_CONFIG_HEADERS([include/config.h include/urcu/config.h])
  31 AC_CONFIG_AUX_DIR([config])
  32 AC_CONFIG_MACRO_DIR([m4])
  33
  34 AC_CANONICAL_TARGET
  35 AC_CANONICAL_HOST
  36
  37
  38 ##                     ##
  39 ## Automake base setup ##
  40 ##                     ##
  41
  42 AM_INIT_AUTOMAKE([1.12 foreign dist-bzip2 no-dist-gzip nostdinc -Wall -Wno-portability -Werror])
  43 AM_MAINTAINER_MODE([enable])
  44
  45 # Enable silent rules by default
  46 AM_SILENT_RULES([yes])
  47
  48
  49 ##                               ##
  50 ## OS and Arch specific defaults ##
  51 ##                               ##
  52
  53 AS_CASE([$host],
  54   [*-cygwin*], [LT_NO_UNDEFINED="-no-undefined"]
  55 )
  56
  57
  58 ##                   ##
  59 ## C compiler checks ##
  60 ##                   ##
  61
  62 # Choose the C compiler
  63 AC_PROG_CC
  64 # AC_PROG_CC_STDC was merged in AC_PROG_CC in autoconf 2.70
  65 m4_version_prereq([2.70], [], [AC_PROG_CC_STDC])
  66
  67 # Make sure the C compiler supports C99
  68 AS_IF([test "$ac_cv_prog_cc_c99" = "no"], [AC_MSG_ERROR([The compiler does not support C99])])
  69
  70 # Enable available system extensions and LFS support
  71 AC_USE_SYSTEM_EXTENSIONS
  72 AC_SYS_LARGEFILE
  73
  74 # Make sure the C compiler supports __attribute__
  75 AX_C___ATTRIBUTE__
  76 AS_IF([test "x$ax_cv___attribute__" != "xyes"],
  77   [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
  78
  79 # Make sure we have pthread support
  80 AX_PTHREAD([], [AC_MSG_ERROR([Could not configure pthread support])])
  81
  82 # Make sure the C compiler supports weak symbols
  83 AX_SYS_WEAK_ALIAS
  84 AS_IF([test "x$ax_cv_sys_weak_alias" = "xno"],
  85   [AC_MSG_ERROR([Your platform doesn't support weak symbols.])])
  86
  87 # Checks for typedefs, structures, and compiler characteristics.
  88 AC_C_INLINE
  89 AC_C_TYPEOF
  90 AC_TYPE_INT32_T
  91 AC_TYPE_PID_T
  92 AC_TYPE_SIZE_T
  93 AC_TYPE_SSIZE_T
  94 AC_TYPE_UINT16_T
  95 AC_TYPE_UINT32_T
  96 AC_TYPE_UINT64_T
  97 AC_TYPE_UINT8_T
  98
  99
 100 ##               ##
 101 ## Header checks ##
 102 ##               ##
 103
 104 AC_HEADER_STDBOOL
 105 AC_CHECK_HEADERS([ \
 106         limits.h \
 107         stddef.h \
 108         sys/param.h \
 109         sys/time.h \
 110 ])
 111
 112
 113 ##                 ##
 114 ## Programs checks ##
 115 ##                 ##
 116
 117 AC_PROG_AWK
 118 AC_PROG_GREP
 119 AC_PROG_MAKE_SET
 120 AC_CHECK_PROGS(NPROC, [nproc gnproc])
 121 AC_CHECK_PROG(GETCONF, [getconf])
 122 AS_IF([test "x$NPROC" != "x"],
 123         [NPROC_CMD=$NPROC],
 124         [AS_IF([test "x$GETCONF" != "x"],
 125                 [NPROC_CMD="$GETCONF _NPROCESSORS_ONLN"],
 126                 [NPROC_CMD="echo 1"]
 127         )]
 128 )
 129 AC_SUBST([NPROC_CMD], [$NPROC_CMD])
 130
 131 # Initialize and configure libtool
 132 LT_INIT
 133
 134
 135 AH_TEMPLATE([CONFIG_RCU_SMP], [Enable SMP support. With SMP support enabled, uniprocessors are also supported. With SMP support disabled, UP systems work fine, but the behavior of SMP systems is undefined.])
 136 AH_TEMPLATE([CONFIG_RCU_TLS], [TLS provided by the compiler.])
 137 AH_TEMPLATE([CONFIG_RCU_HAVE_CLOCK_GETTIME], [clock_gettime() is detected.])
 138 AH_TEMPLATE([CONFIG_RCU_FORCE_SYS_MEMBARRIER], [Require the operating system to support the membarrier system call for default and bulletproof flavors.])
 139 AH_TEMPLATE([CONFIG_RCU_DEBUG], [Enable internal debugging self-checks. Introduces a performance penalty.])
 140 AH_TEMPLATE([CONFIG_CDS_LFHT_ITER_DEBUG], [Enable extra debugging checks for lock-free hash table iterator traversal. Alters the rculfhash ABI. Make sure to compile both library and application with matching configuration.])
 141
 142 # Allow requiring the operating system to support the membarrier system
 143 # call. Applies to default and bulletproof flavors.
 144 AC_ARG_ENABLE([sys-membarrier-fallback],
 145         AS_HELP_STRING([--disable-sys-membarrier-fallback], [Abort if sys-membarrier is needed but not available rather than using a fallback.]),
 146         [def_sys_membarrier_fallback=$enableval],
 147         [def_sys_membarrier_fallback="yes"])
 148 AS_IF([test "x$def_sys_membarrier_fallback" != "xyes"], [AC_DEFINE([CONFIG_RCU_FORCE_SYS_MEMBARRIER], [1])])
 149
 150 # Allow overriding storage used for TLS variables.
 151 AC_ARG_ENABLE([compiler-tls],
 152         AS_HELP_STRING([--disable-compiler-tls], [Use pthread_getspecific() to emulate Thread Local Storage (TLS) variables.]),
 153         [def_compiler_tls=$enableval],
 154         [def_compiler_tls="yes"])
 155
 156 AS_IF([test "x$def_compiler_tls" = "xyes"], AC_DEFINE([CONFIG_RCU_TLS], [1]), [:])
 157
 158
 159 AM_CFLAGS="$AM_CFLAGS $PTHREAD_CFLAGS"
 160
 161 # Checks for library functions.
 162 AC_FUNC_MMAP
 163 AC_FUNC_FORK
 164 AC_CHECK_FUNCS([ \
 165         atexit \
 166         getcpuid \
 167         gettid \
 168         gettimeofday \
 169         memeset \
 170         memset \
 171         munmap \
 172         rand_r \
 173         sched_getcpu \
 174         strerror \
 175         strtoul \
 176         sysconf \
 177 ])
 178
 179 # AC_FUNC_MALLOC causes problems when cross-compiling.
 180 #AC_FUNC_MALLOC
 181
 182 # Search for clock_gettime
 183 AC_SEARCH_LIBS([clock_gettime], [rt], [
 184         AC_DEFINE([CONFIG_RCU_HAVE_CLOCK_GETTIME], [1])
 185         config_rcu_have_clock_gettime=yes
 186 ], [])
 187
 188 AM_CONDITIONAL([NO_SHARED], [test "x$enable_shared" = "xno"])
 189
 190 # smp-support configure option
 191 AC_ARG_ENABLE([smp-support],
 192         AS_HELP_STRING([--disable-smp-support], [Disable SMP support. Warning: only use this on uniprocessor systems. [default=enabled]]),
 193         [def_smp_support=$enableval],
 194         [def_smp_support="yes"])
 195 AS_IF([test "x$def_smp_support" = "xyes"], [AC_DEFINE([CONFIG_RCU_SMP], [1])])
 196
 197 # RCU debugging option
 198 AC_ARG_ENABLE([rcu-debug],
 199       AS_HELP_STRING([--enable-rcu-debug], [Enable internal debugging
 200                       self-checks. Introduces a performance penalty.]))
 201 AS_IF([test "x$enable_rcu_debug" = "xyes"], [
 202        AC_DEFINE([CONFIG_RCU_DEBUG], [1])
 203 ])
 204
 205 # rculfhash iterator debugging
 206 AC_ARG_ENABLE([cds-lfht-iter-debug],
 207       AS_HELP_STRING([--enable-cds-lfht-iter-debug], [Enable extra debugging checks for lock-free hash table iterator traversal. Alters the rculfhash ABI. Make sure to compile both library and application with matching configuration.]))
 208 AS_IF([test "x$enable_cds_lfht_iter_debug" = "xyes"], [
 209        AC_DEFINE([CONFIG_CDS_LFHT_ITER_DEBUG], [1])
 210 ])
 211
 212 # From the sched_setaffinity(2)'s man page:
 213 # ~~~~
 214 # The CPU affinity system calls were introduced in Linux kernel 2.5.8.
 215 # The library interfaces were introduced in glibc 2.3.  Initially, the
 216 # glibc interfaces included a cpusetsize argument.  In glibc 2.3.3,
 217 # the cpuset size argument was removed, but this argument was
 218 # restored in glibc 2.3.4.
 219 # ~~~~
 220
 221 # In addition to that, some vendors ported the system call to 2.4
 222 # kernels.
 223
 224 # Furthermore, when the function first appeared, the MASK argument was
 225 # an unsigned long pointer, while later it was made into a cpu_set_t
 226 # pointer.  Systems that have the cpu_set_t version also should have
 227 # the CPU_ZERO, CPU_SET, etc. macros.
 228
 229 # All this mess means we have to cater for at least 3 different
 230 # sched_setaffinity prototypes:
 231
 232 # ~~~~
 233 #  int sched_setaffinity (pid_t pid, unsigned int len, unsigned long *mask);
 234 #  int sched_setaffinity (pid_t __pid, size_t __cpusetsize, const cpu_set_t *__cpuset);
 235 #  int sched_setaffinity (pid_t __pid, const cpu_set_t *__mask);
 236 # ~~~~
 237
 238 AC_CHECK_TYPES([cpu_set_t],
 239         [have_cpu_set_t="yes"],
 240         [have_cpu_set_t="no"],
 241         [#include <sched.h>])
 242
 243 # Confirm that we have CPU_ZERO, and it actually works.
 244 AC_MSG_CHECKING([whether CPU_ZERO works])
 245 AH_TEMPLATE([HAVE_CPU_ZERO], [Defined to 1 if we have CPU_ZERO and it works])
 246 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 247                 #include <sched.h>
 248                 int main()
 249                 {
 250                         cpu_set_t foo; CPU_ZERO(&foo);
 251                         return 0;
 252                 }
 253         ]])
 254 ],[
 255         AC_DEFINE(HAVE_CPU_ZERO, 1)
 256         AC_MSG_RESULT([yes])
 257 ],[
 258         AC_MSG_RESULT([no])
 259 ])
 260
 261 # Confirm that we have CPU_SET, and it actually works.
 262 AC_MSG_CHECKING([whether CPU_SET works])
 263 AH_TEMPLATE([HAVE_CPU_SET], [Defined to 1 if we have CPU_SET and it works])
 264 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 265                 #include <sched.h>
 266                 int main()
 267                 {
 268                         cpu_set_t foo; CPU_SET(0, &foo);
 269                         return 0;
 270                 }
 271         ]])
 272 ],[
 273         AC_DEFINE(HAVE_CPU_SET, 1)
 274         AC_MSG_RESULT([yes])
 275 ],[
 276         AC_MSG_RESULT([no])
 277 ])
 278
 279 # First check if the function is available at all.
 280 AC_CHECK_FUNCS([sched_setaffinity],[
 281         # Okay, we have it.  Check if also have cpu_set_t.  If we don't,
 282         # then we have the first version using unsigned long, and no
 283         # CPU_ZERO, etc. macros.  If we do have cpu_set_t, we may have the
 284         # version with 2 or 3 arguments.  In that case, CPU_ZERO, etc.,
 285         # should also be present, but we confirm nonetheless.
 286
 287         AS_IF([test "x$have_cpu_set_t" = "xyes"], [
 288                 # We do have it.
 289                 # Check how many arguments does sched_setaffinity take.
 290                 # Should be 3 or 2.
 291                 AC_MSG_CHECKING([how many arguments sched_setaffinity takes])
 292                 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 293                                 #include <sched.h>
 294                                 int main()
 295                                 {
 296                                         cpu_set_t foo;
 297                                         sched_setaffinity(0, sizeof (foo), &foo);
 298                                         return 0;
 299                                 }
 300                         ]])
 301                 ],
 302                 [sched_set_affinity_args=3],
 303                 [sched_set_affinity_args=2])
 304                 AC_DEFINE_UNQUOTED(SCHED_SETAFFINITY_ARGS,
 305                         $sched_set_affinity_args,
 306                         [Defined to sched_setaffinity's number of arguments.])
 307                 AC_MSG_RESULT([$sched_set_affinity_args])
 308         ],[
 309                 # No cpu_set_t, always 3 args.
 310                 AC_DEFINE(SCHED_SETAFFINITY_ARGS, 3)
 311         ])
 312 ])
 313
 314 ##                                             ##
 315 ## Substitute variables for use in Makefile.am ##
 316 ##                                             ##
 317
 318 # Library versions for libtool
 319 AC_SUBST([URCU_LIBRARY_VERSION], [urcu_lib_version])
 320
 321 AC_SUBST(LT_NO_UNDEFINED)
 322
 323 AM_CPPFLAGS="-include config.h"
 324 AC_SUBST(AM_CPPFLAGS)
 325
 326 AM_CFLAGS="-Wall -Wextra -Wno-unused-parameter $AM_CFLAGS"
 327 AC_SUBST(AM_CFLAGS)
 328
 329 AC_CONFIG_FILES([
 330         Makefile
 331         doc/Makefile
 332         doc/examples/Makefile
 333         include/Makefile
 334         src/Makefile
 335         tests/Makefile
 336         tests/common/Makefile
 337         tests/unit/Makefile
 338         tests/benchmark/Makefile
 339         tests/regression/Makefile
 340         tests/utils/Makefile
 341         src/liburcu.pc
 342         src/liburcu-bp.pc
 343         src/liburcu-cds.pc
 344         src/liburcu-qsbr.pc
 345         src/liburcu-mb.pc
 346         src/liburcu-signal.pc
 347 ])
 348
 349 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_perf_global.tap], [chmod +x tests/regression/rcutorture_urcu_bp_perf_global.tap])
 350 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_perf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_bp_perf_percpu.tap])
 351 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_perf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_bp_perf_perthread.tap])
 352 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_rperf_global.tap], [chmod +x tests/regression/rcutorture_urcu_bp_rperf_global.tap])
 353 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_rperf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_bp_rperf_percpu.tap])
 354 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_rperf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_bp_rperf_perthread.tap])
 355 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_stress_global.tap], [chmod +x tests/regression/rcutorture_urcu_bp_stress_global.tap])
 356 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_stress_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_bp_stress_percpu.tap])
 357 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_stress_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_bp_stress_perthread.tap])
 358 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_uperf_global.tap], [chmod +x tests/regression/rcutorture_urcu_bp_uperf_global.tap])
 359 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_uperf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_bp_uperf_percpu.tap])
 360 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_uperf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_bp_uperf_perthread.tap])
 361 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_perf_global.tap], [chmod +x tests/regression/rcutorture_urcu_mb_perf_global.tap])
 362 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_perf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_mb_perf_percpu.tap])
 363 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_perf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_mb_perf_perthread.tap])
 364 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_rperf_global.tap], [chmod +x tests/regression/rcutorture_urcu_mb_rperf_global.tap])
 365 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_rperf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_mb_rperf_percpu.tap])
 366 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_rperf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_mb_rperf_perthread.tap])
 367 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_stress_global.tap], [chmod +x tests/regression/rcutorture_urcu_mb_stress_global.tap])
 368 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_stress_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_mb_stress_percpu.tap])
 369 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_stress_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_mb_stress_perthread.tap])
 370 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_uperf_global.tap], [chmod +x tests/regression/rcutorture_urcu_mb_uperf_global.tap])
 371 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_uperf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_mb_uperf_percpu.tap])
 372 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_uperf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_mb_uperf_perthread.tap])
 373 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_perf_global.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_perf_global.tap])
 374 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_perf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_perf_percpu.tap])
 375 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_perf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_perf_perthread.tap])
 376 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_rperf_global.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_rperf_global.tap])
 377 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_rperf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_rperf_percpu.tap])
 378 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_rperf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_rperf_perthread.tap])
 379 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_stress_global.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_stress_global.tap])
 380 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_stress_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_stress_percpu.tap])
 381 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_stress_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_stress_perthread.tap])
 382 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_uperf_global.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_uperf_global.tap])
 383 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_uperf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_uperf_percpu.tap])
 384 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_uperf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_uperf_perthread.tap])
 385 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_perf_global.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_perf_global.tap])
 386 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_perf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_perf_percpu.tap])
 387 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_perf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_perf_perthread.tap])
 388 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_rperf_global.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_rperf_global.tap])
 389 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_rperf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_rperf_percpu.tap])
 390 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_rperf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_rperf_perthread.tap])
 391 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_stress_global.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_stress_global.tap])
 392 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_stress_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_stress_percpu.tap])
 393 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_stress_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_stress_perthread.tap])
 394 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_uperf_global.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_uperf_global.tap])
 395 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_uperf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_uperf_percpu.tap])
 396 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_uperf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_uperf_perthread.tap])
 397 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_perf_global.tap], [chmod +x tests/regression/rcutorture_urcu_signal_perf_global.tap])
 398 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_perf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_signal_perf_percpu.tap])
 399 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_perf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_signal_perf_perthread.tap])
 400 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_rperf_global.tap], [chmod +x tests/regression/rcutorture_urcu_signal_rperf_global.tap])
 401 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_rperf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_signal_rperf_percpu.tap])
 402 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_rperf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_signal_rperf_perthread.tap])
 403 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_stress_global.tap], [chmod +x tests/regression/rcutorture_urcu_signal_stress_global.tap])
 404 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_stress_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_signal_stress_percpu.tap])
 405 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_stress_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_signal_stress_perthread.tap])
 406 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_uperf_global.tap], [chmod +x tests/regression/rcutorture_urcu_signal_uperf_global.tap])
 407 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_uperf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_signal_uperf_percpu.tap])
 408 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_uperf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_signal_uperf_perthread.tap])
 409
 410
 411 AC_OUTPUT
 412
 413 #
 414 # Mini-report on what will be built.
 415 #
 416
 417 PPRINT_INIT
 418 PPRINT_SET_INDENT(1)
 419 PPRINT_SET_TS(38)
 420
 421 AS_ECHO
 422 AS_ECHO("${PPRINT_COLOR_BLDBLU}Userspace-RCU $PACKAGE_VERSION${PPRINT_COLOR_RST}")
 423 AS_ECHO
 424
 425 PPRINT_SUBTITLE([Features])
 426
 427 PPRINT_PROP_STRING([Target architecture], $host_cpu)
 428
 429 # SMP support enabled/disabled
 430 test "x$def_smp_support" = "xyes" && value=1 || value=0
 431 PPRINT_PROP_BOOL([SMP support], $value)
 432
 433 # TLS
 434 test "x$def_compiler_tls" = "xyes" && value="compiler TLS" || value="pthread_getspecific()"
 435 PPRINT_PROP_STRING([Thread Local Storage (TLS)], [$value])
 436
 437 # clock_gettime() available
 438 test "x$config_rcu_have_clock_gettime" = "xyes" && value=1 || value=0
 439 PPRINT_PROP_BOOL([clock_gettime()], $value)
 440
 441 # Require membarrier
 442 test "x$def_sys_membarrier_fallback" != "xyes" && value=1 || value=0
 443 PPRINT_PROP_BOOL([Require membarrier], $value)
 444
 445 # RCU debug enabled/disabled
 446 test "x$enable_rcu_debug" = "xyes" && value=1 || value=0
 447 PPRINT_PROP_BOOL([Internal debugging], $value)
 448
 449 # rculfhash iterator debug enabled/disabled
 450 test "x$enable_cds_lfht_iter_debug" = "xyes" && value=1 || value=0
 451 PPRINT_PROP_BOOL([Lock-free hash table iterator debugging], $value)
 452
 453 PPRINT_PROP_BOOL([Multi-flavor support], 1)
 454
 455 report_bindir="`eval eval echo $bindir`"
 456 report_libdir="`eval eval echo $libdir`"
 457
 458 # Print the bindir and libdir this `make install' will install into.
 459 AS_ECHO
 460 PPRINT_SUBTITLE([Install directories])
 461 PPRINT_PROP_STRING([Binaries], [$report_bindir])
 462 PPRINT_PROP_STRING([Libraries], [$report_libdir])
 463