configure.ac

   1 AC_PREREQ(2.59)
   2 AC_INIT([userspace-rcu],[0.9.0],[mathieu dot desnoyers at efficios dot com], [], [http://liburcu.org/])
   3
   4 # Following the numbering scheme proposed by libtool for the library version
   5 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
   6 AC_SUBST([URCU_LIBRARY_VERSION], [5:0:1])
   7
   8 AC_CONFIG_HEADERS([include/config.h include/urcu/config.h])
   9 AC_CONFIG_AUX_DIR([config])
  10 AC_CONFIG_MACRO_DIR([m4])
  11
  12 AC_CANONICAL_TARGET
  13 AC_CANONICAL_HOST
  14
  15 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip nostdinc])
  16 AM_MAINTAINER_MODE([enable])
  17
  18 # Enable silent rules if available (Introduced in AM 1.11)
  19 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  20
  21 AH_TEMPLATE([CONFIG_RCU_SMP], [Enable SMP support. With SMP support enabled, uniprocessors are also supported. With SMP support disabled, UP systems work fine, but the behavior of SMP systems is undefined.])
  22 AH_TEMPLATE([CONFIG_RCU_HAVE_FENCE], [Defined when on a system that has memory fence instructions.])
  23 AH_TEMPLATE([CONFIG_RCU_HAVE_FUTEX], [Defined when on a system with futex support.])
  24 AH_TEMPLATE([CONFIG_RCU_COMPAT_ARCH], [Compatibility mode for i386 which lacks cmpxchg instruction.])
  25 AH_TEMPLATE([CONFIG_RCU_ARM_HAVE_DMB], [Use the dmb instruction if available for use on ARM.])
  26 AH_TEMPLATE([CONFIG_RCU_TLS], [TLS provided by the compiler.])
  27 AH_TEMPLATE([CONFIG_RCU_HAVE_CLOCK_GETTIME], [clock_gettime() is detected.])
  28
  29 # Allow overriding storage used for TLS variables.
  30 AC_ARG_ENABLE([compiler-tls],
  31         AS_HELP_STRING([--disable-compiler-tls], [Use pthread_getspecific() to emulate Thread Local Storage (TLS) variables.]),
  32         [def_compiler_tls=$enableval],
  33         [def_compiler_tls="yes"])
  34
  35 # If not overridden, use ax_tls.m4 to check if TLS is available.
  36 AS_IF([test "x$def_compiler_tls" = "xyes"],
  37         [AX_TLS([def_tls_detect=$ac_cv_tls], [:])],
  38         [:])
  39
  40 AS_IF([test "x$def_tls_detect" = "x"],
  41         [:],
  42         [AC_DEFINE_UNQUOTED([CONFIG_RCU_TLS], $def_tls_detect)])
  43
  44 # Checks for C compiler
  45 AC_USE_SYSTEM_EXTENSIONS
  46 AC_PROG_CC
  47 AC_PROG_CC_STDC
  48
  49 # Checks for programs.
  50 AC_PROG_AWK
  51 AC_PROG_MAKE_SET
  52 AC_CHECK_PROGS(NPROC, [nproc gnproc])
  53 AC_CHECK_PROGS(GETCONF, [getconf])
  54 AS_IF([test "x$NPROC" != "x"],
  55         [NPROC_CMD=$NPROC],
  56         [AS_IF([test "x$GETCONF" != "x"],
  57                 [NPROC_CMD="$GETCONF _NPROCESSORS_ONLN"],
  58                 [NPROC_CMD="echo 1"]
  59         )]
  60 )
  61 AC_SUBST([NPROC_CMD], [$NPROC_CMD])
  62
  63 LT_INIT
  64
  65 # Checks for typedefs, structures, and compiler characteristics.
  66 AC_C_INLINE
  67 AC_TYPE_PID_T
  68 AC_TYPE_SIZE_T
  69 AC_TYPE_SSIZE_T
  70 AC_TYPE_UINT16_T
  71 AC_TYPE_INT32_T
  72 AC_TYPE_UINT32_T
  73 AC_TYPE_UINT64_T
  74 AC_TYPE_UINT8_T
  75
  76 AX_C___ATTRIBUTE__
  77 AS_IF([test "x$ax_cv___attribute__" = "xyes"],
  78         [:],
  79         [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
  80
  81 AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])
  82 LIBS="$PTHREAD_LIBS $LIBS"
  83 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
  84 CC="$PTHREAD_CC"
  85
  86 # Checks for library functions.
  87 AC_FUNC_MALLOC
  88 AC_FUNC_MMAP
  89 AC_FUNC_FORK
  90 AC_CHECK_FUNCS([ \
  91         atexit \
  92         getcpuid \
  93         gettid \
  94         gettimeofday \
  95         memeset \
  96         memset \
  97         munmap \
  98         sched_getcpu \
  99         strerror \
 100         strtoul \
 101         sysconf \
 102 ])
 103
 104 # Check for headers
 105 AC_HEADER_STDBOOL
 106 AC_CHECK_HEADERS([ \
 107         limits.h \
 108         stddef.h \
 109         sys/param.h \
 110         sys/time.h \
 111 ])
 112
 113 # Find arch type
 114 AS_CASE([$host_cpu],
 115         [k1om], [ARCHTYPE="x86"],
 116         [i386], [ARCHTYPE="x86" && SUBARCHTYPE="x86compat"],
 117         [i486], [ARCHTYPE="x86"],
 118         [i586], [ARCHTYPE="x86"],
 119         [i686], [ARCHTYPE="x86"],
 120         [amd64], [ARCHTYPE="x86"],
 121         [x86_64], [ARCHTYPE="x86"],
 122         [powerpc], [ARCHTYPE="ppc"],
 123         [ppc64], [ARCHTYPE="ppc"],
 124         [powerpc64], [ARCHTYPE="ppc"],
 125         [powerpc64le], [ARCHTYPE="ppc"],
 126         [ppc], [ARCHTYPE="ppc"],
 127         [s390], [ARCHTYPE="s390"],
 128         [s390x], [ARCHTYPE="s390"],
 129         [sparc], [ARCHTYPE="sparc64"],
 130         [sparc64], [ARCHTYPE="sparc64"],
 131         [alpha*], [ARCHTYPE="alpha"],
 132         [ia64], [ARCHTYPE="ia64"],
 133         [arm*], [ARCHTYPE="arm"],
 134         [aarch64*], [ARCHTYPE="aarch64"],
 135         [mips*], [ARCHTYPE="mips"],
 136         [nios2*], [ARCHTYPE="nios2"],
 137         [tile*], [ARCHTYPE="tile"],
 138         [hppa*], [ARCHTYPE="hppa"],
 139         [ARCHTYPE="unknown"]
 140 )
 141
 142 AS_CASE([$host],[*-cygwin*],
 143         [AM_CONDITIONAL(USE_CYGWIN, true)],
 144         [AM_CONDITIONAL(USE_CYGWIN, false)]
 145 )
 146
 147 AC_SUBST(ARCHTYPE)
 148 AC_SUBST(SUBARCHTYPE)
 149
 150 UATOMICSRC=include/urcu/uatomic/$ARCHTYPE.h
 151 ARCHSRC=include/urcu/arch/$ARCHTYPE.h
 152
 153 AS_IF([test "x$SUBARCHTYPE" = xx86compat],[
 154         AC_DEFINE([CONFIG_RCU_COMPAT_ARCH], [1])
 155 ])
 156
 157 AS_IF([test "$host_cpu" = "armv7l"],[
 158         CFLAGS="$CFLAGS -mcpu=cortex-a9 -mtune=cortex-a9 -O1"
 159 ])
 160
 161 # ARM-specific checks
 162 AS_IF([test "x$ARCHTYPE" = "xarm"],[
 163         AC_MSG_CHECKING([for dmb instruction])
 164         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 165                                 int main()
 166                                 {
 167                                         asm volatile("dmb":::"memory");
 168                                         return 0;
 169                                 }
 170                 ]])
 171         ],[
 172                 AC_MSG_RESULT([yes])
 173                 AC_DEFINE([CONFIG_RCU_ARM_HAVE_DMB], [1])
 174         ],[
 175                 AC_MSG_RESULT([no])
 176         ])
 177 ])
 178
 179 # Tile-specific checks
 180 AS_IF([echo "$host_cpu" | grep "^tile"],[
 181         AC_MSG_CHECKING([for Tile architecture type])
 182         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 183                                 #ifndef __tilegx__
 184                                 #error
 185                                 #endif
 186                 ]])
 187         ],[
 188                 AC_MSG_RESULT([ok])
 189         ],[
 190                 AC_MSG_FAILURE([URCU has only been tested on the TileGx architecture. For other Tile* architectures, please run the tests first and report the results to the maintainer so that proper support can be added.])
 191         ])
 192 ])
 193
 194 # x86-specific checks
 195 AS_IF([test "x$ARCHTYPE" = "xx86"],[
 196         AC_MSG_CHECKING([if architecture really supports the mfence instruction])
 197         #For now, using lock; addl compatibility mode even for i686, because the
 198         #Pentium III is seen as a i686, but lacks mfence instruction.
 199         #Only using fence for x86_64.
 200         #
 201         #k1om is the name for the Intel MIC family (Xeon Phi). It is an x86_64
 202         #variant but lacks fence instructions.
 203         AS_IF([test "x$host_cpu" != "xi386" -a "x$host_cpu" != "xi486" -a "x$host_cpu" != "xi586" -a "x$host_cpu" != "xi686" -a "x$host_vendor" != "xk1om" -a "x$host_cpu" != "xk1om"],[
 204                 AC_MSG_RESULT([yes])
 205                 AC_DEFINE([CONFIG_RCU_HAVE_FENCE], [1])
 206         ],[
 207                 AC_MSG_RESULT([no])
 208         ])
 209 ])
 210
 211 # Check if sys_futex() is available
 212 AC_MSG_CHECKING([for sys_futex()])
 213 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 214                 #include <sys/syscall.h>
 215                 #ifndef __NR_futex
 216                 #error "futexes not available"
 217                 #endif
 218         ]])
 219 ],[
 220         AC_MSG_RESULT([yes])
 221         AC_DEFINE([CONFIG_RCU_HAVE_FUTEX], [1])
 222         compat_futex_test=0
 223 ],[
 224         AC_MSG_RESULT([no])
 225         compat_futex_test=1
 226 ])
 227
 228 # Search for clock_gettime
 229 AC_SEARCH_LIBS([clock_gettime], [rt], [
 230         AC_DEFINE([CONFIG_RCU_HAVE_CLOCK_GETTIME], [1])
 231 ], [])
 232
 233 AM_CONDITIONAL([COMPAT_FUTEX], [test "x$compat_futex_test" = "x1"])
 234 AM_CONDITIONAL([COMPAT_ARCH], [test "x$SUBARCHTYPE" = "xx86compat"])
 235 AM_CONDITIONAL([NO_SHARED], [test "x$enable_shared" = "xno"])
 236
 237 # smp-support configure option
 238 AC_ARG_ENABLE([smp-support],
 239         AS_HELP_STRING([--disable-smp-support], [Disable SMP support. Warning: only use this on uniprocessor systems. [default=enabled]]),
 240         [def_smp_support=$enableval],
 241         [def_smp_support="yes"])
 242 AS_IF([test "x$def_smp_support" = "xyes"], [AC_DEFINE([CONFIG_RCU_SMP], [1])])
 243
 244
 245 # From the sched_setaffinity(2)'s man page:
 246 # ~~~~
 247 # The CPU affinity system calls were introduced in Linux kernel 2.5.8.
 248 # The library interfaces were introduced in glibc 2.3.  Initially, the
 249 # glibc interfaces included a cpusetsize argument.  In glibc 2.3.3,
 250 # the cpuset size argument was removed, but this argument was
 251 # restored in glibc 2.3.4.
 252 # ~~~~
 253
 254 # In addition to that, some vendors ported the system call to 2.4
 255 # kernels.
 256
 257 # Furthermore, when the function first appeared, the MASK argument was
 258 # an unsigned long pointer, while later it was made into a cpu_set_t
 259 # pointer.  Systems that have the cpu_set_t version also should have
 260 # the CPU_ZERO, CPU_SET, etc. macros.
 261
 262 # All this mess means we have to cater for at least 3 different
 263 # sched_setaffinity prototypes:
 264
 265 # ~~~~
 266 #  int sched_setaffinity (pid_t pid, unsigned int len, unsigned long *mask);
 267 #  int sched_setaffinity (pid_t __pid, size_t __cpusetsize, const cpu_set_t *__cpuset);
 268 #  int sched_setaffinity (pid_t __pid, const cpu_set_t *__mask);
 269 # ~~~~
 270
 271 AC_CHECK_TYPES([cpu_set_t],
 272         [have_cpu_set_t="yes"],
 273         [have_cpu_set_t="no"],
 274         [#include <sched.h>])
 275
 276 # Confirm that we have CPU_ZERO, and it actually works.
 277 AC_MSG_CHECKING([whether CPU_ZERO works])
 278 AH_TEMPLATE([HAVE_CPU_ZERO], [Defined to 1 if we have CPU_ZERO and it works])
 279 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 280                 #include <sched.h>
 281                 int main()
 282                 {
 283                         cpu_set_t foo; CPU_ZERO(&foo);
 284                         return 0;
 285                 }
 286         ]])
 287 ],[
 288         AC_DEFINE(HAVE_CPU_ZERO, 1)
 289         AC_MSG_RESULT([yes])
 290 ],[
 291         AC_MSG_RESULT([no])
 292 ])
 293
 294 # Confirm that we have CPU_SET, and it actually works.
 295 AC_MSG_CHECKING([whether CPU_SET works])
 296 AH_TEMPLATE([HAVE_CPU_SET], [Defined to 1 if we have CPU_SET and it works])
 297 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 298                 #include <sched.h>
 299                 int main()
 300                 {
 301                         cpu_set_t foo, mask; CPU_SET(0, &foo);
 302                         return 0;
 303                 }
 304         ]])
 305 ],[
 306         AC_DEFINE(HAVE_CPU_SET, 1)
 307         AC_MSG_RESULT([yes])
 308 ],[
 309         AC_MSG_RESULT([no])
 310 ])
 311
 312 # First check if the function is available at all.
 313 AC_CHECK_FUNCS([sched_setaffinity],[
 314         # Okay, we have it.  Check if also have cpu_set_t.  If we don't,
 315         # then we have the first version using unsigned long, and no
 316         # CPU_ZERO, etc. macros.  If we do have cpu_set_t, we may have the
 317         # version with 2 or 3 arguments.  In that case, CPU_ZERO, etc.,
 318         # should also be present, but we confirm nonetheless.
 319
 320         AS_IF([test "x$have_cpu_set_t" = "xyes"], [
 321                 # We do have it.
 322                 # Check how many arguments does sched_setaffinity take.
 323                 # Should be 3 or 2.
 324                 AC_MSG_CHECKING([how many arguments sched_setaffinity takes])
 325                 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 326                                 #include <sched.h>
 327                                 int main()
 328                                 {
 329                                         cpu_set_t foo;
 330                                         sched_setaffinity(0, sizeof (foo), &foo);
 331                                         return 0;
 332                                 }
 333                         ]])
 334                 ],
 335                 [sched_set_affinity_args=3],
 336                 [sched_set_affinity_args=2])
 337                 AC_DEFINE_UNQUOTED(SCHED_SETAFFINITY_ARGS,
 338                         $sched_set_affinity_args,
 339                         [Defined to sched_setaffinity's number of arguments.])
 340                 AC_MSG_RESULT([$sched_set_affinity_args])
 341         ],[
 342                 # No cpu_set_t, always 3 args.
 343                 AC_DEFINE(SCHED_SETAFFINITY_ARGS, 3)
 344         ])
 345 ])
 346
 347 DEFAULT_INCLUDES="-include config.h"
 348 AC_SUBST(DEFAULT_INCLUDES)
 349
 350 AC_CONFIG_LINKS([
 351         include/urcu/arch.h:$ARCHSRC
 352         include/urcu/uatomic.h:$UATOMICSRC
 353 ])
 354 AC_CONFIG_FILES([
 355         Makefile
 356         doc/Makefile
 357         doc/examples/Makefile
 358         include/Makefile
 359         src/Makefile
 360         tests/Makefile
 361         tests/common/Makefile
 362         tests/unit/Makefile
 363         tests/benchmark/Makefile
 364         tests/regression/Makefile
 365         tests/regression/regression_tests
 366         tests/utils/Makefile
 367         src/liburcu.pc
 368         src/liburcu-bp.pc
 369         src/liburcu-cds.pc
 370         src/liburcu-qsbr.pc
 371         src/liburcu-mb.pc
 372         src/liburcu-signal.pc
 373 ])
 374 AC_OUTPUT
 375
 376 # Report on selected configure options
 377 AS_IF([test "x$def_smp_support" = "xyes"],[
 378         AS_ECHO("SMP support enabled.")
 379 ],[
 380         AS_ECHO("SMP support disabled.")
 381 ])
 382
 383 AS_IF([test "x$def_tls_detect" = "x"],[
 384         AS_ECHO("Thread Local Storage (TLS): pthread_getspecific().")
 385 ],[
 386         AS_ECHO("Thread Local Storage (TLS): $def_tls_detect.")
 387 ])