b3096c6d45ca492d781ff35ff059868066fe260b
[urcu.git] / configure.ac
1 AC_PREREQ(2.59)
2 AC_INIT([userspace-rcu],[0.9.0],[mathieu dot desnoyers at efficios dot com], [], [http://liburcu.org/])
3
4 # Following the numbering scheme proposed by libtool for the library version
5 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
6 AC_SUBST([URCU_LIBRARY_VERSION], [4:0:0])
7
8 AC_CONFIG_SRCDIR([urcu.h])
9 AC_CONFIG_HEADERS([config.h urcu/config.h])
10 AC_CONFIG_AUX_DIR([config])
11 AC_CONFIG_MACRO_DIR([m4])
12
13 AC_CANONICAL_TARGET
14 AC_CANONICAL_HOST
15
16 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
17 AM_MAINTAINER_MODE([enable])
18
19 # Enable silent rules if available (Introduced in AM 1.11)
20 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
21
22 AH_TEMPLATE([CONFIG_RCU_SMP], [Enable SMP support. With SMP support enabled, uniprocessors are also supported. With SMP support disabled, UP systems work fine, but the behavior of SMP systems is undefined.])
23 AH_TEMPLATE([CONFIG_RCU_HAVE_FENCE], [Defined when on a system that has memory fence instructions.])
24 AH_TEMPLATE([CONFIG_RCU_HAVE_FUTEX], [Defined when on a system with futex support.])
25 AH_TEMPLATE([CONFIG_RCU_COMPAT_ARCH], [Compatibility mode for i386 which lacks cmpxchg instruction.])
26 AH_TEMPLATE([CONFIG_RCU_ARM_HAVE_DMB], [Use the dmb instruction if available for use on ARM.])
27 AH_TEMPLATE([CONFIG_RCU_TLS], [TLS provided by the compiler.])
28
29 # Allow overriding storage used for TLS variables.
30 AC_ARG_ENABLE([compiler-tls],
31 AS_HELP_STRING([--disable-compiler-tls], [Use pthread_getspecific() to emulate Thread Local Storage (TLS) variables.]),
32 [def_compiler_tls=$enableval],
33 [def_compiler_tls="yes"])
34
35 # If not overridden, use ax_tls.m4 to check if TLS is available.
36 AS_IF([test "x$def_compiler_tls" = "xyes"],
37 [AX_TLS([def_tls_detect=$ac_cv_tls], [:])],
38 [:])
39
40 AS_IF([test "x$def_tls_detect" = "x"],
41 [:],
42 [AC_DEFINE_UNQUOTED([CONFIG_RCU_TLS], $def_tls_detect)])
43
44 # Checks for C compiler
45 AC_USE_SYSTEM_EXTENSIONS
46 AC_PROG_CC
47 AC_PROG_CC_STDC
48
49 # Checks for programs.
50 AC_PROG_AWK
51 AC_PROG_MAKE_SET
52 AC_CHECK_PROGS(NPROC, [nproc gnproc])
53 LT_INIT
54
55 # Checks for typedefs, structures, and compiler characteristics.
56 AC_C_INLINE
57 AC_TYPE_PID_T
58 AC_TYPE_SIZE_T
59 AC_TYPE_SSIZE_T
60 AC_TYPE_UINT16_T
61 AC_TYPE_INT32_T
62 AC_TYPE_UINT32_T
63 AC_TYPE_UINT64_T
64 AC_TYPE_UINT8_T
65
66 AX_C___ATTRIBUTE__
67 AS_IF([test "x$ax_cv___attribute__" = "xyes"],
68 [:],
69 [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
70
71 AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])
72 LIBS="$PTHREAD_LIBS $LIBS"
73 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
74 CC="$PTHREAD_CC"
75
76 # Checks for library functions.
77 AC_FUNC_MALLOC
78 AC_FUNC_MMAP
79 AC_FUNC_FORK
80 AC_CHECK_FUNCS([ \
81 atexit \
82 getcpuid \
83 gettid \
84 gettimeofday \
85 memeset \
86 memset \
87 munmap \
88 sched_getcpu \
89 strerror \
90 strtoul \
91 sysconf \
92 ])
93
94 # Check for headers
95 AC_HEADER_STDBOOL
96 AC_CHECK_HEADERS([ \
97 limits.h \
98 stddef.h \
99 sys/param.h \
100 sys/time.h \
101 ])
102
103 # Find arch type
104 AS_CASE([$host_cpu],
105 [k1om], [ARCHTYPE="x86"],
106 [i386], [ARCHTYPE="x86" && SUBARCHTYPE="x86compat"],
107 [i486], [ARCHTYPE="x86"],
108 [i586], [ARCHTYPE="x86"],
109 [i686], [ARCHTYPE="x86"],
110 [amd64], [ARCHTYPE="x86"],
111 [x86_64], [ARCHTYPE="x86"],
112 [powerpc], [ARCHTYPE="ppc"],
113 [ppc64], [ARCHTYPE="ppc"],
114 [powerpc64], [ARCHTYPE="ppc"],
115 [powerpc64le], [ARCHTYPE="ppc"],
116 [ppc], [ARCHTYPE="ppc"],
117 [s390], [ARCHTYPE="s390"],
118 [s390x], [ARCHTYPE="s390"],
119 [sparc], [ARCHTYPE="sparc64"],
120 [sparc64], [ARCHTYPE="sparc64"],
121 [alpha*], [ARCHTYPE="alpha"],
122 [ia64], [ARCHTYPE="ia64"],
123 [arm*], [ARCHTYPE="arm"],
124 [aarch64*], [ARCHTYPE="aarch64"],
125 [mips*], [ARCHTYPE="mips"],
126 [nios2*], [ARCHTYPE="nios2"],
127 [tile*], [ARCHTYPE="tile"],
128 [hppa*], [ARCHTYPE="hppa"],
129 [ARCHTYPE="unknown"]
130 )
131
132 AS_CASE([$host],[*-*-linux-androideabi],
133 [AM_CONDITIONAL(TARGET_IS_ANDROID, true)],
134 [AM_CONDITIONAL(TARGET_IS_ANDROID, false)]
135 )
136
137 AS_CASE([$host],[*-cygwin*],
138 [AM_CONDITIONAL(USE_CYGWIN, true)],
139 [AM_CONDITIONAL(USE_CYGWIN, false)]
140 )
141
142 AC_SUBST(ARCHTYPE)
143 AC_SUBST(SUBARCHTYPE)
144
145 UATOMICSRC=urcu/uatomic/$ARCHTYPE.h
146 ARCHSRC=urcu/arch/$ARCHTYPE.h
147
148 AS_IF([test "x$SUBARCHTYPE" = xx86compat],[
149 AC_DEFINE([CONFIG_RCU_COMPAT_ARCH], [1])
150 ])
151
152 AS_IF([test "$host_cpu" = "armv7l"],[
153 CFLAGS="$CFLAGS -mcpu=cortex-a9 -mtune=cortex-a9 -O1"
154 ])
155
156 # ARM-specific checks
157 AS_IF([test "x$ARCHTYPE" = "xarm"],[
158 AC_MSG_CHECKING([for dmb instruction])
159 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
160 int main()
161 {
162 asm volatile("dmb":::"memory");
163 return 0;
164 }
165 ]])
166 ],[
167 AC_MSG_RESULT([yes])
168 AC_DEFINE([CONFIG_RCU_ARM_HAVE_DMB], [1])
169 ],[
170 AC_MSG_RESULT([no])
171 ])
172 ])
173
174 # Tile-specific checks
175 AS_IF([echo "$host_cpu" | grep "^tile"],[
176 AC_MSG_CHECKING([for Tile architecture type])
177 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
178 #ifndef __tilegx__
179 #error
180 #endif
181 ]])
182 ],[
183 AC_MSG_RESULT([ok])
184 ],[
185 AC_MSG_FAILURE([URCU has only been tested on the TileGx architecture. For other Tile* architectures, please run the tests first and report the results to the maintainer so that proper support can be added.])
186 ])
187 ])
188
189 # x86-specific checks
190 AS_IF([test "x$ARCHTYPE" = "xx86"],[
191 AC_MSG_CHECKING([if architecture really supports the mfence instruction])
192 #For now, using lock; addl compatibility mode even for i686, because the
193 #Pentium III is seen as a i686, but lacks mfence instruction.
194 #Only using fence for x86_64.
195 #
196 #k1om is the name for the Intel MIC family (Xeon Phi). It is an x86_64
197 #variant but lacks fence instructions.
198 AS_IF([test "x$host_cpu" != "xi386" -a "x$host_cpu" != "xi486" -a "x$host_cpu" != "xi586" -a "x$host_cpu" != "xi686" -a "x$host_vendor" != "xk1om" -a "x$host_cpu" != "xk1om"],[
199 AC_MSG_RESULT([yes])
200 AC_DEFINE([CONFIG_RCU_HAVE_FENCE], [1])
201 ],[
202 AC_MSG_RESULT([no])
203 ])
204 ])
205
206 # Check if sys_futex() is available
207 AC_MSG_CHECKING([for sys_futex()])
208 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
209 #include <sys/syscall.h>
210 #ifndef __NR_futex
211 #error "futexes not available"
212 #endif
213 ]])
214 ],[
215 AC_MSG_RESULT([yes])
216 AC_DEFINE([CONFIG_RCU_HAVE_FUTEX], [1])
217 compat_futex_test=0
218 ],[
219 AC_MSG_RESULT([no])
220 compat_futex_test=1
221 ])
222
223 # Search for clock_gettime
224 AC_SEARCH_LIBS([clock_gettime], [rt], [],
225 [AC_MSG_ERROR([Cannot find clock_gettime function.])]
226 )
227
228 # Check for pthread
229 AC_CHECK_LIB([pthread], [pthread_create],
230 [AM_CONDITIONAL(LIBC_INCLUDES_PTHREAD, false)],
231 [AC_CHECK_LIB([c], [pthread_create],
232 [AM_CONDITIONAL(LIBC_INCLUDES_PTHREAD, true)],
233 [AC_MSG_ERROR([Cannot find libpthread. Use [LDFLAGS]=-Ldir to specify its location.])]
234 )]
235 )
236
237 AM_CONDITIONAL([COMPAT_FUTEX], [test "x$compat_futex_test" = "x1"])
238 AM_CONDITIONAL([COMPAT_ARCH], [test "x$SUBARCHTYPE" = "xx86compat"])
239 AM_CONDITIONAL([NO_SHARED], [test "x$enable_shared" = "xno"])
240
241 # smp-support configure option
242 AC_ARG_ENABLE([smp-support],
243 AS_HELP_STRING([--disable-smp-support], [Disable SMP support. Warning: only use this on uniprocessor systems. [default=enabled]]),
244 [def_smp_support=$enableval],
245 [def_smp_support="yes"])
246 AS_IF([test "x$def_smp_support" = "xyes"], [AC_DEFINE([CONFIG_RCU_SMP], [1])])
247
248
249 # From the sched_setaffinity(2)'s man page:
250 # ~~~~
251 # The CPU affinity system calls were introduced in Linux kernel 2.5.8.
252 # The library interfaces were introduced in glibc 2.3. Initially, the
253 # glibc interfaces included a cpusetsize argument. In glibc 2.3.3,
254 # the cpuset size argument was removed, but this argument was
255 # restored in glibc 2.3.4.
256 # ~~~~
257
258 # In addition to that, some vendors ported the system call to 2.4
259 # kernels.
260
261 # Furthermore, when the function first appeared, the MASK argument was
262 # an unsigned long pointer, while later it was made into a cpu_set_t
263 # pointer. Systems that have the cpu_set_t version also should have
264 # the CPU_ZERO, CPU_SET, etc. macros.
265
266 # All this mess means we have to cater for at least 3 different
267 # sched_setaffinity prototypes:
268
269 # ~~~~
270 # int sched_setaffinity (pid_t pid, unsigned int len, unsigned long *mask);
271 # int sched_setaffinity (pid_t __pid, size_t __cpusetsize, const cpu_set_t *__cpuset);
272 # int sched_setaffinity (pid_t __pid, const cpu_set_t *__mask);
273 # ~~~~
274
275 # Since we define _GNU_SOURCE in the sources, must do so too in the
276 # autoconf tests, as defining _GNU_SOURCE or not exposes
277 # sched_setaffinity bits differently.
278 saved_CFLAGS=$CFLAGS
279 CFLAGS="$CFLAGS -D_GNU_SOURCE"
280
281 AC_CHECK_TYPES([cpu_set_t],
282 [have_cpu_set_t="yes"],
283 [have_cpu_set_t="no"],
284 [#include <sched.h>])
285
286 # Confirm that we have CPU_ZERO, and it actually works.
287 AC_MSG_CHECKING([whether CPU_ZERO works])
288 AH_TEMPLATE([HAVE_CPU_ZERO], [Defined to 1 if we have CPU_ZERO and it works])
289 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
290 #define _GNU_SOURCE
291 #include <sched.h>
292 int main()
293 {
294 cpu_set_t foo; CPU_ZERO(&foo);
295 return 0;
296 }
297 ]])
298 ],[
299 AC_DEFINE(HAVE_CPU_ZERO, 1)
300 AC_MSG_RESULT([yes])
301 ],[
302 AC_MSG_RESULT([no])
303 ])
304
305 # Confirm that we have CPU_SET, and it actually works.
306 AC_MSG_CHECKING([whether CPU_SET works])
307 AH_TEMPLATE([HAVE_CPU_SET], [Defined to 1 if we have CPU_SET and it works])
308 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
309 #define _GNU_SOURCE
310 #include <sched.h>
311 int main()
312 {
313 cpu_set_t foo, mask; CPU_SET(0, &foo);
314 return 0;
315 }
316 ]])
317 ],[
318 AC_DEFINE(HAVE_CPU_SET, 1)
319 AC_MSG_RESULT([yes])
320 ],[
321 AC_MSG_RESULT([no])
322 ])
323
324 # First check if the function is available at all.
325 AC_CHECK_FUNCS([sched_setaffinity],[
326 # Okay, we have it. Check if also have cpu_set_t. If we don't,
327 # then we have the first version using unsigned long, and no
328 # CPU_ZERO, etc. macros. If we do have cpu_set_t, we may have the
329 # version with 2 or 3 arguments. In that case, CPU_ZERO, etc.,
330 # should also be present, but we confirm nonetheless.
331
332 AS_IF([test "x$have_cpu_set_t" = "xyes"], [
333 # We do have it.
334 # Check how many arguments does sched_setaffinity take.
335 # Should be 3 or 2.
336 AC_MSG_CHECKING([how many arguments sched_setaffinity takes])
337 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
338 #include <sched.h>
339 int main()
340 {
341 cpu_set_t foo;
342 sched_setaffinity(0, sizeof (foo), &foo);
343 return 0;
344 }
345 ]])
346 ],
347 [sched_set_affinity_args=3],
348 [sched_set_affinity_args=2])
349 AC_DEFINE_UNQUOTED(SCHED_SETAFFINITY_ARGS,
350 $sched_set_affinity_args,
351 [Defined to sched_setaffinity's number of arguments.])
352 AC_MSG_RESULT([$sched_set_affinity_args])
353 ],[
354 # No cpu_set_t, always 3 args.
355 AC_DEFINE(SCHED_SETAFFINITY_ARGS, 3)
356 ])
357 ])
358
359 CFLAGS=$saved_CFLAGS
360
361 AC_CONFIG_LINKS([
362 urcu/arch.h:$ARCHSRC
363 urcu/uatomic.h:$UATOMICSRC
364 ])
365 AC_CONFIG_FILES([
366 Makefile
367 doc/Makefile
368 doc/examples/Makefile
369 tests/Makefile
370 tests/common/Makefile
371 tests/unit/Makefile
372 tests/benchmark/Makefile
373 tests/regression/Makefile
374 tests/regression/regression_tests
375 tests/utils/Makefile
376 liburcu.pc
377 liburcu-bp.pc
378 liburcu-cds.pc
379 liburcu-qsbr.pc
380 liburcu-mb.pc
381 liburcu-signal.pc
382 ])
383 AC_OUTPUT
384
385 # Report on selected configure options
386 AS_IF([test "x$def_smp_support" = "xyes"],[
387 AS_ECHO("SMP support enabled.")
388 ],[
389 AS_ECHO("SMP support disabled.")
390 ])
391
392 AS_IF([test "x$def_tls_detect" = "x"],[
393 AS_ECHO("Thread Local Storage (TLS): pthread_getspecific().")
394 ],[
395 AS_ECHO("Thread Local Storage (TLS): $def_tls_detect.")
396 ])
This page took 0.054517 seconds and 4 git commands to generate.