Android: implement rand_r()
[urcu.git] / configure.ac
1 # -*- Autoconf -*-
2 # Process this file with autoconf to produce a configure script.
3
4
5 AC_INIT([userspace-rcu],[0.8.0],[mathieu dot desnoyers at efficios dot com])
6
7 # Following the numbering scheme proposed by libtool for the library version
8 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
9 AC_SUBST([URCU_LIBRARY_VERSION], [3:0:0])
10
11 AC_CONFIG_AUX_DIR([config])
12 AC_CONFIG_MACRO_DIR([config])
13 AC_CANONICAL_TARGET
14 AC_CANONICAL_HOST
15 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
16 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
17
18 m4_include([config/ax_tls.m4])
19
20 AC_CONFIG_SRCDIR([urcu.h])
21
22 AC_CONFIG_HEADERS([config.h urcu/config.h])
23
24 AH_TEMPLATE([CONFIG_RCU_SMP], [Enable SMP support. With SMP support enabled, uniprocessors are also supported. With SMP support disabled, UP systems work fine, but the behavior of SMP systems is undefined.])
25 AH_TEMPLATE([CONFIG_RCU_HAVE_FENCE], [Defined when on a system that has memory fence instructions.])
26 AH_TEMPLATE([CONFIG_RCU_HAVE_FUTEX], [Defined when on a system with futex support.])
27 AH_TEMPLATE([CONFIG_RCU_COMPAT_ARCH], [Compatibility mode for i386 which lacks cmpxchg instruction.])
28 AH_TEMPLATE([CONFIG_RCU_ARM_HAVE_DMB], [Use the dmb instruction if available for use on ARM.])
29 AH_TEMPLATE([CONFIG_RCU_TLS], [TLS provided by the compiler.])
30
31 # Allow overriding storage used for TLS variables.
32 AC_ARG_ENABLE([compiler-tls],
33 AS_HELP_STRING([--disable-compiler-tls], [Use pthread_getspecific() to emulate Thread Local Storage (TLS) variables.]),
34 [def_compiler_tls=$enableval],
35 [def_compiler_tls="yes"])
36
37 # If not overridden, use ax_tls.m4 to check if TLS is available.
38 AS_IF([test "x$def_compiler_tls" = "xyes"],
39 [AX_TLS([def_tls_detect=$ac_cv_tls], [:])],
40 [:])
41
42 AS_IF([test "x$def_tls_detect" = "x"],
43 [:],
44 [AC_DEFINE_UNQUOTED([CONFIG_RCU_TLS], $def_tls_detect)])
45
46 # Checks for programs.
47 AC_PROG_CC
48 AC_PROG_MAKE_SET
49 LT_INIT
50
51 # Checks for typedefs, structures, and compiler characteristics.
52 AC_C_INLINE
53 AC_TYPE_PID_T
54 AC_TYPE_SIZE_T
55
56 # Checks for library functions.
57 AC_FUNC_MALLOC
58 AC_FUNC_MMAP
59 AC_CHECK_FUNCS([bzero gettimeofday munmap sched_getcpu strtoul sysconf])
60
61 # Find arch type
62 AS_CASE([$host_cpu],
63 [i386], [ARCHTYPE="x86" && SUBARCHTYPE="x86compat"],
64 [i486], [ARCHTYPE="x86"],
65 [i586], [ARCHTYPE="x86"],
66 [i686], [ARCHTYPE="x86"],
67 [amd64], [ARCHTYPE="x86"],
68 [x86_64], [ARCHTYPE="x86"],
69 [powerpc], [ARCHTYPE="ppc"],
70 [ppc64], [ARCHTYPE="ppc"],
71 [powerpc64], [ARCHTYPE="ppc"],
72 [ppc], [ARCHTYPE="ppc"],
73 [s390], [ARCHTYPE="s390"],
74 [s390x], [ARCHTYPE="s390"],
75 [sparc], [ARCHTYPE="sparc64"],
76 [sparc64], [ARCHTYPE="sparc64"],
77 [alpha*], [ARCHTYPE="alpha"],
78 [ia64], [ARCHTYPE="gcc"],
79 [arm*], [ARCHTYPE="arm"],
80 [mips*], [ARCHTYPE="mips"],
81 [tile*], [ARCHTYPE="gcc"],
82 [ARCHTYPE="unknown"]
83 )
84
85 AS_CASE([$host],[*-*-linux-androideabi],
86 [AM_CONDITIONAL(TARGET_IS_ANDROID, true)],
87 [AM_CONDITIONAL(TARGET_IS_ANDROID, false)]
88 )
89
90 AC_SUBST(ARCHTYPE)
91 AC_SUBST(SUBARCHTYPE)
92
93 UATOMICSRC=urcu/uatomic/$ARCHTYPE.h
94 ARCHSRC=urcu/arch/$ARCHTYPE.h
95
96 AS_IF([test "x$SUBARCHTYPE" = xx86compat],[
97 AC_DEFINE([CONFIG_RCU_COMPAT_ARCH], [1])
98 ])
99
100 AS_IF([test "$host_cpu" = "armv7l"],[
101 CFLAGS="$CFLAGS -mcpu=cortex-a9 -mtune=cortex-a9 -O1"
102 ])
103
104 # ARM-specific checks
105 AS_IF([test "x$ARCHTYPE" = "xarm"],[
106 AC_MSG_CHECKING([for dmb instruction])
107 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
108 int main()
109 {
110 asm volatile("dmb":::"memory");
111 return 0;
112 }
113 ]])
114 ],[
115 AC_MSG_RESULT([yes])
116 AC_DEFINE([CONFIG_RCU_ARM_HAVE_DMB], [1])
117 ],[
118 AC_MSG_RESULT([no])
119 ])
120 ])
121
122 # Tile-specific checks
123 AS_IF([echo "$host_cpu" | grep "^tile"],[
124 AC_MSG_CHECKING([for Tile architecture type])
125 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
126 #ifndef __tilegx__
127 #error
128 #endif
129 ]])
130 ],[
131 AC_MSG_RESULT([ok])
132 ],[
133 AC_MSG_FAILURE([URCU has only been tested on the TileGx architecture. For other Tile* architectures, please run the tests first and report the results to the maintainer so that proper support can be added.])
134 ])
135 ])
136
137 # x86-specific checks
138 AS_IF([test "x$ARCHTYPE" = "xx86"],[
139 AC_MSG_CHECKING([if architecture really supports the mfence instruction])
140 #For now, using lock; addl compatibility mode even for i686, because the
141 #Pentium III is seen as a i686, but lacks mfence instruction.
142 #Only using fence for x86_64.
143 AS_IF([test "x$host_cpu" != "xi386" -a "x$host_cpu" != "xi486" -a "x$host_cpu" != "xi586" -a "x$host_cpu" != "xi686"],[
144 AC_MSG_RESULT([yes])
145 AC_DEFINE([CONFIG_RCU_HAVE_FENCE], [1])
146 ],[
147 AC_MSG_RESULT([no])
148 ])
149 ])
150
151 # Check if sys_futex() is available
152 AC_MSG_CHECKING([for sys_futex()])
153 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
154 #include <sys/syscall.h>
155 #ifndef __NR_futex
156 #error "futexes not available"
157 #endif
158 ]])
159 ],[
160 AC_MSG_RESULT([yes])
161 AC_DEFINE([CONFIG_RCU_HAVE_FUTEX], [1])
162 compat_futex_test=0
163 ],[
164 AC_MSG_RESULT([no])
165 compat_futex_test=1
166 ])
167
168 AM_CONDITIONAL([COMPAT_FUTEX], [test "x$compat_futex_test" = "x1"])
169 AM_CONDITIONAL([COMPAT_ARCH], [test "x$SUBARCHTYPE" = "xx86compat"])
170 AM_CONDITIONAL([NO_SHARED], [test "x$enable_shared" = "xno"])
171
172 # smp-support configure option
173 AC_ARG_ENABLE([smp-support],
174 AS_HELP_STRING([--disable-smp-support], [Disable SMP support. Warning: only use this on uniprocessor systems. [default=enabled]]),
175 [def_smp_support=$enableval],
176 [def_smp_support="yes"])
177 AS_IF([test "x$def_smp_support" = "xyes"], [AC_DEFINE([CONFIG_RCU_SMP], [1])])
178
179
180 # From the sched_setaffinity(2)'s man page:
181 # ~~~~
182 # The CPU affinity system calls were introduced in Linux kernel 2.5.8.
183 # The library interfaces were introduced in glibc 2.3. Initially, the
184 # glibc interfaces included a cpusetsize argument. In glibc 2.3.3,
185 # the cpuset size argument was removed, but this argument was
186 # restored in glibc 2.3.4.
187 # ~~~~
188
189 # In addition to that, some vendors ported the system call to 2.4
190 # kernels.
191
192 # Furthermore, when the function first appeared, the MASK argument was
193 # an unsigned long pointer, while later it was made into a cpu_set_t
194 # pointer. Systems that have the cpu_set_t version also should have
195 # the CPU_ZERO, CPU_SET, etc. macros.
196
197 # All this mess means we have to cater for at least 3 different
198 # sched_setaffinity prototypes:
199
200 # ~~~~
201 # int sched_setaffinity (pid_t pid, unsigned int len, unsigned long *mask);
202 # int sched_setaffinity (pid_t __pid, size_t __cpusetsize, const cpu_set_t *__cpuset);
203 # int sched_setaffinity (pid_t __pid, const cpu_set_t *__mask);
204 # ~~~~
205
206 # Since we define _GNU_SOURCE in the sources, must do so too in the
207 # autoconf tests, as defining _GNU_SOURCE or not exposes
208 # sched_setaffinity bits differently.
209 saved_CFLAGS=$CFLAGS
210 CFLAGS="$CFLAGS -D_GNU_SOURCE"
211
212 AC_CHECK_TYPES([cpu_set_t],
213 [have_cpu_set_t="yes"],
214 [have_cpu_set_t="no"],
215 [#include <sched.h>])
216
217 # Confirm that we have CPU_ZERO, and it actually works.
218 AC_MSG_CHECKING([whether CPU_ZERO works])
219 AH_TEMPLATE([HAVE_CPU_ZERO], [Defined to 1 if we have CPU_ZERO and it works])
220 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
221 #define _GNU_SOURCE
222 #include <sched.h>
223 int main()
224 {
225 cpu_set_t foo; CPU_ZERO(&foo);
226 return 0;
227 }
228 ]])
229 ],[
230 AC_DEFINE(HAVE_CPU_ZERO, 1)
231 AC_MSG_RESULT([yes])
232 ],[
233 AC_MSG_RESULT([no])
234 ])
235
236 # Confirm that we have CPU_SET, and it actually works.
237 AC_MSG_CHECKING([whether CPU_SET works])
238 AH_TEMPLATE([HAVE_CPU_SET], [Defined to 1 if we have CPU_SET and it works])
239 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
240 #define _GNU_SOURCE
241 #include <sched.h>
242 int main()
243 {
244 cpu_set_t foo, mask; CPU_SET(0, &foo);
245 return 0;
246 }
247 ]])
248 ],[
249 AC_DEFINE(HAVE_CPU_SET, 1)
250 AC_MSG_RESULT([yes])
251 ],[
252 AC_MSG_RESULT([no])
253 ])
254
255 # First check if the function is available at all.
256 AC_CHECK_FUNCS([sched_setaffinity],[
257 # Okay, we have it. Check if also have cpu_set_t. If we don't,
258 # then we have the first version using unsigned long, and no
259 # CPU_ZERO, etc. macros. If we do have cpu_set_t, we may have the
260 # version with 2 or 3 arguments. In that case, CPU_ZERO, etc.,
261 # should also be present, but we confirm nonetheless.
262
263 AS_IF([test "x$have_cpu_set_t" = "xyes"], [
264 # We do have it.
265 # Check how many arguments does sched_setaffinity take.
266 # Should be 3 or 2.
267 AC_MSG_CHECKING([how many arguments sched_setaffinity takes])
268 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
269 #include <sched.h>
270 int main()
271 {
272 cpu_set_t foo;
273 sched_setaffinity(0, sizeof (foo), &foo);
274 return 0;
275 }
276 ]])
277 ],
278 [sched_set_affinity_args=3],
279 [sched_set_affinity_args=2])
280 AC_DEFINE_UNQUOTED(SCHED_SETAFFINITY_ARGS,
281 $sched_set_affinity_args,
282 [Defined to sched_setaffinity's number of arguments.])
283 AC_MSG_RESULT([$sched_set_affinity_args])
284 ],[
285 # No cpu_set_t, always 3 args.
286 AC_DEFINE(SCHED_SETAFFINITY_ARGS, 3)
287 ])
288 ])
289
290 CFLAGS=$saved_CFLAGS
291
292 AC_CONFIG_LINKS([
293 urcu/arch.h:$ARCHSRC
294 urcu/uatomic.h:$UATOMICSRC
295 ])
296 AC_CONFIG_FILES([
297 Makefile
298 doc/Makefile
299 doc/examples/Makefile
300 tests/Makefile
301 tests/common/Makefile
302 tests/unit/Makefile
303 tests/benchmark/Makefile
304 tests/regression/Makefile
305 liburcu.pc
306 liburcu-bp.pc
307 liburcu-cds.pc
308 liburcu-qsbr.pc
309 liburcu-mb.pc
310 liburcu-signal.pc
311 ])
312 AC_OUTPUT
313
314 # Report on selected configure options
315 AS_IF([test "x$def_smp_support" = "xyes"],[
316 AS_ECHO("SMP support enabled.")
317 ],[
318 AS_ECHO("SMP support disabled.")
319 ])
320
321 AS_IF([test "x$def_tls_detect" = "x"],[
322 AS_ECHO("Thread Local Storage (TLS): pthread_getspecific().")
323 ],[
324 AS_ECHO("Thread Local Storage (TLS): $def_tls_detect.")
325 ])
This page took 0.034822 seconds and 4 git commands to generate.