configure.ac

   1 AC_PREREQ(2.59)
   2 AC_INIT([userspace-rcu],[0.11.0-pre],[mathieu dot desnoyers at efficios dot com], [], [http://liburcu.org/])
   3
   4 # Following the numbering scheme proposed by libtool for the library version
   5 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
   6 AC_SUBST([URCU_LIBRARY_VERSION], [6:0:0])
   7
   8 AC_CONFIG_HEADERS([include/config.h include/urcu/config.h])
   9 AC_CONFIG_AUX_DIR([config])
  10 AC_CONFIG_MACRO_DIR([m4])
  11
  12 AC_CANONICAL_TARGET
  13 AC_CANONICAL_HOST
  14
  15 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip nostdinc])
  16 AM_MAINTAINER_MODE([enable])
  17
  18 # Enable silent rules if available (Introduced in AM 1.11)
  19 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  20
  21 AC_REQUIRE_AUX_FILE([tap-driver.sh])
  22
  23 AH_TEMPLATE([CONFIG_RCU_SMP], [Enable SMP support. With SMP support enabled, uniprocessors are also supported. With SMP support disabled, UP systems work fine, but the behavior of SMP systems is undefined.])
  24 AH_TEMPLATE([CONFIG_RCU_HAVE_FENCE], [Defined when on a system that has memory fence instructions.])
  25 AH_TEMPLATE([CONFIG_RCU_HAVE_FUTEX], [Defined when on a system with futex support.])
  26 AH_TEMPLATE([CONFIG_RCU_COMPAT_ARCH], [Compatibility mode for i386 which lacks cmpxchg instruction.])
  27 AH_TEMPLATE([CONFIG_RCU_ARM_HAVE_DMB], [Use the dmb instruction if available for use on ARM.])
  28 AH_TEMPLATE([CONFIG_RCU_TLS], [TLS provided by the compiler.])
  29 AH_TEMPLATE([CONFIG_RCU_HAVE_CLOCK_GETTIME], [clock_gettime() is detected.])
  30 AH_TEMPLATE([CONFIG_RCU_FORCE_SYS_MEMBARRIER], [Require the operating system to support the membarrier system call for default and bulletproof flavors.])
  31 AH_TEMPLATE([CONFIG_RCU_DEBUG], [Enable internal debugging self-checks. Introduce performance penalty.])
  32
  33 # Allow requiring the operating system to support the membarrier system
  34 # call. Applies to default and bulletproof flavors.
  35 AC_ARG_ENABLE([sys-membarrier-fallback],
  36         AS_HELP_STRING([--disable-sys-membarrier-fallback], [Abort if sys-membarrier is needed but not available rather than using a fallback.]),
  37         [def_sys_membarrier_fallback=$enableval],
  38         [def_sys_membarrier_fallback="yes"])
  39 AS_IF([test "x$def_sys_membarrier_fallback" != "xyes"], [AC_DEFINE([CONFIG_RCU_FORCE_SYS_MEMBARRIER], [1])])
  40
  41 # Allow overriding storage used for TLS variables.
  42 AC_ARG_ENABLE([compiler-tls],
  43         AS_HELP_STRING([--disable-compiler-tls], [Use pthread_getspecific() to emulate Thread Local Storage (TLS) variables.]),
  44         [def_compiler_tls=$enableval],
  45         [def_compiler_tls="yes"])
  46
  47 # If not overridden, use ax_tls.m4 to check if TLS is available.
  48 AS_IF([test "x$def_compiler_tls" = "xyes"],
  49         [AX_TLS([def_tls_detect=$ac_cv_tls], [:])],
  50         [:])
  51
  52 AS_IF([test "x$def_tls_detect" = "x"],
  53         [:],
  54         [AC_DEFINE_UNQUOTED([CONFIG_RCU_TLS], $def_tls_detect)])
  55
  56 # Checks for C compiler
  57 AC_USE_SYSTEM_EXTENSIONS
  58 AC_PROG_CC
  59 AC_PROG_CC_STDC
  60
  61 # Checks for programs.
  62 AC_PROG_AWK
  63 AC_PROG_MAKE_SET
  64 AC_CHECK_PROGS(NPROC, [nproc gnproc])
  65 AC_CHECK_PROGS(GETCONF, [getconf])
  66 AS_IF([test "x$NPROC" != "x"],
  67         [NPROC_CMD=$NPROC],
  68         [AS_IF([test "x$GETCONF" != "x"],
  69                 [NPROC_CMD="$GETCONF _NPROCESSORS_ONLN"],
  70                 [NPROC_CMD="echo 1"]
  71         )]
  72 )
  73 AC_SUBST([NPROC_CMD], [$NPROC_CMD])
  74
  75 LT_INIT
  76
  77 # Checks for typedefs, structures, and compiler characteristics.
  78 AC_C_INLINE
  79 AC_TYPE_PID_T
  80 AC_TYPE_SIZE_T
  81 AC_TYPE_SSIZE_T
  82 AC_TYPE_UINT16_T
  83 AC_TYPE_INT32_T
  84 AC_TYPE_UINT32_T
  85 AC_TYPE_UINT64_T
  86 AC_TYPE_UINT8_T
  87
  88 AX_C___ATTRIBUTE__
  89 AS_IF([test "x$ax_cv___attribute__" = "xyes"],
  90         [:],
  91         [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
  92
  93 AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])
  94
  95 AM_CFLAGS="$AM_CFLAGS $PTHREAD_CFLAGS"
  96
  97 # Checks for library functions.
  98 AC_FUNC_MMAP
  99 AC_FUNC_FORK
 100 AC_CHECK_FUNCS([ \
 101         atexit \
 102         getcpuid \
 103         gettid \
 104         gettimeofday \
 105         memeset \
 106         memset \
 107         munmap \
 108         rand_r \
 109         sched_getcpu \
 110         strerror \
 111         strtoul \
 112         sysconf \
 113 ])
 114
 115 # AC_FUNC_MALLOC causes problems when cross-compiling.
 116 #AC_FUNC_MALLOC
 117
 118 # Check for headers
 119 AC_HEADER_STDBOOL
 120 AC_CHECK_HEADERS([ \
 121         limits.h \
 122         stddef.h \
 123         sys/param.h \
 124         sys/time.h \
 125 ])
 126
 127 # Find arch type
 128 AS_CASE([$host_cpu],
 129         [k1om], [ARCHTYPE="x86"],
 130         [i386], [ARCHTYPE="x86" && SUBARCHTYPE="x86compat"],
 131         [i486], [ARCHTYPE="x86"],
 132         [i586], [ARCHTYPE="x86"],
 133         [i686], [ARCHTYPE="x86"],
 134         [amd64], [ARCHTYPE="x86"],
 135         [x86_64], [ARCHTYPE="x86"],
 136         [powerpc], [ARCHTYPE="ppc"],
 137         [ppc64], [ARCHTYPE="ppc"],
 138         [powerpc64], [ARCHTYPE="ppc"],
 139         [powerpc64le], [ARCHTYPE="ppc"],
 140         [ppc], [ARCHTYPE="ppc"],
 141         [s390], [ARCHTYPE="s390"],
 142         [s390x], [ARCHTYPE="s390"],
 143         [sparc], [ARCHTYPE="sparc64"],
 144         [sparc64], [ARCHTYPE="sparc64"],
 145         [alpha*], [ARCHTYPE="alpha"],
 146         [ia64], [ARCHTYPE="ia64"],
 147         [arm*], [ARCHTYPE="arm"],
 148         [aarch64*], [ARCHTYPE="aarch64"],
 149         [mips*], [ARCHTYPE="mips"],
 150         [nios2*], [ARCHTYPE="nios2"],
 151         [tile*], [ARCHTYPE="tile"],
 152         [hppa*], [ARCHTYPE="hppa"],
 153         [m68k], [ARCHTYPE="m68k"],
 154         [riscv*], [ARCHTYPE="riscv"],
 155         [ARCHTYPE="unknown"]
 156 )
 157
 158 AS_CASE([$host],[*-cygwin*],
 159         [AM_CONDITIONAL(USE_CYGWIN, true)],
 160         [AM_CONDITIONAL(USE_CYGWIN, false)]
 161 )
 162
 163 AC_SUBST(ARCHTYPE)
 164 AC_SUBST(SUBARCHTYPE)
 165
 166 UATOMICSRC=include/urcu/uatomic/$ARCHTYPE.h
 167 ARCHSRC=include/urcu/arch/$ARCHTYPE.h
 168
 169 AS_IF([test "x$SUBARCHTYPE" = xx86compat],[
 170         AC_DEFINE([CONFIG_RCU_COMPAT_ARCH], [1])
 171 ])
 172
 173 AS_IF([test "$host_cpu" = "armv7l"],[
 174         AM_CFLAGS="$AM_CFLAGS -mcpu=cortex-a9 -mtune=cortex-a9 -O1"
 175 ])
 176
 177 # ARM-specific checks
 178 AS_IF([test "x$ARCHTYPE" = "xarm"],[
 179         AC_MSG_CHECKING([for dmb instruction])
 180         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 181                                 int main()
 182                                 {
 183                                         asm volatile("dmb":::"memory");
 184                                         return 0;
 185                                 }
 186                 ]])
 187         ],[
 188                 AC_MSG_RESULT([yes])
 189                 AC_DEFINE([CONFIG_RCU_ARM_HAVE_DMB], [1])
 190         ],[
 191                 AC_MSG_RESULT([no])
 192         ])
 193 ])
 194
 195 # Tile-specific checks
 196 AS_IF([echo "$host_cpu" | grep "^tile"],[
 197         AC_MSG_CHECKING([for Tile architecture type])
 198         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 199                                 #ifndef __tilegx__
 200                                 #error
 201                                 #endif
 202                 ]])
 203         ],[
 204                 AC_MSG_RESULT([ok])
 205         ],[
 206                 AC_MSG_FAILURE([URCU has only been tested on the TileGx architecture. For other Tile* architectures, please run the tests first and report the results to the maintainer so that proper support can be added.])
 207         ])
 208 ])
 209
 210 # x86-specific checks
 211 AS_IF([test "x$ARCHTYPE" = "xx86"],[
 212         AC_MSG_CHECKING([if architecture really supports the mfence instruction])
 213         #For now, using lock; addl compatibility mode even for i686, because the
 214         #Pentium III is seen as a i686, but lacks mfence instruction.
 215         #Only using fence for x86_64.
 216         #
 217         #k1om is the name for the Intel MIC family (Xeon Phi). It is an x86_64
 218         #variant but lacks fence instructions.
 219         AS_IF([test "x$host_cpu" != "xi386" -a "x$host_cpu" != "xi486" -a "x$host_cpu" != "xi586" -a "x$host_cpu" != "xi686" -a "x$host_vendor" != "xk1om" -a "x$host_cpu" != "xk1om"],[
 220                 AC_MSG_RESULT([yes])
 221                 AC_DEFINE([CONFIG_RCU_HAVE_FENCE], [1])
 222                 config_rcu_have_fence=yes
 223         ],[
 224                 AC_MSG_RESULT([no])
 225                 config_rcu_have_fence=no
 226         ])
 227 ])
 228
 229 # Check if sys_futex() is available
 230 AC_MSG_CHECKING([for sys_futex()])
 231 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 232                 #include <sys/syscall.h>
 233                 #ifndef __NR_futex
 234                 #error "futexes not available"
 235                 #endif
 236         ]])
 237 ],[
 238         AC_MSG_RESULT([yes])
 239         AC_DEFINE([CONFIG_RCU_HAVE_FUTEX], [1])
 240         compat_futex_test=0
 241 ],[
 242         AC_MSG_RESULT([no])
 243         compat_futex_test=1
 244 ])
 245
 246 # Search for clock_gettime
 247 AC_SEARCH_LIBS([clock_gettime], [rt], [
 248         AC_DEFINE([CONFIG_RCU_HAVE_CLOCK_GETTIME], [1])
 249         config_rcu_have_clock_gettime=yes
 250 ], [])
 251
 252 AM_CONDITIONAL([COMPAT_FUTEX], [test "x$compat_futex_test" = "x1"])
 253 AM_CONDITIONAL([COMPAT_ARCH], [test "x$SUBARCHTYPE" = "xx86compat"])
 254 AM_CONDITIONAL([NO_SHARED], [test "x$enable_shared" = "xno"])
 255
 256 # smp-support configure option
 257 AC_ARG_ENABLE([smp-support],
 258         AS_HELP_STRING([--disable-smp-support], [Disable SMP support. Warning: only use this on uniprocessor systems. [default=enabled]]),
 259         [def_smp_support=$enableval],
 260         [def_smp_support="yes"])
 261 AS_IF([test "x$def_smp_support" = "xyes"], [AC_DEFINE([CONFIG_RCU_SMP], [1])])
 262
 263 # RCU debugging option
 264 AC_ARG_ENABLE([rcu-debug],
 265       AS_HELP_STRING([--enable-rcu-debug], [Enable internal debugging
 266                       self-checks. Introduce performance penalty.]))
 267 AS_IF([test "x$enable_rcu_debug" = "xyes"], [
 268        AC_DEFINE([CONFIG_RCU_DEBUG], [1])
 269 ])
 270
 271 # From the sched_setaffinity(2)'s man page:
 272 # ~~~~
 273 # The CPU affinity system calls were introduced in Linux kernel 2.5.8.
 274 # The library interfaces were introduced in glibc 2.3.  Initially, the
 275 # glibc interfaces included a cpusetsize argument.  In glibc 2.3.3,
 276 # the cpuset size argument was removed, but this argument was
 277 # restored in glibc 2.3.4.
 278 # ~~~~
 279
 280 # In addition to that, some vendors ported the system call to 2.4
 281 # kernels.
 282
 283 # Furthermore, when the function first appeared, the MASK argument was
 284 # an unsigned long pointer, while later it was made into a cpu_set_t
 285 # pointer.  Systems that have the cpu_set_t version also should have
 286 # the CPU_ZERO, CPU_SET, etc. macros.
 287
 288 # All this mess means we have to cater for at least 3 different
 289 # sched_setaffinity prototypes:
 290
 291 # ~~~~
 292 #  int sched_setaffinity (pid_t pid, unsigned int len, unsigned long *mask);
 293 #  int sched_setaffinity (pid_t __pid, size_t __cpusetsize, const cpu_set_t *__cpuset);
 294 #  int sched_setaffinity (pid_t __pid, const cpu_set_t *__mask);
 295 # ~~~~
 296
 297 AC_CHECK_TYPES([cpu_set_t],
 298         [have_cpu_set_t="yes"],
 299         [have_cpu_set_t="no"],
 300         [#include <sched.h>])
 301
 302 # Confirm that we have CPU_ZERO, and it actually works.
 303 AC_MSG_CHECKING([whether CPU_ZERO works])
 304 AH_TEMPLATE([HAVE_CPU_ZERO], [Defined to 1 if we have CPU_ZERO and it works])
 305 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 306                 #include <sched.h>
 307                 int main()
 308                 {
 309                         cpu_set_t foo; CPU_ZERO(&foo);
 310                         return 0;
 311                 }
 312         ]])
 313 ],[
 314         AC_DEFINE(HAVE_CPU_ZERO, 1)
 315         AC_MSG_RESULT([yes])
 316 ],[
 317         AC_MSG_RESULT([no])
 318 ])
 319
 320 # Confirm that we have CPU_SET, and it actually works.
 321 AC_MSG_CHECKING([whether CPU_SET works])
 322 AH_TEMPLATE([HAVE_CPU_SET], [Defined to 1 if we have CPU_SET and it works])
 323 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 324                 #include <sched.h>
 325                 int main()
 326                 {
 327                         cpu_set_t foo, mask; CPU_SET(0, &foo);
 328                         return 0;
 329                 }
 330         ]])
 331 ],[
 332         AC_DEFINE(HAVE_CPU_SET, 1)
 333         AC_MSG_RESULT([yes])
 334 ],[
 335         AC_MSG_RESULT([no])
 336 ])
 337
 338 # First check if the function is available at all.
 339 AC_CHECK_FUNCS([sched_setaffinity],[
 340         # Okay, we have it.  Check if also have cpu_set_t.  If we don't,
 341         # then we have the first version using unsigned long, and no
 342         # CPU_ZERO, etc. macros.  If we do have cpu_set_t, we may have the
 343         # version with 2 or 3 arguments.  In that case, CPU_ZERO, etc.,
 344         # should also be present, but we confirm nonetheless.
 345
 346         AS_IF([test "x$have_cpu_set_t" = "xyes"], [
 347                 # We do have it.
 348                 # Check how many arguments does sched_setaffinity take.
 349                 # Should be 3 or 2.
 350                 AC_MSG_CHECKING([how many arguments sched_setaffinity takes])
 351                 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 352                                 #include <sched.h>
 353                                 int main()
 354                                 {
 355                                         cpu_set_t foo;
 356                                         sched_setaffinity(0, sizeof (foo), &foo);
 357                                         return 0;
 358                                 }
 359                         ]])
 360                 ],
 361                 [sched_set_affinity_args=3],
 362                 [sched_set_affinity_args=2])
 363                 AC_DEFINE_UNQUOTED(SCHED_SETAFFINITY_ARGS,
 364                         $sched_set_affinity_args,
 365                         [Defined to sched_setaffinity's number of arguments.])
 366                 AC_MSG_RESULT([$sched_set_affinity_args])
 367         ],[
 368                 # No cpu_set_t, always 3 args.
 369                 AC_DEFINE(SCHED_SETAFFINITY_ARGS, 3)
 370         ])
 371 ])
 372
 373 AM_CPPFLAGS="-include config.h"
 374 AC_SUBST(AM_CPPFLAGS)
 375
 376 AM_CFLAGS="-Wall $AM_CFLAGS"
 377 AC_SUBST(AM_CFLAGS)
 378
 379 AC_CONFIG_LINKS([
 380         include/urcu/arch.h:$ARCHSRC
 381         include/urcu/uatomic.h:$UATOMICSRC
 382 ])
 383 AC_CONFIG_FILES([
 384         Makefile
 385         doc/Makefile
 386         doc/examples/Makefile
 387         include/Makefile
 388         src/Makefile
 389         tests/Makefile
 390         tests/common/Makefile
 391         tests/unit/Makefile
 392         tests/benchmark/Makefile
 393         tests/regression/Makefile
 394         tests/utils/Makefile
 395         src/liburcu.pc
 396         src/liburcu-bp.pc
 397         src/liburcu-cds.pc
 398         src/liburcu-qsbr.pc
 399         src/liburcu-mb.pc
 400         src/liburcu-signal.pc
 401 ])
 402
 403 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_perf_global.tap], [chmod +x tests/regression/rcutorture_urcu_bp_perf_global.tap])
 404 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_perf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_bp_perf_percpu.tap])
 405 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_perf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_bp_perf_perthread.tap])
 406 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_rperf_global.tap], [chmod +x tests/regression/rcutorture_urcu_bp_rperf_global.tap])
 407 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_rperf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_bp_rperf_percpu.tap])
 408 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_rperf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_bp_rperf_perthread.tap])
 409 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_stress_global.tap], [chmod +x tests/regression/rcutorture_urcu_bp_stress_global.tap])
 410 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_stress_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_bp_stress_percpu.tap])
 411 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_stress_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_bp_stress_perthread.tap])
 412 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_uperf_global.tap], [chmod +x tests/regression/rcutorture_urcu_bp_uperf_global.tap])
 413 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_uperf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_bp_uperf_percpu.tap])
 414 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_uperf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_bp_uperf_perthread.tap])
 415 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_perf_global.tap], [chmod +x tests/regression/rcutorture_urcu_mb_perf_global.tap])
 416 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_perf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_mb_perf_percpu.tap])
 417 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_perf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_mb_perf_perthread.tap])
 418 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_rperf_global.tap], [chmod +x tests/regression/rcutorture_urcu_mb_rperf_global.tap])
 419 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_rperf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_mb_rperf_percpu.tap])
 420 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_rperf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_mb_rperf_perthread.tap])
 421 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_stress_global.tap], [chmod +x tests/regression/rcutorture_urcu_mb_stress_global.tap])
 422 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_stress_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_mb_stress_percpu.tap])
 423 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_stress_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_mb_stress_perthread.tap])
 424 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_uperf_global.tap], [chmod +x tests/regression/rcutorture_urcu_mb_uperf_global.tap])
 425 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_uperf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_mb_uperf_percpu.tap])
 426 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_uperf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_mb_uperf_perthread.tap])
 427 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_perf_global.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_perf_global.tap])
 428 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_perf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_perf_percpu.tap])
 429 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_perf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_perf_perthread.tap])
 430 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_rperf_global.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_rperf_global.tap])
 431 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_rperf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_rperf_percpu.tap])
 432 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_rperf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_rperf_perthread.tap])
 433 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_stress_global.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_stress_global.tap])
 434 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_stress_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_stress_percpu.tap])
 435 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_stress_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_stress_perthread.tap])
 436 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_uperf_global.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_uperf_global.tap])
 437 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_uperf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_uperf_percpu.tap])
 438 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_uperf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_uperf_perthread.tap])
 439 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_perf_global.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_perf_global.tap])
 440 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_perf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_perf_percpu.tap])
 441 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_perf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_perf_perthread.tap])
 442 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_rperf_global.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_rperf_global.tap])
 443 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_rperf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_rperf_percpu.tap])
 444 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_rperf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_rperf_perthread.tap])
 445 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_stress_global.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_stress_global.tap])
 446 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_stress_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_stress_percpu.tap])
 447 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_stress_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_stress_perthread.tap])
 448 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_uperf_global.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_uperf_global.tap])
 449 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_uperf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_uperf_percpu.tap])
 450 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_uperf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_uperf_perthread.tap])
 451 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_perf_global.tap], [chmod +x tests/regression/rcutorture_urcu_signal_perf_global.tap])
 452 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_perf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_signal_perf_percpu.tap])
 453 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_perf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_signal_perf_perthread.tap])
 454 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_rperf_global.tap], [chmod +x tests/regression/rcutorture_urcu_signal_rperf_global.tap])
 455 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_rperf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_signal_rperf_percpu.tap])
 456 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_rperf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_signal_rperf_perthread.tap])
 457 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_stress_global.tap], [chmod +x tests/regression/rcutorture_urcu_signal_stress_global.tap])
 458 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_stress_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_signal_stress_percpu.tap])
 459 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_stress_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_signal_stress_perthread.tap])
 460 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_uperf_global.tap], [chmod +x tests/regression/rcutorture_urcu_signal_uperf_global.tap])
 461 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_uperf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_signal_uperf_percpu.tap])
 462 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_uperf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_signal_uperf_perthread.tap])
 463
 464
 465 AC_OUTPUT
 466
 467 #
 468 # Mini-report on what will be built.
 469 #
 470
 471 PPRINT_INIT
 472 PPRINT_SET_INDENT(1)
 473 PPRINT_SET_TS(38)
 474
 475 AS_ECHO
 476 AS_ECHO("${PPRINT_COLOR_BLDBLU}Userspace-RCU $PACKAGE_VERSION${PPRINT_COLOR_RST}")
 477 AS_ECHO
 478
 479 PPRINT_SUBTITLE([Features])
 480
 481 PPRINT_PROP_STRING([Target architecture], $host_cpu)
 482
 483 # SMP support enabled/disabled
 484 test "x$def_smp_support" = "xyes" && value=1 || value=0
 485 PPRINT_PROP_BOOL([SMP support], $value)
 486
 487 # Memory fence support available
 488 test "x$config_rcu_have_fence" = "xyes" && value=1 || value=0
 489 PPRINT_PROP_BOOL([Memory fence instructions], $value)
 490
 491 # Futex support available
 492 test "x$compat_futex_test" = "x0" && value=1 || value=0
 493 PPRINT_PROP_BOOL([Futex support], $value)
 494
 495 # TLS
 496 test "x$def_tls_detect" = "x" && value="pthread_getspecific()" || value="$def_tls_detect"
 497 PPRINT_PROP_STRING([Thread Local Storage (TLS)], [$value])
 498
 499 # clock_gettime() available
 500 test "x$config_rcu_have_clock_gettime" = "xyes" && value=1 || value=0
 501 PPRINT_PROP_BOOL([clock_gettime()], $value)
 502
 503 # Require membarrier
 504 test "x$def_sys_membarrier_fallback" != "xyes" && value=1 || value=0
 505 PPRINT_PROP_BOOL([Require membarrier], $value)
 506
 507 # RCU debug enabled/disabled
 508 test "x$enable_rcu_debug" = "xyes" && value=1 || value=0
 509 PPRINT_PROP_BOOL([Internal debugging], $value)
 510
 511 report_bindir="`eval eval echo $bindir`"
 512 report_libdir="`eval eval echo $libdir`"
 513
 514 # Print the bindir and libdir this `make install' will install into.
 515 AS_ECHO
 516 PPRINT_SUBTITLE([Install directories])
 517 PPRINT_PROP_STRING([Binaries], [$report_bindir])
 518 PPRINT_PROP_STRING([Libraries], [$report_libdir])
 519