configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4
   5 AC_INIT([userspace-rcu],[0.8.0],[mathieu dot desnoyers at efficios dot com])
   6
   7 # Following the numbering scheme proposed by libtool for the library version
   8 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
   9 AC_SUBST([URCU_LIBRARY_VERSION], [3:0:0])
  10
  11 AC_CONFIG_AUX_DIR([config])
  12 AC_CONFIG_MACRO_DIR([config])
  13 AC_CANONICAL_TARGET
  14 AC_CANONICAL_HOST
  15 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
  16 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  17
  18 m4_include([config/ax_tls.m4])
  19
  20 AC_CONFIG_SRCDIR([urcu.h])
  21
  22 AC_CONFIG_HEADERS([config.h urcu/config.h])
  23
  24 AH_TEMPLATE([CONFIG_RCU_SMP], [Enable SMP support. With SMP support enabled, uniprocessors are also supported. With SMP support disabled, UP systems work fine, but the behavior of SMP systems is undefined.])
  25 AH_TEMPLATE([CONFIG_RCU_HAVE_FENCE], [Defined when on a system that has memory fence instructions.])
  26 AH_TEMPLATE([CONFIG_RCU_HAVE_FUTEX], [Defined when on a system with futex support.])
  27 AH_TEMPLATE([CONFIG_RCU_COMPAT_ARCH], [Compatibility mode for i386 which lacks cmpxchg instruction.])
  28 AH_TEMPLATE([CONFIG_RCU_ARM_HAVE_DMB], [Use the dmb instruction if available for use on ARM.])
  29 AH_TEMPLATE([CONFIG_RCU_TLS], [TLS provided by the compiler.])
  30
  31 # Allow overriding storage used for TLS variables.
  32 AC_ARG_ENABLE([compiler-tls],
  33         AS_HELP_STRING([--disable-compiler-tls], [Use pthread_getspecific() to emulate Thread Local Storage (TLS) variables.]),
  34         [def_compiler_tls=$enableval],
  35         [def_compiler_tls="yes"])
  36
  37 # If not overridden, use ax_tls.m4 to check if TLS is available.
  38 AS_IF([test "x$def_compiler_tls" = "xyes"],
  39         [AX_TLS([def_tls_detect=$ac_cv_tls], [:])],
  40         [:])
  41
  42 AS_IF([test "x$def_tls_detect" = "x"],
  43         [:],
  44         [AC_DEFINE_UNQUOTED([CONFIG_RCU_TLS], $def_tls_detect)])
  45
  46 # Checks for programs.
  47 AC_PROG_CC
  48 AC_PROG_MAKE_SET
  49 LT_INIT
  50
  51 # Checks for typedefs, structures, and compiler characteristics.
  52 AC_C_INLINE
  53 AC_TYPE_PID_T
  54 AC_TYPE_SIZE_T
  55
  56 # Checks for library functions.
  57 AC_FUNC_MALLOC
  58 AC_FUNC_MMAP
  59 AC_CHECK_FUNCS([bzero gettimeofday munmap sched_getcpu strtoul sysconf gettid])
  60
  61 # Find arch type
  62 AS_CASE([$host_cpu],
  63         [i386], [ARCHTYPE="x86" && SUBARCHTYPE="x86compat"],
  64         [i486], [ARCHTYPE="x86"],
  65         [i586], [ARCHTYPE="x86"],
  66         [i686], [ARCHTYPE="x86"],
  67         [amd64], [ARCHTYPE="x86"],
  68         [x86_64], [ARCHTYPE="x86"],
  69         [powerpc], [ARCHTYPE="ppc"],
  70         [ppc64], [ARCHTYPE="ppc"],
  71         [powerpc64], [ARCHTYPE="ppc"],
  72         [ppc], [ARCHTYPE="ppc"],
  73         [s390], [ARCHTYPE="s390"],
  74         [s390x], [ARCHTYPE="s390"],
  75         [sparc], [ARCHTYPE="sparc64"],
  76         [sparc64], [ARCHTYPE="sparc64"],
  77         [alpha*], [ARCHTYPE="alpha"],
  78         [ia64], [ARCHTYPE="gcc"],
  79         [arm*], [ARCHTYPE="arm"],
  80         [mips*], [ARCHTYPE="mips"],
  81         [tile*], [ARCHTYPE="gcc"],
  82         [ARCHTYPE="unknown"]
  83 )
  84
  85 AS_CASE([$host],[*-*-linux-androideabi],
  86         [AM_CONDITIONAL(TARGET_IS_ANDROID, true)],
  87         [AM_CONDITIONAL(TARGET_IS_ANDROID, false)]
  88 )
  89
  90 AC_SUBST(ARCHTYPE)
  91 AC_SUBST(SUBARCHTYPE)
  92
  93 UATOMICSRC=urcu/uatomic/$ARCHTYPE.h
  94 ARCHSRC=urcu/arch/$ARCHTYPE.h
  95
  96 AS_IF([test "x$SUBARCHTYPE" = xx86compat],[
  97         AC_DEFINE([CONFIG_RCU_COMPAT_ARCH], [1])
  98 ])
  99
 100 AS_IF([test "$host_cpu" = "armv7l"],[
 101         CFLAGS="$CFLAGS -mcpu=cortex-a9 -mtune=cortex-a9 -O1"
 102 ])
 103
 104 # ARM-specific checks
 105 AS_IF([test "x$ARCHTYPE" = "xarm"],[
 106         AC_MSG_CHECKING([for dmb instruction])
 107         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 108                                 int main()
 109                                 {
 110                                         asm volatile("dmb":::"memory");
 111                                         return 0;
 112                                 }
 113                 ]])
 114         ],[
 115                 AC_MSG_RESULT([yes])
 116                 AC_DEFINE([CONFIG_RCU_ARM_HAVE_DMB], [1])
 117         ],[
 118                 AC_MSG_RESULT([no])
 119         ])
 120 ])
 121
 122 # Tile-specific checks
 123 AS_IF([echo "$host_cpu" | grep "^tile"],[
 124         AC_MSG_CHECKING([for Tile architecture type])
 125         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 126                                 #ifndef __tilegx__
 127                                 #error
 128                                 #endif
 129                 ]])
 130         ],[
 131                 AC_MSG_RESULT([ok])
 132         ],[
 133                 AC_MSG_FAILURE([URCU has only been tested on the TileGx architecture. For other Tile* architectures, please run the tests first and report the results to the maintainer so that proper support can be added.])
 134         ])
 135 ])
 136
 137 # x86-specific checks
 138 AS_IF([test "x$ARCHTYPE" = "xx86"],[
 139         AC_MSG_CHECKING([if architecture really supports the mfence instruction])
 140         #For now, using lock; addl compatibility mode even for i686, because the
 141         #Pentium III is seen as a i686, but lacks mfence instruction.
 142         #Only using fence for x86_64.
 143         AS_IF([test "x$host_cpu" != "xi386" -a "x$host_cpu" != "xi486" -a "x$host_cpu" != "xi586" -a "x$host_cpu" != "xi686"],[
 144                 AC_MSG_RESULT([yes])
 145                 AC_DEFINE([CONFIG_RCU_HAVE_FENCE], [1])
 146         ],[
 147                 AC_MSG_RESULT([no])
 148         ])
 149 ])
 150
 151 # Check if sys_futex() is available
 152 AC_MSG_CHECKING([for sys_futex()])
 153 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 154                 #include <sys/syscall.h>
 155                 #ifndef __NR_futex
 156                 #error "futexes not available"
 157                 #endif
 158         ]])
 159 ],[
 160         AC_MSG_RESULT([yes])
 161         AC_DEFINE([CONFIG_RCU_HAVE_FUTEX], [1])
 162         compat_futex_test=0
 163 ],[
 164         AC_MSG_RESULT([no])
 165         compat_futex_test=1
 166 ])
 167
 168 # Check for pthread
 169 AC_CHECK_LIB([pthread], [pthread_create],
 170         [AM_CONDITIONAL(LIBC_INCLUDES_PTHREAD, false)],
 171         [AC_CHECK_LIB([c], [pthread_create],
 172                 [AM_CONDITIONAL(LIBC_INCLUDES_PTHREAD, true)],
 173                 [AC_MSG_ERROR([Cannot find libpthread. Use [LDFLAGS]=-Ldir to specify its location.])]
 174         )]
 175 )
 176
 177 AM_CONDITIONAL([COMPAT_FUTEX], [test "x$compat_futex_test" = "x1"])
 178 AM_CONDITIONAL([COMPAT_ARCH], [test "x$SUBARCHTYPE" = "xx86compat"])
 179 AM_CONDITIONAL([NO_SHARED], [test "x$enable_shared" = "xno"])
 180
 181 # smp-support configure option
 182 AC_ARG_ENABLE([smp-support],
 183         AS_HELP_STRING([--disable-smp-support], [Disable SMP support. Warning: only use this on uniprocessor systems. [default=enabled]]),
 184         [def_smp_support=$enableval],
 185         [def_smp_support="yes"])
 186 AS_IF([test "x$def_smp_support" = "xyes"], [AC_DEFINE([CONFIG_RCU_SMP], [1])])
 187
 188
 189 # From the sched_setaffinity(2)'s man page:
 190 # ~~~~
 191 # The CPU affinity system calls were introduced in Linux kernel 2.5.8.
 192 # The library interfaces were introduced in glibc 2.3.  Initially, the
 193 # glibc interfaces included a cpusetsize argument.  In glibc 2.3.3,
 194 # the cpuset size argument was removed, but this argument was
 195 # restored in glibc 2.3.4.
 196 # ~~~~
 197
 198 # In addition to that, some vendors ported the system call to 2.4
 199 # kernels.
 200
 201 # Furthermore, when the function first appeared, the MASK argument was
 202 # an unsigned long pointer, while later it was made into a cpu_set_t
 203 # pointer.  Systems that have the cpu_set_t version also should have
 204 # the CPU_ZERO, CPU_SET, etc. macros.
 205
 206 # All this mess means we have to cater for at least 3 different
 207 # sched_setaffinity prototypes:
 208
 209 # ~~~~
 210 #  int sched_setaffinity (pid_t pid, unsigned int len, unsigned long *mask);
 211 #  int sched_setaffinity (pid_t __pid, size_t __cpusetsize, const cpu_set_t *__cpuset);
 212 #  int sched_setaffinity (pid_t __pid, const cpu_set_t *__mask);
 213 # ~~~~
 214
 215 # Since we define _GNU_SOURCE in the sources, must do so too in the
 216 # autoconf tests, as defining _GNU_SOURCE or not exposes
 217 # sched_setaffinity bits differently.
 218 saved_CFLAGS=$CFLAGS
 219 CFLAGS="$CFLAGS -D_GNU_SOURCE"
 220
 221 AC_CHECK_TYPES([cpu_set_t],
 222         [have_cpu_set_t="yes"],
 223         [have_cpu_set_t="no"],
 224         [#include <sched.h>])
 225
 226 # Confirm that we have CPU_ZERO, and it actually works.
 227 AC_MSG_CHECKING([whether CPU_ZERO works])
 228 AH_TEMPLATE([HAVE_CPU_ZERO], [Defined to 1 if we have CPU_ZERO and it works])
 229 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 230                 #define _GNU_SOURCE
 231                 #include <sched.h>
 232                 int main()
 233                 {
 234                         cpu_set_t foo; CPU_ZERO(&foo);
 235                         return 0;
 236                 }
 237         ]])
 238 ],[
 239         AC_DEFINE(HAVE_CPU_ZERO, 1)
 240         AC_MSG_RESULT([yes])
 241 ],[
 242         AC_MSG_RESULT([no])
 243 ])
 244
 245 # Confirm that we have CPU_SET, and it actually works.
 246 AC_MSG_CHECKING([whether CPU_SET works])
 247 AH_TEMPLATE([HAVE_CPU_SET], [Defined to 1 if we have CPU_SET and it works])
 248 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 249                 #define _GNU_SOURCE
 250                 #include <sched.h>
 251                 int main()
 252                 {
 253                         cpu_set_t foo, mask; CPU_SET(0, &foo);
 254                         return 0;
 255                 }
 256         ]])
 257 ],[
 258         AC_DEFINE(HAVE_CPU_SET, 1)
 259         AC_MSG_RESULT([yes])
 260 ],[
 261         AC_MSG_RESULT([no])
 262 ])
 263
 264 # First check if the function is available at all.
 265 AC_CHECK_FUNCS([sched_setaffinity],[
 266         # Okay, we have it.  Check if also have cpu_set_t.  If we don't,
 267         # then we have the first version using unsigned long, and no
 268         # CPU_ZERO, etc. macros.  If we do have cpu_set_t, we may have the
 269         # version with 2 or 3 arguments.  In that case, CPU_ZERO, etc.,
 270         # should also be present, but we confirm nonetheless.
 271
 272         AS_IF([test "x$have_cpu_set_t" = "xyes"], [
 273                 # We do have it.
 274                 # Check how many arguments does sched_setaffinity take.
 275                 # Should be 3 or 2.
 276                 AC_MSG_CHECKING([how many arguments sched_setaffinity takes])
 277                 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 278                                 #include <sched.h>
 279                                 int main()
 280                                 {
 281                                         cpu_set_t foo;
 282                                         sched_setaffinity(0, sizeof (foo), &foo);
 283                                         return 0;
 284                                 }
 285                         ]])
 286                 ],
 287                 [sched_set_affinity_args=3],
 288                 [sched_set_affinity_args=2])
 289                 AC_DEFINE_UNQUOTED(SCHED_SETAFFINITY_ARGS,
 290                         $sched_set_affinity_args,
 291                         [Defined to sched_setaffinity's number of arguments.])
 292                 AC_MSG_RESULT([$sched_set_affinity_args])
 293         ],[
 294                 # No cpu_set_t, always 3 args.
 295                 AC_DEFINE(SCHED_SETAFFINITY_ARGS, 3)
 296         ])
 297 ])
 298
 299 CFLAGS=$saved_CFLAGS
 300
 301 AC_CONFIG_LINKS([
 302         urcu/arch.h:$ARCHSRC
 303         urcu/uatomic.h:$UATOMICSRC
 304 ])
 305 AC_CONFIG_FILES([
 306         Makefile
 307         doc/Makefile
 308         doc/examples/Makefile
 309         tests/Makefile
 310         tests/common/Makefile
 311         tests/unit/Makefile
 312         tests/benchmark/Makefile
 313         tests/regression/Makefile
 314         liburcu.pc
 315         liburcu-bp.pc
 316         liburcu-cds.pc
 317         liburcu-qsbr.pc
 318         liburcu-mb.pc
 319         liburcu-signal.pc
 320 ])
 321 AC_OUTPUT
 322
 323 # Report on selected configure options
 324 AS_IF([test "x$def_smp_support" = "xyes"],[
 325         AS_ECHO("SMP support enabled.")
 326 ],[
 327         AS_ECHO("SMP support disabled.")
 328 ])
 329
 330 AS_IF([test "x$def_tls_detect" = "x"],[
 331         AS_ECHO("Thread Local Storage (TLS): pthread_getspecific().")
 332 ],[
 333         AS_ECHO("Thread Local Storage (TLS): $def_tls_detect.")
 334 ])