Update version to 0.7.2
[urcu.git] / configure.ac
1 # -*- Autoconf -*-
2 # Process this file with autoconf to produce a configure script.
3
4
5 AC_INIT([userspace-rcu],[0.7.2],[mathieu dot desnoyers at efficios dot com])
6
7 # Following the numbering scheme proposed by libtool for the library version
8 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
9 AC_SUBST([URCU_LIBRARY_VERSION], [1:0:0])
10
11 AC_CONFIG_AUX_DIR([config])
12 AC_CONFIG_MACRO_DIR([config])
13 AC_CANONICAL_TARGET
14 AC_CANONICAL_HOST
15 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
16 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
17
18 m4_include([config/ax_tls.m4])
19
20 AC_CONFIG_SRCDIR([urcu.h])
21
22 AC_CONFIG_HEADERS([config.h urcu/config.h])
23
24 AH_TEMPLATE([CONFIG_RCU_SMP], [Enable SMP support. With SMP support enabled, uniprocessors are also supported. With SMP support disabled, UP systems work fine, but the behavior of SMP systems is undefined.])
25 AH_TEMPLATE([CONFIG_RCU_HAVE_FENCE], [Defined when on a system that has memory fence instructions.])
26 AH_TEMPLATE([CONFIG_RCU_HAVE_FUTEX], [Defined when on a system with futex support.])
27 AH_TEMPLATE([CONFIG_RCU_COMPAT_ARCH], [Compatibility mode for i386 which lacks cmpxchg instruction.])
28 AH_TEMPLATE([CONFIG_RCU_ARM_HAVE_DMB], [Use the dmb instruction if available for use on ARM.])
29 AH_TEMPLATE([CONFIG_RCU_TLS], [TLS provided by the compiler.])
30
31 AX_TLS([AC_DEFINE_UNQUOTED([CONFIG_RCU_TLS], $ac_cv_tls)], [])
32
33 # Checks for programs.
34 AC_PROG_CC
35 AC_PROG_MAKE_SET
36 LT_INIT
37
38 # Checks for typedefs, structures, and compiler characteristics.
39 AC_C_INLINE
40 AC_TYPE_PID_T
41 AC_TYPE_SIZE_T
42
43 # Checks for library functions.
44 AC_FUNC_MALLOC
45 AC_FUNC_MMAP
46 AC_CHECK_FUNCS([bzero gettimeofday munmap sched_getcpu strtoul sysconf])
47
48 # Find arch type
49 AS_CASE([$host_cpu],
50 [i386], [ARCHTYPE="x86" && SUBARCHTYPE="x86compat"],
51 [i486], [ARCHTYPE="x86"],
52 [i586], [ARCHTYPE="x86"],
53 [i686], [ARCHTYPE="x86"],
54 [amd64], [ARCHTYPE="x86"],
55 [x86_64], [ARCHTYPE="x86"],
56 [powerpc], [ARCHTYPE="ppc"],
57 [ppc64], [ARCHTYPE="ppc"],
58 [powerpc64], [ARCHTYPE="ppc"],
59 [ppc], [ARCHTYPE="ppc"],
60 [s390], [ARCHTYPE="s390"],
61 [s390x], [ARCHTYPE="s390"],
62 [sparc64], [ARCHTYPE="sparc64"],
63 [alpha*], [ARCHTYPE="alpha"],
64 [ia64], [ARCHTYPE="gcc"],
65 [arm*], [ARCHTYPE="arm"],
66 [ARCHTYPE="unknown"]
67 )
68
69 AC_SUBST(ARCHTYPE)
70 AC_SUBST(SUBARCHTYPE)
71
72 UATOMICSRC=urcu/uatomic/$ARCHTYPE.h
73 ARCHSRC=urcu/arch/$ARCHTYPE.h
74
75 AS_IF([test "x$SUBARCHTYPE" = xx86compat],[
76 AC_DEFINE([CONFIG_RCU_COMPAT_ARCH], [1])
77 ])
78
79 AS_IF([test "$host_cpu" = "armv7l"],[
80 CFLAGS="$CFLAGS -mcpu=cortex-a9 -mtune=cortex-a9 -O1"
81 ])
82
83 # ARM-specific checks
84 AS_IF([test "x$ARCHTYPE" = "xarm"],[
85 AC_MSG_CHECKING([for dmb instruction])
86 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
87 int main()
88 {
89 asm volatile("dmb":::"memory");
90 return 0;
91 }
92 ]])
93 ],[
94 AC_MSG_RESULT([yes])
95 AC_DEFINE([CONFIG_RCU_ARM_HAVE_DMB], [1])
96 ],[
97 AC_MSG_RESULT([no])
98 ])
99 ])
100
101 # x86-specific checks
102 AS_IF([test "x$ARCHTYPE" = "xx86"],[
103 AC_MSG_CHECKING([if architecture really supports the mfence instruction])
104 #For now, using lock; addl compatibility mode even for i686, because the
105 #Pentium III is seen as a i686, but lacks mfence instruction.
106 #Only using fence for x86_64.
107 AS_IF([test "x$host_cpu" != "xi386" -a "x$host_cpu" != "xi486" -a "x$host_cpu" != "xi586" -a "x$host_cpu" != "xi686"],[
108 AC_MSG_RESULT([yes])
109 AC_DEFINE([CONFIG_RCU_HAVE_FENCE], [1])
110 ],[
111 AC_MSG_RESULT([no])
112 ])
113 ])
114
115 # Check if sys_futex() is available
116 AC_MSG_CHECKING([for sys_futex()])
117 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
118 #include <sys/syscall.h>
119 #ifndef __NR_futex
120 #error "futexes not available"
121 #endif
122 ]])
123 ],[
124 AC_MSG_RESULT([yes])
125 AC_DEFINE([CONFIG_RCU_HAVE_FUTEX], [1])
126 compat_futex_test=0
127 ],[
128 AC_MSG_RESULT([no])
129 compat_futex_test=1
130 ])
131
132 AM_CONDITIONAL([COMPAT_FUTEX], [test "x$compat_futex_test" = "x1"])
133 AM_CONDITIONAL([COMPAT_ARCH], [test "x$SUBARCHTYPE" = "xx86compat"])
134
135 # smp-support configure option
136 AC_ARG_ENABLE([smp-support],
137 AS_HELP_STRING([--disable-smp-support], [Disable SMP support. Warning: only use this on uniprocessor systems. [default=enabled]]),
138 [def_smp_support=$enableval],
139 [def_smp_support="yes"])
140 AS_IF([test "x$def_smp_support" = "xyes"], [AC_DEFINE([CONFIG_RCU_SMP], [1])])
141
142
143 # From the sched_setaffinity(2)'s man page:
144 # ~~~~
145 # The CPU affinity system calls were introduced in Linux kernel 2.5.8.
146 # The library interfaces were introduced in glibc 2.3. Initially, the
147 # glibc interfaces included a cpusetsize argument. In glibc 2.3.3,
148 # the cpuset size argument was removed, but this argument was
149 # restored in glibc 2.3.4.
150 # ~~~~
151
152 # In addition to that, some vendors ported the system call to 2.4
153 # kernels.
154
155 # Furthermore, when the function first appeared, the MASK argument was
156 # an unsigned long pointer, while later it was made into a cpu_set_t
157 # pointer. Systems that have the cpu_set_t version also should have
158 # the CPU_ZERO, CPU_SET, etc. macros.
159
160 # All this mess means we have to cater for at least 3 different
161 # sched_setaffinity prototypes:
162
163 # ~~~~
164 # int sched_setaffinity (pid_t pid, unsigned int len, unsigned long *mask);
165 # int sched_setaffinity (pid_t __pid, size_t __cpusetsize, const cpu_set_t *__cpuset);
166 # int sched_setaffinity (pid_t __pid, const cpu_set_t *__mask);
167 # ~~~~
168
169 # Since we define _GNU_SOURCE in the sources, must do so too in the
170 # autoconf tests, as defining _GNU_SOURCE or not exposes
171 # sched_setaffinity bits differently.
172 saved_CFLAGS=$CFLAGS
173 CFLAGS="$CFLAGS -D_GNU_SOURCE"
174
175 # First check if the function is available at all.
176 AC_CHECK_FUNCS([sched_setaffinity],[
177 # Okay, we have it. Check if also have cpu_set_t. If we don't,
178 # then we have the first version using unsigned long, and no
179 # CPU_ZERO, etc. macros. If we do have cpu_set_t, we may have the
180 # version with 2 or 3 arguments. In that case, CPU_ZERO, etc.,
181 # should also be present, but we confirm nonetheless.
182
183 AC_CHECK_TYPES([cpu_set_t],[
184 # We do have it. Confirm that we have CPU_ZERO, and it actually works.
185 AC_MSG_CHECKING([whether CPU_ZERO works])
186 AH_TEMPLATE([HAVE_CPU_ZERO], [Defined to 1 if we have CPU_ZERO and it works])
187 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
188 #define _GNU_SOURCE
189 #include <sched.h>
190 int main()
191 {
192 cpu_set_t foo; CPU_ZERO (&foo);
193 return 0;
194 }
195 ]])
196 ],[
197 # Works!
198 AC_DEFINE(HAVE_CPU_ZERO, 1)
199 AC_MSG_RESULT([yes])
200 ],[
201 AC_MSG_RESULT([no])
202 ])
203
204 # Check how many arguments does sched_setaffinity take.
205 # Should be 3 or 2.
206 AC_MSG_CHECKING([how many arguments sched_setaffinity takes])
207 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
208 #include <sched.h>
209 int main()
210 {
211 cpu_set_t foo;
212 sched_setaffinity (0, sizeof (foo), &foo);
213 return 0;
214 }
215 ]])
216 ],
217 [sched_set_affinity_args=3],
218 [sched_set_affinity_args=2])
219 AC_DEFINE_UNQUOTED(SCHED_SETAFFINITY_ARGS, $sched_set_affinity_args,
220 [Defined to sched_setaffinity's number of arguments.])
221 AC_MSG_RESULT([$sched_set_affinity_args])
222 ],[
223 # No cpu_set_t, always 3 args.
224 AC_DEFINE(SCHED_SETAFFINITY_ARGS, 3)
225 ],
226 [#include <sched.h>])
227 ])
228
229 CFLAGS=$saved_CFLAGS
230
231 AC_CONFIG_LINKS([
232 urcu/arch.h:$ARCHSRC
233 urcu/uatomic.h:$UATOMICSRC
234 ])
235 AC_CONFIG_FILES([
236 Makefile
237 doc/Makefile
238 tests/Makefile
239 liburcu.pc
240 liburcu-bp.pc
241 liburcu-cds.pc
242 liburcu-qsbr.pc
243 liburcu-mb.pc
244 liburcu-signal.pc
245 ])
246 AC_OUTPUT
247
248 # Report on selected configure options
249 AS_IF([test "x$def_smp_support" = "xyes"],[
250 AS_ECHO("SMP support enabled.")
251 ],[
252 AS_ECHO("SMP support disabled.")
253 ])
This page took 0.048406 seconds and 4 git commands to generate.