[urcu.git] / configure.ac

#                                               -*- Autoconf -*-
# Process this file with autoconf to produce a configure script.


AC_INIT([userspace-rcu],[0.7.4],[mathieu dot desnoyers at efficios dot com])

# Following the numbering scheme proposed by libtool for the library version
# http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
AC_SUBST([URCU_LIBRARY_VERSION], [2:0:0])

AC_CONFIG_AUX_DIR([config])
AC_CONFIG_MACRO_DIR([config])
AC_CANONICAL_TARGET
AC_CANONICAL_HOST
AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])

m4_include([config/ax_tls.m4])

AC_CONFIG_SRCDIR([urcu.h])

AC_CONFIG_HEADERS([config.h urcu/config.h])

AH_TEMPLATE([CONFIG_RCU_SMP], [Enable SMP support. With SMP support enabled, uniprocessors are also supported. With SMP support disabled, UP systems work fine, but the behavior of SMP systems is undefined.])
AH_TEMPLATE([CONFIG_RCU_HAVE_FENCE], [Defined when on a system that has memory fence instructions.])
AH_TEMPLATE([CONFIG_RCU_HAVE_FUTEX], [Defined when on a system with futex support.])
AH_TEMPLATE([CONFIG_RCU_COMPAT_ARCH], [Compatibility mode for i386 which lacks cmpxchg instruction.])
AH_TEMPLATE([CONFIG_RCU_ARM_HAVE_DMB], [Use the dmb instruction if available for use on ARM.])
AH_TEMPLATE([CONFIG_RCU_TLS], [TLS provided by the compiler.])

# Allow overriding storage used for TLS variables.
AC_ARG_ENABLE([compiler-tls],
	AS_HELP_STRING([--disable-compiler-tls], [Use pthread_getspecific() to emulate Thread Local Storage (TLS) variables.]),
	[def_compiler_tls=$enableval],
	[def_compiler_tls="yes"])

# If not overridden, use ax_tls.m4 to check if TLS is available.
AS_IF([test "x$def_compiler_tls" = "xyes"],
	[AX_TLS([def_tls_detect=$ac_cv_tls], [:])],
	[:])

AS_IF([test "x$def_tls_detect" = "x"],
	[:],
	[AC_DEFINE_UNQUOTED([CONFIG_RCU_TLS], $def_tls_detect)])

# Checks for programs.
AC_PROG_CC
AC_PROG_MAKE_SET
LT_INIT

# Checks for typedefs, structures, and compiler characteristics.
AC_C_INLINE
AC_TYPE_PID_T
AC_TYPE_SIZE_T

# Checks for library functions.
AC_FUNC_MALLOC
AC_FUNC_MMAP
AC_CHECK_FUNCS([bzero gettimeofday munmap sched_getcpu strtoul sysconf])

# Find arch type
AS_CASE([$host_cpu],
	[i386], [ARCHTYPE="x86" && SUBARCHTYPE="x86compat"],
	[i486], [ARCHTYPE="x86"],
	[i586], [ARCHTYPE="x86"],
	[i686], [ARCHTYPE="x86"],
	[amd64], [ARCHTYPE="x86"],
	[x86_64], [ARCHTYPE="x86"],
	[powerpc], [ARCHTYPE="ppc"],
	[ppc64], [ARCHTYPE="ppc"],
	[powerpc64], [ARCHTYPE="ppc"],
	[ppc], [ARCHTYPE="ppc"],
	[s390], [ARCHTYPE="s390"],
	[s390x], [ARCHTYPE="s390"],
	[sparc64], [ARCHTYPE="sparc64"],
	[alpha*], [ARCHTYPE="alpha"],
	[ia64], [ARCHTYPE="gcc"],
	[arm*], [ARCHTYPE="arm"],
	[mips*], [ARCHTYPE="mips"],
	[tile*], [ARCHTYPE="gcc"],
	[ARCHTYPE="unknown"]
)

AC_SUBST(ARCHTYPE)
AC_SUBST(SUBARCHTYPE)

UATOMICSRC=urcu/uatomic/$ARCHTYPE.h
ARCHSRC=urcu/arch/$ARCHTYPE.h

AS_IF([test "x$SUBARCHTYPE" = xx86compat],[
	AC_DEFINE([CONFIG_RCU_COMPAT_ARCH], [1])
])

AS_IF([test "$host_cpu" = "armv7l"],[
	CFLAGS="$CFLAGS -mcpu=cortex-a9 -mtune=cortex-a9 -O1"
])

# ARM-specific checks
AS_IF([test "x$ARCHTYPE" = "xarm"],[
	AC_MSG_CHECKING([for dmb instruction])
	AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
				int main()
				{
					asm volatile("dmb":::"memory");
					return 0;
				}
		]])
	],[
		AC_MSG_RESULT([yes])
		AC_DEFINE([CONFIG_RCU_ARM_HAVE_DMB], [1])
	],[
		AC_MSG_RESULT([no])
	])
])

# Tile-specific checks
AS_IF([echo "$host_cpu" | grep "^tile"],[
	AC_MSG_CHECKING([for Tile architecture type])
	AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
				#ifndef __tilegx__
				#error
				#endif
		]])
	],[
		AC_MSG_RESULT([ok])
	],[
		AC_MSG_FAILURE([URCU has only been tested on the TileGx architecture. For other Tile* architectures, please run the tests first and report the results to the maintainer so that proper support can be added.])
	])
])

# x86-specific checks
AS_IF([test "x$ARCHTYPE" = "xx86"],[
	AC_MSG_CHECKING([if architecture really supports the mfence instruction])
	#For now, using lock; addl compatibility mode even for i686, because the
	#Pentium III is seen as a i686, but lacks mfence instruction.
	#Only using fence for x86_64.
	AS_IF([test "x$host_cpu" != "xi386" -a "x$host_cpu" != "xi486" -a "x$host_cpu" != "xi586" -a "x$host_cpu" != "xi686"],[
		AC_MSG_RESULT([yes])
		AC_DEFINE([CONFIG_RCU_HAVE_FENCE], [1])
	],[
		AC_MSG_RESULT([no])
	])
])

# Check if sys_futex() is available
AC_MSG_CHECKING([for sys_futex()])
AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
		#include <sys/syscall.h>
		#ifndef __NR_futex
		#error "futexes not available"
		#endif
	]])
],[
	AC_MSG_RESULT([yes])
	AC_DEFINE([CONFIG_RCU_HAVE_FUTEX], [1])
	compat_futex_test=0
],[
	AC_MSG_RESULT([no])
	compat_futex_test=1
])

AM_CONDITIONAL([COMPAT_FUTEX], [test "x$compat_futex_test" = "x1"])
AM_CONDITIONAL([COMPAT_ARCH], [test "x$SUBARCHTYPE" = "xx86compat"])

# smp-support configure option
AC_ARG_ENABLE([smp-support], 
	AS_HELP_STRING([--disable-smp-support], [Disable SMP support. Warning: only use this on uniprocessor systems. [default=enabled]]),
	[def_smp_support=$enableval],
	[def_smp_support="yes"])
AS_IF([test "x$def_smp_support" = "xyes"], [AC_DEFINE([CONFIG_RCU_SMP], [1])])


# From the sched_setaffinity(2)'s man page:
# ~~~~
# The CPU affinity system calls were introduced in Linux kernel 2.5.8.
# The library interfaces were introduced in glibc 2.3.  Initially, the
# glibc interfaces included a cpusetsize argument.  In glibc 2.3.3,
# the cpuset size argument was removed, but this argument was
# restored in glibc 2.3.4.
# ~~~~

# In addition to that, some vendors ported the system call to 2.4
# kernels.

# Furthermore, when the function first appeared, the MASK argument was
# an unsigned long pointer, while later it was made into a cpu_set_t
# pointer.  Systems that have the cpu_set_t version also should have
# the CPU_ZERO, CPU_SET, etc. macros.

# All this mess means we have to cater for at least 3 different
# sched_setaffinity prototypes:

# ~~~~
#  int sched_setaffinity (pid_t pid, unsigned int len, unsigned long *mask);
#  int sched_setaffinity (pid_t __pid, size_t __cpusetsize, const cpu_set_t *__cpuset);
#  int sched_setaffinity (pid_t __pid, const cpu_set_t *__mask);
# ~~~~

# Since we define _GNU_SOURCE in the sources, must do so too in the
# autoconf tests, as defining _GNU_SOURCE or not exposes
# sched_setaffinity bits differently.
saved_CFLAGS=$CFLAGS
CFLAGS="$CFLAGS -D_GNU_SOURCE"

# First check if the function is available at all.
AC_CHECK_FUNCS([sched_setaffinity],[
	# Okay, we have it.  Check if also have cpu_set_t.  If we don't,
	# then we have the first version using unsigned long, and no
	# CPU_ZERO, etc. macros.  If we do have cpu_set_t, we may have the
	# version with 2 or 3 arguments.  In that case, CPU_ZERO, etc.,
	# should also be present, but we confirm nonetheless.

	AC_CHECK_TYPES([cpu_set_t],[
		# We do have it.  Confirm that we have CPU_ZERO, and it actually works.
		AC_MSG_CHECKING([whether CPU_ZERO works])
		AH_TEMPLATE([HAVE_CPU_ZERO], [Defined to 1 if we have CPU_ZERO and it works])
		AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
				#define _GNU_SOURCE
				#include <sched.h>
				int main()
				{
					cpu_set_t foo; CPU_ZERO (&foo);
					return 0;
				}
			]])
		],[
			# Works!
			AC_DEFINE(HAVE_CPU_ZERO, 1)
			AC_MSG_RESULT([yes])
		],[
			AC_MSG_RESULT([no])
		])

		# Confirm that we have CPU_SET, and it actually works.
		AC_MSG_CHECKING([whether CPU_SET works])
		AH_TEMPLATE([HAVE_CPU_SET], [Defined to 1 if we have CPU_SET and it works])
		AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
				#define _GNU_SOURCE
				#include <sched.h>
				int main()
				{
					cpu_set_t foo, mask; CPU_SET (0, &foo);
					return 0;
				}
			]])
		],[
			# Works!
			AC_DEFINE(HAVE_CPU_SET, 1)
			AC_MSG_RESULT([yes])
		],[
			AC_MSG_RESULT([no])
		])

		# Check how many arguments does sched_setaffinity take.
		# Should be 3 or 2.
		AC_MSG_CHECKING([how many arguments sched_setaffinity takes])
		AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
				#include <sched.h>
				int main()
				{
					cpu_set_t foo;
					sched_setaffinity (0, sizeof (foo), &foo);
					return 0;
				}
			]])
		],
		[sched_set_affinity_args=3],
		[sched_set_affinity_args=2])
		AC_DEFINE_UNQUOTED(SCHED_SETAFFINITY_ARGS, $sched_set_affinity_args,
			[Defined to sched_setaffinity's number of arguments.])
		AC_MSG_RESULT([$sched_set_affinity_args])
	],[
		# No cpu_set_t, always 3 args.
		AC_DEFINE(SCHED_SETAFFINITY_ARGS, 3)
    	],
    	[#include <sched.h>])
])

CFLAGS=$saved_CFLAGS

AC_CONFIG_LINKS([
	urcu/arch.h:$ARCHSRC
	urcu/uatomic.h:$UATOMICSRC
])
AC_CONFIG_FILES([
	Makefile
	doc/Makefile
	tests/Makefile
	liburcu.pc
	liburcu-bp.pc
	liburcu-cds.pc
	liburcu-qsbr.pc
	liburcu-mb.pc
	liburcu-signal.pc
])
AC_OUTPUT

# Report on selected configure options
AS_IF([test "x$def_smp_support" = "xyes"],[
	AS_ECHO("SMP support enabled.")
],[
	AS_ECHO("SMP support disabled.")
])

AS_IF([test "x$def_tls_detect" = "x"],[
	AS_ECHO("Thread Local Storage (TLS): pthread_getspecific().")
],[
	AS_ECHO("Thread Local Storage (TLS): $def_tls_detect.")
])
Commit	Line	Data
	1	# -- Autoconf --
	2	# Process this file with autoconf to produce a configure script.
	3
	4
	5	AC_INIT([userspace-rcu],[0.7.4],[mathieu dot desnoyers at efficios dot com])
	6
	7	# Following the numbering scheme proposed by libtool for the library version
	8	# http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
	9	AC_SUBST([URCU_LIBRARY_VERSION], [2:0:0])
	10
	11	AC_CONFIG_AUX_DIR([config])
	12	AC_CONFIG_MACRO_DIR([config])
	13	AC_CANONICAL_TARGET
	14	AC_CANONICAL_HOST
	15	AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
	16	m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
	17
	18	m4_include([config/ax_tls.m4])
	19
	20	AC_CONFIG_SRCDIR([urcu.h])
	21
	22	AC_CONFIG_HEADERS([config.h urcu/config.h])
	23
	24	AH_TEMPLATE([CONFIG_RCU_SMP], [Enable SMP support. With SMP support enabled, uniprocessors are also supported. With SMP support disabled, UP systems work fine, but the behavior of SMP systems is undefined.])
	25	AH_TEMPLATE([CONFIG_RCU_HAVE_FENCE], [Defined when on a system that has memory fence instructions.])
	26	AH_TEMPLATE([CONFIG_RCU_HAVE_FUTEX], [Defined when on a system with futex support.])
	27	AH_TEMPLATE([CONFIG_RCU_COMPAT_ARCH], [Compatibility mode for i386 which lacks cmpxchg instruction.])
	28	AH_TEMPLATE([CONFIG_RCU_ARM_HAVE_DMB], [Use the dmb instruction if available for use on ARM.])
	29	AH_TEMPLATE([CONFIG_RCU_TLS], [TLS provided by the compiler.])
	30
	31	# Allow overriding storage used for TLS variables.
	32	AC_ARG_ENABLE([compiler-tls],
	33	AS_HELP_STRING([--disable-compiler-tls], [Use pthread_getspecific() to emulate Thread Local Storage (TLS) variables.]),
	34	[def_compiler_tls=$enableval],
	35	[def_compiler_tls="yes"])
	36
	37	# If not overridden, use ax_tls.m4 to check if TLS is available.
	38	AS_IF([test "x$def_compiler_tls" = "xyes"],
	39	[AX_TLS([def_tls_detect=$ac_cv_tls], [:])],
	40	[:])
	41
	42	AS_IF([test "x$def_tls_detect" = "x"],
	43	[:],
	44	[AC_DEFINE_UNQUOTED([CONFIG_RCU_TLS], $def_tls_detect)])
	45
	46	# Checks for programs.
	47	AC_PROG_CC
	48	AC_PROG_MAKE_SET
	49	LT_INIT
	50
	51	# Checks for typedefs, structures, and compiler characteristics.
	52	AC_C_INLINE
	53	AC_TYPE_PID_T
	54	AC_TYPE_SIZE_T
	55
	56	# Checks for library functions.
	57	AC_FUNC_MALLOC
	58	AC_FUNC_MMAP
	59	AC_CHECK_FUNCS([bzero gettimeofday munmap sched_getcpu strtoul sysconf])
	60
	61	# Find arch type
	62	AS_CASE([$host_cpu],
	63	[i386], [ARCHTYPE="x86" && SUBARCHTYPE="x86compat"],
	64	[i486], [ARCHTYPE="x86"],
	65	[i586], [ARCHTYPE="x86"],
	66	[i686], [ARCHTYPE="x86"],
	67	[amd64], [ARCHTYPE="x86"],
	68	[x86_64], [ARCHTYPE="x86"],
	69	[powerpc], [ARCHTYPE="ppc"],
	70	[ppc64], [ARCHTYPE="ppc"],
	71	[powerpc64], [ARCHTYPE="ppc"],
	72	[ppc], [ARCHTYPE="ppc"],
	73	[s390], [ARCHTYPE="s390"],
	74	[s390x], [ARCHTYPE="s390"],
	75	[sparc64], [ARCHTYPE="sparc64"],
	76	[alpha*], [ARCHTYPE="alpha"],
	77	[ia64], [ARCHTYPE="gcc"],
	78	[arm*], [ARCHTYPE="arm"],
	79	[mips*], [ARCHTYPE="mips"],
	80	[tile*], [ARCHTYPE="gcc"],
	81	[ARCHTYPE="unknown"]
	82	)
	83
	84	AC_SUBST(ARCHTYPE)
	85	AC_SUBST(SUBARCHTYPE)
	86
	87	UATOMICSRC=urcu/uatomic/$ARCHTYPE.h
	88	ARCHSRC=urcu/arch/$ARCHTYPE.h
	89
	90	AS_IF([test "x$SUBARCHTYPE" = xx86compat],[
	91	AC_DEFINE([CONFIG_RCU_COMPAT_ARCH], [1])
	92	])
	93
	94	AS_IF([test "$host_cpu" = "armv7l"],[
	95	CFLAGS="$CFLAGS -mcpu=cortex-a9 -mtune=cortex-a9 -O1"
	96	])
	97
	98	# ARM-specific checks
	99	AS_IF([test "x$ARCHTYPE" = "xarm"],[
	100	AC_MSG_CHECKING([for dmb instruction])
	101	AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
	102	int main()
	103	{
	104	asm volatile("dmb":::"memory");
	105	return 0;
	106	}
	107	]])
	108	],[
	109	AC_MSG_RESULT([yes])
	110	AC_DEFINE([CONFIG_RCU_ARM_HAVE_DMB], [1])
	111	],[
	112	AC_MSG_RESULT([no])
	113	])
	114	])
	115
	116	# Tile-specific checks
	117	AS_IF([echo "$host_cpu" \| grep "^tile"],[
	118	AC_MSG_CHECKING([for Tile architecture type])
	119	AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
	120	#ifndef __tilegx__
	121	#error
	122	#endif
	123	]])
	124	],[
	125	AC_MSG_RESULT([ok])
	126	],[
	127	AC_MSG_FAILURE([URCU has only been tested on the TileGx architecture. For other Tile* architectures, please run the tests first and report the results to the maintainer so that proper support can be added.])
	128	])
	129	])
	130
	131	# x86-specific checks
	132	AS_IF([test "x$ARCHTYPE" = "xx86"],[
	133	AC_MSG_CHECKING([if architecture really supports the mfence instruction])
	134	#For now, using lock; addl compatibility mode even for i686, because the
	135	#Pentium III is seen as a i686, but lacks mfence instruction.
	136	#Only using fence for x86_64.
	137	AS_IF([test "x$host_cpu" != "xi386" -a "x$host_cpu" != "xi486" -a "x$host_cpu" != "xi586" -a "x$host_cpu" != "xi686"],[
	138	AC_MSG_RESULT([yes])
	139	AC_DEFINE([CONFIG_RCU_HAVE_FENCE], [1])
	140	],[
	141	AC_MSG_RESULT([no])
	142	])
	143	])
	144
	145	# Check if sys_futex() is available
	146	AC_MSG_CHECKING([for sys_futex()])
	147	AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
	148	#include <sys/syscall.h>
	149	#ifndef __NR_futex
	150	#error "futexes not available"
	151	#endif
	152	]])
	153	],[
	154	AC_MSG_RESULT([yes])
	155	AC_DEFINE([CONFIG_RCU_HAVE_FUTEX], [1])
	156	compat_futex_test=0
	157	],[
	158	AC_MSG_RESULT([no])
	159	compat_futex_test=1
	160	])
	161
	162	AM_CONDITIONAL([COMPAT_FUTEX], [test "x$compat_futex_test" = "x1"])
	163	AM_CONDITIONAL([COMPAT_ARCH], [test "x$SUBARCHTYPE" = "xx86compat"])
	164
	165	# smp-support configure option
	166	AC_ARG_ENABLE([smp-support],
	167	AS_HELP_STRING([--disable-smp-support], [Disable SMP support. Warning: only use this on uniprocessor systems. [default=enabled]]),
	168	[def_smp_support=$enableval],
	169	[def_smp_support="yes"])
	170	AS_IF([test "x$def_smp_support" = "xyes"], [AC_DEFINE([CONFIG_RCU_SMP], [1])])
	171
	172
	173	# From the sched_setaffinity(2)'s man page:
	174	# ~~~~
	175	# The CPU affinity system calls were introduced in Linux kernel 2.5.8.
	176	# The library interfaces were introduced in glibc 2.3. Initially, the
	177	# glibc interfaces included a cpusetsize argument. In glibc 2.3.3,
	178	# the cpuset size argument was removed, but this argument was
	179	# restored in glibc 2.3.4.
	180	# ~~~~
	181
	182	# In addition to that, some vendors ported the system call to 2.4
	183	# kernels.
	184
	185	# Furthermore, when the function first appeared, the MASK argument was
	186	# an unsigned long pointer, while later it was made into a cpu_set_t
	187	# pointer. Systems that have the cpu_set_t version also should have
	188	# the CPU_ZERO, CPU_SET, etc. macros.
	189
	190	# All this mess means we have to cater for at least 3 different
	191	# sched_setaffinity prototypes:
	192
	193	# ~~~~
	194	# int sched_setaffinity (pid_t pid, unsigned int len, unsigned long *mask);
	195	# int sched_setaffinity (pid_t __pid, size_t __cpusetsize, const cpu_set_t *__cpuset);
	196	# int sched_setaffinity (pid_t __pid, const cpu_set_t *__mask);
	197	# ~~~~
	198
	199	# Since we define _GNU_SOURCE in the sources, must do so too in the
	200	# autoconf tests, as defining _GNU_SOURCE or not exposes
	201	# sched_setaffinity bits differently.
	202	saved_CFLAGS=$CFLAGS
	203	CFLAGS="$CFLAGS -D_GNU_SOURCE"
	204
	205	# First check if the function is available at all.
	206	AC_CHECK_FUNCS([sched_setaffinity],[
	207	# Okay, we have it. Check if also have cpu_set_t. If we don't,
	208	# then we have the first version using unsigned long, and no
	209	# CPU_ZERO, etc. macros. If we do have cpu_set_t, we may have the
	210	# version with 2 or 3 arguments. In that case, CPU_ZERO, etc.,
	211	# should also be present, but we confirm nonetheless.
	212
	213	AC_CHECK_TYPES([cpu_set_t],[
	214	# We do have it. Confirm that we have CPU_ZERO, and it actually works.
	215	AC_MSG_CHECKING([whether CPU_ZERO works])
	216	AH_TEMPLATE([HAVE_CPU_ZERO], [Defined to 1 if we have CPU_ZERO and it works])
	217	AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
	218	#define _GNU_SOURCE
	219	#include <sched.h>
	220	int main()
	221	{
	222	cpu_set_t foo; CPU_ZERO (&foo);
	223	return 0;
	224	}
	225	]])
	226	],[
	227	# Works!
	228	AC_DEFINE(HAVE_CPU_ZERO, 1)
	229	AC_MSG_RESULT([yes])
	230	],[
	231	AC_MSG_RESULT([no])
	232	])
	233
	234	# Confirm that we have CPU_SET, and it actually works.
	235	AC_MSG_CHECKING([whether CPU_SET works])
	236	AH_TEMPLATE([HAVE_CPU_SET], [Defined to 1 if we have CPU_SET and it works])
	237	AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
	238	#define _GNU_SOURCE
	239	#include <sched.h>
	240	int main()
	241	{
	242	cpu_set_t foo, mask; CPU_SET (0, &foo);
	243	return 0;
	244	}
	245	]])
	246	],[
	247	# Works!
	248	AC_DEFINE(HAVE_CPU_SET, 1)
	249	AC_MSG_RESULT([yes])
	250	],[
	251	AC_MSG_RESULT([no])
	252	])
	253
	254	# Check how many arguments does sched_setaffinity take.
	255	# Should be 3 or 2.
	256	AC_MSG_CHECKING([how many arguments sched_setaffinity takes])
	257	AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
	258	#include <sched.h>
	259	int main()
	260	{
	261	cpu_set_t foo;
	262	sched_setaffinity (0, sizeof (foo), &foo);
	263	return 0;
	264	}
	265	]])
	266	],
	267	[sched_set_affinity_args=3],
	268	[sched_set_affinity_args=2])
	269	AC_DEFINE_UNQUOTED(SCHED_SETAFFINITY_ARGS, $sched_set_affinity_args,
	270	[Defined to sched_setaffinity's number of arguments.])
	271	AC_MSG_RESULT([$sched_set_affinity_args])
	272	],[
	273	# No cpu_set_t, always 3 args.
	274	AC_DEFINE(SCHED_SETAFFINITY_ARGS, 3)
	275	],
	276	[#include <sched.h>])
	277	])
	278
	279	CFLAGS=$saved_CFLAGS
	280
	281	AC_CONFIG_LINKS([
	282	urcu/arch.h:$ARCHSRC
	283	urcu/uatomic.h:$UATOMICSRC
	284	])
	285	AC_CONFIG_FILES([
	286	Makefile
	287	doc/Makefile
	288	tests/Makefile
	289	liburcu.pc
	290	liburcu-bp.pc
	291	liburcu-cds.pc
	292	liburcu-qsbr.pc
	293	liburcu-mb.pc
	294	liburcu-signal.pc
	295	])
	296	AC_OUTPUT
	297
	298	# Report on selected configure options
	299	AS_IF([test "x$def_smp_support" = "xyes"],[
	300	AS_ECHO("SMP support enabled.")
	301	],[
	302	AS_ECHO("SMP support disabled.")
	303	])
	304
	305	AS_IF([test "x$def_tls_detect" = "x"],[
	306	AS_ECHO("Thread Local Storage (TLS): pthread_getspecific().")
	307	],[
	308	AS_ECHO("Thread Local Storage (TLS): $def_tls_detect.")
	309	])