[urcu.git] / configure.ac

dnl SPDX-License-Identifier: LGPL-2.1-only
dnl
dnl Copyright (C) 2021 EfficiOS, Inc.
dnl
dnl Process this file with autoconf to produce a configure script.

# Project version information
m4_define([urcu_version_major], [0])
m4_define([urcu_version_minor], [14])
m4_define([urcu_version_patch], [0])
m4_define([urcu_version_dev_stage], [-pre])
m4_define([urcu_version], urcu_version_major[.]urcu_version_minor[.]urcu_version_patch[]urcu_version_dev_stage)

# Library version information of "liburcu"
# Following the numbering scheme proposed by libtool for the library version
# http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
m4_define([urcu_lib_version_current], [9])
m4_define([urcu_lib_version_revision], [0])
m4_define([urcu_lib_version_age], [1])
m4_define([urcu_lib_version], urcu_lib_version_current[:]urcu_lib_version_revision[:]urcu_lib_version_age)


##                     ##
## Autoconf base setup ##
##                     ##

AC_PREREQ([2.69])
AC_INIT([userspace-rcu],[urcu_version],[mathieu dot desnoyers at efficios dot com],[],[http://liburcu.org/])

AC_CONFIG_HEADERS([include/config.h include/urcu/config.h])
AC_CONFIG_AUX_DIR([config])
AC_CONFIG_MACRO_DIR([m4])

AC_CANONICAL_TARGET
AC_CANONICAL_HOST


##                     ##
## Automake base setup ##
##                     ##

AM_INIT_AUTOMAKE([1.12 foreign dist-bzip2 no-dist-gzip nostdinc -Wall -Wno-portability -Werror])
AM_MAINTAINER_MODE([enable])

# Enable silent rules by default
AM_SILENT_RULES([yes])


##                               ##
## OS and Arch specific defaults ##
##                               ##

AS_CASE([$host],
  [*-cygwin*], [LT_NO_UNDEFINED="-no-undefined"]
)


##                   ##
## C compiler checks ##
##                   ##

# Choose the C compiler
AC_PROG_CC
# AC_PROG_CC_STDC was merged in AC_PROG_CC in autoconf 2.70
m4_version_prereq([2.70], [], [AC_PROG_CC_STDC])

# Make sure the C compiler supports C99
AS_IF([test "$ac_cv_prog_cc_c99" = "no"], [AC_MSG_ERROR([The compiler does not support C99])])

# Enable available system extensions and LFS support
AC_USE_SYSTEM_EXTENSIONS
AC_SYS_LARGEFILE

##                     ##
## C++ compiler checks ##
##                     ##

# Require a C++11 compiler without GNU extensions (-std=c++11)
AX_CXX_COMPILE_STDCXX([11], [noext], [mandatory])

# Make sure the C compiler supports __attribute__
AX_C___ATTRIBUTE__
AS_IF([test "x$ax_cv___attribute__" != "xyes"],
  [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])

# Make sure we have pthread support
AX_PTHREAD([], [AC_MSG_ERROR([Could not configure pthread support])])

# Checks for typedefs, structures, and compiler characteristics.
AC_C_INLINE
AC_C_TYPEOF
AC_TYPE_INT32_T
AC_TYPE_PID_T
AC_TYPE_SIZE_T
AC_TYPE_SSIZE_T
AC_TYPE_UINT16_T
AC_TYPE_UINT32_T
AC_TYPE_UINT64_T
AC_TYPE_UINT8_T

# Detect warning flags supported by the C compiler and append them to
# WARN_CFLAGS.
m4_define([WARN_FLAGS_LIST], [ dnl
  -Wall dnl
  -Wextra dnl
  -Wmissing-prototypes dnl
  -Wmissing-declarations dnl
  -Wnull-dereference dnl
  -Wundef dnl
  -Wshadow dnl
  -Wjump-misses-init dnl
  -Wsuggest-attribute=format dnl
  -Wtautological-constant-out-of-range-compare dnl
  -Wnested-externs dnl
  -Wwrite-strings dnl
  -Wformat=2 dnl
  -Wstrict-aliasing dnl
  -Wmissing-noreturn dnl
  -Winit-self dnl
  -Wduplicated-cond dnl
  -Wduplicated-branches dnl
  -Wlogical-op dnl
  dnl
  dnl-Wredundant-decls dnl
  -Wno-null-dereference dnl
])

# Pass -Werror as an extra flag during the test: this is needed to make the
# -Wunknown-warning-option diagnostic fatal with clang.
AC_LANG_PUSH([C])
AX_APPEND_COMPILE_FLAGS([WARN_FLAGS_LIST], [WARN_CFLAGS], [-Werror])
AC_LANG_POP([C])

AC_LANG_PUSH([C++])
AX_APPEND_COMPILE_FLAGS([WARN_FLAGS_LIST], [WARN_CXXFLAGS], [-Werror])
AC_LANG_POP([C++])

AE_IF_FEATURE_ENABLED([Werror], [WARN_CFLAGS="${WARN_CFLAGS} -Werror"])
AE_IF_FEATURE_ENABLED([Werror], [WARN_CXXFLAGS="${WARN_CXXFLAGS} -Werror"])


##               ##
## Header checks ##
##               ##

AC_HEADER_STDBOOL
AC_CHECK_HEADERS([ \
	limits.h \
	stddef.h \
	sys/param.h \
	sys/time.h \
])


##                 ##
## Programs checks ##
##                 ##

AC_PROG_AWK
AC_PROG_GREP
AC_PROG_MAKE_SET
AC_CHECK_PROGS(NPROC, [nproc gnproc])
AC_CHECK_PROGS(GETCONF, [getconf])
AC_CHECK_PROGS(TIME, [time])

# Initialize and configure libtool
LT_INIT


##                ##
## Library checks ##
##                ##

# Checks for library functions.
AC_FUNC_MMAP
AC_FUNC_FORK
AC_CHECK_FUNCS([ \
	atexit \
	getcpuid \
	gettid \
	gettimeofday \
	memeset \
	memset \
	munmap \
	rand_r \
	sched_getcpu \
	sched_setaffinity \
	strerror \
	strtoul \
	sysconf \
])

# AC_FUNC_MALLOC causes problems when cross-compiling.
#AC_FUNC_MALLOC

# Search for clock_gettime() in -lrt
AC_SEARCH_LIBS([clock_gettime], [rt], [
  AC_DEFINE([CONFIG_RCU_HAVE_CLOCK_GETTIME], [1], [clock_gettime() is detected.])
])


##                             ##
## Optional features selection ##
##                             ##

# Allow to fallback to FIXME if the membarrier syscall is unavailable on the
# running kernel, when disabled, abort if the syscall is unavailable. Applies
# to default and bulletproof flavors.
# Enabled by default
AE_FEATURE_DEFAULT_ENABLE
AE_FEATURE([sys-membarrier-fallback], [Abort if sys-membarrier is needed but not available rather than using a fallback.])

# Use compiler Thread Local Storage, when disabled use pthread_getspecific() to emulate TLS.
# Enabled by default
AE_FEATURE_DEFAULT_ENABLE
AE_FEATURE([compiler-tls], [Use pthread_getspecific() to emulate Thread Local Storage (TLS) variables.])

# smp-support configure option
# Enabled by default
AE_FEATURE_DEFAULT_ENABLE
AE_FEATURE([smp-support], [Disable SMP support. Warning: only use this on uniprocessor systems.])

# RCU debugging option
# Disabled by default
AE_FEATURE_DEFAULT_DISABLE
AE_FEATURE([rcu-debug], [Enable internal debugging self-checks. Introduces a performance penalty.])

# rculfhash iterator debugging
# Disabled by default
AE_FEATURE_DEFAULT_DISABLE
AE_FEATURE([cds-lfht-iter-debug], [Enable extra debugging checks for lock-free hash table iterator traversal. Alters the rculfhash ABI. Make sure to compile both library and application with matching configuration.])

# When given, add -Werror to WARN_CFLAGS and WARN_CXXFLAGS.
# Disabled by default
AE_FEATURE_DEFAULT_DISABLE
AE_FEATURE([Werror],[Treat compiler warnings as errors.])

##                                                                    ##
## Set defines for optional features conditionnals in the source code ##
##                                                                    ##

AE_IF_FEATURE_DISABLED([sys-membarrier-fallback], [
  AC_DEFINE([CONFIG_RCU_FORCE_SYS_MEMBARRIER], [1], [Require the operating system to support the membarrier system call for default and bulletproof flavors.])
])

AE_IF_FEATURE_ENABLED([compiler-tls], [
  AC_DEFINE([CONFIG_RCU_TLS], [1], [Use compiler provided Thread Local Storage.])
])

AE_IF_FEATURE_ENABLED([smp-support], [
  AC_DEFINE([CONFIG_RCU_SMP], [1], [Enable SMP support. With SMP support enabled, uniprocessors are also supported. With SMP support disabled, UP systems work fine, but the behavior of SMP systems is undefined.])
])

AE_IF_FEATURE_ENABLED([rcu-debug], [
  AC_DEFINE([CONFIG_RCU_DEBUG], [1], [Enable internal debugging self-checks. Introduces a performance penalty.])
])

AE_IF_FEATURE_ENABLED([cds-lfht-iter-debug], [
  AC_DEFINE([CONFIG_CDS_LFHT_ITER_DEBUG], [1], [Enable extra debugging checks for lock-free hash table iterator traversal. Alters the rculfhash ABI. Make sure to compile both library and application with matching configuration.])
])


##                                                                          ##
## Set automake variables for optional feature conditionnals in Makefile.am ##
##                                                                          ##

# Building the examples requires the shared libraries to be enabled
AM_CONDITIONAL([ENABLE_EXAMPLES], AE_IS_FEATURE_ENABLED([shared]))


##                                             ##
## Substitute variables for use in Makefile.am ##
##                                             ##

# Library versions for libtool
AC_SUBST([URCU_LIBRARY_VERSION], [urcu_lib_version])

AC_SUBST(LT_NO_UNDEFINED)

# The order in which the include folders are searched is important.
# The top_builddir should always be searched first in the event that a build
# time generated file is included.
AM_CPPFLAGS="-I\$(top_builddir)/include -I\$(top_srcdir)/include -include config.h"
AC_SUBST(AM_CPPFLAGS)

AM_CFLAGS="$WARN_CFLAGS $PTHREAD_CFLAGS"
AC_SUBST(AM_CFLAGS)

AM_CXXFLAGS="$WARN_CXXFLAGS $PTHREAD_CFLAGS"
AC_SUBST(AM_CXXFLAGS)


##                                     ##
## Output files generated by configure ##
##                                     ##

AC_CONFIG_FILES([
	Makefile
	doc/Makefile
	doc/examples/Makefile
	extras/Makefile
	include/Makefile
	src/Makefile
	tests/Makefile
	tests/common/Makefile
	tests/unit/Makefile
	tests/benchmark/Makefile
	tests/regression/Makefile
	tests/utils/Makefile
	src/liburcu.pc
	src/liburcu-bp.pc
	src/liburcu-cds.pc
	src/liburcu-qsbr.pc
	src/liburcu-mb.pc
	src/liburcu-memb.pc
	src/liburcu-signal.pc
])

AC_CONFIG_FILES([tests/utils/env.sh],[chmod +x tests/utils/env.sh])


AC_OUTPUT

#
# Mini-report on what will be built.
#

PPRINT_INIT
PPRINT_SET_INDENT(1)
PPRINT_SET_TS(38)

AS_ECHO
AS_ECHO("${PPRINT_COLOR_BLDBLU}Userspace-RCU $PACKAGE_VERSION${PPRINT_COLOR_RST}")
AS_ECHO

PPRINT_SUBTITLE([Features])

PPRINT_PROP_STRING([Target architecture], $host_cpu)

# SMP support enabled/disabled
AE_IS_FEATURE_ENABLED([smp-support]) && value=1 || value=0
PPRINT_PROP_BOOL([SMP support], $value)

# TLS
AE_IS_FEATURE_ENABLED([compiler-tls]) && value="compiler TLS" || value="pthread_getspecific()"
PPRINT_PROP_STRING([Thread Local Storage (TLS)], [$value])

# clock_gettime() available
test "x$ac_cv_search_function_clock_gettime" != "xno" && value=1 || value=0
PPRINT_PROP_BOOL([clock_gettime()], $value)

# Require membarrier
AE_IS_FEATURE_ENABLED([sys-membarrier-fallback]) && value=0 || value=1
PPRINT_PROP_BOOL([Require membarrier], $value)

# RCU debug enabled/disabled
AE_IS_FEATURE_ENABLED([rcu-debug]) && value=1 || value=0
PPRINT_PROP_BOOL([Internal debugging], $value)

# rculfhash iterator debug enabled/disabled
AE_IS_FEATURE_ENABLED([cds-lfht-iter-debug]) && value=1 || value=0
PPRINT_PROP_BOOL([Lock-free HT iterator debugging], $value)

PPRINT_PROP_BOOL([Multi-flavor support], 1)

report_bindir="`eval eval echo $bindir`"
report_libdir="`eval eval echo $libdir`"

# Print the bindir and libdir this 'make install' will install into.
AS_ECHO
PPRINT_SUBTITLE([Install directories])
PPRINT_PROP_STRING([Binaries], [$report_bindir])
PPRINT_PROP_STRING([Libraries], [$report_libdir])
Commit	Line	Data
	1	dnl SPDX-License-Identifier: LGPL-2.1-only
	2	dnl
	3	dnl Copyright (C) 2021 EfficiOS, Inc.
	4	dnl
	5	dnl Process this file with autoconf to produce a configure script.
	6
	7	# Project version information
	8	m4_define([urcu_version_major], [0])
	9	m4_define([urcu_version_minor], [14])
	10	m4_define([urcu_version_patch], [0])
	11	m4_define([urcu_version_dev_stage], [-pre])
	12	m4_define([urcu_version], urcu_version_major[.]urcu_version_minor[.]urcu_version_patch[]urcu_version_dev_stage)
	13
	14	# Library version information of "liburcu"
	15	# Following the numbering scheme proposed by libtool for the library version
	16	# http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
	17	m4_define([urcu_lib_version_current], [9])
	18	m4_define([urcu_lib_version_revision], [0])
	19	m4_define([urcu_lib_version_age], [1])
	20	m4_define([urcu_lib_version], urcu_lib_version_current[:]urcu_lib_version_revision[:]urcu_lib_version_age)
	21
	22
	23	## ##
	24	## Autoconf base setup ##
	25	## ##
	26
	27	AC_PREREQ([2.69])
	28	AC_INIT([userspace-rcu],[urcu_version],[mathieu dot desnoyers at efficios dot com],[],[http://liburcu.org/])
	29
	30	AC_CONFIG_HEADERS([include/config.h include/urcu/config.h])
	31	AC_CONFIG_AUX_DIR([config])
	32	AC_CONFIG_MACRO_DIR([m4])
	33
	34	AC_CANONICAL_TARGET
	35	AC_CANONICAL_HOST
	36
	37
	38	## ##
	39	## Automake base setup ##
	40	## ##
	41
	42	AM_INIT_AUTOMAKE([1.12 foreign dist-bzip2 no-dist-gzip nostdinc -Wall -Wno-portability -Werror])
	43	AM_MAINTAINER_MODE([enable])
	44
	45	# Enable silent rules by default
	46	AM_SILENT_RULES([yes])
	47
	48
	49	## ##
	50	## OS and Arch specific defaults ##
	51	## ##
	52
	53	AS_CASE([$host],
	54	[-cygwin], [LT_NO_UNDEFINED="-no-undefined"]
	55	)
	56
	57
	58	## ##
	59	## C compiler checks ##
	60	## ##
	61
	62	# Choose the C compiler
	63	AC_PROG_CC
	64	# AC_PROG_CC_STDC was merged in AC_PROG_CC in autoconf 2.70
	65	m4_version_prereq([2.70], [], [AC_PROG_CC_STDC])
	66
	67	# Make sure the C compiler supports C99
	68	AS_IF([test "$ac_cv_prog_cc_c99" = "no"], [AC_MSG_ERROR([The compiler does not support C99])])
	69
	70	# Enable available system extensions and LFS support
	71	AC_USE_SYSTEM_EXTENSIONS
	72	AC_SYS_LARGEFILE
	73
	74	## ##
	75	## C++ compiler checks ##
	76	## ##
	77
	78	# Require a C++11 compiler without GNU extensions (-std=c++11)
	79	AX_CXX_COMPILE_STDCXX([11], [noext], [mandatory])
	80
	81	# Make sure the C compiler supports __attribute__
	82	AX_C___ATTRIBUTE__
	83	AS_IF([test "x$ax_cv___attribute__" != "xyes"],
	84	[AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
	85
	86	# Make sure we have pthread support
	87	AX_PTHREAD([], [AC_MSG_ERROR([Could not configure pthread support])])
	88
	89	# Checks for typedefs, structures, and compiler characteristics.
	90	AC_C_INLINE
	91	AC_C_TYPEOF
	92	AC_TYPE_INT32_T
	93	AC_TYPE_PID_T
	94	AC_TYPE_SIZE_T
	95	AC_TYPE_SSIZE_T
	96	AC_TYPE_UINT16_T
	97	AC_TYPE_UINT32_T
	98	AC_TYPE_UINT64_T
	99	AC_TYPE_UINT8_T
	100
	101	# Detect warning flags supported by the C compiler and append them to
	102	# WARN_CFLAGS.
	103	m4_define([WARN_FLAGS_LIST], [ dnl
	104	-Wall dnl
	105	-Wextra dnl
	106	-Wmissing-prototypes dnl
	107	-Wmissing-declarations dnl
	108	-Wnull-dereference dnl
	109	-Wundef dnl
	110	-Wshadow dnl
	111	-Wjump-misses-init dnl
	112	-Wsuggest-attribute=format dnl
	113	-Wtautological-constant-out-of-range-compare dnl
	114	-Wnested-externs dnl
	115	-Wwrite-strings dnl
	116	-Wformat=2 dnl
	117	-Wstrict-aliasing dnl
	118	-Wmissing-noreturn dnl
	119	-Winit-self dnl
	120	-Wduplicated-cond dnl
	121	-Wduplicated-branches dnl
	122	-Wlogical-op dnl
	123	dnl
	124	dnl-Wredundant-decls dnl
	125	-Wno-null-dereference dnl
	126	])
	127
	128	# Pass -Werror as an extra flag during the test: this is needed to make the
	129	# -Wunknown-warning-option diagnostic fatal with clang.
	130	AC_LANG_PUSH([C])
	131	AX_APPEND_COMPILE_FLAGS([WARN_FLAGS_LIST], [WARN_CFLAGS], [-Werror])
	132	AC_LANG_POP([C])
	133
	134	AC_LANG_PUSH([C++])
	135	AX_APPEND_COMPILE_FLAGS([WARN_FLAGS_LIST], [WARN_CXXFLAGS], [-Werror])
	136	AC_LANG_POP([C++])
	137
	138	AE_IF_FEATURE_ENABLED([Werror], [WARN_CFLAGS="${WARN_CFLAGS} -Werror"])
	139	AE_IF_FEATURE_ENABLED([Werror], [WARN_CXXFLAGS="${WARN_CXXFLAGS} -Werror"])
	140
	141
	142	## ##
	143	## Header checks ##
	144	## ##
	145
	146	AC_HEADER_STDBOOL
	147	AC_CHECK_HEADERS([ \
	148	limits.h \
	149	stddef.h \
	150	sys/param.h \
	151	sys/time.h \
	152	])
	153
	154
	155	## ##
	156	## Programs checks ##
	157	## ##
	158
	159	AC_PROG_AWK
	160	AC_PROG_GREP
	161	AC_PROG_MAKE_SET
	162	AC_CHECK_PROGS(NPROC, [nproc gnproc])
	163	AC_CHECK_PROGS(GETCONF, [getconf])
	164	AC_CHECK_PROGS(TIME, [time])
	165
	166	# Initialize and configure libtool
	167	LT_INIT
	168
	169
	170	## ##
	171	## Library checks ##
	172	## ##
	173
	174	# Checks for library functions.
	175	AC_FUNC_MMAP
	176	AC_FUNC_FORK
	177	AC_CHECK_FUNCS([ \
	178	atexit \
	179	getcpuid \
	180	gettid \
	181	gettimeofday \
	182	memeset \
	183	memset \
	184	munmap \
	185	rand_r \
	186	sched_getcpu \
	187	sched_setaffinity \
	188	strerror \
	189	strtoul \
	190	sysconf \
	191	])
	192
	193	# AC_FUNC_MALLOC causes problems when cross-compiling.
	194	#AC_FUNC_MALLOC
	195
	196	# Search for clock_gettime() in -lrt
	197	AC_SEARCH_LIBS([clock_gettime], [rt], [
	198	AC_DEFINE([CONFIG_RCU_HAVE_CLOCK_GETTIME], [1], [clock_gettime() is detected.])
	199	])
	200
	201
	202	## ##
	203	## Optional features selection ##
	204	## ##
	205
	206	# Allow to fallback to FIXME if the membarrier syscall is unavailable on the
	207	# running kernel, when disabled, abort if the syscall is unavailable. Applies
	208	# to default and bulletproof flavors.
	209	# Enabled by default
	210	AE_FEATURE_DEFAULT_ENABLE
	211	AE_FEATURE([sys-membarrier-fallback], [Abort if sys-membarrier is needed but not available rather than using a fallback.])
	212
	213	# Use compiler Thread Local Storage, when disabled use pthread_getspecific() to emulate TLS.
	214	# Enabled by default
	215	AE_FEATURE_DEFAULT_ENABLE
	216	AE_FEATURE([compiler-tls], [Use pthread_getspecific() to emulate Thread Local Storage (TLS) variables.])
	217
	218	# smp-support configure option
	219	# Enabled by default
	220	AE_FEATURE_DEFAULT_ENABLE
	221	AE_FEATURE([smp-support], [Disable SMP support. Warning: only use this on uniprocessor systems.])
	222
	223	# RCU debugging option
	224	# Disabled by default
	225	AE_FEATURE_DEFAULT_DISABLE
	226	AE_FEATURE([rcu-debug], [Enable internal debugging self-checks. Introduces a performance penalty.])
	227
	228	# rculfhash iterator debugging
	229	# Disabled by default
	230	AE_FEATURE_DEFAULT_DISABLE
	231	AE_FEATURE([cds-lfht-iter-debug], [Enable extra debugging checks for lock-free hash table iterator traversal. Alters the rculfhash ABI. Make sure to compile both library and application with matching configuration.])
	232
	233	# When given, add -Werror to WARN_CFLAGS and WARN_CXXFLAGS.
	234	# Disabled by default
	235	AE_FEATURE_DEFAULT_DISABLE
	236	AE_FEATURE([Werror],[Treat compiler warnings as errors.])
	237
	238	## ##
	239	## Set defines for optional features conditionnals in the source code ##
	240	## ##
	241
	242	AE_IF_FEATURE_DISABLED([sys-membarrier-fallback], [
	243	AC_DEFINE([CONFIG_RCU_FORCE_SYS_MEMBARRIER], [1], [Require the operating system to support the membarrier system call for default and bulletproof flavors.])
	244	])
	245
	246	AE_IF_FEATURE_ENABLED([compiler-tls], [
	247	AC_DEFINE([CONFIG_RCU_TLS], [1], [Use compiler provided Thread Local Storage.])
	248	])
	249
	250	AE_IF_FEATURE_ENABLED([smp-support], [
	251	AC_DEFINE([CONFIG_RCU_SMP], [1], [Enable SMP support. With SMP support enabled, uniprocessors are also supported. With SMP support disabled, UP systems work fine, but the behavior of SMP systems is undefined.])
	252	])
	253
	254	AE_IF_FEATURE_ENABLED([rcu-debug], [
	255	AC_DEFINE([CONFIG_RCU_DEBUG], [1], [Enable internal debugging self-checks. Introduces a performance penalty.])
	256	])
	257
	258	AE_IF_FEATURE_ENABLED([cds-lfht-iter-debug], [
	259	AC_DEFINE([CONFIG_CDS_LFHT_ITER_DEBUG], [1], [Enable extra debugging checks for lock-free hash table iterator traversal. Alters the rculfhash ABI. Make sure to compile both library and application with matching configuration.])
	260	])
	261
	262
	263	## ##
	264	## Set automake variables for optional feature conditionnals in Makefile.am ##
	265	## ##
	266
	267	# Building the examples requires the shared libraries to be enabled
	268	AM_CONDITIONAL([ENABLE_EXAMPLES], AE_IS_FEATURE_ENABLED([shared]))
	269
	270
	271	## ##
	272	## Substitute variables for use in Makefile.am ##
	273	## ##
	274
	275	# Library versions for libtool
	276	AC_SUBST([URCU_LIBRARY_VERSION], [urcu_lib_version])
	277
	278	AC_SUBST(LT_NO_UNDEFINED)
	279
	280	# The order in which the include folders are searched is important.
	281	# The top_builddir should always be searched first in the event that a build
	282	# time generated file is included.
	283	AM_CPPFLAGS="-I\$(top_builddir)/include -I\$(top_srcdir)/include -include config.h"
	284	AC_SUBST(AM_CPPFLAGS)
	285
	286	AM_CFLAGS="$WARN_CFLAGS $PTHREAD_CFLAGS"
	287	AC_SUBST(AM_CFLAGS)
	288
	289	AM_CXXFLAGS="$WARN_CXXFLAGS $PTHREAD_CFLAGS"
	290	AC_SUBST(AM_CXXFLAGS)
	291
	292
	293	## ##
	294	## Output files generated by configure ##
	295	## ##
	296
	297	AC_CONFIG_FILES([
	298	Makefile
	299	doc/Makefile
	300	doc/examples/Makefile
	301	extras/Makefile
	302	include/Makefile
	303	src/Makefile
	304	tests/Makefile
	305	tests/common/Makefile
	306	tests/unit/Makefile
	307	tests/benchmark/Makefile
	308	tests/regression/Makefile
	309	tests/utils/Makefile
	310	src/liburcu.pc
	311	src/liburcu-bp.pc
	312	src/liburcu-cds.pc
	313	src/liburcu-qsbr.pc
	314	src/liburcu-mb.pc
	315	src/liburcu-memb.pc
	316	src/liburcu-signal.pc
	317	])
	318
	319	AC_CONFIG_FILES([tests/utils/env.sh],[chmod +x tests/utils/env.sh])
	320
	321
	322	AC_OUTPUT
	323
	324	#
	325	# Mini-report on what will be built.
	326	#
	327
	328	PPRINT_INIT
	329	PPRINT_SET_INDENT(1)
	330	PPRINT_SET_TS(38)
	331
	332	AS_ECHO
	333	AS_ECHO("${PPRINT_COLOR_BLDBLU}Userspace-RCU $PACKAGE_VERSION${PPRINT_COLOR_RST}")
	334	AS_ECHO
	335
	336	PPRINT_SUBTITLE([Features])
	337
	338	PPRINT_PROP_STRING([Target architecture], $host_cpu)
	339
	340	# SMP support enabled/disabled
	341	AE_IS_FEATURE_ENABLED([smp-support]) && value=1 \|\| value=0
	342	PPRINT_PROP_BOOL([SMP support], $value)
	343
	344	# TLS
	345	AE_IS_FEATURE_ENABLED([compiler-tls]) && value="compiler TLS" \|\| value="pthread_getspecific()"
	346	PPRINT_PROP_STRING([Thread Local Storage (TLS)], [$value])
	347
	348	# clock_gettime() available
	349	test "x$ac_cv_search_function_clock_gettime" != "xno" && value=1 \|\| value=0
	350	PPRINT_PROP_BOOL([clock_gettime()], $value)
	351
	352	# Require membarrier
	353	AE_IS_FEATURE_ENABLED([sys-membarrier-fallback]) && value=0 \|\| value=1
	354	PPRINT_PROP_BOOL([Require membarrier], $value)
	355
	356	# RCU debug enabled/disabled
	357	AE_IS_FEATURE_ENABLED([rcu-debug]) && value=1 \|\| value=0
	358	PPRINT_PROP_BOOL([Internal debugging], $value)
	359
	360	# rculfhash iterator debug enabled/disabled
	361	AE_IS_FEATURE_ENABLED([cds-lfht-iter-debug]) && value=1 \|\| value=0
	362	PPRINT_PROP_BOOL([Lock-free HT iterator debugging], $value)
	363
	364	PPRINT_PROP_BOOL([Multi-flavor support], 1)
	365
	366	report_bindir="`eval eval echo $bindir`"
	367	report_libdir="`eval eval echo $libdir`"
	368
	369	# Print the bindir and libdir this 'make install' will install into.
	370	AS_ECHO
	371	PPRINT_SUBTITLE([Install directories])
	372	PPRINT_PROP_STRING([Binaries], [$report_bindir])
	373	PPRINT_PROP_STRING([Libraries], [$report_libdir])
	374