[urcu.git] / configure.ac

AC_PREREQ(2.59)
AC_INIT([userspace-rcu],[0.9.7],[mathieu dot desnoyers at efficios dot com], [], [http://liburcu.org/])

# Following the numbering scheme proposed by libtool for the library version
# http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
AC_SUBST([URCU_LIBRARY_VERSION], [5:0:1])

AC_CONFIG_SRCDIR([urcu.h])
AC_CONFIG_HEADERS([config.h urcu/config.h])
AC_CONFIG_AUX_DIR([config])
AC_CONFIG_MACRO_DIR([m4])

AC_CANONICAL_TARGET
AC_CANONICAL_HOST

AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
AM_MAINTAINER_MODE([enable])

# Enable silent rules if available (Introduced in AM 1.11)
m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])

AH_TEMPLATE([CONFIG_RCU_SMP], [Enable SMP support. With SMP support enabled, uniprocessors are also supported. With SMP support disabled, UP systems work fine, but the behavior of SMP systems is undefined.])
AH_TEMPLATE([CONFIG_RCU_HAVE_FENCE], [Defined when on a system that has memory fence instructions.])
AH_TEMPLATE([CONFIG_RCU_HAVE_FUTEX], [Defined when on a system with futex support.])
AH_TEMPLATE([CONFIG_RCU_COMPAT_ARCH], [Compatibility mode for i386 which lacks cmpxchg instruction.])
AH_TEMPLATE([CONFIG_RCU_ARM_HAVE_DMB], [Use the dmb instruction if available for use on ARM.])
AH_TEMPLATE([CONFIG_RCU_TLS], [TLS provided by the compiler.])
AH_TEMPLATE([CONFIG_RCU_HAVE_CLOCK_GETTIME], [clock_gettime() is detected.])

# Allow overriding storage used for TLS variables.
AC_ARG_ENABLE([compiler-tls],
	AS_HELP_STRING([--disable-compiler-tls], [Use pthread_getspecific() to emulate Thread Local Storage (TLS) variables.]),
	[def_compiler_tls=$enableval],
	[def_compiler_tls="yes"])

AS_IF([test "x$def_compiler_tls" = "xyes"], AC_DEFINE([CONFIG_RCU_TLS], [1]), [:])

# Checks for C compiler
AC_USE_SYSTEM_EXTENSIONS
AC_PROG_CC
AC_PROG_CC_STDC

# Checks for programs.
AC_PROG_AWK
AC_PROG_MAKE_SET
AC_CHECK_PROGS(NPROC, [nproc gnproc])
AC_CHECK_PROGS(GETCONF, [getconf])
AS_IF([test "x$NPROC" != "x"],
	[NPROC_CMD=$NPROC],
	[AS_IF([test "x$GETCONF" != "x"],
		[NPROC_CMD="$GETCONF _NPROCESSORS_ONLN"],
		[NPROC_CMD="echo 1"]
	)]
)
AC_SUBST([NPROC_CMD], [$NPROC_CMD])

LT_INIT

# Checks for typedefs, structures, and compiler characteristics.
AC_C_INLINE
AC_TYPE_PID_T
AC_TYPE_SIZE_T
AC_TYPE_SSIZE_T
AC_TYPE_UINT16_T
AC_TYPE_INT32_T
AC_TYPE_UINT32_T
AC_TYPE_UINT64_T
AC_TYPE_UINT8_T

AX_C___ATTRIBUTE__
AS_IF([test "x$ax_cv___attribute__" = "xyes"],
	[:],
	[AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])

AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])

AM_CFLAGS="$AM_CFLAGS $PTHREAD_CFLAGS"

# Checks for library functions.
AC_FUNC_MMAP
AC_FUNC_FORK
AC_CHECK_FUNCS([ \
	atexit \
	getcpuid \
	gettid \
	gettimeofday \
	memeset \
	memset \
	munmap \
	sched_getcpu \
	strerror \
	strtoul \
	sysconf \
])

# AC_FUNC_MALLOC causes problems when cross-compiling.
#AC_FUNC_MALLOC

# Check for headers
AC_HEADER_STDBOOL
AC_CHECK_HEADERS([ \
	limits.h \
	stddef.h \
	sys/param.h \
	sys/time.h \
])

# Find arch type
AS_CASE([$host_cpu],
	[k1om], [ARCHTYPE="x86"],
	[i386], [ARCHTYPE="x86" && SUBARCHTYPE="x86compat"],
	[i486], [ARCHTYPE="x86"],
	[i586], [ARCHTYPE="x86"],
	[i686], [ARCHTYPE="x86"],
	[amd64], [ARCHTYPE="x86"],
	[x86_64], [ARCHTYPE="x86"],
	[powerpc], [ARCHTYPE="ppc"],
	[ppc64], [ARCHTYPE="ppc"],
	[powerpc64], [ARCHTYPE="ppc"],
	[powerpc64le], [ARCHTYPE="ppc"],
	[ppc], [ARCHTYPE="ppc"],
	[s390], [ARCHTYPE="s390"],
	[s390x], [ARCHTYPE="s390"],
	[sparc], [ARCHTYPE="sparc64"],
	[sparc64], [ARCHTYPE="sparc64"],
	[alpha*], [ARCHTYPE="alpha"],
	[ia64], [ARCHTYPE="ia64"],
	[arm*], [ARCHTYPE="arm"],
	[aarch64*], [ARCHTYPE="aarch64"],
	[mips*], [ARCHTYPE="mips"],
	[tile*], [ARCHTYPE="tile"],
	[hppa*], [ARCHTYPE="hppa"],
	[ARCHTYPE="unknown"]
)

AS_CASE([$host],[*-*-linux-androideabi],
	[AM_CONDITIONAL(TARGET_IS_ANDROID, true)],
	[AM_CONDITIONAL(TARGET_IS_ANDROID, false)]
)

AS_CASE([$host],[*-cygwin*],
	[AM_CONDITIONAL(USE_CYGWIN, true)],
	[AM_CONDITIONAL(USE_CYGWIN, false)]
)

AC_SUBST(ARCHTYPE)
AC_SUBST(SUBARCHTYPE)

UATOMICSRC=urcu/uatomic/$ARCHTYPE.h
ARCHSRC=urcu/arch/$ARCHTYPE.h

AS_IF([test "x$SUBARCHTYPE" = xx86compat],[
	AC_DEFINE([CONFIG_RCU_COMPAT_ARCH], [1])
])

AS_IF([test "$host_cpu" = "armv7l"],[
	AM_CFLAGS="$AM_CFLAGS -mcpu=cortex-a9 -mtune=cortex-a9 -O1"
])

# ARM-specific checks
AS_IF([test "x$ARCHTYPE" = "xarm"],[
	AC_MSG_CHECKING([for dmb instruction])
	AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
				int main()
				{
					asm volatile("dmb":::"memory");
					return 0;
				}
		]])
	],[
		AC_MSG_RESULT([yes])
		AC_DEFINE([CONFIG_RCU_ARM_HAVE_DMB], [1])
	],[
		AC_MSG_RESULT([no])
	])
])

# Tile-specific checks
AS_IF([echo "$host_cpu" | grep "^tile"],[
	AC_MSG_CHECKING([for Tile architecture type])
	AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
				#ifndef __tilegx__
				#error
				#endif
		]])
	],[
		AC_MSG_RESULT([ok])
	],[
		AC_MSG_FAILURE([URCU has only been tested on the TileGx architecture. For other Tile* architectures, please run the tests first and report the results to the maintainer so that proper support can be added.])
	])
])

# x86-specific checks
AS_IF([test "x$ARCHTYPE" = "xx86"],[
	AC_MSG_CHECKING([if architecture really supports the mfence instruction])
	#For now, using lock; addl compatibility mode even for i686, because the
	#Pentium III is seen as a i686, but lacks mfence instruction.
	#Only using fence for x86_64.
	#
	#k1om is the name for the Intel MIC family (Xeon Phi). It is an x86_64
	#variant but lacks fence instructions.
	AS_IF([test "x$host_cpu" != "xi386" -a "x$host_cpu" != "xi486" -a "x$host_cpu" != "xi586" -a "x$host_cpu" != "xi686" -a "x$host_vendor" != "xk1om" -a "x$host_cpu" != "xk1om"],[
		AC_MSG_RESULT([yes])
		AC_DEFINE([CONFIG_RCU_HAVE_FENCE], [1])
	],[
		AC_MSG_RESULT([no])
	])
])

# Check if sys_futex() is available
AC_MSG_CHECKING([for sys_futex()])
AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
		#include <sys/syscall.h>
		#ifndef __NR_futex
		#error "futexes not available"
		#endif
	]])
],[
	AC_MSG_RESULT([yes])
	AC_DEFINE([CONFIG_RCU_HAVE_FUTEX], [1])
	compat_futex_test=0
],[
	AC_MSG_RESULT([no])
	compat_futex_test=1
])

# Search for clock_gettime
AC_SEARCH_LIBS([clock_gettime], [rt], [
	AC_DEFINE([CONFIG_RCU_HAVE_CLOCK_GETTIME], [1])
], [])

# Check for pthread
AC_CHECK_LIB([pthread], [pthread_create],
	[AM_CONDITIONAL(LIBC_INCLUDES_PTHREAD, false)],
	[AC_CHECK_LIB([c], [pthread_create],
		[AM_CONDITIONAL(LIBC_INCLUDES_PTHREAD, true)],
		[AC_MSG_ERROR([Cannot find libpthread. Use [LDFLAGS]=-Ldir to specify its location.])]
	)]
)

AM_CONDITIONAL([COMPAT_FUTEX], [test "x$compat_futex_test" = "x1"])
AM_CONDITIONAL([COMPAT_ARCH], [test "x$SUBARCHTYPE" = "xx86compat"])
AM_CONDITIONAL([NO_SHARED], [test "x$enable_shared" = "xno"])

# smp-support configure option
AC_ARG_ENABLE([smp-support], 
	AS_HELP_STRING([--disable-smp-support], [Disable SMP support. Warning: only use this on uniprocessor systems. [default=enabled]]),
	[def_smp_support=$enableval],
	[def_smp_support="yes"])
AS_IF([test "x$def_smp_support" = "xyes"], [AC_DEFINE([CONFIG_RCU_SMP], [1])])


# From the sched_setaffinity(2)'s man page:
# ~~~~
# The CPU affinity system calls were introduced in Linux kernel 2.5.8.
# The library interfaces were introduced in glibc 2.3.  Initially, the
# glibc interfaces included a cpusetsize argument.  In glibc 2.3.3,
# the cpuset size argument was removed, but this argument was
# restored in glibc 2.3.4.
# ~~~~

# In addition to that, some vendors ported the system call to 2.4
# kernels.

# Furthermore, when the function first appeared, the MASK argument was
# an unsigned long pointer, while later it was made into a cpu_set_t
# pointer.  Systems that have the cpu_set_t version also should have
# the CPU_ZERO, CPU_SET, etc. macros.

# All this mess means we have to cater for at least 3 different
# sched_setaffinity prototypes:

# ~~~~
#  int sched_setaffinity (pid_t pid, unsigned int len, unsigned long *mask);
#  int sched_setaffinity (pid_t __pid, size_t __cpusetsize, const cpu_set_t *__cpuset);
#  int sched_setaffinity (pid_t __pid, const cpu_set_t *__mask);
# ~~~~

# Since we define _GNU_SOURCE in the sources, must do so too in the
# autoconf tests, as defining _GNU_SOURCE or not exposes
# sched_setaffinity bits differently.
saved_CFLAGS="$CFLAGS"
CFLAGS="$CFLAGS $AM_CFLAGS -D_GNU_SOURCE"

AC_CHECK_TYPES([cpu_set_t],
	[have_cpu_set_t="yes"],
	[have_cpu_set_t="no"],
	[#include <sched.h>])

# Confirm that we have CPU_ZERO, and it actually works.
AC_MSG_CHECKING([whether CPU_ZERO works])
AH_TEMPLATE([HAVE_CPU_ZERO], [Defined to 1 if we have CPU_ZERO and it works])
AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
		#define _GNU_SOURCE
		#include <sched.h>
		int main()
		{
			cpu_set_t foo; CPU_ZERO(&foo);
			return 0;
		}
	]])
],[
	AC_DEFINE(HAVE_CPU_ZERO, 1)
	AC_MSG_RESULT([yes])
],[
	AC_MSG_RESULT([no])
])

# Confirm that we have CPU_SET, and it actually works.
AC_MSG_CHECKING([whether CPU_SET works])
AH_TEMPLATE([HAVE_CPU_SET], [Defined to 1 if we have CPU_SET and it works])
AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
		#define _GNU_SOURCE
		#include <sched.h>
		int main()
		{
			cpu_set_t foo, mask; CPU_SET(0, &foo);
			return 0;
		}
	]])
],[
	AC_DEFINE(HAVE_CPU_SET, 1)
	AC_MSG_RESULT([yes])
],[
	AC_MSG_RESULT([no])
])

# First check if the function is available at all.
AC_CHECK_FUNCS([sched_setaffinity],[
	# Okay, we have it.  Check if also have cpu_set_t.  If we don't,
	# then we have the first version using unsigned long, and no
	# CPU_ZERO, etc. macros.  If we do have cpu_set_t, we may have the
	# version with 2 or 3 arguments.  In that case, CPU_ZERO, etc.,
	# should also be present, but we confirm nonetheless.

	AS_IF([test "x$have_cpu_set_t" = "xyes"], [
		# We do have it.
		# Check how many arguments does sched_setaffinity take.
		# Should be 3 or 2.
		AC_MSG_CHECKING([how many arguments sched_setaffinity takes])
		AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
				#include <sched.h>
				int main()
				{
					cpu_set_t foo;
					sched_setaffinity(0, sizeof (foo), &foo);
					return 0;
				}
			]])
		],
		[sched_set_affinity_args=3],
		[sched_set_affinity_args=2])
		AC_DEFINE_UNQUOTED(SCHED_SETAFFINITY_ARGS,
			$sched_set_affinity_args,
			[Defined to sched_setaffinity's number of arguments.])
		AC_MSG_RESULT([$sched_set_affinity_args])
	],[
		# No cpu_set_t, always 3 args.
		AC_DEFINE(SCHED_SETAFFINITY_ARGS, 3)
	])
])

CFLAGS=$saved_CFLAGS
AC_SUBST(AM_CFLAGS)

AC_CONFIG_LINKS([
	urcu/arch.h:$ARCHSRC
	urcu/uatomic.h:$UATOMICSRC
])
AC_CONFIG_FILES([
	Makefile
	doc/Makefile
	doc/examples/Makefile
	tests/Makefile
	tests/common/Makefile
	tests/unit/Makefile
	tests/benchmark/Makefile
	tests/regression/Makefile
	tests/regression/regression_tests
	tests/utils/Makefile
	liburcu.pc
	liburcu-bp.pc
	liburcu-cds.pc
	liburcu-qsbr.pc
	liburcu-mb.pc
	liburcu-signal.pc
])
AC_OUTPUT

# Report on selected configure options
AS_IF([test "x$def_smp_support" = "xyes"],[
	AS_ECHO("SMP support enabled.")
],[
	AS_ECHO("SMP support disabled.")
])

AS_IF([test "x$def_compiler_tls" = "xyes"],[
	AS_ECHO("Thread Local Storage (TLS): compiler TLS.")
],[
	AS_ECHO("Thread Local Storage (TLS): pthread_getspecific().")
])
Commit	Line	Data
	1	AC_PREREQ(2.59)
	2	AC_INIT([userspace-rcu],[0.9.7],[mathieu dot desnoyers at efficios dot com], [], [http://liburcu.org/])
	3
	4	# Following the numbering scheme proposed by libtool for the library version
	5	# http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
	6	AC_SUBST([URCU_LIBRARY_VERSION], [5:0:1])
	7
	8	AC_CONFIG_SRCDIR([urcu.h])
	9	AC_CONFIG_HEADERS([config.h urcu/config.h])
	10	AC_CONFIG_AUX_DIR([config])
	11	AC_CONFIG_MACRO_DIR([m4])
	12
	13	AC_CANONICAL_TARGET
	14	AC_CANONICAL_HOST
	15
	16	AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
	17	AM_MAINTAINER_MODE([enable])
	18
	19	# Enable silent rules if available (Introduced in AM 1.11)
	20	m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
	21
	22	AH_TEMPLATE([CONFIG_RCU_SMP], [Enable SMP support. With SMP support enabled, uniprocessors are also supported. With SMP support disabled, UP systems work fine, but the behavior of SMP systems is undefined.])
	23	AH_TEMPLATE([CONFIG_RCU_HAVE_FENCE], [Defined when on a system that has memory fence instructions.])
	24	AH_TEMPLATE([CONFIG_RCU_HAVE_FUTEX], [Defined when on a system with futex support.])
	25	AH_TEMPLATE([CONFIG_RCU_COMPAT_ARCH], [Compatibility mode for i386 which lacks cmpxchg instruction.])
	26	AH_TEMPLATE([CONFIG_RCU_ARM_HAVE_DMB], [Use the dmb instruction if available for use on ARM.])
	27	AH_TEMPLATE([CONFIG_RCU_TLS], [TLS provided by the compiler.])
	28	AH_TEMPLATE([CONFIG_RCU_HAVE_CLOCK_GETTIME], [clock_gettime() is detected.])
	29
	30	# Allow overriding storage used for TLS variables.
	31	AC_ARG_ENABLE([compiler-tls],
	32	AS_HELP_STRING([--disable-compiler-tls], [Use pthread_getspecific() to emulate Thread Local Storage (TLS) variables.]),
	33	[def_compiler_tls=$enableval],
	34	[def_compiler_tls="yes"])
	35
	36	AS_IF([test "x$def_compiler_tls" = "xyes"], AC_DEFINE([CONFIG_RCU_TLS], [1]), [:])
	37
	38	# Checks for C compiler
	39	AC_USE_SYSTEM_EXTENSIONS
	40	AC_PROG_CC
	41	AC_PROG_CC_STDC
	42
	43	# Checks for programs.
	44	AC_PROG_AWK
	45	AC_PROG_MAKE_SET
	46	AC_CHECK_PROGS(NPROC, [nproc gnproc])
	47	AC_CHECK_PROGS(GETCONF, [getconf])
	48	AS_IF([test "x$NPROC" != "x"],
	49	[NPROC_CMD=$NPROC],
	50	[AS_IF([test "x$GETCONF" != "x"],
	51	[NPROC_CMD="$GETCONF _NPROCESSORS_ONLN"],
	52	[NPROC_CMD="echo 1"]
	53	)]
	54	)
	55	AC_SUBST([NPROC_CMD], [$NPROC_CMD])
	56
	57	LT_INIT
	58
	59	# Checks for typedefs, structures, and compiler characteristics.
	60	AC_C_INLINE
	61	AC_TYPE_PID_T
	62	AC_TYPE_SIZE_T
	63	AC_TYPE_SSIZE_T
	64	AC_TYPE_UINT16_T
	65	AC_TYPE_INT32_T
	66	AC_TYPE_UINT32_T
	67	AC_TYPE_UINT64_T
	68	AC_TYPE_UINT8_T
	69
	70	AX_C___ATTRIBUTE__
	71	AS_IF([test "x$ax_cv___attribute__" = "xyes"],
	72	[:],
	73	[AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
	74
	75	AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])
	76
	77	AM_CFLAGS="$AM_CFLAGS $PTHREAD_CFLAGS"
	78
	79	# Checks for library functions.
	80	AC_FUNC_MMAP
	81	AC_FUNC_FORK
	82	AC_CHECK_FUNCS([ \
	83	atexit \
	84	getcpuid \
	85	gettid \
	86	gettimeofday \
	87	memeset \
	88	memset \
	89	munmap \
	90	sched_getcpu \
	91	strerror \
	92	strtoul \
	93	sysconf \
	94	])
	95
	96	# AC_FUNC_MALLOC causes problems when cross-compiling.
	97	#AC_FUNC_MALLOC
	98
	99	# Check for headers
	100	AC_HEADER_STDBOOL
	101	AC_CHECK_HEADERS([ \
	102	limits.h \
	103	stddef.h \
	104	sys/param.h \
	105	sys/time.h \
	106	])
	107
	108	# Find arch type
	109	AS_CASE([$host_cpu],
	110	[k1om], [ARCHTYPE="x86"],
	111	[i386], [ARCHTYPE="x86" && SUBARCHTYPE="x86compat"],
	112	[i486], [ARCHTYPE="x86"],
	113	[i586], [ARCHTYPE="x86"],
	114	[i686], [ARCHTYPE="x86"],
	115	[amd64], [ARCHTYPE="x86"],
	116	[x86_64], [ARCHTYPE="x86"],
	117	[powerpc], [ARCHTYPE="ppc"],
	118	[ppc64], [ARCHTYPE="ppc"],
	119	[powerpc64], [ARCHTYPE="ppc"],
	120	[powerpc64le], [ARCHTYPE="ppc"],
	121	[ppc], [ARCHTYPE="ppc"],
	122	[s390], [ARCHTYPE="s390"],
	123	[s390x], [ARCHTYPE="s390"],
	124	[sparc], [ARCHTYPE="sparc64"],
	125	[sparc64], [ARCHTYPE="sparc64"],
	126	[alpha*], [ARCHTYPE="alpha"],
	127	[ia64], [ARCHTYPE="ia64"],
	128	[arm*], [ARCHTYPE="arm"],
	129	[aarch64*], [ARCHTYPE="aarch64"],
	130	[mips*], [ARCHTYPE="mips"],
	131	[tile*], [ARCHTYPE="tile"],
	132	[hppa*], [ARCHTYPE="hppa"],
	133	[ARCHTYPE="unknown"]
	134	)
	135
	136	AS_CASE([$host],[--linux-androideabi],
	137	[AM_CONDITIONAL(TARGET_IS_ANDROID, true)],
	138	[AM_CONDITIONAL(TARGET_IS_ANDROID, false)]
	139	)
	140
	141	AS_CASE([$host],[-cygwin],
	142	[AM_CONDITIONAL(USE_CYGWIN, true)],
	143	[AM_CONDITIONAL(USE_CYGWIN, false)]
	144	)
	145
	146	AC_SUBST(ARCHTYPE)
	147	AC_SUBST(SUBARCHTYPE)
	148
	149	UATOMICSRC=urcu/uatomic/$ARCHTYPE.h
	150	ARCHSRC=urcu/arch/$ARCHTYPE.h
	151
	152	AS_IF([test "x$SUBARCHTYPE" = xx86compat],[
	153	AC_DEFINE([CONFIG_RCU_COMPAT_ARCH], [1])
	154	])
	155
	156	AS_IF([test "$host_cpu" = "armv7l"],[
	157	AM_CFLAGS="$AM_CFLAGS -mcpu=cortex-a9 -mtune=cortex-a9 -O1"
	158	])
	159
	160	# ARM-specific checks
	161	AS_IF([test "x$ARCHTYPE" = "xarm"],[
	162	AC_MSG_CHECKING([for dmb instruction])
	163	AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
	164	int main()
	165	{
	166	asm volatile("dmb":::"memory");
	167	return 0;
	168	}
	169	]])
	170	],[
	171	AC_MSG_RESULT([yes])
	172	AC_DEFINE([CONFIG_RCU_ARM_HAVE_DMB], [1])
	173	],[
	174	AC_MSG_RESULT([no])
	175	])
	176	])
	177
	178	# Tile-specific checks
	179	AS_IF([echo "$host_cpu" \| grep "^tile"],[
	180	AC_MSG_CHECKING([for Tile architecture type])
	181	AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
	182	#ifndef __tilegx__
	183	#error
	184	#endif
	185	]])
	186	],[
	187	AC_MSG_RESULT([ok])
	188	],[
	189	AC_MSG_FAILURE([URCU has only been tested on the TileGx architecture. For other Tile* architectures, please run the tests first and report the results to the maintainer so that proper support can be added.])
	190	])
	191	])
	192
	193	# x86-specific checks
	194	AS_IF([test "x$ARCHTYPE" = "xx86"],[
	195	AC_MSG_CHECKING([if architecture really supports the mfence instruction])
	196	#For now, using lock; addl compatibility mode even for i686, because the
	197	#Pentium III is seen as a i686, but lacks mfence instruction.
	198	#Only using fence for x86_64.
	199	#
	200	#k1om is the name for the Intel MIC family (Xeon Phi). It is an x86_64
	201	#variant but lacks fence instructions.
	202	AS_IF([test "x$host_cpu" != "xi386" -a "x$host_cpu" != "xi486" -a "x$host_cpu" != "xi586" -a "x$host_cpu" != "xi686" -a "x$host_vendor" != "xk1om" -a "x$host_cpu" != "xk1om"],[
	203	AC_MSG_RESULT([yes])
	204	AC_DEFINE([CONFIG_RCU_HAVE_FENCE], [1])
	205	],[
	206	AC_MSG_RESULT([no])
	207	])
	208	])
	209
	210	# Check if sys_futex() is available
	211	AC_MSG_CHECKING([for sys_futex()])
	212	AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
	213	#include <sys/syscall.h>
	214	#ifndef __NR_futex
	215	#error "futexes not available"
	216	#endif
	217	]])
	218	],[
	219	AC_MSG_RESULT([yes])
	220	AC_DEFINE([CONFIG_RCU_HAVE_FUTEX], [1])
	221	compat_futex_test=0
	222	],[
	223	AC_MSG_RESULT([no])
	224	compat_futex_test=1
	225	])
	226
	227	# Search for clock_gettime
	228	AC_SEARCH_LIBS([clock_gettime], [rt], [
	229	AC_DEFINE([CONFIG_RCU_HAVE_CLOCK_GETTIME], [1])
	230	], [])
	231
	232	# Check for pthread
	233	AC_CHECK_LIB([pthread], [pthread_create],
	234	[AM_CONDITIONAL(LIBC_INCLUDES_PTHREAD, false)],
	235	[AC_CHECK_LIB([c], [pthread_create],
	236	[AM_CONDITIONAL(LIBC_INCLUDES_PTHREAD, true)],
	237	[AC_MSG_ERROR([Cannot find libpthread. Use [LDFLAGS]=-Ldir to specify its location.])]
	238	)]
	239	)
	240
	241	AM_CONDITIONAL([COMPAT_FUTEX], [test "x$compat_futex_test" = "x1"])
	242	AM_CONDITIONAL([COMPAT_ARCH], [test "x$SUBARCHTYPE" = "xx86compat"])
	243	AM_CONDITIONAL([NO_SHARED], [test "x$enable_shared" = "xno"])
	244
	245	# smp-support configure option
	246	AC_ARG_ENABLE([smp-support],
	247	AS_HELP_STRING([--disable-smp-support], [Disable SMP support. Warning: only use this on uniprocessor systems. [default=enabled]]),
	248	[def_smp_support=$enableval],
	249	[def_smp_support="yes"])
	250	AS_IF([test "x$def_smp_support" = "xyes"], [AC_DEFINE([CONFIG_RCU_SMP], [1])])
	251
	252
	253	# From the sched_setaffinity(2)'s man page:
	254	# ~~~~
	255	# The CPU affinity system calls were introduced in Linux kernel 2.5.8.
	256	# The library interfaces were introduced in glibc 2.3. Initially, the
	257	# glibc interfaces included a cpusetsize argument. In glibc 2.3.3,
	258	# the cpuset size argument was removed, but this argument was
	259	# restored in glibc 2.3.4.
	260	# ~~~~
	261
	262	# In addition to that, some vendors ported the system call to 2.4
	263	# kernels.
	264
	265	# Furthermore, when the function first appeared, the MASK argument was
	266	# an unsigned long pointer, while later it was made into a cpu_set_t
	267	# pointer. Systems that have the cpu_set_t version also should have
	268	# the CPU_ZERO, CPU_SET, etc. macros.
	269
	270	# All this mess means we have to cater for at least 3 different
	271	# sched_setaffinity prototypes:
	272
	273	# ~~~~
	274	# int sched_setaffinity (pid_t pid, unsigned int len, unsigned long *mask);
	275	# int sched_setaffinity (pid_t __pid, size_t __cpusetsize, const cpu_set_t *__cpuset);
	276	# int sched_setaffinity (pid_t __pid, const cpu_set_t *__mask);
	277	# ~~~~
	278
	279	# Since we define _GNU_SOURCE in the sources, must do so too in the
	280	# autoconf tests, as defining _GNU_SOURCE or not exposes
	281	# sched_setaffinity bits differently.
	282	saved_CFLAGS="$CFLAGS"
	283	CFLAGS="$CFLAGS $AM_CFLAGS -D_GNU_SOURCE"
	284
	285	AC_CHECK_TYPES([cpu_set_t],
	286	[have_cpu_set_t="yes"],
	287	[have_cpu_set_t="no"],
	288	[#include <sched.h>])
	289
	290	# Confirm that we have CPU_ZERO, and it actually works.
	291	AC_MSG_CHECKING([whether CPU_ZERO works])
	292	AH_TEMPLATE([HAVE_CPU_ZERO], [Defined to 1 if we have CPU_ZERO and it works])
	293	AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
	294	#define _GNU_SOURCE
	295	#include <sched.h>
	296	int main()
	297	{
	298	cpu_set_t foo; CPU_ZERO(&foo);
	299	return 0;
	300	}
	301	]])
	302	],[
	303	AC_DEFINE(HAVE_CPU_ZERO, 1)
	304	AC_MSG_RESULT([yes])
	305	],[
	306	AC_MSG_RESULT([no])
	307	])
	308
	309	# Confirm that we have CPU_SET, and it actually works.
	310	AC_MSG_CHECKING([whether CPU_SET works])
	311	AH_TEMPLATE([HAVE_CPU_SET], [Defined to 1 if we have CPU_SET and it works])
	312	AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
	313	#define _GNU_SOURCE
	314	#include <sched.h>
	315	int main()
	316	{
	317	cpu_set_t foo, mask; CPU_SET(0, &foo);
	318	return 0;
	319	}
	320	]])
	321	],[
	322	AC_DEFINE(HAVE_CPU_SET, 1)
	323	AC_MSG_RESULT([yes])
	324	],[
	325	AC_MSG_RESULT([no])
	326	])
	327
	328	# First check if the function is available at all.
	329	AC_CHECK_FUNCS([sched_setaffinity],[
	330	# Okay, we have it. Check if also have cpu_set_t. If we don't,
	331	# then we have the first version using unsigned long, and no
	332	# CPU_ZERO, etc. macros. If we do have cpu_set_t, we may have the
	333	# version with 2 or 3 arguments. In that case, CPU_ZERO, etc.,
	334	# should also be present, but we confirm nonetheless.
	335
	336	AS_IF([test "x$have_cpu_set_t" = "xyes"], [
	337	# We do have it.
	338	# Check how many arguments does sched_setaffinity take.
	339	# Should be 3 or 2.
	340	AC_MSG_CHECKING([how many arguments sched_setaffinity takes])
	341	AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
	342	#include <sched.h>
	343	int main()
	344	{
	345	cpu_set_t foo;
	346	sched_setaffinity(0, sizeof (foo), &foo);
	347	return 0;
	348	}
	349	]])
	350	],
	351	[sched_set_affinity_args=3],
	352	[sched_set_affinity_args=2])
	353	AC_DEFINE_UNQUOTED(SCHED_SETAFFINITY_ARGS,
	354	$sched_set_affinity_args,
	355	[Defined to sched_setaffinity's number of arguments.])
	356	AC_MSG_RESULT([$sched_set_affinity_args])
	357	],[
	358	# No cpu_set_t, always 3 args.
	359	AC_DEFINE(SCHED_SETAFFINITY_ARGS, 3)
	360	])
	361	])
	362
	363	CFLAGS=$saved_CFLAGS
	364	AC_SUBST(AM_CFLAGS)
	365
	366	AC_CONFIG_LINKS([
	367	urcu/arch.h:$ARCHSRC
	368	urcu/uatomic.h:$UATOMICSRC
	369	])
	370	AC_CONFIG_FILES([
	371	Makefile
	372	doc/Makefile
	373	doc/examples/Makefile
	374	tests/Makefile
	375	tests/common/Makefile
	376	tests/unit/Makefile
	377	tests/benchmark/Makefile
	378	tests/regression/Makefile
	379	tests/regression/regression_tests
	380	tests/utils/Makefile
	381	liburcu.pc
	382	liburcu-bp.pc
	383	liburcu-cds.pc
	384	liburcu-qsbr.pc
	385	liburcu-mb.pc
	386	liburcu-signal.pc
	387	])
	388	AC_OUTPUT
	389
	390	# Report on selected configure options
	391	AS_IF([test "x$def_smp_support" = "xyes"],[
	392	AS_ECHO("SMP support enabled.")
	393	],[
	394	AS_ECHO("SMP support disabled.")
	395	])
	396
	397	AS_IF([test "x$def_compiler_tls" = "xyes"],[
	398	AS_ECHO("Thread Local Storage (TLS): compiler TLS.")
	399	],[
	400	AS_ECHO("Thread Local Storage (TLS): pthread_getspecific().")
	401	])