[urcu.git] / configure.ac

AC_PREREQ(2.59)
AC_INIT([userspace-rcu],[0.10.0-pre],[mathieu dot desnoyers at efficios dot com], [], [http://liburcu.org/])

# Following the numbering scheme proposed by libtool for the library version
# http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
AC_SUBST([URCU_LIBRARY_VERSION], [5:0:1])

AC_CONFIG_HEADERS([include/config.h include/urcu/config.h])
AC_CONFIG_AUX_DIR([config])
AC_CONFIG_MACRO_DIR([m4])

AC_CANONICAL_TARGET
AC_CANONICAL_HOST

AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip nostdinc])
AM_MAINTAINER_MODE([enable])

# Enable silent rules if available (Introduced in AM 1.11)
m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])

AH_TEMPLATE([CONFIG_RCU_SMP], [Enable SMP support. With SMP support enabled, uniprocessors are also supported. With SMP support disabled, UP systems work fine, but the behavior of SMP systems is undefined.])
AH_TEMPLATE([CONFIG_RCU_HAVE_FENCE], [Defined when on a system that has memory fence instructions.])
AH_TEMPLATE([CONFIG_RCU_HAVE_FUTEX], [Defined when on a system with futex support.])
AH_TEMPLATE([CONFIG_RCU_COMPAT_ARCH], [Compatibility mode for i386 which lacks cmpxchg instruction.])
AH_TEMPLATE([CONFIG_RCU_ARM_HAVE_DMB], [Use the dmb instruction if available for use on ARM.])
AH_TEMPLATE([CONFIG_RCU_TLS], [TLS provided by the compiler.])
AH_TEMPLATE([CONFIG_RCU_HAVE_CLOCK_GETTIME], [clock_gettime() is detected.])

# Allow overriding storage used for TLS variables.
AC_ARG_ENABLE([compiler-tls],
	AS_HELP_STRING([--disable-compiler-tls], [Use pthread_getspecific() to emulate Thread Local Storage (TLS) variables.]),
	[def_compiler_tls=$enableval],
	[def_compiler_tls="yes"])

# If not overridden, use ax_tls.m4 to check if TLS is available.
AS_IF([test "x$def_compiler_tls" = "xyes"],
	[AX_TLS([def_tls_detect=$ac_cv_tls], [:])],
	[:])

AS_IF([test "x$def_tls_detect" = "x"],
	[:],
	[AC_DEFINE_UNQUOTED([CONFIG_RCU_TLS], $def_tls_detect)])

# Checks for C compiler
AC_USE_SYSTEM_EXTENSIONS
AC_PROG_CC
AC_PROG_CC_STDC

# Checks for programs.
AC_PROG_AWK
AC_PROG_MAKE_SET
AC_CHECK_PROGS(NPROC, [nproc gnproc])
AC_CHECK_PROGS(GETCONF, [getconf])
AS_IF([test "x$NPROC" != "x"],
	[NPROC_CMD=$NPROC],
	[AS_IF([test "x$GETCONF" != "x"],
		[NPROC_CMD="$GETCONF _NPROCESSORS_ONLN"],
		[NPROC_CMD="echo 1"]
	)]
)
AC_SUBST([NPROC_CMD], [$NPROC_CMD])

LT_INIT

# Checks for typedefs, structures, and compiler characteristics.
AC_C_INLINE
AC_TYPE_PID_T
AC_TYPE_SIZE_T
AC_TYPE_SSIZE_T
AC_TYPE_UINT16_T
AC_TYPE_INT32_T
AC_TYPE_UINT32_T
AC_TYPE_UINT64_T
AC_TYPE_UINT8_T

AX_C___ATTRIBUTE__
AS_IF([test "x$ax_cv___attribute__" = "xyes"],
	[:],
	[AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])

AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])
LIBS="$PTHREAD_LIBS $LIBS"
CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
CC="$PTHREAD_CC"

# Checks for library functions.
AC_FUNC_MMAP
AC_FUNC_FORK
AC_CHECK_FUNCS([ \
	atexit \
	getcpuid \
	gettid \
	gettimeofday \
	memeset \
	memset \
	munmap \
	rand_r \
	sched_getcpu \
	strerror \
	strtoul \
	sysconf \
])

# AC_FUNC_MALLOC causes problems when cross-compiling.
#AC_FUNC_MALLOC

# Check for headers
AC_HEADER_STDBOOL
AC_CHECK_HEADERS([ \
	limits.h \
	stddef.h \
	sys/param.h \
	sys/time.h \
])

# Find arch type
AS_CASE([$host_cpu],
	[k1om], [ARCHTYPE="x86"],
	[i386], [ARCHTYPE="x86" && SUBARCHTYPE="x86compat"],
	[i486], [ARCHTYPE="x86"],
	[i586], [ARCHTYPE="x86"],
	[i686], [ARCHTYPE="x86"],
	[amd64], [ARCHTYPE="x86"],
	[x86_64], [ARCHTYPE="x86"],
	[powerpc], [ARCHTYPE="ppc"],
	[ppc64], [ARCHTYPE="ppc"],
	[powerpc64], [ARCHTYPE="ppc"],
	[powerpc64le], [ARCHTYPE="ppc"],
	[ppc], [ARCHTYPE="ppc"],
	[s390], [ARCHTYPE="s390"],
	[s390x], [ARCHTYPE="s390"],
	[sparc], [ARCHTYPE="sparc64"],
	[sparc64], [ARCHTYPE="sparc64"],
	[alpha*], [ARCHTYPE="alpha"],
	[ia64], [ARCHTYPE="ia64"],
	[arm*], [ARCHTYPE="arm"],
	[aarch64*], [ARCHTYPE="aarch64"],
	[mips*], [ARCHTYPE="mips"],
	[nios2*], [ARCHTYPE="nios2"],
	[tile*], [ARCHTYPE="tile"],
	[hppa*], [ARCHTYPE="hppa"],
	[ARCHTYPE="unknown"]
)

AS_CASE([$host],[*-cygwin*],
	[AM_CONDITIONAL(USE_CYGWIN, true)],
	[AM_CONDITIONAL(USE_CYGWIN, false)]
)

AC_SUBST(ARCHTYPE)
AC_SUBST(SUBARCHTYPE)

UATOMICSRC=include/urcu/uatomic/$ARCHTYPE.h
ARCHSRC=include/urcu/arch/$ARCHTYPE.h

AS_IF([test "x$SUBARCHTYPE" = xx86compat],[
	AC_DEFINE([CONFIG_RCU_COMPAT_ARCH], [1])
])

AS_IF([test "$host_cpu" = "armv7l"],[
	CFLAGS="$CFLAGS -mcpu=cortex-a9 -mtune=cortex-a9 -O1"
])

# ARM-specific checks
AS_IF([test "x$ARCHTYPE" = "xarm"],[
	AC_MSG_CHECKING([for dmb instruction])
	AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
				int main()
				{
					asm volatile("dmb":::"memory");
					return 0;
				}
		]])
	],[
		AC_MSG_RESULT([yes])
		AC_DEFINE([CONFIG_RCU_ARM_HAVE_DMB], [1])
	],[
		AC_MSG_RESULT([no])
	])
])

# Tile-specific checks
AS_IF([echo "$host_cpu" | grep "^tile"],[
	AC_MSG_CHECKING([for Tile architecture type])
	AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
				#ifndef __tilegx__
				#error
				#endif
		]])
	],[
		AC_MSG_RESULT([ok])
	],[
		AC_MSG_FAILURE([URCU has only been tested on the TileGx architecture. For other Tile* architectures, please run the tests first and report the results to the maintainer so that proper support can be added.])
	])
])

# x86-specific checks
AS_IF([test "x$ARCHTYPE" = "xx86"],[
	AC_MSG_CHECKING([if architecture really supports the mfence instruction])
	#For now, using lock; addl compatibility mode even for i686, because the
	#Pentium III is seen as a i686, but lacks mfence instruction.
	#Only using fence for x86_64.
	#
	#k1om is the name for the Intel MIC family (Xeon Phi). It is an x86_64
	#variant but lacks fence instructions.
	AS_IF([test "x$host_cpu" != "xi386" -a "x$host_cpu" != "xi486" -a "x$host_cpu" != "xi586" -a "x$host_cpu" != "xi686" -a "x$host_vendor" != "xk1om" -a "x$host_cpu" != "xk1om"],[
		AC_MSG_RESULT([yes])
		AC_DEFINE([CONFIG_RCU_HAVE_FENCE], [1])
	],[
		AC_MSG_RESULT([no])
	])
])

# Check if sys_futex() is available
AC_MSG_CHECKING([for sys_futex()])
AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
		#include <sys/syscall.h>
		#ifndef __NR_futex
		#error "futexes not available"
		#endif
	]])
],[
	AC_MSG_RESULT([yes])
	AC_DEFINE([CONFIG_RCU_HAVE_FUTEX], [1])
	compat_futex_test=0
],[
	AC_MSG_RESULT([no])
	compat_futex_test=1
])

# Search for clock_gettime
AC_SEARCH_LIBS([clock_gettime], [rt], [
	AC_DEFINE([CONFIG_RCU_HAVE_CLOCK_GETTIME], [1])
], [])

AM_CONDITIONAL([COMPAT_FUTEX], [test "x$compat_futex_test" = "x1"])
AM_CONDITIONAL([COMPAT_ARCH], [test "x$SUBARCHTYPE" = "xx86compat"])
AM_CONDITIONAL([NO_SHARED], [test "x$enable_shared" = "xno"])

# smp-support configure option
AC_ARG_ENABLE([smp-support], 
	AS_HELP_STRING([--disable-smp-support], [Disable SMP support. Warning: only use this on uniprocessor systems. [default=enabled]]),
	[def_smp_support=$enableval],
	[def_smp_support="yes"])
AS_IF([test "x$def_smp_support" = "xyes"], [AC_DEFINE([CONFIG_RCU_SMP], [1])])


# From the sched_setaffinity(2)'s man page:
# ~~~~
# The CPU affinity system calls were introduced in Linux kernel 2.5.8.
# The library interfaces were introduced in glibc 2.3.  Initially, the
# glibc interfaces included a cpusetsize argument.  In glibc 2.3.3,
# the cpuset size argument was removed, but this argument was
# restored in glibc 2.3.4.
# ~~~~

# In addition to that, some vendors ported the system call to 2.4
# kernels.

# Furthermore, when the function first appeared, the MASK argument was
# an unsigned long pointer, while later it was made into a cpu_set_t
# pointer.  Systems that have the cpu_set_t version also should have
# the CPU_ZERO, CPU_SET, etc. macros.

# All this mess means we have to cater for at least 3 different
# sched_setaffinity prototypes:

# ~~~~
#  int sched_setaffinity (pid_t pid, unsigned int len, unsigned long *mask);
#  int sched_setaffinity (pid_t __pid, size_t __cpusetsize, const cpu_set_t *__cpuset);
#  int sched_setaffinity (pid_t __pid, const cpu_set_t *__mask);
# ~~~~

AC_CHECK_TYPES([cpu_set_t],
	[have_cpu_set_t="yes"],
	[have_cpu_set_t="no"],
	[#include <sched.h>])

# Confirm that we have CPU_ZERO, and it actually works.
AC_MSG_CHECKING([whether CPU_ZERO works])
AH_TEMPLATE([HAVE_CPU_ZERO], [Defined to 1 if we have CPU_ZERO and it works])
AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
		#include <sched.h>
		int main()
		{
			cpu_set_t foo; CPU_ZERO(&foo);
			return 0;
		}
	]])
],[
	AC_DEFINE(HAVE_CPU_ZERO, 1)
	AC_MSG_RESULT([yes])
],[
	AC_MSG_RESULT([no])
])

# Confirm that we have CPU_SET, and it actually works.
AC_MSG_CHECKING([whether CPU_SET works])
AH_TEMPLATE([HAVE_CPU_SET], [Defined to 1 if we have CPU_SET and it works])
AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
		#include <sched.h>
		int main()
		{
			cpu_set_t foo, mask; CPU_SET(0, &foo);
			return 0;
		}
	]])
],[
	AC_DEFINE(HAVE_CPU_SET, 1)
	AC_MSG_RESULT([yes])
],[
	AC_MSG_RESULT([no])
])

# First check if the function is available at all.
AC_CHECK_FUNCS([sched_setaffinity],[
	# Okay, we have it.  Check if also have cpu_set_t.  If we don't,
	# then we have the first version using unsigned long, and no
	# CPU_ZERO, etc. macros.  If we do have cpu_set_t, we may have the
	# version with 2 or 3 arguments.  In that case, CPU_ZERO, etc.,
	# should also be present, but we confirm nonetheless.

	AS_IF([test "x$have_cpu_set_t" = "xyes"], [
		# We do have it.
		# Check how many arguments does sched_setaffinity take.
		# Should be 3 or 2.
		AC_MSG_CHECKING([how many arguments sched_setaffinity takes])
		AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
				#include <sched.h>
				int main()
				{
					cpu_set_t foo;
					sched_setaffinity(0, sizeof (foo), &foo);
					return 0;
				}
			]])
		],
		[sched_set_affinity_args=3],
		[sched_set_affinity_args=2])
		AC_DEFINE_UNQUOTED(SCHED_SETAFFINITY_ARGS,
			$sched_set_affinity_args,
			[Defined to sched_setaffinity's number of arguments.])
		AC_MSG_RESULT([$sched_set_affinity_args])
	],[
		# No cpu_set_t, always 3 args.
		AC_DEFINE(SCHED_SETAFFINITY_ARGS, 3)
	])
])

DEFAULT_INCLUDES="-include config.h"
AC_SUBST(DEFAULT_INCLUDES)

AC_CONFIG_LINKS([
	include/urcu/arch.h:$ARCHSRC
	include/urcu/uatomic.h:$UATOMICSRC
])
AC_CONFIG_FILES([
	Makefile
	doc/Makefile
	doc/examples/Makefile
	include/Makefile
	src/Makefile
	tests/Makefile
	tests/common/Makefile
	tests/unit/Makefile
	tests/benchmark/Makefile
	tests/regression/Makefile
	tests/regression/regression_tests
	tests/utils/Makefile
	src/liburcu.pc
	src/liburcu-bp.pc
	src/liburcu-cds.pc
	src/liburcu-qsbr.pc
	src/liburcu-mb.pc
	src/liburcu-signal.pc
])
AC_OUTPUT

# Report on selected configure options
AS_IF([test "x$def_smp_support" = "xyes"],[
	AS_ECHO("SMP support enabled.")
],[
	AS_ECHO("SMP support disabled.")
])

AS_IF([test "x$def_tls_detect" = "x"],[
	AS_ECHO("Thread Local Storage (TLS): pthread_getspecific().")
],[
	AS_ECHO("Thread Local Storage (TLS): $def_tls_detect.")
])
Commit	Line	Data
074c3a1b	1	AC_PREREQ(2.59)
d5edb898	2	AC_INIT([userspace-rcu],[0.10.0-pre],[mathieu dot desnoyers at efficios dot com], [], [http://liburcu.org/])
98bc124a YB	3
	4	# Following the numbering scheme proposed by libtool for the library version
	5	# http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
9e5f4ff4	6	AC_SUBST([URCU_LIBRARY_VERSION], [5:0:1])
98bc124a	7
6893800a	8	AC_CONFIG_HEADERS([include/config.h include/urcu/config.h])
48d848c7	9	AC_CONFIG_AUX_DIR([config])
074c3a1b MJ	10	AC_CONFIG_MACRO_DIR([m4])
074c3a1b MJ	11
7d413817 MD	12	AC_CANONICAL_TARGET
7d413817 MD	13	AC_CANONICAL_HOST
074c3a1b	14
6893800a	15	AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip nostdinc])
35eb2d6c	16	AM_MAINTAINER_MODE([enable])
7d413817	17
074c3a1b MJ	18	# Enable silent rules if available (Introduced in AM 1.11)
074c3a1b MJ	19	m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
e72596d1	20
02be5561 MD	21	AH_TEMPLATE([CONFIG_RCU_SMP], [Enable SMP support. With SMP support enabled, uniprocessors are also supported. With SMP support disabled, UP systems work fine, but the behavior of SMP systems is undefined.])
	22	AH_TEMPLATE([CONFIG_RCU_HAVE_FENCE], [Defined when on a system that has memory fence instructions.])
	23	AH_TEMPLATE([CONFIG_RCU_HAVE_FUTEX], [Defined when on a system with futex support.])
a6412536 AM	24	AH_TEMPLATE([CONFIG_RCU_COMPAT_ARCH], [Compatibility mode for i386 which lacks cmpxchg instruction.])
a6412536 AM	25	AH_TEMPLATE([CONFIG_RCU_ARM_HAVE_DMB], [Use the dmb instruction if available for use on ARM.])
a767fdc3	26	AH_TEMPLATE([CONFIG_RCU_TLS], [TLS provided by the compiler.])
a0307b90	27	AH_TEMPLATE([CONFIG_RCU_HAVE_CLOCK_GETTIME], [clock_gettime() is detected.])
a767fdc3	28
75478b32 MD	29	# Allow overriding storage used for TLS variables.
	30	AC_ARG_ENABLE([compiler-tls],
	31	AS_HELP_STRING([--disable-compiler-tls], [Use pthread_getspecific() to emulate Thread Local Storage (TLS) variables.]),
	32	[def_compiler_tls=$enableval],
	33	[def_compiler_tls="yes"])
	34
	35	# If not overridden, use ax_tls.m4 to check if TLS is available.
	36	AS_IF([test "x$def_compiler_tls" = "xyes"],
	37	[AX_TLS([def_tls_detect=$ac_cv_tls], [:])],
	38	[:])
	39
	40	AS_IF([test "x$def_tls_detect" = "x"],
	41	[:],
	42	[AC_DEFINE_UNQUOTED([CONFIG_RCU_TLS], $def_tls_detect)])
48d848c7	43
074c3a1b MJ	44	# Checks for C compiler
074c3a1b MJ	45	AC_USE_SYSTEM_EXTENSIONS
48d848c7	46	AC_PROG_CC
074c3a1b MJ	47	AC_PROG_CC_STDC
	48
	49	# Checks for programs.
27d5e306	50	AC_PROG_AWK
48d848c7	51	AC_PROG_MAKE_SET
074c3a1b	52	AC_CHECK_PROGS(NPROC, [nproc gnproc])
2350bf7b MJ	53	AC_CHECK_PROGS(GETCONF, [getconf])
	54	AS_IF([test "x$NPROC" != "x"],
	55	[NPROC_CMD=$NPROC],
	56	[AS_IF([test "x$GETCONF" != "x"],
	57	[NPROC_CMD="$GETCONF _NPROCESSORS_ONLN"],
	58	[NPROC_CMD="echo 1"]
	59	)]
	60	)
	61	AC_SUBST([NPROC_CMD], [$NPROC_CMD])
	62
b14a378a	63	LT_INIT
48d848c7 PMF	64
	65	# Checks for typedefs, structures, and compiler characteristics.
	66	AC_C_INLINE
	67	AC_TYPE_PID_T
	68	AC_TYPE_SIZE_T
27d5e306 MJ	69	AC_TYPE_SSIZE_T
27d5e306 MJ	70	AC_TYPE_UINT16_T
991d28ca JR	71	AC_TYPE_INT32_T
	72	AC_TYPE_UINT32_T
	73	AC_TYPE_UINT64_T
	74	AC_TYPE_UINT8_T
48d848c7	75
074c3a1b MJ	76	AX_C___ATTRIBUTE__
	77	AS_IF([test "x$ax_cv___attribute__" = "xyes"],
	78	[:],
	79	[AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
	80
	81	AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])
	82	LIBS="$PTHREAD_LIBS $LIBS"
	83	CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
	84	CC="$PTHREAD_CC"
	85
48d848c7	86	# Checks for library functions.
48d848c7	87	AC_FUNC_MMAP
27d5e306 MJ	88	AC_FUNC_FORK
	89	AC_CHECK_FUNCS([ \
	90	atexit \
27d5e306 MJ	91	getcpuid \
	92	gettid \
	93	gettimeofday \
	94	memeset \
	95	memset \
	96	munmap \
3e4ae45a	97	rand_r \
27d5e306 MJ	98	sched_getcpu \
	99	strerror \
	100	strtoul \
	101	sysconf \
	102	])
48d848c7	103
9a62b0f0 MJ	104	# AC_FUNC_MALLOC causes problems when cross-compiling.
	105	#AC_FUNC_MALLOC
	106
bb6afa9a	107	# Check for headers
7dea28e7	108	AC_HEADER_STDBOOL
27d5e306 MJ	109	AC_CHECK_HEADERS([ \
	110	limits.h \
	111	stddef.h \
	112	sys/param.h \
	113	sys/time.h \
	114	])
bb6afa9a	115
48d848c7	116	# Find arch type
58e9f838	117	AS_CASE([$host_cpu],
52fe6e60	118	[k1om], [ARCHTYPE="x86"],
a6412536 AM	119	[i386], [ARCHTYPE="x86" && SUBARCHTYPE="x86compat"],
	120	[i486], [ARCHTYPE="x86"],
	121	[i586], [ARCHTYPE="x86"],
	122	[i686], [ARCHTYPE="x86"],
	123	[amd64], [ARCHTYPE="x86"],
	124	[x86_64], [ARCHTYPE="x86"],
	125	[powerpc], [ARCHTYPE="ppc"],
	126	[ppc64], [ARCHTYPE="ppc"],
	127	[powerpc64], [ARCHTYPE="ppc"],
61126bd9	128	[powerpc64le], [ARCHTYPE="ppc"],
a6412536 AM	129	[ppc], [ARCHTYPE="ppc"],
	130	[s390], [ARCHTYPE="s390"],
	131	[s390x], [ARCHTYPE="s390"],
171ff3a3	132	[sparc], [ARCHTYPE="sparc64"],
a6412536 AM	133	[sparc64], [ARCHTYPE="sparc64"],
a6412536 AM	134	[alpha*], [ARCHTYPE="alpha"],
c21a8d01	135	[ia64], [ARCHTYPE="ia64"],
a6412536	136	[arm*], [ARCHTYPE="arm"],
d1c67842	137	[aarch64*], [ARCHTYPE="aarch64"],
e1259cb1	138	[mips*], [ARCHTYPE="mips"],
859050b3	139	[nios2*], [ARCHTYPE="nios2"],
c23069c6	140	[tile*], [ARCHTYPE="tile"],
13e0bc72	141	[hppa*], [ARCHTYPE="hppa"],
a6412536 AM	142	[ARCHTYPE="unknown"]
a6412536 AM	143	)
91b0650a	144
b129d5d7 SB	145	AS_CASE([$host],[-cygwin],
	146	[AM_CONDITIONAL(USE_CYGWIN, true)],
	147	[AM_CONDITIONAL(USE_CYGWIN, false)]
	148	)
	149
a6412536 AM	150	AC_SUBST(ARCHTYPE)
a6412536 AM	151	AC_SUBST(SUBARCHTYPE)
5e626e0e	152
6893800a MJ	153	UATOMICSRC=include/urcu/uatomic/$ARCHTYPE.h
6893800a MJ	154	ARCHSRC=include/urcu/arch/$ARCHTYPE.h
455b809a	155
a6412536 AM	156	AS_IF([test "x$SUBARCHTYPE" = xx86compat],[
	157	AC_DEFINE([CONFIG_RCU_COMPAT_ARCH], [1])
	158	])
	159
58e9f838	160	AS_IF([test "$host_cpu" = "armv7l"],[
a6412536 AM	161	CFLAGS="$CFLAGS -mcpu=cortex-a9 -mtune=cortex-a9 -O1"
a6412536 AM	162	])
48d848c7	163
a6412536 AM	164	# ARM-specific checks
	165	AS_IF([test "x$ARCHTYPE" = "xarm"],[
	166	AC_MSG_CHECKING([for dmb instruction])
fe0707ab MD	167	AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
	168	int main()
	169	{
	170	asm volatile("dmb":::"memory");
	171	return 0;
	172	}
	173	]])
	174	],[
a6412536 AM	175	AC_MSG_RESULT([yes])
	176	AC_DEFINE([CONFIG_RCU_ARM_HAVE_DMB], [1])
	177	],[
	178	AC_MSG_RESULT([no])
	179	])
	180	])
	181
274773cf SM	182	# Tile-specific checks
	183	AS_IF([echo "$host_cpu" \| grep "^tile"],[
	184	AC_MSG_CHECKING([for Tile architecture type])
	185	AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
	186	#ifndef __tilegx__
	187	#error
	188	#endif
	189	]])
	190	],[
	191	AC_MSG_RESULT([ok])
	192	],[
	193	AC_MSG_FAILURE([URCU has only been tested on the TileGx architecture. For other Tile* architectures, please run the tests first and report the results to the maintainer so that proper support can be added.])
	194	])
	195	])
	196
a6412536 AM	197	# x86-specific checks
	198	AS_IF([test "x$ARCHTYPE" = "xx86"],[
	199	AC_MSG_CHECKING([if architecture really supports the mfence instruction])
	200	#For now, using lock; addl compatibility mode even for i686, because the
	201	#Pentium III is seen as a i686, but lacks mfence instruction.
	202	#Only using fence for x86_64.
8496c886 SM	203	#
	204	#k1om is the name for the Intel MIC family (Xeon Phi). It is an x86_64
	205	#variant but lacks fence instructions.
52fe6e60	206	AS_IF([test "x$host_cpu" != "xi386" -a "x$host_cpu" != "xi486" -a "x$host_cpu" != "xi586" -a "x$host_cpu" != "xi686" -a "x$host_vendor" != "xk1om" -a "x$host_cpu" != "xk1om"],[
a6412536 AM	207	AC_MSG_RESULT([yes])
	208	AC_DEFINE([CONFIG_RCU_HAVE_FENCE], [1])
	209	],[
	210	AC_MSG_RESULT([no])
	211	])
	212	])
	213
	214	# Check if sys_futex() is available
	215	AC_MSG_CHECKING([for sys_futex()])
fe0707ab	216	AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
a6412536	217	#include <sys/syscall.h>
a6412536 AM	218	#ifndef __NR_futex
	219	#error "futexes not available"
	220	#endif
fe0707ab	221	]])
a6412536	222	],[
0854ccff	223	AC_MSG_RESULT([yes])
02be5561	224	AC_DEFINE([CONFIG_RCU_HAVE_FUTEX], [1])
0854ccff	225	compat_futex_test=0
91b0650a	226	],[
0854ccff MD	227	AC_MSG_RESULT([no])
0854ccff MD	228	compat_futex_test=1
91b0650a	229	])
0854ccff	230
8be0fb5f	231	# Search for clock_gettime
a0307b90 MD	232	AC_SEARCH_LIBS([clock_gettime], [rt], [
	233	AC_DEFINE([CONFIG_RCU_HAVE_CLOCK_GETTIME], [1])
	234	], [])
8be0fb5f	235
a6412536 AM	236	AM_CONDITIONAL([COMPAT_FUTEX], [test "x$compat_futex_test" = "x1"])
a6412536 AM	237	AM_CONDITIONAL([COMPAT_ARCH], [test "x$SUBARCHTYPE" = "xx86compat"])
2f49a496	238	AM_CONDITIONAL([NO_SHARED], [test "x$enable_shared" = "xno"])
0854ccff	239
a6412536 AM	240	# smp-support configure option
	241	AC_ARG_ENABLE([smp-support],
	242	AS_HELP_STRING([--disable-smp-support], [Disable SMP support. Warning: only use this on uniprocessor systems. [default=enabled]]),
	243	[def_smp_support=$enableval],
	244	[def_smp_support="yes"])
	245	AS_IF([test "x$def_smp_support" = "xyes"], [AC_DEFINE([CONFIG_RCU_SMP], [1])])
7d413817	246
48d848c7	247
d8540fc5 PA	248	# From the sched_setaffinity(2)'s man page:
	249	# ~~~~
	250	# The CPU affinity system calls were introduced in Linux kernel 2.5.8.
	251	# The library interfaces were introduced in glibc 2.3. Initially, the
	252	# glibc interfaces included a cpusetsize argument. In glibc 2.3.3,
	253	# the cpuset size argument was removed, but this argument was
	254	# restored in glibc 2.3.4.
	255	# ~~~~
	256
	257	# In addition to that, some vendors ported the system call to 2.4
	258	# kernels.
	259
	260	# Furthermore, when the function first appeared, the MASK argument was
	261	# an unsigned long pointer, while later it was made into a cpu_set_t
	262	# pointer. Systems that have the cpu_set_t version also should have
	263	# the CPU_ZERO, CPU_SET, etc. macros.
	264
	265	# All this mess means we have to cater for at least 3 different
	266	# sched_setaffinity prototypes:
	267
	268	# ~~~~
	269	# int sched_setaffinity (pid_t pid, unsigned int len, unsigned long *mask);
	270	# int sched_setaffinity (pid_t __pid, size_t __cpusetsize, const cpu_set_t *__cpuset);
	271	# int sched_setaffinity (pid_t __pid, const cpu_set_t *__mask);
	272	# ~~~~
	273
b3231c17 MD	274	AC_CHECK_TYPES([cpu_set_t],
	275	[have_cpu_set_t="yes"],
	276	[have_cpu_set_t="no"],
	277	[#include <sched.h>])
	278
	279	# Confirm that we have CPU_ZERO, and it actually works.
	280	AC_MSG_CHECKING([whether CPU_ZERO works])
	281	AH_TEMPLATE([HAVE_CPU_ZERO], [Defined to 1 if we have CPU_ZERO and it works])
	282	AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
b3231c17 MD	283	#include <sched.h>
	284	int main()
	285	{
	286	cpu_set_t foo; CPU_ZERO(&foo);
	287	return 0;
	288	}
	289	]])
	290	],[
	291	AC_DEFINE(HAVE_CPU_ZERO, 1)
	292	AC_MSG_RESULT([yes])
	293	],[
	294	AC_MSG_RESULT([no])
	295	])
	296
	297	# Confirm that we have CPU_SET, and it actually works.
	298	AC_MSG_CHECKING([whether CPU_SET works])
	299	AH_TEMPLATE([HAVE_CPU_SET], [Defined to 1 if we have CPU_SET and it works])
	300	AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
b3231c17 MD	301	#include <sched.h>
	302	int main()
	303	{
	304	cpu_set_t foo, mask; CPU_SET(0, &foo);
	305	return 0;
	306	}
	307	]])
	308	],[
	309	AC_DEFINE(HAVE_CPU_SET, 1)
	310	AC_MSG_RESULT([yes])
	311	],[
	312	AC_MSG_RESULT([no])
	313	])
	314
d8540fc5	315	# First check if the function is available at all.
a6412536 AM	316	AC_CHECK_FUNCS([sched_setaffinity],[
	317	# Okay, we have it. Check if also have cpu_set_t. If we don't,
	318	# then we have the first version using unsigned long, and no
	319	# CPU_ZERO, etc. macros. If we do have cpu_set_t, we may have the
	320	# version with 2 or 3 arguments. In that case, CPU_ZERO, etc.,
	321	# should also be present, but we confirm nonetheless.
	322
b3231c17 MD	323	AS_IF([test "x$have_cpu_set_t" = "xyes"], [
b3231c17 MD	324	# We do have it.
a6412536 AM	325	# Check how many arguments does sched_setaffinity take.
	326	# Should be 3 or 2.
	327	AC_MSG_CHECKING([how many arguments sched_setaffinity takes])
ec5e2d14	328	AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
a6412536	329	#include <sched.h>
fe0707ab MD	330	int main()
	331	{
	332	cpu_set_t foo;
b3231c17	333	sched_setaffinity(0, sizeof (foo), &foo);
fe0707ab MD	334	return 0;
fe0707ab MD	335	}
a6412536 AM	336	]])
	337	],
	338	[sched_set_affinity_args=3],
	339	[sched_set_affinity_args=2])
b3231c17 MD	340	AC_DEFINE_UNQUOTED(SCHED_SETAFFINITY_ARGS,
b3231c17 MD	341	$sched_set_affinity_args,
a6412536 AM	342	[Defined to sched_setaffinity's number of arguments.])
	343	AC_MSG_RESULT([$sched_set_affinity_args])
	344	],[
	345	# No cpu_set_t, always 3 args.
	346	AC_DEFINE(SCHED_SETAFFINITY_ARGS, 3)
b3231c17	347	])
a6412536	348	])
d8540fc5	349
6893800a MJ	350	DEFAULT_INCLUDES="-include config.h"
6893800a MJ	351	AC_SUBST(DEFAULT_INCLUDES)
d8540fc5	352
455b809a	353	AC_CONFIG_LINKS([
6893800a MJ	354	include/urcu/arch.h:$ARCHSRC
6893800a MJ	355	include/urcu/uatomic.h:$UATOMICSRC
455b809a	356	])
48d848c7 PMF	357	AC_CONFIG_FILES([
48d848c7 PMF	358	Makefile
fe999c05	359	doc/Makefile
8bad63a0	360	doc/examples/Makefile
6893800a MJ	361	include/Makefile
6893800a MJ	362	src/Makefile
48d848c7	363	tests/Makefile
f5ab766e MD	364	tests/common/Makefile
	365	tests/unit/Makefile
	366	tests/benchmark/Makefile
	367	tests/regression/Makefile
074c3a1b	368	tests/regression/regression_tests
1b387491	369	tests/utils/Makefile
6893800a MJ	370	src/liburcu.pc
	371	src/liburcu-bp.pc
	372	src/liburcu-cds.pc
	373	src/liburcu-qsbr.pc
	374	src/liburcu-mb.pc
	375	src/liburcu-signal.pc
48d848c7 PMF	376	])
48d848c7 PMF	377	AC_OUTPUT
a6412536 AM	378
	379	# Report on selected configure options
	380	AS_IF([test "x$def_smp_support" = "xyes"],[
	381	AS_ECHO("SMP support enabled.")
	382	],[
	383	AS_ECHO("SMP support disabled.")
	384	])
75478b32 MD	385
	386	AS_IF([test "x$def_tls_detect" = "x"],[
	387	AS_ECHO("Thread Local Storage (TLS): pthread_getspecific().")
	388	],[
	389	AS_ECHO("Thread Local Storage (TLS): $def_tls_detect.")
	390	])