configure.ac

   1 dnl -*- Autoconf -*-
   2 dnl Process this file with autoconf to produce a configure script.
   3
   4 dnl Version infos
   5 m4_define([V_MAJOR], [2])
   6 m4_define([V_MINOR], [9])
   7 m4_define([V_PATCH], [0])
   8 m4_define([V_EXTRA], [pre])
   9 m4_define([V_STRING], [V_MAJOR.V_MINOR.V_PATCH])
  10 m4_ifdef([V_EXTRA], [m4_append([V_STRING], [-V_EXTRA])])
  11 m4_define([V_NAME], [[J-TBD]])
  12 m4_define([V_DESC], [[]])
  13
  14 AC_INIT([lttng-ust], V_STRING, [mathieu dot desnoyers at efficios dot com])
  15
  16 # Following the numbering scheme proposed by libtool for the library version
  17 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
  18 # This is the library version of liblttng-ust.
  19 AC_SUBST([LTTNG_UST_LIBRARY_VERSION], [0:0:0])
  20 # note: remember to update tracepoint.h dlopen() to match this version
  21 # number. TODO: eventually automate by exporting the major number.
  22
  23 # This is the library version of liblttng-ust-ctl, used internally by
  24 # liblttng-ust, lttng-sessiond, and lttng-consumerd.
  25 AC_SUBST([LTTNG_UST_CTL_LIBRARY_VERSION], [2:0:0])
  26
  27 AC_CONFIG_AUX_DIR([config])
  28 AC_CANONICAL_TARGET
  29 AC_CANONICAL_HOST
  30 AC_CONFIG_MACRO_DIR([config])
  31 AM_INIT_AUTOMAKE([1.9 foreign dist-bzip2 no-dist-gzip tar-ustar])
  32 AM_MAINTAINER_MODE([enable])
  33 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  34 AC_CONFIG_SRCDIR([include/lttng/tracepoint.h])
  35
  36 AC_REQUIRE_AUX_FILE([tap-driver.sh])
  37
  38 # Configuration options, which will be installed in the config.h
  39 AC_CONFIG_HEADERS([config.h include/lttng/ust-config.h])
  40 AH_TEMPLATE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [Use efficient unaligned access.])
  41 AH_TEMPLATE([LTTNG_UST_HAVE_SDT_INTEGRATION], [SystemTap integration via sdt.h])
  42 AH_TEMPLATE([LTTNG_UST_HAVE_PERF_EVENT], [Perf event integration via perf_event.h])
  43
  44 dnl Substitute minor/major/patchlevel version numbers
  45 AC_SUBST([MAJOR_VERSION], [V_MAJOR])
  46 AC_SUBST([MINOR_VERSION], [V_MINOR])
  47 AC_SUBST([PATCHLEVEL_VERSION], [V_PATCH])
  48
  49 AC_PROG_SED
  50 AC_PROG_GREP
  51 AC_PROG_LN_S
  52
  53 # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
  54 AC_ARG_ENABLE([libtool-linkdep-fixup], [
  55         AS_HELP_STRING([--disable-libtool-linkdep-fixup], [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)])
  56 ], [
  57         libtool_fixup=$enableval
  58 ], [
  59         libtool_fixup=yes
  60 ])
  61
  62 AS_IF([test "x$libtool_fixup" = "xyes"], [
  63         libtool_m4="$srcdir/config/libtool.m4"
  64         libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
  65         AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
  66         libtool_flag_pattern_count=$(grep -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
  67
  68         AS_IF([test $libtool_flag_pattern_count -ne 0], [
  69         AC_MSG_RESULT([$libtool_flag_pattern_count])
  70         AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
  71                 sed -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
  72         ], [
  73                 AC_MSG_RESULT([none])
  74         ])
  75 ])
  76
  77 AM_CONDITIONAL([NO_SHARED], [test "x$enable_shared" = "xno"])
  78
  79 # Checks for programs.
  80 AC_PROG_CC
  81 AC_PROG_CXX
  82 AM_CONDITIONAL([HAVE_CXX], [test "x$CXX" != "x"])
  83 AC_CHECK_PROG([HAVE_CMAKE], [cmake], ["yes"])
  84 AM_CONDITIONAL([HAVE_CMAKE], [test "x$HAVE_CMAKE" = "xyes"])
  85 AC_PROG_MAKE_SET
  86 LT_INIT
  87
  88 # rw_PROG_CXX_WORKS
  89 # Check whether the C++ compiler works.
  90 AC_CACHE_CHECK([whether the C++ compiler works], [rw_cv_prog_cxx_works], [
  91         AC_LANG_PUSH([C++])
  92
  93         AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])], [
  94                 check_cxx_designated_initializers=yes
  95         ], [
  96                 rw_cv_prog_cxx_works=no
  97         ])
  98
  99         AS_IF([test "x$check_cxx_designated_initializers" = "xyes"], [
 100                 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 101                         struct foo { int a; int b; };
 102                         void fct(void)
 103                         {
 104                                 struct foo f = { .a = 0, .b = 1 };
 105                         }
 106                 ]])], [
 107                         rw_cv_prog_cxx_works=yes
 108                 ], [
 109                         rw_cv_prog_cxx_works=no
 110                 ])
 111         ])
 112
 113         AC_LANG_POP([C++])
 114 ])
 115
 116 AM_CONDITIONAL([CXX_WORKS], [test "x$rw_cv_prog_cxx_works" = "xyes"])
 117
 118 # Check if the compiler support weak symbols
 119 AX_SYS_WEAK_ALIAS
 120
 121 AS_IF([test "x${ax_cv_sys_weak_alias}" = "xno"], [
 122         AC_MSG_ERROR([Your platform doesn't support weak symbols.])
 123 ])
 124
 125 # Checks for libraries.
 126 AC_CHECK_LIB([dl], [dlopen], [
 127         have_libdl=yes
 128 ], [
 129         #libdl not found, check for dlopen in libc.
 130         AC_CHECK_LIB([c], [dlopen], [
 131                 have_libc_dl=yes
 132         ], [
 133                 AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
 134         ])
 135 ])
 136
 137 AM_CONDITIONAL([LTTNG_UST_BUILD_WITH_LIBDL], [test "x$have_libdl" = "xyes"])
 138 AM_CONDITIONAL([LTTNG_UST_BUILD_WITH_LIBC_DL], [test "x$have_libc_dl" = "xyes"])
 139
 140 AC_CHECK_LIB([pthread], [pthread_create])
 141 AC_CHECK_LIB([pthread], [pthread_setname_np],
 142         AC_DEFINE([HAVE_PTHREAD_SETNAME_NP], [1], [Define to 1 if pthread_setname_np is available.]),
 143         AC_CHECK_LIB([pthread], [pthread_set_name_np],
 144                 AC_DEFINE([HAVE_PTHREAD_SET_NAME_NP], [1], [Define to 1 if pthread_set_name_np is available.]),
 145                 AC_MSG_RESULT([pthread setname/set_name not found.])))
 146
 147 # Check for dlfcn.h
 148 AC_CHECK_HEADER([dlfcn.h])
 149 AS_IF([test "x${ac_cv_header_dlfcn_h}" = "xyes"], [
 150         AC_CHECK_DECLS([RTLD_DI_LINKMAP], [], [], [
 151                 #define _GNU_SOURCE /* Required on Linux to get GNU extensions */
 152                 #include <dlfcn.h>
 153         ])
 154 ], [
 155         ac_cv_have_decl_RTLD_DI_LINKMAP="no"
 156 ])
 157
 158 AM_CONDITIONAL([HAVE_DLINFO], [test "x${ac_cv_have_decl_RTLD_DI_LINKMAP}" = "xyes"])
 159
 160 # Checks for header files.
 161 dnl AC_CHECK_HEADERS([fcntl.h stdint.h stdlib.h string.h sys/socket.h sys/time.h unistd.h])
 162
 163 # Checks for typedefs, structures, and compiler characteristics.
 164 AC_C_INLINE
 165 dnl AC_TYPE_INT16_T
 166 dnl AC_TYPE_INT32_T
 167 dnl AC_TYPE_INT64_T
 168 dnl AC_TYPE_INT8_T
 169 dnl AC_TYPE_PID_T
 170 dnl AC_TYPE_SIZE_T
 171 dnl AC_TYPE_SSIZE_T
 172 dnl AC_TYPE_UINT16_T
 173 dnl AC_TYPE_UINT32_T
 174 dnl AC_TYPE_UINT64_T
 175 dnl AC_TYPE_UINT8_T
 176 dnl AC_CHECK_TYPES([ptrdiff_t])
 177
 178 # Checks for library functions.
 179 AC_FUNC_MALLOC
 180 AC_CHECK_FUNCS([gettimeofday munmap socket strerror strtol sched_getcpu sysconf])
 181
 182 CFLAGS="-Wall $CFLAGS"
 183
 184 # URCU
 185
 186 # urcu - check if we just find the headers it out of the box.
 187 AC_CHECK_HEADERS([urcu-bp.h], [], [AC_MSG_ERROR([Cannot find [URCU] headers (urcu-bp.h). Use [CPPFLAGS]=-Idir to specify their location.
 188 This error can also occur when the liburcu package's configure script has not been run.])])
 189
 190 # urcu-cds - check that URCU Concurrent Data Structure lib is available to compilation
 191 # Part of Userspace RCU library 0.7.2 or better.
 192 AC_CHECK_LIB([urcu-cds], [_cds_lfht_new], [], [AC_MSG_ERROR([Cannot find
 193 liburcu-cds lib, part of Userspace RCU 0.7 or better. Use [LDFLAGS]=-Ldir to specify its location.])])
 194
 195 AC_MSG_CHECKING([caa_likely()])
 196 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 197         #include <urcu/compiler.h>
 198         void fct(void)
 199         {
 200                 if (caa_likely(1)) {
 201                 }
 202         }
 203 ]])], [
 204         AC_MSG_RESULT([yes])
 205 ], [
 206         AC_MSG_RESULT([no])
 207         AC_MSG_ERROR([Please upgrade your version of liburcu to 0.6.6 or better])
 208 ])
 209
 210 # urcu - check that URCU lib is available to compilation
 211 AC_CHECK_LIB([urcu-bp], [synchronize_rcu_bp], [], [AC_MSG_ERROR([Cannot find liburcu-bp lib. Use [LDFLAGS]=-Ldir to specify its location.])])
 212
 213 # urcu - check that URCU lib is at least version 0.6
 214 AC_CHECK_LIB([urcu-bp], [call_rcu_bp], [], [AC_MSG_ERROR([liburcu 0.6 or newer is needed, please update your version or use [LDFLAGS]=-Ldir to specify the right location.])])
 215
 216 # optional linux/perf_event.h
 217 AC_CHECK_HEADERS([linux/perf_event.h], [have_perf_event=yes], [])
 218
 219 # Perf event counters are only supported on x86 so far.
 220 AC_MSG_CHECKING([UST support for architecture perf event counters])
 221 AS_CASE([$host_cpu],
 222         [i[[3456]]86], [UST_SUPPORT_FOR_ARCH_PERF_EVENT_COUNTERS=yes],
 223         [x86_64], [UST_SUPPORT_FOR_ARCH_PERF_EVENT_COUNTERS=yes],
 224         [amd64], [UST_SUPPORT_FOR_ARCH_PERF_EVENT_COUNTERS=yes],
 225         [UST_SUPPORT_FOR_ARCH_PERF_EVENT_COUNTERS=no])
 226 AC_MSG_RESULT([$UST_SUPPORT_FOR_ARCH_PERF_EVENT_COUNTERS])
 227
 228 AM_CONDITIONAL([HAVE_PERF_EVENT], [test "x$have_perf_event" = "xyes" && test "x$UST_SUPPORT_FOR_ARCH_PERF_EVENT_COUNTERS" = "xyes"])
 229
 230 AS_IF([test "x$have_perf_event" = "xyes" && test "x$UST_SUPPORT_FOR_ARCH_PERF_EVENT_COUNTERS" = "xyes"], [
 231         AC_DEFINE([LTTNG_UST_HAVE_PERF_EVENT], [1])
 232 ])
 233
 234 AC_MSG_CHECKING([host system alignment requirements])
 235 AS_CASE([$host_cpu],
 236         [i[[3456]]86], [],
 237         [x86_64], [],
 238         [amd64], [],
 239         [powerpc], [],
 240         [ppc64], [],
 241         [ppc64le], [],
 242         [powerpc64], [],
 243         [powerpc64le], [],
 244         [s390], [NO_UNALIGNED_ACCESS=1],
 245         [s390x], [NO_UNALIGNED_ACCESS=1],
 246         [arm*], [NO_UNALIGNED_ACCESS=1],
 247         [aarch64*], [NO_UNALIGNED_ACCESS=1],
 248         [mips*], [NO_UNALIGNED_ACCESS=1],
 249         [tile*], [NO_UNALIGNED_ACCESS=1],
 250         [
 251                 UNSUPPORTED_ARCH=1
 252                 NO_UNALIGNED_ACCESS=1
 253         ])
 254 AC_MSG_RESULT([$host_cpu])
 255
 256 AS_IF([test "x$NO_UNALIGNED_ACCESS" = "x"], [
 257         AC_DEFINE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [1])
 258 ])
 259
 260 # Check for JNI header files if requested
 261 AC_ARG_ENABLE([jni-interface], [
 262         AS_HELP_STRING([--enable-jni-interface], [build JNI interface between C and Java. Needs Java include files [default=no]])
 263 ], [
 264         jni_interface=$enableval
 265 ], [
 266         jni_interface=no
 267 ])
 268
 269 AM_CONDITIONAL([BUILD_JNI_INTERFACE], [test "x$jni_interface" = "xyes"])
 270
 271
 272 AC_ARG_ENABLE([java-agent-jul], [
 273         AS_HELP_STRING([--enable-java-agent-jul], [build the LTTng UST Java agent with JUL support [default=no]])
 274 ], [
 275         java_agent_jul=$enableval
 276 ], [
 277         java_agent_jul=no
 278 ])
 279
 280 AC_ARG_ENABLE([java-agent-log4j], [
 281         AS_HELP_STRING([--enable-java-agent-log4j], [build the LTTng UST Java agent with Log4j support [default=no]])
 282 ], [
 283         java_agent_log4j=$enableval
 284 ], [
 285         java_agent_log4j=no
 286 ])
 287
 288 AC_ARG_ENABLE([java-agent-all], [
 289         AS_HELP_STRING([--enable-java-agent-all], [build the LTTng UST Java agent with all supported backends [default=no]])
 290 ], [
 291         java_agent_jul=$enableval
 292         java_agent_log4j=$enableval
 293 ], [:])
 294
 295 AM_CONDITIONAL([BUILD_JAVA_AGENT], [test "x$java_agent_jul" = "xyes" || test "x$java_agent_log4j" = "xyes"])
 296 AM_CONDITIONAL([BUILD_JAVA_AGENT_WITH_JUL], [test "x$java_agent_jul" = "xyes"])
 297 AM_CONDITIONAL([BUILD_JAVA_AGENT_WITH_LOG4J], [test "x$java_agent_log4j" = "xyes"])
 298
 299 AS_IF([test "x$jni_interface" = "xyes" || test "x$java_agent_jul" = "xyes" || test "x$java_agent_log4j" = "xyes"], [
 300         AX_JAVA_OPTIONS
 301         AX_PROG_JAVAC
 302         AX_PROG_JAVA
 303         AX_PROG_JAR
 304
 305         AX_JNI_INCLUDE_DIR
 306         for JNI_INCLUDE_DIR in $JNI_INCLUDE_DIRS
 307         do
 308                 CPPFLAGS="$CPPFLAGS -I$JNI_INCLUDE_DIR"
 309         done
 310
 311         AX_PROG_JAVAH
 312 ])
 313
 314 AS_IF([test "x$java_agent_log4j" = "xyes"], [
 315         AX_CHECK_CLASSPATH
 316         AX_CHECK_CLASS([org.apache.log4j.Logger])
 317         AS_IF([test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"], [
 318                 AC_MSG_ERROR([The UST Java agent support for log4j was requested but the Log4j classes were not found. Please specify the location of the Log4j jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j.jar"])
 319         ])
 320 ])
 321
 322 # Option to build the python agent
 323 AC_ARG_ENABLE([python-agent], [
 324         AS_HELP_STRING([--enable-python-agent], [build the LTTng UST Python agent [default=no]])
 325 ], [
 326         python_agent=$enableval
 327 ], [:])
 328 AM_CONDITIONAL([BUILD_PYTHON_AGENT], [test "x$python_agent" = "xyes"])
 329 AS_IF([test "x$python_agent" = "xyes"], [
 330         AM_PATH_PYTHON([2.7])
 331 ])
 332
 333 # sdt.h integration
 334 AC_ARG_WITH([sdt], [
 335         AS_HELP_STRING([--with-sdt], [provide SystemTap integration via sdt.h [default=no]])
 336 ], [
 337         with_sdt=$withval
 338 ], [
 339         with_sdt="no"
 340 ])
 341
 342 AS_IF([test "x$with_sdt" = "xyes"], [
 343         AC_MSG_CHECKING([STAP_PROBEV()])
 344         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 345                 #define SDT_USE_VARIADIC
 346                 #include <sys/sdt.h>
 347                 void fct(void)
 348                 {
 349                         STAP_PROBEV(provider,name,1,2,3,4,5,6,7,8,9,10);
 350                 }
 351         ]])], [
 352                 AC_MSG_RESULT([yes])
 353                 AC_DEFINE([LTTNG_UST_HAVE_SDT_INTEGRATION], [1])
 354         ], [
 355                 AC_MSG_RESULT([no])
 356                 AC_MSG_ERROR([The sdt.h integration was requested but the STAP_PROBEV define cannot be used. Make sure it is installed, and up to date, or use CPPFLAGS=-I/path/ to specify a non-standard path to sys/sdt.h])
 357         ])
 358 ])
 359
 360 AC_MSG_CHECKING([whether shared libraries are enabled])
 361 AS_IF([test "x$enable_shared" = "xyes"], [
 362         AC_MSG_RESULT([yes])
 363 ], [
 364         AC_MSG_RESULT([no])
 365         AC_MSG_ERROR([LTTng-UST requires shared libraries to be enabled])
 366 ])
 367
 368 AC_ARG_WITH([lttng-system-rundir], [
 369         AS_HELP_STRING([--with-lttng-system-rundir], [Location of the system directory where LTTng-UST expects the system-wide lttng-sessiond runtime files. The default is "/var/run/lttng".]),
 370 ], [
 371         lttng_system_rundir="$withval"
 372 ], [
 373         lttng_system_rundir="/var/run/lttng"
 374 ])
 375 AC_DEFINE_UNQUOTED([LTTNG_SYSTEM_RUNDIR], ["$lttng_system_rundir"],
 376                 [LTTng system runtime directory])
 377
 378 AC_CHECK_PROG([BUILD_GEN_TP_EXAMPLES], [python], ["yes"])
 379 AM_CONDITIONAL([BUILD_GEN_TP_EXAMPLES], [test "x$BUILD_GEN_TP_EXAMPLES" = "xyes"])
 380
 381 # Set $IN_GIT_REPO if we're in the Git repository; the `bootstrap` file
 382 # is not distributed in tarballs.
 383 AS_IF([test -f "$srcdir/bootstrap"], [in_git_repo=yes], [in_git_repo=no])
 384 AM_CONDITIONAL([IN_GIT_REPO], [test "x$in_git_repo" = "xyes"])
 385
 386 # Enable building man pages (user's intention).
 387 AC_ARG_ENABLE(
 388         man-pages,
 389         AS_HELP_STRING(
 390                 [--disable-man-pages],
 391                 [Do not build and install man pages (already built in a distributed tarball)]
 392         ),
 393         [man_pages_opt=$enableval],
 394         [man_pages_opt=yes]
 395 )
 396
 397 # Check for asciidoc and xmlto if we enabled building the man pages.
 398 have_asciidoc_xmlto=no
 399
 400 AS_IF([test "x$man_pages_opt" = "xyes"], [
 401         AC_PATH_PROG([ASCIIDOC], [asciidoc], [no])
 402         AC_PATH_PROG([XMLTO], [xmlto], [no])
 403
 404         AS_IF([test "x$ASCIIDOC" = "xno" || test "x$XMLTO" = "xno"], [
 405                 AS_IF([test "x$in_git_repo" = "xyes"], [
 406                         # This is an error because we're in the Git repo, which
 407                         # means the man pages are not already generated for us,
 408                         # thus asciidoc/xmlto are required because we were asked
 409                         # to build the man pages.
 410                         AC_MSG_ERROR([
 411 Both asciidoc and xmlto are needed to build the LTTng-UST man pages. Use
 412 --disable-man-pages to disable building the man pages, in which case
 413 they will not be installed.
 414                         ])
 415                 ], [
 416                         # Only warn here: since we're in the tarball, the man
 417                         # pages should already be generated at this point, thus
 418                         # asciidoc/xmlto are not strictly required.
 419                         AC_MSG_WARN([
 420 Both asciidoc and xmlto are needed to build the LTTng-UST man pages.
 421 Note that the man pages are already built in this distribution tarball,
 422 so asciidoc and xmlto are only needed if you intend to modify their
 423 sources. Use --disable-man-pages to completely disable building
 424 and installing the man pages.
 425                         ])
 426                 ])
 427         ], [
 428                 have_asciidoc_xmlto=yes
 429         ])
 430 ])
 431
 432 # Export man page build condition: build the man pages if the user
 433 # asked for it, and if the tools are available.
 434 AM_CONDITIONAL([MAN_PAGES_OPT], [test "x$man_pages_opt" != "xno"])
 435 AM_CONDITIONAL([HAVE_ASCIIDOC_XMLTO], [test "x$have_asciidoc_xmlto" = "xyes"])
 436
 437 # Default values
 438 AC_DEFUN([_AC_DEFINE_AND_SUBST], [
 439         AC_DEFINE_UNQUOTED([CONFIG_$1], [$2], [$1])
 440         $1="$2"
 441         AC_SUBST([$1])
 442 ])
 443
 444 _AC_DEFINE_AND_SUBST([LTTNG_UST_DEFAULT_CONSTRUCTOR_TIMEOUT_MS], [3000])
 445
 446 AC_CONFIG_FILES([
 447         Makefile
 448         doc/Makefile
 449         doc/examples/Makefile
 450         doc/man/Makefile
 451         include/Makefile
 452         include/lttng/ust-version.h
 453         snprintf/Makefile
 454         libringbuffer/Makefile
 455         liblttng-ust-comm/Makefile
 456         liblttng-ust/Makefile
 457         liblttng-ust-ctl/Makefile
 458         liblttng-ust-fork/Makefile
 459         liblttng-ust-dl/Makefile
 460         liblttng-ust-java/Makefile
 461         liblttng-ust-java-agent/Makefile
 462         liblttng-ust-java-agent/java/Makefile
 463         liblttng-ust-java-agent/java/lttng-ust-agent-all/Makefile
 464         liblttng-ust-java-agent/java/lttng-ust-agent-common/Makefile
 465         liblttng-ust-java-agent/java/lttng-ust-agent-jul/Makefile
 466         liblttng-ust-java-agent/java/lttng-ust-agent-log4j/Makefile
 467         liblttng-ust-java-agent/jni/Makefile
 468         liblttng-ust-java-agent/jni/common/Makefile
 469         liblttng-ust-java-agent/jni/jul/Makefile
 470         liblttng-ust-java-agent/jni/log4j/Makefile
 471         liblttng-ust-libc-wrapper/Makefile
 472         liblttng-ust-cyg-profile/Makefile
 473         liblttng-ust-python-agent/Makefile
 474         python-lttngust/Makefile
 475         python-lttngust/setup.py
 476         python-lttngust/lttngust/__init__.py
 477         tools/Makefile
 478         tests/Makefile
 479         tests/ctf-types/Makefile
 480         tests/hello/Makefile
 481         tests/hello.cxx/Makefile
 482         tests/same_line_tracepoint/Makefile
 483         tests/snprintf/Makefile
 484         tests/ust-elf/Makefile
 485         tests/benchmark/Makefile
 486         tests/utils/Makefile
 487         tests/test-app-ctx/Makefile
 488         tests/gcc-weak-hidden/Makefile
 489         lttng-ust.pc
 490 ])
 491
 492 # Create link for python agent for the VPATH guru.
 493 AC_CONFIG_LINKS([
 494         python-lttngust/lttngust/agent.py:python-lttngust/lttngust/agent.py
 495         python-lttngust/lttngust/cmd.py:python-lttngust/lttngust/cmd.py
 496         python-lttngust/lttngust/debug.py:python-lttngust/lttngust/debug.py
 497         python-lttngust/lttngust/loghandler.py:python-lttngust/lttngust/loghandler.py
 498 ])
 499
 500 AC_OUTPUT
 501
 502 AS_ECHO
 503 AS_ECHO(["m4_bpatsubst(V_NAME, ["], [\\"])"])
 504 AS_ECHO
 505 AS_ECHO(["m4_bpatsubst(V_DESC, ["], [\\"])"])
 506
 507 # Report on the configuration options
 508 AS_ECHO
 509 AS_ECHO(["LTTng-UST will be built with the following options:"])
 510
 511 AS_ECHO
 512
 513 AS_ECHO_N(["Java agent (JUL support): "])
 514 AS_IF([test "x$java_agent_jul" = "xyes"], [AS_ECHO(["Enabled"])], [AS_ECHO(["Disabled"])])
 515
 516 AS_ECHO_N(["Java agent (Log4j support): "])
 517 AS_IF([test "x$java_agent_log4j" = "xyes"], [AS_ECHO(["Enabled"])], [AS_ECHO(["Disabled"])])
 518
 519 AS_ECHO_N(["JNI interface (JNI): "])
 520 AS_IF([test "x$jni_interface" = "xyes"], [AS_ECHO(["Enabled"])], [AS_ECHO(["Disabled"])])
 521
 522 AS_ECHO_N(["Python ($PYTHON) agent: "])
 523 AS_IF([test "x$python_agent" = "xyes"], [AS_ECHO(["Enabled"])], [AS_ECHO(["Disabled"])])
 524
 525 AS_ECHO_N(["sdt.h integration: "])
 526 AS_IF([test "x$with_sdt" = "xyes"], [AS_ECHO(["Enabled"])], [AS_ECHO(["Disabled"])])
 527
 528 AS_ECHO(["Architecture: $host_cpu"])
 529 AS_ECHO_N(["Efficient unaligned memory access: "])
 530 AS_IF([test "x$NO_UNALIGNED_ACCESS" != "x1"], [AS_ECHO(["yes"])], [AS_IF([test "x$UNSUPPORTED_ARCH" != "x1"], [AS_ECHO(["no"])], [AS_ECHO(["unknown"])])])
 531 AS_IF([test "x$UNSUPPORTED_ARCH" = "x1"], [AC_MSG_WARN([Your architecture ($host_cpu) is unsupported, using safe default of no unaligned access])])
 532 AS_ECHO
 533
 534 AS_ECHO(["Type 'make' to compile."])
 535