configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 m4_define([V_MAJOR], [2])
   5 m4_define([V_MINOR], [8])
   6 m4_define([V_PATCH], [0])
   7 m4_define([V_EXTRA], [pre])
   8 m4_define([V_STRING], [V_MAJOR.V_MINOR.V_PATCH])
   9 m4_ifdef([V_EXTRA], [m4_append([V_STRING], [-V_EXTRA])])
  10
  11 AC_INIT([lttng-ust],V_STRING,[mathieu dot desnoyers at efficios dot com])
  12
  13 # Following the numbering scheme proposed by libtool for the library version
  14 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
  15 # This is the library version of liblttng-ust.
  16 AC_SUBST([LTTNG_UST_LIBRARY_VERSION], [0:0:0])
  17 # note: remember to update tracepoint.h dlopen() to match this version
  18 # number. TODO: eventually automate by exporting the major number.
  19
  20 # This is the library version of liblttng-ust-ctl, used internally by
  21 # liblttng-ust, lttng-sessiond, and lttng-consumerd.
  22 AC_SUBST([LTTNG_UST_CTL_LIBRARY_VERSION], [2:0:0])
  23
  24 AC_CONFIG_AUX_DIR([config])
  25 AC_CANONICAL_TARGET
  26 AC_CANONICAL_HOST
  27 AC_CONFIG_MACRO_DIR([config])
  28 AM_INIT_AUTOMAKE([1.9 foreign dist-bzip2 no-dist-gzip tar-ustar])
  29 AM_MAINTAINER_MODE([enable])
  30 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  31 AC_CONFIG_SRCDIR([include/lttng/tracepoint.h])
  32
  33 # Configuration options, which will be installed in the config.h
  34 AC_CONFIG_HEADERS([config.h include/lttng/ust-config.h])
  35 AH_TEMPLATE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [Use efficient unaligned access.])
  36 AH_TEMPLATE([LTTNG_UST_HAVE_SDT_INTEGRATION], [SystemTap integration via sdt.h])
  37 AH_TEMPLATE([LTTNG_UST_HAVE_PERF_EVENT], [Perf event integration via perf_event.h])
  38
  39 # Substitute minor/major/patchlevel version numbers
  40 AC_PROG_SED
  41 AC_SUBST([MAJOR_VERSION], [V_MAJOR])
  42 AC_SUBST([MINOR_VERSION], [V_MINOR])
  43 AC_SUBST([PATCHLEVEL_VERSION], [V_PATCH])
  44
  45 version_name="Herbe à Détourne"
  46 version_description='Brewed with unrestrained amounts of Citra hop, the Herbe à Détourne is a fantastic New World Tripel brewed by "Dieu du Ciel!". Aromas of mango, cantaloupe melon and passion fruit, combined with a controlled bitter finish, unite in making this smooth golden-orange beer stand apart.'
  47 version_description_c=$(echo $version_description | sed 's/"/\\"/g')
  48
  49 AC_DEFINE_UNQUOTED([VERSION_NAME], ["$version_name"], [UST version name])
  50 AC_DEFINE_UNQUOTED([VERSION_DESCRIPTION], ["$version_description_c"], [UST version description])
  51
  52 AC_PROG_GREP
  53 AC_PROG_LN_S
  54 # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
  55 AC_ARG_ENABLE(libtool-linkdep-fixup,
  56         AS_HELP_STRING([--disable-libtool-linkdep-fixup],
  57                         [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)]),
  58         libtool_fixup=$enableval,
  59         libtool_fixup=yes)
  60
  61 AS_IF([test "x$libtool_fixup" = "xyes"],
  62             [
  63             libtool_m4="$srcdir/config/libtool.m4"
  64             libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
  65             AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
  66             libtool_flag_pattern_count=$(grep -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
  67             AS_IF([test $libtool_flag_pattern_count -ne 0],
  68             [
  69                   AC_MSG_RESULT([$libtool_flag_pattern_count])
  70                   AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
  71                   sed -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
  72                   ],
  73                   [
  74                   AC_MSG_RESULT([none])
  75                   ])
  76             ])
  77
  78 AM_CONDITIONAL([NO_SHARED], [test "x$enable_shared" = "xno"])
  79
  80 # Checks for programs.
  81 AC_PROG_CC
  82 AC_PROG_CXX
  83 AC_PROG_MAKE_SET
  84 LT_INIT
  85
  86 # rw_PROG_CXX_WORKS
  87 # Check whether the C++ compiler works.
  88 AC_CACHE_CHECK([whether the C++ compiler works],
  89                 [rw_cv_prog_cxx_works],
  90                 [AC_LANG_PUSH([C++])
  91                 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
  92                                 [check_cxx_designated_initializers=yes],
  93                                 [rw_cv_prog_cxx_works=no])
  94                 if test "$check_cxx_designated_initializers" = "yes"; then
  95                         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
  96                                 struct foo { int a; int b; };
  97                                 void fct(void)
  98                                 {
  99                                         struct foo f = { .a = 0, .b = 1 };
 100                                 }
 101                         ]])],[
 102                                 rw_cv_prog_cxx_works=yes
 103                         ],[
 104                                 rw_cv_prog_cxx_works=no
 105                         ])
 106                 fi
 107                 AC_LANG_POP([C++])])
 108
 109 AM_CONDITIONAL([CXX_WORKS], [test "x$rw_cv_prog_cxx_works" = "xyes"])
 110
 111 # Check if the compiler support weak symbols
 112 AX_SYS_WEAK_ALIAS
 113
 114 if test "x${ax_cv_sys_weak_alias}" = "xno"; then
 115    AC_MSG_ERROR([Your platform doesn't support weak symbols.])
 116 fi
 117
 118 ## Checks for libraries.
 119 AC_CHECK_LIB([dl], [dlopen],
 120 [
 121         have_libdl=yes
 122 ],
 123 [
 124         #libdl not found, check for dlopen in libc.
 125         AC_CHECK_LIB([c], [dlopen],
 126         [
 127                 have_libc_dl=yes
 128         ],
 129         [
 130                 AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
 131         ])
 132 ])
 133 AM_CONDITIONAL([LTTNG_UST_BUILD_WITH_LIBDL], [test "x$have_libdl" = "xyes"])
 134 AM_CONDITIONAL([LTTNG_UST_BUILD_WITH_LIBC_DL], [test "x$have_libc_dl" = "xyes"])
 135
 136 AC_CHECK_LIB([pthread], [pthread_create])
 137
 138 # Check for dlfcn.h
 139 AC_CHECK_HEADER([dlfcn.h])
 140 AS_IF([test "x${ac_cv_header_dlfcn_h}" = "xyes"],
 141         [AC_CHECK_DECLS([RTLD_DI_LINKMAP],,,
 142                 [#define _GNU_SOURCE /* Required on Linux to get GNU extensions */
 143                 #include <dlfcn.h>])
 144         ],
 145         [ac_cv_have_decl_RTLD_DI_LINKMAP="no"])
 146 AM_CONDITIONAL([HAVE_DLINFO], [test "x${ac_cv_have_decl_RTLD_DI_LINKMAP}" = "xyes"])
 147
 148 # Checks for header files.
 149 #AC_CHECK_HEADERS([fcntl.h stdint.h stdlib.h string.h sys/socket.h sys/time.h unistd.h])
 150
 151 # Checks for typedefs, structures, and compiler characteristics.
 152 AC_C_INLINE
 153 #AC_TYPE_INT16_T
 154 #AC_TYPE_INT32_T
 155 #AC_TYPE_INT64_T
 156 #AC_TYPE_INT8_T
 157 #AC_TYPE_PID_T
 158 #AC_TYPE_SIZE_T
 159 #AC_TYPE_SSIZE_T
 160 #AC_TYPE_UINT16_T
 161 #AC_TYPE_UINT32_T
 162 #AC_TYPE_UINT64_T
 163 #AC_TYPE_UINT8_T
 164 #AC_CHECK_TYPES([ptrdiff_t])
 165
 166 # Checks for library functions.
 167 AC_FUNC_MALLOC
 168 AC_CHECK_FUNCS([gettimeofday munmap socket strerror strtol sched_getcpu sysconf])
 169
 170 CFLAGS="-Wall $CFLAGS"
 171
 172 # URCU
 173
 174 # urcu - check if we just find the headers it out of the box.
 175 AC_CHECK_HEADERS([urcu-bp.h], [], [AC_MSG_ERROR([Cannot find [URCU] headers (urcu-bp.h). Use [CPPFLAGS]=-Idir to specify their location.
 176 This error can also occur when the liburcu package's configure script has not been run.])])
 177
 178 # urcu-cds - check that URCU Concurrent Data Structure lib is available to compilation
 179 # Part of Userspace RCU library 0.7.2 or better.
 180 AC_CHECK_LIB([urcu-cds], [_cds_lfht_new], [], [AC_MSG_ERROR([Cannot find
 181 liburcu-cds lib, part of Userspace RCU 0.7 or better. Use [LDFLAGS]=-Ldir to specify its location.])])
 182
 183 AC_MSG_CHECKING([caa_likely()])
 184 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 185 #include <urcu/compiler.h>
 186 void fct(void)
 187 {
 188         if (caa_likely(1)) {
 189         }
 190 }
 191 ]])],[
 192         AC_MSG_RESULT([yes])
 193 ],[
 194         AC_MSG_RESULT([no])
 195         AC_MSG_ERROR([Please upgrade your version of liburcu to 0.6.6 or better])
 196
 197 ])
 198
 199 # urcu - check that URCU lib is available to compilation
 200 AC_CHECK_LIB([urcu-bp], [synchronize_rcu_bp], [], [AC_MSG_ERROR([Cannot find liburcu-bp lib. Use [LDFLAGS]=-Ldir to specify its location.])])
 201
 202 # urcu - check that URCU lib is at least version 0.6
 203 AC_CHECK_LIB([urcu-bp], [call_rcu_bp], [], [AC_MSG_ERROR([liburcu 0.6 or newer is needed, please update your version or use [LDFLAGS]=-Ldir to specify the right location.])])
 204
 205 # optional linux/perf_event.h
 206 AC_CHECK_HEADERS([linux/perf_event.h], [have_perf_event=yes], [])
 207
 208 # Perf event counters are only supported on x86 so far.
 209 AC_MSG_CHECKING([UST support for architecture perf event counters])
 210 case $host_cpu in
 211 changequote(,)dnl
 212         i[3456]86)
 213 changequote([,])dnl
 214         UST_SUPPORT_FOR_ARCH_PERF_EVENT_COUNTERS=yes;;
 215         x86_64) UST_SUPPORT_FOR_ARCH_PERF_EVENT_COUNTERS=yes;;
 216         amd64) UST_SUPPORT_FOR_ARCH_PERF_EVENT_COUNTERS=yes;;
 217         *) UST_SUPPORT_FOR_ARCH_PERF_EVENT_COUNTERS=no;;
 218 esac
 219 AC_MSG_RESULT([$UST_SUPPORT_FOR_ARCH_PERF_EVENT_COUNTERS])
 220
 221 AM_CONDITIONAL([HAVE_PERF_EVENT], [test "x$have_perf_event" = "xyes" -a "x$UST_SUPPORT_FOR_ARCH_PERF_EVENT_COUNTERS" = "xyes"])
 222
 223 if test "x$have_perf_event" = "xyes" -a "x$UST_SUPPORT_FOR_ARCH_PERF_EVENT_COUNTERS" = "xyes"; then
 224 AC_DEFINE([LTTNG_UST_HAVE_PERF_EVENT], [1])
 225 fi
 226
 227 AC_MSG_CHECKING([host system alignment requirements])
 228 case $host_cpu in
 229 changequote(,)dnl
 230         i[3456]86)
 231 changequote([,])dnl
 232           ;;
 233         x86_64) ;;
 234         amd64) ;;
 235         powerpc) ;;
 236         ppc64) ;;
 237         ppc64le) ;;
 238         powerpc64) ;;
 239         powerpc64le) ;;
 240         s390) NO_UNALIGNED_ACCESS=1 ;;
 241         s390x) NO_UNALIGNED_ACCESS=1 ;;
 242         arm*) NO_UNALIGNED_ACCESS=1 ;;
 243         aarch64) NO_UNALIGNED_ACCESS=1 ;;
 244         mips*) NO_UNALIGNED_ACCESS=1 ;;
 245         tile*) NO_UNALIGNED_ACCESS=1 ;;
 246         *)
 247                 UNSUPPORTED_ARCH=1
 248                 NO_UNALIGNED_ACCESS=1
 249                 ;;
 250 esac
 251 AC_MSG_RESULT([$host_cpu])
 252
 253 if test x$NO_UNALIGNED_ACCESS = x ; then
 254 AC_DEFINE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [1])
 255 fi
 256
 257 # Check for JNI header files if requested
 258 AC_ARG_ENABLE([jni-interface],
 259         [AS_HELP_STRING([--enable-jni-interface],[build JNI interface between C and Java. Needs Java include files [default=no]])],
 260         [jni_interface=$enableval],
 261         [jni_interface=no]
 262 )
 263
 264 AM_CONDITIONAL([BUILD_JNI_INTERFACE], [test "x$jni_interface" = "xyes"])
 265
 266
 267 AC_ARG_ENABLE([java-agent-jul],
 268         [AS_HELP_STRING([--enable-java-agent-jul],[build the LTTng UST Java agent with JUL support [default=no]])],
 269         [java_agent_jul=$enableval],
 270         [java_agent_jul=no]
 271 )
 272
 273 AC_ARG_ENABLE([java-agent-log4j],
 274         [AS_HELP_STRING([--enable-java-agent-log4j],[build the LTTng UST Java agent with Log4j support [default=no]])],
 275         [java_agent_log4j=$enableval],
 276         [java_agent_log4j=no]
 277 )
 278
 279 AC_ARG_ENABLE([java-agent-all],
 280         [AS_HELP_STRING([--enable-java-agent-all],[build the LTTng UST Java agent with all supported backends [default=no]])],
 281         [java_agent_jul=$enableval
 282          java_agent_log4j=$enableval],
 283         [:]
 284 )
 285
 286
 287 AM_CONDITIONAL([BUILD_JAVA_AGENT], [test "x$java_agent_jul" = "xyes" || test "x$java_agent_log4j" = "xyes"])
 288 AM_CONDITIONAL([BUILD_JAVA_AGENT_WITH_JUL], [test "x$java_agent_jul" = "xyes"])
 289 AM_CONDITIONAL([BUILD_JAVA_AGENT_WITH_LOG4J], [test "x$java_agent_log4j" = "xyes"])
 290
 291 if test "x$jni_interface" = "xyes" || test "x$java_agent_jul" = "xyes" || test "x$java_agent_log4j" = "xyes"; then
 292   AX_JAVA_OPTIONS
 293   AX_PROG_JAVAC
 294   AX_PROG_JAVA
 295   AX_PROG_JAR
 296
 297   AX_JNI_INCLUDE_DIR
 298   for JNI_INCLUDE_DIR in $JNI_INCLUDE_DIRS
 299   do
 300         CPPFLAGS="$CPPFLAGS -I$JNI_INCLUDE_DIR"
 301   done
 302
 303   AX_PROG_JAVAH
 304 fi
 305
 306 if test "x$java_agent_log4j" = "xyes"; then
 307   AX_CHECK_CLASSPATH
 308
 309   AX_CHECK_CLASS(org.apache.log4j.Logger)
 310
 311   if test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"; then
 312      AC_MSG_ERROR([The UST Java agent support for log4j was requested but the Log4j classes were not found. Please specify the location of the Log4j jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j.jar"])
 313   fi
 314 fi
 315
 316 # Option to build the python agent
 317 AC_ARG_ENABLE([python-agent],
 318         [AS_HELP_STRING([--enable-python-agent],[build the LTTng UST Python agent [default=no]])],
 319     [python_agent=$enableval],
 320         [:]
 321 )
 322 AM_CONDITIONAL([BUILD_PYTHON_AGENT], [test "x$python_agent" = "xyes"])
 323 if test "x$python_agent" = "xyes"; then
 324         AM_PATH_PYTHON([2.7])
 325 fi
 326
 327 # sdt.h integration
 328 AC_ARG_WITH([sdt],
 329         [AS_HELP_STRING([--with-sdt],[provide SystemTap integration via sdt.h [default=no]])],
 330         [with_sdt=$withval],
 331         [with_sdt="no"]
 332 )
 333
 334 AS_IF([test "x$with_sdt" = "xyes"],[
 335         AC_MSG_CHECKING([STAP_PROBEV()])
 336         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 337         #define SDT_USE_VARIADIC
 338         #include <sys/sdt.h>
 339         void fct(void)
 340         {
 341                 STAP_PROBEV(provider,name,1,2,3,4,5,6,7,8,9,10);
 342         }
 343         ]])],[
 344                 AC_MSG_RESULT([yes])
 345                 AC_DEFINE([LTTNG_UST_HAVE_SDT_INTEGRATION], [1])
 346         ],[
 347                 AC_MSG_RESULT([no])
 348                 AC_MSG_ERROR([The sdt.h integration was requested but the STAP_PROBEV define cannot be used. Make sure it is installed, and up to date, or use CPPFLAGS=-I/path/ to specify a non-standard path to sys/sdt.h])
 349         ])
 350 ])
 351
 352 AC_MSG_CHECKING([whether shared libraries are enabled])
 353 AS_IF([test "x$enable_shared" = "xyes"],
 354         [
 355                 AC_MSG_RESULT([yes])
 356         ],
 357         [
 358                 AC_MSG_RESULT([no])
 359                 AC_MSG_ERROR([LTTng-UST requires shared libraries to be enabled])
 360         ])
 361
 362 AC_ARG_WITH([lttng-system-rundir],
 363         AS_HELP_STRING([--with-lttng-system-rundir],
 364         [Location of the system directory where LTTng-UST expects the system-wide lttng-sessiond runtime files. The default is "/var/run/lttng".]),
 365         [lttng_system_rundir="$withval"],
 366         [lttng_system_rundir="/var/run/lttng"])
 367 AC_DEFINE_UNQUOTED([LTTNG_SYSTEM_RUNDIR], ["$lttng_system_rundir"],
 368         [LTTng system runtime directory])
 369
 370 AC_CHECK_PROG([BUILD_GEN_TP_EXAMPLES],[python],["yes"])
 371 AM_CONDITIONAL([BUILD_GEN_TP_EXAMPLES], [test $BUILD_GEN_TP_EXAMPLES], [Build examples requiring lttng-gen-tp])
 372
 373 AC_CONFIG_FILES([
 374         Makefile
 375         doc/Makefile
 376         doc/examples/Makefile
 377         include/Makefile
 378         include/lttng/ust-version.h
 379         snprintf/Makefile
 380         libringbuffer/Makefile
 381         liblttng-ust-comm/Makefile
 382         liblttng-ust/Makefile
 383         liblttng-ust-ctl/Makefile
 384         liblttng-ust-fork/Makefile
 385         liblttng-ust-dl/Makefile
 386         liblttng-ust-java/Makefile
 387         liblttng-ust-java-agent/Makefile
 388         liblttng-ust-java-agent/java/Makefile
 389         liblttng-ust-java-agent/java/lttng-ust-agent-common/Makefile
 390         liblttng-ust-java-agent/java/lttng-ust-agent-jul/Makefile
 391         liblttng-ust-java-agent/java/lttng-ust-agent-log4j/Makefile
 392         liblttng-ust-java-agent/jni/Makefile
 393         liblttng-ust-java-agent/jni/common/Makefile
 394         liblttng-ust-java-agent/jni/jul/Makefile
 395         liblttng-ust-java-agent/jni/log4j/Makefile
 396         liblttng-ust-libc-wrapper/Makefile
 397         liblttng-ust-cyg-profile/Makefile
 398         liblttng-ust-python-agent/Makefile
 399         python-lttngust/Makefile
 400         python-lttngust/setup.py
 401         python-lttngust/lttngust/__init__.py
 402         tools/Makefile
 403         tests/Makefile
 404         tests/ctf-types/Makefile
 405         tests/hello/Makefile
 406         tests/hello.cxx/Makefile
 407         tests/same_line_tracepoint/Makefile
 408         tests/snprintf/Makefile
 409         tests/ust-elf/Makefile
 410         tests/benchmark/Makefile
 411         tests/utils/Makefile
 412         tests/test-app-ctx/Makefile
 413         lttng-ust.pc
 414 ])
 415
 416 # Create link for python agent for the VPATH guru.
 417 AC_CONFIG_LINKS([
 418         python-lttngust/lttngust/agent.py:python-lttngust/lttngust/agent.py
 419         python-lttngust/lttngust/cmd.py:python-lttngust/lttngust/cmd.py
 420         python-lttngust/lttngust/debug.py:python-lttngust/lttngust/debug.py
 421         python-lttngust/lttngust/loghandler.py:python-lttngust/lttngust/loghandler.py
 422 ])
 423
 424 AC_OUTPUT
 425
 426 AS_ECHO()
 427 AS_ECHO("Version name: $version_name")
 428 AS_ECHO("$version_description")
 429
 430 # Report on the configuration options
 431 AS_ECHO()
 432 AS_ECHO("LTTng-UST will be built with the following options:")
 433
 434 AS_ECHO()
 435
 436 AS_ECHO_N("Java agent (JUL support): ")
 437 AS_IF([test "x$java_agent_jul" = "xyes"], [AS_ECHO("Enabled")], [AS_ECHO("Disabled")])
 438
 439 AS_ECHO_N("Java agent (Log4j support): ")
 440 AS_IF([test "x$java_agent_log4j" = "xyes"], [AS_ECHO("Enabled")], [AS_ECHO("Disabled")])
 441
 442 AS_ECHO_N("JNI interface (JNI): ")
 443 AS_IF([test "x$jni_interface" = "xyes"], [AS_ECHO("Enabled")], [AS_ECHO("Disabled")])
 444
 445 AS_ECHO_N("Python ($PYTHON) agent: ")
 446 AS_IF([test "x$python_agent" = "xyes"], [AS_ECHO("Enabled")], [AS_ECHO("Disabled")])
 447
 448 AS_ECHO_N("sdt.h integration: ")
 449 AS_IF([test "x$with_sdt" = "xyes"], [AS_ECHO("Enabled")], [AS_ECHO("Disabled")])
 450
 451 AS_ECHO("Architecture: $host_cpu")
 452 AS_ECHO_N("Efficient unaligned memory access: ")
 453 AS_IF([test "x$NO_UNALIGNED_ACCESS" != "x1"], [AS_ECHO("yes")], [AS_IF([test "x$UNSUPPORTED_ARCH" != "x1"], [AS_ECHO("no")], [AS_ECHO("unknown")])])
 454 AS_IF([test "x$UNSUPPORTED_ARCH" = "x1"], [AC_MSG_WARN([Your architecture ($host_cpu) is unsupported, using safe default of no unaligned access])])
 455 AS_ECHO()
 456
 457 AS_ECHO("Type 'make' to compile.")
 458