configure: regroup library checks
[lttng-ust.git] / configure.ac
... / ...
CommitLineData
1dnl SPDX-License-Identifier: LGPL-2.1-only
2dnl
3dnl Copyright (C) 2021 EfficiOS, Inc.
4dnl
5dnl Process this file with autoconf to produce a configure script.
6
7
8# Project version information
9m4_define([ust_version_major], [2])
10m4_define([ust_version_minor], [13])
11m4_define([ust_version_patch], [0])
12m4_define([ust_version_dev_stage], [-pre])
13m4_define([ust_version], ust_version_major[.]ust_version_minor[.]ust_version_patch[]ust_version_dev_stage)
14m4_define([ust_version_name], [[Codename TBD]])
15m4_define([ust_version_description], [[Description TBD]])
16
17# Library version information of "liblttng-ust"
18# Following the numbering scheme proposed by libtool for the library version
19# http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
20m4_define([ust_lib_version_current], [1])
21m4_define([ust_lib_version_revision], [0])
22m4_define([ust_lib_version_age], [0])
23m4_define([ust_lib_version], ust_lib_version_current[:]ust_lib_version_revision[:]ust_lib_version_age)
24
25# Library version information of "liblttng-ust-ctl"
26# Following the numbering scheme proposed by libtool for the library version
27# http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
28m4_define([ust_ctl_lib_version_current], [5])
29m4_define([ust_ctl_lib_version_revision], [0])
30m4_define([ust_ctl_lib_version_age], [0])
31m4_define([ust_ctl_lib_version], ust_ctl_lib_version_current[:]ust_ctl_lib_version_revision[:]ust_ctl_lib_version_age)
32
33
34## ##
35## Autoconf base setup ##
36## ##
37
38AC_PREREQ([2.69])
39AC_INIT([lttng-ust],[ust_version],[mathieu dot desnoyers at efficios dot com],[],[https://lttng.org])
40
41AC_CONFIG_HEADERS([include/config.h include/lttng/ust-config.h include/lttng/ust-version.h])
42AC_CONFIG_AUX_DIR([config])
43AC_CONFIG_MACRO_DIR([m4])
44AC_CONFIG_SRCDIR([include/lttng/tracepoint.h])
45
46AC_CANONICAL_TARGET
47AC_CANONICAL_HOST
48
49
50## ##
51## Automake base setup ##
52## ##
53
54AM_INIT_AUTOMAKE([1.12 foreign dist-bzip2 no-dist-gzip tar-ustar nostdinc -Wall -Wno-portability -Werror])
55AM_MAINTAINER_MODE([enable])
56
57# Enable silent rules by default
58AM_SILENT_RULES([yes])
59
60
61## ##
62## C compiler checks ##
63## ##
64
65# Choose the C compiler
66AC_PROG_CC
67# AC_PROG_CC_STDC was merged in AC_PROG_CC in autoconf 2.70
68m4_version_prereq([2.70], [], [AC_PROG_CC_STDC])
69
70# Make sure the C compiler supports C99
71AS_IF([test "$ac_cv_prog_cc_c99" = "no"], [AC_MSG_ERROR([The compiler does not support C99])])
72
73# Enable available system extensions and LFS support
74AC_USE_SYSTEM_EXTENSIONS
75AC_SYS_LARGEFILE
76
77# Make sure the C compiler supports __attribute__
78AX_C___ATTRIBUTE__
79AS_IF([test "x$ax_cv___attribute__" != "xyes"],
80 [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
81
82# Make sure we have pthread support
83AX_PTHREAD([], [AC_MSG_ERROR([Could not configure pthread support])])
84
85# Make sure the C compiler supports weak symbols
86AX_SYS_WEAK_ALIAS
87AS_IF([test "x$ax_cv_sys_weak_alias" = "xno"],
88 [AC_MSG_ERROR([Your platform doesn't support weak symbols.])])
89
90# Checks for typedefs, structures, and compiler characteristics.
91AC_C_INLINE
92AC_C_TYPEOF
93AC_TYPE_INT16_T
94AC_TYPE_INT32_T
95AC_TYPE_INT64_T
96AC_TYPE_INT8_T
97AC_TYPE_MODE_T
98AC_TYPE_OFF_T
99AC_TYPE_PID_T
100AC_TYPE_SIZE_T
101AC_TYPE_SSIZE_T
102AC_TYPE_UID_T
103AC_TYPE_UINT16_T
104AC_TYPE_UINT32_T
105AC_TYPE_UINT64_T
106AC_TYPE_UINT8_T
107AC_CHECK_TYPES([ptrdiff_t])
108
109
110## ##
111## C++ compiler checks ##
112## ##
113
114# Find an optional C++11 compiler without GNU extensions (-std=c++11)
115AX_CXX_COMPILE_STDCXX([11], [noext], [optional])
116AM_CONDITIONAL([HAVE_CXX], [test "$HAVE_CXX11" = "1"])
117
118
119## ##
120## Header checks ##
121## ##
122
123AC_HEADER_STDBOOL
124AC_CHECK_HEADERS([ \
125 arpa/inet.h \
126 dlfcn.h \
127 fcntl.h \
128 float.h \
129 limits.h \
130 linux/perf_event.h \
131 locale.h \
132 stddef.h \
133 sys/socket.h \
134 sys/time.h \
135 wchar.h \
136])
137
138# Check for dlinfo() by testing for RTLD_DI_LINKMAP in dlfcn.h
139AS_IF([test "x$ac_cv_header_dlfcn_h" = "xyes"], [
140 AC_CHECK_DECL([RTLD_DI_LINKMAP], [], [], [[#include <dlfcn.h>]])
141])
142
143
144## ##
145## Programs checks ##
146## ##
147
148AM_PROG_AR
149AC_PROG_SED
150AC_PROG_GREP
151AC_PROG_LN_S
152AC_PROG_MKDIR_P
153AC_PROG_MAKE_SET
154AC_CHECK_PROGS([ASCIIDOC], [asciidoc])
155AC_CHECK_PROGS([CMAKE], [cmake])
156AC_CHECK_PROGS([FOLD], [fold])
157AC_CHECK_PROGS([XMLTO], [xmlto])
158
159AM_PATH_PYTHON([2.7], [], [PYTHON=""])
160
161AX_PROG_JAVAC
162AX_PROG_JAVA
163AX_PROG_JAR
164
165# Initialize and configure libtool
166LT_INIT([disable-static])
167
168
169## ##
170## Library checks ##
171## ##
172
173AC_FUNC_CHOWN
174AC_FUNC_FORK
175AC_FUNC_MMAP
176AC_FUNC_STRERROR_R
177AC_FUNC_STRNLEN
178AC_CHECK_FUNCS([ \
179 atexit \
180 clock_gettime \
181 ftruncate \
182 getpagesize \
183 gettimeofday \
184 localeconv \
185 memchr \
186 memmove \
187 memset \
188 mkdir \
189 munmap \
190 realpath \
191 sched_getcpu \
192 socket \
193 strchr \
194 strdup \
195 strerror \
196 strtol \
197 strtoul \
198 sysconf \
199])
200
201# AC_FUNC_MALLOC causes problems when cross-compiling.
202#AC_FUNC_MALLOC
203#AC_FUNC_REALLOC
204
205# Check for pthread_setname_np and its signature
206LTTNG_PTHREAD_SETNAME_NP
207LTTNG_PTHREAD_GETNAME_NP
208
209# Check dor dlopen() in -ldl or -lc
210AC_CHECK_LIB([dl], [dlopen], [
211 libdl_name=dl
212 DL_LIBS="-ldl"
213], [
214 # dlopen not found in libdl, check in libc
215 AC_CHECK_LIB([c], [dlopen], [
216 libdl_name=c
217 DL_LIBS="-lc"
218 ], [
219 AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
220 ])
221])
222AC_SUBST(DL_LIBS)
223
224# Check if libdl has dlmopen()
225AC_CHECK_LIB([$libdl_name], [dlmopen], [
226 AC_DEFINE([HAVE_DLMOPEN], [1], [Define to 1 if dlmopen is available.])
227])
228
229# Require URCU >= 0.12 for DEFINE_URCU_TLS_INIT
230PKG_CHECK_MODULES([URCU], [liburcu >= 0.12])
231
232
233AM_CONDITIONAL([HAVE_CMAKE], [test "x$CMAKE" != "x"])
234
235AC_MSG_CHECKING([whether shared libraries are enabled])
236AS_IF([test "x$enable_shared" = "xyes"], [
237 AC_MSG_RESULT([yes])
238], [
239 AC_MSG_RESULT([no])
240 AC_MSG_ERROR([LTTng-UST requires shared libraries to be enabled])
241])
242
243# Set architecture specific options
244AS_CASE([$host_cpu],
245 [i[[3456]]86], [],
246 [x86_64], [],
247 [amd64], [],
248 [powerpc], [],
249 [ppc64], [],
250 [ppc64le], [],
251 [powerpc64], [],
252 [powerpc64le], [],
253 [s390], [],
254 [s390x], [],
255 [arm*], [
256 NO_NUMA=1
257 ],
258 [aarch64*], [],
259 [mips*], [],
260 [tile*], [],
261 [
262 UNSUPPORTED_ARCH=1
263 ])
264
265# Set os specific options
266AS_CASE([$host_os],
267 [freebsd*], [NO_NUMA=1]
268)
269
270# Configuration options, which will be installed in the config.h
271AH_TEMPLATE([LTTNG_UST_HAVE_SDT_INTEGRATION], [SystemTap integration via sdt.h])
272
273
274AM_CONDITIONAL([ENABLE_UST_DL], [test "x${ac_cv_have_decl_RTLD_DI_LINKMAP}" = "xyes"])
275
276# numa.h integration
277AS_IF([test "x$NO_NUMA" = "x1"],[
278 AS_IF([test "x$enable_numa" = "x" ], [enable_numa=no])
279])
280
281AC_ARG_ENABLE([numa], [
282AS_HELP_STRING([--disable-numa], [disable NUMA support])
283], [
284 enable_numa=$enableval
285], [
286 enable_numa=yes
287])
288
289AS_IF([test "x$enable_numa" = "xyes"], [
290 # numa - check that numa lib is available
291 AC_CHECK_LIB([numa], [numa_available], [],
292[AC_MSG_ERROR([libnuma is not available. Please either install it (e.g. libnuma-dev) or use [LDFLAGS]=-Ldir to specify the right location, or use --disable-numa configure argument to disable NUMA support.])])
293 have_libnuma=yes
294])
295AM_CONDITIONAL([ENABLE_NUMA], [test "x$have_libnuma" = "xyes"])
296
297AM_CONDITIONAL([HAVE_PERF_EVENT], [test "x$ac_cv_header_linux_perf_event_h" = "xyes"])
298
299# Check for JNI header files if requested
300AC_ARG_ENABLE([jni-interface], [
301AS_HELP_STRING([--enable-jni-interface], [build JNI interface between C and Java. Needs Java include files [default=no]])
302], [
303 jni_interface=$enableval
304], [
305 jni_interface=no
306])
307
308AM_CONDITIONAL([ENABLE_JNI_INTERFACE], [test "x$jni_interface" = "xyes"])
309
310
311AC_ARG_ENABLE([java-agent-jul], [
312AS_HELP_STRING([--enable-java-agent-jul], [build the LTTng UST Java agent with JUL support [default=no]])
313], [
314 java_agent_jul=$enableval
315], [
316 java_agent_jul=no
317])
318
319AC_ARG_ENABLE([java-agent-log4j], [
320AS_HELP_STRING([--enable-java-agent-log4j], [build the LTTng UST Java agent with Log4j support [default=no]])
321], [
322 java_agent_log4j=$enableval
323], [
324 java_agent_log4j=no
325])
326
327AC_ARG_ENABLE([java-agent-all], [
328AS_HELP_STRING([--enable-java-agent-all], [build the LTTng UST Java agent with all supported backends [default=no]])
329], [
330 java_agent_jul=$enableval
331 java_agent_log4j=$enableval
332], [:])
333
334AM_CONDITIONAL([ENABLE_JAVA_AGENT], [test "x$java_agent_jul" = "xyes" || test "x$java_agent_log4j" = "xyes"])
335AM_CONDITIONAL([ENABLE_JAVA_AGENT_WITH_JUL], [test "x$java_agent_jul" = "xyes"])
336AM_CONDITIONAL([ENABLE_JAVA_AGENT_WITH_LOG4J], [test "x$java_agent_log4j" = "xyes"])
337
338AS_IF([test "x$jni_interface" = "xyes" || test "x$java_agent_jul" = "xyes" || test "x$java_agent_log4j" = "xyes"], [
339 AX_JAVA_OPTIONS
340 AC_ARG_VAR([CLASSPATH], [Java class path])
341
342 AX_JNI_INCLUDE_DIR
343 for JNI_INCLUDE_DIR in $JNI_INCLUDE_DIRS
344 do
345 JNI_CPPFLAGS="$JNI_CPPFLAGS -I$JNI_INCLUDE_DIR"
346 done
347
348 saved_CPPFLAGS="$CPPFLAGS"
349 CPPFLAGS="$CPPFLAGS $JNI_CPPFLAGS"
350 AX_PROG_JAVAH
351 CPPFLAGS="$saved_CPPFLAGS"
352])
353
354AM_CONDITIONAL([HAVE_JAVAH], [test "x$JAVAH" != "x"])
355
356AS_IF([test "x$java_agent_log4j" = "xyes"], [
357 AX_CHECK_CLASSPATH
358 AX_CHECK_CLASS([org.apache.log4j.Logger])
359 AS_IF([test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"], [
360 AC_MSG_ERROR([The UST Java agent support for log4j was requested but the Log4j classes were not found. Please specify the location of the Log4j jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j.jar"])
361 ])
362])
363
364# Option to build the python agent
365AC_ARG_ENABLE([python-agent], [
366AS_HELP_STRING([--enable-python-agent], [build the LTTng UST Python agent [default=no]])
367], [
368 python_agent=$enableval
369], [:])
370AM_CONDITIONAL([ENABLE_PYTHON_AGENT], [test "x$python_agent" = "xyes"])
371
372# sdt.h integration
373AC_ARG_WITH([sdt], [
374AS_HELP_STRING([--with-sdt], [provide SystemTap integration via sdt.h [default=no]])
375], [
376 with_sdt=$withval
377], [
378 with_sdt="no"
379])
380
381AS_IF([test "x$with_sdt" = "xyes"], [
382 AC_MSG_CHECKING([STAP_PROBEV()])
383 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
384 #define SDT_USE_VARIADIC
385 #include <sys/sdt.h>
386 void fct(void)
387 {
388 STAP_PROBEV(provider,name,1,2,3,4,5,6,7,8,9,10);
389 }
390 ]])], [
391 AC_MSG_RESULT([yes])
392 AC_DEFINE([LTTNG_UST_HAVE_SDT_INTEGRATION], [1])
393 ], [
394 AC_MSG_RESULT([no])
395 AC_MSG_ERROR([The sdt.h integration was requested but the STAP_PROBEV define cannot be used. Make sure it is installed, and up to date, or use CPPFLAGS=-I/path/ to specify a non-standard path to sys/sdt.h])
396 ])
397])
398
399AC_ARG_WITH([lttng-system-rundir], [
400AS_HELP_STRING([--with-lttng-system-rundir], [Location of the system directory where LTTng-UST expects the system-wide lttng-sessiond runtime files. The default is "/var/run/lttng".]),
401], [
402 lttng_system_rundir="$withval"
403], [
404 lttng_system_rundir="/var/run/lttng"
405])
406AC_DEFINE_UNQUOTED([LTTNG_SYSTEM_RUNDIR], ["$lttng_system_rundir"],
407 [LTTng system runtime directory])
408
409AM_CONDITIONAL([ENABLE_GEN_TP_EXAMPLES], [test "x$PYTHON" != "x"])
410
411# Enable building examples
412AC_ARG_ENABLE(
413 examples,
414 AS_HELP_STRING(
415 [--disable-examples],
416 [Do not build and install examples]
417 ),
418 [enable_examples=$enableval],
419 [enable_examples=yes]
420)
421
422AM_CONDITIONAL([ENABLE_EXAMPLES], [test "x$enable_examples" != "xno"])
423
424# Enable building man pages (user's intention).
425AC_ARG_ENABLE(
426 man-pages,
427 AS_HELP_STRING(
428 [--disable-man-pages],
429 [Do not build and install man pages (already built in a distributed tarball)]
430 ),
431 [man_pages_opt=$enableval],
432 [man_pages_opt=yes]
433)
434
435# Check for asciidoc and xmlto if we enabled building the man pages.
436have_asciidoc_xmlto=no
437warn_prebuilt_man_pages=no
438
439AS_IF([test "x$man_pages_opt" = "xyes"], [
440 AS_IF([test "x$ASCIIDOC" = "x" || test "x$XMLTO" = "x"], [
441 AE_IF_IN_GIT_REPO([
442 # This is an error because we're in the Git repo, which
443 # means the man pages are not already generated for us,
444 # thus asciidoc/xmlto are required because we were asked
445 # to build the man pages.
446 AC_MSG_ERROR([
447Both asciidoc and xmlto are needed to build the LTTng-UST man pages. Use
448--disable-man-pages to disable building the man pages, in which case
449they will not be installed.
450 ])
451 ], [
452 # Only warn here: since we're in the tarball, the man
453 # pages should already be generated at this point, thus
454 # asciidoc/xmlto are not strictly required.
455 warn_prebuilt_man_pages=yes
456 ])
457 ], [
458 have_asciidoc_xmlto=yes
459 ])
460])
461
462# Export man page build condition: build the man pages if the user
463# asked for it, and if the tools are available.
464AM_CONDITIONAL([ENABLE_MAN_PAGES], [test "x$man_pages_opt" != "xno"])
465AM_CONDITIONAL([HAVE_ASCIIDOC_XMLTO], [test "x$have_asciidoc_xmlto" = "xyes"])
466
467
468# Defined in include/lttng/ust-version.h
469AC_DEFINE([LTTNG_UST_MAJOR_VERSION], ust_version_major, [LTTng UST major version])
470AC_DEFINE([LTTNG_UST_MINOR_VERSION], ust_version_minor, [LTTng UST minor version])
471AC_DEFINE([LTTNG_UST_PATCHLEVEL_VERSION], ust_version_patch, [LTTng UST patch version])
472AC_DEFINE([LTTNG_UST_VERSION], ["]ust_version["], [LTTng UST version string])
473AC_DEFINE([LTTNG_UST_LIB_SONAME_MAJOR], [ust_lib_version_current], [Major SONAME number of liblttng-ust])
474AC_DEFINE([LTTNG_UST_CTL_LIB_SONAME_MAJOR], [ust_ctl_lib_version_current], [Major SONAME number of liblttng-ust-ctl])
475
476
477AM_CFLAGS="-Wall $URCU_CFLAGS $PTHREAD_CFLAGS"
478AC_SUBST(AM_CFLAGS)
479
480AM_CXXFLAGS="$AM_CFLAGS"
481AC_SUBST(AM_CXXFLAGS)
482
483# The order in which the include folders are searched is important.
484# The top_builddir should always be searched first in the event that a build
485# time generated file is included.
486AM_CPPFLAGS="-I\$(top_builddir)/include -I\$(top_srcdir)/include -include config.h"
487AC_SUBST(AM_CPPFLAGS)
488
489AC_SUBST(JNI_CPPFLAGS)
490
491
492## ##
493## Output files generated by configure ##
494## ##
495
496# List of files to be generated from '.in' templates by AC_OUTPUT
497AC_CONFIG_FILES([
498 Makefile
499 doc/Makefile
500 doc/examples/Makefile
501 doc/man/Makefile
502 include/Makefile
503 snprintf/Makefile
504 libcounter/Makefile
505 libmsgpack/Makefile
506 libringbuffer/Makefile
507 liblttng-ust-comm/Makefile
508 liblttng-ust/Makefile
509 liblttng-ust-ctl/Makefile
510 liblttng-ust-fork/Makefile
511 liblttng-ust-dl/Makefile
512 liblttng-ust-fd/Makefile
513 liblttng-ust-java/Makefile
514 liblttng-ust-java-agent/Makefile
515 liblttng-ust-java-agent/java/Makefile
516 liblttng-ust-java-agent/java/lttng-ust-agent-all/Makefile
517 liblttng-ust-java-agent/java/lttng-ust-agent-common/Makefile
518 liblttng-ust-java-agent/java/lttng-ust-agent-jul/Makefile
519 liblttng-ust-java-agent/java/lttng-ust-agent-log4j/Makefile
520 liblttng-ust-java-agent/jni/Makefile
521 liblttng-ust-java-agent/jni/common/Makefile
522 liblttng-ust-java-agent/jni/jul/Makefile
523 liblttng-ust-java-agent/jni/log4j/Makefile
524 liblttng-ust-libc-wrapper/Makefile
525 liblttng-ust-cyg-profile/Makefile
526 liblttng-ust-python-agent/Makefile
527 python-lttngust/Makefile
528 python-lttngust/setup.py
529 python-lttngust/lttngust/__init__.py
530 tools/Makefile
531 tests/Makefile
532 tests/compile/Makefile
533 tests/compile/ctf-types/Makefile
534 tests/compile/hello.cxx/Makefile
535 tests/compile/hello/Makefile
536 tests/compile/hello-many/Makefile
537 tests/compile/same_line_tracepoint/Makefile
538 tests/compile/test-app-ctx/Makefile
539 tests/benchmark/Makefile
540 tests/unit/gcc-weak-hidden/Makefile
541 tests/unit/libmsgpack/Makefile
542 tests/unit/Makefile
543 tests/unit/libringbuffer/Makefile
544 tests/unit/pthread_name/Makefile
545 tests/unit/snprintf/Makefile
546 tests/unit/ust-elf/Makefile
547 tests/utils/Makefile
548 lttng-ust.pc
549 lttng-ust-ctl.pc
550])
551
552AC_OUTPUT
553
554
555## ##
556## Mini-report on what will be built. ##
557## ##
558
559PPRINT_INIT
560PPRINT_SET_INDENT(1)
561PPRINT_SET_TS(38)
562
563AS_ECHO
564AS_IF([test -n "ust_version_name"], [
565 AS_ECHO("${PPRINT_COLOR_BLDBLU}LTTng-ust $PACKAGE_VERSION \"ust_version_name\"$PPRINT_COLOR_RST")
566], [
567 AS_ECHO("${PPRINT_COLOR_BLDBLU}LTTng-ust $PACKAGE_VERSION")
568])
569
570AS_ECHO
571
572AS_IF([test -n "ust_version_description"], [
573 AS_IF([test -n "$FOLD"], [
574 AS_ECHO("`AS_ECHO("ust_version_description") | $FOLD -s`")
575 ], [
576 AS_ECHO("ust_version_description")
577 ])
578 AS_ECHO
579])
580
581PPRINT_SUBTITLE([System])
582
583PPRINT_PROP_STRING([Target architecture], $host_cpu)
584
585AS_IF([test "x$UNSUPPORTED_ARCH" = "x1"],[
586 PPRINT_WARN([Your architecture ($host_cpu) is unsupported, using safe default of no unaligned access.])
587])
588
589AS_ECHO
590PPRINT_SUBTITLE([Features])
591PPRINT_SET_INDENT(1)
592
593test "x$with_sdt" = "xyes" && value=1 || value=0
594PPRINT_PROP_BOOL_CUSTOM([sdt.h integration], $value, [use --with-sdt])
595
596test "x$java_agent_jul" = xyes && value=1 || value=0
597PPRINT_PROP_BOOL_CUSTOM([Java agent (JUL support)], $value, [use --enable-java-agent-jul])
598
599test "x$java_agent_log4j" = xyes && value=1 || value=0
600PPRINT_PROP_BOOL_CUSTOM([Java agent (Log4j support)], $value, [use --enable-java-agent-log4j])
601
602test "x$jni_interface" = xyes && value=1 || value=0
603PPRINT_PROP_BOOL_CUSTOM([JNI interface (JNI)], $value, [use --enable-jni-interface])
604
605test "x$python_agent" = xyes && value=1 || value=0
606PPRINT_PROP_BOOL_CUSTOM([Python agent], $value, [use --enable-python-agent])
607
608test "x$ac_cv_header_linux_perf_event_h" = "xyes" && value=1 || value=0
609PPRINT_PROP_BOOL_CUSTOM([Perf event integration], $value)
610
611test "x$enable_numa" = xyes && value=1 || value=0
612PPRINT_PROP_BOOL([NUMA], $value)
613
614AS_ECHO
615PPRINT_SET_INDENT(0)
616
617test "x$enable_examples" = xyes && value=1 || value=0
618PPRINT_PROP_BOOL([Build and install examples], $value, $PPRINT_COLOR_SUBTITLE)
619
620# man pages build enabled/disabled
621m4_pushdef([build_man_pages_msg], [Build and install man pages])
622
623AS_IF([test "x$man_pages_opt" != "xno"], [
624 AE_IF_IN_GIT_REPO([
625 PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
626 ], [
627 AS_IF([test "x$have_asciidoc_xmlto" = "xyes"], [
628 PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
629 ], [
630 PPRINT_PROP_STRING([build_man_pages_msg],
631 [${PPRINT_COLOR_BLDGRN}yes (already built)],
632 $PPRINT_COLOR_SUBTITLE)
633 ])
634 ])
635], [
636 PPRINT_PROP_BOOL([build_man_pages_msg], 0, $PPRINT_COLOR_SUBTITLE)
637])
638
639m4_popdef([build_man_pages_msg])
640
641PPRINT_SET_INDENT(1)
642
643report_bindir="`eval eval echo $bindir`"
644report_libdir="`eval eval echo $libdir`"
645
646# Print the bindir and libdir this `make install' will install into.
647AS_ECHO
648PPRINT_SUBTITLE([Install directories])
649PPRINT_PROP_STRING([Binaries], [$report_bindir])
650PPRINT_PROP_STRING([Libraries], [$report_libdir])
651
652AS_ECHO
653PPRINT_SUBTITLE([System directories])
654
655PPRINT_PROP_STRING([lttng-sessiond rundir], [$lttng_system_rundir])
656
657PPRINT_SET_INDENT(0)
658
659AS_IF([test "x$warn_prebuilt_man_pages" = "xyes" ], [
660 AS_ECHO
661 PPRINT_WARN([Both asciidoc and xmlto are needed to build the LTTng-UST man pages.
662
663Note that the man pages are already built in this distribution tarball,
664therefore asciidoc and xmlto are only needed if you intend to modify
665their sources.
666
667Use --disable-man-pages to completely disable building and installing
668the man pages.])
669])
This page took 0.024255 seconds and 4 git commands to generate.