configure.ac

   1 AC_PREREQ([2.64])
   2 AC_INIT([lttng-tools],[2.10.0-pre],[jeremie.galarneau@efficios.com],[],[https://lttng.org])
   3
   4 AC_CONFIG_HEADERS([include/config.h])
   5 AC_CONFIG_AUX_DIR([config])
   6 AC_CONFIG_MACRO_DIR([m4])
   7
   8 AC_CANONICAL_TARGET
   9 AC_CANONICAL_HOST
  10
  11 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip tar-pax])
  12 AM_MAINTAINER_MODE([enable])
  13
  14 # Enable silent rules if available (Introduced in AM 1.11)
  15 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  16
  17 AC_REQUIRE_AUX_FILE([tap-driver.sh])
  18
  19 # Checks for C compiler
  20 AC_USE_SYSTEM_EXTENSIONS
  21 AC_SYS_LARGEFILE
  22 AC_PROG_CC
  23 AC_PROG_CC_STDC
  24
  25 # Checks for programs.
  26 AC_PROG_GREP
  27 AC_PROG_LEX
  28 AC_PROG_MAKE_SET
  29 AC_PROG_SED
  30 AC_PROG_YACC
  31 AC_PATH_PROG(report_fold, fold)
  32 LT_INIT
  33
  34 # Check for objcopy, required by the base address statedump and dynamic linker tests
  35 AC_CHECK_TOOL([OBJCOPY], objcopy, no)
  36 AS_IF([test "x$OBJCOPY" = xno],
  37         [AC_MSG_WARN([Cannont find objcopy. The base address statedump and dynamic linker tests will be disabled. Install the binutils package to remediate this.])]
  38 )
  39 AM_CONDITIONAL([HAVE_OBJCOPY], [test "x$OBJCOPY" != xno])
  40
  41 # Checks for typedefs, structures, and compiler characteristics.
  42 AC_C_INLINE
  43 AC_TYPE_INT32_T
  44 AC_TYPE_INT64_T
  45 AC_TYPE_MODE_T
  46 AC_TYPE_OFF_T
  47 AC_TYPE_PID_T
  48 AC_TYPE_SIZE_T
  49 AC_TYPE_SSIZE_T
  50 AC_TYPE_UID_T
  51 AC_TYPE_UINT16_T
  52 AC_TYPE_UINT32_T
  53 AC_TYPE_UINT64_T
  54 AC_TYPE_UINT8_T
  55
  56 AX_C___ATTRIBUTE__
  57 AS_IF([test "x$ax_cv___attribute__" = "xyes"],
  58         [:],
  59         [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
  60
  61 AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])
  62 LIBS="$PTHREAD_LIBS $LIBS"
  63 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
  64 CC="$PTHREAD_CC"
  65
  66 AX_LIB_SOCKET_NSL
  67
  68 # Compute minor/major/patchlevel version numbers
  69 major_version=$(echo AC_PACKAGE_VERSION | $SED 's/^\([[0-9]]\)*\.[[0-9]]*\.[[0-9]]*.*$/\1/')
  70 minor_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.\([[0-9]]*\)\.[[0-9]]*.*$/\1/')
  71 patchlevel_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\).*$/\1/')
  72
  73 AC_SUBST([MAJOR_VERSION], [$major_version])
  74 AC_SUBST([MINOR_VERSION], [$minor_version])
  75 AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version])
  76 AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [LTTng-Tools major version number])
  77 AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [LTTng-Tools minor version number])
  78 AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [LTTng-Tools patchlevel version number])
  79
  80 version_name="Codename TBD"
  81 version_description='Description TBD'
  82 version_description_c=$(echo $version_description | $SED 's/"/\\"/g')
  83
  84 AC_DEFINE_UNQUOTED([VERSION_NAME], ["$version_name"], "")
  85 AC_DEFINE_UNQUOTED([VERSION_DESCRIPTION], ["$version_description_c"], "")
  86
  87 # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
  88 AC_ARG_ENABLE(libtool-linkdep-fixup,
  89         AS_HELP_STRING([--disable-libtool-linkdep-fixup],
  90                         [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)]),
  91         libtool_fixup=$enableval,
  92         libtool_fixup=yes)
  93
  94 AS_IF([test "x$libtool_fixup" = "xyes"],
  95             [
  96             libtool_m4="$srcdir/m4/libtool.m4"
  97             libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
  98             AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
  99             libtool_flag_pattern_count=$($GREP -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
 100             AS_IF([test $libtool_flag_pattern_count -ne 0],
 101             [
 102                   AC_MSG_RESULT([$libtool_flag_pattern_count])
 103                   AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
 104                   $SED -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
 105                   ],
 106                   [
 107                   AC_MSG_RESULT([none])
 108                   ])
 109             ])
 110
 111 AM_CONDITIONAL([NO_SHARED], [test x$enable_shared = xno])
 112
 113 AC_CHECK_HEADERS([ \
 114         sys/types.h unistd.h fcntl.h string.h pthread.h limits.h \
 115         signal.h stdlib.h sys/un.h sys/socket.h stdlib.h stdio.h \
 116         getopt.h sys/ipc.h sys/shm.h popt.h grp.h arpa/inet.h \
 117         netdb.h netinet/in.h paths.h stddef.h sys/file.h sys/ioctl.h \
 118         sys/mount.h sys/param.h sys/time.h
 119 ])
 120
 121 # Basic functions check
 122 AC_CHECK_FUNCS([ \
 123         atexit bzero clock_gettime dup2 fdatasync fls ftruncate \
 124         gethostbyname gethostname getpagesize localtime_r memchr memset \
 125         mkdir munmap putenv realpath rmdir socket strchr strcspn strdup \
 126         strncasecmp strndup strnlen strpbrk strrchr strstr strtol strtoul \
 127         strtoull dirfd gethostbyname2 getipnodebyname epoll_create1 \
 128 ])
 129
 130 # Check if clock_gettime, timer_create, timer_settime, and timer_delete are available in lib rt, and if so,
 131 # add -lrt to LIBS
 132 AC_CHECK_LIB([rt], [clock_gettime, timer_create, timer_settime, timer_delete])
 133
 134 # Babeltrace viewer check
 135 AC_ARG_WITH([babeltrace-bin],
 136         AS_HELP_STRING([--with-babeltrace-bin],
 137         [Location of the babeltrace viewer executable (including the filename)]),
 138         [BABELTRACE_BIN="$withval"],
 139         [BABELTRACE_BIN=''])
 140 AC_SUBST([BABELTRACE_BIN])
 141
 142 # lttv-gui
 143 AC_ARG_WITH([lttv-gui-bin],
 144         AS_HELP_STRING([--with-lttv-gui-bin],
 145    [Location of the lttv GUI viewer executable (including the filename)]),
 146    [LTTV_GUI_BIN="$withval"],
 147    [LTTV_GUI_BIN=''])
 148 AC_SUBST([LTTV_GUI_BIN])
 149
 150 AC_ARG_WITH([consumerd32-bin],
 151         AS_HELP_STRING([--with-consumerd32-bin],
 152         [Location of the 32-bit consumerd executable (including the filename)]),
 153         [CONSUMERD32_BIN="$withval"],
 154         [CONSUMERD32_BIN=''])
 155 AC_SUBST([CONSUMERD32_BIN])
 156
 157 AC_ARG_WITH([consumerd64-bin],
 158         AS_HELP_STRING([--with-consumerd64-bin],
 159         [Location of the 64-bit consumerd executable (including the filename)]),
 160         [CONSUMERD64_BIN="$withval"],
 161         [CONSUMERD64_BIN=''])
 162 AC_SUBST([CONSUMERD64_BIN])
 163
 164 AC_ARG_WITH([consumerd32-libdir],
 165         AS_HELP_STRING([--with-consumerd32-libdir],
 166         [Directory containing the 32-bit consumerd libraries]),
 167         [CONSUMERD32_LIBDIR="$withval"],
 168         [CONSUMERD32_LIBDIR=''])
 169 AC_SUBST([CONSUMERD32_LIBDIR])
 170
 171 AC_ARG_WITH([consumerd64-libdir],
 172         AS_HELP_STRING([--with-consumerd64-libdir],
 173         [Directory containing the 64-bit consumerd libraries]),
 174         [CONSUMERD64_LIBDIR="$withval"],
 175         [CONSUMERD64_LIBDIR=''])
 176 AC_SUBST([CONSUMERD64_LIBDIR])
 177
 178 AC_ARG_WITH([sessiond-bin],
 179         AS_HELP_STRING([--with-sessiond-bin],
 180         [Location of the sessiond executable (including the filename)]),
 181         [SESSIOND_BIN="$withval"],
 182         [SESSIOND_BIN=''])
 183 AC_SUBST([SESSIOND_BIN])
 184
 185 AC_ARG_WITH([lttng-system-rundir],
 186         AS_HELP_STRING([--with-lttng-system-rundir],
 187         [Location of the system directory where the system-wide lttng-sessiond runtime files are kept. The default is "/var/run/lttng".]),
 188         [LTTNG_SYSTEM_RUNDIR="$withval"],
 189         [LTTNG_SYSTEM_RUNDIR="/var/run/lttng"])
 190 AC_SUBST([LTTNG_SYSTEM_RUNDIR])
 191
 192 AC_ARG_ENABLE([test-java-agent-jul],
 193         [AS_HELP_STRING([--enable-test-java-agent-jul],[enable the LTTng UST Java agent JUL tests [default=no]])],
 194         [test_java_agent_jul=$enableval],
 195         [test_java_agent_jul=no]
 196 )
 197
 198 AC_ARG_ENABLE([test-java-agent-log4j],
 199         [AS_HELP_STRING([--enable-test-java-agent-log4j],[enable the LTTng UST Java agent Log4j tests [default=no]])],
 200         [test_java_agent_log4j=$enableval],
 201         [test_java_agent_log4j=no]
 202 )
 203
 204 AC_ARG_ENABLE([test-java-agent-all],
 205         [AS_HELP_STRING([--enable-test-java-agent-all],[enable all the LTTng UST Java agent tests [default=no]])],
 206         [test_java_agent_jul=$enableval
 207          test_java_agent_log4j=$enableval],
 208         [:]
 209 )
 210
 211 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_BIN], "$CONSUMERD32_BIN", [Location of the 32-bit consumerd executable.])
 212 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_BIN], "$CONSUMERD64_BIN", [Location of the 64-bit consumerd executable])
 213 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_LIBDIR], "$CONSUMERD32_LIBDIR", [Search for consumerd 32-bit libraries in this location.])
 214 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_LIBDIR], "$CONSUMERD64_LIBDIR", [Search for consumerd 64-bit libraries in this location.])
 215 AC_DEFINE_UNQUOTED([CONFIG_BABELTRACE_BIN], "$BABELTRACE_BIN", [Location of the babeltrace viewer executable.])
 216 AC_DEFINE_UNQUOTED([CONFIG_LTTV_GUI_BIN], "$LTTV_GUI_BIN", [Location of the lttv GUI viewer executable.])
 217 AC_DEFINE_UNQUOTED([CONFIG_SESSIOND_BIN], "$SESSIOND_BIN", [Location of the sessiond executable.])
 218 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_RUNDIR], ["$LTTNG_SYSTEM_RUNDIR"], [LTTng system runtime directory])
 219
 220 AC_DEFUN([_AC_DEFINE_AND_SUBST], [
 221         AC_DEFINE_UNQUOTED([CONFIG_$1], [$2], [$1])
 222         $1="$2"
 223         AC_SUBST([$1])
 224 ])
 225
 226 AC_DEFUN([_AC_DEFINE_QUOTED_AND_SUBST], [
 227         AC_DEFINE_UNQUOTED([CONFIG_$1], ["$2"], [$1])
 228         $1="$2"
 229         AC_SUBST([$1])
 230 ])
 231
 232 # Default values
 233 m4_define([_DEFAULT_CHANNEL_SUBBUF_SIZE], [4096])
 234 m4_define([_DEFAULT_CHANNEL_SUBBUF_NUM], [4])
 235 m4_define([_DEFAULT_CHANNEL_SWITCH_TIMER], [0])
 236 m4_define([_DEFAULT_CHANNEL_LIVE_TIMER], [0])
 237 m4_define([_DEFAULT_CHANNEL_READ_TIMER], [200000])
 238 _AC_DEFINE_AND_SUBST([DEFAULT_AGENT_TCP_PORT], [5345])
 239 _AC_DEFINE_AND_SUBST([DEFAULT_APP_SOCKET_RW_TIMEOUT], [5])
 240 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE])
 241 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_COUNT], [0])
 242 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_SIZE], [0])
 243 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 244 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_READ_TIMER], [_DEFAULT_CHANNEL_READ_TIMER])
 245 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 246 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_SIZE], [262144])
 247 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 248 _AC_DEFINE_AND_SUBST([DEFAULT_LTTNG_LIVE_TIMER], [1000000])
 249 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_CACHE_SIZE], [4096])
 250 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_READ_TIMER], [0])
 251 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_NUM], [2])
 252 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_SIZE], [4096])
 253 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 254 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_CONTROL_PORT], [5342])
 255 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_DATA_PORT], [5343])
 256 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_VIEWER_PORT], [5344])
 257 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 258 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_READ_TIMER], [0])
 259 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 260 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE])
 261 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 262 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 263 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_READ_TIMER], [0])
 264 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 265 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_SIZE], [131072])
 266 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 267 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_AGENT_BIND_ADDRESS], [localhost])
 268 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_CONTROL_BIND_ADDRESS], [0.0.0.0])
 269 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_DATA_BIND_ADDRESS], [0.0.0.0])
 270 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_VIEWER_BIND_ADDRESS], [localhost])
 271
 272 # Command short descriptions
 273 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ADD_CONTEXT], [Add context fields to a channel])
 274 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_CREATE], [Create a tracing session])
 275 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DESTROY], [Tear down tracing sessions])
 276 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_CHANNEL], [Disable tracing channels])
 277 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_EVENT], [Disable event rules])
 278 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_CHANNEL], [Create or enable tracing channels])
 279 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_EVENT], [Create or enable event rules])
 280 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_HELP], [Display help information about a command])
 281 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LIST], [List tracing sessions, domains, channels, and events])
 282 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LOAD], [Load tracing session configurations])
 283 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_METADATA], [Manage an LTTng tracing session's metadata generation])
 284 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_REGENERATE], [Manage an LTTng tracing session's data regeneration])
 285 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SAVE], [Save tracing session configurations])
 286 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SET_SESSION], [Set current tracing session])
 287 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SNAPSHOT], [Snapshot buffers of current tracing session])
 288 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_START], [Start tracing])
 289 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STATUS], [Get the status of the current tracing session])
 290 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STOP], [Stop tracing])
 291 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_TRACK], [Track specific system resources])
 292 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_UNTRACK], [Untrack specific system resources])
 293 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VERSION], [Show version information])
 294 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VIEW], [Start trace viewer])
 295
 296 if test "x$prefix" = "xNONE"; then
 297         prefix=$ac_default_prefix
 298 fi
 299 CONFDIR=`eval echo $sysconfdir`
 300 AC_SUBST(CONFDIR)
 301 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_CONFIGDIR],"$CONFDIR", [LTTng system configuration directory.])
 302
 303 AC_DEFINE_DIR([CONFIG_LTTNG_SYSTEM_DATADIR],[datadir], [LTTng system data directory.])
 304
 305 #
 306 # Check for pthread
 307 AC_CHECK_LIB([pthread], [pthread_create], [],
 308         [AC_MSG_ERROR([Cannot find libpthread. Use LDFLAGS=-Ldir to specify its location.])]
 309 )
 310
 311 # Check libpopt
 312 PKG_CHECK_MODULES([POPT], [popt],
 313         [LIBS="$LIBS $POPT_LIBS"],
 314         [
 315                 AC_MSG_WARN([pkg-config was unable to find a valid .pc for libpopt. Set PKG_CONFIG_PATH to specify the pkgconfig configuration file location])
 316                 AC_MSG_WARN([Finding libpopt without pkg-config.])
 317                 AC_CHECK_LIB([popt],
 318                         [poptGetContext],
 319                         [],
 320                         [
 321                                  AC_MSG_ERROR([Cannot find libpopt. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location])
 322                         ]
 323                 )
 324         ]
 325 )
 326
 327 PKG_CHECK_MODULES([libxml2], [libxml-2.0 >= 2.7.6])
 328
 329 # Check for uuid in system libs
 330 AC_CHECK_FUNCS([uuid_generate],
 331 [
 332         AC_DEFINE_UNQUOTED([LTTNG_HAVE_LIBUUID], 1, [Has libuuid support.])
 333         link_with_libuuid=no
 334 ],
 335 [
 336 # First, check the pkg-config module is available, otherwise explicitly check
 337 # for libuuid, or uuid support in the C-library.
 338 PKG_CHECK_MODULES([UUID], [uuid],
 339 [
 340         LIBS="$LIBS $UUID_LIBS"
 341         AC_DEFINE_UNQUOTED([LTTNG_HAVE_LIBUUID], 1, [Has libuuid support.])
 342         link_with_libuuid=yes
 343 ],
 344 [
 345         # Check for libuuid
 346         AC_CHECK_LIB([uuid],
 347                 [uuid_generate],
 348                 [
 349                         AC_DEFINE_UNQUOTED([LTTNG_HAVE_LIBUUID], 1, [Has libuuid support.])
 350                         link_with_libuuid=yes
 351                 ],
 352                 [
 353                         # libuuid not found, check for uuid_create in libc.
 354                         AC_CHECK_LIB([c],
 355                                 [uuid_create],
 356                                 [
 357                                         AC_DEFINE_UNQUOTED([LTTNG_HAVE_LIBC_UUID], 1, [Has libc uuid support.])
 358                                         link_with_libc_uuid=yes
 359                                 ],
 360                                 [
 361                                         AC_MSG_ERROR([Cannot find libuuid uuid_generate nor libc uuid_create. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location])
 362                                 ]
 363                         )
 364                 ]
 365         )
 366 ])
 367 ])
 368
 369 AM_CONDITIONAL([LTTNG_BUILD_WITH_LIBUUID], [test "x$link_with_libuuid" = "xyes"])
 370 AM_CONDITIONAL([LTTNG_BUILD_WITH_LIBC_UUID], [test "x$link_with_libc_uuid" = "xyes"])
 371
 372 AC_CHECK_FUNC([clock_gettime], [AC_DEFINE_UNQUOTED([LTTNG_HAVE_CLOCK_GETTIME], 1, [Has clock_gettime() support.])])
 373
 374 # URCU library version needed or newer
 375 m4_define([WRONG_LIBURCU_MSG], [Userspace RCU (liburcu) >= 0.8.0 is needed])
 376
 377 # Check liburcu needed function calls
 378 AC_CHECK_DECL([cds_list_add], [],
 379         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/list.h>]])
 380 AC_CHECK_DECL([cds_wfcq_init], [],
 381         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/wfcqueue.h>]])
 382 AC_CHECK_DECL([cds_wfcq_dequeue_blocking], [],
 383         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/wfcqueue.h>]])
 384 AC_CHECK_DECL([futex_async], [],
 385         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/futex.h>]])
 386 AC_CHECK_DECL([rcu_thread_offline], [],
 387         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
 388 AC_CHECK_DECL([rcu_thread_online], [],
 389         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
 390 AC_CHECK_DECL([caa_likely], [],
 391         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
 392 AC_CHECK_LIB([urcu-cds], [_cds_lfht_new], [],
 393         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])])
 394
 395 #Function added in urcu 0.7.0
 396 AC_CHECK_DECL([cmm_smp_mb__before_uatomic_or], [],
 397         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]]
 398 )
 399
 400 # Check kmod library
 401 AC_ARG_WITH(kmod-prefix,
 402   AS_HELP_STRING([--with-kmod-prefix=PATH],
 403                 [Specify the installation prefix of the kmod library.
 404                 Headers must be in PATH/include; libraries in PATH/lib.]),
 405                 [
 406                         CPPFLAGS="$CPPFLAGS -I${withval}/include"
 407                         LDFLAGS="$LDFLAGS -L${withval}/lib64 -L${withval}/lib"
 408                 ])
 409
 410 AC_ARG_ENABLE(kmod,
 411         AS_HELP_STRING([--disable-kmod],[build without kmod support]),
 412         kmod_support=$enableval, kmod_support=yes)
 413
 414 AS_IF([test "x$kmod_support" = "xyes"], [
 415         AC_CHECK_LIB([kmod], [kmod_module_probe_insert_module],
 416                 [
 417                         AC_DEFINE([HAVE_KMOD], [1], [has kmod support])
 418                         LIBS="$LIBS -lkmod"
 419                         kmod_found=yes
 420                 ],
 421                 kmod_found=no
 422         )
 423 ])
 424 AM_CONDITIONAL([HAVE_KMOD], [test "x$kmod_found" = xyes])
 425
 426 AC_ARG_WITH(lttng-ust-prefix,
 427   AS_HELP_STRING([--with-lttng-ust-prefix=PATH],
 428                  [Specify the installation prefix of the lttng-ust library.
 429                   Headers must be in PATH/include; libraries in PATH/lib.]),
 430                   [
 431                     CPPFLAGS="$CPPFLAGS -I${withval}/include"
 432                     LDFLAGS="$LDFLAGS -L${withval}/lib64 -L${withval}/lib"
 433                   ])
 434
 435 # Check liblttng-ust-ctl library
 436 AC_ARG_WITH(lttng-ust,
 437         AS_HELP_STRING([--without-lttng-ust],[build without LTTng-UST (Userspace Tracing) support]),
 438         lttng_ust_support=$withval, lttng_ust_support=yes)
 439
 440 AS_IF([test "x$lttng_ust_support" = "xyes"], [
 441         AC_CHECK_LIB([lttng-ust-ctl], [ustctl_recv_channel_from_consumer],
 442                 [
 443                         AC_DEFINE([HAVE_LIBLTTNG_UST_CTL], [1], [has LTTng-UST control support])
 444                         lttng_ust_ctl_found=yes
 445                 ],
 446                 [AC_MSG_ERROR([Cannot find LTTng-UST >= 2.2.x. Use --with-lttng-ust-prefix=PREFIX to specify its location, or specify --without-lttng-ust to build lttng-tools without LTTng-UST support.])],
 447                 [-lurcu-common -lurcu-bp -lurcu-cds -lrt -ldl]
 448         )
 449 ])
 450 AM_CONDITIONAL([HAVE_LIBLTTNG_UST_CTL], [test "x$lttng_ust_ctl_found" = xyes])
 451 AC_CHECK_FUNCS([sched_getcpu sysconf sync_file_range])
 452
 453 # check for dlopen
 454 AC_CHECK_LIB([dl], [dlopen],
 455 [
 456         have_libdl=yes
 457 ],
 458 [
 459         #libdl not found, check for dlopen in libc.
 460         AC_CHECK_LIB([c], [dlopen],
 461         [
 462                 have_libc_dl=yes
 463         ],
 464         [
 465                 AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
 466         ])
 467 ])
 468 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBDL], [test "x$have_libdl" = "xyes"])
 469 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBC_DL], [test "x$have_libc_dl" = "xyes"])
 470
 471 # Check for fmemopen
 472 AC_CHECK_LIB([c], [fmemopen],
 473 [
 474         AC_DEFINE_UNQUOTED([LTTNG_HAVE_FMEMOPEN], 1, [Has fmemopen support.])
 475 ]
 476 )
 477
 478 # Check for open_memstream
 479 AC_CHECK_LIB([c], [open_memstream],
 480 [
 481         AC_DEFINE_UNQUOTED([LTTNG_HAVE_OPEN_MEMSTREAM], 1, [Has open_memstream support.])
 482 ]
 483 )
 484
 485 # check for libpfm
 486 AC_CHECK_LIB([pfm], [pfm_initialize],
 487              [
 488               have_libpfm=yes
 489               ])
 490 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBPFM], [test "x$have_libpfm" = "xyes"])
 491
 492 AC_ARG_ENABLE([git-version],
 493               [AC_HELP_STRING([--disable-git-version],
 494                               [Do not use the git version for the build])],
 495               [have_git_version=$enableval], [have_git_version=yes]
 496 )
 497
 498 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_GIT_SOURCE],
 499         [test "x${have_git_version}" = "xyes"])
 500
 501 # For Python
 502 # SWIG version needed or newer:
 503 swig_version=2.0.0
 504
 505 AC_ARG_ENABLE([python-bindings],
 506               [AC_HELP_STRING([--enable-python-bindings],
 507                               [compile Python bindings])],
 508               [enable_python_binding=$enableval], [enable_python_binding=no])
 509
 510 AM_CONDITIONAL([PYTHON_BINDING], [test "x$enable_python_binding" = xyes])
 511
 512 if test "x$enable_python_binding" = xyes; then
 513   AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ])
 514   AS_IF([test x$enable_shared = xno], [ AC_MSG_ERROR([Python bindings require shared libraries.]) ])
 515   AM_PATH_PYTHON([3.0])
 516
 517   AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config])
 518   AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
 519   AS_IF([test -z "$PYTHON_INCLUDE"], [
 520     AS_IF([test -z "$PYTHON_CONFIG"], [
 521       AC_PATH_PROGS([PYTHON_CONFIG],
 522                     [python$PYTHON_VERSION-config python-config],
 523                     [no],
 524                     [`dirname $PYTHON`])
 525       AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
 526     ])
 527     AC_MSG_CHECKING([python include flags])
 528     PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
 529     AC_MSG_RESULT([$PYTHON_INCLUDE])
 530   ])
 531
 532 else
 533     AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl
 534 [if you want Python bindings.])
 535
 536 fi
 537
 538 # Epoll check. If not present, the build will fallback on poll() API
 539 AX_HAVE_EPOLL(
 540         [AX_CONFIG_FEATURE_ENABLE(epoll)],
 541         [AX_CONFIG_FEATURE_DISABLE(epoll)]
 542 )
 543 AX_CONFIG_FEATURE(
 544         [epoll], [This platform supports epoll(7)],
 545         [HAVE_EPOLL], [This platform supports epoll(7).],
 546         [enable_epoll="yes"], [enable_epoll="no"]
 547 )
 548 AM_CONDITIONAL([COMPAT_EPOLL], [ test "$enable_epoll" = "yes" ])
 549
 550 AM_CONDITIONAL([TEST_JAVA_JUL_AGENT], [test "x$test_java_agent_jul" = "xyes"])
 551 AM_CONDITIONAL([TEST_JAVA_LOG4J_AGENT], [test "x$test_java_agent_log4j" = "xyes"])
 552
 553 if test "x$test_java_agent_jul" = "xyes" || test "x$test_java_agent_log4j" = "xyes"; then
 554         AX_JAVA_OPTIONS
 555         AX_PROG_JAVAC
 556         AX_PROG_JAVA
 557         AX_PROG_JAR
 558
 559         AX_CHECK_CLASSPATH
 560
 561         # Check for Java UST agent common class first
 562         AX_CHECK_CLASS(org.lttng.ust.agent.AbstractLttngAgent)
 563         if test "x$ac_cv_class_org_lttng_ust_agent_AbstractLttngAgent" = "xno"; then
 564                 AC_MSG_ERROR([The UST Java agent common class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-common.jar"])
 565         fi
 566
 567         if test "x$test_java_agent_jul" = "xyes"; then
 568                 # Check for JUL agent class
 569                 AX_CHECK_CLASS(org.lttng.ust.agent.jul.LttngLogHandler)
 570                 if test "x$ac_cv_class_org_lttng_ust_agent_jul_LttngLogHandler" = "xno"; then
 571                         AC_MSG_ERROR([The UST Java agent JUL class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-jul.jar"])
 572                 fi
 573         fi
 574
 575         if test "x$test_java_agent_log4j" = "xyes"; then
 576                 # Check for Log4j agent class
 577                 AX_CHECK_CLASS(org.lttng.ust.agent.log4j.LttngLogAppender)
 578                 if test "x$ac_cv_class_org_lttng_ust_agent_log4j_LttngLogAppender" = "xno"; then
 579                         AC_MSG_ERROR([The UST Java agent Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-log4j.jar"])
 580                 fi
 581
 582                 # Check for Log4j class
 583                 AX_CHECK_CLASS(org.apache.log4j.Logger)
 584                 if test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"; then
 585                         AC_MSG_ERROR([The Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j.jar"])
 586                 fi
 587         fi
 588 fi
 589
 590 # set $IN_GIT_REPO if we're in the Git repository; the `bootstrap` file
 591 # is not distributed in tarballs
 592 AS_IF([test -f "$srcdir/bootstrap"], [in_git_repo=yes], [in_git_repo=no])
 593 AM_CONDITIONAL([IN_GIT_REPO], [test "x$in_git_repo" = "xyes"])
 594
 595 # enable building man pages (user's intention)
 596 AC_ARG_ENABLE(
 597         man-pages,
 598         AS_HELP_STRING(
 599                 [--disable-man-pages],
 600                 [Do not build and install man pages (already built in a distributed tarball)]
 601         ),
 602         [man_pages_opt=$enableval],
 603         [man_pages_opt=yes]
 604 )
 605
 606 # check for asciidoc and xmlto if we enabled building the man pages
 607 have_asciidoc_xmlto=no
 608 warn_prebuilt_man_pages=no
 609
 610 AS_IF([test "x$man_pages_opt" = "xyes"], [
 611         AC_PATH_PROG([ASCIIDOC], [asciidoc], [no])
 612         AC_PATH_PROG([XMLTO], [xmlto], [no])
 613
 614         AS_IF([test "x$ASCIIDOC" = "xno" || test "x$XMLTO" = "xno"], [
 615                 AS_IF([test "x$in_git_repo" = "xyes"], [
 616                         # this is an error because we're in the Git repo, which
 617                         # means the man pages are not already generated for us,
 618                         # thus asciidoc/xmlto are required because we were asked
 619                         # to build the man pages
 620                         AC_MSG_ERROR([
 621 You need asciidoc and xmlto to build the LTTng-tools man pages. Use
 622 --disable-man-pages to disable building the man pages, in which case
 623 they will not be installed.
 624                         ])
 625                 ], [
 626                         # only warn here: since we're in the tarball, the man
 627                         # pages should already be generated at this point, thus
 628                         # asciidoc/xmlto are not strictly required
 629                         warn_prebuilt_man_pages=yes
 630                 ])
 631         ], [
 632                 have_asciidoc_xmlto=yes
 633         ])
 634 ])
 635
 636 # export man page build condition: build the man pages if the user
 637 # asked for it, and if the tools are available
 638 AM_CONDITIONAL([MAN_PAGES_OPT], [test "x$man_pages_opt" != "xno"])
 639 AM_CONDITIONAL([HAVE_ASCIIDOC_XMLTO], [test "x$have_asciidoc_xmlto" = "xyes"])
 640
 641 AC_DEFINE_UNQUOTED([MANPATH], ["`eval eval echo $mandir`"], [Path to man pages.])
 642
 643 # Python agent test
 644 UST_PYTHON_AGENT="lttngust"
 645
 646 AC_ARG_ENABLE(test-python2-agent,
 647         AS_HELP_STRING([--enable-test-python2-agent],
 648                 [enable tests for python2 agent. Python2 interpreter path can be overridden by setting the PYTHON2 environment variable. Default: Autodetect]
 649         ),[:],[test_python2_agent_autodetect=yes]
 650 )
 651
 652 AC_ARG_ENABLE(test-python3-agent,
 653         AS_HELP_STRING([--enable-test-python3-agent],
 654                 [enable tests for python3 agent. Python3 interpreter path can be overridden by setting the PYTHON3 environment variable. Default: Autodetect]
 655         ),[:],[test_python3_agent_autodetect=yes]
 656 )
 657
 658 AC_ARG_ENABLE(test-python-agent-all,
 659         AS_HELP_STRING([--enable-test-python-agent-all],
 660                 [enable test for all python{2/3} agent.]
 661         ),
 662 )
 663
 664 AS_IF([test ! -z "$enable_test_python_agent_all"], [
 665        unset test_python2_agent_autodetect
 666        unset test_python3_agent_autodetect
 667 ])
 668
 669 AS_IF([test "x$enable_test_python_agent_all" = "xyes"], [
 670        enable_test_python2_agent=yes
 671        enable_test_python3_agent=yes
 672 ])
 673
 674 AS_IF([test "x$enable_test_python_agent_all" = "xno"], [
 675        enable_test_python2_agent=no
 676        enable_test_python3_agent=no
 677 ])
 678
 679
 680 AS_IF([test "x$enable_test_python2_agent" = "xyes" -o "x$test_python2_agent_autodetect" = "xyes" ], [
 681         AS_IF([test -z "$PYTHON2"], [
 682                         PYTHON2=python2
 683                 ], [
 684                         AC_MSG_WARN([Using user-defined PYTHON2 ($PYTHON2) for lttng-ust python2 agent check])
 685         ])
 686
 687         AC_PATH_PROG([PYTHON2_BIN],[$PYTHON2])
 688         AS_IF([test -z "$PYTHON2_BIN"], [
 689                 AS_IF([test -z "$test_python2_agent_autodetect"],[
 690                         AC_MSG_ERROR([No python2 interpreter found. PYTHON2 can be set to override default interpreter path])
 691                 ])
 692         ], [
 693                 AC_MSG_CHECKING([for python2 lttng-ust agent])
 694                 AS_IF([$PYTHON2_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
 695                         PYTHON2_AGENT=$PYTHON2_BIN
 696                         AC_MSG_RESULT([yes])
 697                         RUN_PYTHON_AGENT_TEST=yes
 698                 ], [
 699                         AC_MSG_RESULT([no])
 700                         AS_IF([test -z "$test_python2_agent_autodetect"],[
 701                                 AC_MSG_ERROR([No python2 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
 702                         ])
 703                 ])
 704
 705         ])
 706
 707 ])
 708
 709 AS_IF([test "x$enable_test_python3_agent" = "xyes" -o "x$test_python3_agent_autodetect" = "xyes" ], [
 710         AS_IF([test -z "$PYTHON3"], [
 711                 PYTHON3=python3
 712         ], [
 713                 AC_MSG_WARN([Using user-defined PYTHON3 ($PYTHON3) for lttng-ust python3 agent check])
 714         ])
 715
 716         AC_PATH_PROG([PYTHON3_BIN],[$PYTHON3])
 717         AS_IF([test -z "$PYTHON3_BIN"], [
 718                 AS_IF([test -z "$test_python3_agent_autodetect"],[
 719                         AC_MSG_ERROR([No python3 interpreter found. PYTHON3 can be set to override default interpreter path])
 720                 ])
 721         ], [
 722                 AC_MSG_CHECKING([for python3 lttng-ust agent])
 723                 AS_IF([$PYTHON3_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
 724                         PYTHON3_AGENT=$PYTHON3_BIN
 725                         AC_MSG_RESULT([yes])
 726                         RUN_PYTHON_AGENT_TEST=yes
 727                 ], [
 728                         AC_MSG_RESULT([no])
 729                         AS_IF([test -z "$test_python3_agent_autodetect"],[
 730                                 AC_MSG_ERROR([No python3 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
 731                         ])
 732                 ])
 733
 734         ])
 735 ])
 736 AC_SUBST([RUN_PYTHON_AGENT_TEST])
 737 AC_SUBST([PYTHON2_AGENT])
 738 AC_SUBST([PYTHON3_AGENT])
 739
 740 # Arguments for binaries build exclusion
 741 AC_ARG_ENABLE([bin-lttng], AS_HELP_STRING([--disable-bin-lttng],[Disable the build of lttng binaries]))
 742 AC_ARG_ENABLE([bin-lttng-consumerd], AS_HELP_STRING([--disable-bin-lttng-consumerd],
 743               [Disable the build of lttng-consumerd binaries]))
 744 AC_ARG_ENABLE([bin-lttng-crash], AS_HELP_STRING([--disable-bin-lttng-crash],[Disable the build of lttng-crash binaries]))
 745 AC_ARG_ENABLE([bin-lttng-relayd], AS_HELP_STRING([--disable-bin-lttng-relayd],
 746               [Disable the build of lttng-relayd binaries]))
 747 AC_ARG_ENABLE([bin-lttng-sessiond], AS_HELP_STRING([--disable-bin-lttng-sessiond],
 748               [Disable the build of lttng-sessiond binaries]))
 749 AC_ARG_ENABLE([extras], AS_HELP_STRING([--disable-extras],
 750               [Disable the build of the extra components]))
 751
 752
 753 # Always build libconfig since it a dependency of libcommon
 754 build_lib_config=yes
 755
 756 build_lib_compat=no
 757 build_lib_consumer=no
 758 build_lib_hashtable=no
 759 build_lib_health=no
 760 build_lib_index=no
 761 build_lib_kernel_consumer=no
 762 build_lib_kernel_ctl=no
 763 build_lib_lttng_ctl=no
 764 build_lib_relayd=no
 765 build_lib_sessiond_comm=no
 766 build_lib_testpoint=no
 767 build_lib_ust_consumer=no
 768
 769 # There is an overlap for enabled dependencies, but this makes everything
 770 # simpler. libcommon and libconfig are always compiled so they are not repeated
 771 # here.
 772
 773 # Enable binary dependencies.
 774 AS_IF([test x$enable_bin_lttng != xno],
 775       [
 776        build_lib_lttng_ctl=yes
 777       ]
 778 )
 779
 780 AS_IF([test x$enable_bin_lttng_consumerd != xno],
 781       [
 782        build_lib_consumer=yes
 783        build_lib_sessiond_comm=yes
 784        build_lib_index=yes
 785        build_lib_health=yes
 786        build_lib_testpoint=yes
 787       ]
 788 )
 789
 790 AS_IF([test x$enable_bin_lttng_crash != xno],
 791       # Do nothing since libconfig and libcommon are built by default.
 792       []
 793 )
 794
 795 AS_IF([test x$enable_bin_lttng_relayd != xno],
 796       [
 797        build_lib_lttng_ctl=yes
 798        build_lib_sessiond_comm=yes
 799        build_lib_hashtable=yes
 800        build_lib_compat=yes
 801        build_lib_index=yes
 802        build_lib_health=yes
 803        build_lib_testpoint=yes
 804       ]
 805 )
 806 AS_IF([test x$enable_bin_lttng_sessiond != xno],
 807       [
 808        build_lib_lttng_ctl=yes
 809        build_lib_sessiond_comm=yes
 810        build_lib_kernel_ctl=yes
 811        build_lib_hashtable=yes
 812        build_lib_compat=yes
 813        build_lib_relayd=yes
 814        build_lib_testpoint=yes
 815        build_lib_health=yes
 816        build_lib_health=yes
 817       ]
 818 )
 819
 820 # Libraries dependencies enabling
 821 AS_IF([test x$build_lib_lttng_ctl = xyes],
 822       [
 823        build_lib_sessiond_comm=yes
 824        build_lib_hashtable=yes
 825       ]
 826 )
 827
 828 AS_IF([test x$build_lib_consumer = xyes],
 829       [
 830        build_lib_sessiond_comm=yes
 831        build_lib_kernel_consumer=yes
 832        build_lib_hashtable=yes
 833        build_lib_compat=yes
 834        build_lib_relayd=yes
 835        AS_IF([test x$lttng_ust_ctl_found = xyes],[build_lib_ust_consumer=yes])
 836       ]
 837 )
 838
 839 AS_IF([test x$build_lib_kernel_consumer = xyes],
 840       [
 841        build_lib_kernel_ctl=yes
 842        build_lib_relayd=yes
 843       ]
 844 )
 845
 846 AS_IF([test x$build_lib_relayd = xyes],
 847       [
 848        build_lib_sessiond_comm=yes
 849       ]
 850 )
 851
 852
 853 # Export binaries build conditions.
 854 AM_CONDITIONAL([BUILD_BIN_LTTNG], [test x$enable_bin_lttng != xno])
 855 AM_CONDITIONAL([BUILD_BIN_LTTNG_CONSUMERD], [test x$enable_bin_lttng_consumerd != xno])
 856 AM_CONDITIONAL([BUILD_BIN_LTTNG_CRASH], [test x$enable_bin_lttng_crash != xno])
 857 AM_CONDITIONAL([BUILD_BIN_LTTNG_RELAYD], [test x$enable_bin_lttng_relayd != xno])
 858 AM_CONDITIONAL([BUILD_BIN_LTTNG_SESSIOND], [test x$enable_bin_lttng_sessiond != xno])
 859
 860 # Export the tests and extras build conditions.
 861 AS_IF([\
 862 test "x$enable_bin_lttng" != "xno" && \
 863 test "x$enable_bin_lttng_consumerd" != "xno" && \
 864 test "x$enable_bin_lttng_crash" != "xno" && \
 865 test "x$enable_bin_lttng_relayd" != "xno" && \
 866 test "x$enable_bin_lttng_sessiond" != "xno"],
 867 [build_tests=yes],
 868 [build_tests=no]
 869 )
 870
 871 AM_CONDITIONAL([BUILD_TESTS], [test x$build_tests = xyes])
 872 AM_CONDITIONAL([BUILD_EXTRAS], [test x$enable_extras != xno])
 873
 874 # Export libraries build conditions.
 875 AM_CONDITIONAL([BUILD_LIB_COMPAT], [test x$build_lib_compat = xyes])
 876 AM_CONDITIONAL([BUILD_LIB_CONFIG], [test x$build_lib_config = xyes])
 877 AM_CONDITIONAL([BUILD_LIB_CONSUMER], [test x$build_lib_consumer = xyes])
 878 AM_CONDITIONAL([BUILD_LIB_HASHTABLE], [test x$build_lib_hashtable = xyes])
 879 AM_CONDITIONAL([BUILD_LIB_HEALTH], [test x$build_lib_health = xyes])
 880 AM_CONDITIONAL([BUILD_LIB_INDEX], [test x$build_lib_index = xyes])
 881 AM_CONDITIONAL([BUILD_LIB_KERNEL_CONSUMER], [test x$build_lib_kernel_consumer = xyes])
 882 AM_CONDITIONAL([BUILD_LIB_KERNEL_CTL], [test x$build_lib_kernel_ctl = xyes])
 883 AM_CONDITIONAL([BUILD_LIB_LTTNG_CTL], [test x$build_lib_lttng_ctl = xyes])
 884 AM_CONDITIONAL([BUILD_LIB_RELAYD], [test x$build_lib_relayd = xyes])
 885 AM_CONDITIONAL([BUILD_LIB_SESSIOND_COMM], [test x$build_lib_sessiond_comm = xyes])
 886 AM_CONDITIONAL([BUILD_LIB_TESTPOINT], [test x$build_lib_testpoint = xyes])
 887 AM_CONDITIONAL([BUILD_LIB_UST_CONSUMER], [test x$build_lib_ust_consumer = xyes])
 888
 889 # check for pgrep
 890 AC_PATH_PROG([PGREP], [pgrep], [no])
 891 AM_CONDITIONAL([HAS_PGREP], [test "x$PGREP" != "xno"])
 892
 893 # check for bison
 894 have_bison=yes
 895
 896 AS_IF([test "x$(basename "$YACC")" != "xbison -y"], [have_bison=no])
 897 AC_PATH_PROG([BISON], [bison])
 898 AX_PROG_BISON_VERSION([2.4], [], [have_bison=no])
 899
 900 AS_IF([test "x$have_bison" = "xno"], [
 901         AS_IF([test "x$in_git_repo" = "xyes"], [
 902                 AC_MSG_ERROR([Bison >= 2.4 is required when building from the Git repository.])
 903         ], [
 904                 AC_MSG_WARN([
 905 Missing Bison >= 2.4. Note that the parser files are already built in
 906 this distribution tarball, so Bison is only needed if you intend to
 907 modify their sources.
 908                 ])
 909         ])
 910 ])
 911
 912 # export bison condition
 913 AM_CONDITIONAL([HAVE_BISON], [test "x$have_bison" = "xyes"])
 914
 915 # check for flex
 916 have_flex=yes
 917
 918 AS_IF([test "x$LEX" != "xflex"], [have_flex=no])
 919 AC_PATH_PROG([FLEX], [flex])
 920 AX_PROG_FLEX_VERSION([2.5.35], [], [have_flex=no])
 921
 922 AS_IF([test "x$have_flex" = "xno"], [
 923         AS_IF([test "x$in_git_repo" = "xyes"], [
 924                 AC_MSG_ERROR([Flex >= 2.5.35 is required when building from the Git repository.])
 925         ], [
 926                 AC_MSG_WARN([
 927 Missing Flex >= 2.5.35. Note that the lexer files are already built in
 928 this distribution tarball, so Flex is only needed if you intend to
 929 modify their sources.
 930                 ])
 931         ])
 932 ])
 933
 934 # export flex condition
 935 AM_CONDITIONAL([HAVE_FLEX], [test "x$have_flex" = "xyes"])
 936
 937 CFLAGS="-Wall $CFLAGS -g -fno-strict-aliasing"
 938
 939 DEFAULT_INCLUDES="-I\$(top_srcdir) -I\$(top_builddir) -I\$(top_builddir)/src -I\$(top_builddir)/include -include config.h"
 940
 941 lttngincludedir="${includedir}/lttng"
 942
 943 AC_SUBST(lttngincludedir)
 944 AC_SUBST(DEFAULT_INCLUDES)
 945
 946 lttnglibexecdir="${libdir}/lttng/libexec"
 947 AC_SUBST(lttnglibexecdir)
 948
 949 AC_CONFIG_FILES([
 950         Makefile
 951         doc/Makefile
 952         doc/man/Makefile
 953         doc/man/asciidoc-attrs.conf
 954         include/Makefile
 955         extras/Makefile
 956         extras/bindings/Makefile
 957         extras/bindings/swig/Makefile
 958         extras/bindings/swig/python/Makefile
 959         extras/core-handler/Makefile
 960         src/Makefile
 961         src/common/Makefile
 962         src/common/kernel-ctl/Makefile
 963         src/common/kernel-consumer/Makefile
 964         src/common/consumer/Makefile
 965         src/common/ust-consumer/Makefile
 966         src/common/hashtable/Makefile
 967         src/common/sessiond-comm/Makefile
 968         src/common/compat/Makefile
 969         src/common/relayd/Makefile
 970         src/common/testpoint/Makefile
 971         src/common/index/Makefile
 972         src/common/health/Makefile
 973         src/common/config/Makefile
 974         src/lib/Makefile
 975         src/lib/lttng-ctl/Makefile
 976         src/lib/lttng-ctl/filter/Makefile
 977         src/lib/lttng-ctl/lttng-ctl.pc
 978         src/bin/Makefile
 979         src/bin/lttng-consumerd/Makefile
 980         src/bin/lttng-sessiond/Makefile
 981         src/bin/lttng-relayd/Makefile
 982         src/bin/lttng/Makefile
 983         src/bin/lttng-crash/Makefile
 984         tests/Makefile
 985         tests/destructive/Makefile
 986         tests/regression/Makefile
 987         tests/regression/kernel/Makefile
 988         tests/regression/tools/Makefile
 989         tests/regression/tools/streaming/Makefile
 990         tests/regression/tools/filtering/Makefile
 991         tests/regression/tools/health/Makefile
 992         tests/regression/tools/tracefile-limits/Makefile
 993         tests/regression/tools/snapshots/Makefile
 994         tests/regression/tools/live/Makefile
 995         tests/regression/tools/exclusion/Makefile
 996         tests/regression/tools/save-load/Makefile
 997         tests/regression/tools/save-load/configuration/Makefile
 998         tests/regression/tools/mi/Makefile
 999         tests/regression/tools/wildcard/Makefile
1000         tests/regression/tools/crash/Makefile
1001         tests/regression/tools/regen-metadata/Makefile
1002         tests/regression/tools/regen-statedump/Makefile
1003         tests/regression/ust/Makefile
1004         tests/regression/ust/nprocesses/Makefile
1005         tests/regression/ust/high-throughput/Makefile
1006         tests/regression/ust/low-throughput/Makefile
1007         tests/regression/ust/before-after/Makefile
1008         tests/regression/ust/buffers-pid/Makefile
1009         tests/regression/ust/periodical-metadata-flush/Makefile
1010         tests/regression/ust/multi-session/Makefile
1011         tests/regression/ust/overlap/Makefile
1012         tests/regression/ust/overlap/demo/Makefile
1013         tests/regression/ust/linking/Makefile
1014         tests/regression/ust/daemon/Makefile
1015         tests/regression/ust/exit-fast/Makefile
1016         tests/regression/ust/fork/Makefile
1017         tests/regression/ust/libc-wrapper/Makefile
1018         tests/regression/ust/baddr-statedump/Makefile
1019         tests/regression/ust/ust-dl/Makefile
1020         tests/regression/ust/java-jul/Makefile
1021         tests/regression/ust/java-log4j/Makefile
1022         tests/regression/ust/python-logging/Makefile
1023         tests/regression/ust/getcpu-override/Makefile
1024         tests/regression/ust/clock-override/Makefile
1025         tests/regression/ust/type-declarations/Makefile
1026         tests/regression/ust/rotation-destroy-flush/Makefile
1027         tests/stress/Makefile
1028         tests/unit/Makefile
1029         tests/unit/ini_config/Makefile
1030         tests/perf/Makefile
1031         tests/utils/Makefile
1032         tests/utils/tap/Makefile
1033         tests/utils/testapp/Makefile
1034         tests/utils/testapp/gen-ust-events/Makefile
1035         tests/utils/testapp/gen-ust-nevents/Makefile
1036         tests/utils/testapp/gen-ust-tracef/Makefile
1037 ])
1038
1039 # Inject variable into python test script.
1040 AC_CONFIG_FILES([tests/regression/ust/python-logging/test_python_logging],[chmod +x tests/regression/ust/python-logging/test_python_logging])
1041 # Inject LTTNG_TOOLS_BUILD_WITH_LIBPFM variable in test script.
1042 AC_CONFIG_FILES([tests/perf/test_perf_raw],[chmod +x tests/perf/test_perf_raw])
1043
1044 AC_OUTPUT
1045
1046 #
1047 # Mini-report on what will be built.
1048 #
1049
1050 PPRINT_INIT
1051 PPRINT_SET_INDENT(1)
1052 PPRINT_SET_TS(38)
1053
1054 AS_ECHO
1055 AS_ECHO("${PPRINT_COLOR_BLDBLU}LTTng-tools $PACKAGE_VERSION \"$version_name\"$PPRINT_COLOR_RST")
1056 AS_ECHO
1057
1058 AS_IF([test -n "$report_fold"], [
1059         AS_ECHO("`AS_ECHO("$version_description") | $report_fold -s`")
1060 ], [
1061         AS_ECHO("$version_description")
1062 ])
1063
1064 AS_ECHO
1065 PPRINT_SUBTITLE([Features])
1066
1067 # Target architecture we're building for.
1068 target_arch=$host_cpu
1069 [
1070 for f in $CFLAGS; do
1071         if test $f = "-m32"; then
1072                         target_arch="32-bit"
1073         elif test $f = "-m64"; then
1074                         target_arch="64-bit"
1075         fi
1076 done
1077 ]
1078 PPRINT_PROP_STRING([Target architecture], $target_arch)
1079
1080 # kmod enabled/disabled
1081 test "x$kmod_found" = "xyes" && value=1 || value=0
1082 PPRINT_PROP_BOOL([libkmod support], $value)
1083
1084 # LTTng-UST enabled/disabled
1085 test "x$lttng_ust_support" = "xyes" && value=1 || value=0
1086 PPRINT_PROP_BOOL([LTTng-UST support], $value)
1087
1088 AS_ECHO
1089 PPRINT_SUBTITLE([Binaries])
1090
1091 # List binaries to be built
1092 test x$enable_bin_lttng != xno && value=1 || value=0
1093 PPRINT_PROP_BOOL([lttng], $value)
1094
1095 test x$enable_bin_lttng_consumerd != xno && value=1 || value=0
1096 PPRINT_PROP_BOOL([lttng-consumerd], $value)
1097
1098 test x$enable_bin_lttng_crash != xno && value=1 || value=0
1099 PPRINT_PROP_BOOL([lttng-crash], $value)
1100
1101 test x$enable_bin_lttng_relayd != xno && value=1 || value=0
1102 PPRINT_PROP_BOOL([lttng-relayd], $value)
1103
1104 test x$enable_bin_lttng_sessiond != xno && value=1 || value=0
1105 PPRINT_PROP_BOOL([lttng-sessiond], $value)
1106
1107 # Extras
1108 test x$enable_extras != xno && value=1 || value=0
1109 AS_ECHO
1110 PPRINT_SET_INDENT(0)
1111 PPRINT_PROP_BOOL([Extras], $value, $PPRINT_COLOR_SUBTITLE)
1112 PPRINT_SET_INDENT(1)
1113
1114 AS_ECHO
1115 PPRINT_SUBTITLE([Tests])
1116
1117 # Print clear message that tests won't be built
1118 AS_IF([test "x$build_tests" = "xno"],[
1119         PPRINT_WARN([Tests won't be built since some binaries were disabled])
1120 ])
1121
1122 # LTTng UST Java agent JUL tests enabled/disabled
1123 test "x$test_java_agent_jul" = "xyes" && value=1 || value=0
1124 PPRINT_PROP_BOOL([LTTng-UST Java agent JUL tests], $value)
1125
1126 # LTTng UST Java agent Log4j tests enabled/disabled
1127 test "x$test_java_agent_log4j" = "xyes" && value=1 || value=0
1128 PPRINT_PROP_BOOL([LTTng-UST Java agent Log4j tests], $value)
1129
1130 test ! -z "$PYTHON2_AGENT" && value=1 || value=0
1131 PPRINT_PROP_BOOL([LTTng-UST Python2 agent tests], $value)
1132
1133 test ! -z "$PYTHON3_AGENT" && value=1 || value=0
1134 PPRINT_PROP_BOOL([LTTng-UST Python3 agent tests], $value)
1135
1136 #Python binding enabled/disabled
1137 test "x$enable_python_binding" = xyes && value=1 || value=0
1138 AS_ECHO
1139 PPRINT_SET_INDENT(0)
1140 PPRINT_PROP_BOOL([Python binding], $value, $PPRINT_COLOR_SUBTITLE)
1141
1142 # man pages build enabled/disabled
1143 m4_pushdef([build_man_pages_msg], [Build and install man pages])
1144
1145 AS_IF([test "x$man_pages_opt" != "xno"], [
1146         AS_IF([test "x$in_git_repo" = "xyes"], [
1147                 PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
1148         ], [
1149                 AS_IF([test "x$have_asciidoc_xmlto" = "xyes"], [
1150                         PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
1151                 ], [
1152                         PPRINT_PROP_STRING([build_man_pages_msg],
1153                                 [${PPRINT_COLOR_BLDGRN}yes (already built)],
1154                                 $PPRINT_COLOR_SUBTITLE)
1155                 ])
1156         ])
1157 ], [
1158         PPRINT_PROP_BOOL([build_man_pages_msg], 0, $PPRINT_COLOR_SUBTITLE)
1159 ])
1160
1161 m4_popdef([build_man_pages_msg])
1162
1163 PPRINT_SET_INDENT(1)
1164
1165 report_bindir="`eval eval echo $bindir`"
1166 report_libdir="`eval eval echo $libdir`"
1167
1168 # Print the bindir and libdir this `make install' will install into.
1169 AS_ECHO
1170 PPRINT_SUBTITLE([Install directories])
1171 PPRINT_PROP_STRING([Binaries], [$report_bindir])
1172 PPRINT_PROP_STRING([Libraries], [$report_libdir])
1173
1174 AS_ECHO
1175 PPRINT_SUBTITLE([Search directories])
1176
1177 # If we build the sessiond, print the paths it will use
1178 AS_IF([test "$SESSIOND_BIN" = ""],[
1179         path="$report_bindir/lttng-sessiond"
1180 ],[
1181         path="$SESSIOND_BIN"
1182 ])
1183 PPRINT_PROP_STRING([lttng-sessiond executable], [$path])
1184
1185 AS_IF([test "$CONSUMERD32_BIN" = ""],[
1186         path="`eval eval echo $lttnglibexecdir`/lttng-consumerd"
1187 ],[
1188         path="$CONSUMERD32_BIN"
1189 ])
1190 PPRINT_PROP_STRING([32-bit lttng-consumerd executable], [$path])
1191
1192 AS_IF([test "$CONSUMERD32_LIBDIR" = ""],[
1193         path="`eval eval echo $libdir`"
1194 ],[
1195         path="$CONSUMERD32_LIBDIR"
1196 ])
1197 PPRINT_PROP_STRING([32-bit consumer libraries], [$path])
1198
1199 AS_IF([test "$CONSUMERD64_BIN" = ""],[
1200         path="`eval eval echo $lttnglibexecdir`/lttng-consumerd"
1201 ],[
1202         path="$CONSUMERD64_BIN"
1203 ])
1204 PPRINT_PROP_STRING([64-bit lttng-consumerd executable], [$path])
1205
1206 AS_IF([test "$CONSUMERD64_LIBDIR" = ""],[
1207         path="`eval eval echo $libdir`"
1208 ],[
1209         path="$CONSUMERD64_LIBDIR"
1210 ])
1211 PPRINT_PROP_STRING([64-bit consumer libraries], [$path])
1212 PPRINT_SET_INDENT(0)
1213
1214 AS_IF([test "x$warn_prebuilt_man_pages" = "xyes" ], [
1215         AS_ECHO
1216         PPRINT_WARN([You need asciidoc and xmlto to build the LTTng-tools man pages.
1217
1218 Note that the man pages are already built in this distribution tarball,
1219 therefore asciidoc and xmlto are only needed if you intend to modify
1220 their sources.
1221
1222 Also note that the installed man pages will contain the project's
1223 default command-line option and environment variable values.
1224
1225 Use --disable-man-pages to completely disable building and installing
1226 the man pages.])
1227 ])