configure.ac

   1 dnl SPDX-License-Identifier: GPL-2.0-only
   2 AC_PREREQ([2.64])
   3 AC_INIT([lttng-tools],[2.14.0-pre],[jeremie.galarneau@efficios.com],[],[https://lttng.org])
   4
   5 AC_CONFIG_HEADERS([include/config.h])
   6 AC_CONFIG_AUX_DIR([config])
   7 AC_CONFIG_MACRO_DIR([m4])
   8
   9 AC_CANONICAL_TARGET
  10 AC_CANONICAL_HOST
  11
  12 AM_INIT_AUTOMAKE([1.12 foreign dist-bzip2 no-dist-gzip tar-pax nostdinc])
  13 AM_MAINTAINER_MODE([enable])
  14
  15 # Enable silent rules if available (Introduced in AM 1.11)
  16 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  17
  18 # Checks for C compiler
  19 AC_USE_SYSTEM_EXTENSIONS
  20 AC_SYS_LARGEFILE
  21 AC_PROG_CC
  22 # AC_PROG_CC_STDC was merged in AC_PROG_CC in autoconf 2.70
  23 m4_version_prereq([2.70], [], [AC_PROG_CC_STDC])
  24 AC_PROG_CXX
  25 RW_PROG_CXX_WORKS
  26 AM_CONDITIONAL([CXX_WORKS], [test "x$rw_cv_prog_cxx_works" = "xyes"])
  27
  28 # Detect warning flags supported by the compiler, append them to WARN_CFLAGS.
  29 #
  30 # Pass -Werror as an extra flag during the test: this is needed to make the
  31 # -Wunknown-warning-option diagnostic fatal with clang.
  32 AX_APPEND_COMPILE_FLAGS([ dnl
  33                 -Wall dnl
  34                 dnl We currently get this warning when building with Clang:
  35                 dnl
  36                 dnl /usr/include/setjmp.h:54:12: error: declaration of built-in function '__sigsetjmp' requires the declaration of the 'jmp_buf' type, commonly provided in the header <setjmp.h>. [-Werror,-Wincomplete-setjmp-declaration]
  37                 dnl extern int __sigsetjmp (struct __jmp_buf_tag __env[1], int __savemask) __THROWNL;
  38                 dnl            ^
  39                 -Wno-incomplete-setjmp-declaration dnl
  40                 -Wdiscarded-qualifiers dnl
  41                 -Wmissing-declarations dnl
  42                 -Wmissing-prototypes dnl
  43                 -Wmissing-parameter-type dnl
  44                 -Wold-style-definition dnl
  45                 -Wstrict-prototypes dnl
  46                 -Wshadow dnl
  47         ],
  48         [WARN_CFLAGS],
  49         [-Werror])
  50
  51 # When given, add -Werror to WARN_CFLAGS.
  52 AC_ARG_ENABLE([Werror],
  53         [AS_HELP_STRING([--enable-Werror], [Treat compiler warnings as errors.])]
  54 )
  55 AS_IF([test "x$enable_Werror" = "xyes"],
  56         [WARN_CFLAGS="${WARN_CFLAGS} -Werror"]
  57 )
  58
  59 # Checks for programs.
  60 AC_PROG_GREP
  61 AC_PROG_MAKE_SET
  62 AC_PROG_SED
  63 AC_PATH_PROG([report_fold], [fold])
  64 LT_INIT
  65
  66 # Check for objcopy, required by the base address statedump and dynamic linker tests
  67 AC_CHECK_TOOL([OBJCOPY], [objcopy], [no])
  68 AS_IF([test "x$OBJCOPY" = "xno"],
  69         [AC_MSG_WARN([Cannot find objcopy. The base address statedump and dynamic linker tests will be disabled. Install the binutils package to remediate this.])]
  70 )
  71 AM_CONDITIONAL([HAVE_OBJCOPY], [test "x$OBJCOPY" != xno])
  72
  73 # check for pgrep
  74 AC_PATH_PROG([PGREP], [pgrep], [no])
  75 AM_CONDITIONAL([HAVE_PGREP], [test "x$PGREP" != "xno"])
  76
  77 # set $IN_GIT_REPO if we're in the Git repository; the `bootstrap` file
  78 # is not distributed in tarballs
  79 AS_IF([test -f "$srcdir/bootstrap"], [in_git_repo=yes], [in_git_repo=no])
  80 AM_CONDITIONAL([IN_GIT_REPO], [test "x$in_git_repo" = "xyes"])
  81
  82 # check for bison
  83 AC_PROG_YACC
  84 BISON=$YACC
  85 AX_PROG_BISON_VERSION([2.4], [have_bison=yes])
  86
  87 AS_IF([test "x$have_bison" != "xyes"], [
  88   AS_IF([test "x$in_git_repo" = "xyes"], [
  89     AC_MSG_FAILURE([
  90 Bison >= 2.4 is required when building from the Git repository. You can
  91 set the YACC variable to override automatic detection.
  92     ])
  93   ], [
  94     AC_MSG_WARN([
  95 Missing Bison >= 2.4. Note that the parser files are already built in
  96 this distribution tarball, so Bison is only needed if you intend to
  97 modify their sources. You can set the YACC variable to override automatic
  98 detection.
  99     ])
 100   ])
 101 ])
 102 AM_CONDITIONAL([HAVE_BISON], [test "x$have_bison" = "xyes"])
 103
 104 # check for flex
 105 # Prior to autoconf 2.70, AC_PROG_FLEX did not take an argument. This is not a
 106 # problem since the argument is silently ignored by older versions.
 107 AC_PROG_LEX([noyywrap])
 108 FLEX=$LEX
 109 AX_PROG_FLEX_VERSION([2.5.35], [have_flex=yes])
 110
 111 AS_IF([test "x$have_flex" != "xyes"], [
 112   AS_IF([test "x$in_git_repo" = "xyes"], [
 113     AC_MSG_FAILURE([
 114 Flex >= 2.5.35 is required when building from the Git repository. You can
 115 set the LEX variable to override automatic detection.
 116     ])
 117   ], [
 118     AC_MSG_WARN([
 119 Missing Flex >= 2.5.35. Note that the lexer files are already built in
 120 this distribution tarball, so Flex is only needed if you intend to
 121 modify their sources. You can set the LEX variable to override automatic
 122 detection.
 123     ])
 124   ])
 125 ])
 126 AM_CONDITIONAL([HAVE_FLEX], [test "x$have_flex" = "xyes"])
 127
 128
 129 # Checks for typedefs, structures, and compiler characteristics.
 130 AC_C_INLINE
 131 AC_TYPE_INT32_T
 132 AC_TYPE_INT64_T
 133 AC_TYPE_MODE_T
 134 AC_TYPE_OFF_T
 135 AC_TYPE_PID_T
 136 AC_TYPE_SIZE_T
 137 AC_TYPE_SSIZE_T
 138 AC_TYPE_UID_T
 139 AC_TYPE_UINT16_T
 140 AC_TYPE_UINT32_T
 141 AC_TYPE_UINT64_T
 142 AC_TYPE_UINT8_T
 143
 144 AX_C___ATTRIBUTE__
 145 AS_IF([test "x$ax_cv___attribute__" = "xyes"],
 146         [:],
 147         [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
 148
 149 AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])
 150
 151 # Check if linker has the -no-pie option.
 152 AX_CHECK_LINK_FLAG([-no-pie], [linker_have_no_pie_option=yes])
 153 AM_CONDITIONAL([LINKER_HAVE_NO_PIE_OPTION], [test "x$linker_have_no_pie_option" = "xyes"])
 154
 155 AX_LIB_SOCKET_NSL
 156
 157 LT_NO_UNDEFINED=""
 158 AS_CASE([$host_os],
 159   [cygwin*],
 160     [
 161       LT_NO_UNDEFINED="-no-undefined"
 162     ],
 163   [cygwin*|darwin*|mingw*|solaris*],
 164     [
 165       # On platforms where we only support the relayd, disable the other binaries by default
 166       AS_IF([test "x$enable_bin_lttng" = "x" ], [enable_bin_lttng=no])
 167       AS_IF([test "x$enable_bin_lttng_consumerd" = "x" ], [enable_bin_lttng_consumerd=no])
 168       AS_IF([test "x$enable_bin_lttng_crash" = "x" ], [enable_bin_lttng_crash=no])
 169       AS_IF([test "x$enable_bin_lttng_sessiond" = "x" ], [enable_bin_lttng_sessiond=no])
 170       AS_IF([test "x$enable_extras" = "x" ], [enable_extras=no])
 171       AS_IF([test "x$with_lttng_ust" = "x" ], [with_lttng_ust=no])
 172     ]
 173 )
 174
 175 AC_SUBST(LT_NO_UNDEFINED)
 176
 177 # Compute minor/major/patchlevel version numbers
 178 major_version=$(echo AC_PACKAGE_VERSION | $SED 's/^\([[0-9]]\)*\.[[0-9]]*\.[[0-9]]*.*$/\1/')
 179 minor_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.\([[0-9]]*\)\.[[0-9]]*.*$/\1/')
 180 patchlevel_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\).*$/\1/')
 181
 182 AC_SUBST([MAJOR_VERSION], [$major_version])
 183 AC_SUBST([MINOR_VERSION], [$minor_version])
 184 AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version])
 185 AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [LTTng-Tools major version number])
 186 AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [LTTng-Tools minor version number])
 187 AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [LTTng-Tools patchlevel version number])
 188
 189 version_name="O-Beer"
 190 version_description="An alcoholic drink made from yeast-fermented malt flavored with hops."
 191 version_description_c=$(echo $version_description | $SED 's/"/\\"/g')
 192
 193 AC_DEFINE_UNQUOTED([VERSION_NAME], ["$version_name"], "")
 194 AC_DEFINE_UNQUOTED([VERSION_DESCRIPTION], ["$version_description_c"], "")
 195
 196 # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
 197 AC_ARG_ENABLE(libtool-linkdep-fixup,
 198         AS_HELP_STRING([--disable-libtool-linkdep-fixup],
 199                         [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)]),
 200         libtool_fixup=$enableval,
 201         libtool_fixup=yes)
 202
 203 AS_IF([test "x$libtool_fixup" = "xyes"],
 204             [
 205             libtool_m4="$srcdir/m4/libtool.m4"
 206             libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
 207             AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
 208             libtool_flag_pattern_count=$($GREP -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
 209             AS_IF([test $libtool_flag_pattern_count -ne 0],
 210             [
 211                   AC_MSG_RESULT([$libtool_flag_pattern_count])
 212                   AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
 213                   $SED -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
 214                   ],
 215                   [
 216                   AC_MSG_RESULT([none])
 217                   ])
 218             ])
 219
 220 AM_CONDITIONAL([NO_SHARED], [test x$enable_shared = xno])
 221
 222 AC_CHECK_HEADERS([ \
 223         sys/types.h unistd.h fcntl.h string.h pthread.h limits.h \
 224         signal.h stdlib.h sys/un.h sys/socket.h stdlib.h stdio.h \
 225         getopt.h sys/ipc.h sys/shm.h popt.h grp.h arpa/inet.h \
 226         netdb.h netinet/in.h paths.h stddef.h sys/file.h sys/ioctl.h \
 227         sys/mount.h sys/param.h sys/time.h elf.h
 228 ])
 229
 230 AM_CONDITIONAL([HAVE_ELF_H], [test x$ac_cv_header_elf_h = xyes])
 231
 232 # Basic functions check
 233 AC_CHECK_FUNCS([ \
 234         atexit bzero clock_gettime dup2 fdatasync fls ftruncate \
 235         gethostbyname gethostname getpagesize localtime_r memchr memrchr memset \
 236         mkdir munmap putenv realpath rmdir socket strchr strcspn strdup \
 237         strncasecmp strndup strnlen strpbrk strrchr strstr strtol strtoul \
 238         strtoull dirfd gethostbyname2 getipnodebyname epoll_create1 \
 239         sched_getcpu sysconf sync_file_range
 240 ])
 241
 242 # Check for pthread_setname_np and pthread_getname_np
 243 LTTNG_PTHREAD_SETNAME_NP
 244 LTTNG_PTHREAD_GETNAME_NP
 245
 246 # Check if clock_gettime, timer_create, timer_settime, and timer_delete are available in lib rt, and if so,
 247 # add -lrt to LIBS
 248 AC_CHECK_LIB([rt], [clock_gettime, timer_create, timer_settime, timer_delete])
 249
 250 # Checks for dl.
 251 AC_CHECK_LIB([dl], [dlopen], [
 252         have_libdl=yes
 253         libdl_name=dl
 254         DL_LIBS="-ldl"
 255 ], [
 256         # libdl not found, check for dlopen in libc.
 257         AC_CHECK_LIB([c], [dlopen], [
 258                 have_libc_dl=yes
 259                 libdl_name=c
 260                 DL_LIBS="-lc"
 261         ], [
 262                 AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
 263         ])
 264 ])
 265 AC_SUBST(DL_LIBS)
 266
 267 # Check if libdl has dlmopen support.
 268 AH_TEMPLATE([HAVE_DLMOPEN], ["Define to 1 if dlmopen is available."])
 269 AC_CHECK_LIB([$libdl_name], [dlmopen], [
 270         AC_DEFINE([HAVE_DLMOPEN], [1])
 271         HAVE_DLMOPEN=1
 272 ], [
 273         HAVE_DLMOPEN=0
 274 ])
 275 AC_SUBST(HAVE_DLMOPEN)
 276
 277 # Babeltrace viewer check
 278 AC_ARG_WITH([babeltrace-bin],
 279         AS_HELP_STRING([--with-babeltrace-bin],
 280         [Location of the babeltrace viewer executable (including the filename)]),
 281         [BABELTRACE_BIN="$withval"],
 282         [BABELTRACE_BIN=''])
 283 AC_SUBST([BABELTRACE_BIN])
 284
 285 AC_ARG_WITH([babeltrace2-bin],
 286         AS_HELP_STRING([--with-babeltrace2-bin],
 287         [Location of the babeltrace2 viewer executable (including the filename)]),
 288         [BABELTRACE2_BIN="$withval"],
 289         [BABELTRACE2_BIN=''])
 290 AC_SUBST([BABELTRACE2_BIN])
 291
 292 AC_ARG_WITH([consumerd32-bin],
 293         AS_HELP_STRING([--with-consumerd32-bin],
 294         [Location of the 32-bit consumerd executable (including the filename)]),
 295         [CONSUMERD32_BIN="$withval"],
 296         [CONSUMERD32_BIN=''])
 297 AC_SUBST([CONSUMERD32_BIN])
 298
 299 AC_ARG_WITH([consumerd64-bin],
 300         AS_HELP_STRING([--with-consumerd64-bin],
 301         [Location of the 64-bit consumerd executable (including the filename)]),
 302         [CONSUMERD64_BIN="$withval"],
 303         [CONSUMERD64_BIN=''])
 304 AC_SUBST([CONSUMERD64_BIN])
 305
 306 AC_ARG_WITH([consumerd32-libdir],
 307         AS_HELP_STRING([--with-consumerd32-libdir],
 308         [Directory containing the 32-bit consumerd libraries]),
 309         [CONSUMERD32_LIBDIR="$withval"],
 310         [CONSUMERD32_LIBDIR=''])
 311 AC_SUBST([CONSUMERD32_LIBDIR])
 312
 313 AC_ARG_WITH([consumerd64-libdir],
 314         AS_HELP_STRING([--with-consumerd64-libdir],
 315         [Directory containing the 64-bit consumerd libraries]),
 316         [CONSUMERD64_LIBDIR="$withval"],
 317         [CONSUMERD64_LIBDIR=''])
 318 AC_SUBST([CONSUMERD64_LIBDIR])
 319
 320 AC_ARG_WITH([sessiond-bin],
 321         AS_HELP_STRING([--with-sessiond-bin],
 322         [Location of the sessiond executable (including the filename)]),
 323         [SESSIOND_BIN="$withval"],
 324         [SESSIOND_BIN=''])
 325 AC_SUBST([SESSIOND_BIN])
 326
 327 AC_ARG_WITH([lttng-system-rundir],
 328         AS_HELP_STRING([--with-lttng-system-rundir],
 329         [Location of the system directory where the system-wide lttng-sessiond runtime files are kept. The default is "/var/run/lttng".]),
 330         [LTTNG_SYSTEM_RUNDIR="$withval"],
 331         [LTTNG_SYSTEM_RUNDIR="/var/run/lttng"])
 332 AC_SUBST([LTTNG_SYSTEM_RUNDIR])
 333
 334 AC_ARG_ENABLE([test-java-agent-jul],
 335         [AS_HELP_STRING([--enable-test-java-agent-jul],[enable the LTTng UST Java agent JUL tests [default=no]])],
 336         [test_java_agent_jul=$enableval],
 337         [test_java_agent_jul=no]
 338 )
 339
 340 AC_ARG_ENABLE([test-java-agent-log4j],
 341         [AS_HELP_STRING([--enable-test-java-agent-log4j],[enable the LTTng UST Java agent Log4j tests [default=no]])],
 342         [test_java_agent_log4j=$enableval],
 343         [test_java_agent_log4j=no]
 344 )
 345
 346 AC_ARG_ENABLE([test-java-agent-all],
 347         [AS_HELP_STRING([--enable-test-java-agent-all],[enable all the LTTng UST Java agent tests [default=no]])],
 348         [test_java_agent_jul=$enableval
 349          test_java_agent_log4j=$enableval],
 350         [:]
 351 )
 352
 353 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_BIN], "$CONSUMERD32_BIN", [Location of the 32-bit consumerd executable.])
 354 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_BIN], "$CONSUMERD64_BIN", [Location of the 64-bit consumerd executable])
 355 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_LIBDIR], "$CONSUMERD32_LIBDIR", [Search for consumerd 32-bit libraries in this location.])
 356 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_LIBDIR], "$CONSUMERD64_LIBDIR", [Search for consumerd 64-bit libraries in this location.])
 357 AC_DEFINE_UNQUOTED([CONFIG_BABELTRACE_BIN], "$BABELTRACE_BIN", [Location of the babeltrace viewer executable.])
 358 AC_DEFINE_UNQUOTED([CONFIG_BABELTRACE2_BIN], "$BABELTRACE2_BIN", [Location of the babeltrace2 viewer executable.])
 359 AC_DEFINE_UNQUOTED([CONFIG_SESSIOND_BIN], "$SESSIOND_BIN", [Location of the sessiond executable.])
 360 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_RUNDIR], ["$LTTNG_SYSTEM_RUNDIR"], [LTTng system runtime directory])
 361
 362 AC_DEFUN([_AC_DEFINE_AND_SUBST], [
 363         AC_DEFINE_UNQUOTED([CONFIG_$1], [$2], [$1])
 364         $1="$2"
 365         AC_SUBST([$1])
 366 ])
 367
 368 AC_DEFUN([_AC_DEFINE_QUOTED_AND_SUBST], [
 369         AC_DEFINE_UNQUOTED([CONFIG_$1], ["$2"], [$1])
 370         $1="$2"
 371         AC_SUBST([$1])
 372 ])
 373
 374 # Default values
 375 m4_define([_DEFAULT_CHANNEL_SUBBUF_SIZE], [16384])
 376 m4_define([_DEFAULT_CHANNEL_SUBBUF_NUM], [4])
 377 m4_define([_DEFAULT_CHANNEL_SWITCH_TIMER], [0])
 378 m4_define([_DEFAULT_CHANNEL_LIVE_TIMER], [0])
 379 m4_define([_DEFAULT_CHANNEL_READ_TIMER], [200000])
 380 m4_define([_DEFAULT_CHANNEL_MONITOR_TIMER], [1000000])
 381 m4_define([_DEFAULT_CHANNEL_BLOCKING_TIMEOUT], [0])
 382 _AC_DEFINE_AND_SUBST([DEFAULT_AGENT_TCP_PORT_RANGE_BEGIN], [5345])
 383 _AC_DEFINE_AND_SUBST([DEFAULT_AGENT_TCP_PORT_RANGE_END], [5354])
 384 _AC_DEFINE_AND_SUBST([DEFAULT_APP_SOCKET_RW_TIMEOUT], [5])
 385 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE])
 386 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_COUNT], [0])
 387 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_SIZE], [0])
 388 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 389 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_READ_TIMER], [_DEFAULT_CHANNEL_READ_TIMER])
 390 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 391 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_SIZE], [1048576])
 392 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 393 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
 394 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_BLOCKING_TIMEOUT], [_DEFAULT_CHANNEL_BLOCKING_TIMEOUT])
 395 _AC_DEFINE_AND_SUBST([DEFAULT_LTTNG_LIVE_TIMER], [1000000])
 396 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_CACHE_SIZE], [4096])
 397 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_READ_TIMER], [0])
 398 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_NUM], [2])
 399 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_SIZE], [4096])
 400 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 401 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_CONTROL_PORT], [5342])
 402 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_DATA_PORT], [5343])
 403 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_VIEWER_PORT], [5344])
 404 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 405 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_READ_TIMER], [0])
 406 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_BLOCKING_TIMEOUT], [0])
 407 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 408 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE])
 409 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 410 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
 411 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 412 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_READ_TIMER], [0])
 413 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_BLOCKING_TIMEOUT], [0])
 414 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 415 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_SIZE], [524288])
 416 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 417 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
 418 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_AGENT_BIND_ADDRESS], [localhost])
 419 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_CONTROL_BIND_ADDRESS], [0.0.0.0])
 420 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_DATA_BIND_ADDRESS], [0.0.0.0])
 421 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_VIEWER_BIND_ADDRESS], [localhost])
 422 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_RELAYD_CTRL_MAX_PAYLOAD_SIZE], [134217728])
 423 _AC_DEFINE_AND_SUBST([DEFAULT_ROTATE_PENDING_TIMER], [500000])
 424 _AC_DEFINE_AND_SUBST([DEFAULT_EVENT_NOTIFIER_ERROR_COUNT_MAP_SIZE], [4096])
 425
 426 # Command short descriptions
 427 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ADD_CONTEXT], [Add context fields to be recorded])
 428 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ADD_TRIGGER], [Add a trigger])
 429 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_CLEAR], [Clear a recording session])
 430 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_CREATE], [Create a recording session])
 431 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DESTROY], [Destroy recording sessions])
 432 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_CHANNEL], [Disable channels])
 433 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_EVENT], [Disable recording event rules])
 434 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_ROTATION], [Unset a recording session rotation schedule])
 435 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_CHANNEL], [Create or enable a channel])
 436 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_EVENT], [Create or enable recording event rules])
 437 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_ROTATION], [Set a recording session rotation schedule])
 438 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_HELP], [Show the help of a command])
 439 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LIST], [List recording sessions and instrumentation points])
 440 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LIST_TRIGGERS], [List triggers])
 441 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LOAD], [Load recording session configurations])
 442 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_REGENERATE], [Regenerate specific recording session data])
 443 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_REMOVE_TRIGGER], [Remove a trigger])
 444 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ROTATE], [Archive the current trace chunk of a recording session])
 445 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SAVE], [Save recording session configurations])
 446 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SET_SESSION], [Set the current recording session])
 447 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SNAPSHOT], [Take a recording session snapshot])
 448 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_START], [Start a recording session])
 449 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STATUS], [Show the status of the current recording session])
 450 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STOP], [Stop a recording session])
 451 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_TRACK], [Allow specific processes to record events])
 452 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_UNTRACK], [Disallow specific processes to record events])
 453 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VERSION], [Show LTTng-tools version information])
 454 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VIEW], [Launch a trace reader])
 455
 456 if test "x$prefix" = "xNONE"; then
 457         prefix=$ac_default_prefix
 458 fi
 459 CONFDIR=`eval echo $sysconfdir`
 460 AC_SUBST(CONFDIR)
 461 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_CONFIGDIR],"$CONFDIR", [LTTng system configuration directory.])
 462
 463 AX_DEFINE_DIR([CONFIG_LTTNG_SYSTEM_DATADIR], [datadir], [LTTng system data directory.])
 464
 465 # Check libpopt
 466 PKG_CHECK_MODULES([POPT], [popt],
 467   [
 468     dnl PKG_CHECK_MODULES defines POPT_LIBS
 469   ],
 470   [
 471     AC_MSG_WARN([pkg-config was unable to find a valid .pc for libpopt. Set PKG_CONFIG_PATH to specify the pkgconfig configuration file location])
 472     AC_MSG_WARN([Finding libpopt without pkg-config.])
 473     AC_CHECK_LIB([popt],
 474       [poptGetContext],
 475       [POPT_LIBS="-lpopt"],
 476       [
 477         AC_MSG_FAILURE([Cannot find libpopt. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location])
 478       ]
 479     )
 480   ]
 481 )
 482 AC_SUBST(POPT_LIBS)
 483
 484 PKG_CHECK_MODULES([libxml2], [libxml-2.0 >= 2.7.6])
 485
 486 AC_CHECK_FUNC([clock_gettime], [AC_DEFINE_UNQUOTED([LTTNG_HAVE_CLOCK_GETTIME], 1, [Has clock_gettime() support.])])
 487
 488 # URCU library version needed or newer
 489 PKG_CHECK_MODULES([URCU], [liburcu >= 0.11])
 490 PKG_CHECK_MODULES([URCU_BP], [liburcu-bp >= 0.11])
 491 PKG_CHECK_MODULES([URCU_CDS], [liburcu-cds >= 0.11])
 492 AM_CPPFLAGS="$AM_CPPFLAGS $URCU_CFLAGS"
 493
 494 # Check for libkmod, it will be auto-neabled if found but won't fail if it's not,
 495 # it can be explicitly disabled with --without-kmod
 496 AH_TEMPLATE([HAVE_KMOD], [Define if you have kmod support])
 497 AC_ARG_WITH([kmod],
 498   [AS_HELP_STRING([--with-kmod], [build with lkmod support @<:@default=check@:>@])],
 499   [],
 500   [with_kmod=check]
 501 )
 502
 503 AS_IF([test "x$with_kmod" != "xno"],
 504   [
 505     AC_CHECK_LIB([kmod], [kmod_module_probe_insert_module],
 506       [
 507         AC_DEFINE([HAVE_KMOD], [1])
 508         KMOD_LIBS="-lkmod"
 509       ],
 510       [
 511         if test "x$with_kmod" != xcheck; then
 512           AC_MSG_FAILURE([Cannot find libkmod. Use [LDFLAGS]=-Ldir and [CPPFLAGS]=-Idir to specify its location.])
 513         else
 514           with_kmod=no
 515         fi
 516       ]
 517     )
 518   ]
 519 )
 520 AC_SUBST(KMOD_LIBS)
 521
 522 # Check for liblttng-ust-ctl, fail if it's not found,
 523 # it can be explicitly disabled with --without-lttng-ust
 524 AH_TEMPLATE([HAVE_LIBLTTNG_UST_CTL], [Define if you have LTTng-UST control support])
 525 AC_ARG_WITH([lttng-ust],
 526   [AS_HELP_STRING([--without-lttng-ust], [build without LTTng-UST (Userspace Tracing) support])],
 527   [],
 528   [with_lttng_ust=yes]
 529 )
 530
 531 AS_IF([test "x$with_lttng_ust" = "xyes"], [
 532   AC_DEFINE([HAVE_LIBLTTNG_UST_CTL], [1])
 533
 534   # Check for liblttng-ust
 535   PKG_CHECK_MODULES([UST], [lttng-ust >= $major_version.$minor_version])
 536
 537   # Check for liblttng-ust-ctl
 538   PKG_CHECK_MODULES([UST_CTL], [lttng-ust-ctl >= $major_version.$minor_version])
 539
 540   AM_CPPFLAGS="$AM_CPPFLAGS $UST_CFLAGS"
 541 ])
 542
 543 AM_CONDITIONAL([HAVE_LIBLTTNG_UST_CTL], [test "x$with_lttng_ust" = "xyes"])
 544
 545
 546 # Check for fmemopen
 547 AC_CHECK_LIB([c], [fmemopen],
 548 [
 549         AC_DEFINE_UNQUOTED([LTTNG_HAVE_FMEMOPEN], 1, [Has fmemopen support.])
 550 ]
 551 )
 552
 553 # check for libpfm
 554 AC_CHECK_LIB([pfm], [pfm_initialize],
 555              [
 556               have_libpfm=yes
 557               ])
 558 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBPFM], [test "x$have_libpfm" = "xyes"])
 559
 560 # For Python
 561 # SWIG version needed or newer:
 562 swig_version=2.0.0
 563
 564 AC_ARG_ENABLE([python-bindings],
 565               [AS_HELP_STRING([--enable-python-bindings],
 566                               [compile Python bindings])],
 567               [enable_python_binding=$enableval], [enable_python_binding=no])
 568
 569 AM_CONDITIONAL([PYTHON_BINDING], [test "x$enable_python_binding" = xyes])
 570
 571 if test "x$enable_python_binding" = xyes; then
 572   AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ])
 573   AS_IF([test x$enable_shared = xno], [ AC_MSG_ERROR([Python bindings require shared libraries.]) ])
 574   AM_PATH_PYTHON([3.0])
 575
 576   AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config])
 577   AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
 578   AS_IF([test -z "$PYTHON_INCLUDE"], [
 579     AS_IF([test -z "$PYTHON_CONFIG"], [
 580       AC_PATH_PROGS([PYTHON_CONFIG],
 581                     [python$PYTHON_VERSION-config python-config],
 582                     [no],
 583                     [`dirname $PYTHON`])
 584       AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
 585     ])
 586     AC_MSG_CHECKING([python include flags])
 587     PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
 588     AC_MSG_RESULT([$PYTHON_INCLUDE])
 589   ])
 590
 591 else
 592     AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl
 593 [if you want Python bindings.])
 594
 595 fi
 596
 597 # Epoll check. If not present, the build will fallback on poll() API
 598 AX_HAVE_EPOLL(
 599         [AX_CONFIG_FEATURE_ENABLE(epoll)],
 600         [AX_CONFIG_FEATURE_DISABLE(epoll)]
 601 )
 602 AX_CONFIG_FEATURE(
 603         [epoll], [This platform supports epoll(7)],
 604         [HAVE_EPOLL], [This platform supports epoll(7).]
 605 )
 606
 607 AS_IF([test "x$ac_cv_func_dirfd" = "xyes"],
 608         [AX_CONFIG_FEATURE_ENABLE(dirfd)],
 609         [AX_CONFIG_FEATURE_DISABLE(dirfd)]
 610 )
 611 AX_CONFIG_FEATURE(
 612         [dirfd], [Use directory file descriptors],
 613         [HAVE_DIRFD], [This platform supports directory file descriptors.]
 614 )
 615
 616 AM_CONDITIONAL([TEST_JAVA_JUL_AGENT], [test "x$test_java_agent_jul" = "xyes"])
 617 AM_CONDITIONAL([TEST_JAVA_LOG4J_AGENT], [test "x$test_java_agent_log4j" = "xyes"])
 618
 619 if test "x$test_java_agent_jul" = "xyes" || test "x$test_java_agent_log4j" = "xyes"; then
 620         AX_JAVA_OPTIONS
 621         AX_PROG_JAVAC
 622         AX_PROG_JAVA
 623         AX_PROG_JAR
 624
 625         AX_CHECK_CLASSPATH
 626
 627         # Check for Java UST agent common class first
 628         AX_CHECK_CLASS(org.lttng.ust.agent.AbstractLttngAgent)
 629         if test "x$ac_cv_class_org_lttng_ust_agent_AbstractLttngAgent" = "xno"; then
 630                 AC_MSG_ERROR([The UST Java agent common class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-common.jar"])
 631         fi
 632
 633         if test "x$test_java_agent_jul" = "xyes"; then
 634                 # Check for JUL agent class
 635                 AX_CHECK_CLASS(org.lttng.ust.agent.jul.LttngLogHandler)
 636                 if test "x$ac_cv_class_org_lttng_ust_agent_jul_LttngLogHandler" = "xno"; then
 637                         AC_MSG_ERROR([The UST Java agent JUL class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-jul.jar"])
 638                 fi
 639         fi
 640
 641         if test "x$test_java_agent_log4j" = "xyes"; then
 642                 # Check for Log4j agent class
 643                 AX_CHECK_CLASS(org.lttng.ust.agent.log4j.LttngLogAppender)
 644                 if test "x$ac_cv_class_org_lttng_ust_agent_log4j_LttngLogAppender" = "xno"; then
 645                         AC_MSG_ERROR([The UST Java agent Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-log4j.jar"])
 646                 fi
 647
 648                 # Check for Log4j class
 649                 AX_CHECK_CLASS(org.apache.log4j.Logger)
 650                 if test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"; then
 651                         AC_MSG_ERROR([The Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j.jar"])
 652                 fi
 653         fi
 654 fi
 655
 656 # enable building man pages (user's intention)
 657 AC_ARG_ENABLE(
 658         man-pages,
 659         AS_HELP_STRING(
 660                 [--disable-man-pages],
 661                 [Do not build and install man pages (already built in a distributed tarball)]
 662         ),
 663         [man_pages_opt=$enableval],
 664         [man_pages_opt=yes]
 665 )
 666
 667 # check for asciidoc and xmlto if we enabled building the man pages
 668 have_asciidoc_xmlto=no
 669 warn_prebuilt_man_pages=no
 670
 671 AS_IF([test "x$man_pages_opt" = "xyes"], [
 672         AC_PATH_PROG([ASCIIDOC], [asciidoc], [no])
 673         AC_PATH_PROG([XMLTO], [xmlto], [no])
 674
 675         AS_IF([test "x$ASCIIDOC" = "xno" || test "x$XMLTO" = "xno"], [
 676                 AS_IF([test "x$in_git_repo" = "xyes"], [
 677                         # this is an error because we're in the Git repo, which
 678                         # means the man pages are not already generated for us,
 679                         # thus asciidoc/xmlto are required because we were asked
 680                         # to build the man pages
 681                         AC_MSG_ERROR([
 682 You need asciidoc and xmlto to build the LTTng-tools man pages. Use
 683 --disable-man-pages to disable building the man pages, in which case
 684 they will not be installed.
 685                         ])
 686                 ], [
 687                         # only warn here: since we're in the tarball, the man
 688                         # pages should already be generated at this point, thus
 689                         # asciidoc/xmlto are not strictly required
 690                         warn_prebuilt_man_pages=yes
 691                 ])
 692         ], [
 693                 have_asciidoc_xmlto=yes
 694         ])
 695 ])
 696
 697 # export man page build condition: build the man pages if the user
 698 # asked for it, and if the tools are available
 699 AM_CONDITIONAL([MAN_PAGES_OPT], [test "x$man_pages_opt" != "xno"])
 700 AM_CONDITIONAL([HAVE_ASCIIDOC_XMLTO], [test "x$have_asciidoc_xmlto" = "xyes"])
 701
 702 AC_DEFINE_UNQUOTED([MANPATH], ["`eval eval echo $mandir`"], [Path to man pages.])
 703
 704 # embedded --help message
 705 AC_ARG_ENABLE(
 706         [embedded-help],
 707         AS_HELP_STRING(
 708                 [--enable-embedded-help],
 709                 [Embed the --help messages in the executable files]
 710         ),
 711         [embedded_help=$enableval],
 712         [embedded_help=no]
 713 )
 714 AS_IF([test "x$embedded_help" = "xyes"], [
 715         AS_IF([test "x$man_pages_opt" = "xno"], [
 716                 AC_MSG_ERROR([You need the --enable-man-pages option with the --enable-embedded-help option.])
 717         ])
 718         AC_PATH_PROG([man_prog_path], [man], [no])
 719         AS_IF([test "x$man_prog_path" = "xno"], [
 720                 AC_MSG_ERROR([You need man with the --enable-embedded-help option.])
 721         ])
 722         AC_DEFINE_UNQUOTED([LTTNG_EMBED_HELP], 1, [Embed --help messages.])
 723         AC_SUBST([MANPROG], [$man_prog_path])
 724 ])
 725 AM_CONDITIONAL([EMBED_HELP], [test "x$embedded_help" != "xno"])
 726
 727 # Python agent test
 728 UST_PYTHON_AGENT="lttngust"
 729
 730 AC_ARG_ENABLE(test-python2-agent,
 731         AS_HELP_STRING([--enable-test-python2-agent],
 732                 [enable tests for python2 agent. Python2 interpreter path can be overridden by setting the PYTHON2 environment variable. Default: Autodetect]
 733         ),[:],[test_python2_agent_autodetect=yes]
 734 )
 735
 736 AC_ARG_ENABLE(test-python3-agent,
 737         AS_HELP_STRING([--enable-test-python3-agent],
 738                 [enable tests for python3 agent. Python3 interpreter path can be overridden by setting the PYTHON3 environment variable. Default: Autodetect]
 739         ),[:],[test_python3_agent_autodetect=yes]
 740 )
 741
 742 AC_ARG_ENABLE(test-python-agent-all,
 743         AS_HELP_STRING([--enable-test-python-agent-all],
 744                 [enable test for all python{2/3} agent.]
 745         ),
 746 )
 747
 748 AS_IF([test ! -z "$enable_test_python_agent_all"], [
 749        unset test_python2_agent_autodetect
 750        unset test_python3_agent_autodetect
 751 ])
 752
 753 AS_IF([test "x$enable_test_python_agent_all" = "xyes"], [
 754        enable_test_python2_agent=yes
 755        enable_test_python3_agent=yes
 756 ])
 757
 758 AS_IF([test "x$enable_test_python_agent_all" = "xno"], [
 759        enable_test_python2_agent=no
 760        enable_test_python3_agent=no
 761 ])
 762
 763
 764 AS_IF([test "x$enable_test_python2_agent" = "xyes" -o "x$test_python2_agent_autodetect" = "xyes" ], [
 765         AS_IF([test -z "$PYTHON2"], [
 766                         PYTHON2=python2
 767                 ], [
 768                         AC_MSG_WARN([Using user-defined PYTHON2 ($PYTHON2) for lttng-ust python2 agent check])
 769         ])
 770
 771         AC_PATH_PROG([PYTHON2_BIN],[$PYTHON2])
 772         AS_IF([test -z "$PYTHON2_BIN"], [
 773                 AS_IF([test -z "$test_python2_agent_autodetect"],[
 774                         AC_MSG_ERROR([No python2 interpreter found. PYTHON2 can be set to override default interpreter path])
 775                 ])
 776         ], [
 777                 AC_MSG_CHECKING([for python2 lttng-ust agent])
 778                 AS_IF([$PYTHON2_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
 779                         PYTHON2_AGENT=$PYTHON2_BIN
 780                         AC_MSG_RESULT([yes])
 781                         RUN_PYTHON_AGENT_TEST=yes
 782                 ], [
 783                         AC_MSG_RESULT([no])
 784                         AS_IF([test -z "$test_python2_agent_autodetect"],[
 785                                 AC_MSG_ERROR([No python2 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
 786                         ])
 787                 ])
 788
 789         ])
 790
 791 ])
 792
 793 AS_IF([test "x$enable_test_python3_agent" = "xyes" -o "x$test_python3_agent_autodetect" = "xyes" ], [
 794         AS_IF([test -z "$PYTHON3"], [
 795                 PYTHON3=python3
 796         ], [
 797                 AC_MSG_WARN([Using user-defined PYTHON3 ($PYTHON3) for lttng-ust python3 agent check])
 798         ])
 799
 800         AC_PATH_PROG([PYTHON3_BIN],[$PYTHON3])
 801         AS_IF([test -z "$PYTHON3_BIN"], [
 802                 AS_IF([test -z "$test_python3_agent_autodetect"],[
 803                         AC_MSG_ERROR([No python3 interpreter found. PYTHON3 can be set to override default interpreter path])
 804                 ])
 805         ], [
 806                 AC_MSG_CHECKING([for python3 lttng-ust agent])
 807                 AS_IF([$PYTHON3_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
 808                         PYTHON3_AGENT=$PYTHON3_BIN
 809                         AC_MSG_RESULT([yes])
 810                         RUN_PYTHON_AGENT_TEST=yes
 811                 ], [
 812                         AC_MSG_RESULT([no])
 813                         AS_IF([test -z "$test_python3_agent_autodetect"],[
 814                                 AC_MSG_ERROR([No python3 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
 815                         ])
 816                 ])
 817
 818         ])
 819 ])
 820 AC_SUBST([RUN_PYTHON_AGENT_TEST])
 821 AC_SUBST([PYTHON2_AGENT])
 822 AC_SUBST([PYTHON3_AGENT])
 823
 824 AC_ARG_ENABLE([test-sdt-uprobe],
 825   [AS_HELP_STRING([--enable-test-sdt-uprobe], [enable the LTTng UST SDT uprobe tests [default=autodetect]])],
 826   [test_sdt_uprobe="$enableval"],
 827   [test_sdt_uprobe=autodetect]
 828 )
 829
 830 AS_IF([test "$test_sdt_uprobe" != "no"], [
 831   LTTNG_CHECK_SDT_WORKS
 832   AC_PATH_PROG([DTRACE], [dtrace])
 833 ])
 834
 835 AS_IF([test "$test_sdt_uprobe" = "yes"], [
 836   AS_IF([test "$lttng_cv_sdt_works" = "no"], [
 837     AC_MSG_ERROR([Cannot find 'sys/sdt.h'.])
 838   ])
 839   AS_IF([test "x$DTRACE" = "x"], [
 840     AC_MSG_ERROR([Cannot find SystemTap dtrace. You can set the DTRACE variable to override automatic detection.])
 841   ])
 842 ])
 843
 844 AS_IF([test "$test_sdt_uprobe" = "autodetect"], [
 845   AS_IF([test "$lttng_cv_sdt_works" = "yes"], [
 846     AS_IF([test "x$DTRACE" != "x"], [
 847       test_sdt_uprobe=yes
 848     ])
 849   ])
 850 ])
 851
 852 AM_CONDITIONAL([TEST_SDT_UPROBE], [test "$test_sdt_uprobe" = "yes"])
 853
 854 # Arguments for binaries build exclusion
 855 AC_ARG_ENABLE([bin-lttng], AS_HELP_STRING([--disable-bin-lttng],[Disable the build of lttng binaries]))
 856 AC_ARG_ENABLE([bin-lttng-consumerd], AS_HELP_STRING([--disable-bin-lttng-consumerd],
 857               [Disable the build of lttng-consumerd binaries]))
 858 AC_ARG_ENABLE([bin-lttng-crash], AS_HELP_STRING([--disable-bin-lttng-crash],[Disable the build of lttng-crash binaries]))
 859 AC_ARG_ENABLE([bin-lttng-relayd], AS_HELP_STRING([--disable-bin-lttng-relayd],
 860               [Disable the build of lttng-relayd binaries]))
 861 AC_ARG_ENABLE([bin-lttng-sessiond], AS_HELP_STRING([--disable-bin-lttng-sessiond],
 862               [Disable the build of lttng-sessiond binaries]))
 863 AC_ARG_ENABLE([extras], AS_HELP_STRING([--disable-extras],
 864               [Disable the build of the extra components]))
 865
 866
 867 build_lib_consumer=no
 868 build_lib_health=no
 869 build_lib_index=no
 870 build_lib_kernel_consumer=no
 871 build_lib_kernel_ctl=no
 872 build_lib_lttng_ctl=no
 873 build_lib_relayd=no
 874 build_lib_sessiond_comm=no
 875 build_lib_testpoint=no
 876 build_lib_ust_consumer=no
 877
 878 # There is an overlap for enabled dependencies, but this makes everything
 879 # simpler. libcommon and libconfig are always compiled so they are not repeated
 880 # here.
 881
 882 # Enable binary dependencies.
 883 AS_IF([test x$enable_bin_lttng != xno],
 884       [
 885        build_lib_lttng_ctl=yes
 886       ]
 887 )
 888
 889 AS_IF([test x$enable_bin_lttng_consumerd != xno],
 890       [
 891        build_lib_consumer=yes
 892        build_lib_sessiond_comm=yes
 893        build_lib_index=yes
 894        build_lib_health=yes
 895        build_lib_testpoint=yes
 896       ]
 897 )
 898
 899 AS_IF([test x$enable_bin_lttng_crash != xno],
 900       # Do nothing since libconfig and libcommon are built by default.
 901       []
 902 )
 903
 904 AS_IF([test x$enable_bin_lttng_relayd != xno],
 905       [
 906        build_lib_lttng_ctl=yes
 907        build_lib_sessiond_comm=yes
 908        build_lib_index=yes
 909        build_lib_health=yes
 910        build_lib_testpoint=yes
 911       ]
 912 )
 913 AS_IF([test x$enable_bin_lttng_sessiond != xno],
 914       [
 915        build_lib_lttng_ctl=yes
 916        build_lib_sessiond_comm=yes
 917        build_lib_kernel_ctl=yes
 918        build_lib_relayd=yes
 919        build_lib_testpoint=yes
 920        build_lib_health=yes
 921       ]
 922 )
 923
 924 # Libraries dependencies enabling
 925 AS_IF([test x$build_lib_lttng_ctl = xyes],
 926       [
 927        build_lib_sessiond_comm=yes
 928       ]
 929 )
 930
 931 AS_IF([test x$build_lib_consumer = xyes],
 932       [
 933        build_lib_sessiond_comm=yes
 934        build_lib_kernel_consumer=yes
 935        build_lib_relayd=yes
 936        AS_IF([test "x$with_lttng_ust" = "xyes"], [build_lib_ust_consumer=yes])
 937       ]
 938 )
 939
 940 AS_IF([test x$build_lib_kernel_consumer = xyes],
 941       [
 942        build_lib_kernel_ctl=yes
 943        build_lib_relayd=yes
 944       ]
 945 )
 946
 947 AS_IF([test x$build_lib_relayd = xyes],
 948       [
 949        build_lib_sessiond_comm=yes
 950       ]
 951 )
 952
 953 # Find arch type
 954 AS_CASE([$host_cpu],
 955         [k1om], [ARCHTYPE="x86"],
 956         [i386], [ARCHTYPE="x86"],
 957         [i486], [ARCHTYPE="x86"],
 958         [i586], [ARCHTYPE="x86"],
 959         [i686], [ARCHTYPE="x86"],
 960         [amd64], [ARCHTYPE="x86"],
 961         [x86_64], [ARCHTYPE="x86"],
 962         [powerpc], [ARCHTYPE="ppc"],
 963         [ppc64], [ARCHTYPE="ppc"],
 964         [powerpc64], [ARCHTYPE="ppc"],
 965         [powerpc64le], [ARCHTYPE="ppc"],
 966         [ppc], [ARCHTYPE="ppc"],
 967         [s390], [ARCHTYPE="s390"],
 968         [s390x], [ARCHTYPE="s390"],
 969         [sparc], [ARCHTYPE="sparc64"],
 970         [sparc64], [ARCHTYPE="sparc64"],
 971         [alpha*], [ARCHTYPE="alpha"],
 972         [ia64], [ARCHTYPE="ia64"],
 973         [arm*], [ARCHTYPE="arm"],
 974         [aarch64*], [ARCHTYPE="aarch64"],
 975         [mips*], [ARCHTYPE="mips"],
 976         [nios2*], [ARCHTYPE="nios2"],
 977         [tile*], [ARCHTYPE="tile"],
 978         [hppa*], [ARCHTYPE="hppa"],
 979         [m68k], [ARCHTYPE="m68k"],
 980         [riscv*], [ARCHTYPE="riscv"],
 981         [ARCHTYPE="unknown"]
 982 )
 983
 984 AC_SUBST(ARCHTYPE)
 985
 986 AS_CASE([$host_os],
 987         [linux*], [OSTYPE="linux"],
 988         [freebsd*], [OSTYPE="freebsd"],
 989         [solaris*], [OSTYPE="solaris"],
 990         [cygwin*], [OSTYPE="cygwin"],
 991         [mingw*], [OSTYPE="mingw"],
 992         [OSTYPE="unknown"]
 993 )
 994 AC_SUBST(OSTYPE)
 995 AM_CONDITIONAL([IS_LINUX], [test $OSTYPE = "linux"])
 996
 997
 998
 999 # Userspace callstack capture is only supported by the Linux kernel on x86.
1000 AH_TEMPLATE([HAVE_MODULES_USERSPACE_CALLSTACK_CONTEXT], [Define if you have LTTng-modules userspace callstack tracing support])
1001 AS_IF([test "x$ARCHTYPE" = "xx86" && test "x$OSTYPE" = "xlinux"],[
1002         have_modules_userspace_callstack_context=yes
1003         AC_DEFINE([HAVE_MODULES_USERSPACE_CALLSTACK_CONTEXT], [1])
1004 ])
1005 AM_CONDITIONAL([HAVE_MODULES_USERSPACE_CALLSTACK_CONTEXT], [test x$have_modules_userspace_callstack_context = xyes])
1006
1007 # Export binaries build conditions.
1008 AM_CONDITIONAL([BUILD_BIN_LTTNG], [test x$enable_bin_lttng != xno])
1009 AM_CONDITIONAL([BUILD_BIN_LTTNG_CONSUMERD], [test x$enable_bin_lttng_consumerd != xno])
1010 AM_CONDITIONAL([BUILD_BIN_LTTNG_CRASH], [test x$enable_bin_lttng_crash != xno])
1011 AM_CONDITIONAL([BUILD_BIN_LTTNG_RELAYD], [test x$enable_bin_lttng_relayd != xno])
1012 AM_CONDITIONAL([BUILD_BIN_LTTNG_SESSIOND], [test x$enable_bin_lttng_sessiond != xno])
1013
1014 # Export the tests and extras build conditions.
1015 AS_IF([\
1016 test "x$enable_bin_lttng" != "xno" && \
1017 test "x$enable_bin_lttng_consumerd" != "xno" && \
1018 test "x$enable_bin_lttng_crash" != "xno" && \
1019 test "x$enable_bin_lttng_relayd" != "xno" && \
1020 test "x$enable_bin_lttng_sessiond" != "xno"],
1021 [build_tests=yes],
1022 [build_tests=no]
1023 )
1024
1025 AM_CONDITIONAL([BUILD_TESTS], [test x$build_tests = xyes])
1026 AM_CONDITIONAL([BUILD_EXTRAS], [test x$enable_extras != xno])
1027
1028 # Export libraries build conditions.
1029 AM_CONDITIONAL([BUILD_LIB_CONSUMER], [test x$build_lib_consumer = xyes])
1030 AM_CONDITIONAL([BUILD_LIB_HEALTH], [test x$build_lib_health = xyes])
1031 AM_CONDITIONAL([BUILD_LIB_INDEX], [test x$build_lib_index = xyes])
1032 AM_CONDITIONAL([BUILD_LIB_KERNEL_CONSUMER], [test x$build_lib_kernel_consumer = xyes])
1033 AM_CONDITIONAL([BUILD_LIB_KERNEL_CTL], [test x$build_lib_kernel_ctl = xyes])
1034 AM_CONDITIONAL([BUILD_LIB_LTTNG_CTL], [test x$build_lib_lttng_ctl = xyes])
1035 AM_CONDITIONAL([BUILD_LIB_RELAYD], [test x$build_lib_relayd = xyes])
1036 AM_CONDITIONAL([BUILD_LIB_SESSIOND_COMM], [test x$build_lib_sessiond_comm = xyes])
1037 AM_CONDITIONAL([BUILD_LIB_TESTPOINT], [test x$build_lib_testpoint = xyes])
1038 AM_CONDITIONAL([BUILD_LIB_UST_CONSUMER], [test x$build_lib_ust_consumer = xyes])
1039
1040 AM_CFLAGS="${WARN_CFLAGS} -fno-strict-aliasing $PTHREAD_CFLAGS"
1041 AC_SUBST(AM_CFLAGS)
1042
1043 # This is set even though it is empty, so Makefiles can do "AM_LDFLAGS += ...".
1044 AM_LDFLAGS=""
1045 AC_SUBST(AM_LDFLAGS)
1046
1047 # The order in which the include folders are searched is important.
1048 # The top_builddir should always be searched first in the event that a build
1049 # time generated file is included. An example of this is the "version.i" file.
1050 # In a scenario where lttng-tools is built from a distribution tarball and in a
1051 # out-of-tree manner, the generated "version.i" has priority on the one from
1052 # the source (distribution tarball) and must be found first.
1053 AM_CPPFLAGS="-I\$(top_builddir)/include -I\$(top_srcdir)/include -I\$(top_builddir)/src -I\$(top_srcdir)/src -include config.h $AM_CPPFLAGS"
1054 AC_SUBST(AM_CPPFLAGS)
1055
1056 lttngincludedir="${includedir}/lttng"
1057 AC_SUBST(lttngincludedir)
1058
1059 lttngactionincludedir="${includedir}/lttng/action"
1060 AC_SUBST(lttngactionincludedir)
1061
1062 lttngconditionincludedir="${includedir}/lttng/condition"
1063 AC_SUBST(lttngconditionincludedir)
1064
1065 lttngnotificationincludedir="${includedir}/lttng/notification"
1066 AC_SUBST(lttngnotificationincludedir)
1067
1068 lttngtriggerincludedir="${includedir}/lttng/trigger"
1069 AC_SUBST(lttngtriggerincludedir)
1070
1071 lttngeventruleincludedir="${includedir}/lttng/event-rule"
1072 AC_SUBST(lttngeventruleincludedir)
1073
1074 lttnglibexecdir="${libdir}/lttng/libexec"
1075 AC_SUBST(lttnglibexecdir)
1076
1077 AC_CONFIG_FILES([
1078         Makefile
1079         doc/Makefile
1080         doc/examples/Makefile
1081         doc/examples/rotation/Makefile
1082         doc/examples/trigger-condition-event-matches/Makefile
1083         doc/man/Makefile
1084         doc/man/asciidoc-attrs.conf
1085         include/Makefile
1086         extras/Makefile
1087         extras/bindings/Makefile
1088         extras/bindings/swig/Makefile
1089         extras/bindings/swig/python/Makefile
1090         extras/core-handler/Makefile
1091         src/Makefile
1092         src/common/Makefile
1093         src/common/argpar/Makefile
1094         src/common/bytecode/Makefile
1095         src/common/kernel-ctl/Makefile
1096         src/common/kernel-consumer/Makefile
1097         src/common/consumer/Makefile
1098         src/common/ust-consumer/Makefile
1099         src/common/hashtable/Makefile
1100         src/common/sessiond-comm/Makefile
1101         src/common/compat/Makefile
1102         src/common/relayd/Makefile
1103         src/common/testpoint/Makefile
1104         src/common/index/Makefile
1105         src/common/health/Makefile
1106         src/common/config/Makefile
1107         src/common/string-utils/Makefile
1108         src/common/fd-tracker/Makefile
1109         src/common/filter/Makefile
1110         src/lib/Makefile
1111         src/lib/lttng-ctl/Makefile
1112         src/lib/lttng-ctl/lttng-ctl.pc
1113         src/bin/Makefile
1114         src/bin/lttng-consumerd/Makefile
1115         src/bin/lttng-sessiond/Makefile
1116         src/bin/lttng-relayd/Makefile
1117         src/bin/lttng/Makefile
1118         src/bin/lttng-crash/Makefile
1119         src/vendor/Makefile
1120         src/vendor/msgpack/Makefile
1121         tests/Makefile
1122         tests/destructive/Makefile
1123         tests/regression/Makefile
1124         tests/regression/kernel/Makefile
1125         tests/regression/tools/Makefile
1126         tests/regression/tools/streaming/Makefile
1127         tests/regression/tools/filtering/Makefile
1128         tests/regression/tools/health/Makefile
1129         tests/regression/tools/tracefile-limits/Makefile
1130         tests/regression/tools/snapshots/Makefile
1131         tests/regression/tools/live/Makefile
1132         tests/regression/tools/exclusion/Makefile
1133         tests/regression/tools/save-load/Makefile
1134         tests/regression/tools/save-load/configuration/Makefile
1135         tests/regression/tools/mi/Makefile
1136         tests/regression/tools/wildcard/Makefile
1137         tests/regression/tools/channel/Makefile
1138         tests/regression/tools/crash/Makefile
1139         tests/regression/tools/regen-metadata/Makefile
1140         tests/regression/tools/regen-statedump/Makefile
1141         tests/regression/tools/notification/Makefile
1142         tests/regression/tools/rotation/Makefile
1143         tests/regression/tools/base-path/Makefile
1144         tests/regression/tools/metadata/Makefile
1145         tests/regression/tools/tracker/Makefile
1146         tests/regression/tools/working-directory/Makefile
1147         tests/regression/tools/relayd-grouping/Makefile
1148         tests/regression/tools/clear/Makefile
1149         tests/regression/tools/trigger/Makefile
1150         tests/regression/tools/trigger/rate-policy/Makefile
1151         tests/regression/tools/trigger/start-stop/Makefile
1152         tests/regression/tools/trigger/utils/Makefile
1153         tests/regression/tools/trigger/name/Makefile
1154         tests/regression/ust/Makefile
1155         tests/regression/ust/nprocesses/Makefile
1156         tests/regression/ust/high-throughput/Makefile
1157         tests/regression/ust/low-throughput/Makefile
1158         tests/regression/ust/before-after/Makefile
1159         tests/regression/ust/buffers-pid/Makefile
1160         tests/regression/ust/periodical-metadata-flush/Makefile
1161         tests/regression/ust/multi-session/Makefile
1162         tests/regression/ust/multi-lib/Makefile
1163         tests/regression/ust/overlap/Makefile
1164         tests/regression/ust/overlap/demo/Makefile
1165         tests/regression/ust/linking/Makefile
1166         tests/regression/ust/daemon/Makefile
1167         tests/regression/ust/exit-fast/Makefile
1168         tests/regression/ust/fork/Makefile
1169         tests/regression/ust/libc-wrapper/Makefile
1170         tests/regression/ust/baddr-statedump/Makefile
1171         tests/regression/ust/ust-dl/Makefile
1172         tests/regression/ust/java-jul/Makefile
1173         tests/regression/ust/java-log4j/Makefile
1174         tests/regression/ust/getcpu-override/Makefile
1175         tests/regression/ust/clock-override/Makefile
1176         tests/regression/ust/type-declarations/Makefile
1177         tests/regression/ust/rotation-destroy-flush/Makefile
1178         tests/regression/ust/blocking/Makefile
1179         tests/regression/ust/namespaces/Makefile
1180         tests/stress/Makefile
1181         tests/unit/Makefile
1182         tests/unit/ini_config/Makefile
1183         tests/perf/Makefile
1184         tests/utils/Makefile
1185         tests/utils/tap/Makefile
1186         tests/utils/testapp/Makefile
1187         tests/utils/testapp/gen-ns-events/Makefile
1188         tests/utils/testapp/gen-kernel-test-events/Makefile
1189         tests/utils/testapp/gen-py-events/Makefile
1190         tests/utils/testapp/gen-ust-events/Makefile
1191         tests/utils/testapp/gen-ust-events-ns/Makefile
1192         tests/utils/testapp/gen-syscall-events-callstack/Makefile
1193         tests/utils/testapp/gen-ust-nevents/Makefile
1194         tests/utils/testapp/gen-ust-nevents-str/Makefile
1195         tests/utils/testapp/gen-syscall-events/Makefile
1196         tests/utils/testapp/gen-ust-tracef/Makefile
1197         tests/utils/testapp/userspace-probe-elf-binary/Makefile
1198         tests/utils/testapp/userspace-probe-elf-cxx-binary/Makefile
1199         tests/utils/testapp/userspace-probe-sdt-binary/Makefile
1200 ])
1201
1202 # Inject variable into python test script.
1203 AC_CONFIG_FILES([tests/regression/ust/python-logging/test_python_logging],[chmod +x tests/regression/ust/python-logging/test_python_logging])
1204 # Inject LTTNG_TOOLS_BUILD_WITH_LIBPFM variable in test script.
1205 AC_CONFIG_FILES([tests/perf/test_perf_raw],[chmod +x tests/perf/test_perf_raw])
1206 AC_CONFIG_FILES([tests/regression/ust/ust-dl/test_ust-dl],[chmod +x tests/regression/ust/ust-dl/test_ust-dl])
1207
1208 AC_OUTPUT
1209
1210 #
1211 # Mini-report on what will be built.
1212 #
1213
1214 PPRINT_INIT
1215 PPRINT_SET_INDENT(1)
1216 PPRINT_SET_TS(38)
1217
1218 AS_ECHO
1219 AS_ECHO("${PPRINT_COLOR_BLDBLU}LTTng-tools $PACKAGE_VERSION \"$version_name\"$PPRINT_COLOR_RST")
1220 AS_ECHO
1221
1222 AS_IF([test -n "$report_fold"], [
1223         AS_ECHO("`AS_ECHO("$version_description") | $report_fold -s`")
1224 ], [
1225         AS_ECHO("$version_description")
1226 ])
1227
1228 AS_ECHO
1229 PPRINT_SUBTITLE([Features])
1230
1231 # Target architecture we're building for.
1232 target_arch=$host_cpu
1233 [
1234 for f in $CFLAGS; do
1235         if test $f = "-m32"; then
1236                         target_arch="32-bit"
1237         elif test $f = "-m64"; then
1238                         target_arch="64-bit"
1239         fi
1240 done
1241 ]
1242 PPRINT_PROP_STRING([Target architecture], $target_arch)
1243
1244 # kmod enabled/disabled
1245 test "x$with_kmod" != "xno" && value=1 || value=0
1246 PPRINT_PROP_BOOL([libkmod support], $value)
1247
1248 # LTTng-UST enabled/disabled
1249 test "x$with_lttng_ust" = "xyes" && value=1 || value=0
1250 PPRINT_PROP_BOOL([LTTng-UST support], $value)
1251
1252 AS_ECHO
1253 PPRINT_SUBTITLE([Binaries])
1254
1255 # List binaries to be built
1256 test x$enable_bin_lttng != xno && value=1 || value=0
1257 PPRINT_PROP_BOOL([lttng], $value)
1258
1259 test x$enable_bin_lttng_consumerd != xno && value=1 || value=0
1260 PPRINT_PROP_BOOL([lttng-consumerd], $value)
1261
1262 test x$enable_bin_lttng_crash != xno && value=1 || value=0
1263 PPRINT_PROP_BOOL([lttng-crash], $value)
1264
1265 test x$enable_bin_lttng_relayd != xno && value=1 || value=0
1266 PPRINT_PROP_BOOL([lttng-relayd], $value)
1267
1268 test x$enable_bin_lttng_sessiond != xno && value=1 || value=0
1269 PPRINT_PROP_BOOL([lttng-sessiond], $value)
1270
1271 # Extras
1272 test x$enable_extras != xno && value=1 || value=0
1273 AS_ECHO
1274 PPRINT_SET_INDENT(0)
1275 PPRINT_PROP_BOOL([Extras], $value, $PPRINT_COLOR_SUBTITLE)
1276 PPRINT_SET_INDENT(1)
1277
1278 AS_ECHO
1279 PPRINT_SUBTITLE([Tests])
1280
1281 # Print clear message that tests won't be built
1282 AS_IF([test "x$build_tests" = "xno"],[
1283         PPRINT_WARN([Tests won't be built since some binaries were disabled])
1284 ])
1285
1286 # LTTng UST Java agent JUL tests enabled/disabled
1287 test "x$test_java_agent_jul" = "xyes" && value=1 || value=0
1288 PPRINT_PROP_BOOL([LTTng-UST Java agent JUL tests], $value)
1289
1290 # LTTng UST Java agent Log4j tests enabled/disabled
1291 test "x$test_java_agent_log4j" = "xyes" && value=1 || value=0
1292 PPRINT_PROP_BOOL([LTTng-UST Java agent Log4j tests], $value)
1293
1294 test ! -z "$PYTHON2_AGENT" && value=1 || value=0
1295 PPRINT_PROP_BOOL([LTTng-UST Python2 agent tests], $value)
1296
1297 test ! -z "$PYTHON3_AGENT" && value=1 || value=0
1298 PPRINT_PROP_BOOL([LTTng-UST Python3 agent tests], $value)
1299
1300 # LTTng UST Java agent Log4j tests enabled/disabled
1301 test "x$test_sdt_uprobe" = "xyes" && value=1 || value=0
1302 PPRINT_PROP_BOOL([LTTng-UST SDT uprobe tests], $value)
1303
1304 #Python binding enabled/disabled
1305 test "x$enable_python_binding" = xyes && value=1 || value=0
1306 AS_ECHO
1307 PPRINT_SET_INDENT(0)
1308 PPRINT_PROP_BOOL([Python binding], $value, $PPRINT_COLOR_SUBTITLE)
1309
1310 # man pages build enabled/disabled
1311 m4_pushdef([build_man_pages_msg], [Build and install man pages])
1312
1313 AS_IF([test "x$man_pages_opt" != "xno"], [
1314         AS_IF([test "x$in_git_repo" = "xyes"], [
1315                 PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
1316         ], [
1317                 AS_IF([test "x$have_asciidoc_xmlto" = "xyes"], [
1318                         PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
1319                 ], [
1320                         PPRINT_PROP_STRING([build_man_pages_msg],
1321                                 [${PPRINT_COLOR_BLDGRN}yes (already built)],
1322                                 $PPRINT_COLOR_SUBTITLE)
1323                 ])
1324         ])
1325 ], [
1326         PPRINT_PROP_BOOL([build_man_pages_msg], 0, $PPRINT_COLOR_SUBTITLE)
1327 ])
1328
1329 m4_popdef([build_man_pages_msg])
1330
1331 test "x$embedded_help" = xyes && value=1 || value=0
1332 PPRINT_PROP_BOOL([Embed --help messages], $value, $PPRINT_COLOR_SUBTITLE)
1333
1334 PPRINT_SET_INDENT(1)
1335
1336 report_bindir="`eval eval echo $bindir`"
1337 report_libdir="`eval eval echo $libdir`"
1338
1339 # Print the bindir and libdir this `make install' will install into.
1340 AS_ECHO
1341 PPRINT_SUBTITLE([Install directories])
1342 PPRINT_PROP_STRING([Binaries], [$report_bindir])
1343 PPRINT_PROP_STRING([Libraries], [$report_libdir])
1344
1345 AS_ECHO
1346 PPRINT_SUBTITLE([Search directories])
1347
1348 # If we build the sessiond, print the paths it will use
1349 AS_IF([test "$SESSIOND_BIN" = ""],[
1350         path="$report_bindir/lttng-sessiond"
1351 ],[
1352         path="$SESSIOND_BIN"
1353 ])
1354 PPRINT_PROP_STRING([lttng-sessiond executable], [$path])
1355
1356 AS_IF([test "$CONSUMERD32_BIN" = ""],[
1357         path="`eval eval echo $lttnglibexecdir`/lttng-consumerd"
1358 ],[
1359         path="$CONSUMERD32_BIN"
1360 ])
1361 PPRINT_PROP_STRING([32-bit lttng-consumerd executable], [$path])
1362
1363 AS_IF([test "$CONSUMERD32_LIBDIR" = ""],[
1364         path="`eval eval echo $libdir`"
1365 ],[
1366         path="$CONSUMERD32_LIBDIR"
1367 ])
1368 PPRINT_PROP_STRING([32-bit consumer libraries], [$path])
1369
1370 AS_IF([test "$CONSUMERD64_BIN" = ""],[
1371         path="`eval eval echo $lttnglibexecdir`/lttng-consumerd"
1372 ],[
1373         path="$CONSUMERD64_BIN"
1374 ])
1375 PPRINT_PROP_STRING([64-bit lttng-consumerd executable], [$path])
1376
1377 AS_IF([test "$CONSUMERD64_LIBDIR" = ""],[
1378         path="`eval eval echo $libdir`"
1379 ],[
1380         path="$CONSUMERD64_LIBDIR"
1381 ])
1382 PPRINT_PROP_STRING([64-bit consumer libraries], [$path])
1383 PPRINT_SET_INDENT(0)
1384
1385 AS_IF([test "x$warn_prebuilt_man_pages" = "xyes" ], [
1386         AS_ECHO
1387         PPRINT_WARN([You need asciidoc and xmlto to build the LTTng-tools man pages.
1388
1389 Note that the man pages are already built in this distribution tarball,
1390 therefore asciidoc and xmlto are only needed if you intend to modify
1391 their sources.
1392
1393 Also note that the installed man pages will contain the project's
1394 default command-line option and environment variable values.
1395
1396 Use --disable-man-pages to completely disable building and installing
1397 the man pages.])
1398 ])