configure.ac

   1 AC_PREREQ([2.64])
   2 AC_INIT([lttng-tools],[2.10.0-pre],[jeremie.galarneau@efficios.com],[],[https://lttng.org])
   3
   4 AC_CONFIG_HEADERS([include/config.h])
   5 AC_CONFIG_AUX_DIR([config])
   6 AC_CONFIG_MACRO_DIR([m4])
   7
   8 AC_CANONICAL_TARGET
   9 AC_CANONICAL_HOST
  10
  11 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip tar-pax nostdinc])
  12 AM_MAINTAINER_MODE([enable])
  13
  14 # Enable silent rules if available (Introduced in AM 1.11)
  15 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  16
  17 AC_REQUIRE_AUX_FILE([tap-driver.sh])
  18
  19 # Checks for C compiler
  20 AC_USE_SYSTEM_EXTENSIONS
  21 AC_SYS_LARGEFILE
  22 AC_PROG_CC
  23 AC_PROG_CC_STDC
  24
  25 # Checks for programs.
  26 AC_PROG_GREP
  27 AC_PROG_MAKE_SET
  28 AC_PROG_SED
  29 AC_PATH_PROG([report_fold], [fold])
  30 LT_INIT
  31
  32 # Check for objcopy, required by the base address statedump and dynamic linker tests
  33 AC_CHECK_TOOL([OBJCOPY], [objcopy], [no])
  34 AS_IF([test "x$OBJCOPY" = "xno"],
  35         [AC_MSG_WARN([Cannot find objcopy. The base address statedump and dynamic linker tests will be disabled. Install the binutils package to remediate this.])]
  36 )
  37 AM_CONDITIONAL([HAVE_OBJCOPY], [test "x$OBJCOPY" != xno])
  38
  39 # check for pgrep
  40 AC_PATH_PROG([PGREP], [pgrep], [no])
  41 AM_CONDITIONAL([HAVE_PGREP], [test "x$PGREP" != "xno"])
  42
  43 # check for bison
  44 AC_PROG_YACC
  45 BISON=$YACC
  46 AX_PROG_BISON_VERSION([2.4], [have_bison=yes])
  47
  48 AS_IF([test "x$have_bison" != "xyes"], [
  49   AS_IF([test "x$in_git_repo" = "xyes"], [
  50     AC_MSG_FAILURE([
  51 Bison >= 2.4 is required when building from the Git repository. You can
  52 set the YACC variable to override automatic detection.
  53     ])
  54   ], [
  55     AC_MSG_WARN([
  56 Missing Bison >= 2.4. Note that the parser files are already built in
  57 this distribution tarball, so Bison is only needed if you intend to
  58 modify their sources. You can set the YACC variable to override automatic
  59 detection.
  60     ])
  61   ])
  62 ])
  63 AM_CONDITIONAL([HAVE_BISON], [test "x$have_bison" = "xyes"])
  64
  65 # check for flex
  66 AC_PROG_LEX
  67 FLEX=$LEX
  68 AX_PROG_FLEX_VERSION([2.5.35], [have_flex=yes])
  69
  70 AS_IF([test "x$have_flex" != "xyes"], [
  71   AS_IF([test "x$in_git_repo" = "xyes"], [
  72     AC_MSG_FAILURE([
  73 Flex >= 2.5.35 is required when building from the Git repository. You can
  74 set the LEX variable to override automatic detection.
  75     ])
  76   ], [
  77     AC_MSG_WARN([
  78 Missing Flex >= 2.5.35. Note that the lexer files are already built in
  79 this distribution tarball, so Flex is only needed if you intend to
  80 modify their sources. You can set the LEX variable to override automatic
  81 detection.
  82     ])
  83   ])
  84 ])
  85 AM_CONDITIONAL([HAVE_FLEX], [test "x$have_flex" = "xyes"])
  86
  87
  88 # Checks for typedefs, structures, and compiler characteristics.
  89 AC_C_INLINE
  90 AC_TYPE_INT32_T
  91 AC_TYPE_INT64_T
  92 AC_TYPE_MODE_T
  93 AC_TYPE_OFF_T
  94 AC_TYPE_PID_T
  95 AC_TYPE_SIZE_T
  96 AC_TYPE_SSIZE_T
  97 AC_TYPE_UID_T
  98 AC_TYPE_UINT16_T
  99 AC_TYPE_UINT32_T
 100 AC_TYPE_UINT64_T
 101 AC_TYPE_UINT8_T
 102
 103 AX_C___ATTRIBUTE__
 104 AS_IF([test "x$ax_cv___attribute__" = "xyes"],
 105         [:],
 106         [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
 107
 108 AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])
 109
 110 AX_LIB_SOCKET_NSL
 111
 112 LT_NO_UNDEFINED=""
 113 AS_CASE([$host_os],
 114   [cygwin*],
 115     [
 116       LT_NO_UNDEFINED="-no-undefined"
 117     ]
 118 )
 119
 120 AC_SUBST(LT_NO_UNDEFINED)
 121
 122 # Compute minor/major/patchlevel version numbers
 123 major_version=$(echo AC_PACKAGE_VERSION | $SED 's/^\([[0-9]]\)*\.[[0-9]]*\.[[0-9]]*.*$/\1/')
 124 minor_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.\([[0-9]]*\)\.[[0-9]]*.*$/\1/')
 125 patchlevel_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\).*$/\1/')
 126
 127 AC_SUBST([MAJOR_VERSION], [$major_version])
 128 AC_SUBST([MINOR_VERSION], [$minor_version])
 129 AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version])
 130 AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [LTTng-Tools major version number])
 131 AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [LTTng-Tools minor version number])
 132 AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [LTTng-Tools patchlevel version number])
 133
 134 version_name="KeKriek"
 135 version_description='From Brasserie Dunham, a sour mashed golden wheat ale fermented with local sour cherries from Tougas orchards. Fresh sweet cherry notes with some tartness, lively carbonation with a dry finish.'
 136 version_description_c=$(echo $version_description | $SED 's/"/\\"/g')
 137
 138 AC_DEFINE_UNQUOTED([VERSION_NAME], ["$version_name"], "")
 139 AC_DEFINE_UNQUOTED([VERSION_DESCRIPTION], ["$version_description_c"], "")
 140
 141 # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
 142 AC_ARG_ENABLE(libtool-linkdep-fixup,
 143         AS_HELP_STRING([--disable-libtool-linkdep-fixup],
 144                         [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)]),
 145         libtool_fixup=$enableval,
 146         libtool_fixup=yes)
 147
 148 AS_IF([test "x$libtool_fixup" = "xyes"],
 149             [
 150             libtool_m4="$srcdir/m4/libtool.m4"
 151             libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
 152             AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
 153             libtool_flag_pattern_count=$($GREP -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
 154             AS_IF([test $libtool_flag_pattern_count -ne 0],
 155             [
 156                   AC_MSG_RESULT([$libtool_flag_pattern_count])
 157                   AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
 158                   $SED -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
 159                   ],
 160                   [
 161                   AC_MSG_RESULT([none])
 162                   ])
 163             ])
 164
 165 AM_CONDITIONAL([NO_SHARED], [test x$enable_shared = xno])
 166
 167 AC_CHECK_HEADERS([ \
 168         sys/types.h unistd.h fcntl.h string.h pthread.h limits.h \
 169         signal.h stdlib.h sys/un.h sys/socket.h stdlib.h stdio.h \
 170         getopt.h sys/ipc.h sys/shm.h popt.h grp.h arpa/inet.h \
 171         netdb.h netinet/in.h paths.h stddef.h sys/file.h sys/ioctl.h \
 172         sys/mount.h sys/param.h sys/time.h
 173 ])
 174
 175 # Basic functions check
 176 AC_CHECK_FUNCS([ \
 177         atexit bzero clock_gettime dup2 fdatasync fls ftruncate \
 178         gethostbyname gethostname getpagesize localtime_r memchr memset \
 179         mkdir munmap putenv realpath rmdir socket strchr strcspn strdup \
 180         strncasecmp strndup strnlen strpbrk strrchr strstr strtol strtoul \
 181         strtoull dirfd gethostbyname2 getipnodebyname epoll_create1 \
 182         sched_getcpu sysconf sync_file_range
 183 ])
 184
 185 # Check if clock_gettime, timer_create, timer_settime, and timer_delete are available in lib rt, and if so,
 186 # add -lrt to LIBS
 187 AC_CHECK_LIB([rt], [clock_gettime, timer_create, timer_settime, timer_delete])
 188
 189 # Babeltrace viewer check
 190 AC_ARG_WITH([babeltrace-bin],
 191         AS_HELP_STRING([--with-babeltrace-bin],
 192         [Location of the babeltrace viewer executable (including the filename)]),
 193         [BABELTRACE_BIN="$withval"],
 194         [BABELTRACE_BIN=''])
 195 AC_SUBST([BABELTRACE_BIN])
 196
 197 # lttv-gui
 198 AC_ARG_WITH([lttv-gui-bin],
 199         AS_HELP_STRING([--with-lttv-gui-bin],
 200    [Location of the lttv GUI viewer executable (including the filename)]),
 201    [LTTV_GUI_BIN="$withval"],
 202    [LTTV_GUI_BIN=''])
 203 AC_SUBST([LTTV_GUI_BIN])
 204
 205 AC_ARG_WITH([consumerd32-bin],
 206         AS_HELP_STRING([--with-consumerd32-bin],
 207         [Location of the 32-bit consumerd executable (including the filename)]),
 208         [CONSUMERD32_BIN="$withval"],
 209         [CONSUMERD32_BIN=''])
 210 AC_SUBST([CONSUMERD32_BIN])
 211
 212 AC_ARG_WITH([consumerd64-bin],
 213         AS_HELP_STRING([--with-consumerd64-bin],
 214         [Location of the 64-bit consumerd executable (including the filename)]),
 215         [CONSUMERD64_BIN="$withval"],
 216         [CONSUMERD64_BIN=''])
 217 AC_SUBST([CONSUMERD64_BIN])
 218
 219 AC_ARG_WITH([consumerd32-libdir],
 220         AS_HELP_STRING([--with-consumerd32-libdir],
 221         [Directory containing the 32-bit consumerd libraries]),
 222         [CONSUMERD32_LIBDIR="$withval"],
 223         [CONSUMERD32_LIBDIR=''])
 224 AC_SUBST([CONSUMERD32_LIBDIR])
 225
 226 AC_ARG_WITH([consumerd64-libdir],
 227         AS_HELP_STRING([--with-consumerd64-libdir],
 228         [Directory containing the 64-bit consumerd libraries]),
 229         [CONSUMERD64_LIBDIR="$withval"],
 230         [CONSUMERD64_LIBDIR=''])
 231 AC_SUBST([CONSUMERD64_LIBDIR])
 232
 233 AC_ARG_WITH([sessiond-bin],
 234         AS_HELP_STRING([--with-sessiond-bin],
 235         [Location of the sessiond executable (including the filename)]),
 236         [SESSIOND_BIN="$withval"],
 237         [SESSIOND_BIN=''])
 238 AC_SUBST([SESSIOND_BIN])
 239
 240 AC_ARG_WITH([lttng-system-rundir],
 241         AS_HELP_STRING([--with-lttng-system-rundir],
 242         [Location of the system directory where the system-wide lttng-sessiond runtime files are kept. The default is "/var/run/lttng".]),
 243         [LTTNG_SYSTEM_RUNDIR="$withval"],
 244         [LTTNG_SYSTEM_RUNDIR="/var/run/lttng"])
 245 AC_SUBST([LTTNG_SYSTEM_RUNDIR])
 246
 247 AC_ARG_ENABLE([test-java-agent-jul],
 248         [AS_HELP_STRING([--enable-test-java-agent-jul],[enable the LTTng UST Java agent JUL tests [default=no]])],
 249         [test_java_agent_jul=$enableval],
 250         [test_java_agent_jul=no]
 251 )
 252
 253 AC_ARG_ENABLE([test-java-agent-log4j],
 254         [AS_HELP_STRING([--enable-test-java-agent-log4j],[enable the LTTng UST Java agent Log4j tests [default=no]])],
 255         [test_java_agent_log4j=$enableval],
 256         [test_java_agent_log4j=no]
 257 )
 258
 259 AC_ARG_ENABLE([test-java-agent-all],
 260         [AS_HELP_STRING([--enable-test-java-agent-all],[enable all the LTTng UST Java agent tests [default=no]])],
 261         [test_java_agent_jul=$enableval
 262          test_java_agent_log4j=$enableval],
 263         [:]
 264 )
 265
 266 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_BIN], "$CONSUMERD32_BIN", [Location of the 32-bit consumerd executable.])
 267 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_BIN], "$CONSUMERD64_BIN", [Location of the 64-bit consumerd executable])
 268 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_LIBDIR], "$CONSUMERD32_LIBDIR", [Search for consumerd 32-bit libraries in this location.])
 269 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_LIBDIR], "$CONSUMERD64_LIBDIR", [Search for consumerd 64-bit libraries in this location.])
 270 AC_DEFINE_UNQUOTED([CONFIG_BABELTRACE_BIN], "$BABELTRACE_BIN", [Location of the babeltrace viewer executable.])
 271 AC_DEFINE_UNQUOTED([CONFIG_LTTV_GUI_BIN], "$LTTV_GUI_BIN", [Location of the lttv GUI viewer executable.])
 272 AC_DEFINE_UNQUOTED([CONFIG_SESSIOND_BIN], "$SESSIOND_BIN", [Location of the sessiond executable.])
 273 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_RUNDIR], ["$LTTNG_SYSTEM_RUNDIR"], [LTTng system runtime directory])
 274
 275 AC_DEFUN([_AC_DEFINE_AND_SUBST], [
 276         AC_DEFINE_UNQUOTED([CONFIG_$1], [$2], [$1])
 277         $1="$2"
 278         AC_SUBST([$1])
 279 ])
 280
 281 AC_DEFUN([_AC_DEFINE_QUOTED_AND_SUBST], [
 282         AC_DEFINE_UNQUOTED([CONFIG_$1], ["$2"], [$1])
 283         $1="$2"
 284         AC_SUBST([$1])
 285 ])
 286
 287 # Default values
 288 m4_define([_DEFAULT_CHANNEL_SUBBUF_SIZE], [16384])
 289 m4_define([_DEFAULT_CHANNEL_SUBBUF_NUM], [4])
 290 m4_define([_DEFAULT_CHANNEL_SWITCH_TIMER], [0])
 291 m4_define([_DEFAULT_CHANNEL_LIVE_TIMER], [0])
 292 m4_define([_DEFAULT_CHANNEL_READ_TIMER], [200000])
 293 m4_define([_DEFAULT_CHANNEL_MONITOR_TIMER], [1000000])
 294 _AC_DEFINE_AND_SUBST([DEFAULT_AGENT_TCP_PORT], [5345])
 295 _AC_DEFINE_AND_SUBST([DEFAULT_APP_SOCKET_RW_TIMEOUT], [5])
 296 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE])
 297 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_COUNT], [0])
 298 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_SIZE], [0])
 299 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 300 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_READ_TIMER], [_DEFAULT_CHANNEL_READ_TIMER])
 301 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 302 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_SIZE], [1048576])
 303 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 304 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
 305 _AC_DEFINE_AND_SUBST([DEFAULT_LTTNG_LIVE_TIMER], [1000000])
 306 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_CACHE_SIZE], [4096])
 307 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_READ_TIMER], [0])
 308 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_NUM], [2])
 309 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_SIZE], [4096])
 310 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 311 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_CONTROL_PORT], [5342])
 312 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_DATA_PORT], [5343])
 313 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_VIEWER_PORT], [5344])
 314 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 315 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_READ_TIMER], [0])
 316 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 317 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE])
 318 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 319 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
 320 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 321 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_READ_TIMER], [0])
 322 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 323 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_SIZE], [524288])
 324 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 325 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
 326 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_AGENT_BIND_ADDRESS], [localhost])
 327 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_CONTROL_BIND_ADDRESS], [0.0.0.0])
 328 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_DATA_BIND_ADDRESS], [0.0.0.0])
 329 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_VIEWER_BIND_ADDRESS], [localhost])
 330
 331 # Command short descriptions
 332 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ADD_CONTEXT], [Add context fields to a channel])
 333 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_CREATE], [Create a tracing session])
 334 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DESTROY], [Tear down tracing sessions])
 335 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_CHANNEL], [Disable tracing channels])
 336 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_EVENT], [Disable event rules])
 337 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_CHANNEL], [Create or enable tracing channels])
 338 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_EVENT], [Create or enable event rules])
 339 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_HELP], [Display help information about a command])
 340 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LIST], [List tracing sessions, domains, channels, and events])
 341 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LOAD], [Load tracing session configurations])
 342 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_REGENERATE], [Manage an LTTng tracing session's data regeneration])
 343 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SAVE], [Save tracing session configurations])
 344 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SET_SESSION], [Set current tracing session])
 345 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SNAPSHOT], [Snapshot buffers of current tracing session])
 346 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_START], [Start tracing])
 347 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STATUS], [Get the status of the current tracing session])
 348 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STOP], [Stop tracing])
 349 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_TRACK], [Track specific system resources])
 350 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_UNTRACK], [Untrack specific system resources])
 351 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VERSION], [Show version information])
 352 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VIEW], [Start trace viewer])
 353
 354 if test "x$prefix" = "xNONE"; then
 355         prefix=$ac_default_prefix
 356 fi
 357 CONFDIR=`eval echo $sysconfdir`
 358 AC_SUBST(CONFDIR)
 359 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_CONFIGDIR],"$CONFDIR", [LTTng system configuration directory.])
 360
 361 AC_DEFINE_DIR([CONFIG_LTTNG_SYSTEM_DATADIR],[datadir], [LTTng system data directory.])
 362
 363 #
 364 # Check for pthread
 365 AC_CHECK_LIB([pthread], [pthread_create], [],
 366         [AC_MSG_ERROR([Cannot find libpthread. Use LDFLAGS=-Ldir to specify its location.])]
 367 )
 368
 369 # Check libpopt
 370 PKG_CHECK_MODULES([POPT], [popt],
 371         [LIBS="$LIBS $POPT_LIBS"],
 372         [
 373                 AC_MSG_WARN([pkg-config was unable to find a valid .pc for libpopt. Set PKG_CONFIG_PATH to specify the pkgconfig configuration file location])
 374                 AC_MSG_WARN([Finding libpopt without pkg-config.])
 375                 AC_CHECK_LIB([popt],
 376                         [poptGetContext],
 377                         [],
 378                         [
 379                                  AC_MSG_ERROR([Cannot find libpopt. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location])
 380                         ]
 381                 )
 382         ]
 383 )
 384
 385 PKG_CHECK_MODULES([libxml2], [libxml-2.0 >= 2.7.6])
 386
 387 # First, check for uuid in system libs
 388 AH_TEMPLATE([LTTNG_HAVE_LIBUUID], [Define if you have libuuid support])
 389 AC_CHECK_FUNCS([uuid_generate],
 390   [
 391     AC_DEFINE([LTTNG_HAVE_LIBUUID], [1])
 392     UUID_LIBS=""
 393   ],
 394   [
 395     # Then, check if the pkg-config module is available, otherwise explicitly check
 396     # for libuuid, or uuid support in the C-library.
 397     PKG_CHECK_MODULES([UUID], [uuid],
 398       [
 399         AC_DEFINE([LTTNG_HAVE_LIBUUID], [1])
 400         dnl PKG_CHECK_MODULES defines UUID_LIBS
 401       ],
 402       [
 403         AC_MSG_WARN([pkg-config was unable to find a valid .pc for libuuid. Set PKG_CONFIG_PATH to specify the pkgconfig configuration file location])
 404         AC_MSG_WARN([Finding libuuid without pkg-config.])
 405         AC_CHECK_LIB([uuid], [uuid_generate],
 406           [
 407             AC_DEFINE([LTTNG_HAVE_LIBUUID], [1])
 408             UUID_LIBS="-luuid"
 409           ],
 410           [
 411             # libuuid not found, check for uuid_create in libc.
 412             AC_CHECK_LIB([c], [uuid_create],
 413               [
 414                 AC_DEFINE([LTTNG_HAVE_LIBUUID], [1])
 415                 UUID_LIBS="-lc"
 416               ],
 417               [
 418                 AC_MSG_FAILURE([Cannot find libuuid uuid_generate nor libc uuid_create. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location])
 419               ]
 420             )
 421           ]
 422         )
 423       ]
 424     )
 425   ]
 426 )
 427 AC_SUBST(UUID_LIBS)
 428
 429 AC_CHECK_FUNC([clock_gettime], [AC_DEFINE_UNQUOTED([LTTNG_HAVE_CLOCK_GETTIME], 1, [Has clock_gettime() support.])])
 430
 431 # URCU library version needed or newer
 432 m4_define([WRONG_LIBURCU_MSG], [Userspace RCU (liburcu) >= 0.9.0 is needed])
 433
 434 # Check liburcu needed function calls
 435 AC_CHECK_DECL([cds_list_add], [],
 436         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/list.h>]])
 437 AC_CHECK_DECL([cds_wfcq_init], [],
 438         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/wfcqueue.h>]])
 439 AC_CHECK_DECL([cds_wfcq_dequeue_blocking], [],
 440         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/wfcqueue.h>]])
 441 AC_CHECK_DECL([futex_async], [],
 442         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/futex.h>]])
 443 AC_CHECK_DECL([rcu_thread_offline], [],
 444         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
 445 AC_CHECK_DECL([rcu_thread_online], [],
 446         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
 447 AC_CHECK_DECL([caa_likely], [],
 448         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
 449 AC_CHECK_LIB([urcu-cds], [_cds_lfht_new], [],
 450         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])])
 451
 452 #Function added in urcu 0.7.0
 453 AC_CHECK_DECL([cmm_smp_mb__before_uatomic_or], [],
 454         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]]
 455 )
 456
 457 #Function added in urcu 0.9.0
 458 AC_CHECK_DECL([urcu_ref_get_unless_zero], [],
 459         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/ref.h>]]
 460 )
 461
 462 # Check for libkmod, it will be auto-neabled if found but won't fail if it's not,
 463 # it can be explicitly disabled with --without-kmod
 464 AH_TEMPLATE([HAVE_KMOD], [Define if you have kmod support])
 465 AC_ARG_WITH([kmod],
 466   [AS_HELP_STRING([--with-kmod], [build with lkmod support @<:@default=check@:>@])],
 467   [],
 468   [with_kmod=check]
 469 )
 470
 471 AS_IF([test "x$with_kmod" != "xno"],
 472   [
 473     AC_CHECK_LIB([kmod], [kmod_module_probe_insert_module],
 474       [
 475         AC_DEFINE([HAVE_KMOD], [1])
 476         KMOD_LIBS="-lkmod"
 477       ],
 478       [
 479         if test "x$with_kmod" != xcheck; then
 480           AC_MSG_FAILURE([Cannot find libkmod. Use [LDFLAGS]=-Ldir and [CPPFLAGS]=-Idir to specify its location.])
 481         else
 482           with_kmod=no
 483         fi
 484       ]
 485     )
 486   ]
 487 )
 488 AC_SUBST(KMOD_LIBS)
 489
 490 # Check for liblttng-ust-ctl, fail if it's not found,
 491 # it can be explicitly disabled with --without-lttng-ust
 492 AH_TEMPLATE([HAVE_LIBLTTNG_UST_CTL], [Define if you have LTTng-UST control support])
 493 AC_ARG_WITH([lttng-ust],
 494   [AS_HELP_STRING([--without-lttng-ust], [build without LTTng-UST (Userspace Tracing) support])],
 495   [],
 496   [with_lttng_ust=yes]
 497 )
 498
 499 AS_IF([test "x$with_lttng_ust" = "xyes"],
 500   [
 501     AC_CHECK_LIB([lttng-ust-ctl], [ustctl_recv_channel_from_consumer],
 502       [
 503         AC_DEFINE([HAVE_LIBLTTNG_UST_CTL], [1])
 504       ],
 505       [
 506         AC_MSG_FAILURE([Cannot find LTTng-UST >= 2.2.x. Use [LDFLAGS]=-Ldir and [CPPFLAGS]=-Idir to specify its location, or specify --without-lttng-ust to build lttng-tools without LTTng-UST support.])
 507       ],
 508       [-lurcu-common -lurcu-bp -lurcu-cds -lrt -ldl]
 509     )
 510   ]
 511 )
 512 AM_CONDITIONAL([HAVE_LIBLTTNG_UST_CTL], [test "x$with_lttng_ust" = "xyes"])
 513
 514
 515
 516 # check for dlopen
 517 AC_CHECK_LIB([dl], [dlopen],
 518   [DL_LIBS="-ldl"],
 519   [
 520     #libdl not found, check for dlopen in libc.
 521     AC_CHECK_LIB([c], [dlopen],
 522       [DL_LIBS="-lc"],
 523       [AC_MSG_FAILURE([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])]
 524     )
 525   ]
 526 )
 527 AC_SUBST(DL_LIBS)
 528
 529 # Check for fmemopen
 530 AC_CHECK_LIB([c], [fmemopen],
 531 [
 532         AC_DEFINE_UNQUOTED([LTTNG_HAVE_FMEMOPEN], 1, [Has fmemopen support.])
 533 ]
 534 )
 535
 536 # Check for open_memstream
 537 AC_CHECK_LIB([c], [open_memstream],
 538 [
 539         AC_DEFINE_UNQUOTED([LTTNG_HAVE_OPEN_MEMSTREAM], 1, [Has open_memstream support.])
 540 ]
 541 )
 542
 543 # check for libpfm
 544 AC_CHECK_LIB([pfm], [pfm_initialize],
 545              [
 546               have_libpfm=yes
 547               ])
 548 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBPFM], [test "x$have_libpfm" = "xyes"])
 549
 550 AC_ARG_ENABLE([git-version],
 551               [AC_HELP_STRING([--disable-git-version],
 552                               [Do not use the git version for the build])],
 553               [have_git_version=$enableval], [have_git_version=yes]
 554 )
 555
 556 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_GIT_SOURCE],
 557         [test "x${have_git_version}" = "xyes"])
 558
 559 # For Python
 560 # SWIG version needed or newer:
 561 swig_version=2.0.0
 562
 563 AC_ARG_ENABLE([python-bindings],
 564               [AC_HELP_STRING([--enable-python-bindings],
 565                               [compile Python bindings])],
 566               [enable_python_binding=$enableval], [enable_python_binding=no])
 567
 568 AM_CONDITIONAL([PYTHON_BINDING], [test "x$enable_python_binding" = xyes])
 569
 570 if test "x$enable_python_binding" = xyes; then
 571   AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ])
 572   AS_IF([test x$enable_shared = xno], [ AC_MSG_ERROR([Python bindings require shared libraries.]) ])
 573   AM_PATH_PYTHON([3.0])
 574
 575   AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config])
 576   AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
 577   AS_IF([test -z "$PYTHON_INCLUDE"], [
 578     AS_IF([test -z "$PYTHON_CONFIG"], [
 579       AC_PATH_PROGS([PYTHON_CONFIG],
 580                     [python$PYTHON_VERSION-config python-config],
 581                     [no],
 582                     [`dirname $PYTHON`])
 583       AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
 584     ])
 585     AC_MSG_CHECKING([python include flags])
 586     PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
 587     AC_MSG_RESULT([$PYTHON_INCLUDE])
 588   ])
 589
 590 else
 591     AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl
 592 [if you want Python bindings.])
 593
 594 fi
 595
 596 # Epoll check. If not present, the build will fallback on poll() API
 597 AX_HAVE_EPOLL(
 598         [AX_CONFIG_FEATURE_ENABLE(epoll)],
 599         [AX_CONFIG_FEATURE_DISABLE(epoll)]
 600 )
 601 AX_CONFIG_FEATURE(
 602         [epoll], [This platform supports epoll(7)],
 603         [HAVE_EPOLL], [This platform supports epoll(7).],
 604         [enable_epoll="yes"], [enable_epoll="no"]
 605 )
 606 AM_CONDITIONAL([COMPAT_EPOLL], [ test "$enable_epoll" = "yes" ])
 607
 608 AM_CONDITIONAL([TEST_JAVA_JUL_AGENT], [test "x$test_java_agent_jul" = "xyes"])
 609 AM_CONDITIONAL([TEST_JAVA_LOG4J_AGENT], [test "x$test_java_agent_log4j" = "xyes"])
 610
 611 if test "x$test_java_agent_jul" = "xyes" || test "x$test_java_agent_log4j" = "xyes"; then
 612         AX_JAVA_OPTIONS
 613         AX_PROG_JAVAC
 614         AX_PROG_JAVA
 615         AX_PROG_JAR
 616
 617         AX_CHECK_CLASSPATH
 618
 619         # Check for Java UST agent common class first
 620         AX_CHECK_CLASS(org.lttng.ust.agent.AbstractLttngAgent)
 621         if test "x$ac_cv_class_org_lttng_ust_agent_AbstractLttngAgent" = "xno"; then
 622                 AC_MSG_ERROR([The UST Java agent common class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-common.jar"])
 623         fi
 624
 625         if test "x$test_java_agent_jul" = "xyes"; then
 626                 # Check for JUL agent class
 627                 AX_CHECK_CLASS(org.lttng.ust.agent.jul.LttngLogHandler)
 628                 if test "x$ac_cv_class_org_lttng_ust_agent_jul_LttngLogHandler" = "xno"; then
 629                         AC_MSG_ERROR([The UST Java agent JUL class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-jul.jar"])
 630                 fi
 631         fi
 632
 633         if test "x$test_java_agent_log4j" = "xyes"; then
 634                 # Check for Log4j agent class
 635                 AX_CHECK_CLASS(org.lttng.ust.agent.log4j.LttngLogAppender)
 636                 if test "x$ac_cv_class_org_lttng_ust_agent_log4j_LttngLogAppender" = "xno"; then
 637                         AC_MSG_ERROR([The UST Java agent Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-log4j.jar"])
 638                 fi
 639
 640                 # Check for Log4j class
 641                 AX_CHECK_CLASS(org.apache.log4j.Logger)
 642                 if test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"; then
 643                         AC_MSG_ERROR([The Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j.jar"])
 644                 fi
 645         fi
 646 fi
 647
 648 # set $IN_GIT_REPO if we're in the Git repository; the `bootstrap` file
 649 # is not distributed in tarballs
 650 AS_IF([test -f "$srcdir/bootstrap"], [in_git_repo=yes], [in_git_repo=no])
 651 AM_CONDITIONAL([IN_GIT_REPO], [test "x$in_git_repo" = "xyes"])
 652
 653 # enable building man pages (user's intention)
 654 AC_ARG_ENABLE(
 655         man-pages,
 656         AS_HELP_STRING(
 657                 [--disable-man-pages],
 658                 [Do not build and install man pages (already built in a distributed tarball)]
 659         ),
 660         [man_pages_opt=$enableval],
 661         [man_pages_opt=yes]
 662 )
 663
 664 # check for asciidoc and xmlto if we enabled building the man pages
 665 have_asciidoc_xmlto=no
 666 warn_prebuilt_man_pages=no
 667
 668 AS_IF([test "x$man_pages_opt" = "xyes"], [
 669         AC_PATH_PROG([ASCIIDOC], [asciidoc], [no])
 670         AC_PATH_PROG([XMLTO], [xmlto], [no])
 671
 672         AS_IF([test "x$ASCIIDOC" = "xno" || test "x$XMLTO" = "xno"], [
 673                 AS_IF([test "x$in_git_repo" = "xyes"], [
 674                         # this is an error because we're in the Git repo, which
 675                         # means the man pages are not already generated for us,
 676                         # thus asciidoc/xmlto are required because we were asked
 677                         # to build the man pages
 678                         AC_MSG_ERROR([
 679 You need asciidoc and xmlto to build the LTTng-tools man pages. Use
 680 --disable-man-pages to disable building the man pages, in which case
 681 they will not be installed.
 682                         ])
 683                 ], [
 684                         # only warn here: since we're in the tarball, the man
 685                         # pages should already be generated at this point, thus
 686                         # asciidoc/xmlto are not strictly required
 687                         warn_prebuilt_man_pages=yes
 688                 ])
 689         ], [
 690                 have_asciidoc_xmlto=yes
 691         ])
 692 ])
 693
 694 # export man page build condition: build the man pages if the user
 695 # asked for it, and if the tools are available
 696 AM_CONDITIONAL([MAN_PAGES_OPT], [test "x$man_pages_opt" != "xno"])
 697 AM_CONDITIONAL([HAVE_ASCIIDOC_XMLTO], [test "x$have_asciidoc_xmlto" = "xyes"])
 698
 699 AC_DEFINE_UNQUOTED([MANPATH], ["`eval eval echo $mandir`"], [Path to man pages.])
 700
 701 # embedded --help message
 702 AC_ARG_ENABLE(
 703         [embedded-help],
 704         AS_HELP_STRING(
 705                 [--enable-embedded-help],
 706                 [Embed the --help messages in the executable files]
 707         ),
 708         [embedded_help=$enableval],
 709         [embedded_help=no]
 710 )
 711 AS_IF([test "x$embedded_help" = "xyes"], [
 712         AS_IF([test "x$man_pages_opt" = "xno"], [
 713                 AC_MSG_ERROR([You need the --enable-man-pages option with the --enable-embedded-help option.])
 714         ])
 715         AC_PATH_PROG([man_prog_path], [man], [no])
 716         AS_IF([test "x$man_prog_path" = "xno"], [
 717                 AC_MSG_ERROR([You need man with the --enable-embedded-help option.])
 718         ])
 719         AC_DEFINE_UNQUOTED([LTTNG_EMBED_HELP], 1, [Embed --help messages.])
 720         AC_SUBST([MANPROG], [$man_prog_path])
 721 ])
 722 AM_CONDITIONAL([EMBED_HELP], [test "x$embedded_help" != "xno"])
 723
 724 # Python agent test
 725 UST_PYTHON_AGENT="lttngust"
 726
 727 AC_ARG_ENABLE(test-python2-agent,
 728         AS_HELP_STRING([--enable-test-python2-agent],
 729                 [enable tests for python2 agent. Python2 interpreter path can be overridden by setting the PYTHON2 environment variable. Default: Autodetect]
 730         ),[:],[test_python2_agent_autodetect=yes]
 731 )
 732
 733 AC_ARG_ENABLE(test-python3-agent,
 734         AS_HELP_STRING([--enable-test-python3-agent],
 735                 [enable tests for python3 agent. Python3 interpreter path can be overridden by setting the PYTHON3 environment variable. Default: Autodetect]
 736         ),[:],[test_python3_agent_autodetect=yes]
 737 )
 738
 739 AC_ARG_ENABLE(test-python-agent-all,
 740         AS_HELP_STRING([--enable-test-python-agent-all],
 741                 [enable test for all python{2/3} agent.]
 742         ),
 743 )
 744
 745 AS_IF([test ! -z "$enable_test_python_agent_all"], [
 746        unset test_python2_agent_autodetect
 747        unset test_python3_agent_autodetect
 748 ])
 749
 750 AS_IF([test "x$enable_test_python_agent_all" = "xyes"], [
 751        enable_test_python2_agent=yes
 752        enable_test_python3_agent=yes
 753 ])
 754
 755 AS_IF([test "x$enable_test_python_agent_all" = "xno"], [
 756        enable_test_python2_agent=no
 757        enable_test_python3_agent=no
 758 ])
 759
 760
 761 AS_IF([test "x$enable_test_python2_agent" = "xyes" -o "x$test_python2_agent_autodetect" = "xyes" ], [
 762         AS_IF([test -z "$PYTHON2"], [
 763                         PYTHON2=python2
 764                 ], [
 765                         AC_MSG_WARN([Using user-defined PYTHON2 ($PYTHON2) for lttng-ust python2 agent check])
 766         ])
 767
 768         AC_PATH_PROG([PYTHON2_BIN],[$PYTHON2])
 769         AS_IF([test -z "$PYTHON2_BIN"], [
 770                 AS_IF([test -z "$test_python2_agent_autodetect"],[
 771                         AC_MSG_ERROR([No python2 interpreter found. PYTHON2 can be set to override default interpreter path])
 772                 ])
 773         ], [
 774                 AC_MSG_CHECKING([for python2 lttng-ust agent])
 775                 AS_IF([$PYTHON2_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
 776                         PYTHON2_AGENT=$PYTHON2_BIN
 777                         AC_MSG_RESULT([yes])
 778                         RUN_PYTHON_AGENT_TEST=yes
 779                 ], [
 780                         AC_MSG_RESULT([no])
 781                         AS_IF([test -z "$test_python2_agent_autodetect"],[
 782                                 AC_MSG_ERROR([No python2 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
 783                         ])
 784                 ])
 785
 786         ])
 787
 788 ])
 789
 790 AS_IF([test "x$enable_test_python3_agent" = "xyes" -o "x$test_python3_agent_autodetect" = "xyes" ], [
 791         AS_IF([test -z "$PYTHON3"], [
 792                 PYTHON3=python3
 793         ], [
 794                 AC_MSG_WARN([Using user-defined PYTHON3 ($PYTHON3) for lttng-ust python3 agent check])
 795         ])
 796
 797         AC_PATH_PROG([PYTHON3_BIN],[$PYTHON3])
 798         AS_IF([test -z "$PYTHON3_BIN"], [
 799                 AS_IF([test -z "$test_python3_agent_autodetect"],[
 800                         AC_MSG_ERROR([No python3 interpreter found. PYTHON3 can be set to override default interpreter path])
 801                 ])
 802         ], [
 803                 AC_MSG_CHECKING([for python3 lttng-ust agent])
 804                 AS_IF([$PYTHON3_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
 805                         PYTHON3_AGENT=$PYTHON3_BIN
 806                         AC_MSG_RESULT([yes])
 807                         RUN_PYTHON_AGENT_TEST=yes
 808                 ], [
 809                         AC_MSG_RESULT([no])
 810                         AS_IF([test -z "$test_python3_agent_autodetect"],[
 811                                 AC_MSG_ERROR([No python3 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
 812                         ])
 813                 ])
 814
 815         ])
 816 ])
 817 AC_SUBST([RUN_PYTHON_AGENT_TEST])
 818 AC_SUBST([PYTHON2_AGENT])
 819 AC_SUBST([PYTHON3_AGENT])
 820
 821 # Arguments for binaries build exclusion
 822 AC_ARG_ENABLE([bin-lttng], AS_HELP_STRING([--disable-bin-lttng],[Disable the build of lttng binaries]))
 823 AC_ARG_ENABLE([bin-lttng-consumerd], AS_HELP_STRING([--disable-bin-lttng-consumerd],
 824               [Disable the build of lttng-consumerd binaries]))
 825 AC_ARG_ENABLE([bin-lttng-crash], AS_HELP_STRING([--disable-bin-lttng-crash],[Disable the build of lttng-crash binaries]))
 826 AC_ARG_ENABLE([bin-lttng-relayd], AS_HELP_STRING([--disable-bin-lttng-relayd],
 827               [Disable the build of lttng-relayd binaries]))
 828 AC_ARG_ENABLE([bin-lttng-sessiond], AS_HELP_STRING([--disable-bin-lttng-sessiond],
 829               [Disable the build of lttng-sessiond binaries]))
 830 AC_ARG_ENABLE([extras], AS_HELP_STRING([--disable-extras],
 831               [Disable the build of the extra components]))
 832
 833
 834 # Always build libconfig since it a dependency of libcommon
 835 build_lib_config=yes
 836
 837 build_lib_compat=no
 838 build_lib_consumer=no
 839 build_lib_hashtable=no
 840 build_lib_health=no
 841 build_lib_index=no
 842 build_lib_kernel_consumer=no
 843 build_lib_kernel_ctl=no
 844 build_lib_lttng_ctl=no
 845 build_lib_relayd=no
 846 build_lib_sessiond_comm=no
 847 build_lib_testpoint=no
 848 build_lib_ust_consumer=no
 849
 850 # There is an overlap for enabled dependencies, but this makes everything
 851 # simpler. libcommon and libconfig are always compiled so they are not repeated
 852 # here.
 853
 854 # Enable binary dependencies.
 855 AS_IF([test x$enable_bin_lttng != xno],
 856       [
 857        build_lib_lttng_ctl=yes
 858       ]
 859 )
 860
 861 AS_IF([test x$enable_bin_lttng_consumerd != xno],
 862       [
 863        build_lib_consumer=yes
 864        build_lib_sessiond_comm=yes
 865        build_lib_index=yes
 866        build_lib_health=yes
 867        build_lib_testpoint=yes
 868       ]
 869 )
 870
 871 AS_IF([test x$enable_bin_lttng_crash != xno],
 872       # Do nothing since libconfig and libcommon are built by default.
 873       []
 874 )
 875
 876 AS_IF([test x$enable_bin_lttng_relayd != xno],
 877       [
 878        build_lib_lttng_ctl=yes
 879        build_lib_sessiond_comm=yes
 880        build_lib_hashtable=yes
 881        build_lib_compat=yes
 882        build_lib_index=yes
 883        build_lib_health=yes
 884        build_lib_testpoint=yes
 885       ]
 886 )
 887 AS_IF([test x$enable_bin_lttng_sessiond != xno],
 888       [
 889        build_lib_lttng_ctl=yes
 890        build_lib_sessiond_comm=yes
 891        build_lib_kernel_ctl=yes
 892        build_lib_hashtable=yes
 893        build_lib_compat=yes
 894        build_lib_relayd=yes
 895        build_lib_testpoint=yes
 896        build_lib_health=yes
 897        build_lib_health=yes
 898       ]
 899 )
 900
 901 # Libraries dependencies enabling
 902 AS_IF([test x$build_lib_lttng_ctl = xyes],
 903       [
 904        build_lib_sessiond_comm=yes
 905        build_lib_hashtable=yes
 906       ]
 907 )
 908
 909 AS_IF([test x$build_lib_consumer = xyes],
 910       [
 911        build_lib_sessiond_comm=yes
 912        build_lib_kernel_consumer=yes
 913        build_lib_hashtable=yes
 914        build_lib_compat=yes
 915        build_lib_relayd=yes
 916        AS_IF([test "x$with_lttng_ust" = "xyes"], [build_lib_ust_consumer=yes])
 917       ]
 918 )
 919
 920 AS_IF([test x$build_lib_kernel_consumer = xyes],
 921       [
 922        build_lib_kernel_ctl=yes
 923        build_lib_relayd=yes
 924       ]
 925 )
 926
 927 AS_IF([test x$build_lib_relayd = xyes],
 928       [
 929        build_lib_sessiond_comm=yes
 930       ]
 931 )
 932
 933
 934 # Export binaries build conditions.
 935 AM_CONDITIONAL([BUILD_BIN_LTTNG], [test x$enable_bin_lttng != xno])
 936 AM_CONDITIONAL([BUILD_BIN_LTTNG_CONSUMERD], [test x$enable_bin_lttng_consumerd != xno])
 937 AM_CONDITIONAL([BUILD_BIN_LTTNG_CRASH], [test x$enable_bin_lttng_crash != xno])
 938 AM_CONDITIONAL([BUILD_BIN_LTTNG_RELAYD], [test x$enable_bin_lttng_relayd != xno])
 939 AM_CONDITIONAL([BUILD_BIN_LTTNG_SESSIOND], [test x$enable_bin_lttng_sessiond != xno])
 940
 941 # Export the tests and extras build conditions.
 942 AS_IF([\
 943 test "x$enable_bin_lttng" != "xno" && \
 944 test "x$enable_bin_lttng_consumerd" != "xno" && \
 945 test "x$enable_bin_lttng_crash" != "xno" && \
 946 test "x$enable_bin_lttng_relayd" != "xno" && \
 947 test "x$enable_bin_lttng_sessiond" != "xno"],
 948 [build_tests=yes],
 949 [build_tests=no]
 950 )
 951
 952 AM_CONDITIONAL([BUILD_TESTS], [test x$build_tests = xyes])
 953 AM_CONDITIONAL([BUILD_EXTRAS], [test x$enable_extras != xno])
 954
 955 # Export libraries build conditions.
 956 AM_CONDITIONAL([BUILD_LIB_COMPAT], [test x$build_lib_compat = xyes])
 957 AM_CONDITIONAL([BUILD_LIB_CONFIG], [test x$build_lib_config = xyes])
 958 AM_CONDITIONAL([BUILD_LIB_CONSUMER], [test x$build_lib_consumer = xyes])
 959 AM_CONDITIONAL([BUILD_LIB_HASHTABLE], [test x$build_lib_hashtable = xyes])
 960 AM_CONDITIONAL([BUILD_LIB_HEALTH], [test x$build_lib_health = xyes])
 961 AM_CONDITIONAL([BUILD_LIB_INDEX], [test x$build_lib_index = xyes])
 962 AM_CONDITIONAL([BUILD_LIB_KERNEL_CONSUMER], [test x$build_lib_kernel_consumer = xyes])
 963 AM_CONDITIONAL([BUILD_LIB_KERNEL_CTL], [test x$build_lib_kernel_ctl = xyes])
 964 AM_CONDITIONAL([BUILD_LIB_LTTNG_CTL], [test x$build_lib_lttng_ctl = xyes])
 965 AM_CONDITIONAL([BUILD_LIB_RELAYD], [test x$build_lib_relayd = xyes])
 966 AM_CONDITIONAL([BUILD_LIB_SESSIOND_COMM], [test x$build_lib_sessiond_comm = xyes])
 967 AM_CONDITIONAL([BUILD_LIB_TESTPOINT], [test x$build_lib_testpoint = xyes])
 968 AM_CONDITIONAL([BUILD_LIB_UST_CONSUMER], [test x$build_lib_ust_consumer = xyes])
 969
 970 AM_CFLAGS="-Wall -fno-strict-aliasing $PTHREAD_CFLAGS"
 971 AC_SUBST(AM_CFLAGS)
 972
 973 AM_CPPFLAGS="-I\$(top_srcdir)/include -I\$(top_builddir)/include -I\$(top_srcdir)/src -include config.h $AM_CPPFLAGS"
 974 AC_SUBST(AM_CPPFLAGS)
 975
 976 lttngincludedir="${includedir}/lttng"
 977 AC_SUBST(lttngincludedir)
 978
 979 lttngactionincludedir="${includedir}/lttng/action"
 980 AC_SUBST(lttngactionincludedir)
 981
 982 lttngconditionincludedir="${includedir}/lttng/condition"
 983 AC_SUBST(lttngconditionincludedir)
 984
 985 lttngnotificationincludedir="${includedir}/lttng/notification"
 986 AC_SUBST(lttngnotificationincludedir)
 987
 988 lttngtriggerincludedir="${includedir}/lttng/trigger"
 989 AC_SUBST(lttngtriggerincludedir)
 990
 991 lttnglibexecdir="${libdir}/lttng/libexec"
 992 AC_SUBST(lttnglibexecdir)
 993
 994 AC_CONFIG_FILES([
 995         Makefile
 996         doc/Makefile
 997         doc/man/Makefile
 998         doc/man/asciidoc-attrs.conf
 999         include/Makefile
1000         extras/Makefile
1001         extras/bindings/Makefile
1002         extras/bindings/swig/Makefile
1003         extras/bindings/swig/python/Makefile
1004         extras/core-handler/Makefile
1005         src/Makefile
1006         src/common/Makefile
1007         src/common/kernel-ctl/Makefile
1008         src/common/kernel-consumer/Makefile
1009         src/common/consumer/Makefile
1010         src/common/ust-consumer/Makefile
1011         src/common/hashtable/Makefile
1012         src/common/sessiond-comm/Makefile
1013         src/common/compat/Makefile
1014         src/common/relayd/Makefile
1015         src/common/testpoint/Makefile
1016         src/common/index/Makefile
1017         src/common/health/Makefile
1018         src/common/config/Makefile
1019         src/common/string-utils/Makefile
1020         src/lib/Makefile
1021         src/lib/lttng-ctl/Makefile
1022         src/lib/lttng-ctl/filter/Makefile
1023         src/lib/lttng-ctl/lttng-ctl.pc
1024         src/bin/Makefile
1025         src/bin/lttng-consumerd/Makefile
1026         src/bin/lttng-sessiond/Makefile
1027         src/bin/lttng-relayd/Makefile
1028         src/bin/lttng/Makefile
1029         src/bin/lttng-crash/Makefile
1030         tests/Makefile
1031         tests/destructive/Makefile
1032         tests/regression/Makefile
1033         tests/regression/kernel/Makefile
1034         tests/regression/tools/Makefile
1035         tests/regression/tools/streaming/Makefile
1036         tests/regression/tools/filtering/Makefile
1037         tests/regression/tools/health/Makefile
1038         tests/regression/tools/tracefile-limits/Makefile
1039         tests/regression/tools/snapshots/Makefile
1040         tests/regression/tools/live/Makefile
1041         tests/regression/tools/exclusion/Makefile
1042         tests/regression/tools/save-load/Makefile
1043         tests/regression/tools/save-load/configuration/Makefile
1044         tests/regression/tools/mi/Makefile
1045         tests/regression/tools/wildcard/Makefile
1046         tests/regression/tools/crash/Makefile
1047         tests/regression/tools/regen-metadata/Makefile
1048         tests/regression/tools/regen-statedump/Makefile
1049         tests/regression/tools/notification/Makefile
1050         tests/regression/ust/Makefile
1051         tests/regression/ust/nprocesses/Makefile
1052         tests/regression/ust/high-throughput/Makefile
1053         tests/regression/ust/low-throughput/Makefile
1054         tests/regression/ust/before-after/Makefile
1055         tests/regression/ust/buffers-pid/Makefile
1056         tests/regression/ust/periodical-metadata-flush/Makefile
1057         tests/regression/ust/multi-session/Makefile
1058         tests/regression/ust/overlap/Makefile
1059         tests/regression/ust/overlap/demo/Makefile
1060         tests/regression/ust/linking/Makefile
1061         tests/regression/ust/daemon/Makefile
1062         tests/regression/ust/exit-fast/Makefile
1063         tests/regression/ust/fork/Makefile
1064         tests/regression/ust/libc-wrapper/Makefile
1065         tests/regression/ust/baddr-statedump/Makefile
1066         tests/regression/ust/ust-dl/Makefile
1067         tests/regression/ust/java-jul/Makefile
1068         tests/regression/ust/java-log4j/Makefile
1069         tests/regression/ust/python-logging/Makefile
1070         tests/regression/ust/getcpu-override/Makefile
1071         tests/regression/ust/clock-override/Makefile
1072         tests/regression/ust/type-declarations/Makefile
1073         tests/regression/ust/rotation-destroy-flush/Makefile
1074         tests/regression/ust/blocking/Makefile
1075         tests/stress/Makefile
1076         tests/unit/Makefile
1077         tests/unit/ini_config/Makefile
1078         tests/perf/Makefile
1079         tests/utils/Makefile
1080         tests/utils/tap/Makefile
1081         tests/utils/testapp/Makefile
1082         tests/utils/testapp/gen-ust-events/Makefile
1083         tests/utils/testapp/gen-ust-nevents/Makefile
1084         tests/utils/testapp/gen-ust-nevents-str/Makefile
1085         tests/utils/testapp/gen-ust-tracef/Makefile
1086 ])
1087
1088 # Inject variable into python test script.
1089 AC_CONFIG_FILES([tests/regression/ust/python-logging/test_python_logging],[chmod +x tests/regression/ust/python-logging/test_python_logging])
1090 # Inject LTTNG_TOOLS_BUILD_WITH_LIBPFM variable in test script.
1091 AC_CONFIG_FILES([tests/perf/test_perf_raw],[chmod +x tests/perf/test_perf_raw])
1092
1093 AC_OUTPUT
1094
1095 #
1096 # Mini-report on what will be built.
1097 #
1098
1099 PPRINT_INIT
1100 PPRINT_SET_INDENT(1)
1101 PPRINT_SET_TS(38)
1102
1103 AS_ECHO
1104 AS_ECHO("${PPRINT_COLOR_BLDBLU}LTTng-tools $PACKAGE_VERSION \"$version_name\"$PPRINT_COLOR_RST")
1105 AS_ECHO
1106
1107 AS_IF([test -n "$report_fold"], [
1108         AS_ECHO("`AS_ECHO("$version_description") | $report_fold -s`")
1109 ], [
1110         AS_ECHO("$version_description")
1111 ])
1112
1113 AS_ECHO
1114 PPRINT_SUBTITLE([Features])
1115
1116 # Target architecture we're building for.
1117 target_arch=$host_cpu
1118 [
1119 for f in $CFLAGS; do
1120         if test $f = "-m32"; then
1121                         target_arch="32-bit"
1122         elif test $f = "-m64"; then
1123                         target_arch="64-bit"
1124         fi
1125 done
1126 ]
1127 PPRINT_PROP_STRING([Target architecture], $target_arch)
1128
1129 # kmod enabled/disabled
1130 test "x$with_kmod" != "xno" && value=1 || value=0
1131 PPRINT_PROP_BOOL([libkmod support], $value)
1132
1133 # LTTng-UST enabled/disabled
1134 test "x$with_lttng_ust" = "xyes" && value=1 || value=0
1135 PPRINT_PROP_BOOL([LTTng-UST support], $value)
1136
1137 AS_ECHO
1138 PPRINT_SUBTITLE([Binaries])
1139
1140 # List binaries to be built
1141 test x$enable_bin_lttng != xno && value=1 || value=0
1142 PPRINT_PROP_BOOL([lttng], $value)
1143
1144 test x$enable_bin_lttng_consumerd != xno && value=1 || value=0
1145 PPRINT_PROP_BOOL([lttng-consumerd], $value)
1146
1147 test x$enable_bin_lttng_crash != xno && value=1 || value=0
1148 PPRINT_PROP_BOOL([lttng-crash], $value)
1149
1150 test x$enable_bin_lttng_relayd != xno && value=1 || value=0
1151 PPRINT_PROP_BOOL([lttng-relayd], $value)
1152
1153 test x$enable_bin_lttng_sessiond != xno && value=1 || value=0
1154 PPRINT_PROP_BOOL([lttng-sessiond], $value)
1155
1156 # Extras
1157 test x$enable_extras != xno && value=1 || value=0
1158 AS_ECHO
1159 PPRINT_SET_INDENT(0)
1160 PPRINT_PROP_BOOL([Extras], $value, $PPRINT_COLOR_SUBTITLE)
1161 PPRINT_SET_INDENT(1)
1162
1163 AS_ECHO
1164 PPRINT_SUBTITLE([Tests])
1165
1166 # Print clear message that tests won't be built
1167 AS_IF([test "x$build_tests" = "xno"],[
1168         PPRINT_WARN([Tests won't be built since some binaries were disabled])
1169 ])
1170
1171 # LTTng UST Java agent JUL tests enabled/disabled
1172 test "x$test_java_agent_jul" = "xyes" && value=1 || value=0
1173 PPRINT_PROP_BOOL([LTTng-UST Java agent JUL tests], $value)
1174
1175 # LTTng UST Java agent Log4j tests enabled/disabled
1176 test "x$test_java_agent_log4j" = "xyes" && value=1 || value=0
1177 PPRINT_PROP_BOOL([LTTng-UST Java agent Log4j tests], $value)
1178
1179 test ! -z "$PYTHON2_AGENT" && value=1 || value=0
1180 PPRINT_PROP_BOOL([LTTng-UST Python2 agent tests], $value)
1181
1182 test ! -z "$PYTHON3_AGENT" && value=1 || value=0
1183 PPRINT_PROP_BOOL([LTTng-UST Python3 agent tests], $value)
1184
1185 #Python binding enabled/disabled
1186 test "x$enable_python_binding" = xyes && value=1 || value=0
1187 AS_ECHO
1188 PPRINT_SET_INDENT(0)
1189 PPRINT_PROP_BOOL([Python binding], $value, $PPRINT_COLOR_SUBTITLE)
1190
1191 # man pages build enabled/disabled
1192 m4_pushdef([build_man_pages_msg], [Build and install man pages])
1193
1194 AS_IF([test "x$man_pages_opt" != "xno"], [
1195         AS_IF([test "x$in_git_repo" = "xyes"], [
1196                 PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
1197         ], [
1198                 AS_IF([test "x$have_asciidoc_xmlto" = "xyes"], [
1199                         PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
1200                 ], [
1201                         PPRINT_PROP_STRING([build_man_pages_msg],
1202                                 [${PPRINT_COLOR_BLDGRN}yes (already built)],
1203                                 $PPRINT_COLOR_SUBTITLE)
1204                 ])
1205         ])
1206 ], [
1207         PPRINT_PROP_BOOL([build_man_pages_msg], 0, $PPRINT_COLOR_SUBTITLE)
1208 ])
1209
1210 m4_popdef([build_man_pages_msg])
1211
1212 test "x$embedded_help" = xyes && value=1 || value=0
1213 PPRINT_PROP_BOOL([Embed --help messages], $value, $PPRINT_COLOR_SUBTITLE)
1214
1215 PPRINT_SET_INDENT(1)
1216
1217 report_bindir="`eval eval echo $bindir`"
1218 report_libdir="`eval eval echo $libdir`"
1219
1220 # Print the bindir and libdir this `make install' will install into.
1221 AS_ECHO
1222 PPRINT_SUBTITLE([Install directories])
1223 PPRINT_PROP_STRING([Binaries], [$report_bindir])
1224 PPRINT_PROP_STRING([Libraries], [$report_libdir])
1225
1226 AS_ECHO
1227 PPRINT_SUBTITLE([Search directories])
1228
1229 # If we build the sessiond, print the paths it will use
1230 AS_IF([test "$SESSIOND_BIN" = ""],[
1231         path="$report_bindir/lttng-sessiond"
1232 ],[
1233         path="$SESSIOND_BIN"
1234 ])
1235 PPRINT_PROP_STRING([lttng-sessiond executable], [$path])
1236
1237 AS_IF([test "$CONSUMERD32_BIN" = ""],[
1238         path="`eval eval echo $lttnglibexecdir`/lttng-consumerd"
1239 ],[
1240         path="$CONSUMERD32_BIN"
1241 ])
1242 PPRINT_PROP_STRING([32-bit lttng-consumerd executable], [$path])
1243
1244 AS_IF([test "$CONSUMERD32_LIBDIR" = ""],[
1245         path="`eval eval echo $libdir`"
1246 ],[
1247         path="$CONSUMERD32_LIBDIR"
1248 ])
1249 PPRINT_PROP_STRING([32-bit consumer libraries], [$path])
1250
1251 AS_IF([test "$CONSUMERD64_BIN" = ""],[
1252         path="`eval eval echo $lttnglibexecdir`/lttng-consumerd"
1253 ],[
1254         path="$CONSUMERD64_BIN"
1255 ])
1256 PPRINT_PROP_STRING([64-bit lttng-consumerd executable], [$path])
1257
1258 AS_IF([test "$CONSUMERD64_LIBDIR" = ""],[
1259         path="`eval eval echo $libdir`"
1260 ],[
1261         path="$CONSUMERD64_LIBDIR"
1262 ])
1263 PPRINT_PROP_STRING([64-bit consumer libraries], [$path])
1264 PPRINT_SET_INDENT(0)
1265
1266 AS_IF([test "x$warn_prebuilt_man_pages" = "xyes" ], [
1267         AS_ECHO
1268         PPRINT_WARN([You need asciidoc and xmlto to build the LTTng-tools man pages.
1269
1270 Note that the man pages are already built in this distribution tarball,
1271 therefore asciidoc and xmlto are only needed if you intend to modify
1272 their sources.
1273
1274 Also note that the installed man pages will contain the project's
1275 default command-line option and environment variable values.
1276
1277 Use --disable-man-pages to completely disable building and installing
1278 the man pages.])
1279 ])