fb2a31f9bdf7bffc360d4862061e3790283a0047
[lttng-tools.git] / configure.ac
1 AC_PREREQ([2.64])
2 AC_INIT([lttng-tools],[2.11.0-pre],[jeremie.galarneau@efficios.com],[],[https://lttng.org])
3
4 AC_CONFIG_HEADERS([include/config.h])
5 AC_CONFIG_AUX_DIR([config])
6 AC_CONFIG_MACRO_DIR([m4])
7
8 AC_CANONICAL_TARGET
9 AC_CANONICAL_HOST
10
11 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip tar-pax nostdinc])
12 AM_MAINTAINER_MODE([enable])
13
14 # Enable silent rules if available (Introduced in AM 1.11)
15 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
16
17 AC_REQUIRE_AUX_FILE([tap-driver.sh])
18
19 # Checks for C compiler
20 AC_USE_SYSTEM_EXTENSIONS
21 AC_SYS_LARGEFILE
22 AC_PROG_CC
23 AC_PROG_CC_STDC
24
25 # Checks for programs.
26 AC_PROG_GREP
27 AC_PROG_MAKE_SET
28 AC_PROG_SED
29 AC_PATH_PROG([report_fold], [fold])
30 LT_INIT
31
32 # Check for objcopy, required by the base address statedump and dynamic linker tests
33 AC_CHECK_TOOL([OBJCOPY], [objcopy], [no])
34 AS_IF([test "x$OBJCOPY" = "xno"],
35 [AC_MSG_WARN([Cannot find objcopy. The base address statedump and dynamic linker tests will be disabled. Install the binutils package to remediate this.])]
36 )
37 AM_CONDITIONAL([HAVE_OBJCOPY], [test "x$OBJCOPY" != xno])
38
39 # check for pgrep
40 AC_PATH_PROG([PGREP], [pgrep], [no])
41 AM_CONDITIONAL([HAVE_PGREP], [test "x$PGREP" != "xno"])
42
43 # set $IN_GIT_REPO if we're in the Git repository; the `bootstrap` file
44 # is not distributed in tarballs
45 AS_IF([test -f "$srcdir/bootstrap"], [in_git_repo=yes], [in_git_repo=no])
46 AM_CONDITIONAL([IN_GIT_REPO], [test "x$in_git_repo" = "xyes"])
47
48 # check for bison
49 AC_PROG_YACC
50 BISON=$YACC
51 AX_PROG_BISON_VERSION([2.4], [have_bison=yes])
52
53 AS_IF([test "x$have_bison" != "xyes"], [
54 AS_IF([test "x$in_git_repo" = "xyes"], [
55 AC_MSG_FAILURE([
56 Bison >= 2.4 is required when building from the Git repository. You can
57 set the YACC variable to override automatic detection.
58 ])
59 ], [
60 AC_MSG_WARN([
61 Missing Bison >= 2.4. Note that the parser files are already built in
62 this distribution tarball, so Bison is only needed if you intend to
63 modify their sources. You can set the YACC variable to override automatic
64 detection.
65 ])
66 ])
67 ])
68 AM_CONDITIONAL([HAVE_BISON], [test "x$have_bison" = "xyes"])
69
70 # check for flex
71 AC_PROG_LEX
72 FLEX=$LEX
73 AX_PROG_FLEX_VERSION([2.5.35], [have_flex=yes])
74
75 AS_IF([test "x$have_flex" != "xyes"], [
76 AS_IF([test "x$in_git_repo" = "xyes"], [
77 AC_MSG_FAILURE([
78 Flex >= 2.5.35 is required when building from the Git repository. You can
79 set the LEX variable to override automatic detection.
80 ])
81 ], [
82 AC_MSG_WARN([
83 Missing Flex >= 2.5.35. Note that the lexer files are already built in
84 this distribution tarball, so Flex is only needed if you intend to
85 modify their sources. You can set the LEX variable to override automatic
86 detection.
87 ])
88 ])
89 ])
90 AM_CONDITIONAL([HAVE_FLEX], [test "x$have_flex" = "xyes"])
91
92
93 # Checks for typedefs, structures, and compiler characteristics.
94 AC_C_INLINE
95 AC_TYPE_INT32_T
96 AC_TYPE_INT64_T
97 AC_TYPE_MODE_T
98 AC_TYPE_OFF_T
99 AC_TYPE_PID_T
100 AC_TYPE_SIZE_T
101 AC_TYPE_SSIZE_T
102 AC_TYPE_UID_T
103 AC_TYPE_UINT16_T
104 AC_TYPE_UINT32_T
105 AC_TYPE_UINT64_T
106 AC_TYPE_UINT8_T
107
108 AX_C___ATTRIBUTE__
109 AS_IF([test "x$ax_cv___attribute__" = "xyes"],
110 [:],
111 [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
112
113 AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])
114
115 # Check if linker has the -no-pie option.
116 AX_CHECK_LINK_FLAG([-no-pie], [linker_have_no_pie_option=yes])
117 AM_CONDITIONAL([LINKER_HAVE_NO_PIE_OPTION], [test "x$linker_have_no_pie_option" = "xyes"])
118
119 AX_LIB_SOCKET_NSL
120
121 LT_NO_UNDEFINED=""
122 AS_CASE([$host_os],
123 [cygwin*],
124 [
125 LT_NO_UNDEFINED="-no-undefined"
126 ],
127 [cygwin*|darwin*|mingw*|solaris*],
128 [
129 # On platforms where we only support the relayd, disable the other binaries by default
130 AS_IF([test "x$enable_bin_lttng" = "x" ], [enable_bin_lttng=no])
131 AS_IF([test "x$enable_bin_lttng_consumerd" = "x" ], [enable_bin_lttng_consumerd=no])
132 AS_IF([test "x$enable_bin_lttng_crash" = "x" ], [enable_bin_lttng_crash=no])
133 AS_IF([test "x$enable_bin_lttng_sessiond" = "x" ], [enable_bin_lttng_sessiond=no])
134 AS_IF([test "x$enable_extras" = "x" ], [enable_extras=no])
135 AS_IF([test "x$with_lttng_ust" = "x" ], [with_lttng_ust=no])
136 ]
137 )
138
139 AC_SUBST(LT_NO_UNDEFINED)
140
141 # Compute minor/major/patchlevel version numbers
142 major_version=$(echo AC_PACKAGE_VERSION | $SED 's/^\([[0-9]]\)*\.[[0-9]]*\.[[0-9]]*.*$/\1/')
143 minor_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.\([[0-9]]*\)\.[[0-9]]*.*$/\1/')
144 patchlevel_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\).*$/\1/')
145
146 AC_SUBST([MAJOR_VERSION], [$major_version])
147 AC_SUBST([MINOR_VERSION], [$minor_version])
148 AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version])
149 AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [LTTng-Tools major version number])
150 AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [LTTng-Tools minor version number])
151 AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [LTTng-Tools patchlevel version number])
152
153 version_name="Codename TBD"
154 version_description='Description TBD'
155 version_description_c=$(echo $version_description | $SED 's/"/\\"/g')
156
157 AC_DEFINE_UNQUOTED([VERSION_NAME], ["$version_name"], "")
158 AC_DEFINE_UNQUOTED([VERSION_DESCRIPTION], ["$version_description_c"], "")
159
160 # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
161 AC_ARG_ENABLE(libtool-linkdep-fixup,
162 AS_HELP_STRING([--disable-libtool-linkdep-fixup],
163 [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)]),
164 libtool_fixup=$enableval,
165 libtool_fixup=yes)
166
167 AS_IF([test "x$libtool_fixup" = "xyes"],
168 [
169 libtool_m4="$srcdir/m4/libtool.m4"
170 libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
171 AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
172 libtool_flag_pattern_count=$($GREP -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
173 AS_IF([test $libtool_flag_pattern_count -ne 0],
174 [
175 AC_MSG_RESULT([$libtool_flag_pattern_count])
176 AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
177 $SED -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
178 ],
179 [
180 AC_MSG_RESULT([none])
181 ])
182 ])
183
184 AM_CONDITIONAL([NO_SHARED], [test x$enable_shared = xno])
185
186 AC_CHECK_HEADERS([ \
187 sys/types.h unistd.h fcntl.h string.h pthread.h limits.h \
188 signal.h stdlib.h sys/un.h sys/socket.h stdlib.h stdio.h \
189 getopt.h sys/ipc.h sys/shm.h popt.h grp.h arpa/inet.h \
190 netdb.h netinet/in.h paths.h stddef.h sys/file.h sys/ioctl.h \
191 sys/mount.h sys/param.h sys/time.h
192 ])
193
194 # Basic functions check
195 AC_CHECK_FUNCS([ \
196 atexit bzero clock_gettime dup2 fdatasync fls ftruncate \
197 gethostbyname gethostname getpagesize localtime_r memchr memrchr memset \
198 mkdir munmap putenv realpath rmdir socket strchr strcspn strdup \
199 strncasecmp strndup strnlen strpbrk strrchr strstr strtol strtoul \
200 strtoull dirfd gethostbyname2 getipnodebyname epoll_create1 \
201 sched_getcpu sysconf sync_file_range
202 ])
203
204 # Check if clock_gettime, timer_create, timer_settime, and timer_delete are available in lib rt, and if so,
205 # add -lrt to LIBS
206 AC_CHECK_LIB([rt], [clock_gettime, timer_create, timer_settime, timer_delete])
207
208 # Checks for dl.
209 AC_CHECK_LIB([dl], [dlopen], [
210 have_libdl=yes
211 libdl_name=dl
212 ], [
213 # libdl not found, check for dlopen in libc.
214 AC_CHECK_LIB([c], [dlopen], [
215 have_libc_dl=yes
216 libdl_name=c
217 ], [
218 AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
219 ])
220 ])
221
222 # Check if libdl has dlmopen support.
223 AH_TEMPLATE([HAVE_DLMOPEN], ["Define to 1 if dlmopen is available."])
224 AC_CHECK_LIB([$libdl_name], [dlmopen], [
225 AC_DEFINE([HAVE_DLMOPEN], [1])
226 HAVE_DLMOPEN=1
227 ], [
228 HAVE_DLMOPEN=0
229 ])
230 AC_SUBST(HAVE_DLMOPEN)
231
232 # Babeltrace viewer check
233 AC_ARG_WITH([babeltrace-bin],
234 AS_HELP_STRING([--with-babeltrace-bin],
235 [Location of the babeltrace viewer executable (including the filename)]),
236 [BABELTRACE_BIN="$withval"],
237 [BABELTRACE_BIN=''])
238 AC_SUBST([BABELTRACE_BIN])
239
240 # lttv-gui
241 AC_ARG_WITH([lttv-gui-bin],
242 AS_HELP_STRING([--with-lttv-gui-bin],
243 [Location of the lttv GUI viewer executable (including the filename)]),
244 [LTTV_GUI_BIN="$withval"],
245 [LTTV_GUI_BIN=''])
246 AC_SUBST([LTTV_GUI_BIN])
247
248 AC_ARG_WITH([consumerd32-bin],
249 AS_HELP_STRING([--with-consumerd32-bin],
250 [Location of the 32-bit consumerd executable (including the filename)]),
251 [CONSUMERD32_BIN="$withval"],
252 [CONSUMERD32_BIN=''])
253 AC_SUBST([CONSUMERD32_BIN])
254
255 AC_ARG_WITH([consumerd64-bin],
256 AS_HELP_STRING([--with-consumerd64-bin],
257 [Location of the 64-bit consumerd executable (including the filename)]),
258 [CONSUMERD64_BIN="$withval"],
259 [CONSUMERD64_BIN=''])
260 AC_SUBST([CONSUMERD64_BIN])
261
262 AC_ARG_WITH([consumerd32-libdir],
263 AS_HELP_STRING([--with-consumerd32-libdir],
264 [Directory containing the 32-bit consumerd libraries]),
265 [CONSUMERD32_LIBDIR="$withval"],
266 [CONSUMERD32_LIBDIR=''])
267 AC_SUBST([CONSUMERD32_LIBDIR])
268
269 AC_ARG_WITH([consumerd64-libdir],
270 AS_HELP_STRING([--with-consumerd64-libdir],
271 [Directory containing the 64-bit consumerd libraries]),
272 [CONSUMERD64_LIBDIR="$withval"],
273 [CONSUMERD64_LIBDIR=''])
274 AC_SUBST([CONSUMERD64_LIBDIR])
275
276 AC_ARG_WITH([sessiond-bin],
277 AS_HELP_STRING([--with-sessiond-bin],
278 [Location of the sessiond executable (including the filename)]),
279 [SESSIOND_BIN="$withval"],
280 [SESSIOND_BIN=''])
281 AC_SUBST([SESSIOND_BIN])
282
283 AC_ARG_WITH([lttng-system-rundir],
284 AS_HELP_STRING([--with-lttng-system-rundir],
285 [Location of the system directory where the system-wide lttng-sessiond runtime files are kept. The default is "/var/run/lttng".]),
286 [LTTNG_SYSTEM_RUNDIR="$withval"],
287 [LTTNG_SYSTEM_RUNDIR="/var/run/lttng"])
288 AC_SUBST([LTTNG_SYSTEM_RUNDIR])
289
290 AC_ARG_ENABLE([test-java-agent-jul],
291 [AS_HELP_STRING([--enable-test-java-agent-jul],[enable the LTTng UST Java agent JUL tests [default=no]])],
292 [test_java_agent_jul=$enableval],
293 [test_java_agent_jul=no]
294 )
295
296 AC_ARG_ENABLE([test-java-agent-log4j],
297 [AS_HELP_STRING([--enable-test-java-agent-log4j],[enable the LTTng UST Java agent Log4j tests [default=no]])],
298 [test_java_agent_log4j=$enableval],
299 [test_java_agent_log4j=no]
300 )
301
302 AC_ARG_ENABLE([test-java-agent-all],
303 [AS_HELP_STRING([--enable-test-java-agent-all],[enable all the LTTng UST Java agent tests [default=no]])],
304 [test_java_agent_jul=$enableval
305 test_java_agent_log4j=$enableval],
306 [:]
307 )
308
309 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_BIN], "$CONSUMERD32_BIN", [Location of the 32-bit consumerd executable.])
310 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_BIN], "$CONSUMERD64_BIN", [Location of the 64-bit consumerd executable])
311 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_LIBDIR], "$CONSUMERD32_LIBDIR", [Search for consumerd 32-bit libraries in this location.])
312 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_LIBDIR], "$CONSUMERD64_LIBDIR", [Search for consumerd 64-bit libraries in this location.])
313 AC_DEFINE_UNQUOTED([CONFIG_BABELTRACE_BIN], "$BABELTRACE_BIN", [Location of the babeltrace viewer executable.])
314 AC_DEFINE_UNQUOTED([CONFIG_LTTV_GUI_BIN], "$LTTV_GUI_BIN", [Location of the lttv GUI viewer executable.])
315 AC_DEFINE_UNQUOTED([CONFIG_SESSIOND_BIN], "$SESSIOND_BIN", [Location of the sessiond executable.])
316 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_RUNDIR], ["$LTTNG_SYSTEM_RUNDIR"], [LTTng system runtime directory])
317
318 AC_DEFUN([_AC_DEFINE_AND_SUBST], [
319 AC_DEFINE_UNQUOTED([CONFIG_$1], [$2], [$1])
320 $1="$2"
321 AC_SUBST([$1])
322 ])
323
324 AC_DEFUN([_AC_DEFINE_QUOTED_AND_SUBST], [
325 AC_DEFINE_UNQUOTED([CONFIG_$1], ["$2"], [$1])
326 $1="$2"
327 AC_SUBST([$1])
328 ])
329
330 # Default values
331 m4_define([_DEFAULT_CHANNEL_SUBBUF_SIZE], [16384])
332 m4_define([_DEFAULT_CHANNEL_SUBBUF_NUM], [4])
333 m4_define([_DEFAULT_CHANNEL_SWITCH_TIMER], [0])
334 m4_define([_DEFAULT_CHANNEL_LIVE_TIMER], [0])
335 m4_define([_DEFAULT_CHANNEL_READ_TIMER], [200000])
336 m4_define([_DEFAULT_CHANNEL_MONITOR_TIMER], [1000000])
337 m4_define([_DEFAULT_CHANNEL_BLOCKING_TIMEOUT], [0])
338 _AC_DEFINE_AND_SUBST([DEFAULT_AGENT_TCP_PORT_RANGE_BEGIN], [5345])
339 _AC_DEFINE_AND_SUBST([DEFAULT_AGENT_TCP_PORT_RANGE_END], [5354])
340 _AC_DEFINE_AND_SUBST([DEFAULT_APP_SOCKET_RW_TIMEOUT], [5])
341 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE])
342 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_COUNT], [0])
343 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_SIZE], [0])
344 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
345 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_READ_TIMER], [_DEFAULT_CHANNEL_READ_TIMER])
346 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
347 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_SIZE], [1048576])
348 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
349 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
350 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_BLOCKING_TIMEOUT], [_DEFAULT_CHANNEL_BLOCKING_TIMEOUT])
351 _AC_DEFINE_AND_SUBST([DEFAULT_LTTNG_LIVE_TIMER], [1000000])
352 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_CACHE_SIZE], [4096])
353 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_READ_TIMER], [0])
354 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_NUM], [2])
355 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_SIZE], [4096])
356 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
357 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_CONTROL_PORT], [5342])
358 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_DATA_PORT], [5343])
359 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_VIEWER_PORT], [5344])
360 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
361 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_READ_TIMER], [0])
362 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_BLOCKING_TIMEOUT], [0])
363 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
364 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE])
365 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
366 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
367 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
368 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_READ_TIMER], [0])
369 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_BLOCKING_TIMEOUT], [0])
370 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
371 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_SIZE], [524288])
372 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
373 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
374 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_AGENT_BIND_ADDRESS], [localhost])
375 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_CONTROL_BIND_ADDRESS], [0.0.0.0])
376 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_DATA_BIND_ADDRESS], [0.0.0.0])
377 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_VIEWER_BIND_ADDRESS], [localhost])
378 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_RELAYD_CTRL_MAX_PAYLOAD_SIZE], [134217728])
379 _AC_DEFINE_AND_SUBST([DEFAULT_ROTATE_PENDING_RELAY_TIMER], [200000])
380
381 # Command short descriptions
382 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ADD_CONTEXT], [Add context fields to a channel])
383 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_CREATE], [Create a tracing session])
384 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DESTROY], [Tear down tracing sessions])
385 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_CHANNEL], [Disable tracing channels])
386 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_EVENT], [Disable event rules])
387 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_ROTATION], [Unset a rotation schedule])
388 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_CHANNEL], [Create or enable tracing channels])
389 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_EVENT], [Create or enable event rules])
390 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_ROTATION], [Set a rotation schedule])
391 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_HELP], [Display help information about a command])
392 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LIST], [List tracing sessions, domains, channels, and events])
393 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LOAD], [Load tracing session configurations])
394 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_REGENERATE], [Manage an LTTng tracing session's data regeneration])
395 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ROTATE], [Archive a tracing session's current trace chunk])
396 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SAVE], [Save tracing session configurations])
397 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SET_SESSION], [Set current tracing session])
398 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SNAPSHOT], [Snapshot buffers of current tracing session])
399 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_START], [Start tracing])
400 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STATUS], [Get the status of the current tracing session])
401 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STOP], [Stop tracing])
402 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_TRACK], [Track specific system resources])
403 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_UNTRACK], [Untrack specific system resources])
404 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VERSION], [Show version information])
405 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VIEW], [Start trace viewer])
406
407 if test "x$prefix" = "xNONE"; then
408 prefix=$ac_default_prefix
409 fi
410 CONFDIR=`eval echo $sysconfdir`
411 AC_SUBST(CONFDIR)
412 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_CONFIGDIR],"$CONFDIR", [LTTng system configuration directory.])
413
414 AC_DEFINE_DIR([CONFIG_LTTNG_SYSTEM_DATADIR],[datadir], [LTTng system data directory.])
415
416 # Check libpopt
417 PKG_CHECK_MODULES([POPT], [popt],
418 [
419 dnl PKG_CHECK_MODULES defines POPT_LIBS
420 ],
421 [
422 AC_MSG_WARN([pkg-config was unable to find a valid .pc for libpopt. Set PKG_CONFIG_PATH to specify the pkgconfig configuration file location])
423 AC_MSG_WARN([Finding libpopt without pkg-config.])
424 AC_CHECK_LIB([popt],
425 [poptGetContext],
426 [POPT_LIBS="-lpopt"],
427 [
428 AC_MSG_FAILURE([Cannot find libpopt. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location])
429 ]
430 )
431 ]
432 )
433 AC_SUBST(POPT_LIBS)
434
435 PKG_CHECK_MODULES([libxml2], [libxml-2.0 >= 2.7.6])
436
437 # First, check for uuid in system libs
438 AH_TEMPLATE([LTTNG_HAVE_LIBUUID], [Define if you have libuuid support])
439 AC_CHECK_FUNCS([uuid_generate],
440 [
441 AC_DEFINE([LTTNG_HAVE_LIBUUID], [1])
442 UUID_LIBS=""
443 ],
444 [
445 # Then, check if the pkg-config module is available, otherwise explicitly check
446 # for libuuid, or uuid support in the C-library.
447 PKG_CHECK_MODULES([UUID], [uuid],
448 [
449 AC_DEFINE([LTTNG_HAVE_LIBUUID], [1])
450 dnl PKG_CHECK_MODULES defines UUID_LIBS
451 ],
452 [
453 AC_MSG_WARN([pkg-config was unable to find a valid .pc for libuuid. Set PKG_CONFIG_PATH to specify the pkgconfig configuration file location])
454 AC_MSG_WARN([Finding libuuid without pkg-config.])
455 AC_CHECK_LIB([uuid], [uuid_generate],
456 [
457 AC_DEFINE([LTTNG_HAVE_LIBUUID], [1])
458 UUID_LIBS="-luuid"
459 ],
460 [
461 # libuuid not found, check for uuid_create in libc.
462 AC_CHECK_LIB([c], [uuid_create],
463 [
464 AC_DEFINE([LTTNG_HAVE_LIBUUID], [1])
465 UUID_LIBS="-lc"
466 ],
467 [
468 AC_MSG_FAILURE([Cannot find libuuid uuid_generate nor libc uuid_create. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location])
469 ]
470 )
471 ]
472 )
473 ]
474 )
475 ]
476 )
477 AC_SUBST(UUID_LIBS)
478
479 AC_CHECK_FUNC([clock_gettime], [AC_DEFINE_UNQUOTED([LTTNG_HAVE_CLOCK_GETTIME], 1, [Has clock_gettime() support.])])
480
481 # URCU library version needed or newer
482 m4_define([WRONG_LIBURCU_MSG], [Userspace RCU (liburcu) >= 0.9.0 is needed])
483
484 # Check liburcu needed function calls
485 AC_CHECK_DECL([cds_list_add], [],
486 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/list.h>]])
487 AC_CHECK_DECL([cds_wfcq_init], [],
488 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/wfcqueue.h>]])
489 AC_CHECK_DECL([cds_wfcq_dequeue_blocking], [],
490 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/wfcqueue.h>]])
491 AC_CHECK_DECL([futex_async], [],
492 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/futex.h>]])
493 AC_CHECK_DECL([rcu_thread_offline], [],
494 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
495 AC_CHECK_DECL([rcu_thread_online], [],
496 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
497 AC_CHECK_DECL([caa_likely], [],
498 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
499 AC_CHECK_LIB([urcu-cds], [_cds_lfht_new], [],
500 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])])
501
502 #Function added in urcu 0.7.0
503 AC_CHECK_DECL([cmm_smp_mb__before_uatomic_or], [],
504 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]]
505 )
506
507 #Function added in urcu 0.9.0
508 AC_CHECK_DECL([urcu_ref_get_unless_zero], [],
509 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/ref.h>]]
510 )
511
512 # Check for libkmod, it will be auto-neabled if found but won't fail if it's not,
513 # it can be explicitly disabled with --without-kmod
514 AH_TEMPLATE([HAVE_KMOD], [Define if you have kmod support])
515 AC_ARG_WITH([kmod],
516 [AS_HELP_STRING([--with-kmod], [build with lkmod support @<:@default=check@:>@])],
517 [],
518 [with_kmod=check]
519 )
520
521 AS_IF([test "x$with_kmod" != "xno"],
522 [
523 AC_CHECK_LIB([kmod], [kmod_module_probe_insert_module],
524 [
525 AC_DEFINE([HAVE_KMOD], [1])
526 KMOD_LIBS="-lkmod"
527 ],
528 [
529 if test "x$with_kmod" != xcheck; then
530 AC_MSG_FAILURE([Cannot find libkmod. Use [LDFLAGS]=-Ldir and [CPPFLAGS]=-Idir to specify its location.])
531 else
532 with_kmod=no
533 fi
534 ]
535 )
536 ]
537 )
538 AC_SUBST(KMOD_LIBS)
539
540 # Check for liblttng-ust-ctl, fail if it's not found,
541 # it can be explicitly disabled with --without-lttng-ust
542 AH_TEMPLATE([HAVE_LIBLTTNG_UST_CTL], [Define if you have LTTng-UST control support])
543 AC_ARG_WITH([lttng-ust],
544 [AS_HELP_STRING([--without-lttng-ust], [build without LTTng-UST (Userspace Tracing) support])],
545 [],
546 [with_lttng_ust=yes]
547 )
548
549 AS_IF([test "x$with_lttng_ust" = "xyes"],
550 [
551 AC_CHECK_LIB([lttng-ust-ctl], [ustctl_recv_channel_from_consumer],
552 [
553 AC_DEFINE([HAVE_LIBLTTNG_UST_CTL], [1])
554 ],
555 [
556 AC_MSG_FAILURE([Cannot find LTTng-UST >= 2.2.x. Use [LDFLAGS]=-Ldir and [CPPFLAGS]=-Idir to specify its location, or specify --without-lttng-ust to build lttng-tools without LTTng-UST support.])
557 ],
558 [-lurcu-common -lurcu-bp -lurcu-cds -lrt -ldl]
559 )
560 ]
561 )
562 AM_CONDITIONAL([HAVE_LIBLTTNG_UST_CTL], [test "x$with_lttng_ust" = "xyes"])
563
564
565
566 # check for dlopen
567 AC_CHECK_LIB([dl], [dlopen],
568 [DL_LIBS="-ldl"],
569 [
570 #libdl not found, check for dlopen in libc.
571 AC_CHECK_LIB([c], [dlopen],
572 [DL_LIBS="-lc"],
573 [AC_MSG_FAILURE([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])]
574 )
575 ]
576 )
577 AC_SUBST(DL_LIBS)
578
579 # Check for fmemopen
580 AC_CHECK_LIB([c], [fmemopen],
581 [
582 AC_DEFINE_UNQUOTED([LTTNG_HAVE_FMEMOPEN], 1, [Has fmemopen support.])
583 ]
584 )
585
586 # check for libpfm
587 AC_CHECK_LIB([pfm], [pfm_initialize],
588 [
589 have_libpfm=yes
590 ])
591 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBPFM], [test "x$have_libpfm" = "xyes"])
592
593 # For Python
594 # SWIG version needed or newer:
595 swig_version=2.0.0
596
597 AC_ARG_ENABLE([python-bindings],
598 [AC_HELP_STRING([--enable-python-bindings],
599 [compile Python bindings])],
600 [enable_python_binding=$enableval], [enable_python_binding=no])
601
602 AM_CONDITIONAL([PYTHON_BINDING], [test "x$enable_python_binding" = xyes])
603
604 if test "x$enable_python_binding" = xyes; then
605 AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ])
606 AS_IF([test x$enable_shared = xno], [ AC_MSG_ERROR([Python bindings require shared libraries.]) ])
607 AM_PATH_PYTHON([3.0])
608
609 AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config])
610 AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
611 AS_IF([test -z "$PYTHON_INCLUDE"], [
612 AS_IF([test -z "$PYTHON_CONFIG"], [
613 AC_PATH_PROGS([PYTHON_CONFIG],
614 [python$PYTHON_VERSION-config python-config],
615 [no],
616 [`dirname $PYTHON`])
617 AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
618 ])
619 AC_MSG_CHECKING([python include flags])
620 PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
621 AC_MSG_RESULT([$PYTHON_INCLUDE])
622 ])
623
624 else
625 AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl
626 [if you want Python bindings.])
627
628 fi
629
630 # Epoll check. If not present, the build will fallback on poll() API
631 AX_HAVE_EPOLL(
632 [AX_CONFIG_FEATURE_ENABLE(epoll)],
633 [AX_CONFIG_FEATURE_DISABLE(epoll)]
634 )
635 AX_CONFIG_FEATURE(
636 [epoll], [This platform supports epoll(7)],
637 [HAVE_EPOLL], [This platform supports epoll(7).],
638 [enable_epoll="yes"], [enable_epoll="no"]
639 )
640 AM_CONDITIONAL([COMPAT_EPOLL], [ test "$enable_epoll" = "yes" ])
641
642 AM_CONDITIONAL([TEST_JAVA_JUL_AGENT], [test "x$test_java_agent_jul" = "xyes"])
643 AM_CONDITIONAL([TEST_JAVA_LOG4J_AGENT], [test "x$test_java_agent_log4j" = "xyes"])
644
645 if test "x$test_java_agent_jul" = "xyes" || test "x$test_java_agent_log4j" = "xyes"; then
646 AX_JAVA_OPTIONS
647 AX_PROG_JAVAC
648 AX_PROG_JAVA
649 AX_PROG_JAR
650
651 AX_CHECK_CLASSPATH
652
653 # Check for Java UST agent common class first
654 AX_CHECK_CLASS(org.lttng.ust.agent.AbstractLttngAgent)
655 if test "x$ac_cv_class_org_lttng_ust_agent_AbstractLttngAgent" = "xno"; then
656 AC_MSG_ERROR([The UST Java agent common class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-common.jar"])
657 fi
658
659 if test "x$test_java_agent_jul" = "xyes"; then
660 # Check for JUL agent class
661 AX_CHECK_CLASS(org.lttng.ust.agent.jul.LttngLogHandler)
662 if test "x$ac_cv_class_org_lttng_ust_agent_jul_LttngLogHandler" = "xno"; then
663 AC_MSG_ERROR([The UST Java agent JUL class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-jul.jar"])
664 fi
665 fi
666
667 if test "x$test_java_agent_log4j" = "xyes"; then
668 # Check for Log4j agent class
669 AX_CHECK_CLASS(org.lttng.ust.agent.log4j.LttngLogAppender)
670 if test "x$ac_cv_class_org_lttng_ust_agent_log4j_LttngLogAppender" = "xno"; then
671 AC_MSG_ERROR([The UST Java agent Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-log4j.jar"])
672 fi
673
674 # Check for Log4j class
675 AX_CHECK_CLASS(org.apache.log4j.Logger)
676 if test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"; then
677 AC_MSG_ERROR([The Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j.jar"])
678 fi
679 fi
680 fi
681
682 # enable building man pages (user's intention)
683 AC_ARG_ENABLE(
684 man-pages,
685 AS_HELP_STRING(
686 [--disable-man-pages],
687 [Do not build and install man pages (already built in a distributed tarball)]
688 ),
689 [man_pages_opt=$enableval],
690 [man_pages_opt=yes]
691 )
692
693 # check for asciidoc and xmlto if we enabled building the man pages
694 have_asciidoc_xmlto=no
695 warn_prebuilt_man_pages=no
696
697 AS_IF([test "x$man_pages_opt" = "xyes"], [
698 AC_PATH_PROG([ASCIIDOC], [asciidoc], [no])
699 AC_PATH_PROG([XMLTO], [xmlto], [no])
700
701 AS_IF([test "x$ASCIIDOC" = "xno" || test "x$XMLTO" = "xno"], [
702 AS_IF([test "x$in_git_repo" = "xyes"], [
703 # this is an error because we're in the Git repo, which
704 # means the man pages are not already generated for us,
705 # thus asciidoc/xmlto are required because we were asked
706 # to build the man pages
707 AC_MSG_ERROR([
708 You need asciidoc and xmlto to build the LTTng-tools man pages. Use
709 --disable-man-pages to disable building the man pages, in which case
710 they will not be installed.
711 ])
712 ], [
713 # only warn here: since we're in the tarball, the man
714 # pages should already be generated at this point, thus
715 # asciidoc/xmlto are not strictly required
716 warn_prebuilt_man_pages=yes
717 ])
718 ], [
719 have_asciidoc_xmlto=yes
720 ])
721 ])
722
723 # export man page build condition: build the man pages if the user
724 # asked for it, and if the tools are available
725 AM_CONDITIONAL([MAN_PAGES_OPT], [test "x$man_pages_opt" != "xno"])
726 AM_CONDITIONAL([HAVE_ASCIIDOC_XMLTO], [test "x$have_asciidoc_xmlto" = "xyes"])
727
728 AC_DEFINE_UNQUOTED([MANPATH], ["`eval eval echo $mandir`"], [Path to man pages.])
729
730 # embedded --help message
731 AC_ARG_ENABLE(
732 [embedded-help],
733 AS_HELP_STRING(
734 [--enable-embedded-help],
735 [Embed the --help messages in the executable files]
736 ),
737 [embedded_help=$enableval],
738 [embedded_help=no]
739 )
740 AS_IF([test "x$embedded_help" = "xyes"], [
741 AS_IF([test "x$man_pages_opt" = "xno"], [
742 AC_MSG_ERROR([You need the --enable-man-pages option with the --enable-embedded-help option.])
743 ])
744 AC_PATH_PROG([man_prog_path], [man], [no])
745 AS_IF([test "x$man_prog_path" = "xno"], [
746 AC_MSG_ERROR([You need man with the --enable-embedded-help option.])
747 ])
748 AC_DEFINE_UNQUOTED([LTTNG_EMBED_HELP], 1, [Embed --help messages.])
749 AC_SUBST([MANPROG], [$man_prog_path])
750 ])
751 AM_CONDITIONAL([EMBED_HELP], [test "x$embedded_help" != "xno"])
752
753 # Python agent test
754 UST_PYTHON_AGENT="lttngust"
755
756 AC_ARG_ENABLE(test-python2-agent,
757 AS_HELP_STRING([--enable-test-python2-agent],
758 [enable tests for python2 agent. Python2 interpreter path can be overridden by setting the PYTHON2 environment variable. Default: Autodetect]
759 ),[:],[test_python2_agent_autodetect=yes]
760 )
761
762 AC_ARG_ENABLE(test-python3-agent,
763 AS_HELP_STRING([--enable-test-python3-agent],
764 [enable tests for python3 agent. Python3 interpreter path can be overridden by setting the PYTHON3 environment variable. Default: Autodetect]
765 ),[:],[test_python3_agent_autodetect=yes]
766 )
767
768 AC_ARG_ENABLE(test-python-agent-all,
769 AS_HELP_STRING([--enable-test-python-agent-all],
770 [enable test for all python{2/3} agent.]
771 ),
772 )
773
774 AS_IF([test ! -z "$enable_test_python_agent_all"], [
775 unset test_python2_agent_autodetect
776 unset test_python3_agent_autodetect
777 ])
778
779 AS_IF([test "x$enable_test_python_agent_all" = "xyes"], [
780 enable_test_python2_agent=yes
781 enable_test_python3_agent=yes
782 ])
783
784 AS_IF([test "x$enable_test_python_agent_all" = "xno"], [
785 enable_test_python2_agent=no
786 enable_test_python3_agent=no
787 ])
788
789
790 AS_IF([test "x$enable_test_python2_agent" = "xyes" -o "x$test_python2_agent_autodetect" = "xyes" ], [
791 AS_IF([test -z "$PYTHON2"], [
792 PYTHON2=python2
793 ], [
794 AC_MSG_WARN([Using user-defined PYTHON2 ($PYTHON2) for lttng-ust python2 agent check])
795 ])
796
797 AC_PATH_PROG([PYTHON2_BIN],[$PYTHON2])
798 AS_IF([test -z "$PYTHON2_BIN"], [
799 AS_IF([test -z "$test_python2_agent_autodetect"],[
800 AC_MSG_ERROR([No python2 interpreter found. PYTHON2 can be set to override default interpreter path])
801 ])
802 ], [
803 AC_MSG_CHECKING([for python2 lttng-ust agent])
804 AS_IF([$PYTHON2_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
805 PYTHON2_AGENT=$PYTHON2_BIN
806 AC_MSG_RESULT([yes])
807 RUN_PYTHON_AGENT_TEST=yes
808 ], [
809 AC_MSG_RESULT([no])
810 AS_IF([test -z "$test_python2_agent_autodetect"],[
811 AC_MSG_ERROR([No python2 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
812 ])
813 ])
814
815 ])
816
817 ])
818
819 AS_IF([test "x$enable_test_python3_agent" = "xyes" -o "x$test_python3_agent_autodetect" = "xyes" ], [
820 AS_IF([test -z "$PYTHON3"], [
821 PYTHON3=python3
822 ], [
823 AC_MSG_WARN([Using user-defined PYTHON3 ($PYTHON3) for lttng-ust python3 agent check])
824 ])
825
826 AC_PATH_PROG([PYTHON3_BIN],[$PYTHON3])
827 AS_IF([test -z "$PYTHON3_BIN"], [
828 AS_IF([test -z "$test_python3_agent_autodetect"],[
829 AC_MSG_ERROR([No python3 interpreter found. PYTHON3 can be set to override default interpreter path])
830 ])
831 ], [
832 AC_MSG_CHECKING([for python3 lttng-ust agent])
833 AS_IF([$PYTHON3_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
834 PYTHON3_AGENT=$PYTHON3_BIN
835 AC_MSG_RESULT([yes])
836 RUN_PYTHON_AGENT_TEST=yes
837 ], [
838 AC_MSG_RESULT([no])
839 AS_IF([test -z "$test_python3_agent_autodetect"],[
840 AC_MSG_ERROR([No python3 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
841 ])
842 ])
843
844 ])
845 ])
846 AC_SUBST([RUN_PYTHON_AGENT_TEST])
847 AC_SUBST([PYTHON2_AGENT])
848 AC_SUBST([PYTHON3_AGENT])
849
850 # Arguments for binaries build exclusion
851 AC_ARG_ENABLE([bin-lttng], AS_HELP_STRING([--disable-bin-lttng],[Disable the build of lttng binaries]))
852 AC_ARG_ENABLE([bin-lttng-consumerd], AS_HELP_STRING([--disable-bin-lttng-consumerd],
853 [Disable the build of lttng-consumerd binaries]))
854 AC_ARG_ENABLE([bin-lttng-crash], AS_HELP_STRING([--disable-bin-lttng-crash],[Disable the build of lttng-crash binaries]))
855 AC_ARG_ENABLE([bin-lttng-relayd], AS_HELP_STRING([--disable-bin-lttng-relayd],
856 [Disable the build of lttng-relayd binaries]))
857 AC_ARG_ENABLE([bin-lttng-sessiond], AS_HELP_STRING([--disable-bin-lttng-sessiond],
858 [Disable the build of lttng-sessiond binaries]))
859 AC_ARG_ENABLE([extras], AS_HELP_STRING([--disable-extras],
860 [Disable the build of the extra components]))
861
862
863 # Always build libconfig since it a dependency of libcommon
864 build_lib_config=yes
865
866 build_lib_compat=no
867 build_lib_consumer=no
868 build_lib_hashtable=no
869 build_lib_health=no
870 build_lib_runas=no
871 build_lib_unix=no
872 build_lib_index=no
873 build_lib_kernel_consumer=no
874 build_lib_kernel_ctl=no
875 build_lib_lttng_ctl=no
876 build_lib_relayd=no
877 build_lib_sessiond_comm=no
878 build_lib_testpoint=no
879 build_lib_ust_consumer=no
880
881 # There is an overlap for enabled dependencies, but this makes everything
882 # simpler. libcommon and libconfig are always compiled so they are not repeated
883 # here.
884
885 # Enable binary dependencies.
886 AS_IF([test x$enable_bin_lttng != xno],
887 [
888 build_lib_lttng_ctl=yes
889 ]
890 )
891
892 AS_IF([test x$enable_bin_lttng_consumerd != xno],
893 [
894 build_lib_consumer=yes
895 build_lib_sessiond_comm=yes
896 build_lib_index=yes
897 build_lib_health=yes
898 build_lib_testpoint=yes
899 ]
900 )
901
902 AS_IF([test x$enable_bin_lttng_crash != xno],
903 # Do nothing since libconfig and libcommon are built by default.
904 []
905 )
906
907 AS_IF([test x$enable_bin_lttng_relayd != xno],
908 [
909 build_lib_lttng_ctl=yes
910 build_lib_sessiond_comm=yes
911 build_lib_hashtable=yes
912 build_lib_compat=yes
913 build_lib_index=yes
914 build_lib_health=yes
915 build_lib_testpoint=yes
916 ]
917 )
918 AS_IF([test x$enable_bin_lttng_sessiond != xno],
919 [
920 build_lib_lttng_ctl=yes
921 build_lib_sessiond_comm=yes
922 build_lib_kernel_ctl=yes
923 build_lib_hashtable=yes
924 build_lib_compat=yes
925 build_lib_relayd=yes
926 build_lib_testpoint=yes
927 build_lib_health=yes
928 build_lib_runas=yes
929 build_lib_unix=yes
930 ]
931 )
932
933 # Libraries dependencies enabling
934 AS_IF([test x$build_lib_lttng_ctl = xyes],
935 [
936 build_lib_sessiond_comm=yes
937 build_lib_hashtable=yes
938 ]
939 )
940
941 AS_IF([test x$build_lib_consumer = xyes],
942 [
943 build_lib_sessiond_comm=yes
944 build_lib_kernel_consumer=yes
945 build_lib_hashtable=yes
946 build_lib_compat=yes
947 build_lib_relayd=yes
948 AS_IF([test "x$with_lttng_ust" = "xyes"], [build_lib_ust_consumer=yes])
949 ]
950 )
951
952 AS_IF([test x$build_lib_kernel_consumer = xyes],
953 [
954 build_lib_kernel_ctl=yes
955 build_lib_relayd=yes
956 ]
957 )
958
959 AS_IF([test x$build_lib_relayd = xyes],
960 [
961 build_lib_sessiond_comm=yes
962 ]
963 )
964
965 # Find arch type
966 AS_CASE([$host_cpu],
967 [k1om], [ARCHTYPE="x86"],
968 [i386], [ARCHTYPE="x86"],
969 [i486], [ARCHTYPE="x86"],
970 [i586], [ARCHTYPE="x86"],
971 [i686], [ARCHTYPE="x86"],
972 [amd64], [ARCHTYPE="x86"],
973 [x86_64], [ARCHTYPE="x86"],
974 [powerpc], [ARCHTYPE="ppc"],
975 [ppc64], [ARCHTYPE="ppc"],
976 [powerpc64], [ARCHTYPE="ppc"],
977 [powerpc64le], [ARCHTYPE="ppc"],
978 [ppc], [ARCHTYPE="ppc"],
979 [s390], [ARCHTYPE="s390"],
980 [s390x], [ARCHTYPE="s390"],
981 [sparc], [ARCHTYPE="sparc64"],
982 [sparc64], [ARCHTYPE="sparc64"],
983 [alpha*], [ARCHTYPE="alpha"],
984 [ia64], [ARCHTYPE="ia64"],
985 [arm*], [ARCHTYPE="arm"],
986 [aarch64*], [ARCHTYPE="aarch64"],
987 [mips*], [ARCHTYPE="mips"],
988 [nios2*], [ARCHTYPE="nios2"],
989 [tile*], [ARCHTYPE="tile"],
990 [hppa*], [ARCHTYPE="hppa"],
991 [m68k], [ARCHTYPE="m68k"],
992 [riscv*], [ARCHTYPE="riscv"],
993 [ARCHTYPE="unknown"]
994 )
995
996 AC_SUBST(ARCHTYPE)
997
998 AH_TEMPLATE([HAVE_MODULES_USERSPACE_CALLSTACK_CONTEXT], [Define if you have LTTng-modules userspace callstack tracing support])
999 AC_MSG_CHECKING([for architecture support of userspace callstack tracing from the kernel])
1000 AS_IF([test "x$ARCHTYPE" = "xx86"],[
1001 # Userspace callstack capture is only supported by the Linux kernel on x86.
1002 AC_MSG_RESULT([yes])
1003 have_modules_userspace_callstack_context=yes
1004 AC_DEFINE([HAVE_MODULES_USERSPACE_CALLSTACK_CONTEXT], [1])
1005 ], [
1006 AC_MSG_RESULT([no])
1007 have_modules_userspace_callstack_context=no
1008 ])
1009 AM_CONDITIONAL([HAVE_MODULES_USERSPACE_CALLSTACK_CONTEXT], [test x$have_modules_userspace_callstack_context != xno])
1010
1011 # Export binaries build conditions.
1012 AM_CONDITIONAL([BUILD_BIN_LTTNG], [test x$enable_bin_lttng != xno])
1013 AM_CONDITIONAL([BUILD_BIN_LTTNG_CONSUMERD], [test x$enable_bin_lttng_consumerd != xno])
1014 AM_CONDITIONAL([BUILD_BIN_LTTNG_CRASH], [test x$enable_bin_lttng_crash != xno])
1015 AM_CONDITIONAL([BUILD_BIN_LTTNG_RELAYD], [test x$enable_bin_lttng_relayd != xno])
1016 AM_CONDITIONAL([BUILD_BIN_LTTNG_SESSIOND], [test x$enable_bin_lttng_sessiond != xno])
1017
1018 # Export the tests and extras build conditions.
1019 AS_IF([\
1020 test "x$enable_bin_lttng" != "xno" && \
1021 test "x$enable_bin_lttng_consumerd" != "xno" && \
1022 test "x$enable_bin_lttng_crash" != "xno" && \
1023 test "x$enable_bin_lttng_relayd" != "xno" && \
1024 test "x$enable_bin_lttng_sessiond" != "xno"],
1025 [build_tests=yes],
1026 [build_tests=no]
1027 )
1028
1029 AM_CONDITIONAL([BUILD_TESTS], [test x$build_tests = xyes])
1030 AM_CONDITIONAL([BUILD_EXTRAS], [test x$enable_extras != xno])
1031
1032 # Export libraries build conditions.
1033 AM_CONDITIONAL([BUILD_LIB_COMPAT], [test x$build_lib_compat = xyes])
1034 AM_CONDITIONAL([BUILD_LIB_CONFIG], [test x$build_lib_config = xyes])
1035 AM_CONDITIONAL([BUILD_LIB_CONSUMER], [test x$build_lib_consumer = xyes])
1036 AM_CONDITIONAL([BUILD_LIB_HASHTABLE], [test x$build_lib_hashtable = xyes])
1037 AM_CONDITIONAL([BUILD_LIB_HEALTH], [test x$build_lib_health = xyes])
1038 AM_CONDITIONAL([BUILD_LIB_RUNAS], [test x$build_lib_runas = xyes])
1039 AM_CONDITIONAL([BUILD_LIB_UNIX], [test x$build_lib_unix = xyes])
1040 AM_CONDITIONAL([BUILD_LIB_INDEX], [test x$build_lib_index = xyes])
1041 AM_CONDITIONAL([BUILD_LIB_KERNEL_CONSUMER], [test x$build_lib_kernel_consumer = xyes])
1042 AM_CONDITIONAL([BUILD_LIB_KERNEL_CTL], [test x$build_lib_kernel_ctl = xyes])
1043 AM_CONDITIONAL([BUILD_LIB_LTTNG_CTL], [test x$build_lib_lttng_ctl = xyes])
1044 AM_CONDITIONAL([BUILD_LIB_RELAYD], [test x$build_lib_relayd = xyes])
1045 AM_CONDITIONAL([BUILD_LIB_SESSIOND_COMM], [test x$build_lib_sessiond_comm = xyes])
1046 AM_CONDITIONAL([BUILD_LIB_TESTPOINT], [test x$build_lib_testpoint = xyes])
1047 AM_CONDITIONAL([BUILD_LIB_UST_CONSUMER], [test x$build_lib_ust_consumer = xyes])
1048
1049 AM_CFLAGS="-Wall -fno-strict-aliasing $PTHREAD_CFLAGS"
1050 AC_SUBST(AM_CFLAGS)
1051
1052 AM_CPPFLAGS="-I\$(top_srcdir)/include -I\$(top_builddir)/include -I\$(top_srcdir)/src -include config.h $AM_CPPFLAGS"
1053 AC_SUBST(AM_CPPFLAGS)
1054
1055 lttngincludedir="${includedir}/lttng"
1056 AC_SUBST(lttngincludedir)
1057
1058 lttngactionincludedir="${includedir}/lttng/action"
1059 AC_SUBST(lttngactionincludedir)
1060
1061 lttngconditionincludedir="${includedir}/lttng/condition"
1062 AC_SUBST(lttngconditionincludedir)
1063
1064 lttngnotificationincludedir="${includedir}/lttng/notification"
1065 AC_SUBST(lttngnotificationincludedir)
1066
1067 lttngtriggerincludedir="${includedir}/lttng/trigger"
1068 AC_SUBST(lttngtriggerincludedir)
1069
1070 lttnglibexecdir="${libdir}/lttng/libexec"
1071 AC_SUBST(lttnglibexecdir)
1072
1073 AC_CONFIG_FILES([
1074 Makefile
1075 doc/Makefile
1076 doc/man/Makefile
1077 doc/man/asciidoc-attrs.conf
1078 include/Makefile
1079 extras/Makefile
1080 extras/bindings/Makefile
1081 extras/bindings/swig/Makefile
1082 extras/bindings/swig/python/Makefile
1083 extras/core-handler/Makefile
1084 src/Makefile
1085 src/common/Makefile
1086 src/common/kernel-ctl/Makefile
1087 src/common/kernel-consumer/Makefile
1088 src/common/consumer/Makefile
1089 src/common/ust-consumer/Makefile
1090 src/common/hashtable/Makefile
1091 src/common/sessiond-comm/Makefile
1092 src/common/compat/Makefile
1093 src/common/relayd/Makefile
1094 src/common/testpoint/Makefile
1095 src/common/index/Makefile
1096 src/common/health/Makefile
1097 src/common/config/Makefile
1098 src/common/string-utils/Makefile
1099 src/lib/Makefile
1100 src/lib/lttng-ctl/Makefile
1101 src/lib/lttng-ctl/filter/Makefile
1102 src/lib/lttng-ctl/lttng-ctl.pc
1103 src/bin/Makefile
1104 src/bin/lttng-consumerd/Makefile
1105 src/bin/lttng-sessiond/Makefile
1106 src/bin/lttng-relayd/Makefile
1107 src/bin/lttng/Makefile
1108 src/bin/lttng-crash/Makefile
1109 tests/Makefile
1110 tests/destructive/Makefile
1111 tests/regression/Makefile
1112 tests/regression/kernel/Makefile
1113 tests/regression/tools/Makefile
1114 tests/regression/tools/streaming/Makefile
1115 tests/regression/tools/filtering/Makefile
1116 tests/regression/tools/health/Makefile
1117 tests/regression/tools/tracefile-limits/Makefile
1118 tests/regression/tools/snapshots/Makefile
1119 tests/regression/tools/live/Makefile
1120 tests/regression/tools/exclusion/Makefile
1121 tests/regression/tools/save-load/Makefile
1122 tests/regression/tools/save-load/configuration/Makefile
1123 tests/regression/tools/mi/Makefile
1124 tests/regression/tools/wildcard/Makefile
1125 tests/regression/tools/crash/Makefile
1126 tests/regression/tools/regen-metadata/Makefile
1127 tests/regression/tools/regen-statedump/Makefile
1128 tests/regression/tools/notification/Makefile
1129 tests/regression/tools/rotation/Makefile
1130 tests/regression/ust/Makefile
1131 tests/regression/ust/nprocesses/Makefile
1132 tests/regression/ust/high-throughput/Makefile
1133 tests/regression/ust/low-throughput/Makefile
1134 tests/regression/ust/before-after/Makefile
1135 tests/regression/ust/buffers-pid/Makefile
1136 tests/regression/ust/periodical-metadata-flush/Makefile
1137 tests/regression/ust/multi-session/Makefile
1138 tests/regression/ust/multi-lib/Makefile
1139 tests/regression/ust/overlap/Makefile
1140 tests/regression/ust/overlap/demo/Makefile
1141 tests/regression/ust/linking/Makefile
1142 tests/regression/ust/daemon/Makefile
1143 tests/regression/ust/exit-fast/Makefile
1144 tests/regression/ust/fork/Makefile
1145 tests/regression/ust/libc-wrapper/Makefile
1146 tests/regression/ust/baddr-statedump/Makefile
1147 tests/regression/ust/ust-dl/Makefile
1148 tests/regression/ust/java-jul/Makefile
1149 tests/regression/ust/java-log4j/Makefile
1150 tests/regression/ust/python-logging/Makefile
1151 tests/regression/ust/getcpu-override/Makefile
1152 tests/regression/ust/clock-override/Makefile
1153 tests/regression/ust/type-declarations/Makefile
1154 tests/regression/ust/rotation-destroy-flush/Makefile
1155 tests/regression/ust/blocking/Makefile
1156 tests/stress/Makefile
1157 tests/unit/Makefile
1158 tests/unit/ini_config/Makefile
1159 tests/perf/Makefile
1160 tests/utils/Makefile
1161 tests/utils/tap/Makefile
1162 tests/utils/testapp/Makefile
1163 tests/utils/testapp/gen-ust-events/Makefile
1164 tests/utils/testapp/gen-syscall-events-callstack/Makefile
1165 tests/utils/testapp/gen-ust-nevents/Makefile
1166 tests/utils/testapp/gen-ust-nevents-str/Makefile
1167 tests/utils/testapp/gen-syscall-events/Makefile
1168 tests/utils/testapp/gen-ust-tracef/Makefile
1169 ])
1170
1171 # Inject variable into python test script.
1172 AC_CONFIG_FILES([tests/regression/ust/python-logging/test_python_logging],[chmod +x tests/regression/ust/python-logging/test_python_logging])
1173 # Inject LTTNG_TOOLS_BUILD_WITH_LIBPFM variable in test script.
1174 AC_CONFIG_FILES([tests/perf/test_perf_raw],[chmod +x tests/perf/test_perf_raw])
1175 AC_CONFIG_FILES([tests/regression/ust/ust-dl/test_ust-dl],[chmod +x tests/regression/ust/ust-dl/test_ust-dl])
1176
1177 AC_OUTPUT
1178
1179 #
1180 # Mini-report on what will be built.
1181 #
1182
1183 PPRINT_INIT
1184 PPRINT_SET_INDENT(1)
1185 PPRINT_SET_TS(38)
1186
1187 AS_ECHO
1188 AS_ECHO("${PPRINT_COLOR_BLDBLU}LTTng-tools $PACKAGE_VERSION \"$version_name\"$PPRINT_COLOR_RST")
1189 AS_ECHO
1190
1191 AS_IF([test -n "$report_fold"], [
1192 AS_ECHO("`AS_ECHO("$version_description") | $report_fold -s`")
1193 ], [
1194 AS_ECHO("$version_description")
1195 ])
1196
1197 AS_ECHO
1198 PPRINT_SUBTITLE([Features])
1199
1200 # Target architecture we're building for.
1201 target_arch=$host_cpu
1202 [
1203 for f in $CFLAGS; do
1204 if test $f = "-m32"; then
1205 target_arch="32-bit"
1206 elif test $f = "-m64"; then
1207 target_arch="64-bit"
1208 fi
1209 done
1210 ]
1211 PPRINT_PROP_STRING([Target architecture], $target_arch)
1212
1213 # kmod enabled/disabled
1214 test "x$with_kmod" != "xno" && value=1 || value=0
1215 PPRINT_PROP_BOOL([libkmod support], $value)
1216
1217 # LTTng-UST enabled/disabled
1218 test "x$with_lttng_ust" = "xyes" && value=1 || value=0
1219 PPRINT_PROP_BOOL([LTTng-UST support], $value)
1220
1221 AS_ECHO
1222 PPRINT_SUBTITLE([Binaries])
1223
1224 # List binaries to be built
1225 test x$enable_bin_lttng != xno && value=1 || value=0
1226 PPRINT_PROP_BOOL([lttng], $value)
1227
1228 test x$enable_bin_lttng_consumerd != xno && value=1 || value=0
1229 PPRINT_PROP_BOOL([lttng-consumerd], $value)
1230
1231 test x$enable_bin_lttng_crash != xno && value=1 || value=0
1232 PPRINT_PROP_BOOL([lttng-crash], $value)
1233
1234 test x$enable_bin_lttng_relayd != xno && value=1 || value=0
1235 PPRINT_PROP_BOOL([lttng-relayd], $value)
1236
1237 test x$enable_bin_lttng_sessiond != xno && value=1 || value=0
1238 PPRINT_PROP_BOOL([lttng-sessiond], $value)
1239
1240 # Extras
1241 test x$enable_extras != xno && value=1 || value=0
1242 AS_ECHO
1243 PPRINT_SET_INDENT(0)
1244 PPRINT_PROP_BOOL([Extras], $value, $PPRINT_COLOR_SUBTITLE)
1245 PPRINT_SET_INDENT(1)
1246
1247 AS_ECHO
1248 PPRINT_SUBTITLE([Tests])
1249
1250 # Print clear message that tests won't be built
1251 AS_IF([test "x$build_tests" = "xno"],[
1252 PPRINT_WARN([Tests won't be built since some binaries were disabled])
1253 ])
1254
1255 # LTTng UST Java agent JUL tests enabled/disabled
1256 test "x$test_java_agent_jul" = "xyes" && value=1 || value=0
1257 PPRINT_PROP_BOOL([LTTng-UST Java agent JUL tests], $value)
1258
1259 # LTTng UST Java agent Log4j tests enabled/disabled
1260 test "x$test_java_agent_log4j" = "xyes" && value=1 || value=0
1261 PPRINT_PROP_BOOL([LTTng-UST Java agent Log4j tests], $value)
1262
1263 test ! -z "$PYTHON2_AGENT" && value=1 || value=0
1264 PPRINT_PROP_BOOL([LTTng-UST Python2 agent tests], $value)
1265
1266 test ! -z "$PYTHON3_AGENT" && value=1 || value=0
1267 PPRINT_PROP_BOOL([LTTng-UST Python3 agent tests], $value)
1268
1269 #Python binding enabled/disabled
1270 test "x$enable_python_binding" = xyes && value=1 || value=0
1271 AS_ECHO
1272 PPRINT_SET_INDENT(0)
1273 PPRINT_PROP_BOOL([Python binding], $value, $PPRINT_COLOR_SUBTITLE)
1274
1275 # man pages build enabled/disabled
1276 m4_pushdef([build_man_pages_msg], [Build and install man pages])
1277
1278 AS_IF([test "x$man_pages_opt" != "xno"], [
1279 AS_IF([test "x$in_git_repo" = "xyes"], [
1280 PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
1281 ], [
1282 AS_IF([test "x$have_asciidoc_xmlto" = "xyes"], [
1283 PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
1284 ], [
1285 PPRINT_PROP_STRING([build_man_pages_msg],
1286 [${PPRINT_COLOR_BLDGRN}yes (already built)],
1287 $PPRINT_COLOR_SUBTITLE)
1288 ])
1289 ])
1290 ], [
1291 PPRINT_PROP_BOOL([build_man_pages_msg], 0, $PPRINT_COLOR_SUBTITLE)
1292 ])
1293
1294 m4_popdef([build_man_pages_msg])
1295
1296 test "x$embedded_help" = xyes && value=1 || value=0
1297 PPRINT_PROP_BOOL([Embed --help messages], $value, $PPRINT_COLOR_SUBTITLE)
1298
1299 PPRINT_SET_INDENT(1)
1300
1301 report_bindir="`eval eval echo $bindir`"
1302 report_libdir="`eval eval echo $libdir`"
1303
1304 # Print the bindir and libdir this `make install' will install into.
1305 AS_ECHO
1306 PPRINT_SUBTITLE([Install directories])
1307 PPRINT_PROP_STRING([Binaries], [$report_bindir])
1308 PPRINT_PROP_STRING([Libraries], [$report_libdir])
1309
1310 AS_ECHO
1311 PPRINT_SUBTITLE([Search directories])
1312
1313 # If we build the sessiond, print the paths it will use
1314 AS_IF([test "$SESSIOND_BIN" = ""],[
1315 path="$report_bindir/lttng-sessiond"
1316 ],[
1317 path="$SESSIOND_BIN"
1318 ])
1319 PPRINT_PROP_STRING([lttng-sessiond executable], [$path])
1320
1321 AS_IF([test "$CONSUMERD32_BIN" = ""],[
1322 path="`eval eval echo $lttnglibexecdir`/lttng-consumerd"
1323 ],[
1324 path="$CONSUMERD32_BIN"
1325 ])
1326 PPRINT_PROP_STRING([32-bit lttng-consumerd executable], [$path])
1327
1328 AS_IF([test "$CONSUMERD32_LIBDIR" = ""],[
1329 path="`eval eval echo $libdir`"
1330 ],[
1331 path="$CONSUMERD32_LIBDIR"
1332 ])
1333 PPRINT_PROP_STRING([32-bit consumer libraries], [$path])
1334
1335 AS_IF([test "$CONSUMERD64_BIN" = ""],[
1336 path="`eval eval echo $lttnglibexecdir`/lttng-consumerd"
1337 ],[
1338 path="$CONSUMERD64_BIN"
1339 ])
1340 PPRINT_PROP_STRING([64-bit lttng-consumerd executable], [$path])
1341
1342 AS_IF([test "$CONSUMERD64_LIBDIR" = ""],[
1343 path="`eval eval echo $libdir`"
1344 ],[
1345 path="$CONSUMERD64_LIBDIR"
1346 ])
1347 PPRINT_PROP_STRING([64-bit consumer libraries], [$path])
1348 PPRINT_SET_INDENT(0)
1349
1350 AS_IF([test "x$warn_prebuilt_man_pages" = "xyes" ], [
1351 AS_ECHO
1352 PPRINT_WARN([You need asciidoc and xmlto to build the LTTng-tools man pages.
1353
1354 Note that the man pages are already built in this distribution tarball,
1355 therefore asciidoc and xmlto are only needed if you intend to modify
1356 their sources.
1357
1358 Also note that the installed man pages will contain the project's
1359 default command-line option and environment variable values.
1360
1361 Use --disable-man-pages to completely disable building and installing
1362 the man pages.])
1363 ])
This page took 0.089865 seconds and 3 git commands to generate.