configure.ac

   1 AC_PREREQ([2.64])
   2 AC_INIT([lttng-tools],[2.12.0-pre],[jeremie.galarneau@efficios.com],[],[https://lttng.org])
   3
   4 AC_CONFIG_HEADERS([include/config.h])
   5 AC_CONFIG_AUX_DIR([config])
   6 AC_CONFIG_MACRO_DIR([m4])
   7
   8 AC_CANONICAL_TARGET
   9 AC_CANONICAL_HOST
  10
  11 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip tar-pax nostdinc])
  12 AM_MAINTAINER_MODE([enable])
  13
  14 # Enable silent rules if available (Introduced in AM 1.11)
  15 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  16
  17 AC_REQUIRE_AUX_FILE([tap-driver.sh])
  18
  19 # Checks for C compiler
  20 AC_USE_SYSTEM_EXTENSIONS
  21 AC_SYS_LARGEFILE
  22 AC_PROG_CC
  23 AC_PROG_CC_STDC
  24 AC_PROG_CXX
  25 RW_PROG_CXX_WORKS
  26 AM_CONDITIONAL([CXX_WORKS], [test "x$rw_cv_prog_cxx_works" = "xyes"])
  27
  28 LTTNG_CHECK_SDT_WORKS
  29 AM_CONDITIONAL([SDT_WORKS], [test "x$lttng_cv_sdt_works" = "xyes"])
  30
  31 # Checks for programs.
  32 AC_PROG_GREP
  33 AC_PROG_MAKE_SET
  34 AC_PROG_SED
  35 AC_PATH_PROG([report_fold], [fold])
  36 LT_INIT
  37
  38 # Check for objcopy, required by the base address statedump and dynamic linker tests
  39 AC_CHECK_TOOL([OBJCOPY], [objcopy], [no])
  40 AS_IF([test "x$OBJCOPY" = "xno"],
  41         [AC_MSG_WARN([Cannot find objcopy. The base address statedump and dynamic linker tests will be disabled. Install the binutils package to remediate this.])]
  42 )
  43 AM_CONDITIONAL([HAVE_OBJCOPY], [test "x$OBJCOPY" != xno])
  44
  45 # check for pgrep
  46 AC_PATH_PROG([PGREP], [pgrep], [no])
  47 AM_CONDITIONAL([HAVE_PGREP], [test "x$PGREP" != "xno"])
  48
  49 # set $IN_GIT_REPO if we're in the Git repository; the `bootstrap` file
  50 # is not distributed in tarballs
  51 AS_IF([test -f "$srcdir/bootstrap"], [in_git_repo=yes], [in_git_repo=no])
  52 AM_CONDITIONAL([IN_GIT_REPO], [test "x$in_git_repo" = "xyes"])
  53
  54 # check for bison
  55 AC_PROG_YACC
  56 BISON=$YACC
  57 AX_PROG_BISON_VERSION([2.4], [have_bison=yes])
  58
  59 AS_IF([test "x$have_bison" != "xyes"], [
  60   AS_IF([test "x$in_git_repo" = "xyes"], [
  61     AC_MSG_FAILURE([
  62 Bison >= 2.4 is required when building from the Git repository. You can
  63 set the YACC variable to override automatic detection.
  64     ])
  65   ], [
  66     AC_MSG_WARN([
  67 Missing Bison >= 2.4. Note that the parser files are already built in
  68 this distribution tarball, so Bison is only needed if you intend to
  69 modify their sources. You can set the YACC variable to override automatic
  70 detection.
  71     ])
  72   ])
  73 ])
  74 AM_CONDITIONAL([HAVE_BISON], [test "x$have_bison" = "xyes"])
  75
  76 # check for flex
  77 AC_PROG_LEX
  78 FLEX=$LEX
  79 AX_PROG_FLEX_VERSION([2.5.35], [have_flex=yes])
  80
  81 AS_IF([test "x$have_flex" != "xyes"], [
  82   AS_IF([test "x$in_git_repo" = "xyes"], [
  83     AC_MSG_FAILURE([
  84 Flex >= 2.5.35 is required when building from the Git repository. You can
  85 set the LEX variable to override automatic detection.
  86     ])
  87   ], [
  88     AC_MSG_WARN([
  89 Missing Flex >= 2.5.35. Note that the lexer files are already built in
  90 this distribution tarball, so Flex is only needed if you intend to
  91 modify their sources. You can set the LEX variable to override automatic
  92 detection.
  93     ])
  94   ])
  95 ])
  96 AM_CONDITIONAL([HAVE_FLEX], [test "x$have_flex" = "xyes"])
  97
  98
  99 # Checks for typedefs, structures, and compiler characteristics.
 100 AC_C_INLINE
 101 AC_TYPE_INT32_T
 102 AC_TYPE_INT64_T
 103 AC_TYPE_MODE_T
 104 AC_TYPE_OFF_T
 105 AC_TYPE_PID_T
 106 AC_TYPE_SIZE_T
 107 AC_TYPE_SSIZE_T
 108 AC_TYPE_UID_T
 109 AC_TYPE_UINT16_T
 110 AC_TYPE_UINT32_T
 111 AC_TYPE_UINT64_T
 112 AC_TYPE_UINT8_T
 113
 114 AX_C___ATTRIBUTE__
 115 AS_IF([test "x$ax_cv___attribute__" = "xyes"],
 116         [:],
 117         [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
 118
 119 AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])
 120
 121 # Check if linker has the -no-pie option.
 122 AX_CHECK_LINK_FLAG([-no-pie], [linker_have_no_pie_option=yes])
 123 AM_CONDITIONAL([LINKER_HAVE_NO_PIE_OPTION], [test "x$linker_have_no_pie_option" = "xyes"])
 124
 125 AX_LIB_SOCKET_NSL
 126
 127 LT_NO_UNDEFINED=""
 128 AS_CASE([$host_os],
 129   [cygwin*],
 130     [
 131       LT_NO_UNDEFINED="-no-undefined"
 132     ],
 133   [cygwin*|darwin*|mingw*|solaris*],
 134     [
 135       # On platforms where we only support the relayd, disable the other binaries by default
 136       AS_IF([test "x$enable_bin_lttng" = "x" ], [enable_bin_lttng=no])
 137       AS_IF([test "x$enable_bin_lttng_consumerd" = "x" ], [enable_bin_lttng_consumerd=no])
 138       AS_IF([test "x$enable_bin_lttng_crash" = "x" ], [enable_bin_lttng_crash=no])
 139       AS_IF([test "x$enable_bin_lttng_sessiond" = "x" ], [enable_bin_lttng_sessiond=no])
 140       AS_IF([test "x$enable_extras" = "x" ], [enable_extras=no])
 141       AS_IF([test "x$with_lttng_ust" = "x" ], [with_lttng_ust=no])
 142     ]
 143 )
 144
 145 AC_SUBST(LT_NO_UNDEFINED)
 146
 147 # Compute minor/major/patchlevel version numbers
 148 major_version=$(echo AC_PACKAGE_VERSION | $SED 's/^\([[0-9]]\)*\.[[0-9]]*\.[[0-9]]*.*$/\1/')
 149 minor_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.\([[0-9]]*\)\.[[0-9]]*.*$/\1/')
 150 patchlevel_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\).*$/\1/')
 151
 152 AC_SUBST([MAJOR_VERSION], [$major_version])
 153 AC_SUBST([MINOR_VERSION], [$minor_version])
 154 AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version])
 155 AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [LTTng-Tools major version number])
 156 AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [LTTng-Tools minor version number])
 157 AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [LTTng-Tools patchlevel version number])
 158
 159 version_name="Codename TBD"
 160 version_description="Description TBD"
 161 version_description_c=$(echo $version_description | $SED 's/"/\\"/g')
 162
 163 AC_DEFINE_UNQUOTED([VERSION_NAME], ["$version_name"], "")
 164 AC_DEFINE_UNQUOTED([VERSION_DESCRIPTION], ["$version_description_c"], "")
 165
 166 # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
 167 AC_ARG_ENABLE(libtool-linkdep-fixup,
 168         AS_HELP_STRING([--disable-libtool-linkdep-fixup],
 169                         [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)]),
 170         libtool_fixup=$enableval,
 171         libtool_fixup=yes)
 172
 173 AS_IF([test "x$libtool_fixup" = "xyes"],
 174             [
 175             libtool_m4="$srcdir/m4/libtool.m4"
 176             libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
 177             AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
 178             libtool_flag_pattern_count=$($GREP -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
 179             AS_IF([test $libtool_flag_pattern_count -ne 0],
 180             [
 181                   AC_MSG_RESULT([$libtool_flag_pattern_count])
 182                   AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
 183                   $SED -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
 184                   ],
 185                   [
 186                   AC_MSG_RESULT([none])
 187                   ])
 188             ])
 189
 190 AM_CONDITIONAL([NO_SHARED], [test x$enable_shared = xno])
 191
 192 AC_CHECK_HEADERS([ \
 193         sys/types.h unistd.h fcntl.h string.h pthread.h limits.h \
 194         signal.h stdlib.h sys/un.h sys/socket.h stdlib.h stdio.h \
 195         getopt.h sys/ipc.h sys/shm.h popt.h grp.h arpa/inet.h \
 196         netdb.h netinet/in.h paths.h stddef.h sys/file.h sys/ioctl.h \
 197         sys/mount.h sys/param.h sys/time.h elf.h
 198 ])
 199
 200 AM_CONDITIONAL([HAVE_ELF_H], [test x$ac_cv_header_elf_h = xyes])
 201
 202 # Basic functions check
 203 AC_CHECK_FUNCS([ \
 204         atexit bzero clock_gettime dup2 fdatasync fls ftruncate \
 205         gethostbyname gethostname getpagesize localtime_r memchr memrchr memset \
 206         mkdir munmap putenv realpath rmdir socket strchr strcspn strdup \
 207         strncasecmp strndup strnlen strpbrk strrchr strstr strtol strtoul \
 208         strtoull dirfd gethostbyname2 getipnodebyname epoll_create1 \
 209         sched_getcpu sysconf sync_file_range
 210 ])
 211
 212 # Check if clock_gettime, timer_create, timer_settime, and timer_delete are available in lib rt, and if so,
 213 # add -lrt to LIBS
 214 AC_CHECK_LIB([rt], [clock_gettime, timer_create, timer_settime, timer_delete])
 215
 216 # Checks for dl.
 217 AC_CHECK_LIB([dl], [dlopen], [
 218         have_libdl=yes
 219         libdl_name=dl
 220         DL_LIBS="-ldl"
 221 ], [
 222         # libdl not found, check for dlopen in libc.
 223         AC_CHECK_LIB([c], [dlopen], [
 224                 have_libc_dl=yes
 225                 libdl_name=c
 226                 DL_LIBS="-lc"
 227         ], [
 228                 AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
 229         ])
 230 ])
 231 AC_SUBST(DL_LIBS)
 232
 233 # Check if libdl has dlmopen support.
 234 AH_TEMPLATE([HAVE_DLMOPEN], ["Define to 1 if dlmopen is available."])
 235 AC_CHECK_LIB([$libdl_name], [dlmopen], [
 236         AC_DEFINE([HAVE_DLMOPEN], [1])
 237         HAVE_DLMOPEN=1
 238 ], [
 239         HAVE_DLMOPEN=0
 240 ])
 241 AC_SUBST(HAVE_DLMOPEN)
 242
 243 # Babeltrace viewer check
 244 AC_ARG_WITH([babeltrace-bin],
 245         AS_HELP_STRING([--with-babeltrace-bin],
 246         [Location of the babeltrace viewer executable (including the filename)]),
 247         [BABELTRACE_BIN="$withval"],
 248         [BABELTRACE_BIN=''])
 249 AC_SUBST([BABELTRACE_BIN])
 250
 251 # lttv-gui
 252 AC_ARG_WITH([lttv-gui-bin],
 253         AS_HELP_STRING([--with-lttv-gui-bin],
 254    [Location of the lttv GUI viewer executable (including the filename)]),
 255    [LTTV_GUI_BIN="$withval"],
 256    [LTTV_GUI_BIN=''])
 257 AC_SUBST([LTTV_GUI_BIN])
 258
 259 AC_ARG_WITH([consumerd32-bin],
 260         AS_HELP_STRING([--with-consumerd32-bin],
 261         [Location of the 32-bit consumerd executable (including the filename)]),
 262         [CONSUMERD32_BIN="$withval"],
 263         [CONSUMERD32_BIN=''])
 264 AC_SUBST([CONSUMERD32_BIN])
 265
 266 AC_ARG_WITH([consumerd64-bin],
 267         AS_HELP_STRING([--with-consumerd64-bin],
 268         [Location of the 64-bit consumerd executable (including the filename)]),
 269         [CONSUMERD64_BIN="$withval"],
 270         [CONSUMERD64_BIN=''])
 271 AC_SUBST([CONSUMERD64_BIN])
 272
 273 AC_ARG_WITH([consumerd32-libdir],
 274         AS_HELP_STRING([--with-consumerd32-libdir],
 275         [Directory containing the 32-bit consumerd libraries]),
 276         [CONSUMERD32_LIBDIR="$withval"],
 277         [CONSUMERD32_LIBDIR=''])
 278 AC_SUBST([CONSUMERD32_LIBDIR])
 279
 280 AC_ARG_WITH([consumerd64-libdir],
 281         AS_HELP_STRING([--with-consumerd64-libdir],
 282         [Directory containing the 64-bit consumerd libraries]),
 283         [CONSUMERD64_LIBDIR="$withval"],
 284         [CONSUMERD64_LIBDIR=''])
 285 AC_SUBST([CONSUMERD64_LIBDIR])
 286
 287 AC_ARG_WITH([sessiond-bin],
 288         AS_HELP_STRING([--with-sessiond-bin],
 289         [Location of the sessiond executable (including the filename)]),
 290         [SESSIOND_BIN="$withval"],
 291         [SESSIOND_BIN=''])
 292 AC_SUBST([SESSIOND_BIN])
 293
 294 AC_ARG_WITH([lttng-system-rundir],
 295         AS_HELP_STRING([--with-lttng-system-rundir],
 296         [Location of the system directory where the system-wide lttng-sessiond runtime files are kept. The default is "/var/run/lttng".]),
 297         [LTTNG_SYSTEM_RUNDIR="$withval"],
 298         [LTTNG_SYSTEM_RUNDIR="/var/run/lttng"])
 299 AC_SUBST([LTTNG_SYSTEM_RUNDIR])
 300
 301 AC_ARG_ENABLE([test-java-agent-jul],
 302         [AS_HELP_STRING([--enable-test-java-agent-jul],[enable the LTTng UST Java agent JUL tests [default=no]])],
 303         [test_java_agent_jul=$enableval],
 304         [test_java_agent_jul=no]
 305 )
 306
 307 AC_ARG_ENABLE([test-java-agent-log4j],
 308         [AS_HELP_STRING([--enable-test-java-agent-log4j],[enable the LTTng UST Java agent Log4j tests [default=no]])],
 309         [test_java_agent_log4j=$enableval],
 310         [test_java_agent_log4j=no]
 311 )
 312
 313 AC_ARG_ENABLE([test-java-agent-all],
 314         [AS_HELP_STRING([--enable-test-java-agent-all],[enable all the LTTng UST Java agent tests [default=no]])],
 315         [test_java_agent_jul=$enableval
 316          test_java_agent_log4j=$enableval],
 317         [:]
 318 )
 319
 320 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_BIN], "$CONSUMERD32_BIN", [Location of the 32-bit consumerd executable.])
 321 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_BIN], "$CONSUMERD64_BIN", [Location of the 64-bit consumerd executable])
 322 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_LIBDIR], "$CONSUMERD32_LIBDIR", [Search for consumerd 32-bit libraries in this location.])
 323 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_LIBDIR], "$CONSUMERD64_LIBDIR", [Search for consumerd 64-bit libraries in this location.])
 324 AC_DEFINE_UNQUOTED([CONFIG_BABELTRACE_BIN], "$BABELTRACE_BIN", [Location of the babeltrace viewer executable.])
 325 AC_DEFINE_UNQUOTED([CONFIG_LTTV_GUI_BIN], "$LTTV_GUI_BIN", [Location of the lttv GUI viewer executable.])
 326 AC_DEFINE_UNQUOTED([CONFIG_SESSIOND_BIN], "$SESSIOND_BIN", [Location of the sessiond executable.])
 327 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_RUNDIR], ["$LTTNG_SYSTEM_RUNDIR"], [LTTng system runtime directory])
 328
 329 AC_DEFUN([_AC_DEFINE_AND_SUBST], [
 330         AC_DEFINE_UNQUOTED([CONFIG_$1], [$2], [$1])
 331         $1="$2"
 332         AC_SUBST([$1])
 333 ])
 334
 335 AC_DEFUN([_AC_DEFINE_QUOTED_AND_SUBST], [
 336         AC_DEFINE_UNQUOTED([CONFIG_$1], ["$2"], [$1])
 337         $1="$2"
 338         AC_SUBST([$1])
 339 ])
 340
 341 # Default values
 342 m4_define([_DEFAULT_CHANNEL_SUBBUF_SIZE], [16384])
 343 m4_define([_DEFAULT_CHANNEL_SUBBUF_NUM], [4])
 344 m4_define([_DEFAULT_CHANNEL_SWITCH_TIMER], [0])
 345 m4_define([_DEFAULT_CHANNEL_LIVE_TIMER], [0])
 346 m4_define([_DEFAULT_CHANNEL_READ_TIMER], [200000])
 347 m4_define([_DEFAULT_CHANNEL_MONITOR_TIMER], [1000000])
 348 m4_define([_DEFAULT_CHANNEL_BLOCKING_TIMEOUT], [0])
 349 _AC_DEFINE_AND_SUBST([DEFAULT_AGENT_TCP_PORT_RANGE_BEGIN], [5345])
 350 _AC_DEFINE_AND_SUBST([DEFAULT_AGENT_TCP_PORT_RANGE_END], [5354])
 351 _AC_DEFINE_AND_SUBST([DEFAULT_APP_SOCKET_RW_TIMEOUT], [5])
 352 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE])
 353 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_COUNT], [0])
 354 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_SIZE], [0])
 355 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 356 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_READ_TIMER], [_DEFAULT_CHANNEL_READ_TIMER])
 357 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 358 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_SIZE], [1048576])
 359 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 360 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
 361 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_BLOCKING_TIMEOUT], [_DEFAULT_CHANNEL_BLOCKING_TIMEOUT])
 362 _AC_DEFINE_AND_SUBST([DEFAULT_LTTNG_LIVE_TIMER], [1000000])
 363 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_CACHE_SIZE], [4096])
 364 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_READ_TIMER], [0])
 365 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_NUM], [2])
 366 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_SIZE], [4096])
 367 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 368 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_CONTROL_PORT], [5342])
 369 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_DATA_PORT], [5343])
 370 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_VIEWER_PORT], [5344])
 371 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 372 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_READ_TIMER], [0])
 373 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_BLOCKING_TIMEOUT], [0])
 374 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 375 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE])
 376 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 377 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
 378 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 379 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_READ_TIMER], [0])
 380 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_BLOCKING_TIMEOUT], [0])
 381 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 382 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_SIZE], [524288])
 383 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 384 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
 385 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_AGENT_BIND_ADDRESS], [localhost])
 386 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_CONTROL_BIND_ADDRESS], [0.0.0.0])
 387 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_DATA_BIND_ADDRESS], [0.0.0.0])
 388 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_VIEWER_BIND_ADDRESS], [localhost])
 389 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_RELAYD_CTRL_MAX_PAYLOAD_SIZE], [134217728])
 390 _AC_DEFINE_AND_SUBST([DEFAULT_ROTATE_PENDING_TIMER], [500000])
 391
 392 # Command short descriptions
 393 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ADD_CONTEXT], [Add context fields to a channel])
 394 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_CREATE], [Create a tracing session])
 395 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DESTROY], [Tear down tracing sessions])
 396 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_CHANNEL], [Disable tracing channels])
 397 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_EVENT], [Disable event rules])
 398 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_ROTATION], [Unset a rotation schedule])
 399 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_CHANNEL], [Create or enable tracing channels])
 400 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_EVENT], [Create or enable event rules])
 401 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_ROTATION], [Set a rotation schedule])
 402 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_HELP], [Display help information about a command])
 403 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LIST], [List tracing sessions, domains, channels, and events])
 404 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LOAD], [Load tracing session configurations])
 405 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_REGENERATE], [Manage an LTTng tracing session's data regeneration])
 406 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ROTATE], [Archive a tracing session's current trace chunk])
 407 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SAVE], [Save tracing session configurations])
 408 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SET_SESSION], [Set current tracing session])
 409 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SNAPSHOT], [Snapshot buffers of current tracing session])
 410 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_START], [Start tracing])
 411 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STATUS], [Get the status of the current tracing session])
 412 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STOP], [Stop tracing])
 413 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_ROTATION], [Unset a rotation schedule])
 414 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_ROTATION], [Set a rotation schedule])
 415 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ROTATE], [Archive a tracing session’s current trace chunk])
 416 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_TRACK], [Track specific system resources])
 417 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_UNTRACK], [Untrack specific system resources])
 418 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VERSION], [Show version information])
 419 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VIEW], [Start trace viewer])
 420
 421 if test "x$prefix" = "xNONE"; then
 422         prefix=$ac_default_prefix
 423 fi
 424 CONFDIR=`eval echo $sysconfdir`
 425 AC_SUBST(CONFDIR)
 426 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_CONFIGDIR],"$CONFDIR", [LTTng system configuration directory.])
 427
 428 AX_DEFINE_DIR([CONFIG_LTTNG_SYSTEM_DATADIR], [datadir], [LTTng system data directory.])
 429
 430 # Check libpopt
 431 PKG_CHECK_MODULES([POPT], [popt],
 432   [
 433     dnl PKG_CHECK_MODULES defines POPT_LIBS
 434   ],
 435   [
 436     AC_MSG_WARN([pkg-config was unable to find a valid .pc for libpopt. Set PKG_CONFIG_PATH to specify the pkgconfig configuration file location])
 437     AC_MSG_WARN([Finding libpopt without pkg-config.])
 438     AC_CHECK_LIB([popt],
 439       [poptGetContext],
 440       [POPT_LIBS="-lpopt"],
 441       [
 442         AC_MSG_FAILURE([Cannot find libpopt. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location])
 443       ]
 444     )
 445   ]
 446 )
 447 AC_SUBST(POPT_LIBS)
 448
 449 PKG_CHECK_MODULES([libxml2], [libxml-2.0 >= 2.7.6])
 450
 451 # First, check for uuid in system libs
 452 AH_TEMPLATE([LTTNG_HAVE_LIBUUID], [Define if you have libuuid support])
 453 AC_CHECK_FUNCS([uuid_generate],
 454   [
 455     AC_DEFINE([LTTNG_HAVE_LIBUUID], [1])
 456     UUID_LIBS=""
 457   ],
 458   [
 459     # Then, check if the pkg-config module is available, otherwise explicitly check
 460     # for libuuid, or uuid support in the C-library.
 461     PKG_CHECK_MODULES([UUID], [uuid],
 462       [
 463         AC_DEFINE([LTTNG_HAVE_LIBUUID], [1])
 464         dnl PKG_CHECK_MODULES defines UUID_LIBS
 465       ],
 466       [
 467         AC_MSG_WARN([pkg-config was unable to find a valid .pc for libuuid. Set PKG_CONFIG_PATH to specify the pkgconfig configuration file location])
 468         AC_MSG_WARN([Finding libuuid without pkg-config.])
 469         AC_CHECK_LIB([uuid], [uuid_generate],
 470           [
 471             AC_DEFINE([LTTNG_HAVE_LIBUUID], [1])
 472             UUID_LIBS="-luuid"
 473           ],
 474           [
 475             # libuuid not found, check for uuid_create in libc.
 476             AC_CHECK_LIB([c], [uuid_create],
 477               [
 478                 AC_DEFINE([LTTNG_HAVE_LIBUUID], [1])
 479                 UUID_LIBS="-lc"
 480               ],
 481               [
 482                 AC_MSG_FAILURE([Cannot find libuuid uuid_generate nor libc uuid_create. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location])
 483               ]
 484             )
 485           ]
 486         )
 487       ]
 488     )
 489   ]
 490 )
 491 AC_SUBST(UUID_LIBS)
 492
 493 AC_CHECK_FUNC([clock_gettime], [AC_DEFINE_UNQUOTED([LTTNG_HAVE_CLOCK_GETTIME], 1, [Has clock_gettime() support.])])
 494
 495 # URCU library version needed or newer
 496 m4_define([WRONG_LIBURCU_MSG], [Userspace RCU (liburcu) >= 0.9.0 is needed])
 497
 498 # Check liburcu needed function calls
 499 AC_CHECK_DECL([cds_list_add], [],
 500         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/list.h>]])
 501 AC_CHECK_DECL([cds_wfcq_init], [],
 502         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/wfcqueue.h>]])
 503 AC_CHECK_DECL([cds_wfcq_dequeue_blocking], [],
 504         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/wfcqueue.h>]])
 505 AC_CHECK_DECL([futex_async], [],
 506         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/futex.h>]])
 507 AC_CHECK_DECL([rcu_thread_offline], [],
 508         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
 509 AC_CHECK_DECL([rcu_thread_online], [],
 510         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
 511 AC_CHECK_DECL([caa_likely], [],
 512         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
 513 AC_CHECK_LIB([urcu-cds], [_cds_lfht_new], [],
 514         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])])
 515
 516 #Function added in urcu 0.7.0
 517 AC_CHECK_DECL([cmm_smp_mb__before_uatomic_or], [],
 518         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]]
 519 )
 520
 521 #Function added in urcu 0.9.0
 522 AC_CHECK_DECL([urcu_ref_get_unless_zero], [],
 523         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/ref.h>]]
 524 )
 525
 526 # Check for libkmod, it will be auto-neabled if found but won't fail if it's not,
 527 # it can be explicitly disabled with --without-kmod
 528 AH_TEMPLATE([HAVE_KMOD], [Define if you have kmod support])
 529 AC_ARG_WITH([kmod],
 530   [AS_HELP_STRING([--with-kmod], [build with lkmod support @<:@default=check@:>@])],
 531   [],
 532   [with_kmod=check]
 533 )
 534
 535 AS_IF([test "x$with_kmod" != "xno"],
 536   [
 537     AC_CHECK_LIB([kmod], [kmod_module_probe_insert_module],
 538       [
 539         AC_DEFINE([HAVE_KMOD], [1])
 540         KMOD_LIBS="-lkmod"
 541       ],
 542       [
 543         if test "x$with_kmod" != xcheck; then
 544           AC_MSG_FAILURE([Cannot find libkmod. Use [LDFLAGS]=-Ldir and [CPPFLAGS]=-Idir to specify its location.])
 545         else
 546           with_kmod=no
 547         fi
 548       ]
 549     )
 550   ]
 551 )
 552 AC_SUBST(KMOD_LIBS)
 553
 554 # Check for liblttng-ust-ctl, fail if it's not found,
 555 # it can be explicitly disabled with --without-lttng-ust
 556 AH_TEMPLATE([HAVE_LIBLTTNG_UST_CTL], [Define if you have LTTng-UST control support])
 557 AC_ARG_WITH([lttng-ust],
 558   [AS_HELP_STRING([--without-lttng-ust], [build without LTTng-UST (Userspace Tracing) support])],
 559   [],
 560   [with_lttng_ust=yes]
 561 )
 562
 563 AS_IF([test "x$with_lttng_ust" = "xyes"],
 564   [
 565     AC_CHECK_LIB([lttng-ust-ctl], [ustctl_recv_channel_from_consumer],
 566       [
 567         AC_DEFINE([HAVE_LIBLTTNG_UST_CTL], [1])
 568       ],
 569       [
 570         AC_MSG_FAILURE([Cannot find LTTng-UST >= 2.2.x. Use [LDFLAGS]=-Ldir and [CPPFLAGS]=-Idir to specify its location, or specify --without-lttng-ust to build lttng-tools without LTTng-UST support.])
 571       ],
 572       [-lurcu-common -lurcu-bp -lurcu-cds -lrt -ldl]
 573     )
 574   ]
 575 )
 576 AM_CONDITIONAL([HAVE_LIBLTTNG_UST_CTL], [test "x$with_lttng_ust" = "xyes"])
 577
 578
 579 # Check for fmemopen
 580 AC_CHECK_LIB([c], [fmemopen],
 581 [
 582         AC_DEFINE_UNQUOTED([LTTNG_HAVE_FMEMOPEN], 1, [Has fmemopen support.])
 583 ]
 584 )
 585
 586 # check for libpfm
 587 AC_CHECK_LIB([pfm], [pfm_initialize],
 588              [
 589               have_libpfm=yes
 590               ])
 591 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBPFM], [test "x$have_libpfm" = "xyes"])
 592
 593 # For Python
 594 # SWIG version needed or newer:
 595 swig_version=2.0.0
 596
 597 AC_ARG_ENABLE([python-bindings],
 598               [AC_HELP_STRING([--enable-python-bindings],
 599                               [compile Python bindings])],
 600               [enable_python_binding=$enableval], [enable_python_binding=no])
 601
 602 AM_CONDITIONAL([PYTHON_BINDING], [test "x$enable_python_binding" = xyes])
 603
 604 if test "x$enable_python_binding" = xyes; then
 605   AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ])
 606   AS_IF([test x$enable_shared = xno], [ AC_MSG_ERROR([Python bindings require shared libraries.]) ])
 607   AM_PATH_PYTHON([3.0])
 608
 609   AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config])
 610   AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
 611   AS_IF([test -z "$PYTHON_INCLUDE"], [
 612     AS_IF([test -z "$PYTHON_CONFIG"], [
 613       AC_PATH_PROGS([PYTHON_CONFIG],
 614                     [python$PYTHON_VERSION-config python-config],
 615                     [no],
 616                     [`dirname $PYTHON`])
 617       AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
 618     ])
 619     AC_MSG_CHECKING([python include flags])
 620     PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
 621     AC_MSG_RESULT([$PYTHON_INCLUDE])
 622   ])
 623
 624 else
 625     AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl
 626 [if you want Python bindings.])
 627
 628 fi
 629
 630 # Epoll check. If not present, the build will fallback on poll() API
 631 AX_HAVE_EPOLL(
 632         [AX_CONFIG_FEATURE_ENABLE(epoll)],
 633         [AX_CONFIG_FEATURE_DISABLE(epoll)]
 634 )
 635 AX_CONFIG_FEATURE(
 636         [epoll], [This platform supports epoll(7)],
 637         [HAVE_EPOLL], [This platform supports epoll(7).],
 638         [enable_epoll="yes"], [enable_epoll="no"]
 639 )
 640 AM_CONDITIONAL([COMPAT_EPOLL], [ test "$enable_epoll" = "yes" ])
 641
 642 AS_IF([test "x$ac_cv_func_dirfd" = "xyes"],
 643         [AX_CONFIG_FEATURE_ENABLE(dirfd)],
 644         [AX_CONFIG_FEATURE_DISABLE(dirfd)]
 645 )
 646 AX_CONFIG_FEATURE(
 647         [dirfd], [Use directory file descriptors],
 648         [COMPAT_DIRFD], [This platform supports directory file descriptors.],
 649         [enable_dirfd="yes"], [enable_dirfd="no"]
 650 )
 651 AM_CONDITIONAL([COMPAT_DIRFD], [ test "$enable_dirfd" = "yes" ])
 652
 653 AM_CONDITIONAL([TEST_JAVA_JUL_AGENT], [test "x$test_java_agent_jul" = "xyes"])
 654 AM_CONDITIONAL([TEST_JAVA_LOG4J_AGENT], [test "x$test_java_agent_log4j" = "xyes"])
 655
 656 if test "x$test_java_agent_jul" = "xyes" || test "x$test_java_agent_log4j" = "xyes"; then
 657         AX_JAVA_OPTIONS
 658         AX_PROG_JAVAC
 659         AX_PROG_JAVA
 660         AX_PROG_JAR
 661
 662         AX_CHECK_CLASSPATH
 663
 664         # Check for Java UST agent common class first
 665         AX_CHECK_CLASS(org.lttng.ust.agent.AbstractLttngAgent)
 666         if test "x$ac_cv_class_org_lttng_ust_agent_AbstractLttngAgent" = "xno"; then
 667                 AC_MSG_ERROR([The UST Java agent common class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-common.jar"])
 668         fi
 669
 670         if test "x$test_java_agent_jul" = "xyes"; then
 671                 # Check for JUL agent class
 672                 AX_CHECK_CLASS(org.lttng.ust.agent.jul.LttngLogHandler)
 673                 if test "x$ac_cv_class_org_lttng_ust_agent_jul_LttngLogHandler" = "xno"; then
 674                         AC_MSG_ERROR([The UST Java agent JUL class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-jul.jar"])
 675                 fi
 676         fi
 677
 678         if test "x$test_java_agent_log4j" = "xyes"; then
 679                 # Check for Log4j agent class
 680                 AX_CHECK_CLASS(org.lttng.ust.agent.log4j.LttngLogAppender)
 681                 if test "x$ac_cv_class_org_lttng_ust_agent_log4j_LttngLogAppender" = "xno"; then
 682                         AC_MSG_ERROR([The UST Java agent Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-log4j.jar"])
 683                 fi
 684
 685                 # Check for Log4j class
 686                 AX_CHECK_CLASS(org.apache.log4j.Logger)
 687                 if test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"; then
 688                         AC_MSG_ERROR([The Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j.jar"])
 689                 fi
 690         fi
 691 fi
 692
 693 # enable building man pages (user's intention)
 694 AC_ARG_ENABLE(
 695         man-pages,
 696         AS_HELP_STRING(
 697                 [--disable-man-pages],
 698                 [Do not build and install man pages (already built in a distributed tarball)]
 699         ),
 700         [man_pages_opt=$enableval],
 701         [man_pages_opt=yes]
 702 )
 703
 704 # check for asciidoc and xmlto if we enabled building the man pages
 705 have_asciidoc_xmlto=no
 706 warn_prebuilt_man_pages=no
 707
 708 AS_IF([test "x$man_pages_opt" = "xyes"], [
 709         AC_PATH_PROG([ASCIIDOC], [asciidoc], [no])
 710         AC_PATH_PROG([XMLTO], [xmlto], [no])
 711
 712         AS_IF([test "x$ASCIIDOC" = "xno" || test "x$XMLTO" = "xno"], [
 713                 AS_IF([test "x$in_git_repo" = "xyes"], [
 714                         # this is an error because we're in the Git repo, which
 715                         # means the man pages are not already generated for us,
 716                         # thus asciidoc/xmlto are required because we were asked
 717                         # to build the man pages
 718                         AC_MSG_ERROR([
 719 You need asciidoc and xmlto to build the LTTng-tools man pages. Use
 720 --disable-man-pages to disable building the man pages, in which case
 721 they will not be installed.
 722                         ])
 723                 ], [
 724                         # only warn here: since we're in the tarball, the man
 725                         # pages should already be generated at this point, thus
 726                         # asciidoc/xmlto are not strictly required
 727                         warn_prebuilt_man_pages=yes
 728                 ])
 729         ], [
 730                 have_asciidoc_xmlto=yes
 731         ])
 732 ])
 733
 734 # export man page build condition: build the man pages if the user
 735 # asked for it, and if the tools are available
 736 AM_CONDITIONAL([MAN_PAGES_OPT], [test "x$man_pages_opt" != "xno"])
 737 AM_CONDITIONAL([HAVE_ASCIIDOC_XMLTO], [test "x$have_asciidoc_xmlto" = "xyes"])
 738
 739 AC_DEFINE_UNQUOTED([MANPATH], ["`eval eval echo $mandir`"], [Path to man pages.])
 740
 741 # embedded --help message
 742 AC_ARG_ENABLE(
 743         [embedded-help],
 744         AS_HELP_STRING(
 745                 [--enable-embedded-help],
 746                 [Embed the --help messages in the executable files]
 747         ),
 748         [embedded_help=$enableval],
 749         [embedded_help=no]
 750 )
 751 AS_IF([test "x$embedded_help" = "xyes"], [
 752         AS_IF([test "x$man_pages_opt" = "xno"], [
 753                 AC_MSG_ERROR([You need the --enable-man-pages option with the --enable-embedded-help option.])
 754         ])
 755         AC_PATH_PROG([man_prog_path], [man], [no])
 756         AS_IF([test "x$man_prog_path" = "xno"], [
 757                 AC_MSG_ERROR([You need man with the --enable-embedded-help option.])
 758         ])
 759         AC_DEFINE_UNQUOTED([LTTNG_EMBED_HELP], 1, [Embed --help messages.])
 760         AC_SUBST([MANPROG], [$man_prog_path])
 761 ])
 762 AM_CONDITIONAL([EMBED_HELP], [test "x$embedded_help" != "xno"])
 763
 764 # Python agent test
 765 UST_PYTHON_AGENT="lttngust"
 766
 767 AC_ARG_ENABLE(test-python2-agent,
 768         AS_HELP_STRING([--enable-test-python2-agent],
 769                 [enable tests for python2 agent. Python2 interpreter path can be overridden by setting the PYTHON2 environment variable. Default: Autodetect]
 770         ),[:],[test_python2_agent_autodetect=yes]
 771 )
 772
 773 AC_ARG_ENABLE(test-python3-agent,
 774         AS_HELP_STRING([--enable-test-python3-agent],
 775                 [enable tests for python3 agent. Python3 interpreter path can be overridden by setting the PYTHON3 environment variable. Default: Autodetect]
 776         ),[:],[test_python3_agent_autodetect=yes]
 777 )
 778
 779 AC_ARG_ENABLE(test-python-agent-all,
 780         AS_HELP_STRING([--enable-test-python-agent-all],
 781                 [enable test for all python{2/3} agent.]
 782         ),
 783 )
 784
 785 AS_IF([test ! -z "$enable_test_python_agent_all"], [
 786        unset test_python2_agent_autodetect
 787        unset test_python3_agent_autodetect
 788 ])
 789
 790 AS_IF([test "x$enable_test_python_agent_all" = "xyes"], [
 791        enable_test_python2_agent=yes
 792        enable_test_python3_agent=yes
 793 ])
 794
 795 AS_IF([test "x$enable_test_python_agent_all" = "xno"], [
 796        enable_test_python2_agent=no
 797        enable_test_python3_agent=no
 798 ])
 799
 800
 801 AS_IF([test "x$enable_test_python2_agent" = "xyes" -o "x$test_python2_agent_autodetect" = "xyes" ], [
 802         AS_IF([test -z "$PYTHON2"], [
 803                         PYTHON2=python2
 804                 ], [
 805                         AC_MSG_WARN([Using user-defined PYTHON2 ($PYTHON2) for lttng-ust python2 agent check])
 806         ])
 807
 808         AC_PATH_PROG([PYTHON2_BIN],[$PYTHON2])
 809         AS_IF([test -z "$PYTHON2_BIN"], [
 810                 AS_IF([test -z "$test_python2_agent_autodetect"],[
 811                         AC_MSG_ERROR([No python2 interpreter found. PYTHON2 can be set to override default interpreter path])
 812                 ])
 813         ], [
 814                 AC_MSG_CHECKING([for python2 lttng-ust agent])
 815                 AS_IF([$PYTHON2_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
 816                         PYTHON2_AGENT=$PYTHON2_BIN
 817                         AC_MSG_RESULT([yes])
 818                         RUN_PYTHON_AGENT_TEST=yes
 819                 ], [
 820                         AC_MSG_RESULT([no])
 821                         AS_IF([test -z "$test_python2_agent_autodetect"],[
 822                                 AC_MSG_ERROR([No python2 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
 823                         ])
 824                 ])
 825
 826         ])
 827
 828 ])
 829
 830 AS_IF([test "x$enable_test_python3_agent" = "xyes" -o "x$test_python3_agent_autodetect" = "xyes" ], [
 831         AS_IF([test -z "$PYTHON3"], [
 832                 PYTHON3=python3
 833         ], [
 834                 AC_MSG_WARN([Using user-defined PYTHON3 ($PYTHON3) for lttng-ust python3 agent check])
 835         ])
 836
 837         AC_PATH_PROG([PYTHON3_BIN],[$PYTHON3])
 838         AS_IF([test -z "$PYTHON3_BIN"], [
 839                 AS_IF([test -z "$test_python3_agent_autodetect"],[
 840                         AC_MSG_ERROR([No python3 interpreter found. PYTHON3 can be set to override default interpreter path])
 841                 ])
 842         ], [
 843                 AC_MSG_CHECKING([for python3 lttng-ust agent])
 844                 AS_IF([$PYTHON3_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
 845                         PYTHON3_AGENT=$PYTHON3_BIN
 846                         AC_MSG_RESULT([yes])
 847                         RUN_PYTHON_AGENT_TEST=yes
 848                 ], [
 849                         AC_MSG_RESULT([no])
 850                         AS_IF([test -z "$test_python3_agent_autodetect"],[
 851                                 AC_MSG_ERROR([No python3 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
 852                         ])
 853                 ])
 854
 855         ])
 856 ])
 857 AC_SUBST([RUN_PYTHON_AGENT_TEST])
 858 AC_SUBST([PYTHON2_AGENT])
 859 AC_SUBST([PYTHON3_AGENT])
 860
 861 # Arguments for binaries build exclusion
 862 AC_ARG_ENABLE([bin-lttng], AS_HELP_STRING([--disable-bin-lttng],[Disable the build of lttng binaries]))
 863 AC_ARG_ENABLE([bin-lttng-consumerd], AS_HELP_STRING([--disable-bin-lttng-consumerd],
 864               [Disable the build of lttng-consumerd binaries]))
 865 AC_ARG_ENABLE([bin-lttng-crash], AS_HELP_STRING([--disable-bin-lttng-crash],[Disable the build of lttng-crash binaries]))
 866 AC_ARG_ENABLE([bin-lttng-relayd], AS_HELP_STRING([--disable-bin-lttng-relayd],
 867               [Disable the build of lttng-relayd binaries]))
 868 AC_ARG_ENABLE([bin-lttng-sessiond], AS_HELP_STRING([--disable-bin-lttng-sessiond],
 869               [Disable the build of lttng-sessiond binaries]))
 870 AC_ARG_ENABLE([extras], AS_HELP_STRING([--disable-extras],
 871               [Disable the build of the extra components]))
 872
 873
 874 # Always build libconfig since it a dependency of libcommon
 875 build_lib_config=yes
 876
 877 build_lib_compat=no
 878 build_lib_consumer=no
 879 build_lib_hashtable=no
 880 build_lib_health=no
 881 build_lib_index=no
 882 build_lib_kernel_consumer=no
 883 build_lib_kernel_ctl=no
 884 build_lib_lttng_ctl=no
 885 build_lib_relayd=no
 886 build_lib_sessiond_comm=no
 887 build_lib_testpoint=no
 888 build_lib_ust_consumer=no
 889
 890 # There is an overlap for enabled dependencies, but this makes everything
 891 # simpler. libcommon and libconfig are always compiled so they are not repeated
 892 # here.
 893
 894 # Enable binary dependencies.
 895 AS_IF([test x$enable_bin_lttng != xno],
 896       [
 897        build_lib_lttng_ctl=yes
 898       ]
 899 )
 900
 901 AS_IF([test x$enable_bin_lttng_consumerd != xno],
 902       [
 903        build_lib_consumer=yes
 904        build_lib_sessiond_comm=yes
 905        build_lib_index=yes
 906        build_lib_health=yes
 907        build_lib_testpoint=yes
 908       ]
 909 )
 910
 911 AS_IF([test x$enable_bin_lttng_crash != xno],
 912       # Do nothing since libconfig and libcommon are built by default.
 913       []
 914 )
 915
 916 AS_IF([test x$enable_bin_lttng_relayd != xno],
 917       [
 918        build_lib_lttng_ctl=yes
 919        build_lib_sessiond_comm=yes
 920        build_lib_hashtable=yes
 921        build_lib_compat=yes
 922        build_lib_index=yes
 923        build_lib_health=yes
 924        build_lib_testpoint=yes
 925       ]
 926 )
 927 AS_IF([test x$enable_bin_lttng_sessiond != xno],
 928       [
 929        build_lib_lttng_ctl=yes
 930        build_lib_sessiond_comm=yes
 931        build_lib_kernel_ctl=yes
 932        build_lib_hashtable=yes
 933        build_lib_compat=yes
 934        build_lib_relayd=yes
 935        build_lib_testpoint=yes
 936        build_lib_health=yes
 937       ]
 938 )
 939
 940 # Libraries dependencies enabling
 941 AS_IF([test x$build_lib_lttng_ctl = xyes],
 942       [
 943        build_lib_sessiond_comm=yes
 944        build_lib_hashtable=yes
 945       ]
 946 )
 947
 948 AS_IF([test x$build_lib_consumer = xyes],
 949       [
 950        build_lib_sessiond_comm=yes
 951        build_lib_kernel_consumer=yes
 952        build_lib_hashtable=yes
 953        build_lib_compat=yes
 954        build_lib_relayd=yes
 955        AS_IF([test "x$with_lttng_ust" = "xyes"], [build_lib_ust_consumer=yes])
 956       ]
 957 )
 958
 959 AS_IF([test x$build_lib_kernel_consumer = xyes],
 960       [
 961        build_lib_kernel_ctl=yes
 962        build_lib_relayd=yes
 963       ]
 964 )
 965
 966 AS_IF([test x$build_lib_relayd = xyes],
 967       [
 968        build_lib_sessiond_comm=yes
 969       ]
 970 )
 971
 972 # Find arch type
 973 AS_CASE([$host_cpu],
 974         [k1om], [ARCHTYPE="x86"],
 975         [i386], [ARCHTYPE="x86"],
 976         [i486], [ARCHTYPE="x86"],
 977         [i586], [ARCHTYPE="x86"],
 978         [i686], [ARCHTYPE="x86"],
 979         [amd64], [ARCHTYPE="x86"],
 980         [x86_64], [ARCHTYPE="x86"],
 981         [powerpc], [ARCHTYPE="ppc"],
 982         [ppc64], [ARCHTYPE="ppc"],
 983         [powerpc64], [ARCHTYPE="ppc"],
 984         [powerpc64le], [ARCHTYPE="ppc"],
 985         [ppc], [ARCHTYPE="ppc"],
 986         [s390], [ARCHTYPE="s390"],
 987         [s390x], [ARCHTYPE="s390"],
 988         [sparc], [ARCHTYPE="sparc64"],
 989         [sparc64], [ARCHTYPE="sparc64"],
 990         [alpha*], [ARCHTYPE="alpha"],
 991         [ia64], [ARCHTYPE="ia64"],
 992         [arm*], [ARCHTYPE="arm"],
 993         [aarch64*], [ARCHTYPE="aarch64"],
 994         [mips*], [ARCHTYPE="mips"],
 995         [nios2*], [ARCHTYPE="nios2"],
 996         [tile*], [ARCHTYPE="tile"],
 997         [hppa*], [ARCHTYPE="hppa"],
 998         [m68k], [ARCHTYPE="m68k"],
 999         [riscv*], [ARCHTYPE="riscv"],
1000         [ARCHTYPE="unknown"]
1001 )
1002
1003 AC_SUBST(ARCHTYPE)
1004
1005 AH_TEMPLATE([HAVE_MODULES_USERSPACE_CALLSTACK_CONTEXT], [Define if you have LTTng-modules userspace callstack tracing support])
1006 AC_MSG_CHECKING([for architecture support of userspace callstack tracing from the kernel])
1007 AS_IF([test "x$ARCHTYPE" = "xx86"],[
1008         # Userspace callstack capture is only supported by the Linux kernel on x86.
1009         AC_MSG_RESULT([yes])
1010         have_modules_userspace_callstack_context=yes
1011         AC_DEFINE([HAVE_MODULES_USERSPACE_CALLSTACK_CONTEXT], [1])
1012 ], [
1013         AC_MSG_RESULT([no])
1014         have_modules_userspace_callstack_context=no
1015 ])
1016 AM_CONDITIONAL([HAVE_MODULES_USERSPACE_CALLSTACK_CONTEXT], [test x$have_modules_userspace_callstack_context != xno])
1017
1018 # Export binaries build conditions.
1019 AM_CONDITIONAL([BUILD_BIN_LTTNG], [test x$enable_bin_lttng != xno])
1020 AM_CONDITIONAL([BUILD_BIN_LTTNG_CONSUMERD], [test x$enable_bin_lttng_consumerd != xno])
1021 AM_CONDITIONAL([BUILD_BIN_LTTNG_CRASH], [test x$enable_bin_lttng_crash != xno])
1022 AM_CONDITIONAL([BUILD_BIN_LTTNG_RELAYD], [test x$enable_bin_lttng_relayd != xno])
1023 AM_CONDITIONAL([BUILD_BIN_LTTNG_SESSIOND], [test x$enable_bin_lttng_sessiond != xno])
1024
1025 # Export the tests and extras build conditions.
1026 AS_IF([\
1027 test "x$enable_bin_lttng" != "xno" && \
1028 test "x$enable_bin_lttng_consumerd" != "xno" && \
1029 test "x$enable_bin_lttng_crash" != "xno" && \
1030 test "x$enable_bin_lttng_relayd" != "xno" && \
1031 test "x$enable_bin_lttng_sessiond" != "xno"],
1032 [build_tests=yes],
1033 [build_tests=no]
1034 )
1035
1036 AM_CONDITIONAL([BUILD_TESTS], [test x$build_tests = xyes])
1037 AM_CONDITIONAL([BUILD_EXTRAS], [test x$enable_extras != xno])
1038
1039 # Export libraries build conditions.
1040 AM_CONDITIONAL([BUILD_LIB_COMPAT], [test x$build_lib_compat = xyes])
1041 AM_CONDITIONAL([BUILD_LIB_CONFIG], [test x$build_lib_config = xyes])
1042 AM_CONDITIONAL([BUILD_LIB_CONSUMER], [test x$build_lib_consumer = xyes])
1043 AM_CONDITIONAL([BUILD_LIB_HASHTABLE], [test x$build_lib_hashtable = xyes])
1044 AM_CONDITIONAL([BUILD_LIB_HEALTH], [test x$build_lib_health = xyes])
1045 AM_CONDITIONAL([BUILD_LIB_INDEX], [test x$build_lib_index = xyes])
1046 AM_CONDITIONAL([BUILD_LIB_KERNEL_CONSUMER], [test x$build_lib_kernel_consumer = xyes])
1047 AM_CONDITIONAL([BUILD_LIB_KERNEL_CTL], [test x$build_lib_kernel_ctl = xyes])
1048 AM_CONDITIONAL([BUILD_LIB_LTTNG_CTL], [test x$build_lib_lttng_ctl = xyes])
1049 AM_CONDITIONAL([BUILD_LIB_RELAYD], [test x$build_lib_relayd = xyes])
1050 AM_CONDITIONAL([BUILD_LIB_SESSIOND_COMM], [test x$build_lib_sessiond_comm = xyes])
1051 AM_CONDITIONAL([BUILD_LIB_TESTPOINT], [test x$build_lib_testpoint = xyes])
1052 AM_CONDITIONAL([BUILD_LIB_UST_CONSUMER], [test x$build_lib_ust_consumer = xyes])
1053
1054 AM_CFLAGS="-Wall -fno-strict-aliasing $PTHREAD_CFLAGS"
1055 AC_SUBST(AM_CFLAGS)
1056
1057 AM_CPPFLAGS="-I\$(top_srcdir)/include -I\$(top_builddir)/include -I\$(top_srcdir)/src -include config.h $AM_CPPFLAGS"
1058 AC_SUBST(AM_CPPFLAGS)
1059
1060 lttngincludedir="${includedir}/lttng"
1061 AC_SUBST(lttngincludedir)
1062
1063 lttngactionincludedir="${includedir}/lttng/action"
1064 AC_SUBST(lttngactionincludedir)
1065
1066 lttngconditionincludedir="${includedir}/lttng/condition"
1067 AC_SUBST(lttngconditionincludedir)
1068
1069 lttngnotificationincludedir="${includedir}/lttng/notification"
1070 AC_SUBST(lttngnotificationincludedir)
1071
1072 lttngtriggerincludedir="${includedir}/lttng/trigger"
1073 AC_SUBST(lttngtriggerincludedir)
1074
1075 lttnglibexecdir="${libdir}/lttng/libexec"
1076 AC_SUBST(lttnglibexecdir)
1077
1078 AC_CONFIG_FILES([
1079         Makefile
1080         doc/Makefile
1081         doc/man/Makefile
1082         doc/man/asciidoc-attrs.conf
1083         include/Makefile
1084         extras/Makefile
1085         extras/bindings/Makefile
1086         extras/bindings/swig/Makefile
1087         extras/bindings/swig/python/Makefile
1088         extras/core-handler/Makefile
1089         src/Makefile
1090         src/common/Makefile
1091         src/common/kernel-ctl/Makefile
1092         src/common/kernel-consumer/Makefile
1093         src/common/consumer/Makefile
1094         src/common/ust-consumer/Makefile
1095         src/common/hashtable/Makefile
1096         src/common/sessiond-comm/Makefile
1097         src/common/compat/Makefile
1098         src/common/relayd/Makefile
1099         src/common/testpoint/Makefile
1100         src/common/index/Makefile
1101         src/common/health/Makefile
1102         src/common/config/Makefile
1103         src/common/string-utils/Makefile
1104         src/lib/Makefile
1105         src/lib/lttng-ctl/Makefile
1106         src/lib/lttng-ctl/filter/Makefile
1107         src/lib/lttng-ctl/lttng-ctl.pc
1108         src/bin/Makefile
1109         src/bin/lttng-consumerd/Makefile
1110         src/bin/lttng-sessiond/Makefile
1111         src/bin/lttng-relayd/Makefile
1112         src/bin/lttng/Makefile
1113         src/bin/lttng-crash/Makefile
1114         tests/Makefile
1115         tests/destructive/Makefile
1116         tests/regression/Makefile
1117         tests/regression/kernel/Makefile
1118         tests/regression/tools/Makefile
1119         tests/regression/tools/streaming/Makefile
1120         tests/regression/tools/filtering/Makefile
1121         tests/regression/tools/health/Makefile
1122         tests/regression/tools/tracefile-limits/Makefile
1123         tests/regression/tools/snapshots/Makefile
1124         tests/regression/tools/live/Makefile
1125         tests/regression/tools/exclusion/Makefile
1126         tests/regression/tools/save-load/Makefile
1127         tests/regression/tools/save-load/configuration/Makefile
1128         tests/regression/tools/mi/Makefile
1129         tests/regression/tools/wildcard/Makefile
1130         tests/regression/tools/crash/Makefile
1131         tests/regression/tools/regen-metadata/Makefile
1132         tests/regression/tools/regen-statedump/Makefile
1133         tests/regression/tools/notification/Makefile
1134         tests/regression/tools/rotation/Makefile
1135         tests/regression/tools/base-path/Makefile
1136         tests/regression/ust/Makefile
1137         tests/regression/ust/nprocesses/Makefile
1138         tests/regression/ust/high-throughput/Makefile
1139         tests/regression/ust/low-throughput/Makefile
1140         tests/regression/ust/before-after/Makefile
1141         tests/regression/ust/buffers-pid/Makefile
1142         tests/regression/ust/periodical-metadata-flush/Makefile
1143         tests/regression/ust/multi-session/Makefile
1144         tests/regression/ust/multi-lib/Makefile
1145         tests/regression/ust/overlap/Makefile
1146         tests/regression/ust/overlap/demo/Makefile
1147         tests/regression/ust/linking/Makefile
1148         tests/regression/ust/daemon/Makefile
1149         tests/regression/ust/exit-fast/Makefile
1150         tests/regression/ust/fork/Makefile
1151         tests/regression/ust/libc-wrapper/Makefile
1152         tests/regression/ust/baddr-statedump/Makefile
1153         tests/regression/ust/ust-dl/Makefile
1154         tests/regression/ust/java-jul/Makefile
1155         tests/regression/ust/java-log4j/Makefile
1156         tests/regression/ust/python-logging/Makefile
1157         tests/regression/ust/getcpu-override/Makefile
1158         tests/regression/ust/clock-override/Makefile
1159         tests/regression/ust/type-declarations/Makefile
1160         tests/regression/ust/rotation-destroy-flush/Makefile
1161         tests/regression/ust/blocking/Makefile
1162         tests/stress/Makefile
1163         tests/unit/Makefile
1164         tests/unit/ini_config/Makefile
1165         tests/perf/Makefile
1166         tests/utils/Makefile
1167         tests/utils/tap/Makefile
1168         tests/utils/testapp/Makefile
1169         tests/utils/testapp/gen-ust-events/Makefile
1170         tests/utils/testapp/gen-syscall-events-callstack/Makefile
1171         tests/utils/testapp/gen-ust-nevents/Makefile
1172         tests/utils/testapp/gen-ust-nevents-str/Makefile
1173         tests/utils/testapp/gen-syscall-events/Makefile
1174         tests/utils/testapp/gen-ust-tracef/Makefile
1175         tests/utils/testapp/userspace-probe-elf-binary/Makefile
1176         tests/utils/testapp/userspace-probe-elf-cxx-binary/Makefile
1177         tests/utils/testapp/userspace-probe-sdt-binary/Makefile
1178 ])
1179
1180 # Inject variable into python test script.
1181 AC_CONFIG_FILES([tests/regression/ust/python-logging/test_python_logging],[chmod +x tests/regression/ust/python-logging/test_python_logging])
1182 # Inject LTTNG_TOOLS_BUILD_WITH_LIBPFM variable in test script.
1183 AC_CONFIG_FILES([tests/perf/test_perf_raw],[chmod +x tests/perf/test_perf_raw])
1184 AC_CONFIG_FILES([tests/regression/ust/ust-dl/test_ust-dl],[chmod +x tests/regression/ust/ust-dl/test_ust-dl])
1185
1186 AC_OUTPUT
1187
1188 #
1189 # Mini-report on what will be built.
1190 #
1191
1192 PPRINT_INIT
1193 PPRINT_SET_INDENT(1)
1194 PPRINT_SET_TS(38)
1195
1196 AS_ECHO
1197 AS_ECHO("${PPRINT_COLOR_BLDBLU}LTTng-tools $PACKAGE_VERSION \"$version_name\"$PPRINT_COLOR_RST")
1198 AS_ECHO
1199
1200 AS_IF([test -n "$report_fold"], [
1201         AS_ECHO("`AS_ECHO("$version_description") | $report_fold -s`")
1202 ], [
1203         AS_ECHO("$version_description")
1204 ])
1205
1206 AS_ECHO
1207 PPRINT_SUBTITLE([Features])
1208
1209 # Target architecture we're building for.
1210 target_arch=$host_cpu
1211 [
1212 for f in $CFLAGS; do
1213         if test $f = "-m32"; then
1214                         target_arch="32-bit"
1215         elif test $f = "-m64"; then
1216                         target_arch="64-bit"
1217         fi
1218 done
1219 ]
1220 PPRINT_PROP_STRING([Target architecture], $target_arch)
1221
1222 # kmod enabled/disabled
1223 test "x$with_kmod" != "xno" && value=1 || value=0
1224 PPRINT_PROP_BOOL([libkmod support], $value)
1225
1226 # LTTng-UST enabled/disabled
1227 test "x$with_lttng_ust" = "xyes" && value=1 || value=0
1228 PPRINT_PROP_BOOL([LTTng-UST support], $value)
1229
1230 AS_ECHO
1231 PPRINT_SUBTITLE([Binaries])
1232
1233 # List binaries to be built
1234 test x$enable_bin_lttng != xno && value=1 || value=0
1235 PPRINT_PROP_BOOL([lttng], $value)
1236
1237 test x$enable_bin_lttng_consumerd != xno && value=1 || value=0
1238 PPRINT_PROP_BOOL([lttng-consumerd], $value)
1239
1240 test x$enable_bin_lttng_crash != xno && value=1 || value=0
1241 PPRINT_PROP_BOOL([lttng-crash], $value)
1242
1243 test x$enable_bin_lttng_relayd != xno && value=1 || value=0
1244 PPRINT_PROP_BOOL([lttng-relayd], $value)
1245
1246 test x$enable_bin_lttng_sessiond != xno && value=1 || value=0
1247 PPRINT_PROP_BOOL([lttng-sessiond], $value)
1248
1249 # Extras
1250 test x$enable_extras != xno && value=1 || value=0
1251 AS_ECHO
1252 PPRINT_SET_INDENT(0)
1253 PPRINT_PROP_BOOL([Extras], $value, $PPRINT_COLOR_SUBTITLE)
1254 PPRINT_SET_INDENT(1)
1255
1256 AS_ECHO
1257 PPRINT_SUBTITLE([Tests])
1258
1259 # Print clear message that tests won't be built
1260 AS_IF([test "x$build_tests" = "xno"],[
1261         PPRINT_WARN([Tests won't be built since some binaries were disabled])
1262 ])
1263
1264 # LTTng UST Java agent JUL tests enabled/disabled
1265 test "x$test_java_agent_jul" = "xyes" && value=1 || value=0
1266 PPRINT_PROP_BOOL([LTTng-UST Java agent JUL tests], $value)
1267
1268 # LTTng UST Java agent Log4j tests enabled/disabled
1269 test "x$test_java_agent_log4j" = "xyes" && value=1 || value=0
1270 PPRINT_PROP_BOOL([LTTng-UST Java agent Log4j tests], $value)
1271
1272 test ! -z "$PYTHON2_AGENT" && value=1 || value=0
1273 PPRINT_PROP_BOOL([LTTng-UST Python2 agent tests], $value)
1274
1275 test ! -z "$PYTHON3_AGENT" && value=1 || value=0
1276 PPRINT_PROP_BOOL([LTTng-UST Python3 agent tests], $value)
1277
1278 #Python binding enabled/disabled
1279 test "x$enable_python_binding" = xyes && value=1 || value=0
1280 AS_ECHO
1281 PPRINT_SET_INDENT(0)
1282 PPRINT_PROP_BOOL([Python binding], $value, $PPRINT_COLOR_SUBTITLE)
1283
1284 # man pages build enabled/disabled
1285 m4_pushdef([build_man_pages_msg], [Build and install man pages])
1286
1287 AS_IF([test "x$man_pages_opt" != "xno"], [
1288         AS_IF([test "x$in_git_repo" = "xyes"], [
1289                 PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
1290         ], [
1291                 AS_IF([test "x$have_asciidoc_xmlto" = "xyes"], [
1292                         PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
1293                 ], [
1294                         PPRINT_PROP_STRING([build_man_pages_msg],
1295                                 [${PPRINT_COLOR_BLDGRN}yes (already built)],
1296                                 $PPRINT_COLOR_SUBTITLE)
1297                 ])
1298         ])
1299 ], [
1300         PPRINT_PROP_BOOL([build_man_pages_msg], 0, $PPRINT_COLOR_SUBTITLE)
1301 ])
1302
1303 m4_popdef([build_man_pages_msg])
1304
1305 test "x$embedded_help" = xyes && value=1 || value=0
1306 PPRINT_PROP_BOOL([Embed --help messages], $value, $PPRINT_COLOR_SUBTITLE)
1307
1308 PPRINT_SET_INDENT(1)
1309
1310 report_bindir="`eval eval echo $bindir`"
1311 report_libdir="`eval eval echo $libdir`"
1312
1313 # Print the bindir and libdir this `make install' will install into.
1314 AS_ECHO
1315 PPRINT_SUBTITLE([Install directories])
1316 PPRINT_PROP_STRING([Binaries], [$report_bindir])
1317 PPRINT_PROP_STRING([Libraries], [$report_libdir])
1318
1319 AS_ECHO
1320 PPRINT_SUBTITLE([Search directories])
1321
1322 # If we build the sessiond, print the paths it will use
1323 AS_IF([test "$SESSIOND_BIN" = ""],[
1324         path="$report_bindir/lttng-sessiond"
1325 ],[
1326         path="$SESSIOND_BIN"
1327 ])
1328 PPRINT_PROP_STRING([lttng-sessiond executable], [$path])
1329
1330 AS_IF([test "$CONSUMERD32_BIN" = ""],[
1331         path="`eval eval echo $lttnglibexecdir`/lttng-consumerd"
1332 ],[
1333         path="$CONSUMERD32_BIN"
1334 ])
1335 PPRINT_PROP_STRING([32-bit lttng-consumerd executable], [$path])
1336
1337 AS_IF([test "$CONSUMERD32_LIBDIR" = ""],[
1338         path="`eval eval echo $libdir`"
1339 ],[
1340         path="$CONSUMERD32_LIBDIR"
1341 ])
1342 PPRINT_PROP_STRING([32-bit consumer libraries], [$path])
1343
1344 AS_IF([test "$CONSUMERD64_BIN" = ""],[
1345         path="`eval eval echo $lttnglibexecdir`/lttng-consumerd"
1346 ],[
1347         path="$CONSUMERD64_BIN"
1348 ])
1349 PPRINT_PROP_STRING([64-bit lttng-consumerd executable], [$path])
1350
1351 AS_IF([test "$CONSUMERD64_LIBDIR" = ""],[
1352         path="`eval eval echo $libdir`"
1353 ],[
1354         path="$CONSUMERD64_LIBDIR"
1355 ])
1356 PPRINT_PROP_STRING([64-bit consumer libraries], [$path])
1357 PPRINT_SET_INDENT(0)
1358
1359 AS_IF([test "x$warn_prebuilt_man_pages" = "xyes" ], [
1360         AS_ECHO
1361         PPRINT_WARN([You need asciidoc and xmlto to build the LTTng-tools man pages.
1362
1363 Note that the man pages are already built in this distribution tarball,
1364 therefore asciidoc and xmlto are only needed if you intend to modify
1365 their sources.
1366
1367 Also note that the installed man pages will contain the project's
1368 default command-line option and environment variable values.
1369
1370 Use --disable-man-pages to completely disable building and installing
1371 the man pages.])
1372 ])