CLI: Import argpar
[lttng-tools.git] / configure.ac
1 dnl SPDX-License-Identifier: GPL-2.0-only
2 AC_PREREQ([2.64])
3 AC_INIT([lttng-tools],[2.13.0-pre],[jeremie.galarneau@efficios.com],[],[https://lttng.org])
4
5 AC_CONFIG_HEADERS([include/config.h])
6 AC_CONFIG_AUX_DIR([config])
7 AC_CONFIG_MACRO_DIR([m4])
8
9 AC_CANONICAL_TARGET
10 AC_CANONICAL_HOST
11
12 AM_INIT_AUTOMAKE([1.12 foreign dist-bzip2 no-dist-gzip tar-pax nostdinc])
13 AM_MAINTAINER_MODE([enable])
14
15 # Enable silent rules if available (Introduced in AM 1.11)
16 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
17
18 AC_REQUIRE_AUX_FILE([tap-driver.sh])
19
20 # Checks for C compiler
21 AC_USE_SYSTEM_EXTENSIONS
22 AC_SYS_LARGEFILE
23 AC_PROG_CC
24 # AC_PROG_CC_STDC was merged in AC_PROG_CC in autoconf 2.70
25 m4_version_prereq([2.70], [], [AC_PROG_CC_STDC])
26 AC_PROG_CXX
27 RW_PROG_CXX_WORKS
28 AM_CONDITIONAL([CXX_WORKS], [test "x$rw_cv_prog_cxx_works" = "xyes"])
29
30 # Detect warning flags supported by the compiler, append them to WARN_CFLAGS.
31 #
32 # Pass -Werror as an extra flag during the test: this is needed to make the
33 # -Wunknown-warning-option diagnostic fatal with clang.
34 AX_APPEND_COMPILE_FLAGS([ dnl
35 -Wall dnl
36 dnl We currently get this warning when building with Clang:
37 dnl
38 dnl /usr/include/setjmp.h:54:12: error: declaration of built-in function '__sigsetjmp' requires the declaration of the 'jmp_buf' type, commonly provided in the header <setjmp.h>. [-Werror,-Wincomplete-setjmp-declaration]
39 dnl extern int __sigsetjmp (struct __jmp_buf_tag __env[1], int __savemask) __THROWNL;
40 dnl ^
41 -Wno-incomplete-setjmp-declaration dnl
42 -Wdiscarded-qualifiers dnl
43 -Wmissing-declarations dnl
44 -Wmissing-prototypes dnl
45 -Wmissing-parameter-type dnl
46 -Wold-style-definition dnl
47 -Wstrict-prototypes dnl
48 ],
49 [WARN_CFLAGS],
50 [-Werror])
51
52 # When given, add -Werror to WARN_CFLAGS.
53 AC_ARG_ENABLE([Werror],
54 [AS_HELP_STRING([--enable-Werror], [Treat compiler warnings as errors.])]
55 )
56 AS_IF([test "x$enable_Werror" = "xyes"],
57 [WARN_CFLAGS="${WARN_CFLAGS} -Werror"]
58 )
59
60 # Checks for programs.
61 AC_PROG_GREP
62 AC_PROG_MAKE_SET
63 AC_PROG_SED
64 AC_PATH_PROG([report_fold], [fold])
65 LT_INIT
66
67 # Check for objcopy, required by the base address statedump and dynamic linker tests
68 AC_CHECK_TOOL([OBJCOPY], [objcopy], [no])
69 AS_IF([test "x$OBJCOPY" = "xno"],
70 [AC_MSG_WARN([Cannot find objcopy. The base address statedump and dynamic linker tests will be disabled. Install the binutils package to remediate this.])]
71 )
72 AM_CONDITIONAL([HAVE_OBJCOPY], [test "x$OBJCOPY" != xno])
73
74 # check for pgrep
75 AC_PATH_PROG([PGREP], [pgrep], [no])
76 AM_CONDITIONAL([HAVE_PGREP], [test "x$PGREP" != "xno"])
77
78 # set $IN_GIT_REPO if we're in the Git repository; the `bootstrap` file
79 # is not distributed in tarballs
80 AS_IF([test -f "$srcdir/bootstrap"], [in_git_repo=yes], [in_git_repo=no])
81 AM_CONDITIONAL([IN_GIT_REPO], [test "x$in_git_repo" = "xyes"])
82
83 # check for bison
84 AC_PROG_YACC
85 BISON=$YACC
86 AX_PROG_BISON_VERSION([2.4], [have_bison=yes])
87
88 AS_IF([test "x$have_bison" != "xyes"], [
89 AS_IF([test "x$in_git_repo" = "xyes"], [
90 AC_MSG_FAILURE([
91 Bison >= 2.4 is required when building from the Git repository. You can
92 set the YACC variable to override automatic detection.
93 ])
94 ], [
95 AC_MSG_WARN([
96 Missing Bison >= 2.4. Note that the parser files are already built in
97 this distribution tarball, so Bison is only needed if you intend to
98 modify their sources. You can set the YACC variable to override automatic
99 detection.
100 ])
101 ])
102 ])
103 AM_CONDITIONAL([HAVE_BISON], [test "x$have_bison" = "xyes"])
104
105 # check for flex
106 # Prior to autoconf 2.70, AC_PROG_FLEX did not take an argument. This is not a
107 # problem since the argument is silently ignored by older versions.
108 AC_PROG_LEX([noyywrap])
109 FLEX=$LEX
110 AX_PROG_FLEX_VERSION([2.5.35], [have_flex=yes])
111
112 AS_IF([test "x$have_flex" != "xyes"], [
113 AS_IF([test "x$in_git_repo" = "xyes"], [
114 AC_MSG_FAILURE([
115 Flex >= 2.5.35 is required when building from the Git repository. You can
116 set the LEX variable to override automatic detection.
117 ])
118 ], [
119 AC_MSG_WARN([
120 Missing Flex >= 2.5.35. Note that the lexer files are already built in
121 this distribution tarball, so Flex is only needed if you intend to
122 modify their sources. You can set the LEX variable to override automatic
123 detection.
124 ])
125 ])
126 ])
127 AM_CONDITIONAL([HAVE_FLEX], [test "x$have_flex" = "xyes"])
128
129
130 # Checks for typedefs, structures, and compiler characteristics.
131 AC_C_INLINE
132 AC_TYPE_INT32_T
133 AC_TYPE_INT64_T
134 AC_TYPE_MODE_T
135 AC_TYPE_OFF_T
136 AC_TYPE_PID_T
137 AC_TYPE_SIZE_T
138 AC_TYPE_SSIZE_T
139 AC_TYPE_UID_T
140 AC_TYPE_UINT16_T
141 AC_TYPE_UINT32_T
142 AC_TYPE_UINT64_T
143 AC_TYPE_UINT8_T
144
145 AX_C___ATTRIBUTE__
146 AS_IF([test "x$ax_cv___attribute__" = "xyes"],
147 [:],
148 [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
149
150 AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])
151
152 # Check if linker has the -no-pie option.
153 AX_CHECK_LINK_FLAG([-no-pie], [linker_have_no_pie_option=yes])
154 AM_CONDITIONAL([LINKER_HAVE_NO_PIE_OPTION], [test "x$linker_have_no_pie_option" = "xyes"])
155
156 AX_LIB_SOCKET_NSL
157
158 LT_NO_UNDEFINED=""
159 AS_CASE([$host_os],
160 [cygwin*],
161 [
162 LT_NO_UNDEFINED="-no-undefined"
163 ],
164 [cygwin*|darwin*|mingw*|solaris*],
165 [
166 # On platforms where we only support the relayd, disable the other binaries by default
167 AS_IF([test "x$enable_bin_lttng" = "x" ], [enable_bin_lttng=no])
168 AS_IF([test "x$enable_bin_lttng_consumerd" = "x" ], [enable_bin_lttng_consumerd=no])
169 AS_IF([test "x$enable_bin_lttng_crash" = "x" ], [enable_bin_lttng_crash=no])
170 AS_IF([test "x$enable_bin_lttng_sessiond" = "x" ], [enable_bin_lttng_sessiond=no])
171 AS_IF([test "x$enable_extras" = "x" ], [enable_extras=no])
172 AS_IF([test "x$with_lttng_ust" = "x" ], [with_lttng_ust=no])
173 ]
174 )
175
176 AC_SUBST(LT_NO_UNDEFINED)
177
178 # Compute minor/major/patchlevel version numbers
179 major_version=$(echo AC_PACKAGE_VERSION | $SED 's/^\([[0-9]]\)*\.[[0-9]]*\.[[0-9]]*.*$/\1/')
180 minor_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.\([[0-9]]*\)\.[[0-9]]*.*$/\1/')
181 patchlevel_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\).*$/\1/')
182
183 AC_SUBST([MAJOR_VERSION], [$major_version])
184 AC_SUBST([MINOR_VERSION], [$minor_version])
185 AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version])
186 AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [LTTng-Tools major version number])
187 AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [LTTng-Tools minor version number])
188 AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [LTTng-Tools patchlevel version number])
189
190 version_name="N-Beer"
191 version_description="An alcoholic drink made from yeast-fermented malt flavored with hops."
192 version_description_c=$(echo $version_description | $SED 's/"/\\"/g')
193
194 AC_DEFINE_UNQUOTED([VERSION_NAME], ["$version_name"], "")
195 AC_DEFINE_UNQUOTED([VERSION_DESCRIPTION], ["$version_description_c"], "")
196
197 # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
198 AC_ARG_ENABLE(libtool-linkdep-fixup,
199 AS_HELP_STRING([--disable-libtool-linkdep-fixup],
200 [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)]),
201 libtool_fixup=$enableval,
202 libtool_fixup=yes)
203
204 AS_IF([test "x$libtool_fixup" = "xyes"],
205 [
206 libtool_m4="$srcdir/m4/libtool.m4"
207 libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
208 AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
209 libtool_flag_pattern_count=$($GREP -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
210 AS_IF([test $libtool_flag_pattern_count -ne 0],
211 [
212 AC_MSG_RESULT([$libtool_flag_pattern_count])
213 AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
214 $SED -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
215 ],
216 [
217 AC_MSG_RESULT([none])
218 ])
219 ])
220
221 AM_CONDITIONAL([NO_SHARED], [test x$enable_shared = xno])
222
223 AC_CHECK_HEADERS([ \
224 sys/types.h unistd.h fcntl.h string.h pthread.h limits.h \
225 signal.h stdlib.h sys/un.h sys/socket.h stdlib.h stdio.h \
226 getopt.h sys/ipc.h sys/shm.h popt.h grp.h arpa/inet.h \
227 netdb.h netinet/in.h paths.h stddef.h sys/file.h sys/ioctl.h \
228 sys/mount.h sys/param.h sys/time.h elf.h
229 ])
230
231 AM_CONDITIONAL([HAVE_ELF_H], [test x$ac_cv_header_elf_h = xyes])
232
233 # Basic functions check
234 AC_CHECK_FUNCS([ \
235 atexit bzero clock_gettime dup2 fdatasync fls ftruncate \
236 gethostbyname gethostname getpagesize localtime_r memchr memrchr memset \
237 mkdir munmap putenv realpath rmdir socket strchr strcspn strdup \
238 strncasecmp strndup strnlen strpbrk strrchr strstr strtol strtoul \
239 strtoull dirfd gethostbyname2 getipnodebyname epoll_create1 \
240 sched_getcpu sysconf sync_file_range
241 ])
242
243 # Check for pthread_setname_np and pthread_getname_np
244 LTTNG_PTHREAD_SETNAME_NP
245 LTTNG_PTHREAD_GETNAME_NP
246
247 # Check if clock_gettime, timer_create, timer_settime, and timer_delete are available in lib rt, and if so,
248 # add -lrt to LIBS
249 AC_CHECK_LIB([rt], [clock_gettime, timer_create, timer_settime, timer_delete])
250
251 # Checks for dl.
252 AC_CHECK_LIB([dl], [dlopen], [
253 have_libdl=yes
254 libdl_name=dl
255 DL_LIBS="-ldl"
256 ], [
257 # libdl not found, check for dlopen in libc.
258 AC_CHECK_LIB([c], [dlopen], [
259 have_libc_dl=yes
260 libdl_name=c
261 DL_LIBS="-lc"
262 ], [
263 AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
264 ])
265 ])
266 AC_SUBST(DL_LIBS)
267
268 # Check if libdl has dlmopen support.
269 AH_TEMPLATE([HAVE_DLMOPEN], ["Define to 1 if dlmopen is available."])
270 AC_CHECK_LIB([$libdl_name], [dlmopen], [
271 AC_DEFINE([HAVE_DLMOPEN], [1])
272 HAVE_DLMOPEN=1
273 ], [
274 HAVE_DLMOPEN=0
275 ])
276 AC_SUBST(HAVE_DLMOPEN)
277
278 # Babeltrace viewer check
279 AC_ARG_WITH([babeltrace-bin],
280 AS_HELP_STRING([--with-babeltrace-bin],
281 [Location of the babeltrace viewer executable (including the filename)]),
282 [BABELTRACE_BIN="$withval"],
283 [BABELTRACE_BIN=''])
284 AC_SUBST([BABELTRACE_BIN])
285
286 AC_ARG_WITH([babeltrace2-bin],
287 AS_HELP_STRING([--with-babeltrace2-bin],
288 [Location of the babeltrace2 viewer executable (including the filename)]),
289 [BABELTRACE2_BIN="$withval"],
290 [BABELTRACE2_BIN=''])
291 AC_SUBST([BABELTRACE2_BIN])
292
293 AC_ARG_WITH([consumerd32-bin],
294 AS_HELP_STRING([--with-consumerd32-bin],
295 [Location of the 32-bit consumerd executable (including the filename)]),
296 [CONSUMERD32_BIN="$withval"],
297 [CONSUMERD32_BIN=''])
298 AC_SUBST([CONSUMERD32_BIN])
299
300 AC_ARG_WITH([consumerd64-bin],
301 AS_HELP_STRING([--with-consumerd64-bin],
302 [Location of the 64-bit consumerd executable (including the filename)]),
303 [CONSUMERD64_BIN="$withval"],
304 [CONSUMERD64_BIN=''])
305 AC_SUBST([CONSUMERD64_BIN])
306
307 AC_ARG_WITH([consumerd32-libdir],
308 AS_HELP_STRING([--with-consumerd32-libdir],
309 [Directory containing the 32-bit consumerd libraries]),
310 [CONSUMERD32_LIBDIR="$withval"],
311 [CONSUMERD32_LIBDIR=''])
312 AC_SUBST([CONSUMERD32_LIBDIR])
313
314 AC_ARG_WITH([consumerd64-libdir],
315 AS_HELP_STRING([--with-consumerd64-libdir],
316 [Directory containing the 64-bit consumerd libraries]),
317 [CONSUMERD64_LIBDIR="$withval"],
318 [CONSUMERD64_LIBDIR=''])
319 AC_SUBST([CONSUMERD64_LIBDIR])
320
321 AC_ARG_WITH([sessiond-bin],
322 AS_HELP_STRING([--with-sessiond-bin],
323 [Location of the sessiond executable (including the filename)]),
324 [SESSIOND_BIN="$withval"],
325 [SESSIOND_BIN=''])
326 AC_SUBST([SESSIOND_BIN])
327
328 AC_ARG_WITH([lttng-system-rundir],
329 AS_HELP_STRING([--with-lttng-system-rundir],
330 [Location of the system directory where the system-wide lttng-sessiond runtime files are kept. The default is "/var/run/lttng".]),
331 [LTTNG_SYSTEM_RUNDIR="$withval"],
332 [LTTNG_SYSTEM_RUNDIR="/var/run/lttng"])
333 AC_SUBST([LTTNG_SYSTEM_RUNDIR])
334
335 AC_ARG_ENABLE([test-java-agent-jul],
336 [AS_HELP_STRING([--enable-test-java-agent-jul],[enable the LTTng UST Java agent JUL tests [default=no]])],
337 [test_java_agent_jul=$enableval],
338 [test_java_agent_jul=no]
339 )
340
341 AC_ARG_ENABLE([test-java-agent-log4j],
342 [AS_HELP_STRING([--enable-test-java-agent-log4j],[enable the LTTng UST Java agent Log4j tests [default=no]])],
343 [test_java_agent_log4j=$enableval],
344 [test_java_agent_log4j=no]
345 )
346
347 AC_ARG_ENABLE([test-java-agent-all],
348 [AS_HELP_STRING([--enable-test-java-agent-all],[enable all the LTTng UST Java agent tests [default=no]])],
349 [test_java_agent_jul=$enableval
350 test_java_agent_log4j=$enableval],
351 [:]
352 )
353
354 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_BIN], "$CONSUMERD32_BIN", [Location of the 32-bit consumerd executable.])
355 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_BIN], "$CONSUMERD64_BIN", [Location of the 64-bit consumerd executable])
356 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_LIBDIR], "$CONSUMERD32_LIBDIR", [Search for consumerd 32-bit libraries in this location.])
357 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_LIBDIR], "$CONSUMERD64_LIBDIR", [Search for consumerd 64-bit libraries in this location.])
358 AC_DEFINE_UNQUOTED([CONFIG_BABELTRACE_BIN], "$BABELTRACE_BIN", [Location of the babeltrace viewer executable.])
359 AC_DEFINE_UNQUOTED([CONFIG_BABELTRACE2_BIN], "$BABELTRACE2_BIN", [Location of the babeltrace2 viewer executable.])
360 AC_DEFINE_UNQUOTED([CONFIG_SESSIOND_BIN], "$SESSIOND_BIN", [Location of the sessiond executable.])
361 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_RUNDIR], ["$LTTNG_SYSTEM_RUNDIR"], [LTTng system runtime directory])
362
363 AC_DEFUN([_AC_DEFINE_AND_SUBST], [
364 AC_DEFINE_UNQUOTED([CONFIG_$1], [$2], [$1])
365 $1="$2"
366 AC_SUBST([$1])
367 ])
368
369 AC_DEFUN([_AC_DEFINE_QUOTED_AND_SUBST], [
370 AC_DEFINE_UNQUOTED([CONFIG_$1], ["$2"], [$1])
371 $1="$2"
372 AC_SUBST([$1])
373 ])
374
375 # Default values
376 m4_define([_DEFAULT_CHANNEL_SUBBUF_SIZE], [16384])
377 m4_define([_DEFAULT_CHANNEL_SUBBUF_NUM], [4])
378 m4_define([_DEFAULT_CHANNEL_SWITCH_TIMER], [0])
379 m4_define([_DEFAULT_CHANNEL_LIVE_TIMER], [0])
380 m4_define([_DEFAULT_CHANNEL_READ_TIMER], [200000])
381 m4_define([_DEFAULT_CHANNEL_MONITOR_TIMER], [1000000])
382 m4_define([_DEFAULT_CHANNEL_BLOCKING_TIMEOUT], [0])
383 _AC_DEFINE_AND_SUBST([DEFAULT_AGENT_TCP_PORT_RANGE_BEGIN], [5345])
384 _AC_DEFINE_AND_SUBST([DEFAULT_AGENT_TCP_PORT_RANGE_END], [5354])
385 _AC_DEFINE_AND_SUBST([DEFAULT_APP_SOCKET_RW_TIMEOUT], [5])
386 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE])
387 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_COUNT], [0])
388 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_SIZE], [0])
389 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
390 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_READ_TIMER], [_DEFAULT_CHANNEL_READ_TIMER])
391 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
392 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_SIZE], [1048576])
393 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
394 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
395 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_BLOCKING_TIMEOUT], [_DEFAULT_CHANNEL_BLOCKING_TIMEOUT])
396 _AC_DEFINE_AND_SUBST([DEFAULT_LTTNG_LIVE_TIMER], [1000000])
397 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_CACHE_SIZE], [4096])
398 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_READ_TIMER], [0])
399 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_NUM], [2])
400 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_SIZE], [4096])
401 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
402 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_CONTROL_PORT], [5342])
403 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_DATA_PORT], [5343])
404 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_VIEWER_PORT], [5344])
405 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
406 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_READ_TIMER], [0])
407 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_BLOCKING_TIMEOUT], [0])
408 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
409 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE])
410 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
411 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
412 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
413 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_READ_TIMER], [0])
414 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_BLOCKING_TIMEOUT], [0])
415 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
416 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_SIZE], [524288])
417 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
418 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
419 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_AGENT_BIND_ADDRESS], [localhost])
420 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_CONTROL_BIND_ADDRESS], [0.0.0.0])
421 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_DATA_BIND_ADDRESS], [0.0.0.0])
422 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_VIEWER_BIND_ADDRESS], [localhost])
423 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_RELAYD_CTRL_MAX_PAYLOAD_SIZE], [134217728])
424 _AC_DEFINE_AND_SUBST([DEFAULT_ROTATE_PENDING_TIMER], [500000])
425
426 # Command short descriptions
427 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ADD_CONTEXT], [Add context fields to a channel])
428 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_CREATE], [Create a tracing session])
429 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_CLEAR], [Clear a tracing session])
430 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DESTROY], [Tear down tracing sessions])
431 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_CHANNEL], [Disable tracing channels])
432 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_EVENT], [Disable event rules])
433 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_ROTATION], [Unset a rotation schedule])
434 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_CHANNEL], [Create or enable tracing channels])
435 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_EVENT], [Create or enable event rules])
436 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_ROTATION], [Set a rotation schedule])
437 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_HELP], [Display help information about a command])
438 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LIST], [List tracing sessions, domains, channels, and events])
439 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LOAD], [Load tracing session configurations])
440 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_REGENERATE], [Manage an LTTng tracing session's data regeneration])
441 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ROTATE], [Archive a tracing session's current trace chunk])
442 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SAVE], [Save tracing session configurations])
443 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SET_SESSION], [Set current tracing session])
444 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SNAPSHOT], [Snapshot buffers of current tracing session])
445 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_START], [Start tracing])
446 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STATUS], [Get the status of the current tracing session])
447 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STOP], [Stop tracing])
448 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_ROTATION], [Unset a rotation schedule])
449 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_ROTATION], [Set a rotation schedule])
450 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_TRACK], [Track specific system resources])
451 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_UNTRACK], [Untrack specific system resources])
452 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VERSION], [Show version information])
453 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VIEW], [Start trace viewer])
454
455 if test "x$prefix" = "xNONE"; then
456 prefix=$ac_default_prefix
457 fi
458 CONFDIR=`eval echo $sysconfdir`
459 AC_SUBST(CONFDIR)
460 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_CONFIGDIR],"$CONFDIR", [LTTng system configuration directory.])
461
462 AX_DEFINE_DIR([CONFIG_LTTNG_SYSTEM_DATADIR], [datadir], [LTTng system data directory.])
463
464 # Check libpopt
465 PKG_CHECK_MODULES([POPT], [popt],
466 [
467 dnl PKG_CHECK_MODULES defines POPT_LIBS
468 ],
469 [
470 AC_MSG_WARN([pkg-config was unable to find a valid .pc for libpopt. Set PKG_CONFIG_PATH to specify the pkgconfig configuration file location])
471 AC_MSG_WARN([Finding libpopt without pkg-config.])
472 AC_CHECK_LIB([popt],
473 [poptGetContext],
474 [POPT_LIBS="-lpopt"],
475 [
476 AC_MSG_FAILURE([Cannot find libpopt. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location])
477 ]
478 )
479 ]
480 )
481 AC_SUBST(POPT_LIBS)
482
483 PKG_CHECK_MODULES([libxml2], [libxml-2.0 >= 2.7.6])
484
485 AC_CHECK_FUNC([clock_gettime], [AC_DEFINE_UNQUOTED([LTTNG_HAVE_CLOCK_GETTIME], 1, [Has clock_gettime() support.])])
486
487 # URCU library version needed or newer
488 PKG_CHECK_MODULES([URCU], [liburcu >= 0.9])
489 PKG_CHECK_MODULES([URCU_BP], [liburcu-bp >= 0.9])
490 PKG_CHECK_MODULES([URCU_CDS], [liburcu-cds >= 0.9])
491 AM_CPPFLAGS="$AM_CPPFLAGS $URCU_CFLAGS"
492
493 # Check for libkmod, it will be auto-neabled if found but won't fail if it's not,
494 # it can be explicitly disabled with --without-kmod
495 AH_TEMPLATE([HAVE_KMOD], [Define if you have kmod support])
496 AC_ARG_WITH([kmod],
497 [AS_HELP_STRING([--with-kmod], [build with lkmod support @<:@default=check@:>@])],
498 [],
499 [with_kmod=check]
500 )
501
502 AS_IF([test "x$with_kmod" != "xno"],
503 [
504 AC_CHECK_LIB([kmod], [kmod_module_probe_insert_module],
505 [
506 AC_DEFINE([HAVE_KMOD], [1])
507 KMOD_LIBS="-lkmod"
508 ],
509 [
510 if test "x$with_kmod" != xcheck; then
511 AC_MSG_FAILURE([Cannot find libkmod. Use [LDFLAGS]=-Ldir and [CPPFLAGS]=-Idir to specify its location.])
512 else
513 with_kmod=no
514 fi
515 ]
516 )
517 ]
518 )
519 AC_SUBST(KMOD_LIBS)
520
521 # Check for liblttng-ust-ctl, fail if it's not found,
522 # it can be explicitly disabled with --without-lttng-ust
523 AH_TEMPLATE([HAVE_LIBLTTNG_UST_CTL], [Define if you have LTTng-UST control support])
524 AC_ARG_WITH([lttng-ust],
525 [AS_HELP_STRING([--without-lttng-ust], [build without LTTng-UST (Userspace Tracing) support])],
526 [],
527 [with_lttng_ust=yes]
528 )
529
530 AS_IF([test "x$with_lttng_ust" = "xyes"], [
531 AC_DEFINE([HAVE_LIBLTTNG_UST_CTL], [1])
532
533 # Check for liblttng-ust
534 PKG_CHECK_MODULES([UST], [lttng-ust >= $major_version.$minor_version])
535
536 # Check for liblttng-ust-ctl
537 PKG_CHECK_MODULES([UST_CTL], [lttng-ust-ctl >= $major_version.$minor_version])
538
539 AM_CPPFLAGS="$AM_CPPFLAGS $UST_CFLAGS"
540 ])
541
542 AM_CONDITIONAL([HAVE_LIBLTTNG_UST_CTL], [test "x$with_lttng_ust" = "xyes"])
543
544
545 # Check for fmemopen
546 AC_CHECK_LIB([c], [fmemopen],
547 [
548 AC_DEFINE_UNQUOTED([LTTNG_HAVE_FMEMOPEN], 1, [Has fmemopen support.])
549 ]
550 )
551
552 # check for libpfm
553 AC_CHECK_LIB([pfm], [pfm_initialize],
554 [
555 have_libpfm=yes
556 ])
557 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBPFM], [test "x$have_libpfm" = "xyes"])
558
559 # For Python
560 # SWIG version needed or newer:
561 swig_version=2.0.0
562
563 AC_ARG_ENABLE([python-bindings],
564 [AS_HELP_STRING([--enable-python-bindings],
565 [compile Python bindings])],
566 [enable_python_binding=$enableval], [enable_python_binding=no])
567
568 AM_CONDITIONAL([PYTHON_BINDING], [test "x$enable_python_binding" = xyes])
569
570 if test "x$enable_python_binding" = xyes; then
571 AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ])
572 AS_IF([test x$enable_shared = xno], [ AC_MSG_ERROR([Python bindings require shared libraries.]) ])
573 AM_PATH_PYTHON([3.0])
574
575 AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config])
576 AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
577 AS_IF([test -z "$PYTHON_INCLUDE"], [
578 AS_IF([test -z "$PYTHON_CONFIG"], [
579 AC_PATH_PROGS([PYTHON_CONFIG],
580 [python$PYTHON_VERSION-config python-config],
581 [no],
582 [`dirname $PYTHON`])
583 AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
584 ])
585 AC_MSG_CHECKING([python include flags])
586 PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
587 AC_MSG_RESULT([$PYTHON_INCLUDE])
588 ])
589
590 else
591 AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl
592 [if you want Python bindings.])
593
594 fi
595
596 # Epoll check. If not present, the build will fallback on poll() API
597 AX_HAVE_EPOLL(
598 [AX_CONFIG_FEATURE_ENABLE(epoll)],
599 [AX_CONFIG_FEATURE_DISABLE(epoll)]
600 )
601 AX_CONFIG_FEATURE(
602 [epoll], [This platform supports epoll(7)],
603 [HAVE_EPOLL], [This platform supports epoll(7).]
604 )
605
606 AS_IF([test "x$ac_cv_func_dirfd" = "xyes"],
607 [AX_CONFIG_FEATURE_ENABLE(dirfd)],
608 [AX_CONFIG_FEATURE_DISABLE(dirfd)]
609 )
610 AX_CONFIG_FEATURE(
611 [dirfd], [Use directory file descriptors],
612 [HAVE_DIRFD], [This platform supports directory file descriptors.]
613 )
614
615 AM_CONDITIONAL([TEST_JAVA_JUL_AGENT], [test "x$test_java_agent_jul" = "xyes"])
616 AM_CONDITIONAL([TEST_JAVA_LOG4J_AGENT], [test "x$test_java_agent_log4j" = "xyes"])
617
618 if test "x$test_java_agent_jul" = "xyes" || test "x$test_java_agent_log4j" = "xyes"; then
619 AX_JAVA_OPTIONS
620 AX_PROG_JAVAC
621 AX_PROG_JAVA
622 AX_PROG_JAR
623
624 AX_CHECK_CLASSPATH
625
626 # Check for Java UST agent common class first
627 AX_CHECK_CLASS(org.lttng.ust.agent.AbstractLttngAgent)
628 if test "x$ac_cv_class_org_lttng_ust_agent_AbstractLttngAgent" = "xno"; then
629 AC_MSG_ERROR([The UST Java agent common class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-common.jar"])
630 fi
631
632 if test "x$test_java_agent_jul" = "xyes"; then
633 # Check for JUL agent class
634 AX_CHECK_CLASS(org.lttng.ust.agent.jul.LttngLogHandler)
635 if test "x$ac_cv_class_org_lttng_ust_agent_jul_LttngLogHandler" = "xno"; then
636 AC_MSG_ERROR([The UST Java agent JUL class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-jul.jar"])
637 fi
638 fi
639
640 if test "x$test_java_agent_log4j" = "xyes"; then
641 # Check for Log4j agent class
642 AX_CHECK_CLASS(org.lttng.ust.agent.log4j.LttngLogAppender)
643 if test "x$ac_cv_class_org_lttng_ust_agent_log4j_LttngLogAppender" = "xno"; then
644 AC_MSG_ERROR([The UST Java agent Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-log4j.jar"])
645 fi
646
647 # Check for Log4j class
648 AX_CHECK_CLASS(org.apache.log4j.Logger)
649 if test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"; then
650 AC_MSG_ERROR([The Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j.jar"])
651 fi
652 fi
653 fi
654
655 # enable building man pages (user's intention)
656 AC_ARG_ENABLE(
657 man-pages,
658 AS_HELP_STRING(
659 [--disable-man-pages],
660 [Do not build and install man pages (already built in a distributed tarball)]
661 ),
662 [man_pages_opt=$enableval],
663 [man_pages_opt=yes]
664 )
665
666 # check for asciidoc and xmlto if we enabled building the man pages
667 have_asciidoc_xmlto=no
668 warn_prebuilt_man_pages=no
669
670 AS_IF([test "x$man_pages_opt" = "xyes"], [
671 AC_PATH_PROG([ASCIIDOC], [asciidoc], [no])
672 AC_PATH_PROG([XMLTO], [xmlto], [no])
673
674 AS_IF([test "x$ASCIIDOC" = "xno" || test "x$XMLTO" = "xno"], [
675 AS_IF([test "x$in_git_repo" = "xyes"], [
676 # this is an error because we're in the Git repo, which
677 # means the man pages are not already generated for us,
678 # thus asciidoc/xmlto are required because we were asked
679 # to build the man pages
680 AC_MSG_ERROR([
681 You need asciidoc and xmlto to build the LTTng-tools man pages. Use
682 --disable-man-pages to disable building the man pages, in which case
683 they will not be installed.
684 ])
685 ], [
686 # only warn here: since we're in the tarball, the man
687 # pages should already be generated at this point, thus
688 # asciidoc/xmlto are not strictly required
689 warn_prebuilt_man_pages=yes
690 ])
691 ], [
692 have_asciidoc_xmlto=yes
693 ])
694 ])
695
696 # export man page build condition: build the man pages if the user
697 # asked for it, and if the tools are available
698 AM_CONDITIONAL([MAN_PAGES_OPT], [test "x$man_pages_opt" != "xno"])
699 AM_CONDITIONAL([HAVE_ASCIIDOC_XMLTO], [test "x$have_asciidoc_xmlto" = "xyes"])
700
701 AC_DEFINE_UNQUOTED([MANPATH], ["`eval eval echo $mandir`"], [Path to man pages.])
702
703 # embedded --help message
704 AC_ARG_ENABLE(
705 [embedded-help],
706 AS_HELP_STRING(
707 [--enable-embedded-help],
708 [Embed the --help messages in the executable files]
709 ),
710 [embedded_help=$enableval],
711 [embedded_help=no]
712 )
713 AS_IF([test "x$embedded_help" = "xyes"], [
714 AS_IF([test "x$man_pages_opt" = "xno"], [
715 AC_MSG_ERROR([You need the --enable-man-pages option with the --enable-embedded-help option.])
716 ])
717 AC_PATH_PROG([man_prog_path], [man], [no])
718 AS_IF([test "x$man_prog_path" = "xno"], [
719 AC_MSG_ERROR([You need man with the --enable-embedded-help option.])
720 ])
721 AC_DEFINE_UNQUOTED([LTTNG_EMBED_HELP], 1, [Embed --help messages.])
722 AC_SUBST([MANPROG], [$man_prog_path])
723 ])
724 AM_CONDITIONAL([EMBED_HELP], [test "x$embedded_help" != "xno"])
725
726 # Python agent test
727 UST_PYTHON_AGENT="lttngust"
728
729 AC_ARG_ENABLE(test-python2-agent,
730 AS_HELP_STRING([--enable-test-python2-agent],
731 [enable tests for python2 agent. Python2 interpreter path can be overridden by setting the PYTHON2 environment variable. Default: Autodetect]
732 ),[:],[test_python2_agent_autodetect=yes]
733 )
734
735 AC_ARG_ENABLE(test-python3-agent,
736 AS_HELP_STRING([--enable-test-python3-agent],
737 [enable tests for python3 agent. Python3 interpreter path can be overridden by setting the PYTHON3 environment variable. Default: Autodetect]
738 ),[:],[test_python3_agent_autodetect=yes]
739 )
740
741 AC_ARG_ENABLE(test-python-agent-all,
742 AS_HELP_STRING([--enable-test-python-agent-all],
743 [enable test for all python{2/3} agent.]
744 ),
745 )
746
747 AS_IF([test ! -z "$enable_test_python_agent_all"], [
748 unset test_python2_agent_autodetect
749 unset test_python3_agent_autodetect
750 ])
751
752 AS_IF([test "x$enable_test_python_agent_all" = "xyes"], [
753 enable_test_python2_agent=yes
754 enable_test_python3_agent=yes
755 ])
756
757 AS_IF([test "x$enable_test_python_agent_all" = "xno"], [
758 enable_test_python2_agent=no
759 enable_test_python3_agent=no
760 ])
761
762
763 AS_IF([test "x$enable_test_python2_agent" = "xyes" -o "x$test_python2_agent_autodetect" = "xyes" ], [
764 AS_IF([test -z "$PYTHON2"], [
765 PYTHON2=python2
766 ], [
767 AC_MSG_WARN([Using user-defined PYTHON2 ($PYTHON2) for lttng-ust python2 agent check])
768 ])
769
770 AC_PATH_PROG([PYTHON2_BIN],[$PYTHON2])
771 AS_IF([test -z "$PYTHON2_BIN"], [
772 AS_IF([test -z "$test_python2_agent_autodetect"],[
773 AC_MSG_ERROR([No python2 interpreter found. PYTHON2 can be set to override default interpreter path])
774 ])
775 ], [
776 AC_MSG_CHECKING([for python2 lttng-ust agent])
777 AS_IF([$PYTHON2_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
778 PYTHON2_AGENT=$PYTHON2_BIN
779 AC_MSG_RESULT([yes])
780 RUN_PYTHON_AGENT_TEST=yes
781 ], [
782 AC_MSG_RESULT([no])
783 AS_IF([test -z "$test_python2_agent_autodetect"],[
784 AC_MSG_ERROR([No python2 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
785 ])
786 ])
787
788 ])
789
790 ])
791
792 AS_IF([test "x$enable_test_python3_agent" = "xyes" -o "x$test_python3_agent_autodetect" = "xyes" ], [
793 AS_IF([test -z "$PYTHON3"], [
794 PYTHON3=python3
795 ], [
796 AC_MSG_WARN([Using user-defined PYTHON3 ($PYTHON3) for lttng-ust python3 agent check])
797 ])
798
799 AC_PATH_PROG([PYTHON3_BIN],[$PYTHON3])
800 AS_IF([test -z "$PYTHON3_BIN"], [
801 AS_IF([test -z "$test_python3_agent_autodetect"],[
802 AC_MSG_ERROR([No python3 interpreter found. PYTHON3 can be set to override default interpreter path])
803 ])
804 ], [
805 AC_MSG_CHECKING([for python3 lttng-ust agent])
806 AS_IF([$PYTHON3_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
807 PYTHON3_AGENT=$PYTHON3_BIN
808 AC_MSG_RESULT([yes])
809 RUN_PYTHON_AGENT_TEST=yes
810 ], [
811 AC_MSG_RESULT([no])
812 AS_IF([test -z "$test_python3_agent_autodetect"],[
813 AC_MSG_ERROR([No python3 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
814 ])
815 ])
816
817 ])
818 ])
819 AC_SUBST([RUN_PYTHON_AGENT_TEST])
820 AC_SUBST([PYTHON2_AGENT])
821 AC_SUBST([PYTHON3_AGENT])
822
823 AC_ARG_ENABLE([test-sdt-uprobe],
824 [AS_HELP_STRING([--enable-test-sdt-uprobe], [enable the LTTng UST SDT uprobe tests [default=autodetect]])],
825 [test_sdt_uprobe="$enableval"],
826 [test_sdt_uprobe=autodetect]
827 )
828
829 AS_IF([test "$test_sdt_uprobe" != "no"], [
830 LTTNG_CHECK_SDT_WORKS
831 AC_PATH_PROG([DTRACE], [dtrace])
832 ])
833
834 AS_IF([test "$test_sdt_uprobe" = "yes"], [
835 AS_IF([test "$lttng_cv_sdt_works" = "no"], [
836 AC_MSG_ERROR([Cannot find 'sys/sdt.h'.])
837 ])
838 AS_IF([test "x$DTRACE" = "x"], [
839 AC_MSG_ERROR([Cannot find SystemTap dtrace. You can set the DTRACE variable to override automatic detection.])
840 ])
841 ])
842
843 AS_IF([test "$test_sdt_uprobe" = "autodetect"], [
844 AS_IF([test "$lttng_cv_sdt_works" = "yes"], [
845 AS_IF([test "x$DTRACE" != "x"], [
846 test_sdt_uprobe=yes
847 ])
848 ])
849 ])
850
851 AM_CONDITIONAL([TEST_SDT_UPROBE], [test "$test_sdt_uprobe" = "yes"])
852
853 # Arguments for binaries build exclusion
854 AC_ARG_ENABLE([bin-lttng], AS_HELP_STRING([--disable-bin-lttng],[Disable the build of lttng binaries]))
855 AC_ARG_ENABLE([bin-lttng-consumerd], AS_HELP_STRING([--disable-bin-lttng-consumerd],
856 [Disable the build of lttng-consumerd binaries]))
857 AC_ARG_ENABLE([bin-lttng-crash], AS_HELP_STRING([--disable-bin-lttng-crash],[Disable the build of lttng-crash binaries]))
858 AC_ARG_ENABLE([bin-lttng-relayd], AS_HELP_STRING([--disable-bin-lttng-relayd],
859 [Disable the build of lttng-relayd binaries]))
860 AC_ARG_ENABLE([bin-lttng-sessiond], AS_HELP_STRING([--disable-bin-lttng-sessiond],
861 [Disable the build of lttng-sessiond binaries]))
862 AC_ARG_ENABLE([extras], AS_HELP_STRING([--disable-extras],
863 [Disable the build of the extra components]))
864
865
866 # Always build libconfig since it a dependency of libcommon
867 build_lib_config=yes
868
869 build_lib_compat=no
870 build_lib_consumer=no
871 build_lib_hashtable=no
872 build_lib_health=no
873 build_lib_index=no
874 build_lib_kernel_consumer=no
875 build_lib_kernel_ctl=no
876 build_lib_lttng_ctl=no
877 build_lib_relayd=no
878 build_lib_fd_tracker=no
879 build_lib_sessiond_comm=no
880 build_lib_testpoint=no
881 build_lib_ust_consumer=no
882
883 # There is an overlap for enabled dependencies, but this makes everything
884 # simpler. libcommon and libconfig are always compiled so they are not repeated
885 # here.
886
887 # Enable binary dependencies.
888 AS_IF([test x$enable_bin_lttng != xno],
889 [
890 build_lib_lttng_ctl=yes
891 ]
892 )
893
894 AS_IF([test x$enable_bin_lttng_consumerd != xno],
895 [
896 build_lib_consumer=yes
897 build_lib_sessiond_comm=yes
898 build_lib_index=yes
899 build_lib_health=yes
900 build_lib_testpoint=yes
901 ]
902 )
903
904 AS_IF([test x$enable_bin_lttng_crash != xno],
905 # Do nothing since libconfig and libcommon are built by default.
906 []
907 )
908
909 AS_IF([test x$enable_bin_lttng_relayd != xno],
910 [
911 build_lib_lttng_ctl=yes
912 build_lib_sessiond_comm=yes
913 build_lib_hashtable=yes
914 build_lib_compat=yes
915 build_lib_index=yes
916 build_lib_health=yes
917 build_lib_testpoint=yes
918 build_lib_fd_tracker=yes
919 ]
920 )
921 AS_IF([test x$enable_bin_lttng_sessiond != xno],
922 [
923 build_lib_lttng_ctl=yes
924 build_lib_sessiond_comm=yes
925 build_lib_kernel_ctl=yes
926 build_lib_hashtable=yes
927 build_lib_compat=yes
928 build_lib_relayd=yes
929 build_lib_testpoint=yes
930 build_lib_health=yes
931 ]
932 )
933
934 # Libraries dependencies enabling
935 AS_IF([test x$build_lib_lttng_ctl = xyes],
936 [
937 build_lib_sessiond_comm=yes
938 build_lib_hashtable=yes
939 ]
940 )
941
942 AS_IF([test x$build_lib_consumer = xyes],
943 [
944 build_lib_sessiond_comm=yes
945 build_lib_kernel_consumer=yes
946 build_lib_hashtable=yes
947 build_lib_compat=yes
948 build_lib_relayd=yes
949 AS_IF([test "x$with_lttng_ust" = "xyes"], [build_lib_ust_consumer=yes])
950 ]
951 )
952
953 AS_IF([test x$build_lib_kernel_consumer = xyes],
954 [
955 build_lib_kernel_ctl=yes
956 build_lib_relayd=yes
957 ]
958 )
959
960 AS_IF([test x$build_lib_relayd = xyes],
961 [
962 build_lib_sessiond_comm=yes
963 ]
964 )
965
966 # Find arch type
967 AS_CASE([$host_cpu],
968 [k1om], [ARCHTYPE="x86"],
969 [i386], [ARCHTYPE="x86"],
970 [i486], [ARCHTYPE="x86"],
971 [i586], [ARCHTYPE="x86"],
972 [i686], [ARCHTYPE="x86"],
973 [amd64], [ARCHTYPE="x86"],
974 [x86_64], [ARCHTYPE="x86"],
975 [powerpc], [ARCHTYPE="ppc"],
976 [ppc64], [ARCHTYPE="ppc"],
977 [powerpc64], [ARCHTYPE="ppc"],
978 [powerpc64le], [ARCHTYPE="ppc"],
979 [ppc], [ARCHTYPE="ppc"],
980 [s390], [ARCHTYPE="s390"],
981 [s390x], [ARCHTYPE="s390"],
982 [sparc], [ARCHTYPE="sparc64"],
983 [sparc64], [ARCHTYPE="sparc64"],
984 [alpha*], [ARCHTYPE="alpha"],
985 [ia64], [ARCHTYPE="ia64"],
986 [arm*], [ARCHTYPE="arm"],
987 [aarch64*], [ARCHTYPE="aarch64"],
988 [mips*], [ARCHTYPE="mips"],
989 [nios2*], [ARCHTYPE="nios2"],
990 [tile*], [ARCHTYPE="tile"],
991 [hppa*], [ARCHTYPE="hppa"],
992 [m68k], [ARCHTYPE="m68k"],
993 [riscv*], [ARCHTYPE="riscv"],
994 [ARCHTYPE="unknown"]
995 )
996
997 AC_SUBST(ARCHTYPE)
998
999 AS_CASE([$host_os],
1000 [linux*], [OSTYPE="linux"],
1001 [freebsd*], [OSTYPE="freebsd"],
1002 [solaris*], [OSTYPE="solaris"],
1003 [cygwin*], [OSTYPE="cygwin"],
1004 [mingw*], [OSTYPE="mingw"],
1005 [OSTYPE="unknown"]
1006 )
1007 AC_SUBST(OSTYPE)
1008 AM_CONDITIONAL([IS_LINUX], [test $OSTYPE = "linux"])
1009
1010
1011
1012 # Userspace callstack capture is only supported by the Linux kernel on x86.
1013 AH_TEMPLATE([HAVE_MODULES_USERSPACE_CALLSTACK_CONTEXT], [Define if you have LTTng-modules userspace callstack tracing support])
1014 AS_IF([test "x$ARCHTYPE" = "xx86" && test "x$OSTYPE" = "xlinux"],[
1015 have_modules_userspace_callstack_context=yes
1016 AC_DEFINE([HAVE_MODULES_USERSPACE_CALLSTACK_CONTEXT], [1])
1017 ])
1018 AM_CONDITIONAL([HAVE_MODULES_USERSPACE_CALLSTACK_CONTEXT], [test x$have_modules_userspace_callstack_context = xyes])
1019
1020 # Export binaries build conditions.
1021 AM_CONDITIONAL([BUILD_BIN_LTTNG], [test x$enable_bin_lttng != xno])
1022 AM_CONDITIONAL([BUILD_BIN_LTTNG_CONSUMERD], [test x$enable_bin_lttng_consumerd != xno])
1023 AM_CONDITIONAL([BUILD_BIN_LTTNG_CRASH], [test x$enable_bin_lttng_crash != xno])
1024 AM_CONDITIONAL([BUILD_BIN_LTTNG_RELAYD], [test x$enable_bin_lttng_relayd != xno])
1025 AM_CONDITIONAL([BUILD_BIN_LTTNG_SESSIOND], [test x$enable_bin_lttng_sessiond != xno])
1026
1027 # Export the tests and extras build conditions.
1028 AS_IF([\
1029 test "x$enable_bin_lttng" != "xno" && \
1030 test "x$enable_bin_lttng_consumerd" != "xno" && \
1031 test "x$enable_bin_lttng_crash" != "xno" && \
1032 test "x$enable_bin_lttng_relayd" != "xno" && \
1033 test "x$enable_bin_lttng_sessiond" != "xno"],
1034 [build_tests=yes],
1035 [build_tests=no]
1036 )
1037
1038 AM_CONDITIONAL([BUILD_TESTS], [test x$build_tests = xyes])
1039 AM_CONDITIONAL([BUILD_EXTRAS], [test x$enable_extras != xno])
1040
1041 # Export libraries build conditions.
1042 AM_CONDITIONAL([BUILD_LIB_COMPAT], [test x$build_lib_compat = xyes])
1043 AM_CONDITIONAL([BUILD_LIB_CONFIG], [test x$build_lib_config = xyes])
1044 AM_CONDITIONAL([BUILD_LIB_CONSUMER], [test x$build_lib_consumer = xyes])
1045 AM_CONDITIONAL([BUILD_LIB_HASHTABLE], [test x$build_lib_hashtable = xyes])
1046 AM_CONDITIONAL([BUILD_LIB_HEALTH], [test x$build_lib_health = xyes])
1047 AM_CONDITIONAL([BUILD_LIB_INDEX], [test x$build_lib_index = xyes])
1048 AM_CONDITIONAL([BUILD_LIB_KERNEL_CONSUMER], [test x$build_lib_kernel_consumer = xyes])
1049 AM_CONDITIONAL([BUILD_LIB_KERNEL_CTL], [test x$build_lib_kernel_ctl = xyes])
1050 AM_CONDITIONAL([BUILD_LIB_LTTNG_CTL], [test x$build_lib_lttng_ctl = xyes])
1051 AM_CONDITIONAL([BUILD_LIB_RELAYD], [test x$build_lib_relayd = xyes])
1052 AM_CONDITIONAL([BUILD_LIB_FD_TRACKER], [test x$build_lib_fd_tracker = xyes])
1053 AM_CONDITIONAL([BUILD_LIB_SESSIOND_COMM], [test x$build_lib_sessiond_comm = xyes])
1054 AM_CONDITIONAL([BUILD_LIB_TESTPOINT], [test x$build_lib_testpoint = xyes])
1055 AM_CONDITIONAL([BUILD_LIB_UST_CONSUMER], [test x$build_lib_ust_consumer = xyes])
1056
1057 AM_CFLAGS="${WARN_CFLAGS} -fno-strict-aliasing $PTHREAD_CFLAGS"
1058 AC_SUBST(AM_CFLAGS)
1059
1060 # This is set even though it is empty, so Makefiles can do "AM_LDFLAGS += ...".
1061 AM_LDFLAGS=""
1062 AC_SUBST(AM_LDFLAGS)
1063
1064 # The order in which the include folders are searched is important.
1065 # The top_builddir should always be searched first in the event that a build
1066 # time generated file is included. An example of this is the "version.i" file.
1067 # In a scenario where lttng-tools is built from a distribution tarball and in a
1068 # out-of-tree manner, the generated "version.i" has priority on the one from
1069 # the source (distribution tarball) and must be found first.
1070 AM_CPPFLAGS="-I\$(top_builddir)/include -I\$(top_srcdir)/include -I\$(top_builddir)/src -I\$(top_srcdir)/src -include config.h $AM_CPPFLAGS"
1071 AC_SUBST(AM_CPPFLAGS)
1072
1073 lttngincludedir="${includedir}/lttng"
1074 AC_SUBST(lttngincludedir)
1075
1076 lttngactionincludedir="${includedir}/lttng/action"
1077 AC_SUBST(lttngactionincludedir)
1078
1079 lttngconditionincludedir="${includedir}/lttng/condition"
1080 AC_SUBST(lttngconditionincludedir)
1081
1082 lttngnotificationincludedir="${includedir}/lttng/notification"
1083 AC_SUBST(lttngnotificationincludedir)
1084
1085 lttngtriggerincludedir="${includedir}/lttng/trigger"
1086 AC_SUBST(lttngtriggerincludedir)
1087
1088 lttngeventruleincludedir="${includedir}/lttng/event-rule"
1089 AC_SUBST(lttngeventruleincludedir)
1090
1091 lttnglibexecdir="${libdir}/lttng/libexec"
1092 AC_SUBST(lttnglibexecdir)
1093
1094 AC_CONFIG_FILES([
1095 Makefile
1096 doc/Makefile
1097 doc/man/Makefile
1098 doc/man/asciidoc-attrs.conf
1099 include/Makefile
1100 extras/Makefile
1101 extras/bindings/Makefile
1102 extras/bindings/swig/Makefile
1103 extras/bindings/swig/python/Makefile
1104 extras/core-handler/Makefile
1105 src/Makefile
1106 src/common/Makefile
1107 src/common/argpar/Makefile
1108 src/common/kernel-ctl/Makefile
1109 src/common/kernel-consumer/Makefile
1110 src/common/consumer/Makefile
1111 src/common/ust-consumer/Makefile
1112 src/common/hashtable/Makefile
1113 src/common/sessiond-comm/Makefile
1114 src/common/compat/Makefile
1115 src/common/relayd/Makefile
1116 src/common/testpoint/Makefile
1117 src/common/index/Makefile
1118 src/common/health/Makefile
1119 src/common/config/Makefile
1120 src/common/string-utils/Makefile
1121 src/common/fd-tracker/Makefile
1122 src/common/filter/Makefile
1123 src/lib/Makefile
1124 src/lib/lttng-ctl/Makefile
1125 src/lib/lttng-ctl/lttng-ctl.pc
1126 src/bin/Makefile
1127 src/bin/lttng-consumerd/Makefile
1128 src/bin/lttng-sessiond/Makefile
1129 src/bin/lttng-relayd/Makefile
1130 src/bin/lttng/Makefile
1131 src/bin/lttng-crash/Makefile
1132 tests/Makefile
1133 tests/destructive/Makefile
1134 tests/regression/Makefile
1135 tests/regression/kernel/Makefile
1136 tests/regression/tools/Makefile
1137 tests/regression/tools/streaming/Makefile
1138 tests/regression/tools/filtering/Makefile
1139 tests/regression/tools/health/Makefile
1140 tests/regression/tools/tracefile-limits/Makefile
1141 tests/regression/tools/snapshots/Makefile
1142 tests/regression/tools/live/Makefile
1143 tests/regression/tools/exclusion/Makefile
1144 tests/regression/tools/save-load/Makefile
1145 tests/regression/tools/save-load/configuration/Makefile
1146 tests/regression/tools/mi/Makefile
1147 tests/regression/tools/wildcard/Makefile
1148 tests/regression/tools/crash/Makefile
1149 tests/regression/tools/regen-metadata/Makefile
1150 tests/regression/tools/regen-statedump/Makefile
1151 tests/regression/tools/notification/Makefile
1152 tests/regression/tools/rotation/Makefile
1153 tests/regression/tools/base-path/Makefile
1154 tests/regression/tools/metadata/Makefile
1155 tests/regression/tools/tracker/Makefile
1156 tests/regression/tools/working-directory/Makefile
1157 tests/regression/tools/relayd-grouping/Makefile
1158 tests/regression/tools/clear/Makefile
1159 tests/regression/ust/Makefile
1160 tests/regression/ust/nprocesses/Makefile
1161 tests/regression/ust/high-throughput/Makefile
1162 tests/regression/ust/low-throughput/Makefile
1163 tests/regression/ust/before-after/Makefile
1164 tests/regression/ust/buffers-pid/Makefile
1165 tests/regression/ust/periodical-metadata-flush/Makefile
1166 tests/regression/ust/multi-session/Makefile
1167 tests/regression/ust/multi-lib/Makefile
1168 tests/regression/ust/overlap/Makefile
1169 tests/regression/ust/overlap/demo/Makefile
1170 tests/regression/ust/linking/Makefile
1171 tests/regression/ust/daemon/Makefile
1172 tests/regression/ust/exit-fast/Makefile
1173 tests/regression/ust/fork/Makefile
1174 tests/regression/ust/libc-wrapper/Makefile
1175 tests/regression/ust/baddr-statedump/Makefile
1176 tests/regression/ust/ust-dl/Makefile
1177 tests/regression/ust/java-jul/Makefile
1178 tests/regression/ust/java-log4j/Makefile
1179 tests/regression/ust/python-logging/Makefile
1180 tests/regression/ust/getcpu-override/Makefile
1181 tests/regression/ust/clock-override/Makefile
1182 tests/regression/ust/type-declarations/Makefile
1183 tests/regression/ust/rotation-destroy-flush/Makefile
1184 tests/regression/ust/blocking/Makefile
1185 tests/regression/ust/namespaces/Makefile
1186 tests/stress/Makefile
1187 tests/unit/Makefile
1188 tests/unit/ini_config/Makefile
1189 tests/perf/Makefile
1190 tests/utils/Makefile
1191 tests/utils/tap/Makefile
1192 tests/utils/testapp/Makefile
1193 tests/utils/testapp/gen-ns-events/Makefile
1194 tests/utils/testapp/gen-kernel-test-events/Makefile
1195 tests/utils/testapp/gen-ust-events/Makefile
1196 tests/utils/testapp/gen-ust-events-ns/Makefile
1197 tests/utils/testapp/gen-syscall-events-callstack/Makefile
1198 tests/utils/testapp/gen-ust-nevents/Makefile
1199 tests/utils/testapp/gen-ust-nevents-str/Makefile
1200 tests/utils/testapp/gen-syscall-events/Makefile
1201 tests/utils/testapp/gen-ust-tracef/Makefile
1202 tests/utils/testapp/userspace-probe-elf-binary/Makefile
1203 tests/utils/testapp/userspace-probe-elf-cxx-binary/Makefile
1204 tests/utils/testapp/userspace-probe-sdt-binary/Makefile
1205 ])
1206
1207 # Inject variable into python test script.
1208 AC_CONFIG_FILES([tests/regression/ust/python-logging/test_python_logging],[chmod +x tests/regression/ust/python-logging/test_python_logging])
1209 # Inject LTTNG_TOOLS_BUILD_WITH_LIBPFM variable in test script.
1210 AC_CONFIG_FILES([tests/perf/test_perf_raw],[chmod +x tests/perf/test_perf_raw])
1211 AC_CONFIG_FILES([tests/regression/ust/ust-dl/test_ust-dl],[chmod +x tests/regression/ust/ust-dl/test_ust-dl])
1212
1213 AC_OUTPUT
1214
1215 #
1216 # Mini-report on what will be built.
1217 #
1218
1219 PPRINT_INIT
1220 PPRINT_SET_INDENT(1)
1221 PPRINT_SET_TS(38)
1222
1223 AS_ECHO
1224 AS_ECHO("${PPRINT_COLOR_BLDBLU}LTTng-tools $PACKAGE_VERSION \"$version_name\"$PPRINT_COLOR_RST")
1225 AS_ECHO
1226
1227 AS_IF([test -n "$report_fold"], [
1228 AS_ECHO("`AS_ECHO("$version_description") | $report_fold -s`")
1229 ], [
1230 AS_ECHO("$version_description")
1231 ])
1232
1233 AS_ECHO
1234 PPRINT_SUBTITLE([Features])
1235
1236 # Target architecture we're building for.
1237 target_arch=$host_cpu
1238 [
1239 for f in $CFLAGS; do
1240 if test $f = "-m32"; then
1241 target_arch="32-bit"
1242 elif test $f = "-m64"; then
1243 target_arch="64-bit"
1244 fi
1245 done
1246 ]
1247 PPRINT_PROP_STRING([Target architecture], $target_arch)
1248
1249 # kmod enabled/disabled
1250 test "x$with_kmod" != "xno" && value=1 || value=0
1251 PPRINT_PROP_BOOL([libkmod support], $value)
1252
1253 # LTTng-UST enabled/disabled
1254 test "x$with_lttng_ust" = "xyes" && value=1 || value=0
1255 PPRINT_PROP_BOOL([LTTng-UST support], $value)
1256
1257 AS_ECHO
1258 PPRINT_SUBTITLE([Binaries])
1259
1260 # List binaries to be built
1261 test x$enable_bin_lttng != xno && value=1 || value=0
1262 PPRINT_PROP_BOOL([lttng], $value)
1263
1264 test x$enable_bin_lttng_consumerd != xno && value=1 || value=0
1265 PPRINT_PROP_BOOL([lttng-consumerd], $value)
1266
1267 test x$enable_bin_lttng_crash != xno && value=1 || value=0
1268 PPRINT_PROP_BOOL([lttng-crash], $value)
1269
1270 test x$enable_bin_lttng_relayd != xno && value=1 || value=0
1271 PPRINT_PROP_BOOL([lttng-relayd], $value)
1272
1273 test x$enable_bin_lttng_sessiond != xno && value=1 || value=0
1274 PPRINT_PROP_BOOL([lttng-sessiond], $value)
1275
1276 # Extras
1277 test x$enable_extras != xno && value=1 || value=0
1278 AS_ECHO
1279 PPRINT_SET_INDENT(0)
1280 PPRINT_PROP_BOOL([Extras], $value, $PPRINT_COLOR_SUBTITLE)
1281 PPRINT_SET_INDENT(1)
1282
1283 AS_ECHO
1284 PPRINT_SUBTITLE([Tests])
1285
1286 # Print clear message that tests won't be built
1287 AS_IF([test "x$build_tests" = "xno"],[
1288 PPRINT_WARN([Tests won't be built since some binaries were disabled])
1289 ])
1290
1291 # LTTng UST Java agent JUL tests enabled/disabled
1292 test "x$test_java_agent_jul" = "xyes" && value=1 || value=0
1293 PPRINT_PROP_BOOL([LTTng-UST Java agent JUL tests], $value)
1294
1295 # LTTng UST Java agent Log4j tests enabled/disabled
1296 test "x$test_java_agent_log4j" = "xyes" && value=1 || value=0
1297 PPRINT_PROP_BOOL([LTTng-UST Java agent Log4j tests], $value)
1298
1299 test ! -z "$PYTHON2_AGENT" && value=1 || value=0
1300 PPRINT_PROP_BOOL([LTTng-UST Python2 agent tests], $value)
1301
1302 test ! -z "$PYTHON3_AGENT" && value=1 || value=0
1303 PPRINT_PROP_BOOL([LTTng-UST Python3 agent tests], $value)
1304
1305 # LTTng UST Java agent Log4j tests enabled/disabled
1306 test "x$test_sdt_uprobe" = "xyes" && value=1 || value=0
1307 PPRINT_PROP_BOOL([LTTng-UST SDT uprobe tests], $value)
1308
1309 #Python binding enabled/disabled
1310 test "x$enable_python_binding" = xyes && value=1 || value=0
1311 AS_ECHO
1312 PPRINT_SET_INDENT(0)
1313 PPRINT_PROP_BOOL([Python binding], $value, $PPRINT_COLOR_SUBTITLE)
1314
1315 # man pages build enabled/disabled
1316 m4_pushdef([build_man_pages_msg], [Build and install man pages])
1317
1318 AS_IF([test "x$man_pages_opt" != "xno"], [
1319 AS_IF([test "x$in_git_repo" = "xyes"], [
1320 PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
1321 ], [
1322 AS_IF([test "x$have_asciidoc_xmlto" = "xyes"], [
1323 PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
1324 ], [
1325 PPRINT_PROP_STRING([build_man_pages_msg],
1326 [${PPRINT_COLOR_BLDGRN}yes (already built)],
1327 $PPRINT_COLOR_SUBTITLE)
1328 ])
1329 ])
1330 ], [
1331 PPRINT_PROP_BOOL([build_man_pages_msg], 0, $PPRINT_COLOR_SUBTITLE)
1332 ])
1333
1334 m4_popdef([build_man_pages_msg])
1335
1336 test "x$embedded_help" = xyes && value=1 || value=0
1337 PPRINT_PROP_BOOL([Embed --help messages], $value, $PPRINT_COLOR_SUBTITLE)
1338
1339 PPRINT_SET_INDENT(1)
1340
1341 report_bindir="`eval eval echo $bindir`"
1342 report_libdir="`eval eval echo $libdir`"
1343
1344 # Print the bindir and libdir this `make install' will install into.
1345 AS_ECHO
1346 PPRINT_SUBTITLE([Install directories])
1347 PPRINT_PROP_STRING([Binaries], [$report_bindir])
1348 PPRINT_PROP_STRING([Libraries], [$report_libdir])
1349
1350 AS_ECHO
1351 PPRINT_SUBTITLE([Search directories])
1352
1353 # If we build the sessiond, print the paths it will use
1354 AS_IF([test "$SESSIOND_BIN" = ""],[
1355 path="$report_bindir/lttng-sessiond"
1356 ],[
1357 path="$SESSIOND_BIN"
1358 ])
1359 PPRINT_PROP_STRING([lttng-sessiond executable], [$path])
1360
1361 AS_IF([test "$CONSUMERD32_BIN" = ""],[
1362 path="`eval eval echo $lttnglibexecdir`/lttng-consumerd"
1363 ],[
1364 path="$CONSUMERD32_BIN"
1365 ])
1366 PPRINT_PROP_STRING([32-bit lttng-consumerd executable], [$path])
1367
1368 AS_IF([test "$CONSUMERD32_LIBDIR" = ""],[
1369 path="`eval eval echo $libdir`"
1370 ],[
1371 path="$CONSUMERD32_LIBDIR"
1372 ])
1373 PPRINT_PROP_STRING([32-bit consumer libraries], [$path])
1374
1375 AS_IF([test "$CONSUMERD64_BIN" = ""],[
1376 path="`eval eval echo $lttnglibexecdir`/lttng-consumerd"
1377 ],[
1378 path="$CONSUMERD64_BIN"
1379 ])
1380 PPRINT_PROP_STRING([64-bit lttng-consumerd executable], [$path])
1381
1382 AS_IF([test "$CONSUMERD64_LIBDIR" = ""],[
1383 path="`eval eval echo $libdir`"
1384 ],[
1385 path="$CONSUMERD64_LIBDIR"
1386 ])
1387 PPRINT_PROP_STRING([64-bit consumer libraries], [$path])
1388 PPRINT_SET_INDENT(0)
1389
1390 AS_IF([test "x$warn_prebuilt_man_pages" = "xyes" ], [
1391 AS_ECHO
1392 PPRINT_WARN([You need asciidoc and xmlto to build the LTTng-tools man pages.
1393
1394 Note that the man pages are already built in this distribution tarball,
1395 therefore asciidoc and xmlto are only needed if you intend to modify
1396 their sources.
1397
1398 Also note that the installed man pages will contain the project's
1399 default command-line option and environment variable values.
1400
1401 Use --disable-man-pages to completely disable building and installing
1402 the man pages.])
1403 ])
This page took 0.099484 seconds and 4 git commands to generate.