configure.ac

   1 dnl SPDX-License-Identifier: GPL-2.0-only
   2 AC_PREREQ([2.64])
   3 AC_INIT([lttng-tools],[2.12.0-rc1],[jeremie.galarneau@efficios.com],[],[https://lttng.org])
   4
   5 AC_CONFIG_HEADERS([include/config.h])
   6 AC_CONFIG_AUX_DIR([config])
   7 AC_CONFIG_MACRO_DIR([m4])
   8
   9 AC_CANONICAL_TARGET
  10 AC_CANONICAL_HOST
  11
  12 AM_INIT_AUTOMAKE([1.12 foreign dist-bzip2 no-dist-gzip tar-pax nostdinc])
  13 AM_MAINTAINER_MODE([enable])
  14
  15 # Enable silent rules if available (Introduced in AM 1.11)
  16 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  17
  18 AC_REQUIRE_AUX_FILE([tap-driver.sh])
  19
  20 # Checks for C compiler
  21 AC_USE_SYSTEM_EXTENSIONS
  22 AC_SYS_LARGEFILE
  23 AC_PROG_CC
  24 AC_PROG_CC_STDC
  25 AC_PROG_CXX
  26 RW_PROG_CXX_WORKS
  27 AM_CONDITIONAL([CXX_WORKS], [test "x$rw_cv_prog_cxx_works" = "xyes"])
  28
  29 # Detect warning flags supported by the compiler, append them to WARN_CFLAGS.
  30 #
  31 # Pass -Werror as an extra flag during the test: this is needed to make the
  32 # -Wunknown-warning-option diagnostic fatal with clang.
  33 AX_APPEND_COMPILE_FLAGS([ dnl
  34                 -Wall dnl
  35                 dnl We currently get this warning when building with Clang:
  36                 dnl
  37                 dnl /usr/include/setjmp.h:54:12: error: declaration of built-in function '__sigsetjmp' requires the declaration of the 'jmp_buf' type, commonly provided in the header <setjmp.h>. [-Werror,-Wincomplete-setjmp-declaration]
  38                 dnl extern int __sigsetjmp (struct __jmp_buf_tag __env[1], int __savemask) __THROWNL;
  39                 dnl            ^
  40                 -Wno-incomplete-setjmp-declaration dnl
  41         ],
  42         [WARN_CFLAGS],
  43         [-Werror])
  44
  45 # When given, add -Werror to WARN_CFLAGS.
  46 AC_ARG_ENABLE([Werror],
  47         [AS_HELP_STRING([--enable-Werror], [Treat compiler warnings as errors.])]
  48 )
  49 AS_IF([test "x$enable_Werror" = "xyes"],
  50         [WARN_CFLAGS="${WARN_CFLAGS} -Werror"]
  51 )
  52
  53 # Checks for programs.
  54 AC_PROG_GREP
  55 AC_PROG_MAKE_SET
  56 AC_PROG_SED
  57 AC_PATH_PROG([report_fold], [fold])
  58 LT_INIT
  59
  60 # Check for objcopy, required by the base address statedump and dynamic linker tests
  61 AC_CHECK_TOOL([OBJCOPY], [objcopy], [no])
  62 AS_IF([test "x$OBJCOPY" = "xno"],
  63         [AC_MSG_WARN([Cannot find objcopy. The base address statedump and dynamic linker tests will be disabled. Install the binutils package to remediate this.])]
  64 )
  65 AM_CONDITIONAL([HAVE_OBJCOPY], [test "x$OBJCOPY" != xno])
  66
  67 # check for pgrep
  68 AC_PATH_PROG([PGREP], [pgrep], [no])
  69 AM_CONDITIONAL([HAVE_PGREP], [test "x$PGREP" != "xno"])
  70
  71 # set $IN_GIT_REPO if we're in the Git repository; the `bootstrap` file
  72 # is not distributed in tarballs
  73 AS_IF([test -f "$srcdir/bootstrap"], [in_git_repo=yes], [in_git_repo=no])
  74 AM_CONDITIONAL([IN_GIT_REPO], [test "x$in_git_repo" = "xyes"])
  75
  76 # check for bison
  77 AC_PROG_YACC
  78 BISON=$YACC
  79 AX_PROG_BISON_VERSION([2.4], [have_bison=yes])
  80
  81 AS_IF([test "x$have_bison" != "xyes"], [
  82   AS_IF([test "x$in_git_repo" = "xyes"], [
  83     AC_MSG_FAILURE([
  84 Bison >= 2.4 is required when building from the Git repository. You can
  85 set the YACC variable to override automatic detection.
  86     ])
  87   ], [
  88     AC_MSG_WARN([
  89 Missing Bison >= 2.4. Note that the parser files are already built in
  90 this distribution tarball, so Bison is only needed if you intend to
  91 modify their sources. You can set the YACC variable to override automatic
  92 detection.
  93     ])
  94   ])
  95 ])
  96 AM_CONDITIONAL([HAVE_BISON], [test "x$have_bison" = "xyes"])
  97
  98 # check for flex
  99 AC_PROG_LEX
 100 FLEX=$LEX
 101 AX_PROG_FLEX_VERSION([2.5.35], [have_flex=yes])
 102
 103 AS_IF([test "x$have_flex" != "xyes"], [
 104   AS_IF([test "x$in_git_repo" = "xyes"], [
 105     AC_MSG_FAILURE([
 106 Flex >= 2.5.35 is required when building from the Git repository. You can
 107 set the LEX variable to override automatic detection.
 108     ])
 109   ], [
 110     AC_MSG_WARN([
 111 Missing Flex >= 2.5.35. Note that the lexer files are already built in
 112 this distribution tarball, so Flex is only needed if you intend to
 113 modify their sources. You can set the LEX variable to override automatic
 114 detection.
 115     ])
 116   ])
 117 ])
 118 AM_CONDITIONAL([HAVE_FLEX], [test "x$have_flex" = "xyes"])
 119
 120
 121 # Checks for typedefs, structures, and compiler characteristics.
 122 AC_C_INLINE
 123 AC_TYPE_INT32_T
 124 AC_TYPE_INT64_T
 125 AC_TYPE_MODE_T
 126 AC_TYPE_OFF_T
 127 AC_TYPE_PID_T
 128 AC_TYPE_SIZE_T
 129 AC_TYPE_SSIZE_T
 130 AC_TYPE_UID_T
 131 AC_TYPE_UINT16_T
 132 AC_TYPE_UINT32_T
 133 AC_TYPE_UINT64_T
 134 AC_TYPE_UINT8_T
 135
 136 AX_C___ATTRIBUTE__
 137 AS_IF([test "x$ax_cv___attribute__" = "xyes"],
 138         [:],
 139         [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
 140
 141 AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])
 142
 143 # Check if linker has the -no-pie option.
 144 AX_CHECK_LINK_FLAG([-no-pie], [linker_have_no_pie_option=yes])
 145 AM_CONDITIONAL([LINKER_HAVE_NO_PIE_OPTION], [test "x$linker_have_no_pie_option" = "xyes"])
 146
 147 AX_LIB_SOCKET_NSL
 148
 149 LT_NO_UNDEFINED=""
 150 AS_CASE([$host_os],
 151   [cygwin*],
 152     [
 153       LT_NO_UNDEFINED="-no-undefined"
 154     ],
 155   [cygwin*|darwin*|mingw*|solaris*],
 156     [
 157       # On platforms where we only support the relayd, disable the other binaries by default
 158       AS_IF([test "x$enable_bin_lttng" = "x" ], [enable_bin_lttng=no])
 159       AS_IF([test "x$enable_bin_lttng_consumerd" = "x" ], [enable_bin_lttng_consumerd=no])
 160       AS_IF([test "x$enable_bin_lttng_crash" = "x" ], [enable_bin_lttng_crash=no])
 161       AS_IF([test "x$enable_bin_lttng_sessiond" = "x" ], [enable_bin_lttng_sessiond=no])
 162       AS_IF([test "x$enable_extras" = "x" ], [enable_extras=no])
 163       AS_IF([test "x$with_lttng_ust" = "x" ], [with_lttng_ust=no])
 164     ]
 165 )
 166
 167 AC_SUBST(LT_NO_UNDEFINED)
 168
 169 # Compute minor/major/patchlevel version numbers
 170 major_version=$(echo AC_PACKAGE_VERSION | $SED 's/^\([[0-9]]\)*\.[[0-9]]*\.[[0-9]]*.*$/\1/')
 171 minor_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.\([[0-9]]*\)\.[[0-9]]*.*$/\1/')
 172 patchlevel_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\).*$/\1/')
 173
 174 AC_SUBST([MAJOR_VERSION], [$major_version])
 175 AC_SUBST([MINOR_VERSION], [$minor_version])
 176 AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version])
 177 AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [LTTng-Tools major version number])
 178 AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [LTTng-Tools minor version number])
 179 AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [LTTng-Tools patchlevel version number])
 180
 181 version_name="(Ta) Meilleure"
 182 version_description="Ta Meilleure is a Northeast IPA beer brewed by Lagabière. Translating to \"Your best one\", this beer gives out strong aromas of passion fruit, lemon, and peaches. Tastewise, expect a lot of fruit, a creamy texture, and a smooth lingering hop bitterness."
 183 version_description_c=$(echo $version_description | $SED 's/"/\\"/g')
 184
 185 AC_DEFINE_UNQUOTED([VERSION_NAME], ["$version_name"], "")
 186 AC_DEFINE_UNQUOTED([VERSION_DESCRIPTION], ["$version_description_c"], "")
 187
 188 # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
 189 AC_ARG_ENABLE(libtool-linkdep-fixup,
 190         AS_HELP_STRING([--disable-libtool-linkdep-fixup],
 191                         [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)]),
 192         libtool_fixup=$enableval,
 193         libtool_fixup=yes)
 194
 195 AS_IF([test "x$libtool_fixup" = "xyes"],
 196             [
 197             libtool_m4="$srcdir/m4/libtool.m4"
 198             libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
 199             AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
 200             libtool_flag_pattern_count=$($GREP -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
 201             AS_IF([test $libtool_flag_pattern_count -ne 0],
 202             [
 203                   AC_MSG_RESULT([$libtool_flag_pattern_count])
 204                   AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
 205                   $SED -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
 206                   ],
 207                   [
 208                   AC_MSG_RESULT([none])
 209                   ])
 210             ])
 211
 212 AM_CONDITIONAL([NO_SHARED], [test x$enable_shared = xno])
 213
 214 AC_CHECK_HEADERS([ \
 215         sys/types.h unistd.h fcntl.h string.h pthread.h limits.h \
 216         signal.h stdlib.h sys/un.h sys/socket.h stdlib.h stdio.h \
 217         getopt.h sys/ipc.h sys/shm.h popt.h grp.h arpa/inet.h \
 218         netdb.h netinet/in.h paths.h stddef.h sys/file.h sys/ioctl.h \
 219         sys/mount.h sys/param.h sys/time.h elf.h
 220 ])
 221
 222 AM_CONDITIONAL([HAVE_ELF_H], [test x$ac_cv_header_elf_h = xyes])
 223
 224 # Basic functions check
 225 AC_CHECK_FUNCS([ \
 226         atexit bzero clock_gettime dup2 fdatasync fls ftruncate \
 227         gethostbyname gethostname getpagesize localtime_r memchr memrchr memset \
 228         mkdir munmap putenv realpath rmdir socket strchr strcspn strdup \
 229         strncasecmp strndup strnlen strpbrk strrchr strstr strtol strtoul \
 230         strtoull dirfd gethostbyname2 getipnodebyname epoll_create1 \
 231         sched_getcpu sysconf sync_file_range
 232 ])
 233
 234 # Check if clock_gettime, timer_create, timer_settime, and timer_delete are available in lib rt, and if so,
 235 # add -lrt to LIBS
 236 AC_CHECK_LIB([rt], [clock_gettime, timer_create, timer_settime, timer_delete])
 237
 238 # Checks for dl.
 239 AC_CHECK_LIB([dl], [dlopen], [
 240         have_libdl=yes
 241         libdl_name=dl
 242         DL_LIBS="-ldl"
 243 ], [
 244         # libdl not found, check for dlopen in libc.
 245         AC_CHECK_LIB([c], [dlopen], [
 246                 have_libc_dl=yes
 247                 libdl_name=c
 248                 DL_LIBS="-lc"
 249         ], [
 250                 AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
 251         ])
 252 ])
 253 AC_SUBST(DL_LIBS)
 254
 255 # Check if libdl has dlmopen support.
 256 AH_TEMPLATE([HAVE_DLMOPEN], ["Define to 1 if dlmopen is available."])
 257 AC_CHECK_LIB([$libdl_name], [dlmopen], [
 258         AC_DEFINE([HAVE_DLMOPEN], [1])
 259         HAVE_DLMOPEN=1
 260 ], [
 261         HAVE_DLMOPEN=0
 262 ])
 263 AC_SUBST(HAVE_DLMOPEN)
 264
 265 # Babeltrace viewer check
 266 AC_ARG_WITH([babeltrace-bin],
 267         AS_HELP_STRING([--with-babeltrace-bin],
 268         [Location of the babeltrace viewer executable (including the filename)]),
 269         [BABELTRACE_BIN="$withval"],
 270         [BABELTRACE_BIN=''])
 271 AC_SUBST([BABELTRACE_BIN])
 272
 273 AC_ARG_WITH([babeltrace2-bin],
 274         AS_HELP_STRING([--with-babeltrace2-bin],
 275         [Location of the babeltrace2 viewer executable (including the filename)]),
 276         [BABELTRACE2_BIN="$withval"],
 277         [BABELTRACE2_BIN=''])
 278 AC_SUBST([BABELTRACE2_BIN])
 279
 280 AC_ARG_WITH([consumerd32-bin],
 281         AS_HELP_STRING([--with-consumerd32-bin],
 282         [Location of the 32-bit consumerd executable (including the filename)]),
 283         [CONSUMERD32_BIN="$withval"],
 284         [CONSUMERD32_BIN=''])
 285 AC_SUBST([CONSUMERD32_BIN])
 286
 287 AC_ARG_WITH([consumerd64-bin],
 288         AS_HELP_STRING([--with-consumerd64-bin],
 289         [Location of the 64-bit consumerd executable (including the filename)]),
 290         [CONSUMERD64_BIN="$withval"],
 291         [CONSUMERD64_BIN=''])
 292 AC_SUBST([CONSUMERD64_BIN])
 293
 294 AC_ARG_WITH([consumerd32-libdir],
 295         AS_HELP_STRING([--with-consumerd32-libdir],
 296         [Directory containing the 32-bit consumerd libraries]),
 297         [CONSUMERD32_LIBDIR="$withval"],
 298         [CONSUMERD32_LIBDIR=''])
 299 AC_SUBST([CONSUMERD32_LIBDIR])
 300
 301 AC_ARG_WITH([consumerd64-libdir],
 302         AS_HELP_STRING([--with-consumerd64-libdir],
 303         [Directory containing the 64-bit consumerd libraries]),
 304         [CONSUMERD64_LIBDIR="$withval"],
 305         [CONSUMERD64_LIBDIR=''])
 306 AC_SUBST([CONSUMERD64_LIBDIR])
 307
 308 AC_ARG_WITH([sessiond-bin],
 309         AS_HELP_STRING([--with-sessiond-bin],
 310         [Location of the sessiond executable (including the filename)]),
 311         [SESSIOND_BIN="$withval"],
 312         [SESSIOND_BIN=''])
 313 AC_SUBST([SESSIOND_BIN])
 314
 315 AC_ARG_WITH([lttng-system-rundir],
 316         AS_HELP_STRING([--with-lttng-system-rundir],
 317         [Location of the system directory where the system-wide lttng-sessiond runtime files are kept. The default is "/var/run/lttng".]),
 318         [LTTNG_SYSTEM_RUNDIR="$withval"],
 319         [LTTNG_SYSTEM_RUNDIR="/var/run/lttng"])
 320 AC_SUBST([LTTNG_SYSTEM_RUNDIR])
 321
 322 AC_ARG_ENABLE([test-java-agent-jul],
 323         [AS_HELP_STRING([--enable-test-java-agent-jul],[enable the LTTng UST Java agent JUL tests [default=no]])],
 324         [test_java_agent_jul=$enableval],
 325         [test_java_agent_jul=no]
 326 )
 327
 328 AC_ARG_ENABLE([test-java-agent-log4j],
 329         [AS_HELP_STRING([--enable-test-java-agent-log4j],[enable the LTTng UST Java agent Log4j tests [default=no]])],
 330         [test_java_agent_log4j=$enableval],
 331         [test_java_agent_log4j=no]
 332 )
 333
 334 AC_ARG_ENABLE([test-java-agent-all],
 335         [AS_HELP_STRING([--enable-test-java-agent-all],[enable all the LTTng UST Java agent tests [default=no]])],
 336         [test_java_agent_jul=$enableval
 337          test_java_agent_log4j=$enableval],
 338         [:]
 339 )
 340
 341 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_BIN], "$CONSUMERD32_BIN", [Location of the 32-bit consumerd executable.])
 342 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_BIN], "$CONSUMERD64_BIN", [Location of the 64-bit consumerd executable])
 343 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_LIBDIR], "$CONSUMERD32_LIBDIR", [Search for consumerd 32-bit libraries in this location.])
 344 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_LIBDIR], "$CONSUMERD64_LIBDIR", [Search for consumerd 64-bit libraries in this location.])
 345 AC_DEFINE_UNQUOTED([CONFIG_BABELTRACE_BIN], "$BABELTRACE_BIN", [Location of the babeltrace viewer executable.])
 346 AC_DEFINE_UNQUOTED([CONFIG_BABELTRACE2_BIN], "$BABELTRACE2_BIN", [Location of the babeltrace2 viewer executable.])
 347 AC_DEFINE_UNQUOTED([CONFIG_SESSIOND_BIN], "$SESSIOND_BIN", [Location of the sessiond executable.])
 348 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_RUNDIR], ["$LTTNG_SYSTEM_RUNDIR"], [LTTng system runtime directory])
 349
 350 AC_DEFUN([_AC_DEFINE_AND_SUBST], [
 351         AC_DEFINE_UNQUOTED([CONFIG_$1], [$2], [$1])
 352         $1="$2"
 353         AC_SUBST([$1])
 354 ])
 355
 356 AC_DEFUN([_AC_DEFINE_QUOTED_AND_SUBST], [
 357         AC_DEFINE_UNQUOTED([CONFIG_$1], ["$2"], [$1])
 358         $1="$2"
 359         AC_SUBST([$1])
 360 ])
 361
 362 # Default values
 363 m4_define([_DEFAULT_CHANNEL_SUBBUF_SIZE], [16384])
 364 m4_define([_DEFAULT_CHANNEL_SUBBUF_NUM], [4])
 365 m4_define([_DEFAULT_CHANNEL_SWITCH_TIMER], [0])
 366 m4_define([_DEFAULT_CHANNEL_LIVE_TIMER], [0])
 367 m4_define([_DEFAULT_CHANNEL_READ_TIMER], [200000])
 368 m4_define([_DEFAULT_CHANNEL_MONITOR_TIMER], [1000000])
 369 m4_define([_DEFAULT_CHANNEL_BLOCKING_TIMEOUT], [0])
 370 _AC_DEFINE_AND_SUBST([DEFAULT_AGENT_TCP_PORT_RANGE_BEGIN], [5345])
 371 _AC_DEFINE_AND_SUBST([DEFAULT_AGENT_TCP_PORT_RANGE_END], [5354])
 372 _AC_DEFINE_AND_SUBST([DEFAULT_APP_SOCKET_RW_TIMEOUT], [5])
 373 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE])
 374 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_COUNT], [0])
 375 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_SIZE], [0])
 376 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 377 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_READ_TIMER], [_DEFAULT_CHANNEL_READ_TIMER])
 378 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 379 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_SIZE], [1048576])
 380 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 381 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
 382 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_BLOCKING_TIMEOUT], [_DEFAULT_CHANNEL_BLOCKING_TIMEOUT])
 383 _AC_DEFINE_AND_SUBST([DEFAULT_LTTNG_LIVE_TIMER], [1000000])
 384 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_CACHE_SIZE], [4096])
 385 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_READ_TIMER], [0])
 386 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_NUM], [2])
 387 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_SIZE], [4096])
 388 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 389 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_CONTROL_PORT], [5342])
 390 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_DATA_PORT], [5343])
 391 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_VIEWER_PORT], [5344])
 392 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 393 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_READ_TIMER], [0])
 394 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_BLOCKING_TIMEOUT], [0])
 395 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 396 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE])
 397 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 398 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
 399 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 400 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_READ_TIMER], [0])
 401 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_BLOCKING_TIMEOUT], [0])
 402 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 403 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_SIZE], [524288])
 404 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 405 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
 406 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_AGENT_BIND_ADDRESS], [localhost])
 407 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_CONTROL_BIND_ADDRESS], [0.0.0.0])
 408 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_DATA_BIND_ADDRESS], [0.0.0.0])
 409 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_VIEWER_BIND_ADDRESS], [localhost])
 410 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_RELAYD_CTRL_MAX_PAYLOAD_SIZE], [134217728])
 411 _AC_DEFINE_AND_SUBST([DEFAULT_ROTATE_PENDING_TIMER], [500000])
 412
 413 # Command short descriptions
 414 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ADD_CONTEXT], [Add context fields to a channel])
 415 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_CREATE], [Create a tracing session])
 416 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_CLEAR], [Clear a tracing session])
 417 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DESTROY], [Tear down tracing sessions])
 418 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_CHANNEL], [Disable tracing channels])
 419 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_EVENT], [Disable event rules])
 420 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_ROTATION], [Unset a rotation schedule])
 421 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_CHANNEL], [Create or enable tracing channels])
 422 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_EVENT], [Create or enable event rules])
 423 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_ROTATION], [Set a rotation schedule])
 424 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_HELP], [Display help information about a command])
 425 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LIST], [List tracing sessions, domains, channels, and events])
 426 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LOAD], [Load tracing session configurations])
 427 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_REGENERATE], [Manage an LTTng tracing session's data regeneration])
 428 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ROTATE], [Archive a tracing session's current trace chunk])
 429 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SAVE], [Save tracing session configurations])
 430 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SET_SESSION], [Set current tracing session])
 431 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SNAPSHOT], [Snapshot buffers of current tracing session])
 432 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_START], [Start tracing])
 433 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STATUS], [Get the status of the current tracing session])
 434 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STOP], [Stop tracing])
 435 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_ROTATION], [Unset a rotation schedule])
 436 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_ROTATION], [Set a rotation schedule])
 437 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_TRACK], [Track specific system resources])
 438 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_UNTRACK], [Untrack specific system resources])
 439 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VERSION], [Show version information])
 440 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VIEW], [Start trace viewer])
 441
 442 if test "x$prefix" = "xNONE"; then
 443         prefix=$ac_default_prefix
 444 fi
 445 CONFDIR=`eval echo $sysconfdir`
 446 AC_SUBST(CONFDIR)
 447 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_CONFIGDIR],"$CONFDIR", [LTTng system configuration directory.])
 448
 449 AX_DEFINE_DIR([CONFIG_LTTNG_SYSTEM_DATADIR], [datadir], [LTTng system data directory.])
 450
 451 # Check libpopt
 452 PKG_CHECK_MODULES([POPT], [popt],
 453   [
 454     dnl PKG_CHECK_MODULES defines POPT_LIBS
 455   ],
 456   [
 457     AC_MSG_WARN([pkg-config was unable to find a valid .pc for libpopt. Set PKG_CONFIG_PATH to specify the pkgconfig configuration file location])
 458     AC_MSG_WARN([Finding libpopt without pkg-config.])
 459     AC_CHECK_LIB([popt],
 460       [poptGetContext],
 461       [POPT_LIBS="-lpopt"],
 462       [
 463         AC_MSG_FAILURE([Cannot find libpopt. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location])
 464       ]
 465     )
 466   ]
 467 )
 468 AC_SUBST(POPT_LIBS)
 469
 470 PKG_CHECK_MODULES([libxml2], [libxml-2.0 >= 2.7.6])
 471
 472 AC_CHECK_FUNC([clock_gettime], [AC_DEFINE_UNQUOTED([LTTNG_HAVE_CLOCK_GETTIME], 1, [Has clock_gettime() support.])])
 473
 474 # URCU library version needed or newer
 475 m4_define([WRONG_LIBURCU_MSG], [Userspace RCU (liburcu) >= 0.9.0 is needed])
 476
 477 # Check liburcu needed function calls
 478 AC_CHECK_DECL([cds_list_add], [],
 479         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/list.h>]])
 480 AC_CHECK_DECL([cds_wfcq_init], [],
 481         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/wfcqueue.h>]])
 482 AC_CHECK_DECL([cds_wfcq_dequeue_blocking], [],
 483         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/wfcqueue.h>]])
 484 AC_CHECK_DECL([futex_async], [],
 485         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/futex.h>]])
 486 AC_CHECK_DECL([rcu_thread_offline], [],
 487         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
 488 AC_CHECK_DECL([rcu_thread_online], [],
 489         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
 490 AC_CHECK_DECL([caa_likely], [],
 491         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
 492 AC_CHECK_LIB([urcu-cds], [_cds_lfht_new], [],
 493         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])])
 494
 495 #Function added in urcu 0.7.0
 496 AC_CHECK_DECL([cmm_smp_mb__before_uatomic_or], [],
 497         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]]
 498 )
 499
 500 #Function added in urcu 0.9.0
 501 AC_CHECK_DECL([urcu_ref_get_unless_zero], [],
 502         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/ref.h>]]
 503 )
 504
 505 # Check for libkmod, it will be auto-neabled if found but won't fail if it's not,
 506 # it can be explicitly disabled with --without-kmod
 507 AH_TEMPLATE([HAVE_KMOD], [Define if you have kmod support])
 508 AC_ARG_WITH([kmod],
 509   [AS_HELP_STRING([--with-kmod], [build with lkmod support @<:@default=check@:>@])],
 510   [],
 511   [with_kmod=check]
 512 )
 513
 514 AS_IF([test "x$with_kmod" != "xno"],
 515   [
 516     AC_CHECK_LIB([kmod], [kmod_module_probe_insert_module],
 517       [
 518         AC_DEFINE([HAVE_KMOD], [1])
 519         KMOD_LIBS="-lkmod"
 520       ],
 521       [
 522         if test "x$with_kmod" != xcheck; then
 523           AC_MSG_FAILURE([Cannot find libkmod. Use [LDFLAGS]=-Ldir and [CPPFLAGS]=-Idir to specify its location.])
 524         else
 525           with_kmod=no
 526         fi
 527       ]
 528     )
 529   ]
 530 )
 531 AC_SUBST(KMOD_LIBS)
 532
 533 # Check for liblttng-ust-ctl, fail if it's not found,
 534 # it can be explicitly disabled with --without-lttng-ust
 535 AH_TEMPLATE([HAVE_LIBLTTNG_UST_CTL], [Define if you have LTTng-UST control support])
 536 AC_ARG_WITH([lttng-ust],
 537   [AS_HELP_STRING([--without-lttng-ust], [build without LTTng-UST (Userspace Tracing) support])],
 538   [],
 539   [with_lttng_ust=yes]
 540 )
 541
 542 AS_IF([test "x$with_lttng_ust" = "xyes"], [
 543   AC_DEFINE([HAVE_LIBLTTNG_UST_CTL], [1])
 544
 545   # Check for liblttng-ust
 546   PKG_CHECK_MODULES([UST], [lttng-ust >= $major_version.$minor_version])
 547
 548   # Check for liblttng-ust-ctl
 549   PKG_CHECK_MODULES([UST_CTL], [lttng-ust-ctl >= $major_version.$minor_version])
 550
 551   AM_CPPFLAGS="$AM_CPPFLAGS $UST_CFLAGS"
 552 ])
 553
 554 AM_CONDITIONAL([HAVE_LIBLTTNG_UST_CTL], [test "x$with_lttng_ust" = "xyes"])
 555
 556
 557 # Check for fmemopen
 558 AC_CHECK_LIB([c], [fmemopen],
 559 [
 560         AC_DEFINE_UNQUOTED([LTTNG_HAVE_FMEMOPEN], 1, [Has fmemopen support.])
 561 ]
 562 )
 563
 564 # check for libpfm
 565 AC_CHECK_LIB([pfm], [pfm_initialize],
 566              [
 567               have_libpfm=yes
 568               ])
 569 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBPFM], [test "x$have_libpfm" = "xyes"])
 570
 571 # For Python
 572 # SWIG version needed or newer:
 573 swig_version=2.0.0
 574
 575 AC_ARG_ENABLE([python-bindings],
 576               [AC_HELP_STRING([--enable-python-bindings],
 577                               [compile Python bindings])],
 578               [enable_python_binding=$enableval], [enable_python_binding=no])
 579
 580 AM_CONDITIONAL([PYTHON_BINDING], [test "x$enable_python_binding" = xyes])
 581
 582 if test "x$enable_python_binding" = xyes; then
 583   AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ])
 584   AS_IF([test x$enable_shared = xno], [ AC_MSG_ERROR([Python bindings require shared libraries.]) ])
 585   AM_PATH_PYTHON([3.0])
 586
 587   AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config])
 588   AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
 589   AS_IF([test -z "$PYTHON_INCLUDE"], [
 590     AS_IF([test -z "$PYTHON_CONFIG"], [
 591       AC_PATH_PROGS([PYTHON_CONFIG],
 592                     [python$PYTHON_VERSION-config python-config],
 593                     [no],
 594                     [`dirname $PYTHON`])
 595       AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
 596     ])
 597     AC_MSG_CHECKING([python include flags])
 598     PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
 599     AC_MSG_RESULT([$PYTHON_INCLUDE])
 600   ])
 601
 602 else
 603     AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl
 604 [if you want Python bindings.])
 605
 606 fi
 607
 608 # Epoll check. If not present, the build will fallback on poll() API
 609 AX_HAVE_EPOLL(
 610         [AX_CONFIG_FEATURE_ENABLE(epoll)],
 611         [AX_CONFIG_FEATURE_DISABLE(epoll)]
 612 )
 613 AX_CONFIG_FEATURE(
 614         [epoll], [This platform supports epoll(7)],
 615         [HAVE_EPOLL], [This platform supports epoll(7).],
 616         [enable_epoll="yes"], [enable_epoll="no"]
 617 )
 618 AM_CONDITIONAL([COMPAT_EPOLL], [ test "$enable_epoll" = "yes" ])
 619
 620 AS_IF([test "x$ac_cv_func_dirfd" = "xyes"],
 621         [AX_CONFIG_FEATURE_ENABLE(dirfd)],
 622         [AX_CONFIG_FEATURE_DISABLE(dirfd)]
 623 )
 624 AX_CONFIG_FEATURE(
 625         [dirfd], [Use directory file descriptors],
 626         [COMPAT_DIRFD], [This platform supports directory file descriptors.],
 627         [enable_dirfd="yes"], [enable_dirfd="no"]
 628 )
 629 AM_CONDITIONAL([COMPAT_DIRFD], [ test "$enable_dirfd" = "yes" ])
 630
 631 AM_CONDITIONAL([TEST_JAVA_JUL_AGENT], [test "x$test_java_agent_jul" = "xyes"])
 632 AM_CONDITIONAL([TEST_JAVA_LOG4J_AGENT], [test "x$test_java_agent_log4j" = "xyes"])
 633
 634 if test "x$test_java_agent_jul" = "xyes" || test "x$test_java_agent_log4j" = "xyes"; then
 635         AX_JAVA_OPTIONS
 636         AX_PROG_JAVAC
 637         AX_PROG_JAVA
 638         AX_PROG_JAR
 639
 640         AX_CHECK_CLASSPATH
 641
 642         # Check for Java UST agent common class first
 643         AX_CHECK_CLASS(org.lttng.ust.agent.AbstractLttngAgent)
 644         if test "x$ac_cv_class_org_lttng_ust_agent_AbstractLttngAgent" = "xno"; then
 645                 AC_MSG_ERROR([The UST Java agent common class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-common.jar"])
 646         fi
 647
 648         if test "x$test_java_agent_jul" = "xyes"; then
 649                 # Check for JUL agent class
 650                 AX_CHECK_CLASS(org.lttng.ust.agent.jul.LttngLogHandler)
 651                 if test "x$ac_cv_class_org_lttng_ust_agent_jul_LttngLogHandler" = "xno"; then
 652                         AC_MSG_ERROR([The UST Java agent JUL class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-jul.jar"])
 653                 fi
 654         fi
 655
 656         if test "x$test_java_agent_log4j" = "xyes"; then
 657                 # Check for Log4j agent class
 658                 AX_CHECK_CLASS(org.lttng.ust.agent.log4j.LttngLogAppender)
 659                 if test "x$ac_cv_class_org_lttng_ust_agent_log4j_LttngLogAppender" = "xno"; then
 660                         AC_MSG_ERROR([The UST Java agent Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-log4j.jar"])
 661                 fi
 662
 663                 # Check for Log4j class
 664                 AX_CHECK_CLASS(org.apache.log4j.Logger)
 665                 if test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"; then
 666                         AC_MSG_ERROR([The Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j.jar"])
 667                 fi
 668         fi
 669 fi
 670
 671 # enable building man pages (user's intention)
 672 AC_ARG_ENABLE(
 673         man-pages,
 674         AS_HELP_STRING(
 675                 [--disable-man-pages],
 676                 [Do not build and install man pages (already built in a distributed tarball)]
 677         ),
 678         [man_pages_opt=$enableval],
 679         [man_pages_opt=yes]
 680 )
 681
 682 # check for asciidoc and xmlto if we enabled building the man pages
 683 have_asciidoc_xmlto=no
 684 warn_prebuilt_man_pages=no
 685
 686 AS_IF([test "x$man_pages_opt" = "xyes"], [
 687         AC_PATH_PROG([ASCIIDOC], [asciidoc], [no])
 688         AC_PATH_PROG([XMLTO], [xmlto], [no])
 689
 690         AS_IF([test "x$ASCIIDOC" = "xno" || test "x$XMLTO" = "xno"], [
 691                 AS_IF([test "x$in_git_repo" = "xyes"], [
 692                         # this is an error because we're in the Git repo, which
 693                         # means the man pages are not already generated for us,
 694                         # thus asciidoc/xmlto are required because we were asked
 695                         # to build the man pages
 696                         AC_MSG_ERROR([
 697 You need asciidoc and xmlto to build the LTTng-tools man pages. Use
 698 --disable-man-pages to disable building the man pages, in which case
 699 they will not be installed.
 700                         ])
 701                 ], [
 702                         # only warn here: since we're in the tarball, the man
 703                         # pages should already be generated at this point, thus
 704                         # asciidoc/xmlto are not strictly required
 705                         warn_prebuilt_man_pages=yes
 706                 ])
 707         ], [
 708                 have_asciidoc_xmlto=yes
 709         ])
 710 ])
 711
 712 # export man page build condition: build the man pages if the user
 713 # asked for it, and if the tools are available
 714 AM_CONDITIONAL([MAN_PAGES_OPT], [test "x$man_pages_opt" != "xno"])
 715 AM_CONDITIONAL([HAVE_ASCIIDOC_XMLTO], [test "x$have_asciidoc_xmlto" = "xyes"])
 716
 717 AC_DEFINE_UNQUOTED([MANPATH], ["`eval eval echo $mandir`"], [Path to man pages.])
 718
 719 # embedded --help message
 720 AC_ARG_ENABLE(
 721         [embedded-help],
 722         AS_HELP_STRING(
 723                 [--enable-embedded-help],
 724                 [Embed the --help messages in the executable files]
 725         ),
 726         [embedded_help=$enableval],
 727         [embedded_help=no]
 728 )
 729 AS_IF([test "x$embedded_help" = "xyes"], [
 730         AS_IF([test "x$man_pages_opt" = "xno"], [
 731                 AC_MSG_ERROR([You need the --enable-man-pages option with the --enable-embedded-help option.])
 732         ])
 733         AC_PATH_PROG([man_prog_path], [man], [no])
 734         AS_IF([test "x$man_prog_path" = "xno"], [
 735                 AC_MSG_ERROR([You need man with the --enable-embedded-help option.])
 736         ])
 737         AC_DEFINE_UNQUOTED([LTTNG_EMBED_HELP], 1, [Embed --help messages.])
 738         AC_SUBST([MANPROG], [$man_prog_path])
 739 ])
 740 AM_CONDITIONAL([EMBED_HELP], [test "x$embedded_help" != "xno"])
 741
 742 # Python agent test
 743 UST_PYTHON_AGENT="lttngust"
 744
 745 AC_ARG_ENABLE(test-python2-agent,
 746         AS_HELP_STRING([--enable-test-python2-agent],
 747                 [enable tests for python2 agent. Python2 interpreter path can be overridden by setting the PYTHON2 environment variable. Default: Autodetect]
 748         ),[:],[test_python2_agent_autodetect=yes]
 749 )
 750
 751 AC_ARG_ENABLE(test-python3-agent,
 752         AS_HELP_STRING([--enable-test-python3-agent],
 753                 [enable tests for python3 agent. Python3 interpreter path can be overridden by setting the PYTHON3 environment variable. Default: Autodetect]
 754         ),[:],[test_python3_agent_autodetect=yes]
 755 )
 756
 757 AC_ARG_ENABLE(test-python-agent-all,
 758         AS_HELP_STRING([--enable-test-python-agent-all],
 759                 [enable test for all python{2/3} agent.]
 760         ),
 761 )
 762
 763 AS_IF([test ! -z "$enable_test_python_agent_all"], [
 764        unset test_python2_agent_autodetect
 765        unset test_python3_agent_autodetect
 766 ])
 767
 768 AS_IF([test "x$enable_test_python_agent_all" = "xyes"], [
 769        enable_test_python2_agent=yes
 770        enable_test_python3_agent=yes
 771 ])
 772
 773 AS_IF([test "x$enable_test_python_agent_all" = "xno"], [
 774        enable_test_python2_agent=no
 775        enable_test_python3_agent=no
 776 ])
 777
 778
 779 AS_IF([test "x$enable_test_python2_agent" = "xyes" -o "x$test_python2_agent_autodetect" = "xyes" ], [
 780         AS_IF([test -z "$PYTHON2"], [
 781                         PYTHON2=python2
 782                 ], [
 783                         AC_MSG_WARN([Using user-defined PYTHON2 ($PYTHON2) for lttng-ust python2 agent check])
 784         ])
 785
 786         AC_PATH_PROG([PYTHON2_BIN],[$PYTHON2])
 787         AS_IF([test -z "$PYTHON2_BIN"], [
 788                 AS_IF([test -z "$test_python2_agent_autodetect"],[
 789                         AC_MSG_ERROR([No python2 interpreter found. PYTHON2 can be set to override default interpreter path])
 790                 ])
 791         ], [
 792                 AC_MSG_CHECKING([for python2 lttng-ust agent])
 793                 AS_IF([$PYTHON2_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
 794                         PYTHON2_AGENT=$PYTHON2_BIN
 795                         AC_MSG_RESULT([yes])
 796                         RUN_PYTHON_AGENT_TEST=yes
 797                 ], [
 798                         AC_MSG_RESULT([no])
 799                         AS_IF([test -z "$test_python2_agent_autodetect"],[
 800                                 AC_MSG_ERROR([No python2 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
 801                         ])
 802                 ])
 803
 804         ])
 805
 806 ])
 807
 808 AS_IF([test "x$enable_test_python3_agent" = "xyes" -o "x$test_python3_agent_autodetect" = "xyes" ], [
 809         AS_IF([test -z "$PYTHON3"], [
 810                 PYTHON3=python3
 811         ], [
 812                 AC_MSG_WARN([Using user-defined PYTHON3 ($PYTHON3) for lttng-ust python3 agent check])
 813         ])
 814
 815         AC_PATH_PROG([PYTHON3_BIN],[$PYTHON3])
 816         AS_IF([test -z "$PYTHON3_BIN"], [
 817                 AS_IF([test -z "$test_python3_agent_autodetect"],[
 818                         AC_MSG_ERROR([No python3 interpreter found. PYTHON3 can be set to override default interpreter path])
 819                 ])
 820         ], [
 821                 AC_MSG_CHECKING([for python3 lttng-ust agent])
 822                 AS_IF([$PYTHON3_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
 823                         PYTHON3_AGENT=$PYTHON3_BIN
 824                         AC_MSG_RESULT([yes])
 825                         RUN_PYTHON_AGENT_TEST=yes
 826                 ], [
 827                         AC_MSG_RESULT([no])
 828                         AS_IF([test -z "$test_python3_agent_autodetect"],[
 829                                 AC_MSG_ERROR([No python3 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
 830                         ])
 831                 ])
 832
 833         ])
 834 ])
 835 AC_SUBST([RUN_PYTHON_AGENT_TEST])
 836 AC_SUBST([PYTHON2_AGENT])
 837 AC_SUBST([PYTHON3_AGENT])
 838
 839 AC_ARG_ENABLE([test-sdt-uprobe],
 840   [AS_HELP_STRING([--enable-test-sdt-uprobe], [enable the LTTng UST SDT uprobe tests [default=autodetect]])],
 841   [test_sdt_uprobe="$enableval"],
 842   [test_sdt_uprobe=autodetect]
 843 )
 844
 845 AS_IF([test "$test_sdt_uprobe" != "no"], [
 846   LTTNG_CHECK_SDT_WORKS
 847   AC_PATH_PROG([DTRACE], [dtrace])
 848 ])
 849
 850 AS_IF([test "$test_sdt_uprobe" = "yes"], [
 851   AS_IF([test "$lttng_cv_sdt_works" = "no"], [
 852     AC_MSG_ERROR([Cannot find 'sys/sdt.h'.])
 853   ])
 854   AS_IF([test "x$DTRACE" = "x"], [
 855     AC_MSG_ERROR([Cannot find SystemTap dtrace. You can set the DTRACE variable to override automatic detection.])
 856   ])
 857 ])
 858
 859 AS_IF([test "$test_sdt_uprobe" = "autodetect"], [
 860   AS_IF([test "$lttng_cv_sdt_works" = "yes"], [
 861     AS_IF([test "x$DTRACE" != "x"], [
 862       test_sdt_uprobe=yes
 863     ])
 864   ])
 865 ])
 866
 867 AM_CONDITIONAL([TEST_SDT_UPROBE], [test "$test_sdt_uprobe" = "yes"])
 868
 869 # Arguments for binaries build exclusion
 870 AC_ARG_ENABLE([bin-lttng], AS_HELP_STRING([--disable-bin-lttng],[Disable the build of lttng binaries]))
 871 AC_ARG_ENABLE([bin-lttng-consumerd], AS_HELP_STRING([--disable-bin-lttng-consumerd],
 872               [Disable the build of lttng-consumerd binaries]))
 873 AC_ARG_ENABLE([bin-lttng-crash], AS_HELP_STRING([--disable-bin-lttng-crash],[Disable the build of lttng-crash binaries]))
 874 AC_ARG_ENABLE([bin-lttng-relayd], AS_HELP_STRING([--disable-bin-lttng-relayd],
 875               [Disable the build of lttng-relayd binaries]))
 876 AC_ARG_ENABLE([bin-lttng-sessiond], AS_HELP_STRING([--disable-bin-lttng-sessiond],
 877               [Disable the build of lttng-sessiond binaries]))
 878 AC_ARG_ENABLE([extras], AS_HELP_STRING([--disable-extras],
 879               [Disable the build of the extra components]))
 880
 881
 882 # Always build libconfig since it a dependency of libcommon
 883 build_lib_config=yes
 884
 885 build_lib_compat=no
 886 build_lib_consumer=no
 887 build_lib_hashtable=no
 888 build_lib_health=no
 889 build_lib_index=no
 890 build_lib_kernel_consumer=no
 891 build_lib_kernel_ctl=no
 892 build_lib_lttng_ctl=no
 893 build_lib_relayd=no
 894 build_lib_fd_tracker=no
 895 build_lib_sessiond_comm=no
 896 build_lib_testpoint=no
 897 build_lib_ust_consumer=no
 898
 899 # There is an overlap for enabled dependencies, but this makes everything
 900 # simpler. libcommon and libconfig are always compiled so they are not repeated
 901 # here.
 902
 903 # Enable binary dependencies.
 904 AS_IF([test x$enable_bin_lttng != xno],
 905       [
 906        build_lib_lttng_ctl=yes
 907       ]
 908 )
 909
 910 AS_IF([test x$enable_bin_lttng_consumerd != xno],
 911       [
 912        build_lib_consumer=yes
 913        build_lib_sessiond_comm=yes
 914        build_lib_index=yes
 915        build_lib_health=yes
 916        build_lib_testpoint=yes
 917       ]
 918 )
 919
 920 AS_IF([test x$enable_bin_lttng_crash != xno],
 921       # Do nothing since libconfig and libcommon are built by default.
 922       []
 923 )
 924
 925 AS_IF([test x$enable_bin_lttng_relayd != xno],
 926       [
 927        build_lib_lttng_ctl=yes
 928        build_lib_sessiond_comm=yes
 929        build_lib_hashtable=yes
 930        build_lib_compat=yes
 931        build_lib_index=yes
 932        build_lib_health=yes
 933        build_lib_testpoint=yes
 934        build_lib_fd_tracker=yes
 935       ]
 936 )
 937 AS_IF([test x$enable_bin_lttng_sessiond != xno],
 938       [
 939        build_lib_lttng_ctl=yes
 940        build_lib_sessiond_comm=yes
 941        build_lib_kernel_ctl=yes
 942        build_lib_hashtable=yes
 943        build_lib_compat=yes
 944        build_lib_relayd=yes
 945        build_lib_testpoint=yes
 946        build_lib_health=yes
 947       ]
 948 )
 949
 950 # Libraries dependencies enabling
 951 AS_IF([test x$build_lib_lttng_ctl = xyes],
 952       [
 953        build_lib_sessiond_comm=yes
 954        build_lib_hashtable=yes
 955       ]
 956 )
 957
 958 AS_IF([test x$build_lib_consumer = xyes],
 959       [
 960        build_lib_sessiond_comm=yes
 961        build_lib_kernel_consumer=yes
 962        build_lib_hashtable=yes
 963        build_lib_compat=yes
 964        build_lib_relayd=yes
 965        AS_IF([test "x$with_lttng_ust" = "xyes"], [build_lib_ust_consumer=yes])
 966       ]
 967 )
 968
 969 AS_IF([test x$build_lib_kernel_consumer = xyes],
 970       [
 971        build_lib_kernel_ctl=yes
 972        build_lib_relayd=yes
 973       ]
 974 )
 975
 976 AS_IF([test x$build_lib_relayd = xyes],
 977       [
 978        build_lib_sessiond_comm=yes
 979       ]
 980 )
 981
 982 # Find arch type
 983 AS_CASE([$host_cpu],
 984         [k1om], [ARCHTYPE="x86"],
 985         [i386], [ARCHTYPE="x86"],
 986         [i486], [ARCHTYPE="x86"],
 987         [i586], [ARCHTYPE="x86"],
 988         [i686], [ARCHTYPE="x86"],
 989         [amd64], [ARCHTYPE="x86"],
 990         [x86_64], [ARCHTYPE="x86"],
 991         [powerpc], [ARCHTYPE="ppc"],
 992         [ppc64], [ARCHTYPE="ppc"],
 993         [powerpc64], [ARCHTYPE="ppc"],
 994         [powerpc64le], [ARCHTYPE="ppc"],
 995         [ppc], [ARCHTYPE="ppc"],
 996         [s390], [ARCHTYPE="s390"],
 997         [s390x], [ARCHTYPE="s390"],
 998         [sparc], [ARCHTYPE="sparc64"],
 999         [sparc64], [ARCHTYPE="sparc64"],
1000         [alpha*], [ARCHTYPE="alpha"],
1001         [ia64], [ARCHTYPE="ia64"],
1002         [arm*], [ARCHTYPE="arm"],
1003         [aarch64*], [ARCHTYPE="aarch64"],
1004         [mips*], [ARCHTYPE="mips"],
1005         [nios2*], [ARCHTYPE="nios2"],
1006         [tile*], [ARCHTYPE="tile"],
1007         [hppa*], [ARCHTYPE="hppa"],
1008         [m68k], [ARCHTYPE="m68k"],
1009         [riscv*], [ARCHTYPE="riscv"],
1010         [ARCHTYPE="unknown"]
1011 )
1012
1013 AC_SUBST(ARCHTYPE)
1014
1015 AH_TEMPLATE([HAVE_MODULES_USERSPACE_CALLSTACK_CONTEXT], [Define if you have LTTng-modules userspace callstack tracing support])
1016 AC_MSG_CHECKING([for architecture support of userspace callstack tracing from the kernel])
1017 AS_IF([test "x$ARCHTYPE" = "xx86"],[
1018         # Userspace callstack capture is only supported by the Linux kernel on x86.
1019         AC_MSG_RESULT([yes])
1020         have_modules_userspace_callstack_context=yes
1021         AC_DEFINE([HAVE_MODULES_USERSPACE_CALLSTACK_CONTEXT], [1])
1022 ], [
1023         AC_MSG_RESULT([no])
1024         have_modules_userspace_callstack_context=no
1025 ])
1026 AM_CONDITIONAL([HAVE_MODULES_USERSPACE_CALLSTACK_CONTEXT], [test x$have_modules_userspace_callstack_context != xno])
1027
1028 # Export binaries build conditions.
1029 AM_CONDITIONAL([BUILD_BIN_LTTNG], [test x$enable_bin_lttng != xno])
1030 AM_CONDITIONAL([BUILD_BIN_LTTNG_CONSUMERD], [test x$enable_bin_lttng_consumerd != xno])
1031 AM_CONDITIONAL([BUILD_BIN_LTTNG_CRASH], [test x$enable_bin_lttng_crash != xno])
1032 AM_CONDITIONAL([BUILD_BIN_LTTNG_RELAYD], [test x$enable_bin_lttng_relayd != xno])
1033 AM_CONDITIONAL([BUILD_BIN_LTTNG_SESSIOND], [test x$enable_bin_lttng_sessiond != xno])
1034
1035 # Export the tests and extras build conditions.
1036 AS_IF([\
1037 test "x$enable_bin_lttng" != "xno" && \
1038 test "x$enable_bin_lttng_consumerd" != "xno" && \
1039 test "x$enable_bin_lttng_crash" != "xno" && \
1040 test "x$enable_bin_lttng_relayd" != "xno" && \
1041 test "x$enable_bin_lttng_sessiond" != "xno"],
1042 [build_tests=yes],
1043 [build_tests=no]
1044 )
1045
1046 AM_CONDITIONAL([BUILD_TESTS], [test x$build_tests = xyes])
1047 AM_CONDITIONAL([BUILD_EXTRAS], [test x$enable_extras != xno])
1048
1049 # Export libraries build conditions.
1050 AM_CONDITIONAL([BUILD_LIB_COMPAT], [test x$build_lib_compat = xyes])
1051 AM_CONDITIONAL([BUILD_LIB_CONFIG], [test x$build_lib_config = xyes])
1052 AM_CONDITIONAL([BUILD_LIB_CONSUMER], [test x$build_lib_consumer = xyes])
1053 AM_CONDITIONAL([BUILD_LIB_HASHTABLE], [test x$build_lib_hashtable = xyes])
1054 AM_CONDITIONAL([BUILD_LIB_HEALTH], [test x$build_lib_health = xyes])
1055 AM_CONDITIONAL([BUILD_LIB_INDEX], [test x$build_lib_index = xyes])
1056 AM_CONDITIONAL([BUILD_LIB_KERNEL_CONSUMER], [test x$build_lib_kernel_consumer = xyes])
1057 AM_CONDITIONAL([BUILD_LIB_KERNEL_CTL], [test x$build_lib_kernel_ctl = xyes])
1058 AM_CONDITIONAL([BUILD_LIB_LTTNG_CTL], [test x$build_lib_lttng_ctl = xyes])
1059 AM_CONDITIONAL([BUILD_LIB_RELAYD], [test x$build_lib_relayd = xyes])
1060 AM_CONDITIONAL([BUILD_LIB_FD_TRACKER], [test x$build_lib_fd_tracker = xyes])
1061 AM_CONDITIONAL([BUILD_LIB_SESSIOND_COMM], [test x$build_lib_sessiond_comm = xyes])
1062 AM_CONDITIONAL([BUILD_LIB_TESTPOINT], [test x$build_lib_testpoint = xyes])
1063 AM_CONDITIONAL([BUILD_LIB_UST_CONSUMER], [test x$build_lib_ust_consumer = xyes])
1064
1065 AM_CFLAGS="${WARN_CFLAGS} -fno-strict-aliasing $PTHREAD_CFLAGS"
1066 AC_SUBST(AM_CFLAGS)
1067
1068 # This is set even though it is empty, so Makefiles can do "AM_LDFLAGS += ...".
1069 AM_LDFLAGS=""
1070 AC_SUBST(AM_LDFLAGS)
1071
1072 # The order in which the include folders are searched is important.
1073 # The top_builddir should always be searched first in the event that a build
1074 # time generated file is included. An example of this is the "version.i" file.
1075 # In a scenario where lttng-tools is built from a distribution tarball and in a
1076 # out-of-tree manner, the generated "version.i" has priority on the one from
1077 # the source (distribution tarball) and must be found first.
1078 AM_CPPFLAGS="-I\$(top_builddir)/include -I\$(top_srcdir)/include -I\$(top_srcdir)/src -include config.h $AM_CPPFLAGS"
1079 AC_SUBST(AM_CPPFLAGS)
1080
1081 lttngincludedir="${includedir}/lttng"
1082 AC_SUBST(lttngincludedir)
1083
1084 lttngactionincludedir="${includedir}/lttng/action"
1085 AC_SUBST(lttngactionincludedir)
1086
1087 lttngconditionincludedir="${includedir}/lttng/condition"
1088 AC_SUBST(lttngconditionincludedir)
1089
1090 lttngnotificationincludedir="${includedir}/lttng/notification"
1091 AC_SUBST(lttngnotificationincludedir)
1092
1093 lttngtriggerincludedir="${includedir}/lttng/trigger"
1094 AC_SUBST(lttngtriggerincludedir)
1095
1096 lttnglibexecdir="${libdir}/lttng/libexec"
1097 AC_SUBST(lttnglibexecdir)
1098
1099 AC_CONFIG_FILES([
1100         Makefile
1101         doc/Makefile
1102         doc/man/Makefile
1103         doc/man/asciidoc-attrs.conf
1104         include/Makefile
1105         extras/Makefile
1106         extras/bindings/Makefile
1107         extras/bindings/swig/Makefile
1108         extras/bindings/swig/python/Makefile
1109         extras/core-handler/Makefile
1110         src/Makefile
1111         src/common/Makefile
1112         src/common/kernel-ctl/Makefile
1113         src/common/kernel-consumer/Makefile
1114         src/common/consumer/Makefile
1115         src/common/ust-consumer/Makefile
1116         src/common/hashtable/Makefile
1117         src/common/sessiond-comm/Makefile
1118         src/common/compat/Makefile
1119         src/common/relayd/Makefile
1120         src/common/testpoint/Makefile
1121         src/common/index/Makefile
1122         src/common/health/Makefile
1123         src/common/config/Makefile
1124         src/common/string-utils/Makefile
1125         src/common/fd-tracker/Makefile
1126         src/lib/Makefile
1127         src/lib/lttng-ctl/Makefile
1128         src/lib/lttng-ctl/filter/Makefile
1129         src/lib/lttng-ctl/lttng-ctl.pc
1130         src/bin/Makefile
1131         src/bin/lttng-consumerd/Makefile
1132         src/bin/lttng-sessiond/Makefile
1133         src/bin/lttng-relayd/Makefile
1134         src/bin/lttng/Makefile
1135         src/bin/lttng-crash/Makefile
1136         tests/Makefile
1137         tests/destructive/Makefile
1138         tests/regression/Makefile
1139         tests/regression/kernel/Makefile
1140         tests/regression/tools/Makefile
1141         tests/regression/tools/streaming/Makefile
1142         tests/regression/tools/filtering/Makefile
1143         tests/regression/tools/health/Makefile
1144         tests/regression/tools/tracefile-limits/Makefile
1145         tests/regression/tools/snapshots/Makefile
1146         tests/regression/tools/live/Makefile
1147         tests/regression/tools/exclusion/Makefile
1148         tests/regression/tools/save-load/Makefile
1149         tests/regression/tools/save-load/configuration/Makefile
1150         tests/regression/tools/mi/Makefile
1151         tests/regression/tools/wildcard/Makefile
1152         tests/regression/tools/crash/Makefile
1153         tests/regression/tools/regen-metadata/Makefile
1154         tests/regression/tools/regen-statedump/Makefile
1155         tests/regression/tools/notification/Makefile
1156         tests/regression/tools/rotation/Makefile
1157         tests/regression/tools/base-path/Makefile
1158         tests/regression/tools/metadata/Makefile
1159         tests/regression/tools/tracker/Makefile
1160         tests/regression/tools/working-directory/Makefile
1161         tests/regression/tools/relayd-grouping/Makefile
1162         tests/regression/tools/clear/Makefile
1163         tests/regression/ust/Makefile
1164         tests/regression/ust/nprocesses/Makefile
1165         tests/regression/ust/high-throughput/Makefile
1166         tests/regression/ust/low-throughput/Makefile
1167         tests/regression/ust/before-after/Makefile
1168         tests/regression/ust/buffers-pid/Makefile
1169         tests/regression/ust/periodical-metadata-flush/Makefile
1170         tests/regression/ust/multi-session/Makefile
1171         tests/regression/ust/multi-lib/Makefile
1172         tests/regression/ust/overlap/Makefile
1173         tests/regression/ust/overlap/demo/Makefile
1174         tests/regression/ust/linking/Makefile
1175         tests/regression/ust/daemon/Makefile
1176         tests/regression/ust/exit-fast/Makefile
1177         tests/regression/ust/fork/Makefile
1178         tests/regression/ust/libc-wrapper/Makefile
1179         tests/regression/ust/baddr-statedump/Makefile
1180         tests/regression/ust/ust-dl/Makefile
1181         tests/regression/ust/java-jul/Makefile
1182         tests/regression/ust/java-log4j/Makefile
1183         tests/regression/ust/python-logging/Makefile
1184         tests/regression/ust/getcpu-override/Makefile
1185         tests/regression/ust/clock-override/Makefile
1186         tests/regression/ust/type-declarations/Makefile
1187         tests/regression/ust/rotation-destroy-flush/Makefile
1188         tests/regression/ust/blocking/Makefile
1189         tests/regression/ust/namespaces/Makefile
1190         tests/stress/Makefile
1191         tests/unit/Makefile
1192         tests/unit/ini_config/Makefile
1193         tests/perf/Makefile
1194         tests/utils/Makefile
1195         tests/utils/tap/Makefile
1196         tests/utils/testapp/Makefile
1197         tests/utils/testapp/gen-ns-events/Makefile
1198         tests/utils/testapp/gen-kernel-test-events/Makefile
1199         tests/utils/testapp/gen-ust-events/Makefile
1200         tests/utils/testapp/gen-ust-events-ns/Makefile
1201         tests/utils/testapp/gen-syscall-events-callstack/Makefile
1202         tests/utils/testapp/gen-ust-nevents/Makefile
1203         tests/utils/testapp/gen-ust-nevents-str/Makefile
1204         tests/utils/testapp/gen-syscall-events/Makefile
1205         tests/utils/testapp/gen-ust-tracef/Makefile
1206         tests/utils/testapp/userspace-probe-elf-binary/Makefile
1207         tests/utils/testapp/userspace-probe-elf-cxx-binary/Makefile
1208         tests/utils/testapp/userspace-probe-sdt-binary/Makefile
1209 ])
1210
1211 # Inject variable into python test script.
1212 AC_CONFIG_FILES([tests/regression/ust/python-logging/test_python_logging],[chmod +x tests/regression/ust/python-logging/test_python_logging])
1213 # Inject LTTNG_TOOLS_BUILD_WITH_LIBPFM variable in test script.
1214 AC_CONFIG_FILES([tests/perf/test_perf_raw],[chmod +x tests/perf/test_perf_raw])
1215 AC_CONFIG_FILES([tests/regression/ust/ust-dl/test_ust-dl],[chmod +x tests/regression/ust/ust-dl/test_ust-dl])
1216
1217 AC_OUTPUT
1218
1219 #
1220 # Mini-report on what will be built.
1221 #
1222
1223 PPRINT_INIT
1224 PPRINT_SET_INDENT(1)
1225 PPRINT_SET_TS(38)
1226
1227 AS_ECHO
1228 AS_ECHO("${PPRINT_COLOR_BLDBLU}LTTng-tools $PACKAGE_VERSION \"$version_name\"$PPRINT_COLOR_RST")
1229 AS_ECHO
1230
1231 AS_IF([test -n "$report_fold"], [
1232         AS_ECHO("`AS_ECHO("$version_description") | $report_fold -s`")
1233 ], [
1234         AS_ECHO("$version_description")
1235 ])
1236
1237 AS_ECHO
1238 PPRINT_SUBTITLE([Features])
1239
1240 # Target architecture we're building for.
1241 target_arch=$host_cpu
1242 [
1243 for f in $CFLAGS; do
1244         if test $f = "-m32"; then
1245                         target_arch="32-bit"
1246         elif test $f = "-m64"; then
1247                         target_arch="64-bit"
1248         fi
1249 done
1250 ]
1251 PPRINT_PROP_STRING([Target architecture], $target_arch)
1252
1253 # kmod enabled/disabled
1254 test "x$with_kmod" != "xno" && value=1 || value=0
1255 PPRINT_PROP_BOOL([libkmod support], $value)
1256
1257 # LTTng-UST enabled/disabled
1258 test "x$with_lttng_ust" = "xyes" && value=1 || value=0
1259 PPRINT_PROP_BOOL([LTTng-UST support], $value)
1260
1261 AS_ECHO
1262 PPRINT_SUBTITLE([Binaries])
1263
1264 # List binaries to be built
1265 test x$enable_bin_lttng != xno && value=1 || value=0
1266 PPRINT_PROP_BOOL([lttng], $value)
1267
1268 test x$enable_bin_lttng_consumerd != xno && value=1 || value=0
1269 PPRINT_PROP_BOOL([lttng-consumerd], $value)
1270
1271 test x$enable_bin_lttng_crash != xno && value=1 || value=0
1272 PPRINT_PROP_BOOL([lttng-crash], $value)
1273
1274 test x$enable_bin_lttng_relayd != xno && value=1 || value=0
1275 PPRINT_PROP_BOOL([lttng-relayd], $value)
1276
1277 test x$enable_bin_lttng_sessiond != xno && value=1 || value=0
1278 PPRINT_PROP_BOOL([lttng-sessiond], $value)
1279
1280 # Extras
1281 test x$enable_extras != xno && value=1 || value=0
1282 AS_ECHO
1283 PPRINT_SET_INDENT(0)
1284 PPRINT_PROP_BOOL([Extras], $value, $PPRINT_COLOR_SUBTITLE)
1285 PPRINT_SET_INDENT(1)
1286
1287 AS_ECHO
1288 PPRINT_SUBTITLE([Tests])
1289
1290 # Print clear message that tests won't be built
1291 AS_IF([test "x$build_tests" = "xno"],[
1292         PPRINT_WARN([Tests won't be built since some binaries were disabled])
1293 ])
1294
1295 # LTTng UST Java agent JUL tests enabled/disabled
1296 test "x$test_java_agent_jul" = "xyes" && value=1 || value=0
1297 PPRINT_PROP_BOOL([LTTng-UST Java agent JUL tests], $value)
1298
1299 # LTTng UST Java agent Log4j tests enabled/disabled
1300 test "x$test_java_agent_log4j" = "xyes" && value=1 || value=0
1301 PPRINT_PROP_BOOL([LTTng-UST Java agent Log4j tests], $value)
1302
1303 test ! -z "$PYTHON2_AGENT" && value=1 || value=0
1304 PPRINT_PROP_BOOL([LTTng-UST Python2 agent tests], $value)
1305
1306 test ! -z "$PYTHON3_AGENT" && value=1 || value=0
1307 PPRINT_PROP_BOOL([LTTng-UST Python3 agent tests], $value)
1308
1309 # LTTng UST Java agent Log4j tests enabled/disabled
1310 test "x$test_sdt_uprobe" = "xyes" && value=1 || value=0
1311 PPRINT_PROP_BOOL([LTTng-UST SDT uprobe tests], $value)
1312
1313 #Python binding enabled/disabled
1314 test "x$enable_python_binding" = xyes && value=1 || value=0
1315 AS_ECHO
1316 PPRINT_SET_INDENT(0)
1317 PPRINT_PROP_BOOL([Python binding], $value, $PPRINT_COLOR_SUBTITLE)
1318
1319 # man pages build enabled/disabled
1320 m4_pushdef([build_man_pages_msg], [Build and install man pages])
1321
1322 AS_IF([test "x$man_pages_opt" != "xno"], [
1323         AS_IF([test "x$in_git_repo" = "xyes"], [
1324                 PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
1325         ], [
1326                 AS_IF([test "x$have_asciidoc_xmlto" = "xyes"], [
1327                         PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
1328                 ], [
1329                         PPRINT_PROP_STRING([build_man_pages_msg],
1330                                 [${PPRINT_COLOR_BLDGRN}yes (already built)],
1331                                 $PPRINT_COLOR_SUBTITLE)
1332                 ])
1333         ])
1334 ], [
1335         PPRINT_PROP_BOOL([build_man_pages_msg], 0, $PPRINT_COLOR_SUBTITLE)
1336 ])
1337
1338 m4_popdef([build_man_pages_msg])
1339
1340 test "x$embedded_help" = xyes && value=1 || value=0
1341 PPRINT_PROP_BOOL([Embed --help messages], $value, $PPRINT_COLOR_SUBTITLE)
1342
1343 PPRINT_SET_INDENT(1)
1344
1345 report_bindir="`eval eval echo $bindir`"
1346 report_libdir="`eval eval echo $libdir`"
1347
1348 # Print the bindir and libdir this `make install' will install into.
1349 AS_ECHO
1350 PPRINT_SUBTITLE([Install directories])
1351 PPRINT_PROP_STRING([Binaries], [$report_bindir])
1352 PPRINT_PROP_STRING([Libraries], [$report_libdir])
1353
1354 AS_ECHO
1355 PPRINT_SUBTITLE([Search directories])
1356
1357 # If we build the sessiond, print the paths it will use
1358 AS_IF([test "$SESSIOND_BIN" = ""],[
1359         path="$report_bindir/lttng-sessiond"
1360 ],[
1361         path="$SESSIOND_BIN"
1362 ])
1363 PPRINT_PROP_STRING([lttng-sessiond executable], [$path])
1364
1365 AS_IF([test "$CONSUMERD32_BIN" = ""],[
1366         path="`eval eval echo $lttnglibexecdir`/lttng-consumerd"
1367 ],[
1368         path="$CONSUMERD32_BIN"
1369 ])
1370 PPRINT_PROP_STRING([32-bit lttng-consumerd executable], [$path])
1371
1372 AS_IF([test "$CONSUMERD32_LIBDIR" = ""],[
1373         path="`eval eval echo $libdir`"
1374 ],[
1375         path="$CONSUMERD32_LIBDIR"
1376 ])
1377 PPRINT_PROP_STRING([32-bit consumer libraries], [$path])
1378
1379 AS_IF([test "$CONSUMERD64_BIN" = ""],[
1380         path="`eval eval echo $lttnglibexecdir`/lttng-consumerd"
1381 ],[
1382         path="$CONSUMERD64_BIN"
1383 ])
1384 PPRINT_PROP_STRING([64-bit lttng-consumerd executable], [$path])
1385
1386 AS_IF([test "$CONSUMERD64_LIBDIR" = ""],[
1387         path="`eval eval echo $libdir`"
1388 ],[
1389         path="$CONSUMERD64_LIBDIR"
1390 ])
1391 PPRINT_PROP_STRING([64-bit consumer libraries], [$path])
1392 PPRINT_SET_INDENT(0)
1393
1394 AS_IF([test "x$warn_prebuilt_man_pages" = "xyes" ], [
1395         AS_ECHO
1396         PPRINT_WARN([You need asciidoc and xmlto to build the LTTng-tools man pages.
1397
1398 Note that the man pages are already built in this distribution tarball,
1399 therefore asciidoc and xmlto are only needed if you intend to modify
1400 their sources.
1401
1402 Also note that the installed man pages will contain the project's
1403 default command-line option and environment variable values.
1404
1405 Use --disable-man-pages to completely disable building and installing
1406 the man pages.])
1407 ])