d5d37094ddbb33c1d489e50e830860d691c60908
[lttng-tools.git] / configure.ac
1 AC_INIT([lttng-tools],[2.0.1],[dgoulet@efficios.com],[],[http://lttng.org])
2 AC_CONFIG_AUX_DIR([config])
3 AC_CANONICAL_TARGET
4 AC_CANONICAL_HOST
5 AC_CONFIG_MACRO_DIR([config])
6 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
7 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
8
9 version_name="Annedd'ale"
10 version_description="New type of beer, 100% from Quebec, flavored with sapin beaumier needles, with a touch of hops."
11
12 AC_DEFINE_UNQUOTED([VERSION_NAME], ["$version_name"], "")
13 AC_DEFINE_UNQUOTED([VERSION_DESCRIPTION], ["$version_description"], "")
14
15 AC_CONFIG_HEADERS([include/config.h])
16
17 AC_CHECK_HEADERS([ \
18 sys/types.h unistd.h fcntl.h string.h pthread.h limits.h \
19 signal.h stdlib.h sys/un.h sys/socket.h stdlib.h stdio.h \
20 getopt.h sys/ipc.h sys/shm.h popt.h grp.h \
21 ])
22
23 # Babeltrace viewer check
24 AC_ARG_WITH([babeltrace-bin],
25 AS_HELP_STRING([--with-babeltrace-bin],
26 [Location of the babeltrace viewer executable (including the filename)]),
27 [BABELTRACE_BIN="$withval"],
28 [BABELTRACE_BIN=''])
29 AC_SUBST([BABELTRACE_BIN])
30
31 # lttv-gui
32 AC_ARG_WITH([lttv-gui-bin],
33 AS_HELP_STRING([--with-lttv-gui-bin],
34 [Location of the lttv GUI viewer executable (including the filename)]),
35 [LTTV_GUI_BIN="$withval"],
36 [LTTV_GUI_BIN=''])
37 AC_SUBST([LTTV_GUI_BIN])
38
39 AC_ARG_WITH([consumerd32-bin],
40 AS_HELP_STRING([--with-consumerd32-bin],
41 [Location of the 32-bit consumerd executable (including the filename)]),
42 [CONSUMERD32_BIN="$withval"],
43 [CONSUMERD32_BIN=''])
44 AC_SUBST([CONSUMERD32_BIN])
45
46 AC_ARG_WITH([consumerd64-bin],
47 AS_HELP_STRING([--with-consumerd64-bin],
48 [Location of the 64-bit consumerd executable (including the filename)]),
49 [CONSUMERD64_BIN="$withval"],
50 [CONSUMERD64_BIN=''])
51 AC_SUBST([CONSUMERD64_BIN])
52
53 AC_ARG_WITH([consumerd32-libdir],
54 AS_HELP_STRING([--with-consumerd32-libdir],
55 [Directory containing the 32-bit consumerd libraries]),
56 [CONSUMERD32_LIBDIR="$withval"],
57 [CONSUMERD32_LIBDIR=''])
58 AC_SUBST([CONSUMERD32_LIBDIR])
59
60 AC_ARG_WITH([consumerd64-libdir],
61 AS_HELP_STRING([--with-consumerd64-libdir],
62 [Directory containing the 64-bit consumerd libraries]),
63 [CONSUMERD64_LIBDIR="$withval"],
64 [CONSUMERD64_LIBDIR=''])
65 AC_SUBST([CONSUMERD64_LIBDIR])
66
67 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_BIN], "$CONSUMERD32_BIN", [Location of the 32-bit consumerd executable.])
68 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_BIN], "$CONSUMERD64_BIN", [Location of the 64-bit consumerd executable])
69 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_LIBDIR], "$CONSUMERD32_LIBDIR", [Search for consumerd 32-bit libraries in this location.])
70 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_LIBDIR], "$CONSUMERD64_LIBDIR", [Search for consumerd 64-bit libraries in this location.])
71 AC_DEFINE_UNQUOTED([CONFIG_BABELTRACE_BIN], "$BABELTRACE_BIN", [Location of the babeltrace viewer executable.])
72 AC_DEFINE_UNQUOTED([CONFIG_LTTV_GUI_BIN], "$LTTV_GUI_BIN", [Location of the lttv GUI viewer executable.])
73
74 # Check for pthread
75 AC_CHECK_LIB([pthread], [pthread_create], [],
76 [AC_MSG_ERROR([Cannot find libpthread. Use [LDFLAGS]=-Ldir to specify its location.])]
77 )
78
79 # Check libpopt
80 AC_CHECK_LIB([popt], [poptGetContext], [],
81 [AC_MSG_ERROR([Cannot find libpopt. Use [LDFLAGS]=-Ldir to specify its location.])]
82 )
83
84 # URCU library version needed or newer
85 liburcu_version=">= 0.6.7"
86
87 # Check liburcu needed function calls
88 AC_CHECK_DECL([cds_list_add], [],
89 [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu/list.h>]]
90 )
91 AC_CHECK_DECL([cds_wfq_init], [],
92 [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu/wfqueue.h>]]
93 )
94 AC_CHECK_DECL([cds_wfq_dequeue_blocking], [],
95 [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu/wfqueue.h>]]
96 )
97 AC_CHECK_DECL([futex_async], [],
98 [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu/futex.h>]]
99 )
100 AC_CHECK_DECL([rcu_thread_offline], [],
101 [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu.h>]]
102 )
103 AC_CHECK_DECL([rcu_thread_online], [],
104 [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu.h>]]
105 )
106 AC_CHECK_DECL([caa_likely], [],
107 [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu.h>]]
108 )
109
110 # Check liblttng-ust-ctl library
111 AC_ARG_ENABLE(lttng-ust,
112 AS_HELP_STRING([--disable-lttng-ust],[build without LTTng-UST (Userspace Tracing) support]),
113 lttng_ust_support=$enableval, lttng_ust_support=yes)
114
115 AS_IF([test "x$lttng_ust_support" = "xyes"], [
116 AC_CHECK_LIB([lttng-ust-ctl], [ustctl_create_session], [],
117 [AC_MSG_ERROR([Cannot find LTTng-UST. Use [LDFLAGS]=-Ldir to specify its location, or specify --disable-lttng-ust to build lttng-tools without LTTng-UST support.])]
118 )
119 ])
120
121 AM_CONDITIONAL([HAVE_LIBLTTNG_UST_CTL], [ test "x$ac_cv_lib_lttng_ust_ctl_ustctl_create_session" = "xyes" ])
122
123 AC_CHECK_FUNCS([sched_getcpu sysconf])
124
125 # check for dlopen
126 AC_CHECK_LIB([dl], [dlopen],
127 [
128 have_libdl=yes
129 ],
130 [
131 #libdl not found, check for dlopen in libc.
132 AC_CHECK_LIB([c], [dlopen],
133 [
134 have_libc_dl=yes
135 ],
136 [
137 AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
138 ])
139 ])
140 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBDL], [test "x$have_libdl" = "xyes"])
141 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBC_DL], [test "x$have_libc_dl" = "xyes"])
142
143 # Option to only build the consumer daemon and its libraries
144 AC_ARG_WITH([consumerd-only],
145 AS_HELP_STRING([--with-consumerd-only],[Only build the consumer daemon [default=no]]),
146 [consumerd_only=$withval],
147 [consumerd_only=no])
148 AM_CONDITIONAL([BUILD_CONSUMERD_ONLY], [test "x$consumerd_only" = "xyes"])
149
150 # Epoll check. If not present, the build will fallback on poll() API
151 AX_HAVE_EPOLL(
152 [AX_CONFIG_FEATURE_ENABLE(epoll)],
153 [AX_CONFIG_FEATURE_DISABLE(epoll)]
154 )
155 AX_CONFIG_FEATURE(
156 [epoll], [This platform supports epoll(7)],
157 [HAVE_EPOLL], [This platform supports epoll(7).],
158 [enable_epoll="yes"], [enable_epoll="no"]
159 )
160 AM_CONDITIONAL([COMPAT_EPOLL], [ test "$enable_epoll" = "yes" ])
161
162 AC_SYS_LARGEFILE
163 AC_PROG_CC
164 LT_INIT
165
166 CFLAGS="-Wall $CFLAGS -g -fno-strict-aliasing"
167
168 DEFAULT_INCLUDES="-I\$(top_srcdir) -I\$(top_builddir) -I\$(top_builddir)/src -I\$(top_builddir)/include -include config.h"
169
170 lttngincludedir="${includedir}/lttng"
171
172 AC_SUBST(lttngincludedir)
173 AC_SUBST(DEFAULT_INCLUDES)
174
175 lttnglibexecdir="${libdir}/lttng/libexec"
176 AC_SUBST(lttnglibexecdir)
177
178 AC_CONFIG_FILES([
179 Makefile
180 doc/Makefile
181 doc/man/Makefile
182 include/Makefile
183 src/Makefile
184 src/common/Makefile
185 src/common/kernel-ctl/Makefile
186 src/common/kernel-consumer/Makefile
187 src/common/ust-consumer/Makefile
188 src/common/hashtable/Makefile
189 src/common/sessiond-comm/Makefile
190 src/common/compat/Makefile
191 src/lib/Makefile
192 src/lib/lttng-ctl/Makefile
193 src/bin/Makefile
194 src/bin/lttng-consumerd/Makefile
195 src/bin/lttng-sessiond/Makefile
196 src/bin/lttng/Makefile
197 tests/Makefile
198 tests/kernel/Makefile
199 tests/tools/Makefile
200 tests/ust/Makefile
201 tests/ust/nprocesses/Makefile
202 tests/ust/high-throughput/Makefile
203 tests/ust/low-throughput/Makefile
204 tests/ust/before-after/Makefile
205 tests/ust/multi-session/Makefile
206 ])
207
208 AC_OUTPUT
209
210 #
211 # Mini-report on what will be built
212 #
213 AS_ECHO()
214
215 AS_ECHO("Version name: $version_name")
216 AS_ECHO("$version_description")
217
218 AS_ECHO()
219
220 # Target architecture we're building for
221 target_arch=$host_cpu
222 [
223 for f in $CFLAGS; do
224 if test $f = "-m32"; then
225 target_arch="32-bit"
226 elif test $f = "-m64"; then
227 target_arch="64-bit"
228 fi
229 done
230 ]
231 AS_ECHO_N("Target architecture: ")
232 AS_ECHO($target_arch)
233
234 # LTTng-UST enabled/disabled
235 AS_ECHO_N("Lttng-UST support: ")
236 AS_IF([test "x$lttng_ust_support" = "xyes"],[
237 AS_ECHO("Enabled")
238 ],[
239 AS_ECHO("Disabled")
240 ])
241
242 # Do we build only the consumerd, or everything
243 AS_IF([test "x$consumerd_only" = "xyes"],[
244 AS_ECHO("Only the consumerd daemon will be built.")
245 ],[
246 AS_ECHO("All binaries will be built.")
247 ])
248
249 # Print the bindir and libdir this `make install' will install into.
250 AS_ECHO()
251 AS_ECHO_N("Binaries will be installed in: ")
252 AS_ECHO("`eval eval echo $bindir`")
253 AS_ECHO_N("Libraries will be installed in: ")
254 AS_ECHO("`eval eval echo $libdir`")
255
256 # If we build the sessiond, print the paths it will use
257 AS_IF([test "x$consumerd_only" = "xno"],[
258 AS_ECHO()
259 AS_ECHO("The sessiond daemon will look in the following directories: ")
260 AS_ECHO_N("32-bit consumerd executable at: ")
261 AS_IF([test "$CONSUMERD32_BIN" = ""],[
262 AS_ECHO_N("`eval eval echo $lttnglibexecdir`")
263 AS_ECHO("/lttng-consumerd")
264 ],[
265 AS_ECHO("$CONSUMERD32_BIN")
266 ])
267
268 AS_ECHO_N("32-bit consumer libraries in: ")
269 AS_IF([test "$CONSUMERD32_LIBDIR" = ""],[
270 AS_ECHO("`eval eval echo $libdir`")
271 ],[
272 AS_ECHO("$CONSUMERD32_LIBDIR")
273 ])
274
275 AS_ECHO_N("64-bit consumerd executable at: ")
276 AS_IF([test "$CONSUMERD64_BIN" = ""],[
277 AS_ECHO_N("`eval eval echo $lttnglibexecdir`")
278 AS_ECHO("/lttng-consumerd")
279 ],[
280 AS_ECHO("$CONSUMERD64_BIN")
281 ])
282
283 AS_ECHO_N("64-bit consumer libraries in: ")
284 AS_IF([test "$CONSUMERD64_LIBDIR" = ""],[
285 AS_ECHO("`eval eval echo $libdir`")
286 ],[
287 AS_ECHO("$CONSUMERD64_LIBDIR")
288 ])
289 ])
290
291 AS_ECHO()
292
This page took 0.049533 seconds and 3 git commands to generate.