Fix not NULL pointer on size 0
[lttng-tools.git] / configure.ac
1 AC_INIT([lttng-tools], [2.0-pre14], [david.goulet@polymtl.ca], ,[http://lttng.org])
2 AC_CONFIG_AUX_DIR([config])
3 AC_CANONICAL_TARGET
4 AC_CANONICAL_HOST
5 AC_CONFIG_MACRO_DIR([config])
6 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
7 AM_SILENT_RULES([yes])
8
9 AC_CONFIG_HEADERS([include/config.h])
10
11 AC_CHECK_HEADERS([ \
12 sys/types.h unistd.h fcntl.h string.h pthread.h limits.h \
13 signal.h stdlib.h sys/un.h sys/socket.h stdlib.h stdio.h \
14 getopt.h sys/ipc.h sys/shm.h popt.h grp.h \
15 ])
16
17 # Check for pthread
18 AC_CHECK_LIB([pthread], [pthread_create], [],
19 [AC_MSG_ERROR([Cannot find libpthread. Use [LDFLAGS]=-Ldir to specify its location.])]
20 )
21
22 # Check libpopt
23 AC_CHECK_LIB([popt], [poptGetContext], [],
24 [AC_MSG_ERROR([Cannot find libpopt. Use [LDFLAGS]=-Ldir to specify its location.])]
25 )
26
27 # URCU library version needed or newer
28 liburcu_version=">= 0.6.6"
29
30 # Check liburcu needed function calls
31 AC_CHECK_DECL([cds_list_add], [],
32 [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu/list.h>]]
33 )
34 AC_CHECK_DECL([cds_wfq_init], [],
35 [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu/wfqueue.h>]]
36 )
37 AC_CHECK_DECL([cds_wfq_dequeue_blocking], [],
38 [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu/wfqueue.h>]]
39 )
40 AC_CHECK_DECL([futex_async], [],
41 [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu/futex.h>]]
42 )
43 AC_CHECK_DECL([rcu_thread_offline], [],
44 [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu.h>]]
45 )
46 AC_CHECK_DECL([rcu_thread_online], [],
47 [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu.h>]]
48 )
49 AC_CHECK_DECL([caa_likely], [],
50 [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu.h>]]
51 )
52
53 # Check liblttng-ust-ctl library
54 AC_ARG_ENABLE(lttng-ust,
55 [ --disable-lttng-ust build without LTTng-UST (Userspace Tracing) support.],
56 lttng_ust_support=no, lttng_ust_support=yes)
57
58 [
59 if test "x$lttng_ust_support" = "xno"; then
60 echo "LTTng-UST support disabled."
61 else
62 ]
63 AC_CHECK_LIB([lttng-ust-ctl], [ustctl_create_session], [],
64 [AC_MSG_ERROR([Cannot find LTTng-UST. Use [LDFLAGS]=-Ldir to specify its location, or specify --disable-lttng-ust to build lttng-tools without LTTng-UST support.])]
65 )
66 [
67 echo "LTTng-UST support enabled."
68 fi
69 ]
70
71 AM_CONDITIONAL([HAVE_LIBLTTNG_UST_CTL], [ test "x$ac_cv_lib_lttng_ust_ctl_ustctl_create_session" = "xyes" ])
72
73 AC_CHECK_FUNCS([sched_getcpu sysconf])
74
75 # Epoll check. If not present, the build will fallback on poll() API
76 AX_HAVE_EPOLL(
77 [AX_CONFIG_FEATURE_ENABLE(epoll)],
78 [AX_CONFIG_FEATURE_DISABLE(epoll)]
79 )
80 AX_CONFIG_FEATURE(
81 [epoll], [This platform supports epoll(7)],
82 [HAVE_EPOLL], [This platform supports epoll(7).],
83 [enable_epoll="yes"], [enable_epoll="no"]
84 )
85 AM_CONDITIONAL([COMPAT_EPOLL], [ test "$enable_epoll" = "yes" ])
86
87 AC_PROG_CC
88 AC_PROG_LIBTOOL
89
90 CFLAGS="-Wall $CFLAGS -g -fno-strict-aliasing"
91
92 DEFAULT_INCLUDES="-I\$(top_srcdir) -I\$(top_builddir)"
93
94 lttngincludedir="${includedir}/lttng"
95
96 AC_SUBST(lttngincludedir)
97 AC_SUBST(DEFAULT_INCLUDES)
98
99 AC_CONFIG_FILES([
100 Makefile
101 include/Makefile
102 libkernelctl/Makefile
103 liblttng-consumer/Makefile
104 liblttng-kconsumer/Makefile
105 liblttng-ustconsumer/Makefile
106 liblttngctl/Makefile
107 liblttng-sessiond-comm/Makefile
108 lttng-consumerd/Makefile
109 lttng-sessiond/Makefile
110 lttng/Makefile
111 tests/Makefile
112 doc/Makefile
113 ])
114
115 AC_OUTPUT
This page took 0.046662 seconds and 4 git commands to generate.