Remove unnecessary inclusions of version.h
[lttng-tools.git] / configure.ac
1 AC_PREREQ([2.64])
2 AC_INIT([lttng-tools],[2.11.0-pre],[jeremie.galarneau@efficios.com],[],[https://lttng.org])
3
4 AC_CONFIG_HEADERS([include/config.h])
5 AC_CONFIG_AUX_DIR([config])
6 AC_CONFIG_MACRO_DIR([m4])
7
8 AC_CANONICAL_TARGET
9 AC_CANONICAL_HOST
10
11 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip tar-pax nostdinc])
12 AM_MAINTAINER_MODE([enable])
13
14 # Enable silent rules if available (Introduced in AM 1.11)
15 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
16
17 AC_REQUIRE_AUX_FILE([tap-driver.sh])
18
19 # Checks for C compiler
20 AC_USE_SYSTEM_EXTENSIONS
21 AC_SYS_LARGEFILE
22 AC_PROG_CC
23 AC_PROG_CC_STDC
24
25 # Checks for programs.
26 AC_PROG_GREP
27 AC_PROG_MAKE_SET
28 AC_PROG_SED
29 AC_PATH_PROG([report_fold], [fold])
30 LT_INIT
31
32 # Check for objcopy, required by the base address statedump and dynamic linker tests
33 AC_CHECK_TOOL([OBJCOPY], [objcopy], [no])
34 AS_IF([test "x$OBJCOPY" = "xno"],
35 [AC_MSG_WARN([Cannot find objcopy. The base address statedump and dynamic linker tests will be disabled. Install the binutils package to remediate this.])]
36 )
37 AM_CONDITIONAL([HAVE_OBJCOPY], [test "x$OBJCOPY" != xno])
38
39 # check for pgrep
40 AC_PATH_PROG([PGREP], [pgrep], [no])
41 AM_CONDITIONAL([HAVE_PGREP], [test "x$PGREP" != "xno"])
42
43 # set $IN_GIT_REPO if we're in the Git repository; the `bootstrap` file
44 # is not distributed in tarballs
45 AS_IF([test -f "$srcdir/bootstrap"], [in_git_repo=yes], [in_git_repo=no])
46 AM_CONDITIONAL([IN_GIT_REPO], [test "x$in_git_repo" = "xyes"])
47
48 # check for bison
49 AC_PROG_YACC
50 BISON=$YACC
51 AX_PROG_BISON_VERSION([2.4], [have_bison=yes])
52
53 AS_IF([test "x$have_bison" != "xyes"], [
54 AS_IF([test "x$in_git_repo" = "xyes"], [
55 AC_MSG_FAILURE([
56 Bison >= 2.4 is required when building from the Git repository. You can
57 set the YACC variable to override automatic detection.
58 ])
59 ], [
60 AC_MSG_WARN([
61 Missing Bison >= 2.4. Note that the parser files are already built in
62 this distribution tarball, so Bison is only needed if you intend to
63 modify their sources. You can set the YACC variable to override automatic
64 detection.
65 ])
66 ])
67 ])
68 AM_CONDITIONAL([HAVE_BISON], [test "x$have_bison" = "xyes"])
69
70 # check for flex
71 AC_PROG_LEX
72 FLEX=$LEX
73 AX_PROG_FLEX_VERSION([2.5.35], [have_flex=yes])
74
75 AS_IF([test "x$have_flex" != "xyes"], [
76 AS_IF([test "x$in_git_repo" = "xyes"], [
77 AC_MSG_FAILURE([
78 Flex >= 2.5.35 is required when building from the Git repository. You can
79 set the LEX variable to override automatic detection.
80 ])
81 ], [
82 AC_MSG_WARN([
83 Missing Flex >= 2.5.35. Note that the lexer files are already built in
84 this distribution tarball, so Flex is only needed if you intend to
85 modify their sources. You can set the LEX variable to override automatic
86 detection.
87 ])
88 ])
89 ])
90 AM_CONDITIONAL([HAVE_FLEX], [test "x$have_flex" = "xyes"])
91
92
93 # Checks for typedefs, structures, and compiler characteristics.
94 AC_C_INLINE
95 AC_TYPE_INT32_T
96 AC_TYPE_INT64_T
97 AC_TYPE_MODE_T
98 AC_TYPE_OFF_T
99 AC_TYPE_PID_T
100 AC_TYPE_SIZE_T
101 AC_TYPE_SSIZE_T
102 AC_TYPE_UID_T
103 AC_TYPE_UINT16_T
104 AC_TYPE_UINT32_T
105 AC_TYPE_UINT64_T
106 AC_TYPE_UINT8_T
107
108 AX_C___ATTRIBUTE__
109 AS_IF([test "x$ax_cv___attribute__" = "xyes"],
110 [:],
111 [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
112
113 AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])
114
115 AX_LIB_SOCKET_NSL
116
117 LT_NO_UNDEFINED=""
118 AS_CASE([$host_os],
119 [cygwin*],
120 [
121 LT_NO_UNDEFINED="-no-undefined"
122 ],
123 [cygwin*|darwin*|mingw*|solaris*],
124 [
125 # On platforms where we only support the relayd, disable the other binaries by default
126 AS_IF([test "x$enable_bin_lttng" = "x" ], [enable_bin_lttng=no])
127 AS_IF([test "x$enable_bin_lttng_consumerd" = "x" ], [enable_bin_lttng_consumerd=no])
128 AS_IF([test "x$enable_bin_lttng_crash" = "x" ], [enable_bin_lttng_crash=no])
129 AS_IF([test "x$enable_bin_lttng_sessiond" = "x" ], [enable_bin_lttng_sessiond=no])
130 AS_IF([test "x$enable_extras" = "x" ], [enable_extras=no])
131 AS_IF([test "x$with_lttng_ust" = "x" ], [with_lttng_ust=no])
132 ]
133 )
134
135 AC_SUBST(LT_NO_UNDEFINED)
136
137 # Compute minor/major/patchlevel version numbers
138 major_version=$(echo AC_PACKAGE_VERSION | $SED 's/^\([[0-9]]\)*\.[[0-9]]*\.[[0-9]]*.*$/\1/')
139 minor_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.\([[0-9]]*\)\.[[0-9]]*.*$/\1/')
140 patchlevel_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\).*$/\1/')
141
142 AC_SUBST([MAJOR_VERSION], [$major_version])
143 AC_SUBST([MINOR_VERSION], [$minor_version])
144 AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version])
145 AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [LTTng-Tools major version number])
146 AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [LTTng-Tools minor version number])
147 AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [LTTng-Tools patchlevel version number])
148
149 version_name="Codename TBD"
150 version_description='Description TBD'
151 version_description_c=$(echo $version_description | $SED 's/"/\\"/g')
152
153 AC_DEFINE_UNQUOTED([VERSION_NAME], ["$version_name"], "")
154 AC_DEFINE_UNQUOTED([VERSION_DESCRIPTION], ["$version_description_c"], "")
155
156 # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
157 AC_ARG_ENABLE(libtool-linkdep-fixup,
158 AS_HELP_STRING([--disable-libtool-linkdep-fixup],
159 [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)]),
160 libtool_fixup=$enableval,
161 libtool_fixup=yes)
162
163 AS_IF([test "x$libtool_fixup" = "xyes"],
164 [
165 libtool_m4="$srcdir/m4/libtool.m4"
166 libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
167 AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
168 libtool_flag_pattern_count=$($GREP -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
169 AS_IF([test $libtool_flag_pattern_count -ne 0],
170 [
171 AC_MSG_RESULT([$libtool_flag_pattern_count])
172 AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
173 $SED -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
174 ],
175 [
176 AC_MSG_RESULT([none])
177 ])
178 ])
179
180 AM_CONDITIONAL([NO_SHARED], [test x$enable_shared = xno])
181
182 AC_CHECK_HEADERS([ \
183 sys/types.h unistd.h fcntl.h string.h pthread.h limits.h \
184 signal.h stdlib.h sys/un.h sys/socket.h stdlib.h stdio.h \
185 getopt.h sys/ipc.h sys/shm.h popt.h grp.h arpa/inet.h \
186 netdb.h netinet/in.h paths.h stddef.h sys/file.h sys/ioctl.h \
187 sys/mount.h sys/param.h sys/time.h
188 ])
189
190 # Basic functions check
191 AC_CHECK_FUNCS([ \
192 atexit bzero clock_gettime dup2 fdatasync fls ftruncate \
193 gethostbyname gethostname getpagesize localtime_r memchr memset \
194 mkdir munmap putenv realpath rmdir socket strchr strcspn strdup \
195 strncasecmp strndup strnlen strpbrk strrchr strstr strtol strtoul \
196 strtoull dirfd gethostbyname2 getipnodebyname epoll_create1 \
197 sched_getcpu sysconf sync_file_range
198 ])
199
200 # Check if clock_gettime, timer_create, timer_settime, and timer_delete are available in lib rt, and if so,
201 # add -lrt to LIBS
202 AC_CHECK_LIB([rt], [clock_gettime, timer_create, timer_settime, timer_delete])
203
204 # Checks for dl.
205 AC_CHECK_LIB([dl], [dlopen], [
206 have_libdl=yes
207 libdl_name=dl
208 ], [
209 # libdl not found, check for dlopen in libc.
210 AC_CHECK_LIB([c], [dlopen], [
211 have_libc_dl=yes
212 libdl_name=c
213 ], [
214 AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
215 ])
216 ])
217
218 # Check if libdl has dlmopen support.
219 AH_TEMPLATE([HAVE_DLMOPEN], ["Define to 1 if dlmopen is available."])
220 AC_CHECK_LIB([$libdl_name], [dlmopen], [
221 AC_DEFINE([HAVE_DLMOPEN], [1])
222 HAVE_DLMOPEN=1
223 ], [
224 HAVE_DLMOPEN=0
225 ])
226 AC_SUBST(HAVE_DLMOPEN)
227
228 # Babeltrace viewer check
229 AC_ARG_WITH([babeltrace-bin],
230 AS_HELP_STRING([--with-babeltrace-bin],
231 [Location of the babeltrace viewer executable (including the filename)]),
232 [BABELTRACE_BIN="$withval"],
233 [BABELTRACE_BIN=''])
234 AC_SUBST([BABELTRACE_BIN])
235
236 # lttv-gui
237 AC_ARG_WITH([lttv-gui-bin],
238 AS_HELP_STRING([--with-lttv-gui-bin],
239 [Location of the lttv GUI viewer executable (including the filename)]),
240 [LTTV_GUI_BIN="$withval"],
241 [LTTV_GUI_BIN=''])
242 AC_SUBST([LTTV_GUI_BIN])
243
244 AC_ARG_WITH([consumerd32-bin],
245 AS_HELP_STRING([--with-consumerd32-bin],
246 [Location of the 32-bit consumerd executable (including the filename)]),
247 [CONSUMERD32_BIN="$withval"],
248 [CONSUMERD32_BIN=''])
249 AC_SUBST([CONSUMERD32_BIN])
250
251 AC_ARG_WITH([consumerd64-bin],
252 AS_HELP_STRING([--with-consumerd64-bin],
253 [Location of the 64-bit consumerd executable (including the filename)]),
254 [CONSUMERD64_BIN="$withval"],
255 [CONSUMERD64_BIN=''])
256 AC_SUBST([CONSUMERD64_BIN])
257
258 AC_ARG_WITH([consumerd32-libdir],
259 AS_HELP_STRING([--with-consumerd32-libdir],
260 [Directory containing the 32-bit consumerd libraries]),
261 [CONSUMERD32_LIBDIR="$withval"],
262 [CONSUMERD32_LIBDIR=''])
263 AC_SUBST([CONSUMERD32_LIBDIR])
264
265 AC_ARG_WITH([consumerd64-libdir],
266 AS_HELP_STRING([--with-consumerd64-libdir],
267 [Directory containing the 64-bit consumerd libraries]),
268 [CONSUMERD64_LIBDIR="$withval"],
269 [CONSUMERD64_LIBDIR=''])
270 AC_SUBST([CONSUMERD64_LIBDIR])
271
272 AC_ARG_WITH([sessiond-bin],
273 AS_HELP_STRING([--with-sessiond-bin],
274 [Location of the sessiond executable (including the filename)]),
275 [SESSIOND_BIN="$withval"],
276 [SESSIOND_BIN=''])
277 AC_SUBST([SESSIOND_BIN])
278
279 AC_ARG_WITH([lttng-system-rundir],
280 AS_HELP_STRING([--with-lttng-system-rundir],
281 [Location of the system directory where the system-wide lttng-sessiond runtime files are kept. The default is "/var/run/lttng".]),
282 [LTTNG_SYSTEM_RUNDIR="$withval"],
283 [LTTNG_SYSTEM_RUNDIR="/var/run/lttng"])
284 AC_SUBST([LTTNG_SYSTEM_RUNDIR])
285
286 AC_ARG_ENABLE([test-java-agent-jul],
287 [AS_HELP_STRING([--enable-test-java-agent-jul],[enable the LTTng UST Java agent JUL tests [default=no]])],
288 [test_java_agent_jul=$enableval],
289 [test_java_agent_jul=no]
290 )
291
292 AC_ARG_ENABLE([test-java-agent-log4j],
293 [AS_HELP_STRING([--enable-test-java-agent-log4j],[enable the LTTng UST Java agent Log4j tests [default=no]])],
294 [test_java_agent_log4j=$enableval],
295 [test_java_agent_log4j=no]
296 )
297
298 AC_ARG_ENABLE([test-java-agent-all],
299 [AS_HELP_STRING([--enable-test-java-agent-all],[enable all the LTTng UST Java agent tests [default=no]])],
300 [test_java_agent_jul=$enableval
301 test_java_agent_log4j=$enableval],
302 [:]
303 )
304
305 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_BIN], "$CONSUMERD32_BIN", [Location of the 32-bit consumerd executable.])
306 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_BIN], "$CONSUMERD64_BIN", [Location of the 64-bit consumerd executable])
307 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_LIBDIR], "$CONSUMERD32_LIBDIR", [Search for consumerd 32-bit libraries in this location.])
308 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_LIBDIR], "$CONSUMERD64_LIBDIR", [Search for consumerd 64-bit libraries in this location.])
309 AC_DEFINE_UNQUOTED([CONFIG_BABELTRACE_BIN], "$BABELTRACE_BIN", [Location of the babeltrace viewer executable.])
310 AC_DEFINE_UNQUOTED([CONFIG_LTTV_GUI_BIN], "$LTTV_GUI_BIN", [Location of the lttv GUI viewer executable.])
311 AC_DEFINE_UNQUOTED([CONFIG_SESSIOND_BIN], "$SESSIOND_BIN", [Location of the sessiond executable.])
312 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_RUNDIR], ["$LTTNG_SYSTEM_RUNDIR"], [LTTng system runtime directory])
313
314 AC_DEFUN([_AC_DEFINE_AND_SUBST], [
315 AC_DEFINE_UNQUOTED([CONFIG_$1], [$2], [$1])
316 $1="$2"
317 AC_SUBST([$1])
318 ])
319
320 AC_DEFUN([_AC_DEFINE_QUOTED_AND_SUBST], [
321 AC_DEFINE_UNQUOTED([CONFIG_$1], ["$2"], [$1])
322 $1="$2"
323 AC_SUBST([$1])
324 ])
325
326 # Default values
327 m4_define([_DEFAULT_CHANNEL_SUBBUF_SIZE], [16384])
328 m4_define([_DEFAULT_CHANNEL_SUBBUF_NUM], [4])
329 m4_define([_DEFAULT_CHANNEL_SWITCH_TIMER], [0])
330 m4_define([_DEFAULT_CHANNEL_LIVE_TIMER], [0])
331 m4_define([_DEFAULT_CHANNEL_READ_TIMER], [200000])
332 m4_define([_DEFAULT_CHANNEL_MONITOR_TIMER], [1000000])
333 m4_define([_DEFAULT_CHANNEL_BLOCKING_TIMEOUT], [0])
334 _AC_DEFINE_AND_SUBST([DEFAULT_AGENT_TCP_PORT_RANGE_BEGIN], [5345])
335 _AC_DEFINE_AND_SUBST([DEFAULT_AGENT_TCP_PORT_RANGE_END], [5354])
336 _AC_DEFINE_AND_SUBST([DEFAULT_APP_SOCKET_RW_TIMEOUT], [5])
337 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE])
338 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_COUNT], [0])
339 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_SIZE], [0])
340 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
341 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_READ_TIMER], [_DEFAULT_CHANNEL_READ_TIMER])
342 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
343 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_SIZE], [1048576])
344 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
345 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
346 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_BLOCKING_TIMEOUT], [_DEFAULT_CHANNEL_BLOCKING_TIMEOUT])
347 _AC_DEFINE_AND_SUBST([DEFAULT_LTTNG_LIVE_TIMER], [1000000])
348 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_CACHE_SIZE], [4096])
349 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_READ_TIMER], [0])
350 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_NUM], [2])
351 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_SIZE], [4096])
352 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
353 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_CONTROL_PORT], [5342])
354 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_DATA_PORT], [5343])
355 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_VIEWER_PORT], [5344])
356 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
357 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_READ_TIMER], [0])
358 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_BLOCKING_TIMEOUT], [0])
359 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
360 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE])
361 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
362 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
363 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
364 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_READ_TIMER], [0])
365 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_BLOCKING_TIMEOUT], [0])
366 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
367 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_SIZE], [524288])
368 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
369 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
370 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_AGENT_BIND_ADDRESS], [localhost])
371 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_CONTROL_BIND_ADDRESS], [0.0.0.0])
372 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_DATA_BIND_ADDRESS], [0.0.0.0])
373 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_VIEWER_BIND_ADDRESS], [localhost])
374 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_RELAYD_CTRL_MAX_PAYLOAD_SIZE], [134217728])
375 _AC_DEFINE_AND_SUBST([DEFAULT_ROTATE_PENDING_RELAY_TIMER], [200000])
376
377 # Command short descriptions
378 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ADD_CONTEXT], [Add context fields to a channel])
379 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_CREATE], [Create a tracing session])
380 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DESTROY], [Tear down tracing sessions])
381 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_CHANNEL], [Disable tracing channels])
382 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_EVENT], [Disable event rules])
383 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_ROTATION], [Unset a rotation schedule])
384 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_CHANNEL], [Create or enable tracing channels])
385 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_EVENT], [Create or enable event rules])
386 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_ROTATION], [Set a rotation schedule])
387 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_HELP], [Display help information about a command])
388 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LIST], [List tracing sessions, domains, channels, and events])
389 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LOAD], [Load tracing session configurations])
390 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_REGENERATE], [Manage an LTTng tracing session's data regeneration])
391 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ROTATE], [Archive a tracing session's current trace chunk])
392 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SAVE], [Save tracing session configurations])
393 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SET_SESSION], [Set current tracing session])
394 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SNAPSHOT], [Snapshot buffers of current tracing session])
395 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_START], [Start tracing])
396 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STATUS], [Get the status of the current tracing session])
397 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STOP], [Stop tracing])
398 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_TRACK], [Track specific system resources])
399 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_UNTRACK], [Untrack specific system resources])
400 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VERSION], [Show version information])
401 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VIEW], [Start trace viewer])
402
403 if test "x$prefix" = "xNONE"; then
404 prefix=$ac_default_prefix
405 fi
406 CONFDIR=`eval echo $sysconfdir`
407 AC_SUBST(CONFDIR)
408 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_CONFIGDIR],"$CONFDIR", [LTTng system configuration directory.])
409
410 AC_DEFINE_DIR([CONFIG_LTTNG_SYSTEM_DATADIR],[datadir], [LTTng system data directory.])
411
412 # Check libpopt
413 PKG_CHECK_MODULES([POPT], [popt],
414 [
415 dnl PKG_CHECK_MODULES defines POPT_LIBS
416 ],
417 [
418 AC_MSG_WARN([pkg-config was unable to find a valid .pc for libpopt. Set PKG_CONFIG_PATH to specify the pkgconfig configuration file location])
419 AC_MSG_WARN([Finding libpopt without pkg-config.])
420 AC_CHECK_LIB([popt],
421 [poptGetContext],
422 [POPT_LIBS="-lpopt"],
423 [
424 AC_MSG_FAILURE([Cannot find libpopt. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location])
425 ]
426 )
427 ]
428 )
429 AC_SUBST(POPT_LIBS)
430
431 PKG_CHECK_MODULES([libxml2], [libxml-2.0 >= 2.7.6])
432
433 # First, check for uuid in system libs
434 AH_TEMPLATE([LTTNG_HAVE_LIBUUID], [Define if you have libuuid support])
435 AC_CHECK_FUNCS([uuid_generate],
436 [
437 AC_DEFINE([LTTNG_HAVE_LIBUUID], [1])
438 UUID_LIBS=""
439 ],
440 [
441 # Then, check if the pkg-config module is available, otherwise explicitly check
442 # for libuuid, or uuid support in the C-library.
443 PKG_CHECK_MODULES([UUID], [uuid],
444 [
445 AC_DEFINE([LTTNG_HAVE_LIBUUID], [1])
446 dnl PKG_CHECK_MODULES defines UUID_LIBS
447 ],
448 [
449 AC_MSG_WARN([pkg-config was unable to find a valid .pc for libuuid. Set PKG_CONFIG_PATH to specify the pkgconfig configuration file location])
450 AC_MSG_WARN([Finding libuuid without pkg-config.])
451 AC_CHECK_LIB([uuid], [uuid_generate],
452 [
453 AC_DEFINE([LTTNG_HAVE_LIBUUID], [1])
454 UUID_LIBS="-luuid"
455 ],
456 [
457 # libuuid not found, check for uuid_create in libc.
458 AC_CHECK_LIB([c], [uuid_create],
459 [
460 AC_DEFINE([LTTNG_HAVE_LIBUUID], [1])
461 UUID_LIBS="-lc"
462 ],
463 [
464 AC_MSG_FAILURE([Cannot find libuuid uuid_generate nor libc uuid_create. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location])
465 ]
466 )
467 ]
468 )
469 ]
470 )
471 ]
472 )
473 AC_SUBST(UUID_LIBS)
474
475 AC_CHECK_FUNC([clock_gettime], [AC_DEFINE_UNQUOTED([LTTNG_HAVE_CLOCK_GETTIME], 1, [Has clock_gettime() support.])])
476
477 # URCU library version needed or newer
478 m4_define([WRONG_LIBURCU_MSG], [Userspace RCU (liburcu) >= 0.9.0 is needed])
479
480 # Check liburcu needed function calls
481 AC_CHECK_DECL([cds_list_add], [],
482 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/list.h>]])
483 AC_CHECK_DECL([cds_wfcq_init], [],
484 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/wfcqueue.h>]])
485 AC_CHECK_DECL([cds_wfcq_dequeue_blocking], [],
486 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/wfcqueue.h>]])
487 AC_CHECK_DECL([futex_async], [],
488 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/futex.h>]])
489 AC_CHECK_DECL([rcu_thread_offline], [],
490 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
491 AC_CHECK_DECL([rcu_thread_online], [],
492 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
493 AC_CHECK_DECL([caa_likely], [],
494 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
495 AC_CHECK_LIB([urcu-cds], [_cds_lfht_new], [],
496 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])])
497
498 #Function added in urcu 0.7.0
499 AC_CHECK_DECL([cmm_smp_mb__before_uatomic_or], [],
500 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]]
501 )
502
503 #Function added in urcu 0.9.0
504 AC_CHECK_DECL([urcu_ref_get_unless_zero], [],
505 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/ref.h>]]
506 )
507
508 # Check for libkmod, it will be auto-neabled if found but won't fail if it's not,
509 # it can be explicitly disabled with --without-kmod
510 AH_TEMPLATE([HAVE_KMOD], [Define if you have kmod support])
511 AC_ARG_WITH([kmod],
512 [AS_HELP_STRING([--with-kmod], [build with lkmod support @<:@default=check@:>@])],
513 [],
514 [with_kmod=check]
515 )
516
517 AS_IF([test "x$with_kmod" != "xno"],
518 [
519 AC_CHECK_LIB([kmod], [kmod_module_probe_insert_module],
520 [
521 AC_DEFINE([HAVE_KMOD], [1])
522 KMOD_LIBS="-lkmod"
523 ],
524 [
525 if test "x$with_kmod" != xcheck; then
526 AC_MSG_FAILURE([Cannot find libkmod. Use [LDFLAGS]=-Ldir and [CPPFLAGS]=-Idir to specify its location.])
527 else
528 with_kmod=no
529 fi
530 ]
531 )
532 ]
533 )
534 AC_SUBST(KMOD_LIBS)
535
536 # Check for liblttng-ust-ctl, fail if it's not found,
537 # it can be explicitly disabled with --without-lttng-ust
538 AH_TEMPLATE([HAVE_LIBLTTNG_UST_CTL], [Define if you have LTTng-UST control support])
539 AC_ARG_WITH([lttng-ust],
540 [AS_HELP_STRING([--without-lttng-ust], [build without LTTng-UST (Userspace Tracing) support])],
541 [],
542 [with_lttng_ust=yes]
543 )
544
545 AS_IF([test "x$with_lttng_ust" = "xyes"],
546 [
547 AC_CHECK_LIB([lttng-ust-ctl], [ustctl_recv_channel_from_consumer],
548 [
549 AC_DEFINE([HAVE_LIBLTTNG_UST_CTL], [1])
550 ],
551 [
552 AC_MSG_FAILURE([Cannot find LTTng-UST >= 2.2.x. Use [LDFLAGS]=-Ldir and [CPPFLAGS]=-Idir to specify its location, or specify --without-lttng-ust to build lttng-tools without LTTng-UST support.])
553 ],
554 [-lurcu-common -lurcu-bp -lurcu-cds -lrt -ldl]
555 )
556 ]
557 )
558 AM_CONDITIONAL([HAVE_LIBLTTNG_UST_CTL], [test "x$with_lttng_ust" = "xyes"])
559
560
561
562 # check for dlopen
563 AC_CHECK_LIB([dl], [dlopen],
564 [DL_LIBS="-ldl"],
565 [
566 #libdl not found, check for dlopen in libc.
567 AC_CHECK_LIB([c], [dlopen],
568 [DL_LIBS="-lc"],
569 [AC_MSG_FAILURE([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])]
570 )
571 ]
572 )
573 AC_SUBST(DL_LIBS)
574
575 # Check for fmemopen
576 AC_CHECK_LIB([c], [fmemopen],
577 [
578 AC_DEFINE_UNQUOTED([LTTNG_HAVE_FMEMOPEN], 1, [Has fmemopen support.])
579 ]
580 )
581
582 # Check for open_memstream
583 AC_CHECK_LIB([c], [open_memstream],
584 [
585 AC_DEFINE_UNQUOTED([LTTNG_HAVE_OPEN_MEMSTREAM], 1, [Has open_memstream support.])
586 ]
587 )
588
589 # check for libpfm
590 AC_CHECK_LIB([pfm], [pfm_initialize],
591 [
592 have_libpfm=yes
593 ])
594 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBPFM], [test "x$have_libpfm" = "xyes"])
595
596 # For Python
597 # SWIG version needed or newer:
598 swig_version=2.0.0
599
600 AC_ARG_ENABLE([python-bindings],
601 [AC_HELP_STRING([--enable-python-bindings],
602 [compile Python bindings])],
603 [enable_python_binding=$enableval], [enable_python_binding=no])
604
605 AM_CONDITIONAL([PYTHON_BINDING], [test "x$enable_python_binding" = xyes])
606
607 if test "x$enable_python_binding" = xyes; then
608 AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ])
609 AS_IF([test x$enable_shared = xno], [ AC_MSG_ERROR([Python bindings require shared libraries.]) ])
610 AM_PATH_PYTHON([3.0])
611
612 AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config])
613 AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
614 AS_IF([test -z "$PYTHON_INCLUDE"], [
615 AS_IF([test -z "$PYTHON_CONFIG"], [
616 AC_PATH_PROGS([PYTHON_CONFIG],
617 [python$PYTHON_VERSION-config python-config],
618 [no],
619 [`dirname $PYTHON`])
620 AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
621 ])
622 AC_MSG_CHECKING([python include flags])
623 PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
624 AC_MSG_RESULT([$PYTHON_INCLUDE])
625 ])
626
627 else
628 AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl
629 [if you want Python bindings.])
630
631 fi
632
633 # Epoll check. If not present, the build will fallback on poll() API
634 AX_HAVE_EPOLL(
635 [AX_CONFIG_FEATURE_ENABLE(epoll)],
636 [AX_CONFIG_FEATURE_DISABLE(epoll)]
637 )
638 AX_CONFIG_FEATURE(
639 [epoll], [This platform supports epoll(7)],
640 [HAVE_EPOLL], [This platform supports epoll(7).],
641 [enable_epoll="yes"], [enable_epoll="no"]
642 )
643 AM_CONDITIONAL([COMPAT_EPOLL], [ test "$enable_epoll" = "yes" ])
644
645 AM_CONDITIONAL([TEST_JAVA_JUL_AGENT], [test "x$test_java_agent_jul" = "xyes"])
646 AM_CONDITIONAL([TEST_JAVA_LOG4J_AGENT], [test "x$test_java_agent_log4j" = "xyes"])
647
648 if test "x$test_java_agent_jul" = "xyes" || test "x$test_java_agent_log4j" = "xyes"; then
649 AX_JAVA_OPTIONS
650 AX_PROG_JAVAC
651 AX_PROG_JAVA
652 AX_PROG_JAR
653
654 AX_CHECK_CLASSPATH
655
656 # Check for Java UST agent common class first
657 AX_CHECK_CLASS(org.lttng.ust.agent.AbstractLttngAgent)
658 if test "x$ac_cv_class_org_lttng_ust_agent_AbstractLttngAgent" = "xno"; then
659 AC_MSG_ERROR([The UST Java agent common class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-common.jar"])
660 fi
661
662 if test "x$test_java_agent_jul" = "xyes"; then
663 # Check for JUL agent class
664 AX_CHECK_CLASS(org.lttng.ust.agent.jul.LttngLogHandler)
665 if test "x$ac_cv_class_org_lttng_ust_agent_jul_LttngLogHandler" = "xno"; then
666 AC_MSG_ERROR([The UST Java agent JUL class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-jul.jar"])
667 fi
668 fi
669
670 if test "x$test_java_agent_log4j" = "xyes"; then
671 # Check for Log4j agent class
672 AX_CHECK_CLASS(org.lttng.ust.agent.log4j.LttngLogAppender)
673 if test "x$ac_cv_class_org_lttng_ust_agent_log4j_LttngLogAppender" = "xno"; then
674 AC_MSG_ERROR([The UST Java agent Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-log4j.jar"])
675 fi
676
677 # Check for Log4j class
678 AX_CHECK_CLASS(org.apache.log4j.Logger)
679 if test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"; then
680 AC_MSG_ERROR([The Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j.jar"])
681 fi
682 fi
683 fi
684
685 # enable building man pages (user's intention)
686 AC_ARG_ENABLE(
687 man-pages,
688 AS_HELP_STRING(
689 [--disable-man-pages],
690 [Do not build and install man pages (already built in a distributed tarball)]
691 ),
692 [man_pages_opt=$enableval],
693 [man_pages_opt=yes]
694 )
695
696 # check for asciidoc and xmlto if we enabled building the man pages
697 have_asciidoc_xmlto=no
698 warn_prebuilt_man_pages=no
699
700 AS_IF([test "x$man_pages_opt" = "xyes"], [
701 AC_PATH_PROG([ASCIIDOC], [asciidoc], [no])
702 AC_PATH_PROG([XMLTO], [xmlto], [no])
703
704 AS_IF([test "x$ASCIIDOC" = "xno" || test "x$XMLTO" = "xno"], [
705 AS_IF([test "x$in_git_repo" = "xyes"], [
706 # this is an error because we're in the Git repo, which
707 # means the man pages are not already generated for us,
708 # thus asciidoc/xmlto are required because we were asked
709 # to build the man pages
710 AC_MSG_ERROR([
711 You need asciidoc and xmlto to build the LTTng-tools man pages. Use
712 --disable-man-pages to disable building the man pages, in which case
713 they will not be installed.
714 ])
715 ], [
716 # only warn here: since we're in the tarball, the man
717 # pages should already be generated at this point, thus
718 # asciidoc/xmlto are not strictly required
719 warn_prebuilt_man_pages=yes
720 ])
721 ], [
722 have_asciidoc_xmlto=yes
723 ])
724 ])
725
726 # export man page build condition: build the man pages if the user
727 # asked for it, and if the tools are available
728 AM_CONDITIONAL([MAN_PAGES_OPT], [test "x$man_pages_opt" != "xno"])
729 AM_CONDITIONAL([HAVE_ASCIIDOC_XMLTO], [test "x$have_asciidoc_xmlto" = "xyes"])
730
731 AC_DEFINE_UNQUOTED([MANPATH], ["`eval eval echo $mandir`"], [Path to man pages.])
732
733 # embedded --help message
734 AC_ARG_ENABLE(
735 [embedded-help],
736 AS_HELP_STRING(
737 [--enable-embedded-help],
738 [Embed the --help messages in the executable files]
739 ),
740 [embedded_help=$enableval],
741 [embedded_help=no]
742 )
743 AS_IF([test "x$embedded_help" = "xyes"], [
744 AS_IF([test "x$man_pages_opt" = "xno"], [
745 AC_MSG_ERROR([You need the --enable-man-pages option with the --enable-embedded-help option.])
746 ])
747 AC_PATH_PROG([man_prog_path], [man], [no])
748 AS_IF([test "x$man_prog_path" = "xno"], [
749 AC_MSG_ERROR([You need man with the --enable-embedded-help option.])
750 ])
751 AC_DEFINE_UNQUOTED([LTTNG_EMBED_HELP], 1, [Embed --help messages.])
752 AC_SUBST([MANPROG], [$man_prog_path])
753 ])
754 AM_CONDITIONAL([EMBED_HELP], [test "x$embedded_help" != "xno"])
755
756 # Python agent test
757 UST_PYTHON_AGENT="lttngust"
758
759 AC_ARG_ENABLE(test-python2-agent,
760 AS_HELP_STRING([--enable-test-python2-agent],
761 [enable tests for python2 agent. Python2 interpreter path can be overridden by setting the PYTHON2 environment variable. Default: Autodetect]
762 ),[:],[test_python2_agent_autodetect=yes]
763 )
764
765 AC_ARG_ENABLE(test-python3-agent,
766 AS_HELP_STRING([--enable-test-python3-agent],
767 [enable tests for python3 agent. Python3 interpreter path can be overridden by setting the PYTHON3 environment variable. Default: Autodetect]
768 ),[:],[test_python3_agent_autodetect=yes]
769 )
770
771 AC_ARG_ENABLE(test-python-agent-all,
772 AS_HELP_STRING([--enable-test-python-agent-all],
773 [enable test for all python{2/3} agent.]
774 ),
775 )
776
777 AS_IF([test ! -z "$enable_test_python_agent_all"], [
778 unset test_python2_agent_autodetect
779 unset test_python3_agent_autodetect
780 ])
781
782 AS_IF([test "x$enable_test_python_agent_all" = "xyes"], [
783 enable_test_python2_agent=yes
784 enable_test_python3_agent=yes
785 ])
786
787 AS_IF([test "x$enable_test_python_agent_all" = "xno"], [
788 enable_test_python2_agent=no
789 enable_test_python3_agent=no
790 ])
791
792
793 AS_IF([test "x$enable_test_python2_agent" = "xyes" -o "x$test_python2_agent_autodetect" = "xyes" ], [
794 AS_IF([test -z "$PYTHON2"], [
795 PYTHON2=python2
796 ], [
797 AC_MSG_WARN([Using user-defined PYTHON2 ($PYTHON2) for lttng-ust python2 agent check])
798 ])
799
800 AC_PATH_PROG([PYTHON2_BIN],[$PYTHON2])
801 AS_IF([test -z "$PYTHON2_BIN"], [
802 AS_IF([test -z "$test_python2_agent_autodetect"],[
803 AC_MSG_ERROR([No python2 interpreter found. PYTHON2 can be set to override default interpreter path])
804 ])
805 ], [
806 AC_MSG_CHECKING([for python2 lttng-ust agent])
807 AS_IF([$PYTHON2_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
808 PYTHON2_AGENT=$PYTHON2_BIN
809 AC_MSG_RESULT([yes])
810 RUN_PYTHON_AGENT_TEST=yes
811 ], [
812 AC_MSG_RESULT([no])
813 AS_IF([test -z "$test_python2_agent_autodetect"],[
814 AC_MSG_ERROR([No python2 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
815 ])
816 ])
817
818 ])
819
820 ])
821
822 AS_IF([test "x$enable_test_python3_agent" = "xyes" -o "x$test_python3_agent_autodetect" = "xyes" ], [
823 AS_IF([test -z "$PYTHON3"], [
824 PYTHON3=python3
825 ], [
826 AC_MSG_WARN([Using user-defined PYTHON3 ($PYTHON3) for lttng-ust python3 agent check])
827 ])
828
829 AC_PATH_PROG([PYTHON3_BIN],[$PYTHON3])
830 AS_IF([test -z "$PYTHON3_BIN"], [
831 AS_IF([test -z "$test_python3_agent_autodetect"],[
832 AC_MSG_ERROR([No python3 interpreter found. PYTHON3 can be set to override default interpreter path])
833 ])
834 ], [
835 AC_MSG_CHECKING([for python3 lttng-ust agent])
836 AS_IF([$PYTHON3_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
837 PYTHON3_AGENT=$PYTHON3_BIN
838 AC_MSG_RESULT([yes])
839 RUN_PYTHON_AGENT_TEST=yes
840 ], [
841 AC_MSG_RESULT([no])
842 AS_IF([test -z "$test_python3_agent_autodetect"],[
843 AC_MSG_ERROR([No python3 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
844 ])
845 ])
846
847 ])
848 ])
849 AC_SUBST([RUN_PYTHON_AGENT_TEST])
850 AC_SUBST([PYTHON2_AGENT])
851 AC_SUBST([PYTHON3_AGENT])
852
853 # Arguments for binaries build exclusion
854 AC_ARG_ENABLE([bin-lttng], AS_HELP_STRING([--disable-bin-lttng],[Disable the build of lttng binaries]))
855 AC_ARG_ENABLE([bin-lttng-consumerd], AS_HELP_STRING([--disable-bin-lttng-consumerd],
856 [Disable the build of lttng-consumerd binaries]))
857 AC_ARG_ENABLE([bin-lttng-crash], AS_HELP_STRING([--disable-bin-lttng-crash],[Disable the build of lttng-crash binaries]))
858 AC_ARG_ENABLE([bin-lttng-relayd], AS_HELP_STRING([--disable-bin-lttng-relayd],
859 [Disable the build of lttng-relayd binaries]))
860 AC_ARG_ENABLE([bin-lttng-sessiond], AS_HELP_STRING([--disable-bin-lttng-sessiond],
861 [Disable the build of lttng-sessiond binaries]))
862 AC_ARG_ENABLE([extras], AS_HELP_STRING([--disable-extras],
863 [Disable the build of the extra components]))
864
865
866 # Always build libconfig since it a dependency of libcommon
867 build_lib_config=yes
868
869 build_lib_compat=no
870 build_lib_consumer=no
871 build_lib_hashtable=no
872 build_lib_health=no
873 build_lib_index=no
874 build_lib_kernel_consumer=no
875 build_lib_kernel_ctl=no
876 build_lib_lttng_ctl=no
877 build_lib_relayd=no
878 build_lib_sessiond_comm=no
879 build_lib_testpoint=no
880 build_lib_ust_consumer=no
881
882 # There is an overlap for enabled dependencies, but this makes everything
883 # simpler. libcommon and libconfig are always compiled so they are not repeated
884 # here.
885
886 # Enable binary dependencies.
887 AS_IF([test x$enable_bin_lttng != xno],
888 [
889 build_lib_lttng_ctl=yes
890 ]
891 )
892
893 AS_IF([test x$enable_bin_lttng_consumerd != xno],
894 [
895 build_lib_consumer=yes
896 build_lib_sessiond_comm=yes
897 build_lib_index=yes
898 build_lib_health=yes
899 build_lib_testpoint=yes
900 ]
901 )
902
903 AS_IF([test x$enable_bin_lttng_crash != xno],
904 # Do nothing since libconfig and libcommon are built by default.
905 []
906 )
907
908 AS_IF([test x$enable_bin_lttng_relayd != xno],
909 [
910 build_lib_lttng_ctl=yes
911 build_lib_sessiond_comm=yes
912 build_lib_hashtable=yes
913 build_lib_compat=yes
914 build_lib_index=yes
915 build_lib_health=yes
916 build_lib_testpoint=yes
917 ]
918 )
919 AS_IF([test x$enable_bin_lttng_sessiond != xno],
920 [
921 build_lib_lttng_ctl=yes
922 build_lib_sessiond_comm=yes
923 build_lib_kernel_ctl=yes
924 build_lib_hashtable=yes
925 build_lib_compat=yes
926 build_lib_relayd=yes
927 build_lib_testpoint=yes
928 build_lib_health=yes
929 build_lib_health=yes
930 ]
931 )
932
933 # Libraries dependencies enabling
934 AS_IF([test x$build_lib_lttng_ctl = xyes],
935 [
936 build_lib_sessiond_comm=yes
937 build_lib_hashtable=yes
938 ]
939 )
940
941 AS_IF([test x$build_lib_consumer = xyes],
942 [
943 build_lib_sessiond_comm=yes
944 build_lib_kernel_consumer=yes
945 build_lib_hashtable=yes
946 build_lib_compat=yes
947 build_lib_relayd=yes
948 AS_IF([test "x$with_lttng_ust" = "xyes"], [build_lib_ust_consumer=yes])
949 ]
950 )
951
952 AS_IF([test x$build_lib_kernel_consumer = xyes],
953 [
954 build_lib_kernel_ctl=yes
955 build_lib_relayd=yes
956 ]
957 )
958
959 AS_IF([test x$build_lib_relayd = xyes],
960 [
961 build_lib_sessiond_comm=yes
962 ]
963 )
964
965
966 # Export binaries build conditions.
967 AM_CONDITIONAL([BUILD_BIN_LTTNG], [test x$enable_bin_lttng != xno])
968 AM_CONDITIONAL([BUILD_BIN_LTTNG_CONSUMERD], [test x$enable_bin_lttng_consumerd != xno])
969 AM_CONDITIONAL([BUILD_BIN_LTTNG_CRASH], [test x$enable_bin_lttng_crash != xno])
970 AM_CONDITIONAL([BUILD_BIN_LTTNG_RELAYD], [test x$enable_bin_lttng_relayd != xno])
971 AM_CONDITIONAL([BUILD_BIN_LTTNG_SESSIOND], [test x$enable_bin_lttng_sessiond != xno])
972
973 # Export the tests and extras build conditions.
974 AS_IF([\
975 test "x$enable_bin_lttng" != "xno" && \
976 test "x$enable_bin_lttng_consumerd" != "xno" && \
977 test "x$enable_bin_lttng_crash" != "xno" && \
978 test "x$enable_bin_lttng_relayd" != "xno" && \
979 test "x$enable_bin_lttng_sessiond" != "xno"],
980 [build_tests=yes],
981 [build_tests=no]
982 )
983
984 AM_CONDITIONAL([BUILD_TESTS], [test x$build_tests = xyes])
985 AM_CONDITIONAL([BUILD_EXTRAS], [test x$enable_extras != xno])
986
987 # Export libraries build conditions.
988 AM_CONDITIONAL([BUILD_LIB_COMPAT], [test x$build_lib_compat = xyes])
989 AM_CONDITIONAL([BUILD_LIB_CONFIG], [test x$build_lib_config = xyes])
990 AM_CONDITIONAL([BUILD_LIB_CONSUMER], [test x$build_lib_consumer = xyes])
991 AM_CONDITIONAL([BUILD_LIB_HASHTABLE], [test x$build_lib_hashtable = xyes])
992 AM_CONDITIONAL([BUILD_LIB_HEALTH], [test x$build_lib_health = xyes])
993 AM_CONDITIONAL([BUILD_LIB_INDEX], [test x$build_lib_index = xyes])
994 AM_CONDITIONAL([BUILD_LIB_KERNEL_CONSUMER], [test x$build_lib_kernel_consumer = xyes])
995 AM_CONDITIONAL([BUILD_LIB_KERNEL_CTL], [test x$build_lib_kernel_ctl = xyes])
996 AM_CONDITIONAL([BUILD_LIB_LTTNG_CTL], [test x$build_lib_lttng_ctl = xyes])
997 AM_CONDITIONAL([BUILD_LIB_RELAYD], [test x$build_lib_relayd = xyes])
998 AM_CONDITIONAL([BUILD_LIB_SESSIOND_COMM], [test x$build_lib_sessiond_comm = xyes])
999 AM_CONDITIONAL([BUILD_LIB_TESTPOINT], [test x$build_lib_testpoint = xyes])
1000 AM_CONDITIONAL([BUILD_LIB_UST_CONSUMER], [test x$build_lib_ust_consumer = xyes])
1001
1002 AM_CFLAGS="-Wall -fno-strict-aliasing $PTHREAD_CFLAGS"
1003 AC_SUBST(AM_CFLAGS)
1004
1005 AM_CPPFLAGS="-I\$(top_srcdir)/include -I\$(top_builddir)/include -I\$(top_srcdir)/src -include config.h $AM_CPPFLAGS"
1006 AC_SUBST(AM_CPPFLAGS)
1007
1008 lttngincludedir="${includedir}/lttng"
1009 AC_SUBST(lttngincludedir)
1010
1011 lttngactionincludedir="${includedir}/lttng/action"
1012 AC_SUBST(lttngactionincludedir)
1013
1014 lttngconditionincludedir="${includedir}/lttng/condition"
1015 AC_SUBST(lttngconditionincludedir)
1016
1017 lttngnotificationincludedir="${includedir}/lttng/notification"
1018 AC_SUBST(lttngnotificationincludedir)
1019
1020 lttngtriggerincludedir="${includedir}/lttng/trigger"
1021 AC_SUBST(lttngtriggerincludedir)
1022
1023 lttnglibexecdir="${libdir}/lttng/libexec"
1024 AC_SUBST(lttnglibexecdir)
1025
1026 AC_CONFIG_FILES([
1027 Makefile
1028 doc/Makefile
1029 doc/man/Makefile
1030 doc/man/asciidoc-attrs.conf
1031 include/Makefile
1032 extras/Makefile
1033 extras/bindings/Makefile
1034 extras/bindings/swig/Makefile
1035 extras/bindings/swig/python/Makefile
1036 extras/core-handler/Makefile
1037 src/Makefile
1038 src/common/Makefile
1039 src/common/kernel-ctl/Makefile
1040 src/common/kernel-consumer/Makefile
1041 src/common/consumer/Makefile
1042 src/common/ust-consumer/Makefile
1043 src/common/hashtable/Makefile
1044 src/common/sessiond-comm/Makefile
1045 src/common/compat/Makefile
1046 src/common/relayd/Makefile
1047 src/common/testpoint/Makefile
1048 src/common/index/Makefile
1049 src/common/health/Makefile
1050 src/common/config/Makefile
1051 src/common/string-utils/Makefile
1052 src/lib/Makefile
1053 src/lib/lttng-ctl/Makefile
1054 src/lib/lttng-ctl/filter/Makefile
1055 src/lib/lttng-ctl/lttng-ctl.pc
1056 src/bin/Makefile
1057 src/bin/lttng-consumerd/Makefile
1058 src/bin/lttng-sessiond/Makefile
1059 src/bin/lttng-relayd/Makefile
1060 src/bin/lttng/Makefile
1061 src/bin/lttng-crash/Makefile
1062 tests/Makefile
1063 tests/destructive/Makefile
1064 tests/regression/Makefile
1065 tests/regression/kernel/Makefile
1066 tests/regression/tools/Makefile
1067 tests/regression/tools/streaming/Makefile
1068 tests/regression/tools/filtering/Makefile
1069 tests/regression/tools/health/Makefile
1070 tests/regression/tools/tracefile-limits/Makefile
1071 tests/regression/tools/snapshots/Makefile
1072 tests/regression/tools/live/Makefile
1073 tests/regression/tools/exclusion/Makefile
1074 tests/regression/tools/save-load/Makefile
1075 tests/regression/tools/save-load/configuration/Makefile
1076 tests/regression/tools/mi/Makefile
1077 tests/regression/tools/wildcard/Makefile
1078 tests/regression/tools/crash/Makefile
1079 tests/regression/tools/regen-metadata/Makefile
1080 tests/regression/tools/regen-statedump/Makefile
1081 tests/regression/tools/notification/Makefile
1082 tests/regression/tools/rotation/Makefile
1083 tests/regression/ust/Makefile
1084 tests/regression/ust/nprocesses/Makefile
1085 tests/regression/ust/high-throughput/Makefile
1086 tests/regression/ust/low-throughput/Makefile
1087 tests/regression/ust/before-after/Makefile
1088 tests/regression/ust/buffers-pid/Makefile
1089 tests/regression/ust/periodical-metadata-flush/Makefile
1090 tests/regression/ust/multi-session/Makefile
1091 tests/regression/ust/multi-lib/Makefile
1092 tests/regression/ust/overlap/Makefile
1093 tests/regression/ust/overlap/demo/Makefile
1094 tests/regression/ust/linking/Makefile
1095 tests/regression/ust/daemon/Makefile
1096 tests/regression/ust/exit-fast/Makefile
1097 tests/regression/ust/fork/Makefile
1098 tests/regression/ust/libc-wrapper/Makefile
1099 tests/regression/ust/baddr-statedump/Makefile
1100 tests/regression/ust/ust-dl/Makefile
1101 tests/regression/ust/java-jul/Makefile
1102 tests/regression/ust/java-log4j/Makefile
1103 tests/regression/ust/python-logging/Makefile
1104 tests/regression/ust/getcpu-override/Makefile
1105 tests/regression/ust/clock-override/Makefile
1106 tests/regression/ust/type-declarations/Makefile
1107 tests/regression/ust/rotation-destroy-flush/Makefile
1108 tests/regression/ust/blocking/Makefile
1109 tests/stress/Makefile
1110 tests/unit/Makefile
1111 tests/unit/ini_config/Makefile
1112 tests/perf/Makefile
1113 tests/utils/Makefile
1114 tests/utils/tap/Makefile
1115 tests/utils/testapp/Makefile
1116 tests/utils/testapp/gen-ust-events/Makefile
1117 tests/utils/testapp/gen-ust-nevents/Makefile
1118 tests/utils/testapp/gen-ust-nevents-str/Makefile
1119 tests/utils/testapp/gen-syscall-events/Makefile
1120 tests/utils/testapp/gen-ust-tracef/Makefile
1121 ])
1122
1123 # Inject variable into python test script.
1124 AC_CONFIG_FILES([tests/regression/ust/python-logging/test_python_logging],[chmod +x tests/regression/ust/python-logging/test_python_logging])
1125 # Inject LTTNG_TOOLS_BUILD_WITH_LIBPFM variable in test script.
1126 AC_CONFIG_FILES([tests/perf/test_perf_raw],[chmod +x tests/perf/test_perf_raw])
1127 AC_CONFIG_FILES([tests/regression/ust/ust-dl/test_ust-dl],[chmod +x tests/regression/ust/ust-dl/test_ust-dl])
1128
1129 AC_OUTPUT
1130
1131 #
1132 # Mini-report on what will be built.
1133 #
1134
1135 PPRINT_INIT
1136 PPRINT_SET_INDENT(1)
1137 PPRINT_SET_TS(38)
1138
1139 AS_ECHO
1140 AS_ECHO("${PPRINT_COLOR_BLDBLU}LTTng-tools $PACKAGE_VERSION \"$version_name\"$PPRINT_COLOR_RST")
1141 AS_ECHO
1142
1143 AS_IF([test -n "$report_fold"], [
1144 AS_ECHO("`AS_ECHO("$version_description") | $report_fold -s`")
1145 ], [
1146 AS_ECHO("$version_description")
1147 ])
1148
1149 AS_ECHO
1150 PPRINT_SUBTITLE([Features])
1151
1152 # Target architecture we're building for.
1153 target_arch=$host_cpu
1154 [
1155 for f in $CFLAGS; do
1156 if test $f = "-m32"; then
1157 target_arch="32-bit"
1158 elif test $f = "-m64"; then
1159 target_arch="64-bit"
1160 fi
1161 done
1162 ]
1163 PPRINT_PROP_STRING([Target architecture], $target_arch)
1164
1165 # kmod enabled/disabled
1166 test "x$with_kmod" != "xno" && value=1 || value=0
1167 PPRINT_PROP_BOOL([libkmod support], $value)
1168
1169 # LTTng-UST enabled/disabled
1170 test "x$with_lttng_ust" = "xyes" && value=1 || value=0
1171 PPRINT_PROP_BOOL([LTTng-UST support], $value)
1172
1173 AS_ECHO
1174 PPRINT_SUBTITLE([Binaries])
1175
1176 # List binaries to be built
1177 test x$enable_bin_lttng != xno && value=1 || value=0
1178 PPRINT_PROP_BOOL([lttng], $value)
1179
1180 test x$enable_bin_lttng_consumerd != xno && value=1 || value=0
1181 PPRINT_PROP_BOOL([lttng-consumerd], $value)
1182
1183 test x$enable_bin_lttng_crash != xno && value=1 || value=0
1184 PPRINT_PROP_BOOL([lttng-crash], $value)
1185
1186 test x$enable_bin_lttng_relayd != xno && value=1 || value=0
1187 PPRINT_PROP_BOOL([lttng-relayd], $value)
1188
1189 test x$enable_bin_lttng_sessiond != xno && value=1 || value=0
1190 PPRINT_PROP_BOOL([lttng-sessiond], $value)
1191
1192 # Extras
1193 test x$enable_extras != xno && value=1 || value=0
1194 AS_ECHO
1195 PPRINT_SET_INDENT(0)
1196 PPRINT_PROP_BOOL([Extras], $value, $PPRINT_COLOR_SUBTITLE)
1197 PPRINT_SET_INDENT(1)
1198
1199 AS_ECHO
1200 PPRINT_SUBTITLE([Tests])
1201
1202 # Print clear message that tests won't be built
1203 AS_IF([test "x$build_tests" = "xno"],[
1204 PPRINT_WARN([Tests won't be built since some binaries were disabled])
1205 ])
1206
1207 # LTTng UST Java agent JUL tests enabled/disabled
1208 test "x$test_java_agent_jul" = "xyes" && value=1 || value=0
1209 PPRINT_PROP_BOOL([LTTng-UST Java agent JUL tests], $value)
1210
1211 # LTTng UST Java agent Log4j tests enabled/disabled
1212 test "x$test_java_agent_log4j" = "xyes" && value=1 || value=0
1213 PPRINT_PROP_BOOL([LTTng-UST Java agent Log4j tests], $value)
1214
1215 test ! -z "$PYTHON2_AGENT" && value=1 || value=0
1216 PPRINT_PROP_BOOL([LTTng-UST Python2 agent tests], $value)
1217
1218 test ! -z "$PYTHON3_AGENT" && value=1 || value=0
1219 PPRINT_PROP_BOOL([LTTng-UST Python3 agent tests], $value)
1220
1221 #Python binding enabled/disabled
1222 test "x$enable_python_binding" = xyes && value=1 || value=0
1223 AS_ECHO
1224 PPRINT_SET_INDENT(0)
1225 PPRINT_PROP_BOOL([Python binding], $value, $PPRINT_COLOR_SUBTITLE)
1226
1227 # man pages build enabled/disabled
1228 m4_pushdef([build_man_pages_msg], [Build and install man pages])
1229
1230 AS_IF([test "x$man_pages_opt" != "xno"], [
1231 AS_IF([test "x$in_git_repo" = "xyes"], [
1232 PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
1233 ], [
1234 AS_IF([test "x$have_asciidoc_xmlto" = "xyes"], [
1235 PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
1236 ], [
1237 PPRINT_PROP_STRING([build_man_pages_msg],
1238 [${PPRINT_COLOR_BLDGRN}yes (already built)],
1239 $PPRINT_COLOR_SUBTITLE)
1240 ])
1241 ])
1242 ], [
1243 PPRINT_PROP_BOOL([build_man_pages_msg], 0, $PPRINT_COLOR_SUBTITLE)
1244 ])
1245
1246 m4_popdef([build_man_pages_msg])
1247
1248 test "x$embedded_help" = xyes && value=1 || value=0
1249 PPRINT_PROP_BOOL([Embed --help messages], $value, $PPRINT_COLOR_SUBTITLE)
1250
1251 PPRINT_SET_INDENT(1)
1252
1253 report_bindir="`eval eval echo $bindir`"
1254 report_libdir="`eval eval echo $libdir`"
1255
1256 # Print the bindir and libdir this `make install' will install into.
1257 AS_ECHO
1258 PPRINT_SUBTITLE([Install directories])
1259 PPRINT_PROP_STRING([Binaries], [$report_bindir])
1260 PPRINT_PROP_STRING([Libraries], [$report_libdir])
1261
1262 AS_ECHO
1263 PPRINT_SUBTITLE([Search directories])
1264
1265 # If we build the sessiond, print the paths it will use
1266 AS_IF([test "$SESSIOND_BIN" = ""],[
1267 path="$report_bindir/lttng-sessiond"
1268 ],[
1269 path="$SESSIOND_BIN"
1270 ])
1271 PPRINT_PROP_STRING([lttng-sessiond executable], [$path])
1272
1273 AS_IF([test "$CONSUMERD32_BIN" = ""],[
1274 path="`eval eval echo $lttnglibexecdir`/lttng-consumerd"
1275 ],[
1276 path="$CONSUMERD32_BIN"
1277 ])
1278 PPRINT_PROP_STRING([32-bit lttng-consumerd executable], [$path])
1279
1280 AS_IF([test "$CONSUMERD32_LIBDIR" = ""],[
1281 path="`eval eval echo $libdir`"
1282 ],[
1283 path="$CONSUMERD32_LIBDIR"
1284 ])
1285 PPRINT_PROP_STRING([32-bit consumer libraries], [$path])
1286
1287 AS_IF([test "$CONSUMERD64_BIN" = ""],[
1288 path="`eval eval echo $lttnglibexecdir`/lttng-consumerd"
1289 ],[
1290 path="$CONSUMERD64_BIN"
1291 ])
1292 PPRINT_PROP_STRING([64-bit lttng-consumerd executable], [$path])
1293
1294 AS_IF([test "$CONSUMERD64_LIBDIR" = ""],[
1295 path="`eval eval echo $libdir`"
1296 ],[
1297 path="$CONSUMERD64_LIBDIR"
1298 ])
1299 PPRINT_PROP_STRING([64-bit consumer libraries], [$path])
1300 PPRINT_SET_INDENT(0)
1301
1302 AS_IF([test "x$warn_prebuilt_man_pages" = "xyes" ], [
1303 AS_ECHO
1304 PPRINT_WARN([You need asciidoc and xmlto to build the LTTng-tools man pages.
1305
1306 Note that the man pages are already built in this distribution tarball,
1307 therefore asciidoc and xmlto are only needed if you intend to modify
1308 their sources.
1309
1310 Also note that the installed man pages will contain the project's
1311 default command-line option and environment variable values.
1312
1313 Use --disable-man-pages to completely disable building and installing
1314 the man pages.])
1315 ])
This page took 0.094445 seconds and 4 git commands to generate.