Tests: Java agent: update after Java agent refactoring
[lttng-tools.git] / configure.ac
1 AC_PREREQ([2.64])
2 AC_INIT([lttng-tools],[2.8.0-pre],[jeremie.galarneau@efficios.com],[],[https://lttng.org])
3 AC_CONFIG_AUX_DIR([config])
4 AC_CANONICAL_TARGET
5 AC_CANONICAL_HOST
6 AC_CONFIG_MACRO_DIR([config])
7 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
8 AM_MAINTAINER_MODE([enable])
9 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
10
11 # Compute minor/major/patchlevel version numbers
12 AC_PROG_SED
13 major_version=$(echo AC_PACKAGE_VERSION | sed 's/^\([[0-9]]\)*\.[[0-9]]*\.[[0-9]]*.*$/\1/')
14 minor_version=$(echo AC_PACKAGE_VERSION | sed 's/^[[0-9]]*\.\([[0-9]]*\)\.[[0-9]]*.*$/\1/')
15 patchlevel_version=$(echo AC_PACKAGE_VERSION | sed 's/^[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\).*$/\1/')
16 AC_SUBST([MAJOR_VERSION], [$major_version])
17 AC_SUBST([MINOR_VERSION], [$minor_version])
18 AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version])
19 AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [LTTng-Tools major version number])
20 AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [LTTng-Tools minor version number])
21 AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [LTTng-Tools patchlevel version number])
22
23 version_name="Herbe à Détourne"
24 version_description='Brewed with unrestrained amounts of Citra hop, the Herbe à Détourne is a fantastic New World Tripel brewed by "Dieu du Ciel!". Aromas of mango, cantaloupe melon and passion fruit, combined with a controlled bitter finish, unite in making this smooth golden-orange beer stand apart.'
25 version_description_c=$(echo $version_description | sed 's/"/\\"/g')
26
27 AC_DEFINE_UNQUOTED([VERSION_NAME], ["$version_name"], "")
28 AC_DEFINE_UNQUOTED([VERSION_DESCRIPTION], ["$version_description_c"], "")
29
30 AC_CONFIG_HEADERS([include/config.h])
31
32 AC_PROG_GREP
33 # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
34 AC_ARG_ENABLE(libtool-linkdep-fixup,
35 AS_HELP_STRING([--disable-libtool-linkdep-fixup],
36 [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)]),
37 libtool_fixup=$enableval,
38 libtool_fixup=yes)
39
40 AS_IF([test "x$libtool_fixup" = "xyes"],
41 [
42 libtool_m4="$srcdir/config/libtool.m4"
43 libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
44 AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
45 libtool_flag_pattern_count=$(grep -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
46 AS_IF([test $libtool_flag_pattern_count -ne 0],
47 [
48 AC_MSG_RESULT([$libtool_flag_pattern_count])
49 AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
50 sed -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
51 ],
52 [
53 AC_MSG_RESULT([none])
54 ])
55 ])
56
57 AM_CONDITIONAL([NO_SHARED], [test x$enable_shared = xno])
58
59 AC_CHECK_HEADERS([ \
60 sys/types.h unistd.h fcntl.h string.h pthread.h limits.h \
61 signal.h stdlib.h sys/un.h sys/socket.h stdlib.h stdio.h \
62 getopt.h sys/ipc.h sys/shm.h popt.h grp.h arpa/inet.h \
63 netdb.h netinet/in.h paths.h stddef.h sys/file.h sys/ioctl.h \
64 sys/mount.h sys/param.h sys/time.h
65 ])
66
67 # Basic functions check
68 AC_CHECK_FUNCS([ \
69 atexit bzero clock_gettime dup2 fdatasync ftruncate \
70 gethostbyname gethostname getpagesize localtime_r memchr memset \
71 mkdir munmap putenv realpath rmdir socket strchr strcspn strdup \
72 strncasecmp strndup strpbrk strrchr strstr strtol strtoul \
73 strtoull \
74 ])
75
76 # Babeltrace viewer check
77 AC_ARG_WITH([babeltrace-bin],
78 AS_HELP_STRING([--with-babeltrace-bin],
79 [Location of the babeltrace viewer executable (including the filename)]),
80 [BABELTRACE_BIN="$withval"],
81 [BABELTRACE_BIN=''])
82 AC_SUBST([BABELTRACE_BIN])
83
84 # lttv-gui
85 AC_ARG_WITH([lttv-gui-bin],
86 AS_HELP_STRING([--with-lttv-gui-bin],
87 [Location of the lttv GUI viewer executable (including the filename)]),
88 [LTTV_GUI_BIN="$withval"],
89 [LTTV_GUI_BIN=''])
90 AC_SUBST([LTTV_GUI_BIN])
91
92 AC_ARG_WITH([consumerd32-bin],
93 AS_HELP_STRING([--with-consumerd32-bin],
94 [Location of the 32-bit consumerd executable (including the filename)]),
95 [CONSUMERD32_BIN="$withval"],
96 [CONSUMERD32_BIN=''])
97 AC_SUBST([CONSUMERD32_BIN])
98
99 AC_ARG_WITH([consumerd64-bin],
100 AS_HELP_STRING([--with-consumerd64-bin],
101 [Location of the 64-bit consumerd executable (including the filename)]),
102 [CONSUMERD64_BIN="$withval"],
103 [CONSUMERD64_BIN=''])
104 AC_SUBST([CONSUMERD64_BIN])
105
106 AC_ARG_WITH([consumerd32-libdir],
107 AS_HELP_STRING([--with-consumerd32-libdir],
108 [Directory containing the 32-bit consumerd libraries]),
109 [CONSUMERD32_LIBDIR="$withval"],
110 [CONSUMERD32_LIBDIR=''])
111 AC_SUBST([CONSUMERD32_LIBDIR])
112
113 AC_ARG_WITH([consumerd64-libdir],
114 AS_HELP_STRING([--with-consumerd64-libdir],
115 [Directory containing the 64-bit consumerd libraries]),
116 [CONSUMERD64_LIBDIR="$withval"],
117 [CONSUMERD64_LIBDIR=''])
118 AC_SUBST([CONSUMERD64_LIBDIR])
119
120 AC_ARG_WITH([sessiond-bin],
121 AS_HELP_STRING([--with-sessiond-bin],
122 [Location of the sessiond executable (including the filename)]),
123 [SESSIOND_BIN="$withval"],
124 [SESSIOND_BIN=''])
125 AC_SUBST([SESSIOND_BIN])
126
127 AC_ARG_WITH([lttng-system-rundir],
128 AS_HELP_STRING([--with-lttng-system-rundir],
129 [Location of the system directory where the system-wide lttng-sessiond runtime files are kept. The default is "/var/run/lttng".]),
130 [LTTNG_SYSTEM_RUNDIR="$withval"],
131 [LTTNG_SYSTEM_RUNDIR="/var/run/lttng"])
132 AC_SUBST([LTTNG_SYSTEM_RUNDIR])
133
134 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_BIN], "$CONSUMERD32_BIN", [Location of the 32-bit consumerd executable.])
135 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_BIN], "$CONSUMERD64_BIN", [Location of the 64-bit consumerd executable])
136 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_LIBDIR], "$CONSUMERD32_LIBDIR", [Search for consumerd 32-bit libraries in this location.])
137 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_LIBDIR], "$CONSUMERD64_LIBDIR", [Search for consumerd 64-bit libraries in this location.])
138 AC_DEFINE_UNQUOTED([CONFIG_BABELTRACE_BIN], "$BABELTRACE_BIN", [Location of the babeltrace viewer executable.])
139 AC_DEFINE_UNQUOTED([CONFIG_LTTV_GUI_BIN], "$LTTV_GUI_BIN", [Location of the lttv GUI viewer executable.])
140 AC_DEFINE_UNQUOTED([CONFIG_SESSIOND_BIN], "$SESSIOND_BIN", [Location of the sessiond executable.])
141 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_RUNDIR], ["$LTTNG_SYSTEM_RUNDIR"], [LTTng system runtime directory])
142
143 if test "x$prefix" = "xNONE"; then
144 prefix=$ac_default_prefix
145 fi
146 CONFDIR=`eval echo $sysconfdir`
147 AC_SUBST(CONFDIR)
148 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_CONFIGDIR],"$CONFDIR", [LTTng system configuration directory.])
149
150 AC_DEFINE_DIR([CONFIG_LTTNG_SYSTEM_DATADIR],[datadir], [LTTng system data directory.])
151
152 #
153 # Check for pthread
154 AC_CHECK_LIB([pthread], [pthread_create], [],
155 [AC_MSG_ERROR([Cannot find libpthread. Use [LDFLAGS]=-Ldir to specify its location.])]
156 )
157
158 # Check libpopt
159 AC_CHECK_LIB([popt], [poptGetContext], [],
160 [AC_MSG_ERROR([Cannot find libpopt. Use [LDFLAGS]=-Ldir to specify its location.])]
161 )
162
163 AM_PATH_XML2(2.7.6, true, AC_MSG_ERROR(No supported version of libxml2 found.))
164
165 # Check for libuuid
166 AC_CHECK_LIB([uuid], [uuid_generate],
167 [
168 AC_DEFINE_UNQUOTED([LTTNG_HAVE_LIBUUID], 1, [Has libuuid support.])
169 have_libuuid=yes
170 ],
171 [
172 # libuuid not found, check for uuid_create in libc.
173 AC_CHECK_LIB([c], [uuid_create],
174 [
175 AC_DEFINE_UNQUOTED([LTTNG_HAVE_LIBC_UUID], 1, [Has libc uuid support.])
176 have_libc_uuid=yes
177 ],
178 [
179 AC_MSG_ERROR([Cannot find libuuid uuid_generate nor libc uuid_create. Use [LDFLAGS]=-Ldir to specify their location.])
180 ])
181 ]
182 )
183 AM_CONDITIONAL([LTTNG_BUILD_WITH_LIBUUID], [test "x$have_libuuid" = "xyes"])
184 AM_CONDITIONAL([LTTNG_BUILD_WITH_LIBC_UUID], [test "x$have_libc_uuid" = "xyes"])
185
186 # URCU library version needed or newer
187 liburcu_version=">= 0.8.0"
188
189 # Check liburcu needed function calls
190 AC_CHECK_DECL([cds_list_add], [],
191 [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu/list.h>]]
192 )
193 AC_CHECK_DECL([cds_wfcq_init], [],
194 [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu/wfcqueue.h>]]
195 )
196 AC_CHECK_DECL([cds_wfcq_dequeue_blocking], [],
197 [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu/wfcqueue.h>]]
198 )
199 AC_CHECK_DECL([futex_async], [],
200 [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu/futex.h>]]
201 )
202 AC_CHECK_DECL([rcu_thread_offline], [],
203 [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu.h>]]
204 )
205 AC_CHECK_DECL([rcu_thread_online], [],
206 [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu.h>]]
207 )
208 AC_CHECK_DECL([caa_likely], [],
209 [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu.h>]]
210 )
211 #Function added in urcu 0.7.0
212 AC_CHECK_DECL([cmm_smp_mb__before_uatomic_or], [],
213 [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu.h>]]
214 )
215
216 # Check kmod library
217 AC_ARG_WITH(kmod-prefix,
218 AS_HELP_STRING([--with-kmod-prefix=PATH],
219 [Specify the installation prefix of the kmod library.
220 Headers must be in PATH/include; libraries in PATH/lib.]),
221 [
222 CPPFLAGS="$CPPFLAGS -I${withval}/include"
223 LDFLAGS="$LDFLAGS -L${withval}/lib64 -L${withval}/lib"
224 ])
225
226 AC_ARG_ENABLE(kmod,
227 AS_HELP_STRING([--disable-kmod],[build without kmod support]),
228 kmod_support=zz$enableval, kmod_support=yes)
229
230 AS_IF([test "x$kmod_support" = "xyes"], [
231 AC_CHECK_LIB([kmod], [kmod_module_probe_insert_module],
232 [
233 AC_DEFINE([HAVE_KMOD], [1], [has kmod support])
234 LIBS="$LIBS -lkmod"
235 kmod_found=yes
236 ],
237 kmod_found=no
238 )
239 ])
240 AM_CONDITIONAL([HAVE_KMOD], [test "x$kmod_found" = xyes])
241
242 AC_ARG_WITH(lttng-ust-prefix,
243 AS_HELP_STRING([--with-lttng-ust-prefix=PATH],
244 [Specify the installation prefix of the lttng-ust library.
245 Headers must be in PATH/include; libraries in PATH/lib.]),
246 [
247 CPPFLAGS="$CPPFLAGS -I${withval}/include"
248 LDFLAGS="$LDFLAGS -L${withval}/lib64 -L${withval}/lib"
249 ])
250
251 # Check liblttng-ust-ctl library
252 AC_ARG_ENABLE(lttng-ust,
253 AS_HELP_STRING([--disable-lttng-ust],[build without LTTng-UST (Userspace Tracing) support]),
254 lttng_ust_support=$enableval, lttng_ust_support=yes)
255
256 AS_IF([test "x$lttng_ust_support" = "xyes"], [
257 AC_CHECK_LIB([lttng-ust-ctl], [ustctl_recv_channel_from_consumer],
258 [
259 AC_DEFINE([HAVE_LIBLTTNG_UST_CTL], [1], [has LTTng-UST control support])
260 lttng_ust_ctl_found=yes
261 ],
262 [AC_MSG_ERROR([Cannot find LTTng-UST >= 2.2.x. Use --with-lttng-ust-prefix=PREFIX to specify its location, or specify --disable-lttng-ust to build lttng-tools without LTTng-UST support.])],
263 [-lurcu-common -lurcu-bp -lurcu-cds -lrt -ldl]
264 )
265 ])
266 AM_CONDITIONAL([HAVE_LIBLTTNG_UST_CTL], [test "x$lttng_ust_ctl_found" = xyes])
267 AC_CHECK_FUNCS([sched_getcpu sysconf sync_file_range])
268
269 # check for dlopen
270 AC_CHECK_LIB([dl], [dlopen],
271 [
272 have_libdl=yes
273 ],
274 [
275 #libdl not found, check for dlopen in libc.
276 AC_CHECK_LIB([c], [dlopen],
277 [
278 have_libc_dl=yes
279 ],
280 [
281 AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
282 ])
283 ])
284 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBDL], [test "x$have_libdl" = "xyes"])
285 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBC_DL], [test "x$have_libc_dl" = "xyes"])
286
287 # Check for fmemopen
288 AC_CHECK_LIB([c], [fmemopen],
289 [
290 AC_DEFINE_UNQUOTED([LTTNG_HAVE_FMEMOPEN], 1, [Has fmemopen support.])
291 ]
292 )
293
294 # Check for open_memstream
295 AC_CHECK_LIB([c], [open_memstream],
296 [
297 AC_DEFINE_UNQUOTED([LTTNG_HAVE_OPEN_MEMSTREAM], 1, [Has open_memstream support.])
298 ]
299 )
300
301 AC_ARG_ENABLE([git-version],
302 [AC_HELP_STRING([--disable-git-version],
303 [Do not use the git version for the build])],
304 [have_git_version=$enableval], [have_git_version=yes]
305 )
306
307 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_GIT_SOURCE],
308 [test "x${have_git_version}" = "xyes"])
309
310 # For Python
311 # SWIG version needed or newer:
312 swig_version=2.0.0
313
314 AC_ARG_ENABLE([python-bindings],
315 [AC_HELP_STRING([--enable-python-bindings],
316 [compile Python bindings])],
317 [enable_python=yes], [enable_python=no])
318
319 AM_CONDITIONAL([USE_PYTHON], [test "x${enable_python:-yes}" = xyes])
320
321 if test "x${enable_python:-yes}" = xyes; then
322 AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ])
323 AM_PATH_PYTHON
324
325 AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config])
326 AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
327 AS_IF([test -z "$PYTHON_INCLUDE"], [
328 AS_IF([test -z "$PYTHON_CONFIG"], [
329 AC_PATH_PROGS([PYTHON_CONFIG],
330 [python$PYTHON_VERSION-config python-config],
331 [no],
332 [`dirname $PYTHON`])
333 AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
334 ])
335 AC_MSG_CHECKING([python include flags])
336 PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
337 AC_MSG_RESULT([$PYTHON_INCLUDE])
338 ])
339
340 else
341 AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl
342 [if you want Python bindings.])
343
344 fi
345
346 # Epoll check. If not present, the build will fallback on poll() API
347 AX_HAVE_EPOLL(
348 [AX_CONFIG_FEATURE_ENABLE(epoll)],
349 [AX_CONFIG_FEATURE_DISABLE(epoll)]
350 )
351 AX_CONFIG_FEATURE(
352 [epoll], [This platform supports epoll(7)],
353 [HAVE_EPOLL], [This platform supports epoll(7).],
354 [enable_epoll="yes"], [enable_epoll="no"]
355 )
356 AM_CONDITIONAL([COMPAT_EPOLL], [ test "$enable_epoll" = "yes" ])
357
358 AX_JAVA_OPTIONS
359 AX_PROG_JAVAC
360 AX_PROG_JAVA
361 AX_PROG_JAR
362
363 AX_CHECK_CLASSPATH
364
365 # Check for Java UST agent common class first
366 AX_CHECK_CLASS(org.lttng.ust.agent.AbstractLttngAgent)
367 if test "x$ac_cv_class_org_lttng_ust_agent_AbstractLttngAgent" = "xyes"; then
368 java_agent_common=yes
369 else
370 java_agent_common=no
371 fi
372
373 # If the common class is available, test for each agent
374 if test "x$java_agent_common" = "xyes"; then
375 # Check for JUL
376 AX_CHECK_CLASS(org.lttng.ust.agent.jul.LttngLogHandler)
377 AX_CHECK_CLASS(org.lttng.ust.agent.log4j.LttngLogAppender)
378 AX_CHECK_CLASS(org.apache.log4j.Logger)
379
380 build_java_jul_agent=no
381 if test "x$ac_cv_class_org_lttng_ust_agent_jul_LttngLogHandler" = "xyes"; then
382 build_java_jul_agent=yes
383 fi
384
385 build_java_log4j_agent=no
386 if test "x$ac_cv_class_org_lttng_ust_agent_log4j_LttngLogAppender" = "xyes"; then
387 if test "x$ac_cv_class_org_apache_log4j_Logger" = "xyes"; then
388 build_java_log4j_agent=yes
389 fi
390 fi
391
392 fi
393
394 AM_CONDITIONAL([BUILD_JAVA_JUL_AGENT], [test "x$build_java_jul_agent" = "xyes"])
395 AM_CONDITIONAL([BUILD_JAVA_LOG4J_AGENT], [test "x$build_java_log4j_agent" = "xyes"])
396
397 AC_SYS_LARGEFILE
398
399 # C compiler tests
400 AC_PROG_CC
401 AC_C_INLINE
402
403 # Type availability checking
404 AC_TYPE_INT32_T
405 AC_TYPE_INT64_T
406 AC_TYPE_MODE_T
407 AC_TYPE_OFF_T
408 AC_TYPE_PID_T
409 AC_TYPE_SIZE_T
410 AC_TYPE_SSIZE_T
411 AC_TYPE_UID_T
412 AC_TYPE_UINT16_T
413 AC_TYPE_UINT32_T
414 AC_TYPE_UINT64_T
415 AC_TYPE_UINT8_T
416
417 LT_INIT
418 AC_PROG_YACC
419 AC_PROG_LEX
420
421 if test ! -f "$srcdir/src/lib/lttng-ctl/filter/filter-parser.h"; then
422 if test x"$YACC" != "xbison -y"; then
423 AC_MSG_ERROR([[bison not found and is required when building from git.
424 Please install bison]])
425 fi
426 AC_PATH_PROG([BISON],[bison])
427 AX_PROG_BISON_VERSION([2.4], [],[
428 AC_MSG_ERROR([[Bison >= 2.4 is required when building from git]])
429 ])
430 fi
431
432 if test ! -f "$srcdir/src/lib/lttng-ctl/filter/filter-lexer.c"; then
433 if test x"$LEX" != "xflex"; then
434 AC_MSG_ERROR([[flex not found and is required when building from git.
435 Please install flex]])
436 fi
437 AC_PATH_PROG([FLEX],[flex])
438 AX_PROG_FLEX_VERSION([2.5.35], [],[
439 AC_MSG_ERROR([[Flex >= 2.5.35 is required when building from git]])
440 ])
441 fi
442
443 CFLAGS="-Wall $CFLAGS -g -fno-strict-aliasing"
444
445 DEFAULT_INCLUDES="-I\$(top_srcdir) -I\$(top_builddir) -I\$(top_builddir)/src -I\$(top_builddir)/include -include config.h"
446
447 lttngincludedir="${includedir}/lttng"
448
449 AC_SUBST(lttngincludedir)
450 AC_SUBST(DEFAULT_INCLUDES)
451
452 lttnglibexecdir="${libdir}/lttng/libexec"
453 AC_SUBST(lttnglibexecdir)
454
455 AC_CONFIG_FILES([
456 Makefile
457 doc/Makefile
458 doc/man/Makefile
459 include/Makefile
460 extras/Makefile
461 extras/bindings/Makefile
462 extras/bindings/swig/Makefile
463 extras/bindings/swig/python/Makefile
464 extras/core-handler/Makefile
465 src/Makefile
466 src/common/Makefile
467 src/common/kernel-ctl/Makefile
468 src/common/kernel-consumer/Makefile
469 src/common/ust-consumer/Makefile
470 src/common/hashtable/Makefile
471 src/common/sessiond-comm/Makefile
472 src/common/compat/Makefile
473 src/common/relayd/Makefile
474 src/common/testpoint/Makefile
475 src/common/index/Makefile
476 src/common/health/Makefile
477 src/common/config/Makefile
478 src/lib/Makefile
479 src/lib/lttng-ctl/Makefile
480 src/lib/lttng-ctl/filter/Makefile
481 src/lib/lttng-ctl/lttng-ctl.pc
482 src/bin/Makefile
483 src/bin/lttng-consumerd/Makefile
484 src/bin/lttng-sessiond/Makefile
485 src/bin/lttng-relayd/Makefile
486 src/bin/lttng/Makefile
487 src/bin/lttng-crash/Makefile
488 tests/Makefile
489 tests/regression/Makefile
490 tests/regression/kernel/Makefile
491 tests/regression/tools/Makefile
492 tests/regression/tools/streaming/Makefile
493 tests/regression/tools/filtering/Makefile
494 tests/regression/tools/health/Makefile
495 tests/regression/tools/tracefile-limits/Makefile
496 tests/regression/tools/snapshots/Makefile
497 tests/regression/tools/live/Makefile
498 tests/regression/tools/exclusion/Makefile
499 tests/regression/tools/save-load/Makefile
500 tests/regression/tools/mi/Makefile
501 tests/regression/ust/Makefile
502 tests/regression/ust/nprocesses/Makefile
503 tests/regression/ust/high-throughput/Makefile
504 tests/regression/ust/low-throughput/Makefile
505 tests/regression/ust/before-after/Makefile
506 tests/regression/ust/buffers-pid/Makefile
507 tests/regression/ust/periodical-metadata-flush/Makefile
508 tests/regression/ust/multi-session/Makefile
509 tests/regression/ust/overlap/Makefile
510 tests/regression/ust/overlap/demo/Makefile
511 tests/regression/ust/linking/Makefile
512 tests/regression/ust/daemon/Makefile
513 tests/regression/ust/exit-fast/Makefile
514 tests/regression/ust/fork/Makefile
515 tests/regression/ust/libc-wrapper/Makefile
516 tests/regression/ust/java-jul/Makefile
517 tests/regression/ust/java-log4j/Makefile
518 tests/regression/ust/python-logging/Makefile
519 tests/regression/ust/getcpu-override/Makefile
520 tests/stress/Makefile
521 tests/unit/Makefile
522 tests/unit/ini_config/Makefile
523 tests/utils/Makefile
524 tests/utils/tap/Makefile
525 tests/utils/testapp/Makefile
526 tests/utils/testapp/gen-ust-events/Makefile
527 tests/utils/testapp/gen-ust-nevents/Makefile
528 tests/utils/testapp/gen-ust-tracef/Makefile
529 ])
530
531 AC_OUTPUT
532
533 #
534 # Mini-report on what will be built
535 #
536 AS_ECHO()
537
538 AS_ECHO("Version name: $version_name")
539 AS_ECHO("$version_description")
540
541 AS_ECHO()
542
543 # Target architecture we're building for
544 target_arch=$host_cpu
545 [
546 for f in $CFLAGS; do
547 if test $f = "-m32"; then
548 target_arch="32-bit"
549 elif test $f = "-m64"; then
550 target_arch="64-bit"
551 fi
552 done
553 ]
554 AS_ECHO_N("Target architecture: ")
555 AS_ECHO($target_arch)
556
557 # kmod enabled/disabled
558 AS_ECHO_N("libkmod support: ")
559 AS_IF([test "x$kmod_found" = "xyes"],[
560 AS_ECHO("Enabled")
561 ],[
562 AS_ECHO("Disabled")
563 ])
564
565 # LTTng-UST enabled/disabled
566 AS_ECHO_N("Lttng-UST support: ")
567 AS_IF([test "x$lttng_ust_support" = "xyes"],[
568 AS_ECHO("Enabled")
569 ],[
570 AS_ECHO("Disabled")
571 ])
572
573 #Python binding enabled/disabled
574 AS_ECHO_N("Python binding: ")
575 AS_IF([test "x${enable_python:-yes}" = xyes], [
576 AS_ECHO("Enabled")
577 ],[
578 AS_ECHO("Disabled")
579 ])
580
581 # Do we build only the consumerd, or everything
582 AS_IF([test "x$consumerd_only" = "xyes"],[
583 AS_ECHO("Only the consumerd daemon will be built.")
584 ],[
585 AS_ECHO("All binaries will be built.")
586 ])
587
588 # Print the bindir and libdir this `make install' will install into.
589 AS_ECHO()
590 AS_ECHO_N("Binaries will be installed in: ")
591 AS_ECHO("`eval eval echo $bindir`")
592 AS_ECHO_N("Libraries will be installed in: ")
593 AS_ECHO("`eval eval echo $libdir`")
594
595 # If we build the sessiond, print the paths it will use
596 AS_IF([test "x$consumerd_only" = "xno"],[
597 AS_ECHO()
598 AS_ECHO_N("The lttng command will look for the lttng-sessiond executable at: ")
599 AS_IF([test "$SESSIOND_BIN" = ""],[
600 AS_ECHO_N("`eval eval echo $bindir`")
601 AS_ECHO("/lttng-sessiond")
602 ],[
603 AS_ECHO("$SESSIOND_BIN")
604 ])
605
606 AS_ECHO()
607 AS_ECHO("The sessiond daemon will look in the following directories: ")
608 AS_ECHO_N("32-bit consumerd executable at: ")
609 AS_IF([test "$CONSUMERD32_BIN" = ""],[
610 AS_ECHO_N("`eval eval echo $lttnglibexecdir`")
611 AS_ECHO("/lttng-consumerd")
612 ],[
613 AS_ECHO("$CONSUMERD32_BIN")
614 ])
615
616 AS_ECHO_N("32-bit consumer libraries in: ")
617 AS_IF([test "$CONSUMERD32_LIBDIR" = ""],[
618 AS_ECHO("`eval eval echo $libdir`")
619 ],[
620 AS_ECHO("$CONSUMERD32_LIBDIR")
621 ])
622
623 AS_ECHO_N("64-bit consumerd executable at: ")
624 AS_IF([test "$CONSUMERD64_BIN" = ""],[
625 AS_ECHO_N("`eval eval echo $lttnglibexecdir`")
626 AS_ECHO("/lttng-consumerd")
627 ],[
628 AS_ECHO("$CONSUMERD64_BIN")
629 ])
630
631 AS_ECHO_N("64-bit consumer libraries in: ")
632 AS_IF([test "$CONSUMERD64_LIBDIR" = ""],[
633 AS_ECHO("`eval eval echo $libdir`")
634 ],[
635 AS_ECHO("$CONSUMERD64_LIBDIR")
636 ])
637 ])
638
639 AS_ECHO()
640
This page took 0.067938 seconds and 4 git commands to generate.