configure.ac

   1 AC_PREREQ([2.64])
   2 AC_INIT([lttng-tools],[2.11.0-pre],[jeremie.galarneau@efficios.com],[],[https://lttng.org])
   3
   4 AC_CONFIG_HEADERS([include/config.h])
   5 AC_CONFIG_AUX_DIR([config])
   6 AC_CONFIG_MACRO_DIR([m4])
   7
   8 AC_CANONICAL_TARGET
   9 AC_CANONICAL_HOST
  10
  11 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip tar-pax nostdinc])
  12 AM_MAINTAINER_MODE([enable])
  13
  14 # Enable silent rules if available (Introduced in AM 1.11)
  15 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  16
  17 AC_REQUIRE_AUX_FILE([tap-driver.sh])
  18
  19 # Checks for C compiler
  20 AC_USE_SYSTEM_EXTENSIONS
  21 AC_SYS_LARGEFILE
  22 AC_PROG_CC
  23 AC_PROG_CC_STDC
  24
  25 # Checks for programs.
  26 AC_PROG_GREP
  27 AC_PROG_MAKE_SET
  28 AC_PROG_SED
  29 AC_PATH_PROG([report_fold], [fold])
  30 LT_INIT
  31
  32 # Check for objcopy, required by the base address statedump and dynamic linker tests
  33 AC_CHECK_TOOL([OBJCOPY], [objcopy], [no])
  34 AS_IF([test "x$OBJCOPY" = "xno"],
  35         [AC_MSG_WARN([Cannot find objcopy. The base address statedump and dynamic linker tests will be disabled. Install the binutils package to remediate this.])]
  36 )
  37 AM_CONDITIONAL([HAVE_OBJCOPY], [test "x$OBJCOPY" != xno])
  38
  39 # check for pgrep
  40 AC_PATH_PROG([PGREP], [pgrep], [no])
  41 AM_CONDITIONAL([HAVE_PGREP], [test "x$PGREP" != "xno"])
  42
  43 # check for bison
  44 AC_PROG_YACC
  45 BISON=$YACC
  46 AX_PROG_BISON_VERSION([2.4], [have_bison=yes])
  47
  48 AS_IF([test "x$have_bison" != "xyes"], [
  49   AS_IF([test "x$in_git_repo" = "xyes"], [
  50     AC_MSG_FAILURE([
  51 Bison >= 2.4 is required when building from the Git repository. You can
  52 set the YACC variable to override automatic detection.
  53     ])
  54   ], [
  55     AC_MSG_WARN([
  56 Missing Bison >= 2.4. Note that the parser files are already built in
  57 this distribution tarball, so Bison is only needed if you intend to
  58 modify their sources. You can set the YACC variable to override automatic
  59 detection.
  60     ])
  61   ])
  62 ])
  63 AM_CONDITIONAL([HAVE_BISON], [test "x$have_bison" = "xyes"])
  64
  65 # check for flex
  66 AC_PROG_LEX
  67 FLEX=$LEX
  68 AX_PROG_FLEX_VERSION([2.5.35], [have_flex=yes])
  69
  70 AS_IF([test "x$have_flex" != "xyes"], [
  71   AS_IF([test "x$in_git_repo" = "xyes"], [
  72     AC_MSG_FAILURE([
  73 Flex >= 2.5.35 is required when building from the Git repository. You can
  74 set the LEX variable to override automatic detection.
  75     ])
  76   ], [
  77     AC_MSG_WARN([
  78 Missing Flex >= 2.5.35. Note that the lexer files are already built in
  79 this distribution tarball, so Flex is only needed if you intend to
  80 modify their sources. You can set the LEX variable to override automatic
  81 detection.
  82     ])
  83   ])
  84 ])
  85 AM_CONDITIONAL([HAVE_FLEX], [test "x$have_flex" = "xyes"])
  86
  87
  88 # Checks for typedefs, structures, and compiler characteristics.
  89 AC_C_INLINE
  90 AC_TYPE_INT32_T
  91 AC_TYPE_INT64_T
  92 AC_TYPE_MODE_T
  93 AC_TYPE_OFF_T
  94 AC_TYPE_PID_T
  95 AC_TYPE_SIZE_T
  96 AC_TYPE_SSIZE_T
  97 AC_TYPE_UID_T
  98 AC_TYPE_UINT16_T
  99 AC_TYPE_UINT32_T
 100 AC_TYPE_UINT64_T
 101 AC_TYPE_UINT8_T
 102
 103 AX_C___ATTRIBUTE__
 104 AS_IF([test "x$ax_cv___attribute__" = "xyes"],
 105         [:],
 106         [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
 107
 108 AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])
 109
 110 AX_LIB_SOCKET_NSL
 111
 112 LT_NO_UNDEFINED=""
 113 AS_CASE([$host_os],
 114   [cygwin*],
 115     [
 116       LT_NO_UNDEFINED="-no-undefined"
 117     ],
 118   [cygwin*|darwin*|mingw*|solaris*],
 119     [
 120       # On platforms where we only support the relayd, disable the other binaries by default
 121       AS_IF([test "x$enable_bin_lttng" = "x" ], [enable_bin_lttng=no])
 122       AS_IF([test "x$enable_bin_lttng_consumerd" = "x" ], [enable_bin_lttng_consumerd=no])
 123       AS_IF([test "x$enable_bin_lttng_crash" = "x" ], [enable_bin_lttng_crash=no])
 124       AS_IF([test "x$enable_bin_lttng_sessiond" = "x" ], [enable_bin_lttng_sessiond=no])
 125       AS_IF([test "x$enable_extras" = "x" ], [enable_extras=no])
 126       AS_IF([test "x$with_lttng_ust" = "x" ], [with_lttng_ust=no])
 127     ]
 128 )
 129
 130 AC_SUBST(LT_NO_UNDEFINED)
 131
 132 # Compute minor/major/patchlevel version numbers
 133 major_version=$(echo AC_PACKAGE_VERSION | $SED 's/^\([[0-9]]\)*\.[[0-9]]*\.[[0-9]]*.*$/\1/')
 134 minor_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.\([[0-9]]*\)\.[[0-9]]*.*$/\1/')
 135 patchlevel_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\).*$/\1/')
 136
 137 AC_SUBST([MAJOR_VERSION], [$major_version])
 138 AC_SUBST([MINOR_VERSION], [$minor_version])
 139 AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version])
 140 AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [LTTng-Tools major version number])
 141 AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [LTTng-Tools minor version number])
 142 AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [LTTng-Tools patchlevel version number])
 143
 144 version_name="Codename TBD"
 145 version_description='Description TBD'
 146 version_description_c=$(echo $version_description | $SED 's/"/\\"/g')
 147
 148 AC_DEFINE_UNQUOTED([VERSION_NAME], ["$version_name"], "")
 149 AC_DEFINE_UNQUOTED([VERSION_DESCRIPTION], ["$version_description_c"], "")
 150
 151 # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
 152 AC_ARG_ENABLE(libtool-linkdep-fixup,
 153         AS_HELP_STRING([--disable-libtool-linkdep-fixup],
 154                         [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)]),
 155         libtool_fixup=$enableval,
 156         libtool_fixup=yes)
 157
 158 AS_IF([test "x$libtool_fixup" = "xyes"],
 159             [
 160             libtool_m4="$srcdir/m4/libtool.m4"
 161             libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
 162             AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
 163             libtool_flag_pattern_count=$($GREP -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
 164             AS_IF([test $libtool_flag_pattern_count -ne 0],
 165             [
 166                   AC_MSG_RESULT([$libtool_flag_pattern_count])
 167                   AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
 168                   $SED -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
 169                   ],
 170                   [
 171                   AC_MSG_RESULT([none])
 172                   ])
 173             ])
 174
 175 AM_CONDITIONAL([NO_SHARED], [test x$enable_shared = xno])
 176
 177 AC_CHECK_HEADERS([ \
 178         sys/types.h unistd.h fcntl.h string.h pthread.h limits.h \
 179         signal.h stdlib.h sys/un.h sys/socket.h stdlib.h stdio.h \
 180         getopt.h sys/ipc.h sys/shm.h popt.h grp.h arpa/inet.h \
 181         netdb.h netinet/in.h paths.h stddef.h sys/file.h sys/ioctl.h \
 182         sys/mount.h sys/param.h sys/time.h
 183 ])
 184
 185 # Basic functions check
 186 AC_CHECK_FUNCS([ \
 187         atexit bzero clock_gettime dup2 fdatasync fls ftruncate \
 188         gethostbyname gethostname getpagesize localtime_r memchr memset \
 189         mkdir munmap putenv realpath rmdir socket strchr strcspn strdup \
 190         strncasecmp strndup strnlen strpbrk strrchr strstr strtol strtoul \
 191         strtoull dirfd gethostbyname2 getipnodebyname epoll_create1 \
 192         sched_getcpu sysconf sync_file_range
 193 ])
 194
 195 # Check if clock_gettime, timer_create, timer_settime, and timer_delete are available in lib rt, and if so,
 196 # add -lrt to LIBS
 197 AC_CHECK_LIB([rt], [clock_gettime, timer_create, timer_settime, timer_delete])
 198
 199 # Checks for dl.
 200 AC_CHECK_LIB([dl], [dlopen], [
 201         have_libdl=yes
 202         libdl_name=dl
 203 ], [
 204         # libdl not found, check for dlopen in libc.
 205         AC_CHECK_LIB([c], [dlopen], [
 206                 have_libc_dl=yes
 207                 libdl_name=c
 208         ], [
 209                 AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
 210         ])
 211 ])
 212
 213 # Check if libdl has dlmopen support.
 214 AH_TEMPLATE([HAVE_DLMOPEN], ["Define to 1 if dlmopen is available."])
 215 AC_CHECK_LIB([$libdl_name], [dlmopen], [
 216         AC_DEFINE([HAVE_DLMOPEN], [1])
 217         HAVE_DLMOPEN=1
 218 ], [
 219         HAVE_DLMOPEN=0
 220 ])
 221 AC_SUBST(HAVE_DLMOPEN)
 222
 223 # Babeltrace viewer check
 224 AC_ARG_WITH([babeltrace-bin],
 225         AS_HELP_STRING([--with-babeltrace-bin],
 226         [Location of the babeltrace viewer executable (including the filename)]),
 227         [BABELTRACE_BIN="$withval"],
 228         [BABELTRACE_BIN=''])
 229 AC_SUBST([BABELTRACE_BIN])
 230
 231 # lttv-gui
 232 AC_ARG_WITH([lttv-gui-bin],
 233         AS_HELP_STRING([--with-lttv-gui-bin],
 234    [Location of the lttv GUI viewer executable (including the filename)]),
 235    [LTTV_GUI_BIN="$withval"],
 236    [LTTV_GUI_BIN=''])
 237 AC_SUBST([LTTV_GUI_BIN])
 238
 239 AC_ARG_WITH([consumerd32-bin],
 240         AS_HELP_STRING([--with-consumerd32-bin],
 241         [Location of the 32-bit consumerd executable (including the filename)]),
 242         [CONSUMERD32_BIN="$withval"],
 243         [CONSUMERD32_BIN=''])
 244 AC_SUBST([CONSUMERD32_BIN])
 245
 246 AC_ARG_WITH([consumerd64-bin],
 247         AS_HELP_STRING([--with-consumerd64-bin],
 248         [Location of the 64-bit consumerd executable (including the filename)]),
 249         [CONSUMERD64_BIN="$withval"],
 250         [CONSUMERD64_BIN=''])
 251 AC_SUBST([CONSUMERD64_BIN])
 252
 253 AC_ARG_WITH([consumerd32-libdir],
 254         AS_HELP_STRING([--with-consumerd32-libdir],
 255         [Directory containing the 32-bit consumerd libraries]),
 256         [CONSUMERD32_LIBDIR="$withval"],
 257         [CONSUMERD32_LIBDIR=''])
 258 AC_SUBST([CONSUMERD32_LIBDIR])
 259
 260 AC_ARG_WITH([consumerd64-libdir],
 261         AS_HELP_STRING([--with-consumerd64-libdir],
 262         [Directory containing the 64-bit consumerd libraries]),
 263         [CONSUMERD64_LIBDIR="$withval"],
 264         [CONSUMERD64_LIBDIR=''])
 265 AC_SUBST([CONSUMERD64_LIBDIR])
 266
 267 AC_ARG_WITH([sessiond-bin],
 268         AS_HELP_STRING([--with-sessiond-bin],
 269         [Location of the sessiond executable (including the filename)]),
 270         [SESSIOND_BIN="$withval"],
 271         [SESSIOND_BIN=''])
 272 AC_SUBST([SESSIOND_BIN])
 273
 274 AC_ARG_WITH([lttng-system-rundir],
 275         AS_HELP_STRING([--with-lttng-system-rundir],
 276         [Location of the system directory where the system-wide lttng-sessiond runtime files are kept. The default is "/var/run/lttng".]),
 277         [LTTNG_SYSTEM_RUNDIR="$withval"],
 278         [LTTNG_SYSTEM_RUNDIR="/var/run/lttng"])
 279 AC_SUBST([LTTNG_SYSTEM_RUNDIR])
 280
 281 AC_ARG_ENABLE([test-java-agent-jul],
 282         [AS_HELP_STRING([--enable-test-java-agent-jul],[enable the LTTng UST Java agent JUL tests [default=no]])],
 283         [test_java_agent_jul=$enableval],
 284         [test_java_agent_jul=no]
 285 )
 286
 287 AC_ARG_ENABLE([test-java-agent-log4j],
 288         [AS_HELP_STRING([--enable-test-java-agent-log4j],[enable the LTTng UST Java agent Log4j tests [default=no]])],
 289         [test_java_agent_log4j=$enableval],
 290         [test_java_agent_log4j=no]
 291 )
 292
 293 AC_ARG_ENABLE([test-java-agent-all],
 294         [AS_HELP_STRING([--enable-test-java-agent-all],[enable all the LTTng UST Java agent tests [default=no]])],
 295         [test_java_agent_jul=$enableval
 296          test_java_agent_log4j=$enableval],
 297         [:]
 298 )
 299
 300 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_BIN], "$CONSUMERD32_BIN", [Location of the 32-bit consumerd executable.])
 301 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_BIN], "$CONSUMERD64_BIN", [Location of the 64-bit consumerd executable])
 302 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_LIBDIR], "$CONSUMERD32_LIBDIR", [Search for consumerd 32-bit libraries in this location.])
 303 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_LIBDIR], "$CONSUMERD64_LIBDIR", [Search for consumerd 64-bit libraries in this location.])
 304 AC_DEFINE_UNQUOTED([CONFIG_BABELTRACE_BIN], "$BABELTRACE_BIN", [Location of the babeltrace viewer executable.])
 305 AC_DEFINE_UNQUOTED([CONFIG_LTTV_GUI_BIN], "$LTTV_GUI_BIN", [Location of the lttv GUI viewer executable.])
 306 AC_DEFINE_UNQUOTED([CONFIG_SESSIOND_BIN], "$SESSIOND_BIN", [Location of the sessiond executable.])
 307 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_RUNDIR], ["$LTTNG_SYSTEM_RUNDIR"], [LTTng system runtime directory])
 308
 309 AC_DEFUN([_AC_DEFINE_AND_SUBST], [
 310         AC_DEFINE_UNQUOTED([CONFIG_$1], [$2], [$1])
 311         $1="$2"
 312         AC_SUBST([$1])
 313 ])
 314
 315 AC_DEFUN([_AC_DEFINE_QUOTED_AND_SUBST], [
 316         AC_DEFINE_UNQUOTED([CONFIG_$1], ["$2"], [$1])
 317         $1="$2"
 318         AC_SUBST([$1])
 319 ])
 320
 321 # Default values
 322 m4_define([_DEFAULT_CHANNEL_SUBBUF_SIZE], [16384])
 323 m4_define([_DEFAULT_CHANNEL_SUBBUF_NUM], [4])
 324 m4_define([_DEFAULT_CHANNEL_SWITCH_TIMER], [0])
 325 m4_define([_DEFAULT_CHANNEL_LIVE_TIMER], [0])
 326 m4_define([_DEFAULT_CHANNEL_READ_TIMER], [200000])
 327 m4_define([_DEFAULT_CHANNEL_MONITOR_TIMER], [1000000])
 328 m4_define([_DEFAULT_CHANNEL_BLOCKING_TIMEOUT], [0])
 329 _AC_DEFINE_AND_SUBST([DEFAULT_AGENT_TCP_PORT], [5345])
 330 _AC_DEFINE_AND_SUBST([DEFAULT_APP_SOCKET_RW_TIMEOUT], [5])
 331 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE])
 332 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_COUNT], [0])
 333 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_SIZE], [0])
 334 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 335 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_READ_TIMER], [_DEFAULT_CHANNEL_READ_TIMER])
 336 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 337 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_SIZE], [1048576])
 338 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 339 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
 340 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_BLOCKING_TIMEOUT], [_DEFAULT_CHANNEL_BLOCKING_TIMEOUT])
 341 _AC_DEFINE_AND_SUBST([DEFAULT_LTTNG_LIVE_TIMER], [1000000])
 342 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_CACHE_SIZE], [4096])
 343 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_READ_TIMER], [0])
 344 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_NUM], [2])
 345 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_SIZE], [4096])
 346 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 347 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_CONTROL_PORT], [5342])
 348 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_DATA_PORT], [5343])
 349 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_VIEWER_PORT], [5344])
 350 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 351 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_READ_TIMER], [0])
 352 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_BLOCKING_TIMEOUT], [0])
 353 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 354 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE])
 355 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 356 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
 357 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 358 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_READ_TIMER], [0])
 359 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_BLOCKING_TIMEOUT], [0])
 360 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 361 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_SIZE], [524288])
 362 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 363 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
 364 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_AGENT_BIND_ADDRESS], [localhost])
 365 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_CONTROL_BIND_ADDRESS], [0.0.0.0])
 366 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_DATA_BIND_ADDRESS], [0.0.0.0])
 367 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_VIEWER_BIND_ADDRESS], [localhost])
 368
 369 # Command short descriptions
 370 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ADD_CONTEXT], [Add context fields to a channel])
 371 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_CREATE], [Create a tracing session])
 372 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DESTROY], [Tear down tracing sessions])
 373 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_CHANNEL], [Disable tracing channels])
 374 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_EVENT], [Disable event rules])
 375 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_CHANNEL], [Create or enable tracing channels])
 376 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_EVENT], [Create or enable event rules])
 377 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_HELP], [Display help information about a command])
 378 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LIST], [List tracing sessions, domains, channels, and events])
 379 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LOAD], [Load tracing session configurations])
 380 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_REGENERATE], [Manage an LTTng tracing session's data regeneration])
 381 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SAVE], [Save tracing session configurations])
 382 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SET_SESSION], [Set current tracing session])
 383 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SNAPSHOT], [Snapshot buffers of current tracing session])
 384 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_START], [Start tracing])
 385 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STATUS], [Get the status of the current tracing session])
 386 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STOP], [Stop tracing])
 387 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_TRACK], [Track specific system resources])
 388 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_UNTRACK], [Untrack specific system resources])
 389 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VERSION], [Show version information])
 390 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VIEW], [Start trace viewer])
 391
 392 if test "x$prefix" = "xNONE"; then
 393         prefix=$ac_default_prefix
 394 fi
 395 CONFDIR=`eval echo $sysconfdir`
 396 AC_SUBST(CONFDIR)
 397 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_CONFIGDIR],"$CONFDIR", [LTTng system configuration directory.])
 398
 399 AC_DEFINE_DIR([CONFIG_LTTNG_SYSTEM_DATADIR],[datadir], [LTTng system data directory.])
 400
 401 # Check libpopt
 402 PKG_CHECK_MODULES([POPT], [popt],
 403   [
 404     dnl PKG_CHECK_MODULES defines POPT_LIBS
 405   ],
 406   [
 407     AC_MSG_WARN([pkg-config was unable to find a valid .pc for libpopt. Set PKG_CONFIG_PATH to specify the pkgconfig configuration file location])
 408     AC_MSG_WARN([Finding libpopt without pkg-config.])
 409     AC_CHECK_LIB([popt],
 410       [poptGetContext],
 411       [POPT_LIBS="-lpopt"],
 412       [
 413         AC_MSG_FAILURE([Cannot find libpopt. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location])
 414       ]
 415     )
 416   ]
 417 )
 418 AC_SUBST(POPT_LIBS)
 419
 420 PKG_CHECK_MODULES([libxml2], [libxml-2.0 >= 2.7.6])
 421
 422 # First, check for uuid in system libs
 423 AH_TEMPLATE([LTTNG_HAVE_LIBUUID], [Define if you have libuuid support])
 424 AC_CHECK_FUNCS([uuid_generate],
 425   [
 426     AC_DEFINE([LTTNG_HAVE_LIBUUID], [1])
 427     UUID_LIBS=""
 428   ],
 429   [
 430     # Then, check if the pkg-config module is available, otherwise explicitly check
 431     # for libuuid, or uuid support in the C-library.
 432     PKG_CHECK_MODULES([UUID], [uuid],
 433       [
 434         AC_DEFINE([LTTNG_HAVE_LIBUUID], [1])
 435         dnl PKG_CHECK_MODULES defines UUID_LIBS
 436       ],
 437       [
 438         AC_MSG_WARN([pkg-config was unable to find a valid .pc for libuuid. Set PKG_CONFIG_PATH to specify the pkgconfig configuration file location])
 439         AC_MSG_WARN([Finding libuuid without pkg-config.])
 440         AC_CHECK_LIB([uuid], [uuid_generate],
 441           [
 442             AC_DEFINE([LTTNG_HAVE_LIBUUID], [1])
 443             UUID_LIBS="-luuid"
 444           ],
 445           [
 446             # libuuid not found, check for uuid_create in libc.
 447             AC_CHECK_LIB([c], [uuid_create],
 448               [
 449                 AC_DEFINE([LTTNG_HAVE_LIBUUID], [1])
 450                 UUID_LIBS="-lc"
 451               ],
 452               [
 453                 AC_MSG_FAILURE([Cannot find libuuid uuid_generate nor libc uuid_create. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location])
 454               ]
 455             )
 456           ]
 457         )
 458       ]
 459     )
 460   ]
 461 )
 462 AC_SUBST(UUID_LIBS)
 463
 464 AC_CHECK_FUNC([clock_gettime], [AC_DEFINE_UNQUOTED([LTTNG_HAVE_CLOCK_GETTIME], 1, [Has clock_gettime() support.])])
 465
 466 # URCU library version needed or newer
 467 m4_define([WRONG_LIBURCU_MSG], [Userspace RCU (liburcu) >= 0.9.0 is needed])
 468
 469 # Check liburcu needed function calls
 470 AC_CHECK_DECL([cds_list_add], [],
 471         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/list.h>]])
 472 AC_CHECK_DECL([cds_wfcq_init], [],
 473         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/wfcqueue.h>]])
 474 AC_CHECK_DECL([cds_wfcq_dequeue_blocking], [],
 475         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/wfcqueue.h>]])
 476 AC_CHECK_DECL([futex_async], [],
 477         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/futex.h>]])
 478 AC_CHECK_DECL([rcu_thread_offline], [],
 479         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
 480 AC_CHECK_DECL([rcu_thread_online], [],
 481         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
 482 AC_CHECK_DECL([caa_likely], [],
 483         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
 484 AC_CHECK_LIB([urcu-cds], [_cds_lfht_new], [],
 485         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])])
 486
 487 #Function added in urcu 0.7.0
 488 AC_CHECK_DECL([cmm_smp_mb__before_uatomic_or], [],
 489         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]]
 490 )
 491
 492 #Function added in urcu 0.9.0
 493 AC_CHECK_DECL([urcu_ref_get_unless_zero], [],
 494         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/ref.h>]]
 495 )
 496
 497 # Check for libkmod, it will be auto-neabled if found but won't fail if it's not,
 498 # it can be explicitly disabled with --without-kmod
 499 AH_TEMPLATE([HAVE_KMOD], [Define if you have kmod support])
 500 AC_ARG_WITH([kmod],
 501   [AS_HELP_STRING([--with-kmod], [build with lkmod support @<:@default=check@:>@])],
 502   [],
 503   [with_kmod=check]
 504 )
 505
 506 AS_IF([test "x$with_kmod" != "xno"],
 507   [
 508     AC_CHECK_LIB([kmod], [kmod_module_probe_insert_module],
 509       [
 510         AC_DEFINE([HAVE_KMOD], [1])
 511         KMOD_LIBS="-lkmod"
 512       ],
 513       [
 514         if test "x$with_kmod" != xcheck; then
 515           AC_MSG_FAILURE([Cannot find libkmod. Use [LDFLAGS]=-Ldir and [CPPFLAGS]=-Idir to specify its location.])
 516         else
 517           with_kmod=no
 518         fi
 519       ]
 520     )
 521   ]
 522 )
 523 AC_SUBST(KMOD_LIBS)
 524
 525 # Check for liblttng-ust-ctl, fail if it's not found,
 526 # it can be explicitly disabled with --without-lttng-ust
 527 AH_TEMPLATE([HAVE_LIBLTTNG_UST_CTL], [Define if you have LTTng-UST control support])
 528 AC_ARG_WITH([lttng-ust],
 529   [AS_HELP_STRING([--without-lttng-ust], [build without LTTng-UST (Userspace Tracing) support])],
 530   [],
 531   [with_lttng_ust=yes]
 532 )
 533
 534 AS_IF([test "x$with_lttng_ust" = "xyes"],
 535   [
 536     AC_CHECK_LIB([lttng-ust-ctl], [ustctl_recv_channel_from_consumer],
 537       [
 538         AC_DEFINE([HAVE_LIBLTTNG_UST_CTL], [1])
 539       ],
 540       [
 541         AC_MSG_FAILURE([Cannot find LTTng-UST >= 2.2.x. Use [LDFLAGS]=-Ldir and [CPPFLAGS]=-Idir to specify its location, or specify --without-lttng-ust to build lttng-tools without LTTng-UST support.])
 542       ],
 543       [-lurcu-common -lurcu-bp -lurcu-cds -lrt -ldl]
 544     )
 545   ]
 546 )
 547 AM_CONDITIONAL([HAVE_LIBLTTNG_UST_CTL], [test "x$with_lttng_ust" = "xyes"])
 548
 549
 550
 551 # check for dlopen
 552 AC_CHECK_LIB([dl], [dlopen],
 553   [DL_LIBS="-ldl"],
 554   [
 555     #libdl not found, check for dlopen in libc.
 556     AC_CHECK_LIB([c], [dlopen],
 557       [DL_LIBS="-lc"],
 558       [AC_MSG_FAILURE([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])]
 559     )
 560   ]
 561 )
 562 AC_SUBST(DL_LIBS)
 563
 564 # Check for fmemopen
 565 AC_CHECK_LIB([c], [fmemopen],
 566 [
 567         AC_DEFINE_UNQUOTED([LTTNG_HAVE_FMEMOPEN], 1, [Has fmemopen support.])
 568 ]
 569 )
 570
 571 # Check for open_memstream
 572 AC_CHECK_LIB([c], [open_memstream],
 573 [
 574         AC_DEFINE_UNQUOTED([LTTNG_HAVE_OPEN_MEMSTREAM], 1, [Has open_memstream support.])
 575 ]
 576 )
 577
 578 # check for libpfm
 579 AC_CHECK_LIB([pfm], [pfm_initialize],
 580              [
 581               have_libpfm=yes
 582               ])
 583 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBPFM], [test "x$have_libpfm" = "xyes"])
 584
 585 AC_ARG_ENABLE([git-version],
 586               [AC_HELP_STRING([--disable-git-version],
 587                               [Do not use the git version for the build])],
 588               [have_git_version=$enableval], [have_git_version=yes]
 589 )
 590
 591 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_GIT_SOURCE],
 592         [test "x${have_git_version}" = "xyes"])
 593
 594 # For Python
 595 # SWIG version needed or newer:
 596 swig_version=2.0.0
 597
 598 AC_ARG_ENABLE([python-bindings],
 599               [AC_HELP_STRING([--enable-python-bindings],
 600                               [compile Python bindings])],
 601               [enable_python_binding=$enableval], [enable_python_binding=no])
 602
 603 AM_CONDITIONAL([PYTHON_BINDING], [test "x$enable_python_binding" = xyes])
 604
 605 if test "x$enable_python_binding" = xyes; then
 606   AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ])
 607   AS_IF([test x$enable_shared = xno], [ AC_MSG_ERROR([Python bindings require shared libraries.]) ])
 608   AM_PATH_PYTHON([3.0])
 609
 610   AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config])
 611   AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
 612   AS_IF([test -z "$PYTHON_INCLUDE"], [
 613     AS_IF([test -z "$PYTHON_CONFIG"], [
 614       AC_PATH_PROGS([PYTHON_CONFIG],
 615                     [python$PYTHON_VERSION-config python-config],
 616                     [no],
 617                     [`dirname $PYTHON`])
 618       AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
 619     ])
 620     AC_MSG_CHECKING([python include flags])
 621     PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
 622     AC_MSG_RESULT([$PYTHON_INCLUDE])
 623   ])
 624
 625 else
 626     AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl
 627 [if you want Python bindings.])
 628
 629 fi
 630
 631 # Epoll check. If not present, the build will fallback on poll() API
 632 AX_HAVE_EPOLL(
 633         [AX_CONFIG_FEATURE_ENABLE(epoll)],
 634         [AX_CONFIG_FEATURE_DISABLE(epoll)]
 635 )
 636 AX_CONFIG_FEATURE(
 637         [epoll], [This platform supports epoll(7)],
 638         [HAVE_EPOLL], [This platform supports epoll(7).],
 639         [enable_epoll="yes"], [enable_epoll="no"]
 640 )
 641 AM_CONDITIONAL([COMPAT_EPOLL], [ test "$enable_epoll" = "yes" ])
 642
 643 AM_CONDITIONAL([TEST_JAVA_JUL_AGENT], [test "x$test_java_agent_jul" = "xyes"])
 644 AM_CONDITIONAL([TEST_JAVA_LOG4J_AGENT], [test "x$test_java_agent_log4j" = "xyes"])
 645
 646 if test "x$test_java_agent_jul" = "xyes" || test "x$test_java_agent_log4j" = "xyes"; then
 647         AX_JAVA_OPTIONS
 648         AX_PROG_JAVAC
 649         AX_PROG_JAVA
 650         AX_PROG_JAR
 651
 652         AX_CHECK_CLASSPATH
 653
 654         # Check for Java UST agent common class first
 655         AX_CHECK_CLASS(org.lttng.ust.agent.AbstractLttngAgent)
 656         if test "x$ac_cv_class_org_lttng_ust_agent_AbstractLttngAgent" = "xno"; then
 657                 AC_MSG_ERROR([The UST Java agent common class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-common.jar"])
 658         fi
 659
 660         if test "x$test_java_agent_jul" = "xyes"; then
 661                 # Check for JUL agent class
 662                 AX_CHECK_CLASS(org.lttng.ust.agent.jul.LttngLogHandler)
 663                 if test "x$ac_cv_class_org_lttng_ust_agent_jul_LttngLogHandler" = "xno"; then
 664                         AC_MSG_ERROR([The UST Java agent JUL class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-jul.jar"])
 665                 fi
 666         fi
 667
 668         if test "x$test_java_agent_log4j" = "xyes"; then
 669                 # Check for Log4j agent class
 670                 AX_CHECK_CLASS(org.lttng.ust.agent.log4j.LttngLogAppender)
 671                 if test "x$ac_cv_class_org_lttng_ust_agent_log4j_LttngLogAppender" = "xno"; then
 672                         AC_MSG_ERROR([The UST Java agent Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-log4j.jar"])
 673                 fi
 674
 675                 # Check for Log4j class
 676                 AX_CHECK_CLASS(org.apache.log4j.Logger)
 677                 if test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"; then
 678                         AC_MSG_ERROR([The Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j.jar"])
 679                 fi
 680         fi
 681 fi
 682
 683 # set $IN_GIT_REPO if we're in the Git repository; the `bootstrap` file
 684 # is not distributed in tarballs
 685 AS_IF([test -f "$srcdir/bootstrap"], [in_git_repo=yes], [in_git_repo=no])
 686 AM_CONDITIONAL([IN_GIT_REPO], [test "x$in_git_repo" = "xyes"])
 687
 688 # enable building man pages (user's intention)
 689 AC_ARG_ENABLE(
 690         man-pages,
 691         AS_HELP_STRING(
 692                 [--disable-man-pages],
 693                 [Do not build and install man pages (already built in a distributed tarball)]
 694         ),
 695         [man_pages_opt=$enableval],
 696         [man_pages_opt=yes]
 697 )
 698
 699 # check for asciidoc and xmlto if we enabled building the man pages
 700 have_asciidoc_xmlto=no
 701 warn_prebuilt_man_pages=no
 702
 703 AS_IF([test "x$man_pages_opt" = "xyes"], [
 704         AC_PATH_PROG([ASCIIDOC], [asciidoc], [no])
 705         AC_PATH_PROG([XMLTO], [xmlto], [no])
 706
 707         AS_IF([test "x$ASCIIDOC" = "xno" || test "x$XMLTO" = "xno"], [
 708                 AS_IF([test "x$in_git_repo" = "xyes"], [
 709                         # this is an error because we're in the Git repo, which
 710                         # means the man pages are not already generated for us,
 711                         # thus asciidoc/xmlto are required because we were asked
 712                         # to build the man pages
 713                         AC_MSG_ERROR([
 714 You need asciidoc and xmlto to build the LTTng-tools man pages. Use
 715 --disable-man-pages to disable building the man pages, in which case
 716 they will not be installed.
 717                         ])
 718                 ], [
 719                         # only warn here: since we're in the tarball, the man
 720                         # pages should already be generated at this point, thus
 721                         # asciidoc/xmlto are not strictly required
 722                         warn_prebuilt_man_pages=yes
 723                 ])
 724         ], [
 725                 have_asciidoc_xmlto=yes
 726         ])
 727 ])
 728
 729 # export man page build condition: build the man pages if the user
 730 # asked for it, and if the tools are available
 731 AM_CONDITIONAL([MAN_PAGES_OPT], [test "x$man_pages_opt" != "xno"])
 732 AM_CONDITIONAL([HAVE_ASCIIDOC_XMLTO], [test "x$have_asciidoc_xmlto" = "xyes"])
 733
 734 AC_DEFINE_UNQUOTED([MANPATH], ["`eval eval echo $mandir`"], [Path to man pages.])
 735
 736 # embedded --help message
 737 AC_ARG_ENABLE(
 738         [embedded-help],
 739         AS_HELP_STRING(
 740                 [--enable-embedded-help],
 741                 [Embed the --help messages in the executable files]
 742         ),
 743         [embedded_help=$enableval],
 744         [embedded_help=no]
 745 )
 746 AS_IF([test "x$embedded_help" = "xyes"], [
 747         AS_IF([test "x$man_pages_opt" = "xno"], [
 748                 AC_MSG_ERROR([You need the --enable-man-pages option with the --enable-embedded-help option.])
 749         ])
 750         AC_PATH_PROG([man_prog_path], [man], [no])
 751         AS_IF([test "x$man_prog_path" = "xno"], [
 752                 AC_MSG_ERROR([You need man with the --enable-embedded-help option.])
 753         ])
 754         AC_DEFINE_UNQUOTED([LTTNG_EMBED_HELP], 1, [Embed --help messages.])
 755         AC_SUBST([MANPROG], [$man_prog_path])
 756 ])
 757 AM_CONDITIONAL([EMBED_HELP], [test "x$embedded_help" != "xno"])
 758
 759 # Python agent test
 760 UST_PYTHON_AGENT="lttngust"
 761
 762 AC_ARG_ENABLE(test-python2-agent,
 763         AS_HELP_STRING([--enable-test-python2-agent],
 764                 [enable tests for python2 agent. Python2 interpreter path can be overridden by setting the PYTHON2 environment variable. Default: Autodetect]
 765         ),[:],[test_python2_agent_autodetect=yes]
 766 )
 767
 768 AC_ARG_ENABLE(test-python3-agent,
 769         AS_HELP_STRING([--enable-test-python3-agent],
 770                 [enable tests for python3 agent. Python3 interpreter path can be overridden by setting the PYTHON3 environment variable. Default: Autodetect]
 771         ),[:],[test_python3_agent_autodetect=yes]
 772 )
 773
 774 AC_ARG_ENABLE(test-python-agent-all,
 775         AS_HELP_STRING([--enable-test-python-agent-all],
 776                 [enable test for all python{2/3} agent.]
 777         ),
 778 )
 779
 780 AS_IF([test ! -z "$enable_test_python_agent_all"], [
 781        unset test_python2_agent_autodetect
 782        unset test_python3_agent_autodetect
 783 ])
 784
 785 AS_IF([test "x$enable_test_python_agent_all" = "xyes"], [
 786        enable_test_python2_agent=yes
 787        enable_test_python3_agent=yes
 788 ])
 789
 790 AS_IF([test "x$enable_test_python_agent_all" = "xno"], [
 791        enable_test_python2_agent=no
 792        enable_test_python3_agent=no
 793 ])
 794
 795
 796 AS_IF([test "x$enable_test_python2_agent" = "xyes" -o "x$test_python2_agent_autodetect" = "xyes" ], [
 797         AS_IF([test -z "$PYTHON2"], [
 798                         PYTHON2=python2
 799                 ], [
 800                         AC_MSG_WARN([Using user-defined PYTHON2 ($PYTHON2) for lttng-ust python2 agent check])
 801         ])
 802
 803         AC_PATH_PROG([PYTHON2_BIN],[$PYTHON2])
 804         AS_IF([test -z "$PYTHON2_BIN"], [
 805                 AS_IF([test -z "$test_python2_agent_autodetect"],[
 806                         AC_MSG_ERROR([No python2 interpreter found. PYTHON2 can be set to override default interpreter path])
 807                 ])
 808         ], [
 809                 AC_MSG_CHECKING([for python2 lttng-ust agent])
 810                 AS_IF([$PYTHON2_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
 811                         PYTHON2_AGENT=$PYTHON2_BIN
 812                         AC_MSG_RESULT([yes])
 813                         RUN_PYTHON_AGENT_TEST=yes
 814                 ], [
 815                         AC_MSG_RESULT([no])
 816                         AS_IF([test -z "$test_python2_agent_autodetect"],[
 817                                 AC_MSG_ERROR([No python2 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
 818                         ])
 819                 ])
 820
 821         ])
 822
 823 ])
 824
 825 AS_IF([test "x$enable_test_python3_agent" = "xyes" -o "x$test_python3_agent_autodetect" = "xyes" ], [
 826         AS_IF([test -z "$PYTHON3"], [
 827                 PYTHON3=python3
 828         ], [
 829                 AC_MSG_WARN([Using user-defined PYTHON3 ($PYTHON3) for lttng-ust python3 agent check])
 830         ])
 831
 832         AC_PATH_PROG([PYTHON3_BIN],[$PYTHON3])
 833         AS_IF([test -z "$PYTHON3_BIN"], [
 834                 AS_IF([test -z "$test_python3_agent_autodetect"],[
 835                         AC_MSG_ERROR([No python3 interpreter found. PYTHON3 can be set to override default interpreter path])
 836                 ])
 837         ], [
 838                 AC_MSG_CHECKING([for python3 lttng-ust agent])
 839                 AS_IF([$PYTHON3_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
 840                         PYTHON3_AGENT=$PYTHON3_BIN
 841                         AC_MSG_RESULT([yes])
 842                         RUN_PYTHON_AGENT_TEST=yes
 843                 ], [
 844                         AC_MSG_RESULT([no])
 845                         AS_IF([test -z "$test_python3_agent_autodetect"],[
 846                                 AC_MSG_ERROR([No python3 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
 847                         ])
 848                 ])
 849
 850         ])
 851 ])
 852 AC_SUBST([RUN_PYTHON_AGENT_TEST])
 853 AC_SUBST([PYTHON2_AGENT])
 854 AC_SUBST([PYTHON3_AGENT])
 855
 856 # Arguments for binaries build exclusion
 857 AC_ARG_ENABLE([bin-lttng], AS_HELP_STRING([--disable-bin-lttng],[Disable the build of lttng binaries]))
 858 AC_ARG_ENABLE([bin-lttng-consumerd], AS_HELP_STRING([--disable-bin-lttng-consumerd],
 859               [Disable the build of lttng-consumerd binaries]))
 860 AC_ARG_ENABLE([bin-lttng-crash], AS_HELP_STRING([--disable-bin-lttng-crash],[Disable the build of lttng-crash binaries]))
 861 AC_ARG_ENABLE([bin-lttng-relayd], AS_HELP_STRING([--disable-bin-lttng-relayd],
 862               [Disable the build of lttng-relayd binaries]))
 863 AC_ARG_ENABLE([bin-lttng-sessiond], AS_HELP_STRING([--disable-bin-lttng-sessiond],
 864               [Disable the build of lttng-sessiond binaries]))
 865 AC_ARG_ENABLE([extras], AS_HELP_STRING([--disable-extras],
 866               [Disable the build of the extra components]))
 867
 868
 869 # Always build libconfig since it a dependency of libcommon
 870 build_lib_config=yes
 871
 872 build_lib_compat=no
 873 build_lib_consumer=no
 874 build_lib_hashtable=no
 875 build_lib_health=no
 876 build_lib_index=no
 877 build_lib_kernel_consumer=no
 878 build_lib_kernel_ctl=no
 879 build_lib_lttng_ctl=no
 880 build_lib_relayd=no
 881 build_lib_sessiond_comm=no
 882 build_lib_testpoint=no
 883 build_lib_ust_consumer=no
 884
 885 # There is an overlap for enabled dependencies, but this makes everything
 886 # simpler. libcommon and libconfig are always compiled so they are not repeated
 887 # here.
 888
 889 # Enable binary dependencies.
 890 AS_IF([test x$enable_bin_lttng != xno],
 891       [
 892        build_lib_lttng_ctl=yes
 893       ]
 894 )
 895
 896 AS_IF([test x$enable_bin_lttng_consumerd != xno],
 897       [
 898        build_lib_consumer=yes
 899        build_lib_sessiond_comm=yes
 900        build_lib_index=yes
 901        build_lib_health=yes
 902        build_lib_testpoint=yes
 903       ]
 904 )
 905
 906 AS_IF([test x$enable_bin_lttng_crash != xno],
 907       # Do nothing since libconfig and libcommon are built by default.
 908       []
 909 )
 910
 911 AS_IF([test x$enable_bin_lttng_relayd != xno],
 912       [
 913        build_lib_lttng_ctl=yes
 914        build_lib_sessiond_comm=yes
 915        build_lib_hashtable=yes
 916        build_lib_compat=yes
 917        build_lib_index=yes
 918        build_lib_health=yes
 919        build_lib_testpoint=yes
 920       ]
 921 )
 922 AS_IF([test x$enable_bin_lttng_sessiond != xno],
 923       [
 924        build_lib_lttng_ctl=yes
 925        build_lib_sessiond_comm=yes
 926        build_lib_kernel_ctl=yes
 927        build_lib_hashtable=yes
 928        build_lib_compat=yes
 929        build_lib_relayd=yes
 930        build_lib_testpoint=yes
 931        build_lib_health=yes
 932        build_lib_health=yes
 933       ]
 934 )
 935
 936 # Libraries dependencies enabling
 937 AS_IF([test x$build_lib_lttng_ctl = xyes],
 938       [
 939        build_lib_sessiond_comm=yes
 940        build_lib_hashtable=yes
 941       ]
 942 )
 943
 944 AS_IF([test x$build_lib_consumer = xyes],
 945       [
 946        build_lib_sessiond_comm=yes
 947        build_lib_kernel_consumer=yes
 948        build_lib_hashtable=yes
 949        build_lib_compat=yes
 950        build_lib_relayd=yes
 951        AS_IF([test "x$with_lttng_ust" = "xyes"], [build_lib_ust_consumer=yes])
 952       ]
 953 )
 954
 955 AS_IF([test x$build_lib_kernel_consumer = xyes],
 956       [
 957        build_lib_kernel_ctl=yes
 958        build_lib_relayd=yes
 959       ]
 960 )
 961
 962 AS_IF([test x$build_lib_relayd = xyes],
 963       [
 964        build_lib_sessiond_comm=yes
 965       ]
 966 )
 967
 968
 969 # Export binaries build conditions.
 970 AM_CONDITIONAL([BUILD_BIN_LTTNG], [test x$enable_bin_lttng != xno])
 971 AM_CONDITIONAL([BUILD_BIN_LTTNG_CONSUMERD], [test x$enable_bin_lttng_consumerd != xno])
 972 AM_CONDITIONAL([BUILD_BIN_LTTNG_CRASH], [test x$enable_bin_lttng_crash != xno])
 973 AM_CONDITIONAL([BUILD_BIN_LTTNG_RELAYD], [test x$enable_bin_lttng_relayd != xno])
 974 AM_CONDITIONAL([BUILD_BIN_LTTNG_SESSIOND], [test x$enable_bin_lttng_sessiond != xno])
 975
 976 # Export the tests and extras build conditions.
 977 AS_IF([\
 978 test "x$enable_bin_lttng" != "xno" && \
 979 test "x$enable_bin_lttng_consumerd" != "xno" && \
 980 test "x$enable_bin_lttng_crash" != "xno" && \
 981 test "x$enable_bin_lttng_relayd" != "xno" && \
 982 test "x$enable_bin_lttng_sessiond" != "xno"],
 983 [build_tests=yes],
 984 [build_tests=no]
 985 )
 986
 987 AM_CONDITIONAL([BUILD_TESTS], [test x$build_tests = xyes])
 988 AM_CONDITIONAL([BUILD_EXTRAS], [test x$enable_extras != xno])
 989
 990 # Export libraries build conditions.
 991 AM_CONDITIONAL([BUILD_LIB_COMPAT], [test x$build_lib_compat = xyes])
 992 AM_CONDITIONAL([BUILD_LIB_CONFIG], [test x$build_lib_config = xyes])
 993 AM_CONDITIONAL([BUILD_LIB_CONSUMER], [test x$build_lib_consumer = xyes])
 994 AM_CONDITIONAL([BUILD_LIB_HASHTABLE], [test x$build_lib_hashtable = xyes])
 995 AM_CONDITIONAL([BUILD_LIB_HEALTH], [test x$build_lib_health = xyes])
 996 AM_CONDITIONAL([BUILD_LIB_INDEX], [test x$build_lib_index = xyes])
 997 AM_CONDITIONAL([BUILD_LIB_KERNEL_CONSUMER], [test x$build_lib_kernel_consumer = xyes])
 998 AM_CONDITIONAL([BUILD_LIB_KERNEL_CTL], [test x$build_lib_kernel_ctl = xyes])
 999 AM_CONDITIONAL([BUILD_LIB_LTTNG_CTL], [test x$build_lib_lttng_ctl = xyes])
1000 AM_CONDITIONAL([BUILD_LIB_RELAYD], [test x$build_lib_relayd = xyes])
1001 AM_CONDITIONAL([BUILD_LIB_SESSIOND_COMM], [test x$build_lib_sessiond_comm = xyes])
1002 AM_CONDITIONAL([BUILD_LIB_TESTPOINT], [test x$build_lib_testpoint = xyes])
1003 AM_CONDITIONAL([BUILD_LIB_UST_CONSUMER], [test x$build_lib_ust_consumer = xyes])
1004
1005 AM_CFLAGS="-Wall -fno-strict-aliasing $PTHREAD_CFLAGS"
1006 AC_SUBST(AM_CFLAGS)
1007
1008 AM_CPPFLAGS="-I\$(top_srcdir)/include -I\$(top_builddir)/include -I\$(top_srcdir)/src -include config.h $AM_CPPFLAGS"
1009 AC_SUBST(AM_CPPFLAGS)
1010
1011 lttngincludedir="${includedir}/lttng"
1012 AC_SUBST(lttngincludedir)
1013
1014 lttngactionincludedir="${includedir}/lttng/action"
1015 AC_SUBST(lttngactionincludedir)
1016
1017 lttngconditionincludedir="${includedir}/lttng/condition"
1018 AC_SUBST(lttngconditionincludedir)
1019
1020 lttngnotificationincludedir="${includedir}/lttng/notification"
1021 AC_SUBST(lttngnotificationincludedir)
1022
1023 lttngtriggerincludedir="${includedir}/lttng/trigger"
1024 AC_SUBST(lttngtriggerincludedir)
1025
1026 lttnglibexecdir="${libdir}/lttng/libexec"
1027 AC_SUBST(lttnglibexecdir)
1028
1029 AC_CONFIG_FILES([
1030         Makefile
1031         doc/Makefile
1032         doc/man/Makefile
1033         doc/man/asciidoc-attrs.conf
1034         include/Makefile
1035         extras/Makefile
1036         extras/bindings/Makefile
1037         extras/bindings/swig/Makefile
1038         extras/bindings/swig/python/Makefile
1039         extras/core-handler/Makefile
1040         src/Makefile
1041         src/common/Makefile
1042         src/common/kernel-ctl/Makefile
1043         src/common/kernel-consumer/Makefile
1044         src/common/consumer/Makefile
1045         src/common/ust-consumer/Makefile
1046         src/common/hashtable/Makefile
1047         src/common/sessiond-comm/Makefile
1048         src/common/compat/Makefile
1049         src/common/relayd/Makefile
1050         src/common/testpoint/Makefile
1051         src/common/index/Makefile
1052         src/common/health/Makefile
1053         src/common/config/Makefile
1054         src/common/string-utils/Makefile
1055         src/lib/Makefile
1056         src/lib/lttng-ctl/Makefile
1057         src/lib/lttng-ctl/filter/Makefile
1058         src/lib/lttng-ctl/lttng-ctl.pc
1059         src/bin/Makefile
1060         src/bin/lttng-consumerd/Makefile
1061         src/bin/lttng-sessiond/Makefile
1062         src/bin/lttng-relayd/Makefile
1063         src/bin/lttng/Makefile
1064         src/bin/lttng-crash/Makefile
1065         tests/Makefile
1066         tests/destructive/Makefile
1067         tests/regression/Makefile
1068         tests/regression/kernel/Makefile
1069         tests/regression/tools/Makefile
1070         tests/regression/tools/streaming/Makefile
1071         tests/regression/tools/filtering/Makefile
1072         tests/regression/tools/health/Makefile
1073         tests/regression/tools/tracefile-limits/Makefile
1074         tests/regression/tools/snapshots/Makefile
1075         tests/regression/tools/live/Makefile
1076         tests/regression/tools/exclusion/Makefile
1077         tests/regression/tools/save-load/Makefile
1078         tests/regression/tools/save-load/configuration/Makefile
1079         tests/regression/tools/mi/Makefile
1080         tests/regression/tools/wildcard/Makefile
1081         tests/regression/tools/crash/Makefile
1082         tests/regression/tools/regen-metadata/Makefile
1083         tests/regression/tools/regen-statedump/Makefile
1084         tests/regression/tools/notification/Makefile
1085         tests/regression/ust/Makefile
1086         tests/regression/ust/nprocesses/Makefile
1087         tests/regression/ust/high-throughput/Makefile
1088         tests/regression/ust/low-throughput/Makefile
1089         tests/regression/ust/before-after/Makefile
1090         tests/regression/ust/buffers-pid/Makefile
1091         tests/regression/ust/periodical-metadata-flush/Makefile
1092         tests/regression/ust/multi-session/Makefile
1093         tests/regression/ust/overlap/Makefile
1094         tests/regression/ust/overlap/demo/Makefile
1095         tests/regression/ust/linking/Makefile
1096         tests/regression/ust/daemon/Makefile
1097         tests/regression/ust/exit-fast/Makefile
1098         tests/regression/ust/fork/Makefile
1099         tests/regression/ust/libc-wrapper/Makefile
1100         tests/regression/ust/baddr-statedump/Makefile
1101         tests/regression/ust/ust-dl/Makefile
1102         tests/regression/ust/java-jul/Makefile
1103         tests/regression/ust/java-log4j/Makefile
1104         tests/regression/ust/python-logging/Makefile
1105         tests/regression/ust/getcpu-override/Makefile
1106         tests/regression/ust/clock-override/Makefile
1107         tests/regression/ust/type-declarations/Makefile
1108         tests/regression/ust/rotation-destroy-flush/Makefile
1109         tests/regression/ust/blocking/Makefile
1110         tests/stress/Makefile
1111         tests/unit/Makefile
1112         tests/unit/ini_config/Makefile
1113         tests/perf/Makefile
1114         tests/utils/Makefile
1115         tests/utils/tap/Makefile
1116         tests/utils/testapp/Makefile
1117         tests/utils/testapp/gen-ust-events/Makefile
1118         tests/utils/testapp/gen-ust-nevents/Makefile
1119         tests/utils/testapp/gen-ust-nevents-str/Makefile
1120         tests/utils/testapp/gen-ust-tracef/Makefile
1121 ])
1122
1123 # Inject variable into python test script.
1124 AC_CONFIG_FILES([tests/regression/ust/python-logging/test_python_logging],[chmod +x tests/regression/ust/python-logging/test_python_logging])
1125 # Inject LTTNG_TOOLS_BUILD_WITH_LIBPFM variable in test script.
1126 AC_CONFIG_FILES([tests/perf/test_perf_raw],[chmod +x tests/perf/test_perf_raw])
1127 AC_CONFIG_FILES([tests/regression/ust/ust-dl/test_ust-dl],[chmod +x tests/regression/ust/ust-dl/test_ust-dl])
1128
1129 AC_OUTPUT
1130
1131 #
1132 # Mini-report on what will be built.
1133 #
1134
1135 PPRINT_INIT
1136 PPRINT_SET_INDENT(1)
1137 PPRINT_SET_TS(38)
1138
1139 AS_ECHO
1140 AS_ECHO("${PPRINT_COLOR_BLDBLU}LTTng-tools $PACKAGE_VERSION \"$version_name\"$PPRINT_COLOR_RST")
1141 AS_ECHO
1142
1143 AS_IF([test -n "$report_fold"], [
1144         AS_ECHO("`AS_ECHO("$version_description") | $report_fold -s`")
1145 ], [
1146         AS_ECHO("$version_description")
1147 ])
1148
1149 AS_ECHO
1150 PPRINT_SUBTITLE([Features])
1151
1152 # Target architecture we're building for.
1153 target_arch=$host_cpu
1154 [
1155 for f in $CFLAGS; do
1156         if test $f = "-m32"; then
1157                         target_arch="32-bit"
1158         elif test $f = "-m64"; then
1159                         target_arch="64-bit"
1160         fi
1161 done
1162 ]
1163 PPRINT_PROP_STRING([Target architecture], $target_arch)
1164
1165 # kmod enabled/disabled
1166 test "x$with_kmod" != "xno" && value=1 || value=0
1167 PPRINT_PROP_BOOL([libkmod support], $value)
1168
1169 # LTTng-UST enabled/disabled
1170 test "x$with_lttng_ust" = "xyes" && value=1 || value=0
1171 PPRINT_PROP_BOOL([LTTng-UST support], $value)
1172
1173 AS_ECHO
1174 PPRINT_SUBTITLE([Binaries])
1175
1176 # List binaries to be built
1177 test x$enable_bin_lttng != xno && value=1 || value=0
1178 PPRINT_PROP_BOOL([lttng], $value)
1179
1180 test x$enable_bin_lttng_consumerd != xno && value=1 || value=0
1181 PPRINT_PROP_BOOL([lttng-consumerd], $value)
1182
1183 test x$enable_bin_lttng_crash != xno && value=1 || value=0
1184 PPRINT_PROP_BOOL([lttng-crash], $value)
1185
1186 test x$enable_bin_lttng_relayd != xno && value=1 || value=0
1187 PPRINT_PROP_BOOL([lttng-relayd], $value)
1188
1189 test x$enable_bin_lttng_sessiond != xno && value=1 || value=0
1190 PPRINT_PROP_BOOL([lttng-sessiond], $value)
1191
1192 # Extras
1193 test x$enable_extras != xno && value=1 || value=0
1194 AS_ECHO
1195 PPRINT_SET_INDENT(0)
1196 PPRINT_PROP_BOOL([Extras], $value, $PPRINT_COLOR_SUBTITLE)
1197 PPRINT_SET_INDENT(1)
1198
1199 AS_ECHO
1200 PPRINT_SUBTITLE([Tests])
1201
1202 # Print clear message that tests won't be built
1203 AS_IF([test "x$build_tests" = "xno"],[
1204         PPRINT_WARN([Tests won't be built since some binaries were disabled])
1205 ])
1206
1207 # LTTng UST Java agent JUL tests enabled/disabled
1208 test "x$test_java_agent_jul" = "xyes" && value=1 || value=0
1209 PPRINT_PROP_BOOL([LTTng-UST Java agent JUL tests], $value)
1210
1211 # LTTng UST Java agent Log4j tests enabled/disabled
1212 test "x$test_java_agent_log4j" = "xyes" && value=1 || value=0
1213 PPRINT_PROP_BOOL([LTTng-UST Java agent Log4j tests], $value)
1214
1215 test ! -z "$PYTHON2_AGENT" && value=1 || value=0
1216 PPRINT_PROP_BOOL([LTTng-UST Python2 agent tests], $value)
1217
1218 test ! -z "$PYTHON3_AGENT" && value=1 || value=0
1219 PPRINT_PROP_BOOL([LTTng-UST Python3 agent tests], $value)
1220
1221 #Python binding enabled/disabled
1222 test "x$enable_python_binding" = xyes && value=1 || value=0
1223 AS_ECHO
1224 PPRINT_SET_INDENT(0)
1225 PPRINT_PROP_BOOL([Python binding], $value, $PPRINT_COLOR_SUBTITLE)
1226
1227 # man pages build enabled/disabled
1228 m4_pushdef([build_man_pages_msg], [Build and install man pages])
1229
1230 AS_IF([test "x$man_pages_opt" != "xno"], [
1231         AS_IF([test "x$in_git_repo" = "xyes"], [
1232                 PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
1233         ], [
1234                 AS_IF([test "x$have_asciidoc_xmlto" = "xyes"], [
1235                         PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
1236                 ], [
1237                         PPRINT_PROP_STRING([build_man_pages_msg],
1238                                 [${PPRINT_COLOR_BLDGRN}yes (already built)],
1239                                 $PPRINT_COLOR_SUBTITLE)
1240                 ])
1241         ])
1242 ], [
1243         PPRINT_PROP_BOOL([build_man_pages_msg], 0, $PPRINT_COLOR_SUBTITLE)
1244 ])
1245
1246 m4_popdef([build_man_pages_msg])
1247
1248 test "x$embedded_help" = xyes && value=1 || value=0
1249 PPRINT_PROP_BOOL([Embed --help messages], $value, $PPRINT_COLOR_SUBTITLE)
1250
1251 PPRINT_SET_INDENT(1)
1252
1253 report_bindir="`eval eval echo $bindir`"
1254 report_libdir="`eval eval echo $libdir`"
1255
1256 # Print the bindir and libdir this `make install' will install into.
1257 AS_ECHO
1258 PPRINT_SUBTITLE([Install directories])
1259 PPRINT_PROP_STRING([Binaries], [$report_bindir])
1260 PPRINT_PROP_STRING([Libraries], [$report_libdir])
1261
1262 AS_ECHO
1263 PPRINT_SUBTITLE([Search directories])
1264
1265 # If we build the sessiond, print the paths it will use
1266 AS_IF([test "$SESSIOND_BIN" = ""],[
1267         path="$report_bindir/lttng-sessiond"
1268 ],[
1269         path="$SESSIOND_BIN"
1270 ])
1271 PPRINT_PROP_STRING([lttng-sessiond executable], [$path])
1272
1273 AS_IF([test "$CONSUMERD32_BIN" = ""],[
1274         path="`eval eval echo $lttnglibexecdir`/lttng-consumerd"
1275 ],[
1276         path="$CONSUMERD32_BIN"
1277 ])
1278 PPRINT_PROP_STRING([32-bit lttng-consumerd executable], [$path])
1279
1280 AS_IF([test "$CONSUMERD32_LIBDIR" = ""],[
1281         path="`eval eval echo $libdir`"
1282 ],[
1283         path="$CONSUMERD32_LIBDIR"
1284 ])
1285 PPRINT_PROP_STRING([32-bit consumer libraries], [$path])
1286
1287 AS_IF([test "$CONSUMERD64_BIN" = ""],[
1288         path="`eval eval echo $lttnglibexecdir`/lttng-consumerd"
1289 ],[
1290         path="$CONSUMERD64_BIN"
1291 ])
1292 PPRINT_PROP_STRING([64-bit lttng-consumerd executable], [$path])
1293
1294 AS_IF([test "$CONSUMERD64_LIBDIR" = ""],[
1295         path="`eval eval echo $libdir`"
1296 ],[
1297         path="$CONSUMERD64_LIBDIR"
1298 ])
1299 PPRINT_PROP_STRING([64-bit consumer libraries], [$path])
1300 PPRINT_SET_INDENT(0)
1301
1302 AS_IF([test "x$warn_prebuilt_man_pages" = "xyes" ], [
1303         AS_ECHO
1304         PPRINT_WARN([You need asciidoc and xmlto to build the LTTng-tools man pages.
1305
1306 Note that the man pages are already built in this distribution tarball,
1307 therefore asciidoc and xmlto are only needed if you intend to modify
1308 their sources.
1309
1310 Also note that the installed man pages will contain the project's
1311 default command-line option and environment variable values.
1312
1313 Use --disable-man-pages to completely disable building and installing
1314 the man pages.])
1315 ])