configure.ac

   1 dnl SPDX-License-Identifier: GPL-2.0-only
   2 AC_PREREQ([2.64])
   3 AC_INIT([lttng-tools],[2.12.0-rc1],[jeremie.galarneau@efficios.com],[],[https://lttng.org])
   4
   5 AC_CONFIG_HEADERS([include/config.h])
   6 AC_CONFIG_AUX_DIR([config])
   7 AC_CONFIG_MACRO_DIR([m4])
   8
   9 AC_CANONICAL_TARGET
  10 AC_CANONICAL_HOST
  11
  12 AM_INIT_AUTOMAKE([1.12 foreign dist-bzip2 no-dist-gzip tar-pax nostdinc])
  13 AM_MAINTAINER_MODE([enable])
  14
  15 # Enable silent rules if available (Introduced in AM 1.11)
  16 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  17
  18 AC_REQUIRE_AUX_FILE([tap-driver.sh])
  19
  20 # Checks for C compiler
  21 AC_USE_SYSTEM_EXTENSIONS
  22 AC_SYS_LARGEFILE
  23 AC_PROG_CC
  24 AC_PROG_CC_STDC
  25 AC_PROG_CXX
  26 RW_PROG_CXX_WORKS
  27 AM_CONDITIONAL([CXX_WORKS], [test "x$rw_cv_prog_cxx_works" = "xyes"])
  28
  29 # Detect warning flags supported by the compiler, append them to WARN_CFLAGS.
  30 #
  31 # Pass -Werror as an extra flag during the test: this is needed to make the
  32 # -Wunknown-warning-option diagnostic fatal with clang.
  33 AX_APPEND_COMPILE_FLAGS([ dnl
  34                 -Wall dnl
  35                 dnl We currently get this warning when building with Clang:
  36                 dnl
  37                 dnl /usr/include/setjmp.h:54:12: error: declaration of built-in function '__sigsetjmp' requires the declaration of the 'jmp_buf' type, commonly provided in the header <setjmp.h>. [-Werror,-Wincomplete-setjmp-declaration]
  38                 dnl extern int __sigsetjmp (struct __jmp_buf_tag __env[1], int __savemask) __THROWNL;
  39                 dnl            ^
  40                 -Wno-incomplete-setjmp-declaration dnl
  41                 -Wdiscarded-qualifiers dnl
  42         ],
  43         [WARN_CFLAGS],
  44         [-Werror])
  45
  46 # When given, add -Werror to WARN_CFLAGS.
  47 AC_ARG_ENABLE([Werror],
  48         [AS_HELP_STRING([--enable-Werror], [Treat compiler warnings as errors.])]
  49 )
  50 AS_IF([test "x$enable_Werror" = "xyes"],
  51         [WARN_CFLAGS="${WARN_CFLAGS} -Werror"]
  52 )
  53
  54 # Checks for programs.
  55 AC_PROG_GREP
  56 AC_PROG_MAKE_SET
  57 AC_PROG_SED
  58 AC_PATH_PROG([report_fold], [fold])
  59 LT_INIT
  60
  61 # Check for objcopy, required by the base address statedump and dynamic linker tests
  62 AC_CHECK_TOOL([OBJCOPY], [objcopy], [no])
  63 AS_IF([test "x$OBJCOPY" = "xno"],
  64         [AC_MSG_WARN([Cannot find objcopy. The base address statedump and dynamic linker tests will be disabled. Install the binutils package to remediate this.])]
  65 )
  66 AM_CONDITIONAL([HAVE_OBJCOPY], [test "x$OBJCOPY" != xno])
  67
  68 # check for pgrep
  69 AC_PATH_PROG([PGREP], [pgrep], [no])
  70 AM_CONDITIONAL([HAVE_PGREP], [test "x$PGREP" != "xno"])
  71
  72 # set $IN_GIT_REPO if we're in the Git repository; the `bootstrap` file
  73 # is not distributed in tarballs
  74 AS_IF([test -f "$srcdir/bootstrap"], [in_git_repo=yes], [in_git_repo=no])
  75 AM_CONDITIONAL([IN_GIT_REPO], [test "x$in_git_repo" = "xyes"])
  76
  77 # check for bison
  78 AC_PROG_YACC
  79 BISON=$YACC
  80 AX_PROG_BISON_VERSION([2.4], [have_bison=yes])
  81
  82 AS_IF([test "x$have_bison" != "xyes"], [
  83   AS_IF([test "x$in_git_repo" = "xyes"], [
  84     AC_MSG_FAILURE([
  85 Bison >= 2.4 is required when building from the Git repository. You can
  86 set the YACC variable to override automatic detection.
  87     ])
  88   ], [
  89     AC_MSG_WARN([
  90 Missing Bison >= 2.4. Note that the parser files are already built in
  91 this distribution tarball, so Bison is only needed if you intend to
  92 modify their sources. You can set the YACC variable to override automatic
  93 detection.
  94     ])
  95   ])
  96 ])
  97 AM_CONDITIONAL([HAVE_BISON], [test "x$have_bison" = "xyes"])
  98
  99 # check for flex
 100 AC_PROG_LEX
 101 FLEX=$LEX
 102 AX_PROG_FLEX_VERSION([2.5.35], [have_flex=yes])
 103
 104 AS_IF([test "x$have_flex" != "xyes"], [
 105   AS_IF([test "x$in_git_repo" = "xyes"], [
 106     AC_MSG_FAILURE([
 107 Flex >= 2.5.35 is required when building from the Git repository. You can
 108 set the LEX variable to override automatic detection.
 109     ])
 110   ], [
 111     AC_MSG_WARN([
 112 Missing Flex >= 2.5.35. Note that the lexer files are already built in
 113 this distribution tarball, so Flex is only needed if you intend to
 114 modify their sources. You can set the LEX variable to override automatic
 115 detection.
 116     ])
 117   ])
 118 ])
 119 AM_CONDITIONAL([HAVE_FLEX], [test "x$have_flex" = "xyes"])
 120
 121
 122 # Checks for typedefs, structures, and compiler characteristics.
 123 AC_C_INLINE
 124 AC_TYPE_INT32_T
 125 AC_TYPE_INT64_T
 126 AC_TYPE_MODE_T
 127 AC_TYPE_OFF_T
 128 AC_TYPE_PID_T
 129 AC_TYPE_SIZE_T
 130 AC_TYPE_SSIZE_T
 131 AC_TYPE_UID_T
 132 AC_TYPE_UINT16_T
 133 AC_TYPE_UINT32_T
 134 AC_TYPE_UINT64_T
 135 AC_TYPE_UINT8_T
 136
 137 AX_C___ATTRIBUTE__
 138 AS_IF([test "x$ax_cv___attribute__" = "xyes"],
 139         [:],
 140         [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
 141
 142 AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])
 143
 144 # Check if linker has the -no-pie option.
 145 AX_CHECK_LINK_FLAG([-no-pie], [linker_have_no_pie_option=yes])
 146 AM_CONDITIONAL([LINKER_HAVE_NO_PIE_OPTION], [test "x$linker_have_no_pie_option" = "xyes"])
 147
 148 AX_LIB_SOCKET_NSL
 149
 150 LT_NO_UNDEFINED=""
 151 AS_CASE([$host_os],
 152   [cygwin*],
 153     [
 154       LT_NO_UNDEFINED="-no-undefined"
 155     ],
 156   [cygwin*|darwin*|mingw*|solaris*],
 157     [
 158       # On platforms where we only support the relayd, disable the other binaries by default
 159       AS_IF([test "x$enable_bin_lttng" = "x" ], [enable_bin_lttng=no])
 160       AS_IF([test "x$enable_bin_lttng_consumerd" = "x" ], [enable_bin_lttng_consumerd=no])
 161       AS_IF([test "x$enable_bin_lttng_crash" = "x" ], [enable_bin_lttng_crash=no])
 162       AS_IF([test "x$enable_bin_lttng_sessiond" = "x" ], [enable_bin_lttng_sessiond=no])
 163       AS_IF([test "x$enable_extras" = "x" ], [enable_extras=no])
 164       AS_IF([test "x$with_lttng_ust" = "x" ], [with_lttng_ust=no])
 165     ]
 166 )
 167
 168 AC_SUBST(LT_NO_UNDEFINED)
 169
 170 # Compute minor/major/patchlevel version numbers
 171 major_version=$(echo AC_PACKAGE_VERSION | $SED 's/^\([[0-9]]\)*\.[[0-9]]*\.[[0-9]]*.*$/\1/')
 172 minor_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.\([[0-9]]*\)\.[[0-9]]*.*$/\1/')
 173 patchlevel_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\).*$/\1/')
 174
 175 AC_SUBST([MAJOR_VERSION], [$major_version])
 176 AC_SUBST([MINOR_VERSION], [$minor_version])
 177 AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version])
 178 AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [LTTng-Tools major version number])
 179 AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [LTTng-Tools minor version number])
 180 AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [LTTng-Tools patchlevel version number])
 181
 182 version_name="(Ta) Meilleure"
 183 version_description="Ta Meilleure is a Northeast IPA beer brewed by Lagabière. Translating to \"Your best one\", this beer gives out strong aromas of passion fruit, lemon, and peaches. Tastewise, expect a lot of fruit, a creamy texture, and a smooth lingering hop bitterness."
 184 version_description_c=$(echo $version_description | $SED 's/"/\\"/g')
 185
 186 AC_DEFINE_UNQUOTED([VERSION_NAME], ["$version_name"], "")
 187 AC_DEFINE_UNQUOTED([VERSION_DESCRIPTION], ["$version_description_c"], "")
 188
 189 # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
 190 AC_ARG_ENABLE(libtool-linkdep-fixup,
 191         AS_HELP_STRING([--disable-libtool-linkdep-fixup],
 192                         [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)]),
 193         libtool_fixup=$enableval,
 194         libtool_fixup=yes)
 195
 196 AS_IF([test "x$libtool_fixup" = "xyes"],
 197             [
 198             libtool_m4="$srcdir/m4/libtool.m4"
 199             libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
 200             AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
 201             libtool_flag_pattern_count=$($GREP -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
 202             AS_IF([test $libtool_flag_pattern_count -ne 0],
 203             [
 204                   AC_MSG_RESULT([$libtool_flag_pattern_count])
 205                   AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
 206                   $SED -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
 207                   ],
 208                   [
 209                   AC_MSG_RESULT([none])
 210                   ])
 211             ])
 212
 213 AM_CONDITIONAL([NO_SHARED], [test x$enable_shared = xno])
 214
 215 AC_CHECK_HEADERS([ \
 216         sys/types.h unistd.h fcntl.h string.h pthread.h limits.h \
 217         signal.h stdlib.h sys/un.h sys/socket.h stdlib.h stdio.h \
 218         getopt.h sys/ipc.h sys/shm.h popt.h grp.h arpa/inet.h \
 219         netdb.h netinet/in.h paths.h stddef.h sys/file.h sys/ioctl.h \
 220         sys/mount.h sys/param.h sys/time.h elf.h
 221 ])
 222
 223 AM_CONDITIONAL([HAVE_ELF_H], [test x$ac_cv_header_elf_h = xyes])
 224
 225 # Basic functions check
 226 AC_CHECK_FUNCS([ \
 227         atexit bzero clock_gettime dup2 fdatasync fls ftruncate \
 228         gethostbyname gethostname getpagesize localtime_r memchr memrchr memset \
 229         mkdir munmap putenv realpath rmdir socket strchr strcspn strdup \
 230         strncasecmp strndup strnlen strpbrk strrchr strstr strtol strtoul \
 231         strtoull dirfd gethostbyname2 getipnodebyname epoll_create1 \
 232         sched_getcpu sysconf sync_file_range
 233 ])
 234
 235 # Check if clock_gettime, timer_create, timer_settime, and timer_delete are available in lib rt, and if so,
 236 # add -lrt to LIBS
 237 AC_CHECK_LIB([rt], [clock_gettime, timer_create, timer_settime, timer_delete])
 238
 239 # Checks for dl.
 240 AC_CHECK_LIB([dl], [dlopen], [
 241         have_libdl=yes
 242         libdl_name=dl
 243         DL_LIBS="-ldl"
 244 ], [
 245         # libdl not found, check for dlopen in libc.
 246         AC_CHECK_LIB([c], [dlopen], [
 247                 have_libc_dl=yes
 248                 libdl_name=c
 249                 DL_LIBS="-lc"
 250         ], [
 251                 AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
 252         ])
 253 ])
 254 AC_SUBST(DL_LIBS)
 255
 256 # Check if libdl has dlmopen support.
 257 AH_TEMPLATE([HAVE_DLMOPEN], ["Define to 1 if dlmopen is available."])
 258 AC_CHECK_LIB([$libdl_name], [dlmopen], [
 259         AC_DEFINE([HAVE_DLMOPEN], [1])
 260         HAVE_DLMOPEN=1
 261 ], [
 262         HAVE_DLMOPEN=0
 263 ])
 264 AC_SUBST(HAVE_DLMOPEN)
 265
 266 # Babeltrace viewer check
 267 AC_ARG_WITH([babeltrace-bin],
 268         AS_HELP_STRING([--with-babeltrace-bin],
 269         [Location of the babeltrace viewer executable (including the filename)]),
 270         [BABELTRACE_BIN="$withval"],
 271         [BABELTRACE_BIN=''])
 272 AC_SUBST([BABELTRACE_BIN])
 273
 274 AC_ARG_WITH([babeltrace2-bin],
 275         AS_HELP_STRING([--with-babeltrace2-bin],
 276         [Location of the babeltrace2 viewer executable (including the filename)]),
 277         [BABELTRACE2_BIN="$withval"],
 278         [BABELTRACE2_BIN=''])
 279 AC_SUBST([BABELTRACE2_BIN])
 280
 281 AC_ARG_WITH([consumerd32-bin],
 282         AS_HELP_STRING([--with-consumerd32-bin],
 283         [Location of the 32-bit consumerd executable (including the filename)]),
 284         [CONSUMERD32_BIN="$withval"],
 285         [CONSUMERD32_BIN=''])
 286 AC_SUBST([CONSUMERD32_BIN])
 287
 288 AC_ARG_WITH([consumerd64-bin],
 289         AS_HELP_STRING([--with-consumerd64-bin],
 290         [Location of the 64-bit consumerd executable (including the filename)]),
 291         [CONSUMERD64_BIN="$withval"],
 292         [CONSUMERD64_BIN=''])
 293 AC_SUBST([CONSUMERD64_BIN])
 294
 295 AC_ARG_WITH([consumerd32-libdir],
 296         AS_HELP_STRING([--with-consumerd32-libdir],
 297         [Directory containing the 32-bit consumerd libraries]),
 298         [CONSUMERD32_LIBDIR="$withval"],
 299         [CONSUMERD32_LIBDIR=''])
 300 AC_SUBST([CONSUMERD32_LIBDIR])
 301
 302 AC_ARG_WITH([consumerd64-libdir],
 303         AS_HELP_STRING([--with-consumerd64-libdir],
 304         [Directory containing the 64-bit consumerd libraries]),
 305         [CONSUMERD64_LIBDIR="$withval"],
 306         [CONSUMERD64_LIBDIR=''])
 307 AC_SUBST([CONSUMERD64_LIBDIR])
 308
 309 AC_ARG_WITH([sessiond-bin],
 310         AS_HELP_STRING([--with-sessiond-bin],
 311         [Location of the sessiond executable (including the filename)]),
 312         [SESSIOND_BIN="$withval"],
 313         [SESSIOND_BIN=''])
 314 AC_SUBST([SESSIOND_BIN])
 315
 316 AC_ARG_WITH([lttng-system-rundir],
 317         AS_HELP_STRING([--with-lttng-system-rundir],
 318         [Location of the system directory where the system-wide lttng-sessiond runtime files are kept. The default is "/var/run/lttng".]),
 319         [LTTNG_SYSTEM_RUNDIR="$withval"],
 320         [LTTNG_SYSTEM_RUNDIR="/var/run/lttng"])
 321 AC_SUBST([LTTNG_SYSTEM_RUNDIR])
 322
 323 AC_ARG_ENABLE([test-java-agent-jul],
 324         [AS_HELP_STRING([--enable-test-java-agent-jul],[enable the LTTng UST Java agent JUL tests [default=no]])],
 325         [test_java_agent_jul=$enableval],
 326         [test_java_agent_jul=no]
 327 )
 328
 329 AC_ARG_ENABLE([test-java-agent-log4j],
 330         [AS_HELP_STRING([--enable-test-java-agent-log4j],[enable the LTTng UST Java agent Log4j tests [default=no]])],
 331         [test_java_agent_log4j=$enableval],
 332         [test_java_agent_log4j=no]
 333 )
 334
 335 AC_ARG_ENABLE([test-java-agent-all],
 336         [AS_HELP_STRING([--enable-test-java-agent-all],[enable all the LTTng UST Java agent tests [default=no]])],
 337         [test_java_agent_jul=$enableval
 338          test_java_agent_log4j=$enableval],
 339         [:]
 340 )
 341
 342 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_BIN], "$CONSUMERD32_BIN", [Location of the 32-bit consumerd executable.])
 343 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_BIN], "$CONSUMERD64_BIN", [Location of the 64-bit consumerd executable])
 344 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_LIBDIR], "$CONSUMERD32_LIBDIR", [Search for consumerd 32-bit libraries in this location.])
 345 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_LIBDIR], "$CONSUMERD64_LIBDIR", [Search for consumerd 64-bit libraries in this location.])
 346 AC_DEFINE_UNQUOTED([CONFIG_BABELTRACE_BIN], "$BABELTRACE_BIN", [Location of the babeltrace viewer executable.])
 347 AC_DEFINE_UNQUOTED([CONFIG_BABELTRACE2_BIN], "$BABELTRACE2_BIN", [Location of the babeltrace2 viewer executable.])
 348 AC_DEFINE_UNQUOTED([CONFIG_SESSIOND_BIN], "$SESSIOND_BIN", [Location of the sessiond executable.])
 349 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_RUNDIR], ["$LTTNG_SYSTEM_RUNDIR"], [LTTng system runtime directory])
 350
 351 AC_DEFUN([_AC_DEFINE_AND_SUBST], [
 352         AC_DEFINE_UNQUOTED([CONFIG_$1], [$2], [$1])
 353         $1="$2"
 354         AC_SUBST([$1])
 355 ])
 356
 357 AC_DEFUN([_AC_DEFINE_QUOTED_AND_SUBST], [
 358         AC_DEFINE_UNQUOTED([CONFIG_$1], ["$2"], [$1])
 359         $1="$2"
 360         AC_SUBST([$1])
 361 ])
 362
 363 # Default values
 364 m4_define([_DEFAULT_CHANNEL_SUBBUF_SIZE], [16384])
 365 m4_define([_DEFAULT_CHANNEL_SUBBUF_NUM], [4])
 366 m4_define([_DEFAULT_CHANNEL_SWITCH_TIMER], [0])
 367 m4_define([_DEFAULT_CHANNEL_LIVE_TIMER], [0])
 368 m4_define([_DEFAULT_CHANNEL_READ_TIMER], [200000])
 369 m4_define([_DEFAULT_CHANNEL_MONITOR_TIMER], [1000000])
 370 m4_define([_DEFAULT_CHANNEL_BLOCKING_TIMEOUT], [0])
 371 _AC_DEFINE_AND_SUBST([DEFAULT_AGENT_TCP_PORT_RANGE_BEGIN], [5345])
 372 _AC_DEFINE_AND_SUBST([DEFAULT_AGENT_TCP_PORT_RANGE_END], [5354])
 373 _AC_DEFINE_AND_SUBST([DEFAULT_APP_SOCKET_RW_TIMEOUT], [5])
 374 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE])
 375 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_COUNT], [0])
 376 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_SIZE], [0])
 377 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 378 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_READ_TIMER], [_DEFAULT_CHANNEL_READ_TIMER])
 379 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 380 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_SIZE], [1048576])
 381 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 382 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
 383 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_BLOCKING_TIMEOUT], [_DEFAULT_CHANNEL_BLOCKING_TIMEOUT])
 384 _AC_DEFINE_AND_SUBST([DEFAULT_LTTNG_LIVE_TIMER], [1000000])
 385 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_CACHE_SIZE], [4096])
 386 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_READ_TIMER], [0])
 387 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_NUM], [2])
 388 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_SIZE], [4096])
 389 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 390 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_CONTROL_PORT], [5342])
 391 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_DATA_PORT], [5343])
 392 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_VIEWER_PORT], [5344])
 393 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 394 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_READ_TIMER], [0])
 395 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_BLOCKING_TIMEOUT], [0])
 396 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 397 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE])
 398 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 399 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
 400 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 401 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_READ_TIMER], [0])
 402 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_BLOCKING_TIMEOUT], [0])
 403 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 404 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_SIZE], [524288])
 405 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 406 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
 407 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_AGENT_BIND_ADDRESS], [localhost])
 408 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_CONTROL_BIND_ADDRESS], [0.0.0.0])
 409 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_DATA_BIND_ADDRESS], [0.0.0.0])
 410 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_VIEWER_BIND_ADDRESS], [localhost])
 411 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_RELAYD_CTRL_MAX_PAYLOAD_SIZE], [134217728])
 412 _AC_DEFINE_AND_SUBST([DEFAULT_ROTATE_PENDING_TIMER], [500000])
 413
 414 # Command short descriptions
 415 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ADD_CONTEXT], [Add context fields to a channel])
 416 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_CREATE], [Create a tracing session])
 417 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_CLEAR], [Clear a tracing session])
 418 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DESTROY], [Tear down tracing sessions])
 419 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_CHANNEL], [Disable tracing channels])
 420 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_EVENT], [Disable event rules])
 421 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_ROTATION], [Unset a rotation schedule])
 422 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_CHANNEL], [Create or enable tracing channels])
 423 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_EVENT], [Create or enable event rules])
 424 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_ROTATION], [Set a rotation schedule])
 425 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_HELP], [Display help information about a command])
 426 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LIST], [List tracing sessions, domains, channels, and events])
 427 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LOAD], [Load tracing session configurations])
 428 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_REGENERATE], [Manage an LTTng tracing session's data regeneration])
 429 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ROTATE], [Archive a tracing session's current trace chunk])
 430 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SAVE], [Save tracing session configurations])
 431 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SET_SESSION], [Set current tracing session])
 432 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SNAPSHOT], [Snapshot buffers of current tracing session])
 433 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_START], [Start tracing])
 434 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STATUS], [Get the status of the current tracing session])
 435 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STOP], [Stop tracing])
 436 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_ROTATION], [Unset a rotation schedule])
 437 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_ROTATION], [Set a rotation schedule])
 438 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_TRACK], [Track specific system resources])
 439 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_UNTRACK], [Untrack specific system resources])
 440 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VERSION], [Show version information])
 441 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VIEW], [Start trace viewer])
 442
 443 if test "x$prefix" = "xNONE"; then
 444         prefix=$ac_default_prefix
 445 fi
 446 CONFDIR=`eval echo $sysconfdir`
 447 AC_SUBST(CONFDIR)
 448 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_CONFIGDIR],"$CONFDIR", [LTTng system configuration directory.])
 449
 450 AX_DEFINE_DIR([CONFIG_LTTNG_SYSTEM_DATADIR], [datadir], [LTTng system data directory.])
 451
 452 # Check libpopt
 453 PKG_CHECK_MODULES([POPT], [popt],
 454   [
 455     dnl PKG_CHECK_MODULES defines POPT_LIBS
 456   ],
 457   [
 458     AC_MSG_WARN([pkg-config was unable to find a valid .pc for libpopt. Set PKG_CONFIG_PATH to specify the pkgconfig configuration file location])
 459     AC_MSG_WARN([Finding libpopt without pkg-config.])
 460     AC_CHECK_LIB([popt],
 461       [poptGetContext],
 462       [POPT_LIBS="-lpopt"],
 463       [
 464         AC_MSG_FAILURE([Cannot find libpopt. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location])
 465       ]
 466     )
 467   ]
 468 )
 469 AC_SUBST(POPT_LIBS)
 470
 471 PKG_CHECK_MODULES([libxml2], [libxml-2.0 >= 2.7.6])
 472
 473 AC_CHECK_FUNC([clock_gettime], [AC_DEFINE_UNQUOTED([LTTNG_HAVE_CLOCK_GETTIME], 1, [Has clock_gettime() support.])])
 474
 475 # URCU library version needed or newer
 476 m4_define([WRONG_LIBURCU_MSG], [Userspace RCU (liburcu) >= 0.9.0 is needed])
 477
 478 # Check liburcu needed function calls
 479 AC_CHECK_DECL([cds_list_add], [],
 480         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/list.h>]])
 481 AC_CHECK_DECL([cds_wfcq_init], [],
 482         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/wfcqueue.h>]])
 483 AC_CHECK_DECL([cds_wfcq_dequeue_blocking], [],
 484         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/wfcqueue.h>]])
 485 AC_CHECK_DECL([futex_async], [],
 486         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/futex.h>]])
 487 AC_CHECK_DECL([rcu_thread_offline], [],
 488         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
 489 AC_CHECK_DECL([rcu_thread_online], [],
 490         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
 491 AC_CHECK_DECL([caa_likely], [],
 492         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
 493 AC_CHECK_LIB([urcu-cds], [_cds_lfht_new], [],
 494         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])])
 495
 496 #Function added in urcu 0.7.0
 497 AC_CHECK_DECL([cmm_smp_mb__before_uatomic_or], [],
 498         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]]
 499 )
 500
 501 #Function added in urcu 0.9.0
 502 AC_CHECK_DECL([urcu_ref_get_unless_zero], [],
 503         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/ref.h>]]
 504 )
 505
 506 # Check for libkmod, it will be auto-neabled if found but won't fail if it's not,
 507 # it can be explicitly disabled with --without-kmod
 508 AH_TEMPLATE([HAVE_KMOD], [Define if you have kmod support])
 509 AC_ARG_WITH([kmod],
 510   [AS_HELP_STRING([--with-kmod], [build with lkmod support @<:@default=check@:>@])],
 511   [],
 512   [with_kmod=check]
 513 )
 514
 515 AS_IF([test "x$with_kmod" != "xno"],
 516   [
 517     AC_CHECK_LIB([kmod], [kmod_module_probe_insert_module],
 518       [
 519         AC_DEFINE([HAVE_KMOD], [1])
 520         KMOD_LIBS="-lkmod"
 521       ],
 522       [
 523         if test "x$with_kmod" != xcheck; then
 524           AC_MSG_FAILURE([Cannot find libkmod. Use [LDFLAGS]=-Ldir and [CPPFLAGS]=-Idir to specify its location.])
 525         else
 526           with_kmod=no
 527         fi
 528       ]
 529     )
 530   ]
 531 )
 532 AC_SUBST(KMOD_LIBS)
 533
 534 # Check for liblttng-ust-ctl, fail if it's not found,
 535 # it can be explicitly disabled with --without-lttng-ust
 536 AH_TEMPLATE([HAVE_LIBLTTNG_UST_CTL], [Define if you have LTTng-UST control support])
 537 AC_ARG_WITH([lttng-ust],
 538   [AS_HELP_STRING([--without-lttng-ust], [build without LTTng-UST (Userspace Tracing) support])],
 539   [],
 540   [with_lttng_ust=yes]
 541 )
 542
 543 AS_IF([test "x$with_lttng_ust" = "xyes"], [
 544   AC_DEFINE([HAVE_LIBLTTNG_UST_CTL], [1])
 545
 546   # Check for liblttng-ust
 547   PKG_CHECK_MODULES([UST], [lttng-ust >= $major_version.$minor_version])
 548
 549   # Check for liblttng-ust-ctl
 550   PKG_CHECK_MODULES([UST_CTL], [lttng-ust-ctl >= $major_version.$minor_version])
 551
 552   AM_CPPFLAGS="$AM_CPPFLAGS $UST_CFLAGS"
 553 ])
 554
 555 AM_CONDITIONAL([HAVE_LIBLTTNG_UST_CTL], [test "x$with_lttng_ust" = "xyes"])
 556
 557
 558 # Check for fmemopen
 559 AC_CHECK_LIB([c], [fmemopen],
 560 [
 561         AC_DEFINE_UNQUOTED([LTTNG_HAVE_FMEMOPEN], 1, [Has fmemopen support.])
 562 ]
 563 )
 564
 565 # check for libpfm
 566 AC_CHECK_LIB([pfm], [pfm_initialize],
 567              [
 568               have_libpfm=yes
 569               ])
 570 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBPFM], [test "x$have_libpfm" = "xyes"])
 571
 572 # For Python
 573 # SWIG version needed or newer:
 574 swig_version=2.0.0
 575
 576 AC_ARG_ENABLE([python-bindings],
 577               [AC_HELP_STRING([--enable-python-bindings],
 578                               [compile Python bindings])],
 579               [enable_python_binding=$enableval], [enable_python_binding=no])
 580
 581 AM_CONDITIONAL([PYTHON_BINDING], [test "x$enable_python_binding" = xyes])
 582
 583 if test "x$enable_python_binding" = xyes; then
 584   AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ])
 585   AS_IF([test x$enable_shared = xno], [ AC_MSG_ERROR([Python bindings require shared libraries.]) ])
 586   AM_PATH_PYTHON([3.0])
 587
 588   AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config])
 589   AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
 590   AS_IF([test -z "$PYTHON_INCLUDE"], [
 591     AS_IF([test -z "$PYTHON_CONFIG"], [
 592       AC_PATH_PROGS([PYTHON_CONFIG],
 593                     [python$PYTHON_VERSION-config python-config],
 594                     [no],
 595                     [`dirname $PYTHON`])
 596       AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
 597     ])
 598     AC_MSG_CHECKING([python include flags])
 599     PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
 600     AC_MSG_RESULT([$PYTHON_INCLUDE])
 601   ])
 602
 603 else
 604     AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl
 605 [if you want Python bindings.])
 606
 607 fi
 608
 609 # Epoll check. If not present, the build will fallback on poll() API
 610 AX_HAVE_EPOLL(
 611         [AX_CONFIG_FEATURE_ENABLE(epoll)],
 612         [AX_CONFIG_FEATURE_DISABLE(epoll)]
 613 )
 614 AX_CONFIG_FEATURE(
 615         [epoll], [This platform supports epoll(7)],
 616         [HAVE_EPOLL], [This platform supports epoll(7).],
 617         [enable_epoll="yes"], [enable_epoll="no"]
 618 )
 619 AM_CONDITIONAL([COMPAT_EPOLL], [ test "$enable_epoll" = "yes" ])
 620
 621 AS_IF([test "x$ac_cv_func_dirfd" = "xyes"],
 622         [AX_CONFIG_FEATURE_ENABLE(dirfd)],
 623         [AX_CONFIG_FEATURE_DISABLE(dirfd)]
 624 )
 625 AX_CONFIG_FEATURE(
 626         [dirfd], [Use directory file descriptors],
 627         [COMPAT_DIRFD], [This platform supports directory file descriptors.],
 628         [enable_dirfd="yes"], [enable_dirfd="no"]
 629 )
 630 AM_CONDITIONAL([COMPAT_DIRFD], [ test "$enable_dirfd" = "yes" ])
 631
 632 AM_CONDITIONAL([TEST_JAVA_JUL_AGENT], [test "x$test_java_agent_jul" = "xyes"])
 633 AM_CONDITIONAL([TEST_JAVA_LOG4J_AGENT], [test "x$test_java_agent_log4j" = "xyes"])
 634
 635 if test "x$test_java_agent_jul" = "xyes" || test "x$test_java_agent_log4j" = "xyes"; then
 636         AX_JAVA_OPTIONS
 637         AX_PROG_JAVAC
 638         AX_PROG_JAVA
 639         AX_PROG_JAR
 640
 641         AX_CHECK_CLASSPATH
 642
 643         # Check for Java UST agent common class first
 644         AX_CHECK_CLASS(org.lttng.ust.agent.AbstractLttngAgent)
 645         if test "x$ac_cv_class_org_lttng_ust_agent_AbstractLttngAgent" = "xno"; then
 646                 AC_MSG_ERROR([The UST Java agent common class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-common.jar"])
 647         fi
 648
 649         if test "x$test_java_agent_jul" = "xyes"; then
 650                 # Check for JUL agent class
 651                 AX_CHECK_CLASS(org.lttng.ust.agent.jul.LttngLogHandler)
 652                 if test "x$ac_cv_class_org_lttng_ust_agent_jul_LttngLogHandler" = "xno"; then
 653                         AC_MSG_ERROR([The UST Java agent JUL class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-jul.jar"])
 654                 fi
 655         fi
 656
 657         if test "x$test_java_agent_log4j" = "xyes"; then
 658                 # Check for Log4j agent class
 659                 AX_CHECK_CLASS(org.lttng.ust.agent.log4j.LttngLogAppender)
 660                 if test "x$ac_cv_class_org_lttng_ust_agent_log4j_LttngLogAppender" = "xno"; then
 661                         AC_MSG_ERROR([The UST Java agent Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-log4j.jar"])
 662                 fi
 663
 664                 # Check for Log4j class
 665                 AX_CHECK_CLASS(org.apache.log4j.Logger)
 666                 if test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"; then
 667                         AC_MSG_ERROR([The Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j.jar"])
 668                 fi
 669         fi
 670 fi
 671
 672 # enable building man pages (user's intention)
 673 AC_ARG_ENABLE(
 674         man-pages,
 675         AS_HELP_STRING(
 676                 [--disable-man-pages],
 677                 [Do not build and install man pages (already built in a distributed tarball)]
 678         ),
 679         [man_pages_opt=$enableval],
 680         [man_pages_opt=yes]
 681 )
 682
 683 # check for asciidoc and xmlto if we enabled building the man pages
 684 have_asciidoc_xmlto=no
 685 warn_prebuilt_man_pages=no
 686
 687 AS_IF([test "x$man_pages_opt" = "xyes"], [
 688         AC_PATH_PROG([ASCIIDOC], [asciidoc], [no])
 689         AC_PATH_PROG([XMLTO], [xmlto], [no])
 690
 691         AS_IF([test "x$ASCIIDOC" = "xno" || test "x$XMLTO" = "xno"], [
 692                 AS_IF([test "x$in_git_repo" = "xyes"], [
 693                         # this is an error because we're in the Git repo, which
 694                         # means the man pages are not already generated for us,
 695                         # thus asciidoc/xmlto are required because we were asked
 696                         # to build the man pages
 697                         AC_MSG_ERROR([
 698 You need asciidoc and xmlto to build the LTTng-tools man pages. Use
 699 --disable-man-pages to disable building the man pages, in which case
 700 they will not be installed.
 701                         ])
 702                 ], [
 703                         # only warn here: since we're in the tarball, the man
 704                         # pages should already be generated at this point, thus
 705                         # asciidoc/xmlto are not strictly required
 706                         warn_prebuilt_man_pages=yes
 707                 ])
 708         ], [
 709                 have_asciidoc_xmlto=yes
 710         ])
 711 ])
 712
 713 # export man page build condition: build the man pages if the user
 714 # asked for it, and if the tools are available
 715 AM_CONDITIONAL([MAN_PAGES_OPT], [test "x$man_pages_opt" != "xno"])
 716 AM_CONDITIONAL([HAVE_ASCIIDOC_XMLTO], [test "x$have_asciidoc_xmlto" = "xyes"])
 717
 718 AC_DEFINE_UNQUOTED([MANPATH], ["`eval eval echo $mandir`"], [Path to man pages.])
 719
 720 # embedded --help message
 721 AC_ARG_ENABLE(
 722         [embedded-help],
 723         AS_HELP_STRING(
 724                 [--enable-embedded-help],
 725                 [Embed the --help messages in the executable files]
 726         ),
 727         [embedded_help=$enableval],
 728         [embedded_help=no]
 729 )
 730 AS_IF([test "x$embedded_help" = "xyes"], [
 731         AS_IF([test "x$man_pages_opt" = "xno"], [
 732                 AC_MSG_ERROR([You need the --enable-man-pages option with the --enable-embedded-help option.])
 733         ])
 734         AC_PATH_PROG([man_prog_path], [man], [no])
 735         AS_IF([test "x$man_prog_path" = "xno"], [
 736                 AC_MSG_ERROR([You need man with the --enable-embedded-help option.])
 737         ])
 738         AC_DEFINE_UNQUOTED([LTTNG_EMBED_HELP], 1, [Embed --help messages.])
 739         AC_SUBST([MANPROG], [$man_prog_path])
 740 ])
 741 AM_CONDITIONAL([EMBED_HELP], [test "x$embedded_help" != "xno"])
 742
 743 # Python agent test
 744 UST_PYTHON_AGENT="lttngust"
 745
 746 AC_ARG_ENABLE(test-python2-agent,
 747         AS_HELP_STRING([--enable-test-python2-agent],
 748                 [enable tests for python2 agent. Python2 interpreter path can be overridden by setting the PYTHON2 environment variable. Default: Autodetect]
 749         ),[:],[test_python2_agent_autodetect=yes]
 750 )
 751
 752 AC_ARG_ENABLE(test-python3-agent,
 753         AS_HELP_STRING([--enable-test-python3-agent],
 754                 [enable tests for python3 agent. Python3 interpreter path can be overridden by setting the PYTHON3 environment variable. Default: Autodetect]
 755         ),[:],[test_python3_agent_autodetect=yes]
 756 )
 757
 758 AC_ARG_ENABLE(test-python-agent-all,
 759         AS_HELP_STRING([--enable-test-python-agent-all],
 760                 [enable test for all python{2/3} agent.]
 761         ),
 762 )
 763
 764 AS_IF([test ! -z "$enable_test_python_agent_all"], [
 765        unset test_python2_agent_autodetect
 766        unset test_python3_agent_autodetect
 767 ])
 768
 769 AS_IF([test "x$enable_test_python_agent_all" = "xyes"], [
 770        enable_test_python2_agent=yes
 771        enable_test_python3_agent=yes
 772 ])
 773
 774 AS_IF([test "x$enable_test_python_agent_all" = "xno"], [
 775        enable_test_python2_agent=no
 776        enable_test_python3_agent=no
 777 ])
 778
 779
 780 AS_IF([test "x$enable_test_python2_agent" = "xyes" -o "x$test_python2_agent_autodetect" = "xyes" ], [
 781         AS_IF([test -z "$PYTHON2"], [
 782                         PYTHON2=python2
 783                 ], [
 784                         AC_MSG_WARN([Using user-defined PYTHON2 ($PYTHON2) for lttng-ust python2 agent check])
 785         ])
 786
 787         AC_PATH_PROG([PYTHON2_BIN],[$PYTHON2])
 788         AS_IF([test -z "$PYTHON2_BIN"], [
 789                 AS_IF([test -z "$test_python2_agent_autodetect"],[
 790                         AC_MSG_ERROR([No python2 interpreter found. PYTHON2 can be set to override default interpreter path])
 791                 ])
 792         ], [
 793                 AC_MSG_CHECKING([for python2 lttng-ust agent])
 794                 AS_IF([$PYTHON2_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
 795                         PYTHON2_AGENT=$PYTHON2_BIN
 796                         AC_MSG_RESULT([yes])
 797                         RUN_PYTHON_AGENT_TEST=yes
 798                 ], [
 799                         AC_MSG_RESULT([no])
 800                         AS_IF([test -z "$test_python2_agent_autodetect"],[
 801                                 AC_MSG_ERROR([No python2 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
 802                         ])
 803                 ])
 804
 805         ])
 806
 807 ])
 808
 809 AS_IF([test "x$enable_test_python3_agent" = "xyes" -o "x$test_python3_agent_autodetect" = "xyes" ], [
 810         AS_IF([test -z "$PYTHON3"], [
 811                 PYTHON3=python3
 812         ], [
 813                 AC_MSG_WARN([Using user-defined PYTHON3 ($PYTHON3) for lttng-ust python3 agent check])
 814         ])
 815
 816         AC_PATH_PROG([PYTHON3_BIN],[$PYTHON3])
 817         AS_IF([test -z "$PYTHON3_BIN"], [
 818                 AS_IF([test -z "$test_python3_agent_autodetect"],[
 819                         AC_MSG_ERROR([No python3 interpreter found. PYTHON3 can be set to override default interpreter path])
 820                 ])
 821         ], [
 822                 AC_MSG_CHECKING([for python3 lttng-ust agent])
 823                 AS_IF([$PYTHON3_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
 824                         PYTHON3_AGENT=$PYTHON3_BIN
 825                         AC_MSG_RESULT([yes])
 826                         RUN_PYTHON_AGENT_TEST=yes
 827                 ], [
 828                         AC_MSG_RESULT([no])
 829                         AS_IF([test -z "$test_python3_agent_autodetect"],[
 830                                 AC_MSG_ERROR([No python3 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
 831                         ])
 832                 ])
 833
 834         ])
 835 ])
 836 AC_SUBST([RUN_PYTHON_AGENT_TEST])
 837 AC_SUBST([PYTHON2_AGENT])
 838 AC_SUBST([PYTHON3_AGENT])
 839
 840 AC_ARG_ENABLE([test-sdt-uprobe],
 841   [AS_HELP_STRING([--enable-test-sdt-uprobe], [enable the LTTng UST SDT uprobe tests [default=autodetect]])],
 842   [test_sdt_uprobe="$enableval"],
 843   [test_sdt_uprobe=autodetect]
 844 )
 845
 846 AS_IF([test "$test_sdt_uprobe" != "no"], [
 847   LTTNG_CHECK_SDT_WORKS
 848   AC_PATH_PROG([DTRACE], [dtrace])
 849 ])
 850
 851 AS_IF([test "$test_sdt_uprobe" = "yes"], [
 852   AS_IF([test "$lttng_cv_sdt_works" = "no"], [
 853     AC_MSG_ERROR([Cannot find 'sys/sdt.h'.])
 854   ])
 855   AS_IF([test "x$DTRACE" = "x"], [
 856     AC_MSG_ERROR([Cannot find SystemTap dtrace. You can set the DTRACE variable to override automatic detection.])
 857   ])
 858 ])
 859
 860 AS_IF([test "$test_sdt_uprobe" = "autodetect"], [
 861   AS_IF([test "$lttng_cv_sdt_works" = "yes"], [
 862     AS_IF([test "x$DTRACE" != "x"], [
 863       test_sdt_uprobe=yes
 864     ])
 865   ])
 866 ])
 867
 868 AM_CONDITIONAL([TEST_SDT_UPROBE], [test "$test_sdt_uprobe" = "yes"])
 869
 870 # Arguments for binaries build exclusion
 871 AC_ARG_ENABLE([bin-lttng], AS_HELP_STRING([--disable-bin-lttng],[Disable the build of lttng binaries]))
 872 AC_ARG_ENABLE([bin-lttng-consumerd], AS_HELP_STRING([--disable-bin-lttng-consumerd],
 873               [Disable the build of lttng-consumerd binaries]))
 874 AC_ARG_ENABLE([bin-lttng-crash], AS_HELP_STRING([--disable-bin-lttng-crash],[Disable the build of lttng-crash binaries]))
 875 AC_ARG_ENABLE([bin-lttng-relayd], AS_HELP_STRING([--disable-bin-lttng-relayd],
 876               [Disable the build of lttng-relayd binaries]))
 877 AC_ARG_ENABLE([bin-lttng-sessiond], AS_HELP_STRING([--disable-bin-lttng-sessiond],
 878               [Disable the build of lttng-sessiond binaries]))
 879 AC_ARG_ENABLE([extras], AS_HELP_STRING([--disable-extras],
 880               [Disable the build of the extra components]))
 881
 882
 883 # Always build libconfig since it a dependency of libcommon
 884 build_lib_config=yes
 885
 886 build_lib_compat=no
 887 build_lib_consumer=no
 888 build_lib_hashtable=no
 889 build_lib_health=no
 890 build_lib_index=no
 891 build_lib_kernel_consumer=no
 892 build_lib_kernel_ctl=no
 893 build_lib_lttng_ctl=no
 894 build_lib_relayd=no
 895 build_lib_fd_tracker=no
 896 build_lib_sessiond_comm=no
 897 build_lib_testpoint=no
 898 build_lib_ust_consumer=no
 899
 900 # There is an overlap for enabled dependencies, but this makes everything
 901 # simpler. libcommon and libconfig are always compiled so they are not repeated
 902 # here.
 903
 904 # Enable binary dependencies.
 905 AS_IF([test x$enable_bin_lttng != xno],
 906       [
 907        build_lib_lttng_ctl=yes
 908       ]
 909 )
 910
 911 AS_IF([test x$enable_bin_lttng_consumerd != xno],
 912       [
 913        build_lib_consumer=yes
 914        build_lib_sessiond_comm=yes
 915        build_lib_index=yes
 916        build_lib_health=yes
 917        build_lib_testpoint=yes
 918       ]
 919 )
 920
 921 AS_IF([test x$enable_bin_lttng_crash != xno],
 922       # Do nothing since libconfig and libcommon are built by default.
 923       []
 924 )
 925
 926 AS_IF([test x$enable_bin_lttng_relayd != xno],
 927       [
 928        build_lib_lttng_ctl=yes
 929        build_lib_sessiond_comm=yes
 930        build_lib_hashtable=yes
 931        build_lib_compat=yes
 932        build_lib_index=yes
 933        build_lib_health=yes
 934        build_lib_testpoint=yes
 935        build_lib_fd_tracker=yes
 936       ]
 937 )
 938 AS_IF([test x$enable_bin_lttng_sessiond != xno],
 939       [
 940        build_lib_lttng_ctl=yes
 941        build_lib_sessiond_comm=yes
 942        build_lib_kernel_ctl=yes
 943        build_lib_hashtable=yes
 944        build_lib_compat=yes
 945        build_lib_relayd=yes
 946        build_lib_testpoint=yes
 947        build_lib_health=yes
 948       ]
 949 )
 950
 951 # Libraries dependencies enabling
 952 AS_IF([test x$build_lib_lttng_ctl = xyes],
 953       [
 954        build_lib_sessiond_comm=yes
 955        build_lib_hashtable=yes
 956       ]
 957 )
 958
 959 AS_IF([test x$build_lib_consumer = xyes],
 960       [
 961        build_lib_sessiond_comm=yes
 962        build_lib_kernel_consumer=yes
 963        build_lib_hashtable=yes
 964        build_lib_compat=yes
 965        build_lib_relayd=yes
 966        AS_IF([test "x$with_lttng_ust" = "xyes"], [build_lib_ust_consumer=yes])
 967       ]
 968 )
 969
 970 AS_IF([test x$build_lib_kernel_consumer = xyes],
 971       [
 972        build_lib_kernel_ctl=yes
 973        build_lib_relayd=yes
 974       ]
 975 )
 976
 977 AS_IF([test x$build_lib_relayd = xyes],
 978       [
 979        build_lib_sessiond_comm=yes
 980       ]
 981 )
 982
 983 # Find arch type
 984 AS_CASE([$host_cpu],
 985         [k1om], [ARCHTYPE="x86"],
 986         [i386], [ARCHTYPE="x86"],
 987         [i486], [ARCHTYPE="x86"],
 988         [i586], [ARCHTYPE="x86"],
 989         [i686], [ARCHTYPE="x86"],
 990         [amd64], [ARCHTYPE="x86"],
 991         [x86_64], [ARCHTYPE="x86"],
 992         [powerpc], [ARCHTYPE="ppc"],
 993         [ppc64], [ARCHTYPE="ppc"],
 994         [powerpc64], [ARCHTYPE="ppc"],
 995         [powerpc64le], [ARCHTYPE="ppc"],
 996         [ppc], [ARCHTYPE="ppc"],
 997         [s390], [ARCHTYPE="s390"],
 998         [s390x], [ARCHTYPE="s390"],
 999         [sparc], [ARCHTYPE="sparc64"],
1000         [sparc64], [ARCHTYPE="sparc64"],
1001         [alpha*], [ARCHTYPE="alpha"],
1002         [ia64], [ARCHTYPE="ia64"],
1003         [arm*], [ARCHTYPE="arm"],
1004         [aarch64*], [ARCHTYPE="aarch64"],
1005         [mips*], [ARCHTYPE="mips"],
1006         [nios2*], [ARCHTYPE="nios2"],
1007         [tile*], [ARCHTYPE="tile"],
1008         [hppa*], [ARCHTYPE="hppa"],
1009         [m68k], [ARCHTYPE="m68k"],
1010         [riscv*], [ARCHTYPE="riscv"],
1011         [ARCHTYPE="unknown"]
1012 )
1013
1014 AC_SUBST(ARCHTYPE)
1015
1016 AH_TEMPLATE([HAVE_MODULES_USERSPACE_CALLSTACK_CONTEXT], [Define if you have LTTng-modules userspace callstack tracing support])
1017 AC_MSG_CHECKING([for architecture support of userspace callstack tracing from the kernel])
1018 AS_IF([test "x$ARCHTYPE" = "xx86"],[
1019         # Userspace callstack capture is only supported by the Linux kernel on x86.
1020         AC_MSG_RESULT([yes])
1021         have_modules_userspace_callstack_context=yes
1022         AC_DEFINE([HAVE_MODULES_USERSPACE_CALLSTACK_CONTEXT], [1])
1023 ], [
1024         AC_MSG_RESULT([no])
1025         have_modules_userspace_callstack_context=no
1026 ])
1027 AM_CONDITIONAL([HAVE_MODULES_USERSPACE_CALLSTACK_CONTEXT], [test x$have_modules_userspace_callstack_context != xno])
1028
1029 # Export binaries build conditions.
1030 AM_CONDITIONAL([BUILD_BIN_LTTNG], [test x$enable_bin_lttng != xno])
1031 AM_CONDITIONAL([BUILD_BIN_LTTNG_CONSUMERD], [test x$enable_bin_lttng_consumerd != xno])
1032 AM_CONDITIONAL([BUILD_BIN_LTTNG_CRASH], [test x$enable_bin_lttng_crash != xno])
1033 AM_CONDITIONAL([BUILD_BIN_LTTNG_RELAYD], [test x$enable_bin_lttng_relayd != xno])
1034 AM_CONDITIONAL([BUILD_BIN_LTTNG_SESSIOND], [test x$enable_bin_lttng_sessiond != xno])
1035
1036 # Export the tests and extras build conditions.
1037 AS_IF([\
1038 test "x$enable_bin_lttng" != "xno" && \
1039 test "x$enable_bin_lttng_consumerd" != "xno" && \
1040 test "x$enable_bin_lttng_crash" != "xno" && \
1041 test "x$enable_bin_lttng_relayd" != "xno" && \
1042 test "x$enable_bin_lttng_sessiond" != "xno"],
1043 [build_tests=yes],
1044 [build_tests=no]
1045 )
1046
1047 AM_CONDITIONAL([BUILD_TESTS], [test x$build_tests = xyes])
1048 AM_CONDITIONAL([BUILD_EXTRAS], [test x$enable_extras != xno])
1049
1050 # Export libraries build conditions.
1051 AM_CONDITIONAL([BUILD_LIB_COMPAT], [test x$build_lib_compat = xyes])
1052 AM_CONDITIONAL([BUILD_LIB_CONFIG], [test x$build_lib_config = xyes])
1053 AM_CONDITIONAL([BUILD_LIB_CONSUMER], [test x$build_lib_consumer = xyes])
1054 AM_CONDITIONAL([BUILD_LIB_HASHTABLE], [test x$build_lib_hashtable = xyes])
1055 AM_CONDITIONAL([BUILD_LIB_HEALTH], [test x$build_lib_health = xyes])
1056 AM_CONDITIONAL([BUILD_LIB_INDEX], [test x$build_lib_index = xyes])
1057 AM_CONDITIONAL([BUILD_LIB_KERNEL_CONSUMER], [test x$build_lib_kernel_consumer = xyes])
1058 AM_CONDITIONAL([BUILD_LIB_KERNEL_CTL], [test x$build_lib_kernel_ctl = xyes])
1059 AM_CONDITIONAL([BUILD_LIB_LTTNG_CTL], [test x$build_lib_lttng_ctl = xyes])
1060 AM_CONDITIONAL([BUILD_LIB_RELAYD], [test x$build_lib_relayd = xyes])
1061 AM_CONDITIONAL([BUILD_LIB_FD_TRACKER], [test x$build_lib_fd_tracker = xyes])
1062 AM_CONDITIONAL([BUILD_LIB_SESSIOND_COMM], [test x$build_lib_sessiond_comm = xyes])
1063 AM_CONDITIONAL([BUILD_LIB_TESTPOINT], [test x$build_lib_testpoint = xyes])
1064 AM_CONDITIONAL([BUILD_LIB_UST_CONSUMER], [test x$build_lib_ust_consumer = xyes])
1065
1066 AM_CFLAGS="${WARN_CFLAGS} -fno-strict-aliasing $PTHREAD_CFLAGS"
1067 AC_SUBST(AM_CFLAGS)
1068
1069 # This is set even though it is empty, so Makefiles can do "AM_LDFLAGS += ...".
1070 AM_LDFLAGS=""
1071 AC_SUBST(AM_LDFLAGS)
1072
1073 # The order in which the include folders are searched is important.
1074 # The top_builddir should always be searched first in the event that a build
1075 # time generated file is included. An example of this is the "version.i" file.
1076 # In a scenario where lttng-tools is built from a distribution tarball and in a
1077 # out-of-tree manner, the generated "version.i" has priority on the one from
1078 # the source (distribution tarball) and must be found first.
1079 AM_CPPFLAGS="-I\$(top_builddir)/include -I\$(top_srcdir)/include -I\$(top_srcdir)/src -include config.h $AM_CPPFLAGS"
1080 AC_SUBST(AM_CPPFLAGS)
1081
1082 lttngincludedir="${includedir}/lttng"
1083 AC_SUBST(lttngincludedir)
1084
1085 lttngactionincludedir="${includedir}/lttng/action"
1086 AC_SUBST(lttngactionincludedir)
1087
1088 lttngconditionincludedir="${includedir}/lttng/condition"
1089 AC_SUBST(lttngconditionincludedir)
1090
1091 lttngnotificationincludedir="${includedir}/lttng/notification"
1092 AC_SUBST(lttngnotificationincludedir)
1093
1094 lttngtriggerincludedir="${includedir}/lttng/trigger"
1095 AC_SUBST(lttngtriggerincludedir)
1096
1097 lttnglibexecdir="${libdir}/lttng/libexec"
1098 AC_SUBST(lttnglibexecdir)
1099
1100 AC_CONFIG_FILES([
1101         Makefile
1102         doc/Makefile
1103         doc/man/Makefile
1104         doc/man/asciidoc-attrs.conf
1105         include/Makefile
1106         extras/Makefile
1107         extras/bindings/Makefile
1108         extras/bindings/swig/Makefile
1109         extras/bindings/swig/python/Makefile
1110         extras/core-handler/Makefile
1111         src/Makefile
1112         src/common/Makefile
1113         src/common/kernel-ctl/Makefile
1114         src/common/kernel-consumer/Makefile
1115         src/common/consumer/Makefile
1116         src/common/ust-consumer/Makefile
1117         src/common/hashtable/Makefile
1118         src/common/sessiond-comm/Makefile
1119         src/common/compat/Makefile
1120         src/common/relayd/Makefile
1121         src/common/testpoint/Makefile
1122         src/common/index/Makefile
1123         src/common/health/Makefile
1124         src/common/config/Makefile
1125         src/common/string-utils/Makefile
1126         src/common/fd-tracker/Makefile
1127         src/lib/Makefile
1128         src/lib/lttng-ctl/Makefile
1129         src/lib/lttng-ctl/filter/Makefile
1130         src/lib/lttng-ctl/lttng-ctl.pc
1131         src/bin/Makefile
1132         src/bin/lttng-consumerd/Makefile
1133         src/bin/lttng-sessiond/Makefile
1134         src/bin/lttng-relayd/Makefile
1135         src/bin/lttng/Makefile
1136         src/bin/lttng-crash/Makefile
1137         tests/Makefile
1138         tests/destructive/Makefile
1139         tests/regression/Makefile
1140         tests/regression/kernel/Makefile
1141         tests/regression/tools/Makefile
1142         tests/regression/tools/streaming/Makefile
1143         tests/regression/tools/filtering/Makefile
1144         tests/regression/tools/health/Makefile
1145         tests/regression/tools/tracefile-limits/Makefile
1146         tests/regression/tools/snapshots/Makefile
1147         tests/regression/tools/live/Makefile
1148         tests/regression/tools/exclusion/Makefile
1149         tests/regression/tools/save-load/Makefile
1150         tests/regression/tools/save-load/configuration/Makefile
1151         tests/regression/tools/mi/Makefile
1152         tests/regression/tools/wildcard/Makefile
1153         tests/regression/tools/crash/Makefile
1154         tests/regression/tools/regen-metadata/Makefile
1155         tests/regression/tools/regen-statedump/Makefile
1156         tests/regression/tools/notification/Makefile
1157         tests/regression/tools/rotation/Makefile
1158         tests/regression/tools/base-path/Makefile
1159         tests/regression/tools/metadata/Makefile
1160         tests/regression/tools/tracker/Makefile
1161         tests/regression/tools/working-directory/Makefile
1162         tests/regression/tools/relayd-grouping/Makefile
1163         tests/regression/tools/clear/Makefile
1164         tests/regression/ust/Makefile
1165         tests/regression/ust/nprocesses/Makefile
1166         tests/regression/ust/high-throughput/Makefile
1167         tests/regression/ust/low-throughput/Makefile
1168         tests/regression/ust/before-after/Makefile
1169         tests/regression/ust/buffers-pid/Makefile
1170         tests/regression/ust/periodical-metadata-flush/Makefile
1171         tests/regression/ust/multi-session/Makefile
1172         tests/regression/ust/multi-lib/Makefile
1173         tests/regression/ust/overlap/Makefile
1174         tests/regression/ust/overlap/demo/Makefile
1175         tests/regression/ust/linking/Makefile
1176         tests/regression/ust/daemon/Makefile
1177         tests/regression/ust/exit-fast/Makefile
1178         tests/regression/ust/fork/Makefile
1179         tests/regression/ust/libc-wrapper/Makefile
1180         tests/regression/ust/baddr-statedump/Makefile
1181         tests/regression/ust/ust-dl/Makefile
1182         tests/regression/ust/java-jul/Makefile
1183         tests/regression/ust/java-log4j/Makefile
1184         tests/regression/ust/python-logging/Makefile
1185         tests/regression/ust/getcpu-override/Makefile
1186         tests/regression/ust/clock-override/Makefile
1187         tests/regression/ust/type-declarations/Makefile
1188         tests/regression/ust/rotation-destroy-flush/Makefile
1189         tests/regression/ust/blocking/Makefile
1190         tests/regression/ust/namespaces/Makefile
1191         tests/stress/Makefile
1192         tests/unit/Makefile
1193         tests/unit/ini_config/Makefile
1194         tests/perf/Makefile
1195         tests/utils/Makefile
1196         tests/utils/tap/Makefile
1197         tests/utils/testapp/Makefile
1198         tests/utils/testapp/gen-ns-events/Makefile
1199         tests/utils/testapp/gen-kernel-test-events/Makefile
1200         tests/utils/testapp/gen-ust-events/Makefile
1201         tests/utils/testapp/gen-ust-events-ns/Makefile
1202         tests/utils/testapp/gen-syscall-events-callstack/Makefile
1203         tests/utils/testapp/gen-ust-nevents/Makefile
1204         tests/utils/testapp/gen-ust-nevents-str/Makefile
1205         tests/utils/testapp/gen-syscall-events/Makefile
1206         tests/utils/testapp/gen-ust-tracef/Makefile
1207         tests/utils/testapp/userspace-probe-elf-binary/Makefile
1208         tests/utils/testapp/userspace-probe-elf-cxx-binary/Makefile
1209         tests/utils/testapp/userspace-probe-sdt-binary/Makefile
1210 ])
1211
1212 # Inject variable into python test script.
1213 AC_CONFIG_FILES([tests/regression/ust/python-logging/test_python_logging],[chmod +x tests/regression/ust/python-logging/test_python_logging])
1214 # Inject LTTNG_TOOLS_BUILD_WITH_LIBPFM variable in test script.
1215 AC_CONFIG_FILES([tests/perf/test_perf_raw],[chmod +x tests/perf/test_perf_raw])
1216 AC_CONFIG_FILES([tests/regression/ust/ust-dl/test_ust-dl],[chmod +x tests/regression/ust/ust-dl/test_ust-dl])
1217
1218 AC_OUTPUT
1219
1220 #
1221 # Mini-report on what will be built.
1222 #
1223
1224 PPRINT_INIT
1225 PPRINT_SET_INDENT(1)
1226 PPRINT_SET_TS(38)
1227
1228 AS_ECHO
1229 AS_ECHO("${PPRINT_COLOR_BLDBLU}LTTng-tools $PACKAGE_VERSION \"$version_name\"$PPRINT_COLOR_RST")
1230 AS_ECHO
1231
1232 AS_IF([test -n "$report_fold"], [
1233         AS_ECHO("`AS_ECHO("$version_description") | $report_fold -s`")
1234 ], [
1235         AS_ECHO("$version_description")
1236 ])
1237
1238 AS_ECHO
1239 PPRINT_SUBTITLE([Features])
1240
1241 # Target architecture we're building for.
1242 target_arch=$host_cpu
1243 [
1244 for f in $CFLAGS; do
1245         if test $f = "-m32"; then
1246                         target_arch="32-bit"
1247         elif test $f = "-m64"; then
1248                         target_arch="64-bit"
1249         fi
1250 done
1251 ]
1252 PPRINT_PROP_STRING([Target architecture], $target_arch)
1253
1254 # kmod enabled/disabled
1255 test "x$with_kmod" != "xno" && value=1 || value=0
1256 PPRINT_PROP_BOOL([libkmod support], $value)
1257
1258 # LTTng-UST enabled/disabled
1259 test "x$with_lttng_ust" = "xyes" && value=1 || value=0
1260 PPRINT_PROP_BOOL([LTTng-UST support], $value)
1261
1262 AS_ECHO
1263 PPRINT_SUBTITLE([Binaries])
1264
1265 # List binaries to be built
1266 test x$enable_bin_lttng != xno && value=1 || value=0
1267 PPRINT_PROP_BOOL([lttng], $value)
1268
1269 test x$enable_bin_lttng_consumerd != xno && value=1 || value=0
1270 PPRINT_PROP_BOOL([lttng-consumerd], $value)
1271
1272 test x$enable_bin_lttng_crash != xno && value=1 || value=0
1273 PPRINT_PROP_BOOL([lttng-crash], $value)
1274
1275 test x$enable_bin_lttng_relayd != xno && value=1 || value=0
1276 PPRINT_PROP_BOOL([lttng-relayd], $value)
1277
1278 test x$enable_bin_lttng_sessiond != xno && value=1 || value=0
1279 PPRINT_PROP_BOOL([lttng-sessiond], $value)
1280
1281 # Extras
1282 test x$enable_extras != xno && value=1 || value=0
1283 AS_ECHO
1284 PPRINT_SET_INDENT(0)
1285 PPRINT_PROP_BOOL([Extras], $value, $PPRINT_COLOR_SUBTITLE)
1286 PPRINT_SET_INDENT(1)
1287
1288 AS_ECHO
1289 PPRINT_SUBTITLE([Tests])
1290
1291 # Print clear message that tests won't be built
1292 AS_IF([test "x$build_tests" = "xno"],[
1293         PPRINT_WARN([Tests won't be built since some binaries were disabled])
1294 ])
1295
1296 # LTTng UST Java agent JUL tests enabled/disabled
1297 test "x$test_java_agent_jul" = "xyes" && value=1 || value=0
1298 PPRINT_PROP_BOOL([LTTng-UST Java agent JUL tests], $value)
1299
1300 # LTTng UST Java agent Log4j tests enabled/disabled
1301 test "x$test_java_agent_log4j" = "xyes" && value=1 || value=0
1302 PPRINT_PROP_BOOL([LTTng-UST Java agent Log4j tests], $value)
1303
1304 test ! -z "$PYTHON2_AGENT" && value=1 || value=0
1305 PPRINT_PROP_BOOL([LTTng-UST Python2 agent tests], $value)
1306
1307 test ! -z "$PYTHON3_AGENT" && value=1 || value=0
1308 PPRINT_PROP_BOOL([LTTng-UST Python3 agent tests], $value)
1309
1310 # LTTng UST Java agent Log4j tests enabled/disabled
1311 test "x$test_sdt_uprobe" = "xyes" && value=1 || value=0
1312 PPRINT_PROP_BOOL([LTTng-UST SDT uprobe tests], $value)
1313
1314 #Python binding enabled/disabled
1315 test "x$enable_python_binding" = xyes && value=1 || value=0
1316 AS_ECHO
1317 PPRINT_SET_INDENT(0)
1318 PPRINT_PROP_BOOL([Python binding], $value, $PPRINT_COLOR_SUBTITLE)
1319
1320 # man pages build enabled/disabled
1321 m4_pushdef([build_man_pages_msg], [Build and install man pages])
1322
1323 AS_IF([test "x$man_pages_opt" != "xno"], [
1324         AS_IF([test "x$in_git_repo" = "xyes"], [
1325                 PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
1326         ], [
1327                 AS_IF([test "x$have_asciidoc_xmlto" = "xyes"], [
1328                         PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
1329                 ], [
1330                         PPRINT_PROP_STRING([build_man_pages_msg],
1331                                 [${PPRINT_COLOR_BLDGRN}yes (already built)],
1332                                 $PPRINT_COLOR_SUBTITLE)
1333                 ])
1334         ])
1335 ], [
1336         PPRINT_PROP_BOOL([build_man_pages_msg], 0, $PPRINT_COLOR_SUBTITLE)
1337 ])
1338
1339 m4_popdef([build_man_pages_msg])
1340
1341 test "x$embedded_help" = xyes && value=1 || value=0
1342 PPRINT_PROP_BOOL([Embed --help messages], $value, $PPRINT_COLOR_SUBTITLE)
1343
1344 PPRINT_SET_INDENT(1)
1345
1346 report_bindir="`eval eval echo $bindir`"
1347 report_libdir="`eval eval echo $libdir`"
1348
1349 # Print the bindir and libdir this `make install' will install into.
1350 AS_ECHO
1351 PPRINT_SUBTITLE([Install directories])
1352 PPRINT_PROP_STRING([Binaries], [$report_bindir])
1353 PPRINT_PROP_STRING([Libraries], [$report_libdir])
1354
1355 AS_ECHO
1356 PPRINT_SUBTITLE([Search directories])
1357
1358 # If we build the sessiond, print the paths it will use
1359 AS_IF([test "$SESSIOND_BIN" = ""],[
1360         path="$report_bindir/lttng-sessiond"
1361 ],[
1362         path="$SESSIOND_BIN"
1363 ])
1364 PPRINT_PROP_STRING([lttng-sessiond executable], [$path])
1365
1366 AS_IF([test "$CONSUMERD32_BIN" = ""],[
1367         path="`eval eval echo $lttnglibexecdir`/lttng-consumerd"
1368 ],[
1369         path="$CONSUMERD32_BIN"
1370 ])
1371 PPRINT_PROP_STRING([32-bit lttng-consumerd executable], [$path])
1372
1373 AS_IF([test "$CONSUMERD32_LIBDIR" = ""],[
1374         path="`eval eval echo $libdir`"
1375 ],[
1376         path="$CONSUMERD32_LIBDIR"
1377 ])
1378 PPRINT_PROP_STRING([32-bit consumer libraries], [$path])
1379
1380 AS_IF([test "$CONSUMERD64_BIN" = ""],[
1381         path="`eval eval echo $lttnglibexecdir`/lttng-consumerd"
1382 ],[
1383         path="$CONSUMERD64_BIN"
1384 ])
1385 PPRINT_PROP_STRING([64-bit lttng-consumerd executable], [$path])
1386
1387 AS_IF([test "$CONSUMERD64_LIBDIR" = ""],[
1388         path="`eval eval echo $libdir`"
1389 ],[
1390         path="$CONSUMERD64_LIBDIR"
1391 ])
1392 PPRINT_PROP_STRING([64-bit consumer libraries], [$path])
1393 PPRINT_SET_INDENT(0)
1394
1395 AS_IF([test "x$warn_prebuilt_man_pages" = "xyes" ], [
1396         AS_ECHO
1397         PPRINT_WARN([You need asciidoc and xmlto to build the LTTng-tools man pages.
1398
1399 Note that the man pages are already built in this distribution tarball,
1400 therefore asciidoc and xmlto are only needed if you intend to modify
1401 their sources.
1402
1403 Also note that the installed man pages will contain the project's
1404 default command-line option and environment variable values.
1405
1406 Use --disable-man-pages to completely disable building and installing
1407 the man pages.])
1408 ])